src/code/cold-init.lisp

   1 ;;;; cold initialization stuff, plus some other miscellaneous stuff
   2 ;;;; that we don't have any better place for
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!IMPL")
  14 \f
  15 ;;;; burning our ships behind us
  16
  17 ;;; There's a fair amount of machinery which is needed only at cold
  18 ;;; init time, and should be discarded before freezing the final
  19 ;;; system. We discard it by uninterning the associated symbols.
  20 ;;; Rather than using a special table of symbols to be uninterned,
  21 ;;; which might be tedious to maintain, instead we use a hack:
  22 ;;; anything whose name matches a magic character pattern is
  23 ;;; uninterned.
  24 (defun !unintern-init-only-stuff ()
  25   (do ((any-changes? nil nil))
  26       (nil)
  27     (dolist (package (list-all-packages))
  28       (do-symbols (symbol package)
  29         (let ((name (symbol-name symbol)))
  30           (when (or (string= name "!" :end1 1 :end2 1)
  31                     (and (>= (length name) 2)
  32                          (string= name "*!" :end1 2 :end2 2)))
  33             (/show0 "uninterning cold-init-only symbol..")
  34             (/primitive-print name)
  35             (unintern symbol package)
  36             (setf any-changes? t)))))
  37     (unless any-changes?
  38       (return))))
  39 \f
  40 ;;;; !COLD-INIT
  41
  42 ;;; a list of toplevel things set by GENESIS
  43 (defvar *!reversed-cold-toplevels*)
  44
  45 ;;; a SIMPLE-VECTOR set by GENESIS
  46 (defvar *!load-time-values*)
  47
  48 (defun !cold-lose (msg)
  49   (%primitive print msg)
  50   (%primitive print "too early in cold init to recover from errors")
  51   (%halt))
  52
  53 (eval-when (:compile-toplevel :execute)
  54   ;; FIXME: Perhaps we should make SHOW-AND-CALL-AND-FMAKUNBOUND, too,
  55   ;; and use it for most of the cold-init functions. (Just be careful
  56   ;; not to use it for the COLD-INIT-OR-REINIT functions.)
  57   (sb!xc:defmacro show-and-call (name)
  58     `(progn
  59        (/primitive-print ,(symbol-name name))
  60        (,name))))
  61
  62 ;;; called when a cold system starts up
  63 (defun !cold-init ()
  64   #!+sb-doc "Give the world a shove and hope it spins."
  65
  66   (/show0 "entering !COLD-INIT")
  67
  68   ;; FIXME: It'd probably be cleaner to have most of the stuff here
  69   ;; handled by calls like !GC-COLD-INIT, !ERROR-COLD-INIT, and
  70   ;; !UNIX-COLD-INIT. And *TYPE-SYSTEM-INITIALIZED* could be changed to
  71   ;; *TYPE-SYSTEM-INITIALIZED-WHEN-BOUND* so that it doesn't need to
  72   ;; be explicitly set in order to be meaningful.
  73   (setf *gc-notify-stream* nil
  74         *before-gc-hooks* nil
  75         *after-gc-hooks* nil
  76         *already-maybe-gcing* t
  77         *gc-inhibit* t
  78         *need-to-collect-garbage* nil
  79         sb!unix::*interrupts-enabled* t
  80         sb!unix::*interrupt-pending* nil
  81         *break-on-signals* nil
  82         *maximum-error-depth* 10
  83         *current-error-depth* 0
  84         *cold-init-complete-p* nil
  85         *type-system-initialized* nil)
  86
  87   ;; Anyone might call RANDOM to initialize a hash value or something;
  88   ;; and there's nothing which needs to be initialized in order for
  89   ;; this to be initialized, so we initialize it right away.
  90   (show-and-call !random-cold-init)
  91
  92   (show-and-call !package-cold-init)
  93
  94   ;; All sorts of things need INFO and/or (SETF INFO).
  95   (/show0 "about to SHOW-AND-CALL !GLOBALDB-COLD-INIT")
  96   (show-and-call !globaldb-cold-init)
  97
  98   ;; This needs to be done early, but needs to be after INFO is
  99   ;; initialized.
 100   (show-and-call !fdefn-cold-init)
 101
 102   ;; Various toplevel forms call MAKE-ARRAY, which calls SUBTYPEP, so
 103   ;; the basic type machinery needs to be initialized before toplevel
 104   ;; forms run.
 105   (show-and-call !type-class-cold-init)
 106   (show-and-call !typedefs-cold-init)
 107   (show-and-call !classes-cold-init)
 108   (show-and-call !early-type-cold-init)
 109   (show-and-call !late-type-cold-init)
 110   (show-and-call !alien-type-cold-init)
 111   (show-and-call !target-type-cold-init)
 112   (show-and-call !vm-type-cold-init)
 113   ;; FIXME: It would be tidy to make sure that that these cold init
 114   ;; functions are called in the same relative order as the toplevel
 115   ;; forms of the corresponding source files.
 116
 117   ;;(show-and-call !package-cold-init)
 118   (show-and-call !policy-cold-init-or-resanify)
 119   (/show0 "back from !POLICY-COLD-INIT-OR-RESANIFY")
 120
 121   ;; KLUDGE: Why are fixups mixed up with toplevel forms? Couldn't
 122   ;; fixups be done separately? Wouldn't that be clearer and better?
 123   ;; -- WHN 19991204
 124   (/show0 "doing cold toplevel forms and fixups")
 125   (/show0 "(LISTP *!REVERSED-COLD-TOPLEVELS*)=..")
 126   (/hexstr (if (listp *!reversed-cold-toplevels*) "true" "NIL"))
 127   (/show0 "about to calculate (LENGTH *!REVERSED-COLD-TOPLEVELS*)")
 128   (/show0 "(LENGTH *!REVERSED-COLD-TOPLEVELS*)=..")
 129   #!+sb-show (let ((r-c-tl-length (length *!reversed-cold-toplevels*)))
 130                (/show0 "(length calculated..)")
 131                (let ((hexstr (hexstr r-c-tl-length)))
 132                  (/show0 "(hexstr calculated..)")
 133                  (/primitive-print hexstr)))
 134   (let (#!+sb-show (index-in-cold-toplevels 0))
 135     #!+sb-show (declare (type fixnum index-in-cold-toplevels))
 136
 137     (dolist (toplevel-thing (prog1
 138                                 (nreverse *!reversed-cold-toplevels*)
 139                               ;; (Now that we've NREVERSEd it, it's
 140                               ;; somewhat scrambled, so keep anyone
 141                               ;; else from trying to get at it.)
 142                               (makunbound '*!reversed-cold-toplevels*)))
 143       #!+sb-show
 144       (when (zerop (mod index-in-cold-toplevels 1024))
 145         (/show0 "INDEX-IN-COLD-TOPLEVELS=..")
 146         (/hexstr index-in-cold-toplevels))
 147       #!+sb-show
 148       (setf index-in-cold-toplevels
 149             (the fixnum (1+ index-in-cold-toplevels)))
 150       (typecase toplevel-thing
 151         (function
 152          (funcall toplevel-thing))
 153         (cons
 154          (case (first toplevel-thing)
 155            (:load-time-value
 156             (setf (svref *!load-time-values* (third toplevel-thing))
 157                   (funcall (second toplevel-thing))))
 158            (:load-time-value-fixup
 159             #!-gengc
 160             (setf (sap-ref-32 (second toplevel-thing) 0)
 161                   (get-lisp-obj-address
 162                    (svref *!load-time-values* (third toplevel-thing)))))
 163            #!+(and x86 gencgc)
 164            (:load-time-code-fixup
 165             (sb!vm::!do-load-time-code-fixup (second toplevel-thing)
 166                                              (third  toplevel-thing)
 167                                              (fourth toplevel-thing)
 168                                              (fifth  toplevel-thing)))
 169            (t
 170             (!cold-lose "bogus fixup code in *!REVERSED-COLD-TOPLEVELS*"))))
 171         (t (!cold-lose "bogus function in *!REVERSED-COLD-TOPLEVELS*")))))
 172   (/show0 "done with loop over cold toplevel forms and fixups")
 173
 174   ;; Set sane values again, so that the user sees sane values instead
 175   ;; of whatever is left over from the last DECLAIM/PROCLAIM.
 176   (show-and-call !policy-cold-init-or-resanify)
 177
 178   ;; Only do this after toplevel forms have run, 'cause that's where
 179   ;; DEFTYPEs are.
 180   (setf *type-system-initialized* t)
 181
 182   (show-and-call os-cold-init-or-reinit)
 183
 184   (show-and-call stream-cold-init-or-reset)
 185   (show-and-call !loader-cold-init)
 186   (show-and-call signal-cold-init-or-reinit)
 187   (setf (sb!alien:extern-alien "internal_errors_enabled" boolean) t)
 188
 189   ;; FIXME: This list of modes should be defined in one place and
 190   ;; explicitly shared between here and REINIT.
 191   ;;
 192   ;; FIXME: In CMU CL, this is done "here" (i.e. in the analogous
 193   ;; lispinit.lisp code) for every processor architecture. But Daniel
 194   ;; Barlow's Alpha patches suppress it for Alpha. Why the difference?
 195   #!+alpha
 196   (set-floating-point-modes :traps '(:overflow
 197                                      #!-x86 :underflow
 198                                      :invalid
 199                                      :divide-by-zero))
 200
 201   (show-and-call !class-finalize)
 202
 203   ;; The reader and printer are initialized very late, so that they
 204   ;; can do hairy things like invoking the compiler as part of their
 205   ;; initialization.
 206   (show-and-call !reader-cold-init)
 207   (let ((*readtable* *standard-readtable*))
 208     (show-and-call !sharpm-cold-init)
 209     (show-and-call !backq-cold-init))
 210   (setf *readtable* (copy-readtable *standard-readtable*))
 211   (setf sb!debug:*debug-readtable* (copy-readtable *standard-readtable*))
 212   (sb!pretty:!pprint-cold-init)
 213
 214   ;; the ANSI-specified initial value of *PACKAGE*
 215   (setf *package* (find-package "COMMON-LISP-USER"))
 216   ;; FIXME: I'm not sure where it should be done, but CL-USER really
 217   ;; ought to USE-PACKAGE publicly accessible packages like SB-DEBUG
 218   ;; (for ARG and VAR), SB-EXT, SB-EXT-C-CALL, and SB-EXT-ALIEN so
 219   ;; that the user has a hint about which symbols we consider public.
 220   ;; (Perhaps SB-DEBUG wouldn't need to be in the list if ARG and VAR
 221   ;; could be typed directly, with no parentheses, at the debug prompt
 222   ;; the way that e.g. F or BACKTRACE can be?)
 223
 224   (/show0 "done initializing, setting *COLD-INIT-COMPLETE-P*")
 225   (setf *cold-init-complete-p* t)
 226
 227   ;; The system is finally ready for GC.
 228   #!-gengc (setf *already-maybe-gcing* nil)
 229   (/show0 "enabling GC")
 230   (gc-on)
 231   (/show0 "doing first GC")
 232   (gc :full t)
 233   (/show0 "back from first GC")
 234
 235   ;; The show is on.
 236   (terpri)
 237   (/show0 "going into toplevel loop")
 238   (handling-end-of-the-world
 239     (toplevel-init)))
 240
 241 (defun quit (&key recklessly-p
 242                   (unix-code 0 unix-code-p)
 243                   (unix-status unix-code))
 244   #!+sb-doc
 245   "Terminate the current Lisp. Things are cleaned up (with UNWIND-PROTECT
 246   and so forth) unless RECKLESSLY-P is non-NIL. On UNIX-like systems,
 247   UNIX-STATUS is used as the status code."
 248   (declare (type (signed-byte 32) unix-code))
 249   ;; FIXME: UNIX-CODE was deprecated in sbcl-0.6.8, after having been
 250   ;; around for less than a year. It should be safe to remove it after
 251   ;; a year.
 252   (when unix-code-p
 253     (warn "The UNIX-CODE argument is deprecated. Use the UNIX-STATUS argument
 254 instead (which is another name for the same thing)."))
 255   (if recklessly-p
 256       (sb!unix:unix-exit unix-status)
 257       (throw '%end-of-the-world unix-status)))
 258 \f
 259 ;;;; initialization functions
 260
 261 (defun reinit ()
 262   (without-interrupts
 263     (without-gcing
 264       (os-cold-init-or-reinit)
 265       (stream-reinit)
 266       (signal-cold-init-or-reinit)
 267       (gc-reinit)
 268       (setf (sb!alien:extern-alien "internal_errors_enabled" boolean) t)
 269       (set-floating-point-modes :traps
 270                                 '(:overflow
 271                                   :invalid
 272                                   :divide-by-zero
 273                                   ;; PRINT seems not to like x86 NPX
 274                                   ;; denormal floats like
 275                                   ;; LEAST-NEGATIVE-SINGLE-FLOAT, so
 276                                   ;; the :UNDERFLOW exceptions are
 277                                   ;; disabled by default. Joe User can
 278                                   ;; explicitly enable them if
 279                                   ;; desired.
 280                                   #!-x86 :underflow))
 281       ;; Clear pseudo atomic in case this core wasn't compiled with
 282       ;; support.
 283       ;;
 284       ;; FIXME: In SBCL our cores are always compiled with support. So
 285       ;; we don't need to do this, do we? At least not for this
 286       ;; reason.. (Perhaps we should do it anyway in case someone
 287       ;; manages to save an image from within a pseudo-atomic-atomic
 288       ;; operation?)
 289       #!+x86 (setf *pseudo-atomic-atomic* 0))
 290     (gc-on)))
 291 \f
 292 ;;;; some support for any hapless wretches who end up debugging cold
 293 ;;;; init code
 294
 295 ;;; Decode THING into hexadecimal notation using only machinery
 296 ;;; available early in cold init.
 297 #!+sb-show
 298 (defun hexstr (thing)
 299   (/noshow0 "entering HEXSTR")
 300   (let ((addr (sb!kernel:get-lisp-obj-address thing))
 301         (str (make-string 10)))
 302     (/noshow0 "ADDR and STR calculated")
 303     (setf (char str 0) #\0
 304           (char str 1) #\x)
 305     (/noshow0 "CHARs 0 and 1 set")
 306     (dotimes (i 8)
 307       (/noshow0 "at head of DOTIMES loop")
 308       (let* ((nibble (ldb (byte 4 0) addr))
 309              (chr (char "0123456789abcdef" nibble)))
 310         (declare (type (unsigned-byte 4) nibble)
 311                  (base-char chr))
 312         (/noshow0 "NIBBLE and CHR calculated")
 313         (setf (char str (- 9 i)) chr
 314               addr (ash addr -4))))
 315     str))
 316
 317 #!+sb-show
 318 (defun cold-print (x)
 319   (typecase x
 320     (simple-string (sb!sys:%primitive print x))
 321     (symbol (sb!sys:%primitive print (symbol-name x)))
 322     (list (let ((count 0))
 323             (sb!sys:%primitive print "list:")
 324             (dolist (i x)
 325               (when (>= (incf count) 4)
 326                 (sb!sys:%primitive print "...")
 327                 (return))
 328               (cold-print i))))
 329     (t (sb!sys:%primitive print (hexstr x)))))