src/code/cold-init.lisp

   1 ;;;; cold initialization stuff, plus some other miscellaneous stuff
   2 ;;;; that we don't have any better place for
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!IMPL")
  14 \f
  15 ;;;; burning our ships behind us
  16
  17 ;;; There's a fair amount of machinery which is needed only at cold
  18 ;;; init time, and should be discarded before freezing the final
  19 ;;; system. We discard it by uninterning the associated symbols.
  20 ;;; Rather than using a special table of symbols to be uninterned,
  21 ;;; which might be tedious to maintain, instead we use a hack:
  22 ;;; anything whose name matches a magic character pattern is
  23 ;;; uninterned.
  24 (defun !unintern-init-only-stuff ()
  25   (do ((any-changes? nil nil))
  26       (nil)
  27     (dolist (package (list-all-packages))
  28       (do-symbols (symbol package)
  29         (let ((name (symbol-name symbol)))
  30           (when (or (string= name "!" :end1 1 :end2 1)
  31                     (and (>= (length name) 2)
  32                          (string= name "*!" :end1 2 :end2 2)))
  33             (/show0 "uninterning cold-init-only symbol..")
  34             #!+sb-show (%primitive print name)
  35             (unintern symbol package)
  36             (setf any-changes? t)))))
  37     (unless any-changes?
  38       (return))))
  39 \f
  40 ;;;; !COLD-INIT
  41
  42 ;;; a list of toplevel things set by GENESIS
  43 (defvar *!reversed-cold-toplevels*)
  44
  45 ;;; a SIMPLE-VECTOR set by genesis
  46 (defvar *!load-time-values*)
  47
  48 (defun !cold-lose (msg)
  49   (%primitive print msg)
  50   (%primitive print "too early in cold init to recover from errors")
  51   (%halt))
  52
  53 #!+gengc
  54 (defun do-load-time-value-fixup (object offset index)
  55   (declare (type index offset))
  56   (let ((value (svref *!load-time-values* index)))
  57     (typecase object
  58       (list
  59        (case offset
  60          (0 (setf (car object) value))
  61          (1 (setf (cdr object) value))
  62          (t (!cold-lose "bogus offset in cons cell"))))
  63       (instance
  64        (setf (%instance-ref object (- offset sb!vm:instance-slots-offset))
  65              value))
  66       (code-component
  67        (setf (code-header-ref object offset) value))
  68       (simple-vector
  69        (setf (svref object (- offset sb!vm:vector-data-offset)) value))
  70       (t
  71        (!cold-lose "unknown kind of object for load-time-value fixup")))))
  72
  73 (eval-when (:compile-toplevel :execute)
  74   ;; FIXME: Perhaps we should make SHOW-AND-CALL-AND-FMAKUNBOUND, too,
  75   ;; and use it for most of the cold-init functions. (Just be careful
  76   ;; not to use it for the COLD-INIT-OR-REINIT functions.)
  77   (sb!xc:defmacro show-and-call (name)
  78     `(progn
  79        #!+sb-show (%primitive print ,(symbol-name name))
  80        (,name))))
  81
  82 ;;; called when a cold system starts up
  83 (defun !cold-init ()
  84   #!+sb-doc "Give the world a shove and hope it spins."
  85
  86   (/show0 "entering !COLD-INIT")
  87
  88   ;; FIXME: It'd probably be cleaner to have most of the stuff here
  89   ;; handled by calls like !GC-COLD-INIT, !ERROR-COLD-INIT, and
  90   ;; !UNIX-COLD-INIT. And *TYPE-SYSTEM-INITIALIZED* could be changed to
  91   ;; *TYPE-SYSTEM-INITIALIZED-WHEN-BOUND* so that it doesn't need to
  92   ;; be explicitly set in order to be meaningful.
  93   (setf *gc-verbose* nil)
  94   (setf *gc-notify-stream* nil)
  95   (setf *before-gc-hooks* nil)
  96   (setf *after-gc-hooks* nil)
  97   #!+gengc (setf *handler-clusters* nil)
  98   #!-gengc (setf *already-maybe-gcing* t
  99                  *gc-inhibit* t
 100                  *need-to-collect-garbage* nil
 101                  sb!unix::*interrupts-enabled* t
 102                  sb!unix::*interrupt-pending* nil)
 103   (setf *break-on-signals* nil)
 104   (setf *maximum-error-depth* 10)
 105   (setf *current-error-depth* 0)
 106   (setf *cold-init-complete-p* nil)
 107   (setf *type-system-initialized* nil)
 108
 109   ;; Anyone might call RANDOM to initialize a hash value or something;
 110   ;; and there's nothing which needs to be initialized in order for
 111   ;; this to be initialized, so we initialize it right away.
 112   (show-and-call !random-cold-init)
 113
 114   ;; All sorts of things need INFO and/or (SETF INFO).
 115   (/show0 "about to SHOW-AND-CALL !GLOBALDB-COLD-INIT")
 116   (show-and-call !globaldb-cold-init)
 117
 118   ;; This needs to be done early, but needs to be after INFO is
 119   ;; initialized.
 120   (show-and-call !fdefn-cold-init)
 121
 122   ;; Various toplevel forms call MAKE-ARRAY, which calls SUBTYPEP, so
 123   ;; the basic type machinery needs to be initialized before toplevel
 124   ;; forms run.
 125   (show-and-call !type-class-cold-init)
 126   (show-and-call !typedefs-cold-init)
 127   (show-and-call !classes-cold-init)
 128   (show-and-call !early-type-cold-init)
 129   (show-and-call !late-type-cold-init)
 130   (show-and-call !alien-type-cold-init)
 131   (show-and-call !target-type-cold-init)
 132   (show-and-call !vm-type-cold-init)
 133   ;; FIXME: It would be tidy to make sure that that these cold init
 134   ;; functions are called in the same relative order as the toplevel
 135   ;; forms of the corresponding source files.
 136
 137   (show-and-call !package-cold-init)
 138
 139   ;; Set sane values for our toplevel forms.
 140   (show-and-call !set-sane-cookie-defaults)
 141
 142   ;; KLUDGE: Why are fixups mixed up with toplevel forms? Couldn't
 143   ;; fixups be done separately? Wouldn't that be clearer and better?
 144   ;; -- WHN 19991204
 145   (/show0 "doing cold toplevel forms and fixups")
 146   (/show0 "(LENGTH *!REVERSED-COLD-TOPLEVELS*)=..")
 147   #!+sb-show (%primitive print
 148                          (sb!impl::hexstr (length *!reversed-cold-toplevels*)))
 149   (let (#!+sb-show (index-in-cold-toplevels 0)
 150         #!+sb-show (filename-in-cold-toplevels nil))
 151     #!+sb-show (declare (type fixnum index-in-cold-toplevels))
 152     (dolist (toplevel-thing (prog1
 153                                 (nreverse *!reversed-cold-toplevels*)
 154                               ;; (Now that we've NREVERSEd it, it's
 155                               ;; somewhat scrambled, so keep anyone
 156                               ;; else from trying to get at it.)
 157                               (makunbound '*!reversed-cold-toplevels*)))
 158       #!+sb-show
 159       (when (zerop (mod index-in-cold-toplevels 1024))
 160         (/show0 "INDEX-IN-COLD-TOPLEVELS=..")
 161         (%primitive print (sb!impl::hexstr index-in-cold-toplevels)))
 162       #!+sb-show
 163       (setf index-in-cold-toplevels
 164             (the fixnum (1+ index-in-cold-toplevels)))
 165       (typecase toplevel-thing
 166         (function
 167          (funcall toplevel-thing))
 168         (cons
 169          (case (first toplevel-thing)
 170            (:load-time-value
 171             (setf (svref *!load-time-values* (third toplevel-thing))
 172                   (funcall (second toplevel-thing))))
 173            (:load-time-value-fixup
 174             #!-gengc
 175             (setf (sap-ref-32 (second toplevel-thing) 0)
 176                   (get-lisp-obj-address
 177                    (svref *!load-time-values* (third toplevel-thing))))
 178             #!+gengc
 179             (do-load-time-value-fixup (second toplevel-thing)
 180                                       (third  toplevel-thing)
 181                                       (fourth toplevel-thing)))
 182            #!+(and x86 gencgc)
 183            (:load-time-code-fixup
 184             (sb!vm::do-load-time-code-fixup (second toplevel-thing)
 185                                             (third  toplevel-thing)
 186                                             (fourth toplevel-thing)
 187                                             (fifth  toplevel-thing)))
 188            (t
 189             (!cold-lose "bogus fixup code in *!REVERSED-COLD-TOPLEVELS*"))))
 190         (t (!cold-lose "bogus function in *!REVERSED-COLD-TOPLEVELS*")))))
 191   (/show0 "done with loop over cold toplevel forms and fixups")
 192
 193   ;; Set sane values again, so that the user sees sane values instead of
 194   ;; whatever is left over from the last DECLAIM.
 195   (show-and-call !set-sane-cookie-defaults)
 196
 197   ;; Only do this after top level forms have run, 'cause that's where
 198   ;; DEFTYPEs are.
 199   (setf *type-system-initialized* t)
 200
 201   (show-and-call os-cold-init-or-reinit)
 202
 203   (show-and-call stream-cold-init-or-reset)
 204   (show-and-call !loader-cold-init)
 205   (show-and-call signal-cold-init-or-reinit)
 206   (setf (sb!alien:extern-alien "internal_errors_enabled" boolean) t)
 207
 208   ;; FIXME: This list of modes should be defined in one place and
 209   ;; explicitly shared between here and REINIT.
 210   (set-floating-point-modes :traps '(:overflow
 211                                      #!-x86 :underflow
 212                                      :invalid
 213                                      :divide-by-zero))
 214
 215   (show-and-call !class-finalize)
 216
 217   ;; The reader and printer are initialized very late, so that they
 218   ;; can even do hairy things like invoking the compiler as part of
 219   ;; their initialization.
 220   (show-and-call !reader-cold-init)
 221   (let ((*readtable* *standard-readtable*))
 222     (show-and-call !sharpm-cold-init)
 223     (show-and-call !backq-cold-init))
 224   (setf *readtable* (copy-readtable *standard-readtable*))
 225   (setf sb!debug:*debug-readtable* (copy-readtable *standard-readtable*))
 226   (sb!pretty:!pprint-cold-init)
 227
 228   ;; the ANSI-specified initial value of *PACKAGE*
 229   (setf *package* (find-package "COMMON-LISP-USER"))
 230   ;; FIXME: I'm not sure where it should be done, but CL-USER really
 231   ;; ought to USE-PACKAGE publicly accessible packages like SB-DEBUG
 232   ;; (for ARG and VAR), SB-EXT, SB-EXT-C-CALL, and SB-EXT-ALIEN so
 233   ;; that the user has a hint about which symbols we consider public.
 234   ;; (Perhaps SB-DEBUG wouldn't need to be in the list if ARG and VAR
 235   ;; could be typed directly, with no parentheses, at the debug prompt
 236   ;; the way that e.g. F or BACKTRACE can be?)
 237
 238   (/show0 "done initializing")
 239   (setf *cold-init-complete-p* t)
 240
 241   ;; Unintern no-longer-needed stuff before we GC.
 242   #!-sb-fluid
 243   (!unintern-init-only-stuff)
 244
 245   ;; The system is finally ready for GC.
 246   #!-gengc (setf *already-maybe-gcing* nil)
 247   (/show0 "enabling GC")
 248   (gc-on)
 249   (/show0 "doing first GC")
 250   (gc :full t)
 251   (/show0 "back from first GC")
 252
 253   ;; The show is on.
 254   (terpri)
 255   (/show0 "going into toplevel loop")
 256   (handling-end-of-the-world
 257     (toplevel-init)))
 258
 259 (defun quit (&key recklessly-p
 260                   (unix-code 0 unix-code-p)
 261                   (unix-status unix-code))
 262   #!+sb-doc
 263   "Terminate the current Lisp. Things are cleaned up (with UNWIND-PROTECT
 264   and so forth) unless RECKLESSLY-P is non-NIL. On UNIX-like systems,
 265   UNIX-STATUS is used as the status code."
 266   (declare (type (signed-byte 32) unix-code))
 267   ;; FIXME: UNIX-CODE was deprecated in sbcl-0.6.8, after having been
 268   ;; around for less than a year. It should be safe to remove it after
 269   ;; a year.
 270   (when unix-code-p
 271     (warn "The UNIX-CODE argument is deprecated. Use the UNIX-STATUS argument
 272 instead (which is another name for the same thing)."))
 273   (if recklessly-p
 274       (sb!unix:unix-exit unix-status)
 275       (throw '%end-of-the-world unix-status)))
 276 \f
 277 ;;;; initialization functions
 278
 279 (defun reinit ()
 280   (without-interrupts
 281     (without-gcing
 282       (os-cold-init-or-reinit)
 283       (stream-reinit)
 284       (signal-cold-init-or-reinit)
 285       (gc-cold-init-or-reinit)
 286       (setf (sb!alien:extern-alien "internal_errors_enabled" boolean) t)
 287       (set-floating-point-modes :traps
 288                                 ;; PRINT seems to not like x86 NPX denormal
 289                                 ;; floats like LEAST-NEGATIVE-SINGLE-FLOAT, so
 290                                 ;; the :UNDERFLOW exceptions are disabled by
 291                                 ;; default. Joe User can explicitly enable them
 292                                 ;; if desired.
 293                                 '(:overflow #!-x86 :underflow :invalid
 294                                             :divide-by-zero))
 295       ;; Clear pseudo atomic in case this core wasn't compiled with
 296       ;; support.
 297       ;;
 298       ;; FIXME: In SBCL our cores are always compiled with support. So
 299       ;; we don't need to do this, do we? At least not for this
 300       ;; reason.. (Perhaps we should do it anyway in case someone
 301       ;; manages to save an image from within a pseudo-atomic-atomic
 302       ;; operation?)
 303       #!+x86 (setf sb!impl::*pseudo-atomic-atomic* 0))
 304     (gc-on)))
 305 \f
 306 ;;;; some support for any hapless wretches who end up debugging cold
 307 ;;;; init code
 308
 309 ;;; Decode THING into hex using only machinery available early in cold
 310 ;;; init.
 311 #!+sb-show
 312 (defun hexstr (thing)
 313   (let ((addr (sb!kernel:get-lisp-obj-address thing))
 314         (str (make-string 10)))
 315     (setf (char str 0) #\0
 316           (char str 1) #\x)
 317     (dotimes (i 8)
 318       (let* ((nibble (ldb (byte 4 0) addr))
 319              (chr (char "0123456789abcdef" nibble)))
 320         (declare (type (unsigned-byte 4) nibble)
 321                  (base-char chr))
 322         (setf (char str (- 9 i)) chr
 323               addr (ash addr -4))))
 324     str))
 325
 326 #!+sb-show
 327 (defun cold-print (x)
 328   (typecase x
 329     (simple-string (sb!sys:%primitive print x))
 330     (symbol (sb!sys:%primitive print (symbol-name x)))
 331     (list (let ((count 0))
 332             (sb!sys:%primitive print "list:")
 333             (dolist (i x)
 334               (when (>= (incf count) 4)
 335                 (sb!sys:%primitive print "...")
 336                 (return))
 337               (cold-print i))))
 338     (t (sb!sys:%primitive print (hexstr x)))))