src/code/cold-init.lisp

   1 ;;;; cold initialization stuff, plus some other miscellaneous stuff
   2 ;;;; that we don't have any better place for
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!IMPL")
  14 \f
  15 ;;;; burning our ships behind us
  16
  17 ;;; There's a fair amount of machinery which is needed only at cold
  18 ;;; init time, and should be discarded before freezing the final
  19 ;;; system. We discard it by uninterning the associated symbols.
  20 ;;; Rather than using a special table of symbols to be uninterned,
  21 ;;; which might be tedious to maintain, instead we use a hack:
  22 ;;; anything whose name matches a magic character pattern is
  23 ;;; uninterned.
  24 (defun !unintern-init-only-stuff ()
  25   (do ((any-changes? nil nil))
  26       (nil)
  27     (dolist (package (list-all-packages))
  28       (do-symbols (symbol package)
  29         (let ((name (symbol-name symbol)))
  30           (when (or (string= name "!" :end1 1 :end2 1)
  31                     (and (>= (length name) 2)
  32                          (string= name "*!" :end1 2 :end2 2)))
  33             (/show0 "uninterning cold-init-only symbol..")
  34             #!+sb-show (%primitive print name)
  35             (unintern symbol package)
  36             (setf any-changes? t)))))
  37     (unless any-changes?
  38       (return))))
  39 \f
  40 ;;;; !COLD-INIT
  41
  42 ;;; a list of toplevel things set by GENESIS
  43 (defvar *!reversed-cold-toplevels*)
  44
  45 ;;; a SIMPLE-VECTOR set by genesis
  46 (defvar *!load-time-values*)
  47
  48 (defun !cold-lose (msg)
  49   (%primitive print msg)
  50   (%primitive print "too early in cold init to recover from errors")
  51   (%halt))
  52
  53 #!+gengc
  54 (defun do-load-time-value-fixup (object offset index)
  55   (declare (type index offset))
  56   (let ((value (svref *!load-time-values* index)))
  57     (typecase object
  58       (list
  59        (case offset
  60          (0 (setf (car object) value))
  61          (1 (setf (cdr object) value))
  62          (t (!cold-lose "bogus offset in cons cell"))))
  63       (instance
  64        (setf (%instance-ref object (- offset sb!vm:instance-slots-offset))
  65              value))
  66       (code-component
  67        (setf (code-header-ref object offset) value))
  68       (simple-vector
  69        (setf (svref object (- offset sb!vm:vector-data-offset)) value))
  70       (t
  71        (!cold-lose "unknown kind of object for load-time-value fixup")))))
  72
  73 (eval-when (:compile-toplevel :execute)
  74   ;; FIXME: Perhaps we should make SHOW-AND-CALL-AND-FMAKUNBOUND, too,
  75   ;; and use it for most of the cold-init functions. (Just be careful
  76   ;; not to use it for the COLD-INIT-OR-REINIT functions.)
  77   (sb!xc:defmacro show-and-call (name)
  78     `(progn
  79        #!+sb-show (%primitive print ,(symbol-name name))
  80        (,name))))
  81
  82 ;;; called when a cold system starts up
  83 (defun !cold-init ()
  84   #!+sb-doc "Give the world a shove and hope it spins."
  85
  86   (/show0 "entering !COLD-INIT")
  87
  88   ;; FIXME: It'd probably be cleaner to have most of the stuff here
  89   ;; handled by calls like !GC-COLD-INIT, !ERROR-COLD-INIT, and
  90   ;; !UNIX-COLD-INIT. And *TYPE-SYSTEM-INITIALIZED* could be changed to
  91   ;; *TYPE-SYSTEM-INITIALIZED-WHEN-BOUND* so that it doesn't need to
  92   ;; be explicitly set in order to be meaningful.
  93   (setf *gc-verbose* nil)
  94   (setf *gc-notify-stream* nil)
  95   (setf *before-gc-hooks* nil)
  96   (setf *after-gc-hooks* nil)
  97   #!+gengc (setf *handler-clusters* nil)
  98   #!-gengc (setf *already-maybe-gcing* t
  99                  *gc-inhibit* t
 100                  *need-to-collect-garbage* nil
 101                  sb!unix::*interrupts-enabled* t
 102                  sb!unix::*interrupt-pending* nil)
 103   (setf *break-on-signals* nil)
 104   (setf *maximum-error-depth* 10)
 105   (setf *current-error-depth* 0)
 106   (setf *cold-init-complete-p* nil)
 107   (setf *type-system-initialized* nil)
 108
 109   ;; Anyone might call RANDOM to initialize a hash value or something;
 110   ;; and there's nothing which needs to be initialized in order for
 111   ;; this to be initialized, so we initialize it right away.
 112   (show-and-call !random-cold-init)
 113
 114   ;; All sorts of things need INFO and/or (SETF INFO).
 115   (/show0 "about to SHOW-AND-CALL !GLOBALDB-COLD-INIT")
 116   (show-and-call !globaldb-cold-init)
 117
 118   ;; This needs to be done early, but needs to be after INFO is
 119   ;; initialized.
 120   (show-and-call !fdefn-cold-init)
 121
 122   ;; Various toplevel forms call MAKE-ARRAY, which calls SUBTYPEP, so
 123   ;; the basic type machinery needs to be initialized before toplevel
 124   ;; forms run.
 125   (show-and-call !type-class-cold-init)
 126   (show-and-call !typedefs-cold-init)
 127   (show-and-call !classes-cold-init)
 128   (show-and-call !early-type-cold-init)
 129   (show-and-call !late-type-cold-init)
 130   (show-and-call !alien-type-cold-init)
 131   (show-and-call !target-type-cold-init)
 132   (show-and-call !vm-type-cold-init)
 133   ;; FIXME: It would be tidy to make sure that that these cold init
 134   ;; functions are called in the same relative order as the toplevel
 135   ;; forms of the corresponding source files.
 136
 137   (show-and-call !package-cold-init)
 138   (show-and-call !policy-cold-init-or-resanify)
 139   (/show0 "back from !POLICY-COLD-INIT-OR-RESANIFY")
 140
 141   ;; KLUDGE: Why are fixups mixed up with toplevel forms? Couldn't
 142   ;; fixups be done separately? Wouldn't that be clearer and better?
 143   ;; -- WHN 19991204
 144   (/show0 "doing cold toplevel forms and fixups")
 145   (/show0 "(LENGTH *!REVERSED-COLD-TOPLEVELS*)=..")
 146   #!+sb-show (%primitive print
 147                          (sb!impl::hexstr (length *!reversed-cold-toplevels*)))
 148   (let (#!+sb-show (index-in-cold-toplevels 0)
 149         #!+sb-show (filename-in-cold-toplevels nil))
 150     #!+sb-show (declare (type fixnum index-in-cold-toplevels))
 151     (dolist (toplevel-thing (prog1
 152                                 (nreverse *!reversed-cold-toplevels*)
 153                               ;; (Now that we've NREVERSEd it, it's
 154                               ;; somewhat scrambled, so keep anyone
 155                               ;; else from trying to get at it.)
 156                               (makunbound '*!reversed-cold-toplevels*)))
 157       #!+sb-show
 158       (when (zerop (mod index-in-cold-toplevels 1024))
 159         (/show0 "INDEX-IN-COLD-TOPLEVELS=..")
 160         (%primitive print (sb!impl::hexstr index-in-cold-toplevels)))
 161       #!+sb-show
 162       (setf index-in-cold-toplevels
 163             (the fixnum (1+ index-in-cold-toplevels)))
 164       (typecase toplevel-thing
 165         (function
 166          (funcall toplevel-thing))
 167         (cons
 168          (case (first toplevel-thing)
 169            (:load-time-value
 170             (setf (svref *!load-time-values* (third toplevel-thing))
 171                   (funcall (second toplevel-thing))))
 172            (:load-time-value-fixup
 173             #!-gengc
 174             (setf (sap-ref-32 (second toplevel-thing) 0)
 175                   (get-lisp-obj-address
 176                    (svref *!load-time-values* (third toplevel-thing))))
 177             #!+gengc
 178             (do-load-time-value-fixup (second toplevel-thing)
 179                                       (third  toplevel-thing)
 180                                       (fourth toplevel-thing)))
 181            #!+(and x86 gencgc)
 182            (:load-time-code-fixup
 183             (sb!vm::do-load-time-code-fixup (second toplevel-thing)
 184                                             (third  toplevel-thing)
 185                                             (fourth toplevel-thing)
 186                                             (fifth  toplevel-thing)))
 187            (t
 188             (!cold-lose "bogus fixup code in *!REVERSED-COLD-TOPLEVELS*"))))
 189         (t (!cold-lose "bogus function in *!REVERSED-COLD-TOPLEVELS*")))))
 190   (/show0 "done with loop over cold toplevel forms and fixups")
 191
 192   ;; Set sane values again, so that the user sees sane values instead of
 193   ;; whatever is left over from the last DECLAIM/PROCLAIM.
 194   (show-and-call !policy-cold-init-or-resanify)
 195
 196   ;; Only do this after toplevel forms have run, 'cause that's where
 197   ;; DEFTYPEs are.
 198   (setf *type-system-initialized* t)
 199
 200   (show-and-call os-cold-init-or-reinit)
 201
 202   (show-and-call stream-cold-init-or-reset)
 203   (show-and-call !loader-cold-init)
 204   (show-and-call signal-cold-init-or-reinit)
 205   (setf (sb!alien:extern-alien "internal_errors_enabled" boolean) t)
 206
 207   ;; FIXME: This list of modes should be defined in one place and
 208   ;; explicitly shared between here and REINIT.
 209   (set-floating-point-modes :traps '(:overflow
 210                                      #!-x86 :underflow
 211                                      :invalid
 212                                      :divide-by-zero))
 213
 214   (show-and-call !class-finalize)
 215
 216   ;; The reader and printer are initialized very late, so that they
 217   ;; can even do hairy things like invoking the compiler as part of
 218   ;; their initialization.
 219   (show-and-call !reader-cold-init)
 220   (let ((*readtable* *standard-readtable*))
 221     (show-and-call !sharpm-cold-init)
 222     (show-and-call !backq-cold-init))
 223   (setf *readtable* (copy-readtable *standard-readtable*))
 224   (setf sb!debug:*debug-readtable* (copy-readtable *standard-readtable*))
 225   (sb!pretty:!pprint-cold-init)
 226
 227   ;; the ANSI-specified initial value of *PACKAGE*
 228   (setf *package* (find-package "COMMON-LISP-USER"))
 229   ;; FIXME: I'm not sure where it should be done, but CL-USER really
 230   ;; ought to USE-PACKAGE publicly accessible packages like SB-DEBUG
 231   ;; (for ARG and VAR), SB-EXT, SB-EXT-C-CALL, and SB-EXT-ALIEN so
 232   ;; that the user has a hint about which symbols we consider public.
 233   ;; (Perhaps SB-DEBUG wouldn't need to be in the list if ARG and VAR
 234   ;; could be typed directly, with no parentheses, at the debug prompt
 235   ;; the way that e.g. F or BACKTRACE can be?)
 236
 237   (/show0 "done initializing")
 238   (setf *cold-init-complete-p* t)
 239
 240   ;; Unintern no-longer-needed stuff before we GC.
 241   #!-sb-fluid
 242   (!unintern-init-only-stuff)
 243
 244   ;; The system is finally ready for GC.
 245   #!-gengc (setf *already-maybe-gcing* nil)
 246   (/show0 "enabling GC")
 247   (gc-on)
 248   (/show0 "doing first GC")
 249   (gc :full t)
 250   (/show0 "back from first GC")
 251
 252   ;; The show is on.
 253   (terpri)
 254   (/show0 "going into toplevel loop")
 255   (handling-end-of-the-world
 256     (toplevel-init)))
 257
 258 (defun quit (&key recklessly-p
 259                   (unix-code 0 unix-code-p)
 260                   (unix-status unix-code))
 261   #!+sb-doc
 262   "Terminate the current Lisp. Things are cleaned up (with UNWIND-PROTECT
 263   and so forth) unless RECKLESSLY-P is non-NIL. On UNIX-like systems,
 264   UNIX-STATUS is used as the status code."
 265   (declare (type (signed-byte 32) unix-code))
 266   ;; FIXME: UNIX-CODE was deprecated in sbcl-0.6.8, after having been
 267   ;; around for less than a year. It should be safe to remove it after
 268   ;; a year.
 269   (when unix-code-p
 270     (warn "The UNIX-CODE argument is deprecated. Use the UNIX-STATUS argument
 271 instead (which is another name for the same thing)."))
 272   (if recklessly-p
 273       (sb!unix:unix-exit unix-status)
 274       (throw '%end-of-the-world unix-status)))
 275 \f
 276 ;;;; initialization functions
 277
 278 (defun reinit ()
 279   (without-interrupts
 280     (without-gcing
 281       (os-cold-init-or-reinit)
 282       (stream-reinit)
 283       (signal-cold-init-or-reinit)
 284       (gc-cold-init-or-reinit)
 285       (setf (sb!alien:extern-alien "internal_errors_enabled" boolean) t)
 286       (set-floating-point-modes :traps
 287                                 ;; PRINT seems to not like x86 NPX denormal
 288                                 ;; floats like LEAST-NEGATIVE-SINGLE-FLOAT, so
 289                                 ;; the :UNDERFLOW exceptions are disabled by
 290                                 ;; default. Joe User can explicitly enable them
 291                                 ;; if desired.
 292                                 '(:overflow #!-x86 :underflow :invalid
 293                                             :divide-by-zero))
 294       ;; Clear pseudo atomic in case this core wasn't compiled with
 295       ;; support.
 296       ;;
 297       ;; FIXME: In SBCL our cores are always compiled with support. So
 298       ;; we don't need to do this, do we? At least not for this
 299       ;; reason.. (Perhaps we should do it anyway in case someone
 300       ;; manages to save an image from within a pseudo-atomic-atomic
 301       ;; operation?)
 302       #!+x86 (setf sb!impl::*pseudo-atomic-atomic* 0))
 303     (gc-on)))
 304 \f
 305 ;;;; some support for any hapless wretches who end up debugging cold
 306 ;;;; init code
 307
 308 ;;; Decode THING into hex using only machinery available early in cold
 309 ;;; init.
 310 #!+sb-show
 311 (defun hexstr (thing)
 312   (let ((addr (sb!kernel:get-lisp-obj-address thing))
 313         (str (make-string 10)))
 314     (setf (char str 0) #\0
 315           (char str 1) #\x)
 316     (dotimes (i 8)
 317       (let* ((nibble (ldb (byte 4 0) addr))
 318              (chr (char "0123456789abcdef" nibble)))
 319         (declare (type (unsigned-byte 4) nibble)
 320                  (base-char chr))
 321         (setf (char str (- 9 i)) chr
 322               addr (ash addr -4))))
 323     str))
 324
 325 #!+sb-show
 326 (defun cold-print (x)
 327   (typecase x
 328     (simple-string (sb!sys:%primitive print x))
 329     (symbol (sb!sys:%primitive print (symbol-name x)))
 330     (list (let ((count 0))
 331             (sb!sys:%primitive print "list:")
 332             (dolist (i x)
 333               (when (>= (incf count) 4)
 334                 (sb!sys:%primitive print "...")
 335                 (return))
 336               (cold-print i))))
 337     (t (sb!sys:%primitive print (hexstr x)))))