src/code/cold-init.lisp

   1 ;;;; cold initialization stuff, plus some other miscellaneous stuff
   2 ;;;; that we don't have any better place for
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!IMPL")
  14 \f
  15 ;;;; burning our ships behind us
  16
  17 ;;; There's a fair amount of machinery which is needed only at cold
  18 ;;; init time, and should be discarded before freezing the final
  19 ;;; system. We discard it by uninterning the associated symbols.
  20 ;;; Rather than using a special table of symbols to be uninterned,
  21 ;;; which might be tedious to maintain, instead we use a hack:
  22 ;;; anything whose name matches a magic character pattern is
  23 ;;; uninterned.
  24 ;;;
  25 ;;; FIXME: Are there other tables that need to have entries removed?
  26 ;;; What about symbols of the form DEF!FOO?
  27 (defun !unintern-init-only-stuff ()
  28   (do ((any-changes? nil nil))
  29       (nil)
  30     (dolist (package (list-all-packages))
  31       (do-symbols (symbol package)
  32         (let ((name (symbol-name symbol)))
  33           (when (or (string= name "!" :end1 1 :end2 1)
  34                     (and (>= (length name) 2)
  35                          (string= name "*!" :end1 2 :end2 2)))
  36             (/show0 "uninterning cold-init-only symbol..")
  37             (/primitive-print name)
  38             ;; FIXME: Is this (FIRST (LAST *INFO-ENVIRONMENT*)) really
  39             ;; meant to be an idiom to use?  Is there a more obvious
  40             ;; name for this? [e.g. (GLOBAL-ENVIRONMENT)?]
  41             (do-info ((first (last *info-environment*))
  42                             :name entry :class class :type type)
  43               (when (eq entry symbol)
  44                 (clear-info class type entry)))
  45             (unintern symbol package)
  46             (setf any-changes? t)))))
  47     (unless any-changes?
  48       (return))))
  49 \f
  50 ;;;; putting ourselves out of our misery when things become too much to bear
  51
  52 (declaim (ftype (function (simple-string) nil) !cold-lose))
  53 (defun !cold-lose (msg)
  54   (%primitive print msg)
  55   (%primitive print "too early in cold init to recover from errors")
  56   (%halt))
  57
  58 ;;; last-ditch error reporting for things which should never happen
  59 ;;; and which, if they do happen, are sufficiently likely to torpedo
  60 ;;; the normal error-handling system that we want to bypass it
  61 (declaim (ftype (function (simple-string) nil) critically-unreachable))
  62 (defun critically-unreachable (where)
  63   (%primitive print "internal error: Control should never reach here, i.e.")
  64   (%primitive print where)
  65   (%halt))
  66 \f
  67 ;;;; !COLD-INIT
  68
  69 ;;; a list of toplevel things set by GENESIS
  70 (defvar *!reversed-cold-toplevels*)
  71
  72 ;;; a SIMPLE-VECTOR set by GENESIS
  73 (defvar *!load-time-values*)
  74
  75 (eval-when (:compile-toplevel :execute)
  76   ;; FIXME: Perhaps we should make SHOW-AND-CALL-AND-FMAKUNBOUND, too,
  77   ;; and use it for most of the cold-init functions. (Just be careful
  78   ;; not to use it for the COLD-INIT-OR-REINIT functions.)
  79   (sb!xc:defmacro show-and-call (name)
  80     `(progn
  81        (/primitive-print ,(symbol-name name))
  82        (,name))))
  83
  84 ;;; called when a cold system starts up
  85 (defun !cold-init ()
  86   #!+sb-doc "Give the world a shove and hope it spins."
  87
  88   (/show0 "entering !COLD-INIT")
  89
  90   ;; FIXME: It'd probably be cleaner to have most of the stuff here
  91   ;; handled by calls like !GC-COLD-INIT, !ERROR-COLD-INIT, and
  92   ;; !UNIX-COLD-INIT. And *TYPE-SYSTEM-INITIALIZED* could be changed to
  93   ;; *TYPE-SYSTEM-INITIALIZED-WHEN-BOUND* so that it doesn't need to
  94   ;; be explicitly set in order to be meaningful.
  95   (setf *after-gc-hooks* nil
  96         *gc-inhibit* t
  97         *gc-pending* nil
  98         #!+sb-thread *stop-for-gc-pending* #!+sb-thread nil
  99         sb!unix::*interrupts-enabled* t
 100         sb!unix::*interrupt-pending* nil
 101         *break-on-signals* nil
 102         *maximum-error-depth* 10
 103         *current-error-depth* 0
 104         *cold-init-complete-p* nil
 105         *type-system-initialized* nil)
 106
 107   ;; I'm not sure where eval is first called, so I put this first.
 108   #!+sb-eval
 109   (show-and-call sb!eval::!full-eval-cold-init)
 110
 111   (show-and-call thread-init-or-reinit)
 112   (show-and-call !typecheckfuns-cold-init)
 113
 114   ;; Anyone might call RANDOM to initialize a hash value or something;
 115   ;; and there's nothing which needs to be initialized in order for
 116   ;; this to be initialized, so we initialize it right away.
 117   (show-and-call !random-cold-init)
 118
 119   (show-and-call !character-database-cold-init)
 120   (show-and-call !character-name-database-cold-init)
 121
 122   (show-and-call !early-package-cold-init)
 123   (show-and-call !package-cold-init)
 124
 125   ;; All sorts of things need INFO and/or (SETF INFO).
 126   (/show0 "about to SHOW-AND-CALL !GLOBALDB-COLD-INIT")
 127   (show-and-call !globaldb-cold-init)
 128
 129   ;; This needs to be done early, but needs to be after INFO is
 130   ;; initialized.
 131   (show-and-call !function-names-cold-init)
 132   (show-and-call !fdefn-cold-init)
 133
 134   ;; Various toplevel forms call MAKE-ARRAY, which calls SUBTYPEP, so
 135   ;; the basic type machinery needs to be initialized before toplevel
 136   ;; forms run.
 137   (show-and-call !type-class-cold-init)
 138   (show-and-call !typedefs-cold-init)
 139   (show-and-call !classes-cold-init)
 140   (show-and-call !early-type-cold-init)
 141   (show-and-call !late-type-cold-init)
 142   (show-and-call !alien-type-cold-init)
 143   (show-and-call !target-type-cold-init)
 144   (show-and-call !vm-type-cold-init)
 145   ;; FIXME: It would be tidy to make sure that that these cold init
 146   ;; functions are called in the same relative order as the toplevel
 147   ;; forms of the corresponding source files.
 148
 149   ;;(show-and-call !package-cold-init)
 150   (show-and-call !policy-cold-init-or-resanify)
 151   (/show0 "back from !POLICY-COLD-INIT-OR-RESANIFY")
 152
 153   (show-and-call !constantp-cold-init)
 154   (show-and-call !early-proclaim-cold-init)
 155
 156   ;; KLUDGE: Why are fixups mixed up with toplevel forms? Couldn't
 157   ;; fixups be done separately? Wouldn't that be clearer and better?
 158   ;; -- WHN 19991204
 159   (/show0 "doing cold toplevel forms and fixups")
 160   (/show0 "(LISTP *!REVERSED-COLD-TOPLEVELS*)=..")
 161   (/hexstr (if (listp *!reversed-cold-toplevels*) "true" "NIL"))
 162   (/show0 "about to calculate (LENGTH *!REVERSED-COLD-TOPLEVELS*)")
 163   (/show0 "(LENGTH *!REVERSED-COLD-TOPLEVELS*)=..")
 164   #!+sb-show (let ((r-c-tl-length (length *!reversed-cold-toplevels*)))
 165                (/show0 "(length calculated..)")
 166                (let ((hexstr (hexstr r-c-tl-length)))
 167                  (/show0 "(hexstr calculated..)")
 168                  (/primitive-print hexstr)))
 169   (let (#!+sb-show (index-in-cold-toplevels 0))
 170     #!+sb-show (declare (type fixnum index-in-cold-toplevels))
 171
 172     (dolist (toplevel-thing (prog1
 173                                 (nreverse *!reversed-cold-toplevels*)
 174                               ;; (Now that we've NREVERSEd it, it's
 175                               ;; somewhat scrambled, so keep anyone
 176                               ;; else from trying to get at it.)
 177                               (makunbound '*!reversed-cold-toplevels*)))
 178       #!+sb-show
 179       (when (zerop (mod index-in-cold-toplevels 1024))
 180         (/show0 "INDEX-IN-COLD-TOPLEVELS=..")
 181         (/hexstr index-in-cold-toplevels))
 182       #!+sb-show
 183       (setf index-in-cold-toplevels
 184             (the fixnum (1+ index-in-cold-toplevels)))
 185       (typecase toplevel-thing
 186         (function
 187          (funcall toplevel-thing))
 188         (cons
 189          (case (first toplevel-thing)
 190            (:load-time-value
 191             (setf (svref *!load-time-values* (third toplevel-thing))
 192                   (funcall (second toplevel-thing))))
 193            (:load-time-value-fixup
 194             (setf (sap-ref-word (second toplevel-thing) 0)
 195                   (get-lisp-obj-address
 196                    (svref *!load-time-values* (third toplevel-thing)))))
 197            #!+(and (or x86 x86-64) gencgc)
 198            (:load-time-code-fixup
 199             (sb!vm::!envector-load-time-code-fixup (second toplevel-thing)
 200                                                    (third  toplevel-thing)
 201                                                    (fourth toplevel-thing)
 202                                                    (fifth  toplevel-thing)))
 203            (t
 204             (!cold-lose "bogus fixup code in *!REVERSED-COLD-TOPLEVELS*"))))
 205         (t (!cold-lose "bogus function in *!REVERSED-COLD-TOPLEVELS*")))))
 206   (/show0 "done with loop over cold toplevel forms and fixups")
 207
 208   ;; Set sane values again, so that the user sees sane values instead
 209   ;; of whatever is left over from the last DECLAIM/PROCLAIM.
 210   (show-and-call !policy-cold-init-or-resanify)
 211
 212   ;; Only do this after toplevel forms have run, 'cause that's where
 213   ;; DEFTYPEs are.
 214   (setf *type-system-initialized* t)
 215
 216   ;; now that the type system is definitely initialized, fixup UNKNOWN
 217   ;; types that have crept in.
 218   (show-and-call !fixup-type-cold-init)
 219   ;; run the PROCLAIMs.
 220   (show-and-call !late-proclaim-cold-init)
 221
 222   (show-and-call os-cold-init-or-reinit)
 223
 224   (show-and-call stream-cold-init-or-reset)
 225   (show-and-call !loader-cold-init)
 226   (show-and-call !foreign-cold-init)
 227   #!-win32 (show-and-call signal-cold-init-or-reinit)
 228   (/show0 "enabling internal errors")
 229   (setf (sb!alien:extern-alien "internal_errors_enabled" boolean) t)
 230
 231   ;; FIXME: This list of modes should be defined in one place and
 232   ;; explicitly shared between here and REINIT.
 233
 234   ;; FIXME: For some unknown reason, NetBSD/x86 won't run with the
 235   ;; :invalid trap enabled. That should be fixed, but not today...
 236   ;; PEM -- April 5, 2004
 237   (set-floating-point-modes
 238    :traps '(:overflow #!-netbsd :invalid :divide-by-zero))
 239
 240   (show-and-call !class-finalize)
 241
 242   ;; The reader and printer are initialized very late, so that they
 243   ;; can do hairy things like invoking the compiler as part of their
 244   ;; initialization.
 245   (show-and-call !reader-cold-init)
 246   (let ((*readtable* *standard-readtable*))
 247     (show-and-call !sharpm-cold-init)
 248     (show-and-call !backq-cold-init))
 249   (setf *readtable* (copy-readtable *standard-readtable*))
 250   (setf sb!debug:*debug-readtable* (copy-readtable *standard-readtable*))
 251   (sb!pretty:!pprint-cold-init)
 252
 253   ;; the ANSI-specified initial value of *PACKAGE*
 254   (setf *package* (find-package "COMMON-LISP-USER"))
 255
 256   (/show0 "done initializing, setting *COLD-INIT-COMPLETE-P*")
 257   (setf *cold-init-complete-p* t)
 258
 259   ;; The system is finally ready for GC.
 260   (/show0 "enabling GC")
 261   (gc-on)
 262   (/show0 "doing first GC")
 263   (gc :full t)
 264   (/show0 "back from first GC")
 265
 266   ;; The show is on.
 267   (terpri)
 268   (/show0 "going into toplevel loop")
 269   (handling-end-of-the-world
 270     (toplevel-init)
 271     (critically-unreachable "after TOPLEVEL-INIT")))
 272
 273 (defun quit (&key recklessly-p (unix-status 0))
 274   #!+sb-doc
 275   "Terminate the current Lisp. Things are cleaned up (with
 276 UNWIND-PROTECT and so forth) unless RECKLESSLY-P is non-NIL. On
 277 UNIX-like systems, UNIX-STATUS is used as the status code."
 278   (declare (type (signed-byte 32) unix-status))
 279   (/show0 "entering QUIT")
 280   (if recklessly-p
 281       (sb!unix:unix-exit unix-status)
 282       (throw '%end-of-the-world unix-status))
 283   (critically-unreachable "after trying to die in QUIT"))
 284 \f
 285 ;;;; initialization functions
 286
 287 (defun thread-init-or-reinit ()
 288   (sb!thread::init-initial-thread)
 289   (sb!thread::init-job-control)
 290   (sb!thread::get-foreground))
 291
 292 (defun reinit ()
 293   (setf *default-external-format* nil)
 294   (setf sb!alien::*default-c-string-external-format* nil)
 295   (without-interrupts
 296     (without-gcing
 297         (os-cold-init-or-reinit)
 298       (thread-init-or-reinit)
 299       (stream-reinit)
 300       #!-win32 (signal-cold-init-or-reinit)
 301       (setf (sb!alien:extern-alien "internal_errors_enabled" boolean) t)
 302       ;; PRINT seems not to like x86 NPX denormal floats like
 303       ;; LEAST-NEGATIVE-SINGLE-FLOAT, so the :UNDERFLOW exceptions are
 304       ;; disabled by default. Joe User can explicitly enable them if
 305       ;; desired.
 306       ;;
 307       ;; see also comment at the previous SET-FLOATING-POINT-MODES
 308       ;; call site.
 309       (set-floating-point-modes
 310        :traps '(:overflow #!-netbsd :invalid :divide-by-zero))))
 311   (gc-reinit)
 312   ;; make sure TIME works correctly from saved cores
 313   (setf *internal-real-time-base-seconds* nil)
 314   (setf *gc-run-time* 0)
 315   (foreign-reinit)
 316   ;; If the debugger was disabled in the saved core, we need to
 317   ;; re-disable ldb again.
 318   (when (eq *invoke-debugger-hook* 'sb!debug::debugger-disabled-hook)
 319     (sb!debug::disable-debugger))
 320   (dolist (hook *init-hooks*)
 321     (with-simple-restart (continue "Skip this initialization hook.")
 322       (funcall hook))))
 323 \f
 324 ;;;; some support for any hapless wretches who end up debugging cold
 325 ;;;; init code
 326
 327 ;;; Decode THING into hexadecimal notation using only machinery
 328 ;;; available early in cold init.
 329 #!+sb-show
 330 (defun hexstr (thing)
 331   (/noshow0 "entering HEXSTR")
 332   (let ((addr (get-lisp-obj-address thing))
 333         (str (make-string 10 :element-type 'base-char)))
 334     (/noshow0 "ADDR and STR calculated")
 335     (setf (char str 0) #\0
 336           (char str 1) #\x)
 337     (/noshow0 "CHARs 0 and 1 set")
 338     (dotimes (i 8)
 339       (/noshow0 "at head of DOTIMES loop")
 340       (let* ((nibble (ldb (byte 4 0) addr))
 341              (chr (char "0123456789abcdef" nibble)))
 342         (declare (type (unsigned-byte 4) nibble)
 343                  (base-char chr))
 344         (/noshow0 "NIBBLE and CHR calculated")
 345         (setf (char str (- 9 i)) chr
 346               addr (ash addr -4))))
 347     str))
 348
 349 #!+sb-show
 350 (defun cold-print (x)
 351   (typecase x
 352     (simple-string (sb!sys:%primitive print x))
 353     (symbol (sb!sys:%primitive print (symbol-name x)))
 354     (list (let ((count 0))
 355             (sb!sys:%primitive print "list:")
 356             (dolist (i x)
 357               (when (>= (incf count) 4)
 358                 (sb!sys:%primitive print "...")
 359                 (return))
 360               (cold-print i))))
 361     (t (sb!sys:%primitive print (hexstr x)))))