src/code/cold-init.lisp

   1 ;;;; cold initialization stuff, plus some other miscellaneous stuff
   2 ;;;; that we don't have any better place for
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!IMPL")
  14 \f
  15 ;;;; burning our ships behind us
  16
  17 ;;; There's a fair amount of machinery which is needed only at cold
  18 ;;; init time, and should be discarded before freezing the final
  19 ;;; system. We discard it by uninterning the associated symbols.
  20 ;;; Rather than using a special table of symbols to be uninterned,
  21 ;;; which might be tedious to maintain, instead we use a hack:
  22 ;;; anything whose name matches a magic character pattern is
  23 ;;; uninterned.
  24 (defun !unintern-init-only-stuff ()
  25   (do ((any-changes? nil nil))
  26       (nil)
  27     (dolist (package (list-all-packages))
  28       (do-symbols (symbol package)
  29         (let ((name (symbol-name symbol)))
  30           (when (or (string= name "!" :end1 1 :end2 1)
  31                     (and (>= (length name) 2)
  32                          (string= name "*!" :end1 2 :end2 2)))
  33             (/show0 "uninterning cold-init-only symbol..")
  34             #!+sb-show (%primitive print name)
  35             (unintern symbol package)
  36             (setf any-changes? t)))))
  37     (unless any-changes?
  38       (return))))
  39 \f
  40 ;;;; !COLD-INIT
  41
  42 ;;; a list of toplevel things set by GENESIS
  43 (defvar *!reversed-cold-toplevels*)
  44
  45 ;;; a SIMPLE-VECTOR set by genesis
  46 (defvar *!load-time-values*)
  47
  48 (defun !cold-lose (msg)
  49   (%primitive print msg)
  50   (%primitive print "too early in cold init to recover from errors")
  51   (%halt))
  52
  53 #!+gengc
  54 (defun do-load-time-value-fixup (object offset index)
  55   (declare (type index offset))
  56   (let ((value (svref *!load-time-values* index)))
  57     (typecase object
  58       (list
  59        (case offset
  60          (0 (setf (car object) value))
  61          (1 (setf (cdr object) value))
  62          (t (!cold-lose "bogus offset in cons cell"))))
  63       (instance
  64        (setf (%instance-ref object (- offset sb!vm:instance-slots-offset))
  65              value))
  66       (code-component
  67        (setf (code-header-ref object offset) value))
  68       (simple-vector
  69        (setf (svref object (- offset sb!vm:vector-data-offset)) value))
  70       (t
  71        (!cold-lose "unknown kind of object for load-time-value fixup")))))
  72
  73 (eval-when (:compile-toplevel :execute)
  74   ;; FIXME: Perhaps we should make SHOW-AND-CALL-AND-FMAKUNBOUND, too,
  75   ;; and use it for most of the cold-init functions. (Just be careful
  76   ;; not to use it for the COLD-INIT-OR-REINIT functions.)
  77   (sb!xc:defmacro show-and-call (name)
  78     `(progn
  79        #!+sb-show (%primitive print ,(symbol-name name))
  80        (,name))))
  81
  82 ;;; called when a cold system starts up
  83 (defun !cold-init ()
  84   #!+sb-doc "Give the world a shove and hope it spins."
  85
  86   (/show0 "entering !COLD-INIT")
  87
  88   ;; FIXME: It'd probably be cleaner to have most of the stuff here
  89   ;; handled by calls like !GC-COLD-INIT, !ERROR-COLD-INIT, and
  90   ;; !UNIX-COLD-INIT. And *TYPE-SYSTEM-INITIALIZED* could be changed to
  91   ;; *TYPE-SYSTEM-INITIALIZED-WHEN-BOUND* so that it doesn't need to
  92   ;; be explicitly set in order to be meaningful.
  93   (setf *gc-verbose* nil)
  94   (setf *gc-notify-stream* nil)
  95   (setf *before-gc-hooks* nil)
  96   (setf *after-gc-hooks* nil)
  97   #!+gengc (setf *handler-clusters* nil)
  98   #!-gengc (setf *already-maybe-gcing* t
  99                  *gc-inhibit* t
 100                  *need-to-collect-garbage* nil
 101                  sb!unix::*interrupts-enabled* t
 102                  sb!unix::*interrupt-pending* nil)
 103   (setf *break-on-signals* nil)
 104   (setf *maximum-error-depth* 10)
 105   (setf *current-error-depth* 0)
 106   (setf *cold-init-complete-p* nil)
 107   (setf *type-system-initialized* nil)
 108
 109   ;; Anyone might call RANDOM to initialize a hash value or something;
 110   ;; and there's nothing which needs to be initialized in order for
 111   ;; this to be initialized, so we initialize it right away.
 112   (show-and-call !random-cold-init)
 113
 114   ;; All sorts of things need INFO and/or (SETF INFO).
 115   (/show0 "about to SHOW-AND-CALL !GLOBALDB-COLD-INIT")
 116   (show-and-call !globaldb-cold-init)
 117
 118   ;; This needs to be done early, but needs to be after INFO is
 119   ;; initialized.
 120   (show-and-call !fdefn-cold-init)
 121
 122   ;; Various toplevel forms call MAKE-ARRAY, which calls SUBTYPEP, so
 123   ;; the basic type machinery needs to be initialized before toplevel
 124   ;; forms run.
 125   (show-and-call !type-class-cold-init)
 126   (show-and-call !typedefs-cold-init)
 127   (show-and-call !classes-cold-init)
 128   (show-and-call !early-type-cold-init)
 129   (show-and-call !late-type-cold-init)
 130   (show-and-call !alien-type-cold-init)
 131   (show-and-call !target-type-cold-init)
 132   (show-and-call !vm-type-cold-init)
 133   ;; FIXME: It would be tidy to make sure that that these cold init
 134   ;; functions are called in the same relative order as the toplevel
 135   ;; forms of the corresponding source files.
 136
 137   (show-and-call !package-cold-init)
 138   (show-and-call !policy-cold-init-or-resanify)
 139   (/show0 "back from !POLICY-COLD-INIT-OR-RESANIFY")
 140
 141   ;; KLUDGE: Why are fixups mixed up with toplevel forms? Couldn't
 142   ;; fixups be done separately? Wouldn't that be clearer and better?
 143   ;; -- WHN 19991204
 144   (/show0 "doing cold toplevel forms and fixups")
 145   (/show0 "(LISTP *!REVERSED-COLD-TOPLEVELS*)=..")
 146   #!+sb-show (%primitive print
 147                          (if (listp *!reversed-cold-toplevels*) "true" "NIL"))
 148   (/show0 "about to calculate (LENGTH *!REVERSED-COLD-TOPLEVELS*)")
 149   (/show0 "(LENGTH *!REVERSED-COLD-TOPLEVELS*)=..")
 150   #!+sb-show (let ((r-c-tl-length (length *!reversed-cold-toplevels*)))
 151                (/show0 "(length calculated..)")
 152                (let ((hexstr (sb!impl::hexstr r-c-tl-length)))
 153                  (/show0 "(hexstr calculated..)")
 154                  (%primitive print hexstr)))
 155   (let (#!+sb-show (index-in-cold-toplevels 0))
 156     #!+sb-show (declare (type fixnum index-in-cold-toplevels))
 157     (dolist (toplevel-thing (prog1
 158                                 (nreverse *!reversed-cold-toplevels*)
 159                               ;; (Now that we've NREVERSEd it, it's
 160                               ;; somewhat scrambled, so keep anyone
 161                               ;; else from trying to get at it.)
 162                               (makunbound '*!reversed-cold-toplevels*)))
 163       #!+sb-show
 164       (when (zerop (mod index-in-cold-toplevels 1024))
 165         (/show0 "INDEX-IN-COLD-TOPLEVELS=..")
 166         (%primitive print (sb!impl::hexstr index-in-cold-toplevels)))
 167       #!+sb-show
 168       (setf index-in-cold-toplevels
 169             (the fixnum (1+ index-in-cold-toplevels)))
 170       (typecase toplevel-thing
 171         (function
 172          (funcall toplevel-thing))
 173         (cons
 174          (case (first toplevel-thing)
 175            (:load-time-value
 176             (setf (svref *!load-time-values* (third toplevel-thing))
 177                   (funcall (second toplevel-thing))))
 178            (:load-time-value-fixup
 179             #!-gengc
 180             (setf (sap-ref-32 (second toplevel-thing) 0)
 181                   (get-lisp-obj-address
 182                    (svref *!load-time-values* (third toplevel-thing))))
 183             #!+gengc
 184             (do-load-time-value-fixup (second toplevel-thing)
 185                                       (third  toplevel-thing)
 186                                       (fourth toplevel-thing)))
 187            #!+(and x86 gencgc)
 188            (:load-time-code-fixup
 189             (sb!vm::do-load-time-code-fixup (second toplevel-thing)
 190                                             (third  toplevel-thing)
 191                                             (fourth toplevel-thing)
 192                                             (fifth  toplevel-thing)))
 193            (t
 194             (!cold-lose "bogus fixup code in *!REVERSED-COLD-TOPLEVELS*"))))
 195         (t (!cold-lose "bogus function in *!REVERSED-COLD-TOPLEVELS*")))))
 196   (/show0 "done with loop over cold toplevel forms and fixups")
 197
 198   ;; Set sane values again, so that the user sees sane values instead
 199   ;; of whatever is left over from the last DECLAIM/PROCLAIM.
 200   (show-and-call !policy-cold-init-or-resanify)
 201
 202   ;; Only do this after toplevel forms have run, 'cause that's where
 203   ;; DEFTYPEs are.
 204   (setf *type-system-initialized* t)
 205
 206   (show-and-call os-cold-init-or-reinit)
 207
 208   (show-and-call stream-cold-init-or-reset)
 209   (show-and-call !loader-cold-init)
 210   (show-and-call signal-cold-init-or-reinit)
 211   (setf (sb!alien:extern-alien "internal_errors_enabled" boolean) t)
 212
 213   ;; FIXME: This list of modes should be defined in one place and
 214   ;; explicitly shared between here and REINIT.
 215   (set-floating-point-modes :traps '(:overflow
 216                                      #!-x86 :underflow
 217                                      :invalid
 218                                      :divide-by-zero))
 219
 220   (show-and-call !class-finalize)
 221
 222   ;; The reader and printer are initialized very late, so that they
 223   ;; can do hairy things like invoking the compiler as part of their
 224   ;; initialization.
 225   (show-and-call !reader-cold-init)
 226   (let ((*readtable* *standard-readtable*))
 227     (show-and-call !sharpm-cold-init)
 228     (show-and-call !backq-cold-init))
 229   (setf *readtable* (copy-readtable *standard-readtable*))
 230   (setf sb!debug:*debug-readtable* (copy-readtable *standard-readtable*))
 231   (sb!pretty:!pprint-cold-init)
 232
 233   ;; the ANSI-specified initial value of *PACKAGE*
 234   (setf *package* (find-package "COMMON-LISP-USER"))
 235   ;; FIXME: I'm not sure where it should be done, but CL-USER really
 236   ;; ought to USE-PACKAGE publicly accessible packages like SB-DEBUG
 237   ;; (for ARG and VAR), SB-EXT, SB-EXT-C-CALL, and SB-EXT-ALIEN so
 238   ;; that the user has a hint about which symbols we consider public.
 239   ;; (Perhaps SB-DEBUG wouldn't need to be in the list if ARG and VAR
 240   ;; could be typed directly, with no parentheses, at the debug prompt
 241   ;; the way that e.g. F or BACKTRACE can be?)
 242
 243   (/show0 "done initializing")
 244   (setf *cold-init-complete-p* t)
 245
 246   ;; The system is finally ready for GC.
 247   #!-gengc (setf *already-maybe-gcing* nil)
 248   (/show0 "enabling GC")
 249   (gc-on)
 250   (/show0 "doing first GC")
 251   (gc :full t)
 252   (/show0 "back from first GC")
 253
 254   ;; The show is on.
 255   (terpri)
 256   (/show0 "going into toplevel loop")
 257   (handling-end-of-the-world
 258     (toplevel-init)))
 259
 260 (defun quit (&key recklessly-p
 261                   (unix-code 0 unix-code-p)
 262                   (unix-status unix-code))
 263   #!+sb-doc
 264   "Terminate the current Lisp. Things are cleaned up (with UNWIND-PROTECT
 265   and so forth) unless RECKLESSLY-P is non-NIL. On UNIX-like systems,
 266   UNIX-STATUS is used as the status code."
 267   (declare (type (signed-byte 32) unix-code))
 268   ;; FIXME: UNIX-CODE was deprecated in sbcl-0.6.8, after having been
 269   ;; around for less than a year. It should be safe to remove it after
 270   ;; a year.
 271   (when unix-code-p
 272     (warn "The UNIX-CODE argument is deprecated. Use the UNIX-STATUS argument
 273 instead (which is another name for the same thing)."))
 274   (if recklessly-p
 275       (sb!unix:unix-exit unix-status)
 276       (throw '%end-of-the-world unix-status)))
 277 \f
 278 ;;;; initialization functions
 279
 280 (defun reinit ()
 281   (without-interrupts
 282     (without-gcing
 283       (os-cold-init-or-reinit)
 284       (stream-reinit)
 285       (signal-cold-init-or-reinit)
 286       (gc-cold-init-or-reinit)
 287       (setf (sb!alien:extern-alien "internal_errors_enabled" boolean) t)
 288       (set-floating-point-modes :traps
 289                                 '(:overflow
 290                                   :invalid
 291                                   :divide-by-zero
 292                                   ;; PRINT seems not to like x86 NPX
 293                                   ;; denormal floats like
 294                                   ;; LEAST-NEGATIVE-SINGLE-FLOAT, so
 295                                   ;; the :UNDERFLOW exceptions are
 296                                   ;; disabled by default. Joe User can
 297                                   ;; explicitly enable them if
 298                                   ;; desired.
 299                                   #!-x86 :underflow))
 300       ;; Clear pseudo atomic in case this core wasn't compiled with
 301       ;; support.
 302       ;;
 303       ;; FIXME: In SBCL our cores are always compiled with support. So
 304       ;; we don't need to do this, do we? At least not for this
 305       ;; reason.. (Perhaps we should do it anyway in case someone
 306       ;; manages to save an image from within a pseudo-atomic-atomic
 307       ;; operation?)
 308       #!+x86 (setf sb!impl::*pseudo-atomic-atomic* 0))
 309     (gc-on)))
 310 \f
 311 ;;;; some support for any hapless wretches who end up debugging cold
 312 ;;;; init code
 313
 314 ;;; Decode THING into hexadecimal notation using only machinery
 315 ;;; available early in cold init.
 316 #!+sb-show
 317 (defun hexstr (thing)
 318   (/show0 "entering HEXSTR")
 319   (let ((addr (sb!kernel:get-lisp-obj-address thing))
 320         (str (make-string 10)))
 321     (/show0 "ADDR and STR calculated")
 322     (setf (char str 0) #\0
 323           (char str 1) #\x)
 324     (/show0 "CHARs 0 and 1 set")
 325     (dotimes (i 8)
 326       (/show0 "at head of DOTIMES loop")
 327       (let* ((nibble (ldb (byte 4 0) addr))
 328              (chr (char "0123456789abcdef" nibble)))
 329         (declare (type (unsigned-byte 4) nibble)
 330                  (base-char chr))
 331         (/show0 "NIBBLE and CHR calculated")
 332         (setf (char str (- 9 i)) chr
 333               addr (ash addr -4))))
 334     str))
 335
 336 #!+sb-show
 337 (defun cold-print (x)
 338   (typecase x
 339     (simple-string (sb!sys:%primitive print x))
 340     (symbol (sb!sys:%primitive print (symbol-name x)))
 341     (list (let ((count 0))
 342             (sb!sys:%primitive print "list:")
 343             (dolist (i x)
 344               (when (>= (incf count) 4)
 345                 (sb!sys:%primitive print "...")
 346                 (return))
 347               (cold-print i))))
 348     (t (sb!sys:%primitive print (hexstr x)))))