src/code/cold-init.lisp

   1 ;;;; cold initialization stuff, plus some other miscellaneous stuff
   2 ;;;; that we don't have any better place for
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!IMPL")
  14 \f
  15 ;;;; burning our ships behind us
  16
  17 ;;; There's a fair amount of machinery which is needed only at cold
  18 ;;; init time, and should be discarded before freezing the final
  19 ;;; system. We discard it by uninterning the associated symbols.
  20 ;;; Rather than using a special table of symbols to be uninterned,
  21 ;;; which might be tedious to maintain, instead we use a hack:
  22 ;;; anything whose name matches a magic character pattern is
  23 ;;; uninterned.
  24 (defun !unintern-init-only-stuff ()
  25   (do ((any-changes? nil nil))
  26       (nil)
  27     (dolist (package (list-all-packages))
  28       (do-symbols (symbol package)
  29         (let ((name (symbol-name symbol)))
  30           (when (or (string= name "!" :end1 1 :end2 1)
  31                     (and (>= (length name) 2)
  32                          (string= name "*!" :end1 2 :end2 2)))
  33             (/show0 "uninterning cold-init-only symbol..")
  34             (/primitive-print name)
  35             (unintern symbol package)
  36             (setf any-changes? t)))))
  37     (unless any-changes?
  38       (return))))
  39 \f
  40 ;;;; !COLD-INIT
  41
  42 ;;; a list of toplevel things set by GENESIS
  43 (defvar *!reversed-cold-toplevels*)
  44
  45 ;;; a SIMPLE-VECTOR set by GENESIS
  46 (defvar *!load-time-values*)
  47
  48 (defun !cold-lose (msg)
  49   (%primitive print msg)
  50   (%primitive print "too early in cold init to recover from errors")
  51   (%halt))
  52
  53 (eval-when (:compile-toplevel :execute)
  54   ;; FIXME: Perhaps we should make SHOW-AND-CALL-AND-FMAKUNBOUND, too,
  55   ;; and use it for most of the cold-init functions. (Just be careful
  56   ;; not to use it for the COLD-INIT-OR-REINIT functions.)
  57   (sb!xc:defmacro show-and-call (name)
  58     `(progn
  59        (/primitive-print ,(symbol-name name))
  60        (,name))))
  61
  62 ;;; called when a cold system starts up
  63 (defun !cold-init ()
  64   #!+sb-doc "Give the world a shove and hope it spins."
  65
  66   (/show0 "entering !COLD-INIT")
  67
  68   ;; FIXME: It'd probably be cleaner to have most of the stuff here
  69   ;; handled by calls like !GC-COLD-INIT, !ERROR-COLD-INIT, and
  70   ;; !UNIX-COLD-INIT. And *TYPE-SYSTEM-INITIALIZED* could be changed to
  71   ;; *TYPE-SYSTEM-INITIALIZED-WHEN-BOUND* so that it doesn't need to
  72   ;; be explicitly set in order to be meaningful.
  73   (setf *gc-notify-stream* nil
  74         *before-gc-hooks* nil
  75         *after-gc-hooks* nil
  76         *already-maybe-gcing* t
  77         *gc-inhibit* t
  78         *need-to-collect-garbage* nil
  79         sb!unix::*interrupts-enabled* t
  80         sb!unix::*interrupt-pending* nil
  81         *break-on-signals* nil
  82         *maximum-error-depth* 10
  83         *current-error-depth* 0
  84         *cold-init-complete-p* nil
  85         *type-system-initialized* nil)
  86
  87   ;; Anyone might call RANDOM to initialize a hash value or something;
  88   ;; and there's nothing which needs to be initialized in order for
  89   ;; this to be initialized, so we initialize it right away.
  90   (show-and-call !random-cold-init)
  91
  92   (show-and-call !package-cold-init)
  93
  94   ;; All sorts of things need INFO and/or (SETF INFO).
  95   (/show0 "about to SHOW-AND-CALL !GLOBALDB-COLD-INIT")
  96   (show-and-call !globaldb-cold-init)
  97
  98   ;; This needs to be done early, but needs to be after INFO is
  99   ;; initialized.
 100   (show-and-call !fdefn-cold-init)
 101
 102   ;; Various toplevel forms call MAKE-ARRAY, which calls SUBTYPEP, so
 103   ;; the basic type machinery needs to be initialized before toplevel
 104   ;; forms run.
 105   (show-and-call !type-class-cold-init)
 106   (show-and-call !typedefs-cold-init)
 107   (show-and-call !classes-cold-init)
 108   (show-and-call !early-type-cold-init)
 109   (show-and-call !late-type-cold-init)
 110   (show-and-call !alien-type-cold-init)
 111   (show-and-call !target-type-cold-init)
 112   (show-and-call !vm-type-cold-init)
 113   ;; FIXME: It would be tidy to make sure that that these cold init
 114   ;; functions are called in the same relative order as the toplevel
 115   ;; forms of the corresponding source files.
 116
 117   ;;(show-and-call !package-cold-init)
 118   (show-and-call !policy-cold-init-or-resanify)
 119   (/show0 "back from !POLICY-COLD-INIT-OR-RESANIFY")
 120
 121   ;; KLUDGE: Why are fixups mixed up with toplevel forms? Couldn't
 122   ;; fixups be done separately? Wouldn't that be clearer and better?
 123   ;; -- WHN 19991204
 124   (/show0 "doing cold toplevel forms and fixups")
 125   (/show0 "(LISTP *!REVERSED-COLD-TOPLEVELS*)=..")
 126   (/hexstr (if (listp *!reversed-cold-toplevels*) "true" "NIL"))
 127   (/show0 "about to calculate (LENGTH *!REVERSED-COLD-TOPLEVELS*)")
 128   (/show0 "(LENGTH *!REVERSED-COLD-TOPLEVELS*)=..")
 129   #!+sb-show (let ((r-c-tl-length (length *!reversed-cold-toplevels*)))
 130                (/show0 "(length calculated..)")
 131                (let ((hexstr (hexstr r-c-tl-length)))
 132                  (/show0 "(hexstr calculated..)")
 133                  (/primitive-print hexstr)))
 134   (let (#!+sb-show (index-in-cold-toplevels 0))
 135     #!+sb-show (declare (type fixnum index-in-cold-toplevels))
 136
 137     (dolist (toplevel-thing (prog1
 138                                 (nreverse *!reversed-cold-toplevels*)
 139                               ;; (Now that we've NREVERSEd it, it's
 140                               ;; somewhat scrambled, so keep anyone
 141                               ;; else from trying to get at it.)
 142                               (makunbound '*!reversed-cold-toplevels*)))
 143       #!+sb-show
 144       (when (zerop (mod index-in-cold-toplevels 1024))
 145         (/show0 "INDEX-IN-COLD-TOPLEVELS=..")
 146         (/hexstr index-in-cold-toplevels))
 147       #!+sb-show
 148       (setf index-in-cold-toplevels
 149             (the fixnum (1+ index-in-cold-toplevels)))
 150       (typecase toplevel-thing
 151         (function
 152          (funcall toplevel-thing))
 153         (cons
 154          (case (first toplevel-thing)
 155            (:load-time-value
 156             (setf (svref *!load-time-values* (third toplevel-thing))
 157                   (funcall (second toplevel-thing))))
 158            (:load-time-value-fixup
 159             (setf (sap-ref-32 (second toplevel-thing) 0)
 160                   (get-lisp-obj-address
 161                    (svref *!load-time-values* (third toplevel-thing)))))
 162            #!+(and x86 gencgc)
 163            (:load-time-code-fixup
 164             (sb!vm::!do-load-time-code-fixup (second toplevel-thing)
 165                                              (third  toplevel-thing)
 166                                              (fourth toplevel-thing)
 167                                              (fifth  toplevel-thing)))
 168            (t
 169             (!cold-lose "bogus fixup code in *!REVERSED-COLD-TOPLEVELS*"))))
 170         (t (!cold-lose "bogus function in *!REVERSED-COLD-TOPLEVELS*")))))
 171   (/show0 "done with loop over cold toplevel forms and fixups")
 172
 173   ;; Set sane values again, so that the user sees sane values instead
 174   ;; of whatever is left over from the last DECLAIM/PROCLAIM.
 175   (show-and-call !policy-cold-init-or-resanify)
 176
 177   ;; Only do this after toplevel forms have run, 'cause that's where
 178   ;; DEFTYPEs are.
 179   (setf *type-system-initialized* t)
 180
 181   (show-and-call os-cold-init-or-reinit)
 182
 183   (show-and-call stream-cold-init-or-reset)
 184   (show-and-call !loader-cold-init)
 185   (show-and-call signal-cold-init-or-reinit)
 186   (setf (sb!alien:extern-alien "internal_errors_enabled" boolean) t)
 187
 188   ;; FIXME: This list of modes should be defined in one place and
 189   ;; explicitly shared between here and REINIT.
 190   ;;
 191   ;; FIXME: In CMU CL, this is done "here" (i.e. in the analogous
 192   ;; lispinit.lisp code) for every processor architecture. But Daniel
 193   ;; Barlow's Alpha patches suppress it for Alpha. Why the difference?
 194   #!+alpha
 195   (set-floating-point-modes :traps '(:overflow
 196                                      #!-x86 :underflow
 197                                      :invalid
 198                                      :divide-by-zero))
 199
 200   (show-and-call !class-finalize)
 201
 202   ;; The reader and printer are initialized very late, so that they
 203   ;; can do hairy things like invoking the compiler as part of their
 204   ;; initialization.
 205   (show-and-call !reader-cold-init)
 206   (let ((*readtable* *standard-readtable*))
 207     (show-and-call !sharpm-cold-init)
 208     (show-and-call !backq-cold-init))
 209   (setf *readtable* (copy-readtable *standard-readtable*))
 210   (setf sb!debug:*debug-readtable* (copy-readtable *standard-readtable*))
 211   (sb!pretty:!pprint-cold-init)
 212
 213   ;; the ANSI-specified initial value of *PACKAGE*
 214   (setf *package* (find-package "COMMON-LISP-USER"))
 215   ;; FIXME: I'm not sure where it should be done, but CL-USER really
 216   ;; ought to USE-PACKAGE publicly accessible packages like SB-DEBUG
 217   ;; (for ARG and VAR), SB-EXT, SB-EXT-C-CALL, and SB-EXT-ALIEN so
 218   ;; that the user has a hint about which symbols we consider public.
 219   ;; (Perhaps SB-DEBUG wouldn't need to be in the list if ARG and VAR
 220   ;; could be typed directly, with no parentheses, at the debug prompt
 221   ;; the way that e.g. F or BACKTRACE can be?)
 222
 223   (/show0 "done initializing, setting *COLD-INIT-COMPLETE-P*")
 224   (setf *cold-init-complete-p* t)
 225
 226   ;; The system is finally ready for GC.
 227   (setf *already-maybe-gcing* nil)
 228   (/show0 "enabling GC")
 229   (gc-on)
 230   (/show0 "doing first GC")
 231   (gc :full t)
 232   (/show0 "back from first GC")
 233
 234   ;; The show is on.
 235   (terpri)
 236   (/show0 "going into toplevel loop")
 237   (handling-end-of-the-world
 238     (toplevel-init)))
 239
 240 (defun quit (&key recklessly-p
 241                   (unix-code 0 unix-code-p)
 242                   (unix-status unix-code))
 243   #!+sb-doc
 244   "Terminate the current Lisp. Things are cleaned up (with UNWIND-PROTECT
 245   and so forth) unless RECKLESSLY-P is non-NIL. On UNIX-like systems,
 246   UNIX-STATUS is used as the status code."
 247   (declare (type (signed-byte 32) unix-code))
 248   ;; FIXME: UNIX-CODE was deprecated in sbcl-0.6.8, after having been
 249   ;; around for less than a year. It should be safe to remove it after
 250   ;; a year.
 251   (when unix-code-p
 252     (warn "The UNIX-CODE argument is deprecated. Use the UNIX-STATUS argument
 253 instead (which is another name for the same thing)."))
 254   (if recklessly-p
 255       (sb!unix:unix-exit unix-status)
 256       (throw '%end-of-the-world unix-status)))
 257 \f
 258 ;;;; initialization functions
 259
 260 (defun reinit ()
 261   (without-interrupts
 262     (without-gcing
 263       (os-cold-init-or-reinit)
 264       (stream-reinit)
 265       (signal-cold-init-or-reinit)
 266       (gc-reinit)
 267       (setf (sb!alien:extern-alien "internal_errors_enabled" boolean) t)
 268       (set-floating-point-modes :traps
 269                                 '(:overflow
 270                                   :invalid
 271                                   :divide-by-zero
 272                                   ;; PRINT seems not to like x86 NPX
 273                                   ;; denormal floats like
 274                                   ;; LEAST-NEGATIVE-SINGLE-FLOAT, so
 275                                   ;; the :UNDERFLOW exceptions are
 276                                   ;; disabled by default. Joe User can
 277                                   ;; explicitly enable them if
 278                                   ;; desired.
 279                                   #!-x86 :underflow))
 280       ;; Clear pseudo atomic in case this core wasn't compiled with
 281       ;; support.
 282       ;;
 283       ;; FIXME: In SBCL our cores are always compiled with support. So
 284       ;; we don't need to do this, do we? At least not for this
 285       ;; reason.. (Perhaps we should do it anyway in case someone
 286       ;; manages to save an image from within a pseudo-atomic-atomic
 287       ;; operation?)
 288       #!+x86 (setf *pseudo-atomic-atomic* 0))
 289     (gc-on)))
 290 \f
 291 ;;;; some support for any hapless wretches who end up debugging cold
 292 ;;;; init code
 293
 294 ;;; Decode THING into hexadecimal notation using only machinery
 295 ;;; available early in cold init.
 296 #!+sb-show
 297 (defun hexstr (thing)
 298   (/noshow0 "entering HEXSTR")
 299   (let ((addr (sb!kernel:get-lisp-obj-address thing))
 300         (str (make-string 10)))
 301     (/noshow0 "ADDR and STR calculated")
 302     (setf (char str 0) #\0
 303           (char str 1) #\x)
 304     (/noshow0 "CHARs 0 and 1 set")
 305     (dotimes (i 8)
 306       (/noshow0 "at head of DOTIMES loop")
 307       (let* ((nibble (ldb (byte 4 0) addr))
 308              (chr (char "0123456789abcdef" nibble)))
 309         (declare (type (unsigned-byte 4) nibble)
 310                  (base-char chr))
 311         (/noshow0 "NIBBLE and CHR calculated")
 312         (setf (char str (- 9 i)) chr
 313               addr (ash addr -4))))
 314     str))
 315
 316 #!+sb-show
 317 (defun cold-print (x)
 318   (typecase x
 319     (simple-string (sb!sys:%primitive print x))
 320     (symbol (sb!sys:%primitive print (symbol-name x)))
 321     (list (let ((count 0))
 322             (sb!sys:%primitive print "list:")
 323             (dolist (i x)
 324               (when (>= (incf count) 4)
 325                 (sb!sys:%primitive print "...")
 326                 (return))
 327               (cold-print i))))
 328     (t (sb!sys:%primitive print (hexstr x)))))