src/code/cold-error.lisp

   1 ;;;; miscellaneous stuff that needs to be in the cold load which would
   2 ;;;; otherwise be byte-compiled
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!KERNEL")
  14
  15 (defvar *break-on-signals* nil
  16   #!+sb-doc
  17   "When (TYPEP condition *BREAK-ON-SIGNALS*) is true, then calls to SIGNAL will
  18    enter the debugger prior to signalling that condition.")
  19
  20 (defun signal (datum &rest arguments)
  21   #!+sb-doc
  22   "Invokes the signal facility on a condition formed from DATUM and
  23    ARGUMENTS. If the condition is not handled, NIL is returned. If
  24    (TYPEP condition *BREAK-ON-SIGNALS*) is true, the debugger is invoked
  25    before any signalling is done."
  26   (let ((condition (coerce-to-condition datum
  27                                         arguments
  28                                         'simple-condition
  29                                         'signal))
  30         (*handler-clusters* *handler-clusters*))
  31     (let ((old-bos *break-on-signals*)
  32           (*break-on-signals* nil))
  33       (when (typep condition old-bos)
  34         (break "~A~%BREAK was entered because of *BREAK-ON-SIGNALS* (now NIL)."
  35                condition)))
  36     (loop
  37       (unless *handler-clusters* (return))
  38       (let ((cluster (pop *handler-clusters*)))
  39         (dolist (handler cluster)
  40           (when (typep condition (car handler))
  41             (funcall (cdr handler) condition)))))
  42     nil))
  43
  44 ;;; COERCE-TO-CONDITION is used in SIGNAL, ERROR, CERROR, WARN, and
  45 ;;; INVOKE-DEBUGGER for parsing the hairy argument conventions into a single
  46 ;;; argument that's directly usable by all the other routines.
  47 (defun coerce-to-condition (datum arguments default-type function-name)
  48   (cond ((typep datum 'condition)
  49          (if arguments
  50              (cerror "Ignore the additional arguments."
  51                      'simple-type-error
  52                      :datum arguments
  53                      :expected-type 'null
  54                      :format-control "You may not supply additional arguments ~
  55                                      when giving ~S to ~S."
  56                      :format-arguments (list datum function-name)))
  57          datum)
  58         ((symbolp datum) ; roughly, (SUBTYPEP DATUM 'CONDITION)
  59          (apply #'make-condition datum arguments))
  60         ((or (stringp datum) (functionp datum))
  61          (make-condition default-type
  62                          :format-control datum
  63                          :format-arguments arguments))
  64         (t
  65          (error 'simple-type-error
  66                 :datum datum
  67                 :expected-type '(or symbol string)
  68                 :format-control "bad argument to ~S: ~S"
  69                 :format-arguments (list function-name datum)))))
  70
  71 (defun error (datum &rest arguments)
  72   #!+sb-doc
  73   "Invoke the signal facility on a condition formed from datum and arguments.
  74    If the condition is not handled, the debugger is invoked."
  75   (/show0 "entering ERROR, arguments=..")
  76   #!+sb-show (dolist (argument arguments)
  77                (sb!impl::cold-print argument))
  78   (sb!kernel:infinite-error-protect
  79     (let ((condition (coerce-to-condition datum arguments
  80                                           'simple-error 'error))
  81           ;; FIXME: Why is *STACK-TOP-HINT* in SB-DEBUG instead of SB-DI?
  82           ;; SB-DEBUG should probably be only for true interface stuff.
  83           (sb!debug:*stack-top-hint* sb!debug:*stack-top-hint*))
  84       (unless (and (condition-function-name condition)
  85                    sb!debug:*stack-top-hint*)
  86         (multiple-value-bind (name frame) (sb!kernel:find-caller-name)
  87           (unless (condition-function-name condition)
  88             (setf (condition-function-name condition) name))
  89           (unless sb!debug:*stack-top-hint*
  90             (setf sb!debug:*stack-top-hint* frame))))
  91       (let ((sb!debug:*stack-top-hint* nil))
  92         (signal condition))
  93       (invoke-debugger condition))))
  94
  95 (defun cerror (continue-string datum &rest arguments)
  96   (sb!kernel:infinite-error-protect
  97     (with-simple-restart
  98         (continue "~A" (apply #'format nil continue-string arguments))
  99       (let ((condition (if (typep datum 'condition)
 100                            datum
 101                            (coerce-to-condition datum
 102                                                 arguments
 103                                                 'simple-error
 104                                                 'error)))
 105             (sb!debug:*stack-top-hint* sb!debug:*stack-top-hint*))
 106         (unless (and (condition-function-name condition)
 107                      sb!debug:*stack-top-hint*)
 108           (multiple-value-bind (name frame) (sb!kernel:find-caller-name)
 109             (unless (condition-function-name condition)
 110               (setf (condition-function-name condition) name))
 111             (unless sb!debug:*stack-top-hint*
 112               (setf sb!debug:*stack-top-hint* frame))))
 113         (with-condition-restarts condition (list (find-restart 'continue))
 114           (let ((sb!debug:*stack-top-hint* nil))
 115             (signal condition))
 116           (invoke-debugger condition)))))
 117   nil)
 118
 119 (defun break (&optional (datum "break") &rest arguments)
 120   #!+sb-doc
 121   "Print a message and invoke the debugger without allowing any possibility
 122    of condition handling occurring."
 123   (sb!kernel:infinite-error-protect
 124     (with-simple-restart (continue "Return from BREAK.")
 125       (let ((sb!debug:*stack-top-hint*
 126              (or sb!debug:*stack-top-hint*
 127                  (nth-value 1 (sb!kernel:find-caller-name)))))
 128         (invoke-debugger
 129          (coerce-to-condition datum arguments 'simple-condition 'break)))))
 130   nil)
 131
 132 (defun warn (datum &rest arguments)
 133   #!+sb-doc
 134   "Warn about a situation by signalling a condition formed by DATUM and
 135    ARGUMENTS. While the condition is being signaled, a MUFFLE-WARNING restart
 136    exists that causes WARN to immediately return NIL."
 137   (/noshow0 "entering WARN")
 138   ;; KLUDGE: The current cold load initialization logic causes several calls
 139   ;; to WARN, so we need to be able to handle them without dying. (And calling
 140   ;; FORMAT or even PRINC in cold load is a good way to die.) Of course, the
 141   ;; ideal would be to clean up cold load so that it doesn't call WARN..
 142   ;; -- WHN 19991009
 143   (if (not *cold-init-complete-p*)
 144       (progn
 145         (/show0 "ignoring WARN in cold init, arguments=..")
 146         #!+sb-show (dolist (argument arguments)
 147                      (sb!impl::cold-print argument)))
 148       (sb!kernel:infinite-error-protect
 149        (let ((condition (coerce-to-condition datum arguments
 150                                              'simple-warning 'warn)))
 151          (check-type condition warning "a warning condition")
 152          (restart-case (signal condition)
 153            (muffle-warning ()
 154              :report "Skip warning."
 155              (return-from warn nil)))
 156          (let ((badness (etypecase condition
 157                           (style-warning 'style-warning)
 158                           (warning 'warning))))
 159            (format *error-output*
 160                    "~&~@<~S: ~3i~:_~A~:>~%"
 161                    badness
 162                    condition)))))
 163   nil)