src/code/cold-init.lisp

   1 ;;;; cold initialization stuff, plus some other miscellaneous stuff
   2 ;;;; that we don't have any better place for
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!IMPL")
  14 \f
  15 ;;;; burning our ships behind us
  16
  17 ;;; There's a fair amount of machinery which is needed only at cold
  18 ;;; init time, and should be discarded before freezing the final
  19 ;;; system. We discard it by uninterning the associated symbols.
  20 ;;; Rather than using a special table of symbols to be uninterned,
  21 ;;; which might be tedious to maintain, instead we use a hack:
  22 ;;; anything whose name matches a magic character pattern is
  23 ;;; uninterned.
  24 ;;;
  25 ;;; FIXME: Are there other tables that need to have entries removed?
  26 ;;; What about symbols of the form DEF!FOO?
  27 (defun !unintern-init-only-stuff ()
  28   (do ((any-changes? nil nil))
  29       (nil)
  30     (dolist (package (list-all-packages))
  31       (do-symbols (symbol package)
  32         (let ((name (symbol-name symbol)))
  33           (when (or (string= name "!" :end1 1 :end2 1)
  34                     (and (>= (length name) 2)
  35                          (string= name "*!" :end1 2 :end2 2)))
  36             (/show0 "uninterning cold-init-only symbol..")
  37             (/primitive-print name)
  38             ;; FIXME: Is this (FIRST (LAST *INFO-ENVIRONMENT*)) really
  39             ;; meant to be an idiom to use?  Is there a more obvious
  40             ;; name for this? [e.g. (GLOBAL-ENVIRONMENT)?]
  41             (do-info ((first (last *info-environment*))
  42                             :name entry :class class :type type)
  43               (when (eq entry symbol)
  44                 (clear-info class type entry)))
  45             (unintern symbol package)
  46             (setf any-changes? t)))))
  47     (unless any-changes?
  48       (return))))
  49 \f
  50 ;;;; putting ourselves out of our misery when things become too much to bear
  51
  52 (declaim (ftype (function (simple-string) nil) !cold-lose))
  53 (defun !cold-lose (msg)
  54   (%primitive print msg)
  55   (%primitive print "too early in cold init to recover from errors")
  56   (%halt))
  57
  58 ;;; last-ditch error reporting for things which should never happen
  59 ;;; and which, if they do happen, are sufficiently likely to torpedo
  60 ;;; the normal error-handling system that we want to bypass it
  61 (declaim (ftype (function (simple-string) nil) critically-unreachable))
  62 (defun critically-unreachable (where)
  63   (%primitive print "internal error: Control should never reach here, i.e.")
  64   (%primitive print where)
  65   (%halt))
  66 \f
  67 ;;;; !COLD-INIT
  68
  69 ;;; a list of toplevel things set by GENESIS
  70 (defvar *!reversed-cold-toplevels*)
  71
  72 ;;; a SIMPLE-VECTOR set by GENESIS
  73 (defvar *!load-time-values*)
  74
  75 (eval-when (:compile-toplevel :execute)
  76   ;; FIXME: Perhaps we should make SHOW-AND-CALL-AND-FMAKUNBOUND, too,
  77   ;; and use it for most of the cold-init functions. (Just be careful
  78   ;; not to use it for the COLD-INIT-OR-REINIT functions.)
  79   (sb!xc:defmacro show-and-call (name)
  80     `(progn
  81        (/primitive-print ,(symbol-name name))
  82        (,name))))
  83
  84 ;;; called when a cold system starts up
  85 (defun !cold-init ()
  86   #!+sb-doc "Give the world a shove and hope it spins."
  87
  88   (/show0 "entering !COLD-INIT")
  89
  90   ;; FIXME: It'd probably be cleaner to have most of the stuff here
  91   ;; handled by calls like !GC-COLD-INIT, !ERROR-COLD-INIT, and
  92   ;; !UNIX-COLD-INIT. And *TYPE-SYSTEM-INITIALIZED* could be changed to
  93   ;; *TYPE-SYSTEM-INITIALIZED-WHEN-BOUND* so that it doesn't need to
  94   ;; be explicitly set in order to be meaningful.
  95   (setf *after-gc-hooks* nil
  96         *gc-inhibit* t
  97         *gc-pending* nil
  98         #!+sb-thread *stop-for-gc-pending* #!+sb-thread nil
  99         sb!unix::*interrupts-enabled* t
 100         sb!unix::*interrupt-pending* nil
 101         *break-on-signals* nil
 102         *maximum-error-depth* 10
 103         *current-error-depth* 0
 104         *cold-init-complete-p* nil
 105         *type-system-initialized* nil)
 106
 107   (show-and-call thread-init-or-reinit)
 108   (show-and-call !typecheckfuns-cold-init)
 109
 110   ;; Anyone might call RANDOM to initialize a hash value or something;
 111   ;; and there's nothing which needs to be initialized in order for
 112   ;; this to be initialized, so we initialize it right away.
 113   (show-and-call !random-cold-init)
 114
 115   (show-and-call !character-database-cold-init)
 116   (show-and-call !character-name-database-cold-init)
 117
 118   (show-and-call !early-package-cold-init)
 119   (show-and-call !package-cold-init)
 120
 121   ;; All sorts of things need INFO and/or (SETF INFO).
 122   (/show0 "about to SHOW-AND-CALL !GLOBALDB-COLD-INIT")
 123   (show-and-call !globaldb-cold-init)
 124
 125   ;; This needs to be done early, but needs to be after INFO is
 126   ;; initialized.
 127   (show-and-call !function-names-cold-init)
 128   (show-and-call !fdefn-cold-init)
 129
 130   ;; Various toplevel forms call MAKE-ARRAY, which calls SUBTYPEP, so
 131   ;; the basic type machinery needs to be initialized before toplevel
 132   ;; forms run.
 133   (show-and-call !type-class-cold-init)
 134   (show-and-call !typedefs-cold-init)
 135   (show-and-call !classes-cold-init)
 136   (show-and-call !early-type-cold-init)
 137   (show-and-call !late-type-cold-init)
 138   (show-and-call !alien-type-cold-init)
 139   (show-and-call !target-type-cold-init)
 140   (show-and-call !vm-type-cold-init)
 141   ;; FIXME: It would be tidy to make sure that that these cold init
 142   ;; functions are called in the same relative order as the toplevel
 143   ;; forms of the corresponding source files.
 144
 145   ;;(show-and-call !package-cold-init)
 146   (show-and-call !policy-cold-init-or-resanify)
 147   (/show0 "back from !POLICY-COLD-INIT-OR-RESANIFY")
 148
 149   (show-and-call !constantp-cold-init)
 150   (show-and-call !early-proclaim-cold-init)
 151
 152   ;; KLUDGE: Why are fixups mixed up with toplevel forms? Couldn't
 153   ;; fixups be done separately? Wouldn't that be clearer and better?
 154   ;; -- WHN 19991204
 155   (/show0 "doing cold toplevel forms and fixups")
 156   (/show0 "(LISTP *!REVERSED-COLD-TOPLEVELS*)=..")
 157   (/hexstr (if (listp *!reversed-cold-toplevels*) "true" "NIL"))
 158   (/show0 "about to calculate (LENGTH *!REVERSED-COLD-TOPLEVELS*)")
 159   (/show0 "(LENGTH *!REVERSED-COLD-TOPLEVELS*)=..")
 160   #!+sb-show (let ((r-c-tl-length (length *!reversed-cold-toplevels*)))
 161                (/show0 "(length calculated..)")
 162                (let ((hexstr (hexstr r-c-tl-length)))
 163                  (/show0 "(hexstr calculated..)")
 164                  (/primitive-print hexstr)))
 165   (let (#!+sb-show (index-in-cold-toplevels 0))
 166     #!+sb-show (declare (type fixnum index-in-cold-toplevels))
 167
 168     (dolist (toplevel-thing (prog1
 169                                 (nreverse *!reversed-cold-toplevels*)
 170                               ;; (Now that we've NREVERSEd it, it's
 171                               ;; somewhat scrambled, so keep anyone
 172                               ;; else from trying to get at it.)
 173                               (makunbound '*!reversed-cold-toplevels*)))
 174       #!+sb-show
 175       (when (zerop (mod index-in-cold-toplevels 1024))
 176         (/show0 "INDEX-IN-COLD-TOPLEVELS=..")
 177         (/hexstr index-in-cold-toplevels))
 178       #!+sb-show
 179       (setf index-in-cold-toplevels
 180             (the fixnum (1+ index-in-cold-toplevels)))
 181       (typecase toplevel-thing
 182         (function
 183          (funcall toplevel-thing))
 184         (cons
 185          (case (first toplevel-thing)
 186            (:load-time-value
 187             (setf (svref *!load-time-values* (third toplevel-thing))
 188                   (funcall (second toplevel-thing))))
 189            (:load-time-value-fixup
 190             (setf (sap-ref-word (second toplevel-thing) 0)
 191                   (get-lisp-obj-address
 192                    (svref *!load-time-values* (third toplevel-thing)))))
 193            #!+(and (or x86 x86-64) gencgc)
 194            (:load-time-code-fixup
 195             (sb!vm::!envector-load-time-code-fixup (second toplevel-thing)
 196                                                    (third  toplevel-thing)
 197                                                    (fourth toplevel-thing)
 198                                                    (fifth  toplevel-thing)))
 199            (t
 200             (!cold-lose "bogus fixup code in *!REVERSED-COLD-TOPLEVELS*"))))
 201         (t (!cold-lose "bogus function in *!REVERSED-COLD-TOPLEVELS*")))))
 202   (/show0 "done with loop over cold toplevel forms and fixups")
 203
 204   ;; Set sane values again, so that the user sees sane values instead
 205   ;; of whatever is left over from the last DECLAIM/PROCLAIM.
 206   (show-and-call !policy-cold-init-or-resanify)
 207
 208   ;; Only do this after toplevel forms have run, 'cause that's where
 209   ;; DEFTYPEs are.
 210   (setf *type-system-initialized* t)
 211
 212   ;; now that the type system is definitely initialized, fixup UNKNOWN
 213   ;; types that have crept in.
 214   (show-and-call !fixup-type-cold-init)
 215   ;; run the PROCLAIMs.
 216   (show-and-call !late-proclaim-cold-init)
 217
 218   (show-and-call os-cold-init-or-reinit)
 219
 220   (show-and-call stream-cold-init-or-reset)
 221   (show-and-call !loader-cold-init)
 222   (show-and-call !foreign-cold-init)
 223   #!-win32 (show-and-call signal-cold-init-or-reinit)
 224   (/show0 "enabling internal errors")
 225   (setf (sb!alien:extern-alien "internal_errors_enabled" boolean) t)
 226
 227   ;; FIXME: This list of modes should be defined in one place and
 228   ;; explicitly shared between here and REINIT.
 229
 230   ;; FIXME: For some unknown reason, NetBSD/x86 won't run with the
 231   ;; :invalid trap enabled. That should be fixed, but not today...
 232   ;; PEM -- April 5, 2004
 233   (set-floating-point-modes
 234    :traps '(:overflow #!-netbsd :invalid :divide-by-zero))
 235
 236   (show-and-call !class-finalize)
 237
 238   ;; The reader and printer are initialized very late, so that they
 239   ;; can do hairy things like invoking the compiler as part of their
 240   ;; initialization.
 241   (show-and-call !reader-cold-init)
 242   (let ((*readtable* *standard-readtable*))
 243     (show-and-call !sharpm-cold-init)
 244     (show-and-call !backq-cold-init))
 245   (setf *readtable* (copy-readtable *standard-readtable*))
 246   (setf sb!debug:*debug-readtable* (copy-readtable *standard-readtable*))
 247   (sb!pretty:!pprint-cold-init)
 248
 249   ;; the ANSI-specified initial value of *PACKAGE*
 250   (setf *package* (find-package "COMMON-LISP-USER"))
 251
 252   (/show0 "done initializing, setting *COLD-INIT-COMPLETE-P*")
 253   (setf *cold-init-complete-p* t)
 254
 255   ;; The system is finally ready for GC.
 256   (/show0 "enabling GC")
 257   (gc-on)
 258   (/show0 "doing first GC")
 259   (gc :full t)
 260   (/show0 "back from first GC")
 261
 262   ;; The show is on.
 263   (terpri)
 264   (/show0 "going into toplevel loop")
 265   (handling-end-of-the-world
 266     (toplevel-init)
 267     (critically-unreachable "after TOPLEVEL-INIT")))
 268
 269 (defun quit (&key recklessly-p (unix-status 0))
 270   #!+sb-doc
 271   "Terminate the current Lisp. Things are cleaned up (with
 272 UNWIND-PROTECT and so forth) unless RECKLESSLY-P is non-NIL. On
 273 UNIX-like systems, UNIX-STATUS is used as the status code."
 274   (declare (type (signed-byte 32) unix-status))
 275   (/show0 "entering QUIT")
 276   (if recklessly-p
 277       (sb!unix:unix-exit unix-status)
 278       (throw '%end-of-the-world unix-status))
 279   (critically-unreachable "after trying to die in QUIT"))
 280 \f
 281 ;;;; initialization functions
 282
 283 (defun thread-init-or-reinit ()
 284   (sb!thread::init-initial-thread)
 285   (sb!thread::init-job-control)
 286   (sb!thread::get-foreground))
 287
 288 (defun reinit ()
 289   (setf *default-external-format* nil)
 290   (without-interrupts
 291     (without-gcing
 292         (os-cold-init-or-reinit)
 293       (thread-init-or-reinit)
 294       (stream-reinit)
 295       #!-win32 (signal-cold-init-or-reinit)
 296       (setf (sb!alien:extern-alien "internal_errors_enabled" boolean) t)
 297       ;; PRINT seems not to like x86 NPX denormal floats like
 298       ;; LEAST-NEGATIVE-SINGLE-FLOAT, so the :UNDERFLOW exceptions are
 299       ;; disabled by default. Joe User can explicitly enable them if
 300       ;; desired.
 301       ;;
 302       ;; see also comment at the previous SET-FLOATING-POINT-MODES
 303       ;; call site.
 304       (set-floating-point-modes
 305        :traps '(:overflow #!-netbsd :invalid :divide-by-zero))))
 306   (gc-reinit)
 307   ;; make sure TIME works correctly from saved cores
 308   (setf *internal-real-time-base-seconds* nil)
 309   (setf *gc-run-time* 0)
 310   (foreign-reinit)
 311   ;; If the debugger was disabled in the saved core, we need to
 312   ;; re-disable ldb again.
 313   (when (eq *invoke-debugger-hook* 'sb!debug::debugger-disabled-hook)
 314     (sb!debug::disable-debugger))
 315   (dolist (hook *init-hooks*)
 316     (with-simple-restart (continue "Skip this initialization hook.")
 317       (funcall hook))))
 318 \f
 319 ;;;; some support for any hapless wretches who end up debugging cold
 320 ;;;; init code
 321
 322 ;;; Decode THING into hexadecimal notation using only machinery
 323 ;;; available early in cold init.
 324 #!+sb-show
 325 (defun hexstr (thing)
 326   (/noshow0 "entering HEXSTR")
 327   (let ((addr (get-lisp-obj-address thing))
 328         (str (make-string 10 :element-type 'base-char)))
 329     (/noshow0 "ADDR and STR calculated")
 330     (setf (char str 0) #\0
 331           (char str 1) #\x)
 332     (/noshow0 "CHARs 0 and 1 set")
 333     (dotimes (i 8)
 334       (/noshow0 "at head of DOTIMES loop")
 335       (let* ((nibble (ldb (byte 4 0) addr))
 336              (chr (char "0123456789abcdef" nibble)))
 337         (declare (type (unsigned-byte 4) nibble)
 338                  (base-char chr))
 339         (/noshow0 "NIBBLE and CHR calculated")
 340         (setf (char str (- 9 i)) chr
 341               addr (ash addr -4))))
 342     str))
 343
 344 #!+sb-show
 345 (defun cold-print (x)
 346   (typecase x
 347     (simple-string (sb!sys:%primitive print x))
 348     (symbol (sb!sys:%primitive print (symbol-name x)))
 349     (list (let ((count 0))
 350             (sb!sys:%primitive print "list:")
 351             (dolist (i x)
 352               (when (>= (incf count) 4)
 353                 (sb!sys:%primitive print "...")
 354                 (return))
 355               (cold-print i))))
 356     (t (sb!sys:%primitive print (hexstr x)))))