src/code/cold-init.lisp

   1 ;;;; cold initialization stuff, plus some other miscellaneous stuff
   2 ;;;; that we don't have any better place for
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!IMPL")
  14 \f
  15 ;;;; burning our ships behind us
  16
  17 ;;; There's a fair amount of machinery which is needed only at cold
  18 ;;; init time, and should be discarded before freezing the final
  19 ;;; system. We discard it by uninterning the associated symbols.
  20 ;;; Rather than using a special table of symbols to be uninterned,
  21 ;;; which might be tedious to maintain, instead we use a hack:
  22 ;;; anything whose name matches a magic character pattern is
  23 ;;; uninterned.
  24 ;;;
  25 ;;; FIXME: Are there other tables that need to have entries removed?
  26 ;;; What about symbols of the form DEF!FOO?
  27 (defun !unintern-init-only-stuff ()
  28   (do ((any-changes? nil nil))
  29       (nil)
  30     (dolist (package (list-all-packages))
  31       (do-symbols (symbol package)
  32         (let ((name (symbol-name symbol)))
  33           (when (or (string= name "!" :end1 1 :end2 1)
  34                     (and (>= (length name) 2)
  35                          (string= name "*!" :end1 2 :end2 2)))
  36             (/show0 "uninterning cold-init-only symbol..")
  37             (/primitive-print name)
  38             ;; FIXME: Is this (FIRST (LAST *INFO-ENVIRONMENT*)) really
  39             ;; meant to be an idiom to use?  Is there a more obvious
  40             ;; name for this? [e.g. (GLOBAL-ENVIRONMENT)?]
  41             (do-info ((first (last *info-environment*))
  42                             :name entry :class class :type type)
  43               (when (eq entry symbol)
  44                 (clear-info class type entry)))
  45             (unintern symbol package)
  46             (setf any-changes? t)))))
  47     (unless any-changes?
  48       (return))))
  49 \f
  50 ;;;; putting ourselves out of our misery when things become too much to bear
  51
  52 (declaim (ftype (function (simple-string) nil) !cold-lose))
  53 (defun !cold-lose (msg)
  54   (%primitive print msg)
  55   (%primitive print "too early in cold init to recover from errors")
  56   (%halt))
  57
  58 ;;; last-ditch error reporting for things which should never happen
  59 ;;; and which, if they do happen, are sufficiently likely to torpedo
  60 ;;; the normal error-handling system that we want to bypass it
  61 (declaim (ftype (function (simple-string) nil) critically-unreachable))
  62 (defun critically-unreachable (where)
  63   (%primitive print "internal error: Control should never reach here, i.e.")
  64   (%primitive print where)
  65   (%halt))
  66 \f
  67 ;;;; !COLD-INIT
  68
  69 ;;; a list of toplevel things set by GENESIS
  70 (defvar *!reversed-cold-toplevels*)
  71
  72 ;;; a SIMPLE-VECTOR set by GENESIS
  73 (defvar *!load-time-values*)
  74
  75 (eval-when (:compile-toplevel :execute)
  76   ;; FIXME: Perhaps we should make SHOW-AND-CALL-AND-FMAKUNBOUND, too,
  77   ;; and use it for most of the cold-init functions. (Just be careful
  78   ;; not to use it for the COLD-INIT-OR-REINIT functions.)
  79   (sb!xc:defmacro show-and-call (name)
  80     `(progn
  81        (/primitive-print ,(symbol-name name))
  82        (,name))))
  83
  84 ;;; called when a cold system starts up
  85 (defun !cold-init ()
  86   #!+sb-doc "Give the world a shove and hope it spins."
  87
  88   (/show0 "entering !COLD-INIT")
  89
  90   ;; FIXME: It'd probably be cleaner to have most of the stuff here
  91   ;; handled by calls like !GC-COLD-INIT, !ERROR-COLD-INIT, and
  92   ;; !UNIX-COLD-INIT. And *TYPE-SYSTEM-INITIALIZED* could be changed to
  93   ;; *TYPE-SYSTEM-INITIALIZED-WHEN-BOUND* so that it doesn't need to
  94   ;; be explicitly set in order to be meaningful.
  95   (setf *after-gc-hooks* nil
  96         *gc-inhibit* 1
  97         *need-to-collect-garbage* nil
  98         sb!unix::*interrupts-enabled* t
  99         sb!unix::*interrupt-pending* nil
 100         *break-on-signals* nil
 101         *maximum-error-depth* 10
 102         *current-error-depth* 0
 103         *cold-init-complete-p* nil
 104         *type-system-initialized* nil)
 105
 106   (show-and-call !typecheckfuns-cold-init)
 107
 108   ;; Anyone might call RANDOM to initialize a hash value or something;
 109   ;; and there's nothing which needs to be initialized in order for
 110   ;; this to be initialized, so we initialize it right away.
 111   (show-and-call !random-cold-init)
 112
 113   (show-and-call !character-database-cold-init)
 114
 115   (show-and-call !early-package-cold-init)
 116   (show-and-call !package-cold-init)
 117
 118   ;; All sorts of things need INFO and/or (SETF INFO).
 119   (/show0 "about to SHOW-AND-CALL !GLOBALDB-COLD-INIT")
 120   (show-and-call !globaldb-cold-init)
 121
 122   ;; This needs to be done early, but needs to be after INFO is
 123   ;; initialized.
 124   (show-and-call !function-names-cold-init)
 125   (show-and-call !fdefn-cold-init)
 126
 127   ;; Various toplevel forms call MAKE-ARRAY, which calls SUBTYPEP, so
 128   ;; the basic type machinery needs to be initialized before toplevel
 129   ;; forms run.
 130   (show-and-call !type-class-cold-init)
 131   (show-and-call !typedefs-cold-init)
 132   (show-and-call !classes-cold-init)
 133   (show-and-call !early-type-cold-init)
 134   (show-and-call !late-type-cold-init)
 135   (show-and-call !alien-type-cold-init)
 136   (show-and-call !target-type-cold-init)
 137   (show-and-call !vm-type-cold-init)
 138   ;; FIXME: It would be tidy to make sure that that these cold init
 139   ;; functions are called in the same relative order as the toplevel
 140   ;; forms of the corresponding source files.
 141
 142   ;;(show-and-call !package-cold-init)
 143   (show-and-call !policy-cold-init-or-resanify)
 144   (/show0 "back from !POLICY-COLD-INIT-OR-RESANIFY")
 145
 146   (show-and-call !early-proclaim-cold-init)
 147
 148   ;; KLUDGE: Why are fixups mixed up with toplevel forms? Couldn't
 149   ;; fixups be done separately? Wouldn't that be clearer and better?
 150   ;; -- WHN 19991204
 151   (/show0 "doing cold toplevel forms and fixups")
 152   (/show0 "(LISTP *!REVERSED-COLD-TOPLEVELS*)=..")
 153   (/hexstr (if (listp *!reversed-cold-toplevels*) "true" "NIL"))
 154   (/show0 "about to calculate (LENGTH *!REVERSED-COLD-TOPLEVELS*)")
 155   (/show0 "(LENGTH *!REVERSED-COLD-TOPLEVELS*)=..")
 156   #!+sb-show (let ((r-c-tl-length (length *!reversed-cold-toplevels*)))
 157                (/show0 "(length calculated..)")
 158                (let ((hexstr (hexstr r-c-tl-length)))
 159                  (/show0 "(hexstr calculated..)")
 160                  (/primitive-print hexstr)))
 161   (let (#!+sb-show (index-in-cold-toplevels 0))
 162     #!+sb-show (declare (type fixnum index-in-cold-toplevels))
 163
 164     (dolist (toplevel-thing (prog1
 165                                 (nreverse *!reversed-cold-toplevels*)
 166                               ;; (Now that we've NREVERSEd it, it's
 167                               ;; somewhat scrambled, so keep anyone
 168                               ;; else from trying to get at it.)
 169                               (makunbound '*!reversed-cold-toplevels*)))
 170       #!+sb-show
 171       (when (zerop (mod index-in-cold-toplevels 1024))
 172         (/show0 "INDEX-IN-COLD-TOPLEVELS=..")
 173         (/hexstr index-in-cold-toplevels))
 174       #!+sb-show
 175       (setf index-in-cold-toplevels
 176             (the fixnum (1+ index-in-cold-toplevels)))
 177       (typecase toplevel-thing
 178         (function
 179          (funcall toplevel-thing))
 180         (cons
 181          (case (first toplevel-thing)
 182            (:load-time-value
 183             (setf (svref *!load-time-values* (third toplevel-thing))
 184                   (funcall (second toplevel-thing))))
 185            (:load-time-value-fixup
 186             (setf (sap-ref-word (second toplevel-thing) 0)
 187                   (get-lisp-obj-address
 188                    (svref *!load-time-values* (third toplevel-thing)))))
 189            #!+(and (or x86 x86-64) gencgc)
 190            (:load-time-code-fixup
 191             (sb!vm::!envector-load-time-code-fixup (second toplevel-thing)
 192                                                    (third  toplevel-thing)
 193                                                    (fourth toplevel-thing)
 194                                                    (fifth  toplevel-thing)))
 195            (t
 196             (!cold-lose "bogus fixup code in *!REVERSED-COLD-TOPLEVELS*"))))
 197         (t (!cold-lose "bogus function in *!REVERSED-COLD-TOPLEVELS*")))))
 198   (/show0 "done with loop over cold toplevel forms and fixups")
 199
 200   ;; Set sane values again, so that the user sees sane values instead
 201   ;; of whatever is left over from the last DECLAIM/PROCLAIM.
 202   (show-and-call !policy-cold-init-or-resanify)
 203
 204   ;; Only do this after toplevel forms have run, 'cause that's where
 205   ;; DEFTYPEs are.
 206   (setf *type-system-initialized* t)
 207
 208   ;; now that the type system is definitely initialized, fixup UNKNOWN
 209   ;; types that have crept in.
 210   (show-and-call !fixup-type-cold-init)
 211   ;; run the PROCLAIMs.
 212   (show-and-call !late-proclaim-cold-init)
 213
 214   (show-and-call os-cold-init-or-reinit)
 215
 216   (show-and-call stream-cold-init-or-reset)
 217   (show-and-call !loader-cold-init)
 218   (show-and-call !foreign-cold-init)
 219   (show-and-call signal-cold-init-or-reinit)
 220   (/show0 "enabling internal errors")
 221   (setf (sb!alien:extern-alien "internal_errors_enabled" boolean) t)
 222
 223   ;; FIXME: This list of modes should be defined in one place and
 224   ;; explicitly shared between here and REINIT.
 225
 226   ;; FIXME: For some unknown reason, NetBSD/x86 won't run with the
 227   ;; :invalid trap enabled. That should be fixed, but not today...
 228   ;; PEM -- April 5, 2004
 229   (set-floating-point-modes
 230    :traps '(:overflow #!-netbsd :invalid :divide-by-zero))
 231
 232   (show-and-call !class-finalize)
 233
 234   ;; The reader and printer are initialized very late, so that they
 235   ;; can do hairy things like invoking the compiler as part of their
 236   ;; initialization.
 237   (show-and-call !reader-cold-init)
 238   (let ((*readtable* *standard-readtable*))
 239     (show-and-call !sharpm-cold-init)
 240     (show-and-call !backq-cold-init))
 241   (setf *readtable* (copy-readtable *standard-readtable*))
 242   (setf sb!debug:*debug-readtable* (copy-readtable *standard-readtable*))
 243   (sb!pretty:!pprint-cold-init)
 244
 245   ;; the ANSI-specified initial value of *PACKAGE*
 246   (setf *package* (find-package "COMMON-LISP-USER"))
 247
 248   (/show0 "done initializing, setting *COLD-INIT-COMPLETE-P*")
 249   (setf *cold-init-complete-p* t)
 250
 251   ;; The system is finally ready for GC.
 252   (/show0 "enabling GC")
 253   (gc-on)
 254   (/show0 "doing first GC")
 255   (gc :full t)
 256   (/show0 "back from first GC")
 257
 258   ;; The show is on.
 259   (terpri)
 260   (/show0 "going into toplevel loop")
 261   (handling-end-of-the-world
 262     (thread-init-or-reinit)
 263     (toplevel-init)
 264     (critically-unreachable "after TOPLEVEL-INIT")))
 265
 266 (defun quit (&key recklessly-p (unix-status 0))
 267   #!+sb-doc
 268   "Terminate the current Lisp. Things are cleaned up (with
 269 UNWIND-PROTECT and so forth) unless RECKLESSLY-P is non-NIL. On
 270 UNIX-like systems, UNIX-STATUS is used as the status code."
 271   (declare (type (signed-byte 32) unix-status))
 272   (/show0 "entering QUIT")
 273   (if recklessly-p
 274       (sb!unix:unix-exit unix-status)
 275       (throw '%end-of-the-world unix-status))
 276   (critically-unreachable "after trying to die in QUIT"))
 277 \f
 278 ;;;; initialization functions
 279
 280 (defun thread-init-or-reinit ()
 281   (sb!thread::init-job-control)
 282   (sb!thread::get-foreground))
 283
 284 (defun reinit ()
 285   (without-interrupts
 286     (without-gcing
 287         (os-cold-init-or-reinit)
 288       (stream-reinit)
 289       (signal-cold-init-or-reinit)
 290       (setf (sb!alien:extern-alien "internal_errors_enabled" boolean) t)
 291       ;; PRINT seems not to like x86 NPX denormal floats like
 292       ;; LEAST-NEGATIVE-SINGLE-FLOAT, so the :UNDERFLOW exceptions are
 293       ;; disabled by default. Joe User can explicitly enable them if
 294       ;; desired.
 295       ;;
 296       ;; see also comment at the previous SET-FLOATING-POINT-MODES
 297       ;; call site.
 298       (set-floating-point-modes
 299        :traps '(:overflow #!-netbsd :invalid :divide-by-zero))))
 300   (thread-init-or-reinit)
 301   (gc-reinit)
 302   ;; make sure TIME works correctly from saved cores
 303   (setf *internal-real-time-base-seconds* nil)
 304   (foreign-reinit)
 305   (dolist (hook *init-hooks*)
 306     (with-simple-restart (continue "Skip this initialization hook.")
 307       (funcall hook))))
 308 \f
 309 ;;;; some support for any hapless wretches who end up debugging cold
 310 ;;;; init code
 311
 312 ;;; Decode THING into hexadecimal notation using only machinery
 313 ;;; available early in cold init.
 314 #!+sb-show
 315 (defun hexstr (thing)
 316   (/noshow0 "entering HEXSTR")
 317   (let ((addr (get-lisp-obj-address thing))
 318         (str (make-string 10 :element-type 'base-char)))
 319     (/noshow0 "ADDR and STR calculated")
 320     (setf (char str 0) #\0
 321           (char str 1) #\x)
 322     (/noshow0 "CHARs 0 and 1 set")
 323     (dotimes (i 8)
 324       (/noshow0 "at head of DOTIMES loop")
 325       (let* ((nibble (ldb (byte 4 0) addr))
 326              (chr (char "0123456789abcdef" nibble)))
 327         (declare (type (unsigned-byte 4) nibble)
 328                  (base-char chr))
 329         (/noshow0 "NIBBLE and CHR calculated")
 330         (setf (char str (- 9 i)) chr
 331               addr (ash addr -4))))
 332     str))
 333
 334 #!+sb-show
 335 (defun cold-print (x)
 336   (typecase x
 337     (simple-string (sb!sys:%primitive print x))
 338     (symbol (sb!sys:%primitive print (symbol-name x)))
 339     (list (let ((count 0))
 340             (sb!sys:%primitive print "list:")
 341             (dolist (i x)
 342               (when (>= (incf count) 4)
 343                 (sb!sys:%primitive print "...")
 344                 (return))
 345               (cold-print i))))
 346     (t (sb!sys:%primitive print (hexstr x)))))