src/code/cold-init.lisp

   1 ;;;; cold initialization stuff, plus some other miscellaneous stuff
   2 ;;;; that we don't have any better place for
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!IMPL")
  14 \f
  15 ;;;; burning our ships behind us
  16
  17 ;;; There's a fair amount of machinery which is needed only at cold
  18 ;;; init time, and should be discarded before freezing the final
  19 ;;; system. We discard it by uninterning the associated symbols.
  20 ;;; Rather than using a special table of symbols to be uninterned,
  21 ;;; which might be tedious to maintain, instead we use a hack:
  22 ;;; anything whose name matches a magic character pattern is
  23 ;;; uninterned.
  24 ;;;
  25 ;;; FIXME: Are there other tables that need to have entries removed?
  26 ;;; What about symbols of the form DEF!FOO?
  27 (defun !unintern-init-only-stuff ()
  28   (do ((any-changes? nil nil))
  29       (nil)
  30     (dolist (package (list-all-packages))
  31       (do-symbols (symbol package)
  32         (let ((name (symbol-name symbol)))
  33           (when (or (string= name "!" :end1 1 :end2 1)
  34                     (and (>= (length name) 2)
  35                          (string= name "*!" :end1 2 :end2 2)))
  36             (/show0 "uninterning cold-init-only symbol..")
  37             (/primitive-print name)
  38             ;; FIXME: Is this (FIRST (LAST *INFO-ENVIRONMENT*)) really
  39             ;; meant to be an idiom to use?  Is there a more obvious
  40             ;; name for this? [e.g. (GLOBAL-ENVIRONMENT)?]
  41             (do-info ((first (last *info-environment*))
  42                             :name entry :class class :type type)
  43               (when (eq entry symbol)
  44                 (clear-info class type entry)))
  45             (unintern symbol package)
  46             (setf any-changes? t)))))
  47     (unless any-changes?
  48       (return))))
  49 \f
  50 ;;;; putting ourselves out of our misery when things become too much to bear
  51
  52 (declaim (ftype (function (simple-string) nil) !cold-lose))
  53 (defun !cold-lose (msg)
  54   (%primitive print msg)
  55   (%primitive print "too early in cold init to recover from errors")
  56   (%halt))
  57
  58 ;;; last-ditch error reporting for things which should never happen
  59 ;;; and which, if they do happen, are sufficiently likely to torpedo
  60 ;;; the normal error-handling system that we want to bypass it
  61 (declaim (ftype (function (simple-string) nil) critically-unreachable))
  62 (defun critically-unreachable (where)
  63   (%primitive print "internal error: Control should never reach here, i.e.")
  64   (%primitive print where)
  65   (%halt))
  66 \f
  67 ;;;; !COLD-INIT
  68
  69 ;;; a list of toplevel things set by GENESIS
  70 (defvar *!reversed-cold-toplevels*)
  71
  72 ;;; a SIMPLE-VECTOR set by GENESIS
  73 (defvar *!load-time-values*)
  74
  75 (eval-when (:compile-toplevel :execute)
  76   ;; FIXME: Perhaps we should make SHOW-AND-CALL-AND-FMAKUNBOUND, too,
  77   ;; and use it for most of the cold-init functions. (Just be careful
  78   ;; not to use it for the COLD-INIT-OR-REINIT functions.)
  79   (sb!xc:defmacro show-and-call (name)
  80     `(progn
  81        (/primitive-print ,(symbol-name name))
  82        (,name))))
  83
  84 ;;; called when a cold system starts up
  85 (defun !cold-init ()
  86   #!+sb-doc "Give the world a shove and hope it spins."
  87
  88   (/show0 "entering !COLD-INIT")
  89
  90   ;; FIXME: It'd probably be cleaner to have most of the stuff here
  91   ;; handled by calls like !GC-COLD-INIT, !ERROR-COLD-INIT, and
  92   ;; !UNIX-COLD-INIT. And *TYPE-SYSTEM-INITIALIZED* could be changed to
  93   ;; *TYPE-SYSTEM-INITIALIZED-WHEN-BOUND* so that it doesn't need to
  94   ;; be explicitly set in order to be meaningful.
  95   (setf *after-gc-hooks* nil
  96         *gc-inhibit* t
  97         *gc-pending* nil
  98         #!+sb-thread *stop-for-gc-pending* #!+sb-thread nil
  99         sb!unix::*interrupts-enabled* t
 100         sb!unix::*interrupt-pending* nil
 101         *break-on-signals* nil
 102         *maximum-error-depth* 10
 103         *current-error-depth* 0
 104         *cold-init-complete-p* nil
 105         *type-system-initialized* nil)
 106
 107   (show-and-call thread-init-or-reinit)
 108   (show-and-call !typecheckfuns-cold-init)
 109
 110   ;; Anyone might call RANDOM to initialize a hash value or something;
 111   ;; and there's nothing which needs to be initialized in order for
 112   ;; this to be initialized, so we initialize it right away.
 113   (show-and-call !random-cold-init)
 114
 115   (show-and-call !character-database-cold-init)
 116
 117   (show-and-call !early-package-cold-init)
 118   (show-and-call !package-cold-init)
 119
 120   ;; All sorts of things need INFO and/or (SETF INFO).
 121   (/show0 "about to SHOW-AND-CALL !GLOBALDB-COLD-INIT")
 122   (show-and-call !globaldb-cold-init)
 123
 124   ;; This needs to be done early, but needs to be after INFO is
 125   ;; initialized.
 126   (show-and-call !function-names-cold-init)
 127   (show-and-call !fdefn-cold-init)
 128
 129   ;; Various toplevel forms call MAKE-ARRAY, which calls SUBTYPEP, so
 130   ;; the basic type machinery needs to be initialized before toplevel
 131   ;; forms run.
 132   (show-and-call !type-class-cold-init)
 133   (show-and-call !typedefs-cold-init)
 134   (show-and-call !classes-cold-init)
 135   (show-and-call !early-type-cold-init)
 136   (show-and-call !late-type-cold-init)
 137   (show-and-call !alien-type-cold-init)
 138   (show-and-call !target-type-cold-init)
 139   (show-and-call !vm-type-cold-init)
 140   ;; FIXME: It would be tidy to make sure that that these cold init
 141   ;; functions are called in the same relative order as the toplevel
 142   ;; forms of the corresponding source files.
 143
 144   ;;(show-and-call !package-cold-init)
 145   (show-and-call !policy-cold-init-or-resanify)
 146   (/show0 "back from !POLICY-COLD-INIT-OR-RESANIFY")
 147
 148   (show-and-call !early-proclaim-cold-init)
 149
 150   ;; KLUDGE: Why are fixups mixed up with toplevel forms? Couldn't
 151   ;; fixups be done separately? Wouldn't that be clearer and better?
 152   ;; -- WHN 19991204
 153   (/show0 "doing cold toplevel forms and fixups")
 154   (/show0 "(LISTP *!REVERSED-COLD-TOPLEVELS*)=..")
 155   (/hexstr (if (listp *!reversed-cold-toplevels*) "true" "NIL"))
 156   (/show0 "about to calculate (LENGTH *!REVERSED-COLD-TOPLEVELS*)")
 157   (/show0 "(LENGTH *!REVERSED-COLD-TOPLEVELS*)=..")
 158   #!+sb-show (let ((r-c-tl-length (length *!reversed-cold-toplevels*)))
 159                (/show0 "(length calculated..)")
 160                (let ((hexstr (hexstr r-c-tl-length)))
 161                  (/show0 "(hexstr calculated..)")
 162                  (/primitive-print hexstr)))
 163   (let (#!+sb-show (index-in-cold-toplevels 0))
 164     #!+sb-show (declare (type fixnum index-in-cold-toplevels))
 165
 166     (dolist (toplevel-thing (prog1
 167                                 (nreverse *!reversed-cold-toplevels*)
 168                               ;; (Now that we've NREVERSEd it, it's
 169                               ;; somewhat scrambled, so keep anyone
 170                               ;; else from trying to get at it.)
 171                               (makunbound '*!reversed-cold-toplevels*)))
 172       #!+sb-show
 173       (when (zerop (mod index-in-cold-toplevels 1024))
 174         (/show0 "INDEX-IN-COLD-TOPLEVELS=..")
 175         (/hexstr index-in-cold-toplevels))
 176       #!+sb-show
 177       (setf index-in-cold-toplevels
 178             (the fixnum (1+ index-in-cold-toplevels)))
 179       (typecase toplevel-thing
 180         (function
 181          (funcall toplevel-thing))
 182         (cons
 183          (case (first toplevel-thing)
 184            (:load-time-value
 185             (setf (svref *!load-time-values* (third toplevel-thing))
 186                   (funcall (second toplevel-thing))))
 187            (:load-time-value-fixup
 188             (setf (sap-ref-word (second toplevel-thing) 0)
 189                   (get-lisp-obj-address
 190                    (svref *!load-time-values* (third toplevel-thing)))))
 191            #!+(and (or x86 x86-64) gencgc)
 192            (:load-time-code-fixup
 193             (sb!vm::!envector-load-time-code-fixup (second toplevel-thing)
 194                                                    (third  toplevel-thing)
 195                                                    (fourth toplevel-thing)
 196                                                    (fifth  toplevel-thing)))
 197            (t
 198             (!cold-lose "bogus fixup code in *!REVERSED-COLD-TOPLEVELS*"))))
 199         (t (!cold-lose "bogus function in *!REVERSED-COLD-TOPLEVELS*")))))
 200   (/show0 "done with loop over cold toplevel forms and fixups")
 201
 202   ;; Set sane values again, so that the user sees sane values instead
 203   ;; of whatever is left over from the last DECLAIM/PROCLAIM.
 204   (show-and-call !policy-cold-init-or-resanify)
 205
 206   ;; Only do this after toplevel forms have run, 'cause that's where
 207   ;; DEFTYPEs are.
 208   (setf *type-system-initialized* t)
 209
 210   ;; now that the type system is definitely initialized, fixup UNKNOWN
 211   ;; types that have crept in.
 212   (show-and-call !fixup-type-cold-init)
 213   ;; run the PROCLAIMs.
 214   (show-and-call !late-proclaim-cold-init)
 215
 216   (show-and-call os-cold-init-or-reinit)
 217
 218   (show-and-call stream-cold-init-or-reset)
 219   (show-and-call !loader-cold-init)
 220   (show-and-call !foreign-cold-init)
 221   (show-and-call signal-cold-init-or-reinit)
 222   (/show0 "enabling internal errors")
 223   (setf (sb!alien:extern-alien "internal_errors_enabled" boolean) t)
 224
 225   ;; FIXME: This list of modes should be defined in one place and
 226   ;; explicitly shared between here and REINIT.
 227
 228   ;; FIXME: For some unknown reason, NetBSD/x86 won't run with the
 229   ;; :invalid trap enabled. That should be fixed, but not today...
 230   ;; PEM -- April 5, 2004
 231   (set-floating-point-modes
 232    :traps '(:overflow #!-netbsd :invalid :divide-by-zero))
 233
 234   (show-and-call !class-finalize)
 235
 236   ;; The reader and printer are initialized very late, so that they
 237   ;; can do hairy things like invoking the compiler as part of their
 238   ;; initialization.
 239   (show-and-call !reader-cold-init)
 240   (let ((*readtable* *standard-readtable*))
 241     (show-and-call !sharpm-cold-init)
 242     (show-and-call !backq-cold-init))
 243   (setf *readtable* (copy-readtable *standard-readtable*))
 244   (setf sb!debug:*debug-readtable* (copy-readtable *standard-readtable*))
 245   (sb!pretty:!pprint-cold-init)
 246
 247   ;; the ANSI-specified initial value of *PACKAGE*
 248   (setf *package* (find-package "COMMON-LISP-USER"))
 249
 250   (/show0 "done initializing, setting *COLD-INIT-COMPLETE-P*")
 251   (setf *cold-init-complete-p* t)
 252
 253   ;; The system is finally ready for GC.
 254   (/show0 "enabling GC")
 255   (gc-on)
 256   (/show0 "doing first GC")
 257   (gc :full t)
 258   (/show0 "back from first GC")
 259
 260   ;; The show is on.
 261   (terpri)
 262   (/show0 "going into toplevel loop")
 263   (handling-end-of-the-world
 264     (toplevel-init)
 265     (critically-unreachable "after TOPLEVEL-INIT")))
 266
 267 (defun quit (&key recklessly-p (unix-status 0))
 268   #!+sb-doc
 269   "Terminate the current Lisp. Things are cleaned up (with
 270 UNWIND-PROTECT and so forth) unless RECKLESSLY-P is non-NIL. On
 271 UNIX-like systems, UNIX-STATUS is used as the status code."
 272   (declare (type (signed-byte 32) unix-status))
 273   (/show0 "entering QUIT")
 274   (if recklessly-p
 275       (sb!unix:unix-exit unix-status)
 276       (throw '%end-of-the-world unix-status))
 277   (critically-unreachable "after trying to die in QUIT"))
 278 \f
 279 ;;;; initialization functions
 280
 281 (defun thread-init-or-reinit ()
 282   (sb!thread::init-initial-thread)
 283   (sb!thread::init-job-control)
 284   (sb!thread::get-foreground))
 285
 286 (defun reinit ()
 287   (setf *default-external-format* nil)
 288   (without-interrupts
 289     (without-gcing
 290         (os-cold-init-or-reinit)
 291       (thread-init-or-reinit)
 292       (stream-reinit)
 293       (signal-cold-init-or-reinit)
 294       (setf (sb!alien:extern-alien "internal_errors_enabled" boolean) t)
 295       ;; PRINT seems not to like x86 NPX denormal floats like
 296       ;; LEAST-NEGATIVE-SINGLE-FLOAT, so the :UNDERFLOW exceptions are
 297       ;; disabled by default. Joe User can explicitly enable them if
 298       ;; desired.
 299       ;;
 300       ;; see also comment at the previous SET-FLOATING-POINT-MODES
 301       ;; call site.
 302       (set-floating-point-modes
 303        :traps '(:overflow #!-netbsd :invalid :divide-by-zero))))
 304   (gc-reinit)
 305   ;; make sure TIME works correctly from saved cores
 306   (setf *internal-real-time-base-seconds* nil)
 307   (foreign-reinit)
 308   (dolist (hook *init-hooks*)
 309     (with-simple-restart (continue "Skip this initialization hook.")
 310       (funcall hook))))
 311 \f
 312 ;;;; some support for any hapless wretches who end up debugging cold
 313 ;;;; init code
 314
 315 ;;; Decode THING into hexadecimal notation using only machinery
 316 ;;; available early in cold init.
 317 #!+sb-show
 318 (defun hexstr (thing)
 319   (/noshow0 "entering HEXSTR")
 320   (let ((addr (get-lisp-obj-address thing))
 321         (str (make-string 10 :element-type 'base-char)))
 322     (/noshow0 "ADDR and STR calculated")
 323     (setf (char str 0) #\0
 324           (char str 1) #\x)
 325     (/noshow0 "CHARs 0 and 1 set")
 326     (dotimes (i 8)
 327       (/noshow0 "at head of DOTIMES loop")
 328       (let* ((nibble (ldb (byte 4 0) addr))
 329              (chr (char "0123456789abcdef" nibble)))
 330         (declare (type (unsigned-byte 4) nibble)
 331                  (base-char chr))
 332         (/noshow0 "NIBBLE and CHR calculated")
 333         (setf (char str (- 9 i)) chr
 334               addr (ash addr -4))))
 335     str))
 336
 337 #!+sb-show
 338 (defun cold-print (x)
 339   (typecase x
 340     (simple-string (sb!sys:%primitive print x))
 341     (symbol (sb!sys:%primitive print (symbol-name x)))
 342     (list (let ((count 0))
 343             (sb!sys:%primitive print "list:")
 344             (dolist (i x)
 345               (when (>= (incf count) 4)
 346                 (sb!sys:%primitive print "...")
 347                 (return))
 348               (cold-print i))))
 349     (t (sb!sys:%primitive print (hexstr x)))))