src/code/cold-init.lisp

   1 ;;;; cold initialization stuff, plus some other miscellaneous stuff
   2 ;;;; that we don't have any better place for
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!IMPL")
  14 \f
  15 ;;;; burning our ships behind us
  16
  17 ;;; There's a fair amount of machinery which is needed only at cold
  18 ;;; init time, and should be discarded before freezing the final
  19 ;;; system. We discard it by uninterning the associated symbols.
  20 ;;; Rather than using a special table of symbols to be uninterned,
  21 ;;; which might be tedious to maintain, instead we use a hack:
  22 ;;; anything whose name matches a magic character pattern is
  23 ;;; uninterned.
  24 ;;;
  25 ;;; FIXME: Are there other tables that need to have entries removed?
  26 ;;; What about symbols of the form DEF!FOO?
  27 (defun !unintern-init-only-stuff ()
  28   (do ((any-changes? nil nil))
  29       (nil)
  30     (dolist (package (list-all-packages))
  31       (do-symbols (symbol package)
  32         (let ((name (symbol-name symbol)))
  33           (when (or (string= name "!" :end1 1 :end2 1)
  34                     (and (>= (length name) 2)
  35                          (string= name "*!" :end1 2 :end2 2)))
  36             (/show0 "uninterning cold-init-only symbol..")
  37             (/primitive-print name)
  38             ;; FIXME: Is this (FIRST (LAST *INFO-ENVIRONMENT*)) really
  39             ;; meant to be an idiom to use?  Is there a more obvious
  40             ;; name for this? [e.g. (GLOBAL-ENVIRONMENT)?]
  41             (do-info ((first (last *info-environment*))
  42                             :name entry :class class :type type)
  43               (when (eq entry symbol)
  44                 (clear-info class type entry)))
  45             (unintern symbol package)
  46             (setf any-changes? t)))))
  47     (unless any-changes?
  48       (return))))
  49 \f
  50 ;;;; putting ourselves out of our misery when things become too much to bear
  51
  52 (declaim (ftype (function (simple-string) nil) !cold-lose))
  53 (defun !cold-lose (msg)
  54   (%primitive print msg)
  55   (%primitive print "too early in cold init to recover from errors")
  56   (%halt))
  57
  58 ;;; last-ditch error reporting for things which should never happen
  59 ;;; and which, if they do happen, are sufficiently likely to torpedo
  60 ;;; the normal error-handling system that we want to bypass it
  61 (declaim (ftype (function (simple-string) nil) critically-unreachable))
  62 (defun critically-unreachable (where)
  63   (%primitive print "internal error: Control should never reach here, i.e.")
  64   (%primitive print where)
  65   (%halt))
  66 \f
  67 ;;;; !COLD-INIT
  68
  69 ;;; a list of toplevel things set by GENESIS
  70 (defvar *!reversed-cold-toplevels*)
  71
  72 ;;; a SIMPLE-VECTOR set by GENESIS
  73 (defvar *!load-time-values*)
  74
  75 (eval-when (:compile-toplevel :execute)
  76   ;; FIXME: Perhaps we should make SHOW-AND-CALL-AND-FMAKUNBOUND, too,
  77   ;; and use it for most of the cold-init functions. (Just be careful
  78   ;; not to use it for the COLD-INIT-OR-REINIT functions.)
  79   (sb!xc:defmacro show-and-call (name)
  80     `(progn
  81        (/primitive-print ,(symbol-name name))
  82        (,name))))
  83
  84 ;;; called when a cold system starts up
  85 (defun !cold-init ()
  86   #!+sb-doc "Give the world a shove and hope it spins."
  87
  88   (/show0 "entering !COLD-INIT")
  89
  90   ;; FIXME: It'd probably be cleaner to have most of the stuff here
  91   ;; handled by calls like !GC-COLD-INIT, !ERROR-COLD-INIT, and
  92   ;; !UNIX-COLD-INIT. And *TYPE-SYSTEM-INITIALIZED* could be changed to
  93   ;; *TYPE-SYSTEM-INITIALIZED-WHEN-BOUND* so that it doesn't need to
  94   ;; be explicitly set in order to be meaningful.
  95   (setf *after-gc-hooks* nil
  96         *gc-inhibit* t
  97         *gc-pending* nil
  98         #!+sb-thread *stop-for-gc-pending* #!+sb-thread nil
  99         *interrupts-enabled* t
 100         *interrupt-pending* nil
 101         *break-on-signals* nil
 102         *maximum-error-depth* 10
 103         *current-error-depth* 0
 104         *cold-init-complete-p* nil
 105         *type-system-initialized* nil
 106         sb!vm:*alloc-signal* nil)
 107
 108   ;; I'm not sure where eval is first called, so I put this first.
 109   #!+sb-eval
 110   (show-and-call sb!eval::!full-eval-cold-init)
 111
 112   (show-and-call thread-init-or-reinit)
 113   (show-and-call !typecheckfuns-cold-init)
 114
 115   ;; Anyone might call RANDOM to initialize a hash value or something;
 116   ;; and there's nothing which needs to be initialized in order for
 117   ;; this to be initialized, so we initialize it right away.
 118   (show-and-call !random-cold-init)
 119
 120   ;; Must be done before any non-opencoded array references are made.
 121   (show-and-call !hairy-data-vector-reffer-init)
 122
 123   (show-and-call !character-database-cold-init)
 124   (show-and-call !character-name-database-cold-init)
 125
 126   (show-and-call !early-package-cold-init)
 127   (show-and-call !package-cold-init)
 128
 129   ;; All sorts of things need INFO and/or (SETF INFO).
 130   (/show0 "about to SHOW-AND-CALL !GLOBALDB-COLD-INIT")
 131   (show-and-call !globaldb-cold-init)
 132
 133   ;; This needs to be done early, but needs to be after INFO is
 134   ;; initialized.
 135   (show-and-call !function-names-cold-init)
 136   (show-and-call !fdefn-cold-init)
 137
 138   ;; Various toplevel forms call MAKE-ARRAY, which calls SUBTYPEP, so
 139   ;; the basic type machinery needs to be initialized before toplevel
 140   ;; forms run.
 141   (show-and-call !type-class-cold-init)
 142   (show-and-call !typedefs-cold-init)
 143   (show-and-call !classes-cold-init)
 144   (show-and-call !early-type-cold-init)
 145   (show-and-call !late-type-cold-init)
 146   (show-and-call !alien-type-cold-init)
 147   (show-and-call !target-type-cold-init)
 148   (show-and-call !vm-type-cold-init)
 149   ;; FIXME: It would be tidy to make sure that that these cold init
 150   ;; functions are called in the same relative order as the toplevel
 151   ;; forms of the corresponding source files.
 152
 153   ;;(show-and-call !package-cold-init)
 154   (show-and-call !policy-cold-init-or-resanify)
 155   (/show0 "back from !POLICY-COLD-INIT-OR-RESANIFY")
 156
 157   (show-and-call !constantp-cold-init)
 158   (show-and-call !early-proclaim-cold-init)
 159
 160   ;; KLUDGE: Why are fixups mixed up with toplevel forms? Couldn't
 161   ;; fixups be done separately? Wouldn't that be clearer and better?
 162   ;; -- WHN 19991204
 163   (/show0 "doing cold toplevel forms and fixups")
 164   (/show0 "(LISTP *!REVERSED-COLD-TOPLEVELS*)=..")
 165   (/hexstr (if (listp *!reversed-cold-toplevels*) "true" "NIL"))
 166   (/show0 "about to calculate (LENGTH *!REVERSED-COLD-TOPLEVELS*)")
 167   (/show0 "(LENGTH *!REVERSED-COLD-TOPLEVELS*)=..")
 168   #!+sb-show (let ((r-c-tl-length (length *!reversed-cold-toplevels*)))
 169                (/show0 "(length calculated..)")
 170                (let ((hexstr (hexstr r-c-tl-length)))
 171                  (/show0 "(hexstr calculated..)")
 172                  (/primitive-print hexstr)))
 173   (let (#!+sb-show (index-in-cold-toplevels 0))
 174     #!+sb-show (declare (type fixnum index-in-cold-toplevels))
 175
 176     (dolist (toplevel-thing (prog1
 177                                 (nreverse *!reversed-cold-toplevels*)
 178                               ;; (Now that we've NREVERSEd it, it's
 179                               ;; somewhat scrambled, so keep anyone
 180                               ;; else from trying to get at it.)
 181                               (makunbound '*!reversed-cold-toplevels*)))
 182       #!+sb-show
 183       (when (zerop (mod index-in-cold-toplevels 1024))
 184         (/show0 "INDEX-IN-COLD-TOPLEVELS=..")
 185         (/hexstr index-in-cold-toplevels))
 186       #!+sb-show
 187       (setf index-in-cold-toplevels
 188             (the fixnum (1+ index-in-cold-toplevels)))
 189       (typecase toplevel-thing
 190         (function
 191          (funcall toplevel-thing))
 192         (cons
 193          (case (first toplevel-thing)
 194            (:load-time-value
 195             (setf (svref *!load-time-values* (third toplevel-thing))
 196                   (funcall (second toplevel-thing))))
 197            (:load-time-value-fixup
 198             (setf (sap-ref-word (second toplevel-thing) 0)
 199                   (get-lisp-obj-address
 200                    (svref *!load-time-values* (third toplevel-thing)))))
 201            #!+(and (or x86 x86-64) gencgc)
 202            (:load-time-code-fixup
 203             (sb!vm::!envector-load-time-code-fixup (second toplevel-thing)
 204                                                    (third  toplevel-thing)
 205                                                    (fourth toplevel-thing)
 206                                                    (fifth  toplevel-thing)))
 207            (t
 208             (!cold-lose "bogus fixup code in *!REVERSED-COLD-TOPLEVELS*"))))
 209         (t (!cold-lose "bogus function in *!REVERSED-COLD-TOPLEVELS*")))))
 210   (/show0 "done with loop over cold toplevel forms and fixups")
 211
 212   ;; Set sane values again, so that the user sees sane values instead
 213   ;; of whatever is left over from the last DECLAIM/PROCLAIM.
 214   (show-and-call !policy-cold-init-or-resanify)
 215
 216   ;; Only do this after toplevel forms have run, 'cause that's where
 217   ;; DEFTYPEs are.
 218   (setf *type-system-initialized* t)
 219
 220   ;; now that the type system is definitely initialized, fixup UNKNOWN
 221   ;; types that have crept in.
 222   (show-and-call !fixup-type-cold-init)
 223   ;; run the PROCLAIMs.
 224   (show-and-call !late-proclaim-cold-init)
 225
 226   (show-and-call os-cold-init-or-reinit)
 227
 228   (show-and-call stream-cold-init-or-reset)
 229   (show-and-call !loader-cold-init)
 230   (show-and-call !foreign-cold-init)
 231   #!-win32 (show-and-call signal-cold-init-or-reinit)
 232   (/show0 "enabling internal errors")
 233   (setf (sb!alien:extern-alien "internal_errors_enabled" boolean) t)
 234
 235   (show-and-call float-cold-init-or-reinit)
 236
 237   (show-and-call !class-finalize)
 238
 239   ;; The reader and printer are initialized very late, so that they
 240   ;; can do hairy things like invoking the compiler as part of their
 241   ;; initialization.
 242   (show-and-call !reader-cold-init)
 243   (let ((*readtable* *standard-readtable*))
 244     (show-and-call !sharpm-cold-init)
 245     (show-and-call !backq-cold-init))
 246   (setf *readtable* (copy-readtable *standard-readtable*))
 247   (setf sb!debug:*debug-readtable* (copy-readtable *standard-readtable*))
 248   (sb!pretty:!pprint-cold-init)
 249
 250   ;; the ANSI-specified initial value of *PACKAGE*
 251   (setf *package* (find-package "COMMON-LISP-USER"))
 252
 253   (/show0 "done initializing, setting *COLD-INIT-COMPLETE-P*")
 254   (setf *cold-init-complete-p* t)
 255
 256   ;; The system is finally ready for GC.
 257   (/show0 "enabling GC")
 258   (gc-on)
 259   (/show0 "doing first GC")
 260   (gc :full t)
 261   (/show0 "back from first GC")
 262
 263   ;; The show is on.
 264   (terpri)
 265   (/show0 "going into toplevel loop")
 266   (handling-end-of-the-world
 267     (toplevel-init)
 268     (critically-unreachable "after TOPLEVEL-INIT")))
 269
 270 (defun quit (&key recklessly-p (unix-status 0))
 271   #!+sb-doc
 272   "Terminate the current Lisp. Things are cleaned up (with
 273 UNWIND-PROTECT and so forth) unless RECKLESSLY-P is non-NIL. On
 274 UNIX-like systems, UNIX-STATUS is used as the status code."
 275   (declare (type (signed-byte 32) unix-status))
 276   (/show0 "entering QUIT")
 277   (if recklessly-p
 278       (sb!unix:unix-exit unix-status)
 279       (throw '%end-of-the-world unix-status))
 280   (critically-unreachable "after trying to die in QUIT"))
 281 \f
 282 ;;;; initialization functions
 283
 284 (defun thread-init-or-reinit ()
 285   (sb!thread::init-initial-thread)
 286   (sb!thread::init-job-control)
 287   (sb!thread::get-foreground))
 288
 289 (defun reinit ()
 290   (setf *default-external-format* nil)
 291   (setf sb!alien::*default-c-string-external-format* nil)
 292   (without-interrupts
 293     (without-gcing
 294         (os-cold-init-or-reinit)
 295       (thread-init-or-reinit)
 296       (stream-reinit)
 297       #!-win32
 298       (signal-cold-init-or-reinit)
 299       (setf (sb!alien:extern-alien "internal_errors_enabled" boolean) t)
 300       (float-cold-init-or-reinit)))
 301   (gc-reinit)
 302   (foreign-reinit)
 303   (time-reinit)
 304   ;; If the debugger was disabled in the saved core, we need to
 305   ;; re-disable ldb again.
 306   (when (eq *invoke-debugger-hook* 'sb!debug::debugger-disabled-hook)
 307     (sb!debug::disable-debugger))
 308   (dolist (hook *init-hooks*)
 309     (with-simple-restart (continue "Skip this initialization hook.")
 310       (funcall hook))))
 311 \f
 312 ;;;; some support for any hapless wretches who end up debugging cold
 313 ;;;; init code
 314
 315 ;;; Decode THING into hexadecimal notation using only machinery
 316 ;;; available early in cold init.
 317 #!+sb-show
 318 (defun hexstr (thing)
 319   (/noshow0 "entering HEXSTR")
 320   (let ((addr (get-lisp-obj-address thing))
 321         (str (make-string 10 :element-type 'base-char)))
 322     (/noshow0 "ADDR and STR calculated")
 323     (setf (char str 0) #\0
 324           (char str 1) #\x)
 325     (/noshow0 "CHARs 0 and 1 set")
 326     (dotimes (i 8)
 327       (/noshow0 "at head of DOTIMES loop")
 328       (let* ((nibble (ldb (byte 4 0) addr))
 329              (chr (char "0123456789abcdef" nibble)))
 330         (declare (type (unsigned-byte 4) nibble)
 331                  (base-char chr))
 332         (/noshow0 "NIBBLE and CHR calculated")
 333         (setf (char str (- 9 i)) chr
 334               addr (ash addr -4))))
 335     str))
 336
 337 #!+sb-show
 338 (defun cold-print (x)
 339   (typecase x
 340     (simple-string (sb!sys:%primitive print x))
 341     (symbol (sb!sys:%primitive print (symbol-name x)))
 342     (list (let ((count 0))
 343             (sb!sys:%primitive print "list:")
 344             (dolist (i x)
 345               (when (>= (incf count) 4)
 346                 (sb!sys:%primitive print "...")
 347                 (return))
 348               (cold-print i))))
 349     (t (sb!sys:%primitive print (hexstr x)))))