src/code/cold-init.lisp

   1 ;;;; cold initialization stuff, plus some other miscellaneous stuff
   2 ;;;; that we don't have any better place for
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!IMPL")
  14 \f
  15 ;;;; burning our ships behind us
  16
  17 ;;; There's a fair amount of machinery which is needed only at cold
  18 ;;; init time, and should be discarded before freezing the final
  19 ;;; system. We discard it by uninterning the associated symbols.
  20 ;;; Rather than using a special table of symbols to be uninterned,
  21 ;;; which might be tedious to maintain, instead we use a hack:
  22 ;;; anything whose name matches a magic character pattern is
  23 ;;; uninterned.
  24 ;;;
  25 ;;; FIXME: Are there other tables that need to have entries removed?
  26 ;;; What about symbols of the form DEF!FOO?
  27 (defun !unintern-init-only-stuff ()
  28   (do ((any-changes? nil nil))
  29       (nil)
  30     (dolist (package (list-all-packages))
  31       (do-symbols (symbol package)
  32         (let ((name (symbol-name symbol)))
  33           (when (or (string= name "!" :end1 1 :end2 1)
  34                     (and (>= (length name) 2)
  35                          (string= name "*!" :end1 2 :end2 2)))
  36             (/show0 "uninterning cold-init-only symbol..")
  37             (/primitive-print name)
  38             ;; FIXME: Is this (FIRST (LAST *INFO-ENVIRONMENT*)) really
  39             ;; meant to be an idiom to use?  Is there a more obvious
  40             ;; name for this? [e.g. (GLOBAL-ENVIRONMENT)?]
  41             (do-info ((first (last *info-environment*))
  42                             :name entry :class class :type type)
  43               (when (eq entry symbol)
  44                 (clear-info class type entry)))
  45             (unintern symbol package)
  46             (setf any-changes? t)))))
  47     (unless any-changes?
  48       (return))))
  49 \f
  50 ;;;; putting ourselves out of our misery when things become too much to bear
  51
  52 (declaim (ftype (function (simple-string) nil) !cold-lose))
  53 (defun !cold-lose (msg)
  54   (%primitive print msg)
  55   (%primitive print "too early in cold init to recover from errors")
  56   (%halt))
  57
  58 ;;; last-ditch error reporting for things which should never happen
  59 ;;; and which, if they do happen, are sufficiently likely to torpedo
  60 ;;; the normal error-handling system that we want to bypass it
  61 (declaim (ftype (function (simple-string) nil) critically-unreachable))
  62 (defun critically-unreachable (where)
  63   (%primitive print "internal error: Control should never reach here, i.e.")
  64   (%primitive print where)
  65   (%halt))
  66 \f
  67 ;;;; !COLD-INIT
  68
  69 ;;; a list of toplevel things set by GENESIS
  70 (defvar *!reversed-cold-toplevels*)
  71
  72 ;;; a SIMPLE-VECTOR set by GENESIS
  73 (defvar *!load-time-values*)
  74
  75 (eval-when (:compile-toplevel :execute)
  76   ;; FIXME: Perhaps we should make SHOW-AND-CALL-AND-FMAKUNBOUND, too,
  77   ;; and use it for most of the cold-init functions. (Just be careful
  78   ;; not to use it for the COLD-INIT-OR-REINIT functions.)
  79   (sb!xc:defmacro show-and-call (name)
  80     `(progn
  81        (/primitive-print ,(symbol-name name))
  82        (,name))))
  83
  84 ;;; called when a cold system starts up
  85 (defun !cold-init ()
  86   #!+sb-doc "Give the world a shove and hope it spins."
  87
  88   (/show0 "entering !COLD-INIT")
  89
  90   ;; FIXME: It'd probably be cleaner to have most of the stuff here
  91   ;; handled by calls like !GC-COLD-INIT, !ERROR-COLD-INIT, and
  92   ;; !UNIX-COLD-INIT. And *TYPE-SYSTEM-INITIALIZED* could be changed to
  93   ;; *TYPE-SYSTEM-INITIALIZED-WHEN-BOUND* so that it doesn't need to
  94   ;; be explicitly set in order to be meaningful.
  95   (setf *after-gc-hooks* nil
  96         *gc-inhibit* t
  97         *gc-pending* nil
  98         #!+sb-thread *stop-for-gc-pending* #!+sb-thread nil
  99         *interrupts-enabled* t
 100         *interrupt-pending* nil
 101         *break-on-signals* nil
 102         *maximum-error-depth* 10
 103         *current-error-depth* 0
 104         *cold-init-complete-p* nil
 105         *type-system-initialized* nil
 106         sb!vm:*alloc-signal* nil)
 107
 108   ;; I'm not sure where eval is first called, so I put this first.
 109   #!+sb-eval
 110   (show-and-call sb!eval::!full-eval-cold-init)
 111
 112   (show-and-call thread-init-or-reinit)
 113   (show-and-call !typecheckfuns-cold-init)
 114
 115   ;; Anyone might call RANDOM to initialize a hash value or something;
 116   ;; and there's nothing which needs to be initialized in order for
 117   ;; this to be initialized, so we initialize it right away.
 118   (show-and-call !random-cold-init)
 119
 120   (show-and-call !character-database-cold-init)
 121   (show-and-call !character-name-database-cold-init)
 122
 123   (show-and-call !early-package-cold-init)
 124   (show-and-call !package-cold-init)
 125
 126   ;; All sorts of things need INFO and/or (SETF INFO).
 127   (/show0 "about to SHOW-AND-CALL !GLOBALDB-COLD-INIT")
 128   (show-and-call !globaldb-cold-init)
 129
 130   ;; This needs to be done early, but needs to be after INFO is
 131   ;; initialized.
 132   (show-and-call !function-names-cold-init)
 133   (show-and-call !fdefn-cold-init)
 134
 135   ;; Various toplevel forms call MAKE-ARRAY, which calls SUBTYPEP, so
 136   ;; the basic type machinery needs to be initialized before toplevel
 137   ;; forms run.
 138   (show-and-call !type-class-cold-init)
 139   (show-and-call !typedefs-cold-init)
 140   (show-and-call !classes-cold-init)
 141   (show-and-call !early-type-cold-init)
 142   (show-and-call !late-type-cold-init)
 143   (show-and-call !alien-type-cold-init)
 144   (show-and-call !target-type-cold-init)
 145   (show-and-call !vm-type-cold-init)
 146   ;; FIXME: It would be tidy to make sure that that these cold init
 147   ;; functions are called in the same relative order as the toplevel
 148   ;; forms of the corresponding source files.
 149
 150   ;;(show-and-call !package-cold-init)
 151   (show-and-call !policy-cold-init-or-resanify)
 152   (/show0 "back from !POLICY-COLD-INIT-OR-RESANIFY")
 153
 154   (show-and-call !constantp-cold-init)
 155   (show-and-call !early-proclaim-cold-init)
 156
 157   ;; KLUDGE: Why are fixups mixed up with toplevel forms? Couldn't
 158   ;; fixups be done separately? Wouldn't that be clearer and better?
 159   ;; -- WHN 19991204
 160   (/show0 "doing cold toplevel forms and fixups")
 161   (/show0 "(LISTP *!REVERSED-COLD-TOPLEVELS*)=..")
 162   (/hexstr (if (listp *!reversed-cold-toplevels*) "true" "NIL"))
 163   (/show0 "about to calculate (LENGTH *!REVERSED-COLD-TOPLEVELS*)")
 164   (/show0 "(LENGTH *!REVERSED-COLD-TOPLEVELS*)=..")
 165   #!+sb-show (let ((r-c-tl-length (length *!reversed-cold-toplevels*)))
 166                (/show0 "(length calculated..)")
 167                (let ((hexstr (hexstr r-c-tl-length)))
 168                  (/show0 "(hexstr calculated..)")
 169                  (/primitive-print hexstr)))
 170   (let (#!+sb-show (index-in-cold-toplevels 0))
 171     #!+sb-show (declare (type fixnum index-in-cold-toplevels))
 172
 173     (dolist (toplevel-thing (prog1
 174                                 (nreverse *!reversed-cold-toplevels*)
 175                               ;; (Now that we've NREVERSEd it, it's
 176                               ;; somewhat scrambled, so keep anyone
 177                               ;; else from trying to get at it.)
 178                               (makunbound '*!reversed-cold-toplevels*)))
 179       #!+sb-show
 180       (when (zerop (mod index-in-cold-toplevels 1024))
 181         (/show0 "INDEX-IN-COLD-TOPLEVELS=..")
 182         (/hexstr index-in-cold-toplevels))
 183       #!+sb-show
 184       (setf index-in-cold-toplevels
 185             (the fixnum (1+ index-in-cold-toplevels)))
 186       (typecase toplevel-thing
 187         (function
 188          (funcall toplevel-thing))
 189         (cons
 190          (case (first toplevel-thing)
 191            (:load-time-value
 192             (setf (svref *!load-time-values* (third toplevel-thing))
 193                   (funcall (second toplevel-thing))))
 194            (:load-time-value-fixup
 195             (setf (sap-ref-word (second toplevel-thing) 0)
 196                   (get-lisp-obj-address
 197                    (svref *!load-time-values* (third toplevel-thing)))))
 198            #!+(and (or x86 x86-64) gencgc)
 199            (:load-time-code-fixup
 200             (sb!vm::!envector-load-time-code-fixup (second toplevel-thing)
 201                                                    (third  toplevel-thing)
 202                                                    (fourth toplevel-thing)
 203                                                    (fifth  toplevel-thing)))
 204            (t
 205             (!cold-lose "bogus fixup code in *!REVERSED-COLD-TOPLEVELS*"))))
 206         (t (!cold-lose "bogus function in *!REVERSED-COLD-TOPLEVELS*")))))
 207   (/show0 "done with loop over cold toplevel forms and fixups")
 208
 209   ;; Set sane values again, so that the user sees sane values instead
 210   ;; of whatever is left over from the last DECLAIM/PROCLAIM.
 211   (show-and-call !policy-cold-init-or-resanify)
 212
 213   ;; Only do this after toplevel forms have run, 'cause that's where
 214   ;; DEFTYPEs are.
 215   (setf *type-system-initialized* t)
 216
 217   ;; now that the type system is definitely initialized, fixup UNKNOWN
 218   ;; types that have crept in.
 219   (show-and-call !fixup-type-cold-init)
 220   ;; run the PROCLAIMs.
 221   (show-and-call !late-proclaim-cold-init)
 222
 223   (show-and-call os-cold-init-or-reinit)
 224
 225   (show-and-call stream-cold-init-or-reset)
 226   (show-and-call !loader-cold-init)
 227   (show-and-call !foreign-cold-init)
 228   #!-win32 (show-and-call signal-cold-init-or-reinit)
 229   (/show0 "enabling internal errors")
 230   (setf (sb!alien:extern-alien "internal_errors_enabled" boolean) t)
 231
 232   (show-and-call float-cold-init-or-reinit)
 233
 234   (show-and-call !class-finalize)
 235
 236   ;; The reader and printer are initialized very late, so that they
 237   ;; can do hairy things like invoking the compiler as part of their
 238   ;; initialization.
 239   (show-and-call !reader-cold-init)
 240   (let ((*readtable* *standard-readtable*))
 241     (show-and-call !sharpm-cold-init)
 242     (show-and-call !backq-cold-init))
 243   (setf *readtable* (copy-readtable *standard-readtable*))
 244   (setf sb!debug:*debug-readtable* (copy-readtable *standard-readtable*))
 245   (sb!pretty:!pprint-cold-init)
 246
 247   ;; the ANSI-specified initial value of *PACKAGE*
 248   (setf *package* (find-package "COMMON-LISP-USER"))
 249
 250   (/show0 "done initializing, setting *COLD-INIT-COMPLETE-P*")
 251   (setf *cold-init-complete-p* t)
 252
 253   ;; The system is finally ready for GC.
 254   (/show0 "enabling GC")
 255   (gc-on)
 256   (/show0 "doing first GC")
 257   (gc :full t)
 258   (/show0 "back from first GC")
 259
 260   ;; The show is on.
 261   (terpri)
 262   (/show0 "going into toplevel loop")
 263   (handling-end-of-the-world
 264     (toplevel-init)
 265     (critically-unreachable "after TOPLEVEL-INIT")))
 266
 267 (defun quit (&key recklessly-p (unix-status 0))
 268   #!+sb-doc
 269   "Terminate the current Lisp. Things are cleaned up (with
 270 UNWIND-PROTECT and so forth) unless RECKLESSLY-P is non-NIL. On
 271 UNIX-like systems, UNIX-STATUS is used as the status code."
 272   (declare (type (signed-byte 32) unix-status))
 273   (/show0 "entering QUIT")
 274   (if recklessly-p
 275       (sb!unix:unix-exit unix-status)
 276       (throw '%end-of-the-world unix-status))
 277   (critically-unreachable "after trying to die in QUIT"))
 278 \f
 279 ;;;; initialization functions
 280
 281 (defun thread-init-or-reinit ()
 282   (sb!thread::init-initial-thread)
 283   (sb!thread::init-job-control)
 284   (sb!thread::get-foreground))
 285
 286 (defun reinit ()
 287   (setf *default-external-format* nil)
 288   (setf sb!alien::*default-c-string-external-format* nil)
 289   (without-interrupts
 290     (without-gcing
 291         (os-cold-init-or-reinit)
 292       (thread-init-or-reinit)
 293       (stream-reinit)
 294       #!-win32
 295       (signal-cold-init-or-reinit)
 296       (setf (sb!alien:extern-alien "internal_errors_enabled" boolean) t)
 297       (float-cold-init-or-reinit)))
 298   (gc-reinit)
 299   (foreign-reinit)
 300   (time-reinit)
 301   ;; If the debugger was disabled in the saved core, we need to
 302   ;; re-disable ldb again.
 303   (when (eq *invoke-debugger-hook* 'sb!debug::debugger-disabled-hook)
 304     (sb!debug::disable-debugger))
 305   (dolist (hook *init-hooks*)
 306     (with-simple-restart (continue "Skip this initialization hook.")
 307       (funcall hook))))
 308 \f
 309 ;;;; some support for any hapless wretches who end up debugging cold
 310 ;;;; init code
 311
 312 ;;; Decode THING into hexadecimal notation using only machinery
 313 ;;; available early in cold init.
 314 #!+sb-show
 315 (defun hexstr (thing)
 316   (/noshow0 "entering HEXSTR")
 317   (let ((addr (get-lisp-obj-address thing))
 318         (str (make-string 10 :element-type 'base-char)))
 319     (/noshow0 "ADDR and STR calculated")
 320     (setf (char str 0) #\0
 321           (char str 1) #\x)
 322     (/noshow0 "CHARs 0 and 1 set")
 323     (dotimes (i 8)
 324       (/noshow0 "at head of DOTIMES loop")
 325       (let* ((nibble (ldb (byte 4 0) addr))
 326              (chr (char "0123456789abcdef" nibble)))
 327         (declare (type (unsigned-byte 4) nibble)
 328                  (base-char chr))
 329         (/noshow0 "NIBBLE and CHR calculated")
 330         (setf (char str (- 9 i)) chr
 331               addr (ash addr -4))))
 332     str))
 333
 334 #!+sb-show
 335 (defun cold-print (x)
 336   (typecase x
 337     (simple-string (sb!sys:%primitive print x))
 338     (symbol (sb!sys:%primitive print (symbol-name x)))
 339     (list (let ((count 0))
 340             (sb!sys:%primitive print "list:")
 341             (dolist (i x)
 342               (when (>= (incf count) 4)
 343                 (sb!sys:%primitive print "...")
 344                 (return))
 345               (cold-print i))))
 346     (t (sb!sys:%primitive print (hexstr x)))))