src/code/condition.lisp

   1 ;;;; stuff originally from CMU CL's error.lisp which can or should
   2 ;;;; come late (mostly related to the CONDITION class itself)
   3 ;;;;
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!KERNEL")
  15 \f
  16 ;;;; the CONDITION class
  17
  18 (/show0 "condition.lisp 20")
  19
  20 (eval-when (:compile-toplevel :load-toplevel :execute)
  21
  22 (/show0 "condition.lisp 24")
  23
  24 (def!struct (condition-classoid (:include slot-classoid)
  25                                 (:constructor make-condition-classoid))
  26   ;; list of CONDITION-SLOT structures for the direct slots of this
  27   ;; class
  28   (slots nil :type list)
  29   ;; list of CONDITION-SLOT structures for all of the effective class
  30   ;; slots of this class
  31   (class-slots nil :type list)
  32   ;; report function or NIL
  33   (report nil :type (or function null))
  34   ;; list of alternating initargs and initforms
  35   (default-initargs () :type list)
  36   ;; class precedence list as a list of CLASS objects, with all
  37   ;; non-CONDITION classes removed
  38   (cpl () :type list)
  39   ;; a list of all the effective instance allocation slots of this
  40   ;; class that have a non-constant initform or default-initarg.
  41   ;; Values for these slots must be computed in the dynamic
  42   ;; environment of MAKE-CONDITION.
  43   (hairy-slots nil :type list))
  44
  45 (/show0 "condition.lisp 49")
  46
  47 ) ; EVAL-WHEN
  48
  49 (!defstruct-with-alternate-metaclass condition
  50   :slot-names (actual-initargs assigned-slots)
  51   :boa-constructor %make-condition-object
  52   :superclass-name instance
  53   :metaclass-name condition-classoid
  54   :metaclass-constructor make-condition-classoid
  55   :dd-type structure)
  56
  57 (defun make-condition-object (actual-initargs)
  58   (%make-condition-object actual-initargs nil))
  59
  60 (defstruct (condition-slot (:copier nil))
  61   (name (missing-arg) :type symbol)
  62   ;; list of all applicable initargs
  63   (initargs (missing-arg) :type list)
  64   ;; names of reader and writer functions
  65   (readers (missing-arg) :type list)
  66   (writers (missing-arg) :type list)
  67   ;; true if :INITFORM was specified
  68   (initform-p (missing-arg) :type (member t nil))
  69   ;; If this is a function, call it with no args. Otherwise, it's the
  70   ;; actual value.
  71   (initform (missing-arg) :type t)
  72   ;; allocation of this slot, or NIL until defaulted
  73   (allocation nil :type (member :instance :class nil))
  74   ;; If ALLOCATION is :CLASS, this is a cons whose car holds the value.
  75   (cell nil :type (or cons null))
  76   ;; slot documentation
  77   (documentation nil :type (or string null)))
  78
  79 ;;; KLUDGE: It's not clear to me why CONDITION-CLASS has itself listed
  80 ;;; in its CPL, while other classes derived from CONDITION-CLASS don't
  81 ;;; have themselves listed in their CPLs. This behavior is inherited
  82 ;;; from CMU CL, and didn't seem to be explained there, and I haven't
  83 ;;; figured out whether it's right. -- WHN 19990612
  84 (eval-when (:compile-toplevel :load-toplevel :execute)
  85   (/show0 "condition.lisp 103")
  86   (let ((condition-class (locally
  87                            ;; KLUDGE: There's a DEFTRANSFORM
  88                            ;; FIND-CLASSOID for constant class names
  89                            ;; which creates fast but
  90                            ;; non-cold-loadable, non-compact code. In
  91                            ;; this context, we'd rather have compact,
  92                            ;; cold-loadable code. -- WHN 19990928
  93                            (declare (notinline find-classoid))
  94                            (find-classoid 'condition))))
  95     (setf (condition-classoid-cpl condition-class)
  96           (list condition-class)))
  97   (/show0 "condition.lisp 103"))
  98
  99 (setf (condition-classoid-report (locally
 100                                    ;; KLUDGE: There's a DEFTRANSFORM
 101                                    ;; FIND-CLASSOID for constant class
 102                                    ;; names which creates fast but
 103                                    ;; non-cold-loadable, non-compact
 104                                    ;; code. In this context, we'd
 105                                    ;; rather have compact,
 106                                    ;; cold-loadable code. -- WHN
 107                                    ;; 19990928
 108                                    (declare (notinline find-classoid))
 109                                    (find-classoid 'condition)))
 110       (lambda (cond stream)
 111         (format stream "Condition ~S was signalled." (type-of cond))))
 112
 113 (eval-when (:compile-toplevel :load-toplevel :execute)
 114
 115 (defun find-condition-layout (name parent-types)
 116   (let* ((cpl (remove-duplicates
 117                (reverse
 118                 (reduce #'append
 119                         (mapcar (lambda (x)
 120                                   (condition-classoid-cpl
 121                                    (find-classoid x)))
 122                                 parent-types)))))
 123          (cond-layout (info :type :compiler-layout 'condition))
 124          (olayout (info :type :compiler-layout name))
 125          ;; FIXME: Does this do the right thing in case of multiple
 126          ;; inheritance? A quick look at DEFINE-CONDITION didn't make
 127          ;; it obvious what ANSI intends to be done in the case of
 128          ;; multiple inheritance, so it's not actually clear what the
 129          ;; right thing is..
 130          (new-inherits
 131           (order-layout-inherits (concatenate 'simple-vector
 132                                               (layout-inherits cond-layout)
 133                                               (mapcar #'classoid-layout cpl)))))
 134     (if (and olayout
 135              (not (mismatch (layout-inherits olayout) new-inherits)))
 136         olayout
 137         (make-layout :classoid (make-undefined-classoid name)
 138                      :inherits new-inherits
 139                      :depthoid -1
 140                      :length (layout-length cond-layout)))))
 141
 142 ) ; EVAL-WHEN
 143
 144 ;;; FIXME: ANSI's definition of DEFINE-CONDITION says
 145 ;;;   Condition reporting is mediated through the PRINT-OBJECT method
 146 ;;;   for the condition type in question, with *PRINT-ESCAPE* always
 147 ;;;   being nil. Specifying (:REPORT REPORT-NAME) in the definition of
 148 ;;;   a condition type C is equivalent to:
 149 ;;;     (defmethod print-object ((x c) stream)
 150 ;;;       (if *print-escape* (call-next-method) (report-name x stream)))
 151 ;;; The current code doesn't seem to quite match that.
 152 (def!method print-object ((x condition) stream)
 153   (if *print-escape*
 154       (print-unreadable-object (x stream :type t :identity t))
 155       ;; KLUDGE: A comment from CMU CL here said
 156       ;;   7/13/98 BUG? CPL is not sorted and results here depend on order of
 157       ;;   superclasses in define-condition call!
 158       (dolist (class (condition-classoid-cpl (classoid-of x))
 159                      (error "no REPORT? shouldn't happen!"))
 160         (let ((report (condition-classoid-report class)))
 161           (when report
 162             (return (funcall report x stream)))))))
 163 \f
 164 ;;;; slots of CONDITION objects
 165
 166 (defvar *empty-condition-slot* '(empty))
 167
 168 (defun find-slot-default (class slot)
 169   (let ((initargs (condition-slot-initargs slot))
 170         (cpl (condition-classoid-cpl class)))
 171     (dolist (class cpl)
 172       (let ((default-initargs (condition-classoid-default-initargs class)))
 173         (dolist (initarg initargs)
 174           (let ((val (getf default-initargs initarg *empty-condition-slot*)))
 175             (unless (eq val *empty-condition-slot*)
 176               (return-from find-slot-default
 177                            (if (functionp val)
 178                                (funcall val)
 179                                val)))))))
 180
 181     (if (condition-slot-initform-p slot)
 182         (let ((initform (condition-slot-initform slot)))
 183           (if (functionp initform)
 184               (funcall initform)
 185               initform))
 186         (error "unbound condition slot: ~S" (condition-slot-name slot)))))
 187
 188 (defun find-condition-class-slot (condition-class slot-name)
 189   (dolist (sclass
 190            (condition-classoid-cpl condition-class)
 191            (error "There is no slot named ~S in ~S."
 192                   slot-name condition-class))
 193     (dolist (slot (condition-classoid-slots sclass))
 194       (when (eq (condition-slot-name slot) slot-name)
 195         (return-from find-condition-class-slot slot)))))
 196
 197 (defun condition-writer-function (condition new-value name)
 198   (dolist (cslot (condition-classoid-class-slots
 199                   (layout-classoid (%instance-layout condition)))
 200                  (setf (getf (condition-assigned-slots condition) name)
 201                        new-value))
 202     (when (eq (condition-slot-name cslot) name)
 203       (return (setf (car (condition-slot-cell cslot)) new-value)))))
 204
 205 (defun condition-reader-function (condition name)
 206   (let ((class (layout-classoid (%instance-layout condition))))
 207     (dolist (cslot (condition-classoid-class-slots class))
 208       (when (eq (condition-slot-name cslot) name)
 209         (return-from condition-reader-function
 210                      (car (condition-slot-cell cslot)))))
 211     (let ((val (getf (condition-assigned-slots condition) name
 212                      *empty-condition-slot*)))
 213       (if (eq val *empty-condition-slot*)
 214           (let ((actual-initargs (condition-actual-initargs condition))
 215                 (slot (find-condition-class-slot class name)))
 216             (unless slot
 217               (error "missing slot ~S of ~S" name condition))
 218             (do ((initargs actual-initargs (cddr initargs)))
 219                 ((endp initargs)
 220                  (setf (getf (condition-assigned-slots condition) name)
 221                        (find-slot-default class slot)))
 222               (when (member (car initargs) (condition-slot-initargs slot))
 223                 (return-from condition-reader-function
 224                   (setf (getf (condition-assigned-slots condition)
 225                               name)
 226                         (cadr initargs))))))
 227           val))))
 228 \f
 229 ;;;; MAKE-CONDITION
 230
 231 (defun make-condition (thing &rest args)
 232   #!+sb-doc
 233   "Make an instance of a condition object using the specified initargs."
 234   ;; Note: ANSI specifies no exceptional situations in this function.
 235   ;; signalling simple-type-error would not be wrong.
 236   (let* ((thing (if (symbolp thing)
 237                     (find-classoid thing)
 238                     thing))
 239          (class (typecase thing
 240                   (condition-classoid thing)
 241                   (classoid
 242                    (error 'simple-type-error
 243                           :datum thing
 244                           :expected-type 'condition-class
 245                           :format-control "~S is not a condition class."
 246                           :format-arguments (list thing)))
 247                   (t
 248                    (error 'simple-type-error
 249                           :datum thing
 250                           :expected-type 'condition-class
 251                           :format-control "bad thing for class argument:~%  ~S"
 252                           :format-arguments (list thing)))))
 253          (res (make-condition-object args)))
 254     (setf (%instance-layout res) (classoid-layout class))
 255     ;; Set any class slots with initargs present in this call.
 256     (dolist (cslot (condition-classoid-class-slots class))
 257       (dolist (initarg (condition-slot-initargs cslot))
 258         (let ((val (getf args initarg *empty-condition-slot*)))
 259           (unless (eq val *empty-condition-slot*)
 260             (setf (car (condition-slot-cell cslot)) val)))))
 261     ;; Default any slots with non-constant defaults now.
 262     (dolist (hslot (condition-classoid-hairy-slots class))
 263       (when (dolist (initarg (condition-slot-initargs hslot) t)
 264               (unless (eq (getf args initarg *empty-condition-slot*)
 265                           *empty-condition-slot*)
 266                 (return nil)))
 267         (setf (getf (condition-assigned-slots res) (condition-slot-name hslot))
 268               (find-slot-default class hslot))))
 269
 270     res))
 271 \f
 272 ;;;; DEFINE-CONDITION
 273
 274 (eval-when (:compile-toplevel :load-toplevel :execute)
 275 (defun %compiler-define-condition (name direct-supers layout
 276                                    all-readers all-writers)
 277   (sb!xc:proclaim `(ftype (function (t) t) ,@all-readers))
 278   (sb!xc:proclaim `(ftype (function (t t) t) ,@all-writers))
 279   (multiple-value-bind (class old-layout)
 280       (insured-find-classoid name
 281                              #'condition-classoid-p
 282                              #'make-condition-classoid)
 283     (setf (layout-classoid layout) class)
 284     (setf (classoid-direct-superclasses class)
 285           (mapcar #'find-classoid direct-supers))
 286     (cond ((not old-layout)
 287            (register-layout layout))
 288           ((not *type-system-initialized*)
 289            (setf (layout-classoid old-layout) class)
 290            (setq layout old-layout)
 291            (unless (eq (classoid-layout class) layout)
 292              (register-layout layout)))
 293           ((redefine-layout-warning "current"
 294                                     old-layout
 295                                     "new"
 296                                     (layout-length layout)
 297                                     (layout-inherits layout)
 298                                     (layout-depthoid layout))
 299            (register-layout layout :invalidate t))
 300           ((not (classoid-layout class))
 301            (register-layout layout)))
 302
 303     (setf (layout-info layout)
 304           (locally
 305             ;; KLUDGE: There's a FIND-CLASS DEFTRANSFORM for constant class
 306             ;; names which creates fast but non-cold-loadable, non-compact
 307             ;; code. In this context, we'd rather have compact, cold-loadable
 308             ;; code. -- WHN 19990928
 309             (declare (notinline find-classoid))
 310             (layout-info (classoid-layout (find-classoid 'condition)))))
 311
 312     (setf (find-classoid name) class)
 313
 314     ;; Initialize CPL slot.
 315     (setf (condition-classoid-cpl class)
 316           (remove-if-not #'condition-classoid-p
 317                          (std-compute-class-precedence-list class))))
 318   (values))
 319 ) ; EVAL-WHEN
 320
 321 ;;; Compute the effective slots of CLASS, copying inherited slots and
 322 ;;; destructively modifying direct slots.
 323 ;;;
 324 ;;; FIXME: It'd be nice to explain why it's OK to destructively modify
 325 ;;; direct slots. Presumably it follows from the semantics of
 326 ;;; inheritance and redefinition of conditions, but finding the cite
 327 ;;; and documenting it here would be good. (Or, if this is not in fact
 328 ;;; ANSI-compliant, fixing it would also be good.:-)
 329 (defun compute-effective-slots (class)
 330   (collect ((res (copy-list (condition-classoid-slots class))))
 331     (dolist (sclass (cdr (condition-classoid-cpl class)))
 332       (dolist (sslot (condition-classoid-slots sclass))
 333         (let ((found (find (condition-slot-name sslot) (res)
 334                            :key #'condition-slot-name)))
 335           (cond (found
 336                  (setf (condition-slot-initargs found)
 337                        (union (condition-slot-initargs found)
 338                               (condition-slot-initargs sslot)))
 339                  (unless (condition-slot-initform-p found)
 340                    (setf (condition-slot-initform-p found)
 341                          (condition-slot-initform-p sslot))
 342                    (setf (condition-slot-initform found)
 343                          (condition-slot-initform sslot)))
 344                  (unless (condition-slot-allocation found)
 345                    (setf (condition-slot-allocation found)
 346                          (condition-slot-allocation sslot))))
 347                 (t
 348                  (res (copy-structure sslot)))))))
 349     (res)))
 350
 351 ;;; Early definitions of slot accessor creators.
 352 ;;;
 353 ;;; Slot accessors must be generic functions, but ANSI does not seem
 354 ;;; to specify any of them, and we cannot support it before end of
 355 ;;; warm init. So we use ordinary functions inside SBCL, and switch to
 356 ;;; GFs only at the end of building.
 357 (declaim (notinline install-condition-slot-reader
 358                     install-condition-slot-writer))
 359 (defun install-condition-slot-reader (name condition slot-name)
 360   (declare (ignore condition))
 361   (setf (fdefinition name)
 362         (lambda (condition)
 363           (condition-reader-function condition slot-name))))
 364 (defun install-condition-slot-writer (name condition slot-name)
 365   (declare (ignore condition))
 366   (setf (fdefinition name)
 367         (lambda (new-value condition)
 368           (condition-writer-function condition new-value slot-name))))
 369
 370 (defun %define-condition (name parent-types layout slots documentation
 371                           report default-initargs all-readers all-writers)
 372   (%compiler-define-condition name parent-types layout all-readers all-writers)
 373   (let ((class (find-classoid name)))
 374     (setf (condition-classoid-slots class) slots)
 375     (setf (condition-classoid-report class) report)
 376     (setf (condition-classoid-default-initargs class) default-initargs)
 377     (setf (fdocumentation name 'type) documentation)
 378
 379     (dolist (slot slots)
 380
 381       ;; Set up reader and writer functions.
 382       (let ((slot-name (condition-slot-name slot)))
 383         (dolist (reader (condition-slot-readers slot))
 384           (install-condition-slot-reader reader name slot-name))
 385         (dolist (writer (condition-slot-writers slot))
 386           (install-condition-slot-writer writer name slot-name))))
 387
 388     ;; Compute effective slots and set up the class and hairy slots
 389     ;; (subsets of the effective slots.)
 390     (let ((eslots (compute-effective-slots class))
 391           (e-def-initargs
 392            (reduce #'append
 393                    (mapcar #'condition-classoid-default-initargs
 394                            (condition-classoid-cpl class)))))
 395       (dolist (slot eslots)
 396         (ecase (condition-slot-allocation slot)
 397           (:class
 398            (unless (condition-slot-cell slot)
 399              (setf (condition-slot-cell slot)
 400                    (list (if (condition-slot-initform-p slot)
 401                              (let ((initform (condition-slot-initform slot)))
 402                                (if (functionp initform)
 403                                    (funcall initform)
 404                                    initform))
 405                              *empty-condition-slot*))))
 406            (push slot (condition-classoid-class-slots class)))
 407           ((:instance nil)
 408            (setf (condition-slot-allocation slot) :instance)
 409            (when (or (functionp (condition-slot-initform slot))
 410                      (dolist (initarg (condition-slot-initargs slot) nil)
 411                        (when (functionp (getf e-def-initargs initarg))
 412                          (return t))))
 413              (push slot (condition-classoid-hairy-slots class))))))))
 414   name)
 415
 416 (defmacro define-condition (name (&rest parent-types) (&rest slot-specs)
 417                                  &body options)
 418   #!+sb-doc
 419   "DEFINE-CONDITION Name (Parent-Type*) (Slot-Spec*) Option*
 420    Define NAME as a condition type. This new type inherits slots and its
 421    report function from the specified PARENT-TYPEs. A slot spec is a list of:
 422      (slot-name :reader <rname> :initarg <iname> {Option Value}*
 423
 424    The DEFINE-CLASS slot options :ALLOCATION, :INITFORM, [slot] :DOCUMENTATION
 425    and :TYPE and the overall options :DEFAULT-INITARGS and
 426    [type] :DOCUMENTATION are also allowed.
 427
 428    The :REPORT option is peculiar to DEFINE-CONDITION. Its argument is either
 429    a string or a two-argument lambda or function name. If a function, the
 430    function is called with the condition and stream to report the condition.
 431    If a string, the string is printed.
 432
 433    Condition types are classes, but (as allowed by ANSI and not as described in
 434    CLtL2) are neither STANDARD-OBJECTs nor STRUCTURE-OBJECTs. WITH-SLOTS and
 435    SLOT-VALUE may not be used on condition objects."
 436   (let* ((parent-types (or parent-types '(condition)))
 437          (layout (find-condition-layout name parent-types))
 438          (documentation nil)
 439          (report nil)
 440          (default-initargs ()))
 441     (collect ((slots)
 442               (all-readers nil append)
 443               (all-writers nil append))
 444       (dolist (spec slot-specs)
 445         (when (keywordp spec)
 446           (warn "Keyword slot name indicates probable syntax error:~%  ~S"
 447                 spec))
 448         (let* ((spec (if (consp spec) spec (list spec)))
 449                (slot-name (first spec))
 450                (allocation :instance)
 451                (initform-p nil)
 452                documentation
 453                initform)
 454           (collect ((initargs)
 455                     (readers)
 456                     (writers))
 457             (do ((options (rest spec) (cddr options)))
 458                 ((null options))
 459               (unless (and (consp options) (consp (cdr options)))
 460                 (error "malformed condition slot spec:~%  ~S." spec))
 461               (let ((arg (second options)))
 462                 (case (first options)
 463                   (:reader (readers arg))
 464                   (:writer (writers arg))
 465                   (:accessor
 466                    (readers arg)
 467                    (writers `(setf ,arg)))
 468                   (:initform
 469                    (when initform-p
 470                      (error "more than one :INITFORM in ~S" spec))
 471                    (setq initform-p t)
 472                    (setq initform arg))
 473                   (:initarg (initargs arg))
 474                   (:allocation
 475                    (setq allocation arg))
 476                   (:documentation
 477                    (when documentation
 478                      (error "more than one :DOCUMENTATION in ~S" spec))
 479                    (unless (stringp arg)
 480                      (error "slot :DOCUMENTATION argument is not a string: ~S"
 481                             arg))
 482                    (setq documentation arg))
 483                   (:type)
 484                   (t
 485                    (error "unknown slot option:~%  ~S" (first options))))))
 486
 487             (all-readers (readers))
 488             (all-writers (writers))
 489             (slots `(make-condition-slot
 490                      :name ',slot-name
 491                      :initargs ',(initargs)
 492                      :readers ',(readers)
 493                      :writers ',(writers)
 494                      :initform-p ',initform-p
 495                      :documentation ',documentation
 496                      :initform
 497                      ,(if (constantp initform)
 498                           `',(eval initform)
 499                           `#'(lambda () ,initform)))))))
 500
 501       (dolist (option options)
 502         (unless (consp option)
 503           (error "bad option:~%  ~S" option))
 504         (case (first option)
 505           (:documentation (setq documentation (second option)))
 506           (:report
 507            (let ((arg (second option)))
 508              (setq report
 509                    (if (stringp arg)
 510                        `#'(lambda (condition stream)
 511                           (declare (ignore condition))
 512                           (write-string ,arg stream))
 513                        `#'(lambda (condition stream)
 514                           (funcall #',arg condition stream))))))
 515           (:default-initargs
 516            (do ((initargs (rest option) (cddr initargs)))
 517                ((endp initargs))
 518              (let ((val (second initargs)))
 519                (setq default-initargs
 520                      (list* `',(first initargs)
 521                             (if (constantp val)
 522                                 `',(eval val)
 523                                 `#'(lambda () ,val))
 524                             default-initargs)))))
 525           (t
 526            (error "unknown option: ~S" (first option)))))
 527
 528       `(progn
 529          (eval-when (:compile-toplevel)
 530            (%compiler-define-condition ',name ',parent-types ',layout
 531                                        ',(all-readers) ',(all-writers)))
 532          (eval-when (:load-toplevel :execute)
 533            (%define-condition ',name
 534                               ',parent-types
 535                               ',layout
 536                               (list ,@(slots))
 537                               ,documentation
 538                               ,report
 539                               (list ,@default-initargs)
 540                               ',(all-readers)
 541                               ',(all-writers)))))))
 542 \f
 543 ;;;; DESCRIBE on CONDITIONs
 544
 545 ;;; a function to be used as the guts of DESCRIBE-OBJECT (CONDITION T)
 546 ;;; eventually (once we get CLOS up and running so that we can define
 547 ;;; methods)
 548 (defun describe-condition (condition stream)
 549   (format stream
 550           "~&~@<~S ~_is a ~S. ~_Its slot values are ~_~S.~:>~%"
 551           condition
 552           (type-of condition)
 553           (concatenate 'list
 554                        (condition-actual-initargs condition)
 555                        (condition-assigned-slots condition))))
 556 \f
 557 ;;;; various CONDITIONs specified by ANSI
 558
 559 (define-condition serious-condition (condition) ())
 560
 561 (define-condition error (serious-condition) ())
 562
 563 (define-condition warning (condition) ())
 564 (define-condition style-warning (warning) ())
 565
 566 (defun simple-condition-printer (condition stream)
 567   (apply #'format
 568          stream
 569          (simple-condition-format-control condition)
 570          (simple-condition-format-arguments condition)))
 571
 572 (define-condition simple-condition ()
 573   ((format-control :reader simple-condition-format-control
 574                    :initarg :format-control
 575                    :type format-control)
 576    (format-arguments :reader simple-condition-format-arguments
 577                      :initarg :format-arguments
 578                      :initform '()
 579                      :type list))
 580   (:report simple-condition-printer))
 581
 582 (define-condition simple-warning (simple-condition warning) ())
 583
 584 (define-condition simple-error (simple-condition error) ())
 585
 586 (define-condition storage-condition (serious-condition) ())
 587
 588 (define-condition type-error (error)
 589   ((datum :reader type-error-datum :initarg :datum)
 590    (expected-type :reader type-error-expected-type :initarg :expected-type))
 591   (:report
 592    (lambda (condition stream)
 593      (format stream
 594              "~@<The value ~2I~:_~S ~I~_is not of type ~2I~_~S.~:>"
 595              (type-error-datum condition)
 596              (type-error-expected-type condition)))))
 597
 598 (define-condition simple-type-error (simple-condition type-error) ())
 599
 600 (define-condition program-error (error) ())
 601 (define-condition parse-error   (error) ())
 602 (define-condition control-error (error) ())
 603 (define-condition stream-error  (error)
 604   ((stream :reader stream-error-stream :initarg :stream)))
 605
 606 (define-condition end-of-file (stream-error) ()
 607   (:report
 608    (lambda (condition stream)
 609      (format stream
 610              "end of file on ~S"
 611              (stream-error-stream condition)))))
 612
 613 (define-condition file-error (error)
 614   ((pathname :reader file-error-pathname :initarg :pathname))
 615   (:report
 616    (lambda (condition stream)
 617      (format stream "error on file ~S" (file-error-pathname condition)))))
 618
 619 (define-condition package-error (error)
 620   ((package :reader package-error-package :initarg :package)))
 621
 622 (define-condition cell-error (error)
 623   ((name :reader cell-error-name :initarg :name)))
 624
 625 (define-condition unbound-variable (cell-error) ()
 626   (:report
 627    (lambda (condition stream)
 628      (format stream
 629              "The variable ~S is unbound."
 630              (cell-error-name condition)))))
 631
 632 (define-condition undefined-function (cell-error) ()
 633   (:report
 634    (lambda (condition stream)
 635      (format stream
 636              "The function ~S is undefined."
 637              (cell-error-name condition)))))
 638
 639 (define-condition special-form-function (undefined-function) ()
 640   (:report
 641    (lambda (condition stream)
 642      (format stream
 643              "Cannot FUNCALL the SYMBOL-FUNCTION of special operator ~S."
 644              (cell-error-name condition)))))
 645
 646 (define-condition arithmetic-error (error)
 647   ((operation :reader arithmetic-error-operation
 648               :initarg :operation
 649               :initform nil)
 650    (operands :reader arithmetic-error-operands
 651              :initarg :operands))
 652   (:report (lambda (condition stream)
 653              (format stream
 654                      "arithmetic error ~S signalled"
 655                      (type-of condition))
 656              (when (arithmetic-error-operation condition)
 657                (format stream
 658                        "~%Operation was ~S, operands ~S."
 659                        (arithmetic-error-operation condition)
 660                        (arithmetic-error-operands condition))))))
 661
 662 (define-condition division-by-zero         (arithmetic-error) ())
 663 (define-condition floating-point-overflow  (arithmetic-error) ())
 664 (define-condition floating-point-underflow (arithmetic-error) ())
 665 (define-condition floating-point-inexact   (arithmetic-error) ())
 666 (define-condition floating-point-invalid-operation (arithmetic-error) ())
 667
 668 (define-condition print-not-readable (error)
 669   ((object :reader print-not-readable-object :initarg :object))
 670   (:report
 671    (lambda (condition stream)
 672      (let ((obj (print-not-readable-object condition))
 673            (*print-array* nil))
 674        (format stream "~S cannot be printed readably." obj)))))
 675
 676 (define-condition reader-error (parse-error stream-error)
 677   ((format-control
 678     :reader reader-error-format-control
 679     :initarg :format-control)
 680    (format-arguments
 681     :reader reader-error-format-arguments
 682     :initarg :format-arguments
 683     :initform '()))
 684   (:report
 685    (lambda (condition stream)
 686      (let* ((error-stream (stream-error-stream condition))
 687             (pos (file-position error-stream)))
 688        (let (lineno colno)
 689          (when (and pos
 690                     (< pos sb!xc:array-dimension-limit)
 691                     ;; KLUDGE: lseek() (which is what FILE-POSITION
 692                     ;; reduces to on file-streams) is undefined on
 693                     ;; "some devices", which in practice means that it
 694                     ;; can claim to succeed on /dev/stdin on Darwin
 695                     ;; and Solaris.  This is obviously bad news,
 696                     ;; because the READ-SEQUENCE below will then
 697                     ;; block, not complete, and the report will never
 698                     ;; be printed.  As a workaround, we exclude
 699                     ;; interactive streams from this attempt to report
 700                     ;; positions.  -- CSR, 2003-08-21
 701                     (not (interactive-stream-p error-stream))
 702                     (file-position error-stream :start))
 703            (let ((string
 704                   (make-string pos
 705                                :element-type (stream-element-type error-stream))))
 706              (when (= pos (read-sequence string error-stream))
 707                (setq lineno (1+ (count #\Newline string))
 708                      colno (- pos
 709                               (or (position #\Newline string :from-end t) -1)
 710                               1))))
 711            (file-position error-stream pos))
 712          (format stream
 713                  "READER-ERROR ~@[at ~W ~]~
 714                   ~@[(line ~W~]~@[, column ~W) ~]~
 715                   on ~S:~%~?"
 716                  pos lineno colno error-stream
 717                  (reader-error-format-control condition)
 718                  (reader-error-format-arguments condition)))))))
 719 \f
 720 ;;;; various other (not specified by ANSI) CONDITIONs
 721 ;;;;
 722 ;;;; These might logically belong in other files; they're here, after
 723 ;;;; setup of CONDITION machinery, only because that makes it easier to
 724 ;;;; get cold init to work.
 725
 726 (define-condition simple-style-warning (simple-condition style-warning) ())
 727
 728 (define-condition values-type-error (type-error)
 729   ()
 730   (:report
 731    (lambda (condition stream)
 732      (format stream
 733              "~@<The values set ~2I~:_[~{~S~^ ~}] ~I~_is not of type ~2I~_~S.~:>"
 734              (type-error-datum condition)
 735              (type-error-expected-type condition)))))
 736
 737 ;;; KLUDGE: a condition for floating point errors when we can't or
 738 ;;; won't figure out what type they are. (In FreeBSD and OpenBSD we
 739 ;;; don't know how, at least as of sbcl-0.6.7; in Linux we probably
 740 ;;; know how but the old code was broken by the conversion to POSIX
 741 ;;; signal handling and hasn't been fixed as of sbcl-0.6.7.)
 742 ;;;
 743 ;;; FIXME: Perhaps this should also be a base class for all
 744 ;;; floating point exceptions?
 745 (define-condition floating-point-exception (arithmetic-error)
 746   ((flags :initarg :traps
 747           :initform nil
 748           :reader floating-point-exception-traps))
 749   (:report (lambda (condition stream)
 750              (format stream
 751                      "An arithmetic error ~S was signalled.~%"
 752                      (type-of condition))
 753              (let ((traps (floating-point-exception-traps condition)))
 754                (if traps
 755                    (format stream
 756                            "Trapping conditions are: ~%~{ ~S~^~}~%"
 757                            traps)
 758                    (write-line
 759                     "No traps are enabled? How can this be?"
 760                     stream))))))
 761
 762 (define-condition index-too-large-error (type-error)
 763   ()
 764   (:report
 765    (lambda (condition stream)
 766      (format stream
 767              "The index ~S is too large."
 768              (type-error-datum condition)))))
 769
 770 (define-condition bounding-indices-bad-error (type-error)
 771   ((object :reader bounding-indices-bad-object :initarg :object))
 772   (:report
 773    (lambda (condition stream)
 774      (let* ((datum (type-error-datum condition))
 775             (start (car datum))
 776             (end (cdr datum))
 777             (object (bounding-indices-bad-object condition)))
 778        (etypecase object
 779          (sequence
 780           (format stream
 781                   "The bounding indices ~S and ~S are bad for a sequence of length ~S."
 782                   start end (length object)))
 783          (array
 784           ;; from WITH-ARRAY-DATA
 785           (format stream
 786                   "The START and END parameters ~S and ~S are bad for an array of total size ~S."
 787                   start end (array-total-size object))))))))
 788
 789 (define-condition nil-array-accessed-error (type-error)
 790   ()
 791   (:report (lambda (condition stream)
 792              (declare (ignore condition))
 793              (format stream
 794                      "An attempt to access an array of element-type ~
 795                       NIL was made.  Congratulations!"))))
 796
 797 (define-condition io-timeout (stream-error)
 798   ((direction :reader io-timeout-direction :initarg :direction))
 799   (:report
 800    (lambda (condition stream)
 801      (declare (type stream stream))
 802      (format stream
 803              "I/O timeout ~(~A~)ing ~S"
 804              (io-timeout-direction condition)
 805              (stream-error-stream condition)))))
 806
 807 (define-condition namestring-parse-error (parse-error)
 808   ((complaint :reader namestring-parse-error-complaint :initarg :complaint)
 809    (args :reader namestring-parse-error-args :initarg :args :initform nil)
 810    (namestring :reader namestring-parse-error-namestring :initarg :namestring)
 811    (offset :reader namestring-parse-error-offset :initarg :offset))
 812   (:report
 813    (lambda (condition stream)
 814      (format stream
 815              "parse error in namestring: ~?~%  ~A~%  ~V@T^"
 816              (namestring-parse-error-complaint condition)
 817              (namestring-parse-error-args condition)
 818              (namestring-parse-error-namestring condition)
 819              (namestring-parse-error-offset condition)))))
 820
 821 (define-condition simple-package-error (simple-condition package-error) ())
 822
 823 (define-condition reader-package-error (reader-error) ())
 824
 825 (define-condition reader-eof-error (end-of-file)
 826   ((context :reader reader-eof-error-context :initarg :context))
 827   (:report
 828    (lambda (condition stream)
 829      (format stream
 830              "unexpected end of file on ~S ~A"
 831              (stream-error-stream condition)
 832              (reader-eof-error-context condition)))))
 833
 834 (define-condition reader-impossible-number-error (reader-error)
 835   ((error :reader reader-impossible-number-error-error :initarg :error))
 836   (:report
 837    (lambda (condition stream)
 838      (let ((error-stream (stream-error-stream condition)))
 839        (format stream "READER-ERROR ~@[at ~W ~]on ~S:~%~?~%Original error: ~A"
 840                (file-position error-stream) error-stream
 841                (reader-error-format-control condition)
 842                (reader-error-format-arguments condition)
 843                (reader-impossible-number-error-error condition))))))
 844
 845 (define-condition timeout (serious-condition) ())
 846 \f
 847 ;;;; special SBCL extension conditions
 848
 849 ;;; an error apparently caused by a bug in SBCL itself
 850 ;;;
 851 ;;; Note that we don't make any serious effort to use this condition
 852 ;;; for *all* errors in SBCL itself. E.g. type errors and array
 853 ;;; indexing errors can occur in functions called from SBCL code, and
 854 ;;; will just end up as ordinary TYPE-ERROR or invalid index error,
 855 ;;; because the signalling code has no good way to know that the
 856 ;;; underlying problem is a bug in SBCL. But in the fairly common case
 857 ;;; that the signalling code does know that it's found a bug in SBCL,
 858 ;;; this condition is appropriate, reusing boilerplate and helping
 859 ;;; users to recognize it as an SBCL bug.
 860 (define-condition bug (simple-error)
 861   ()
 862   (:report
 863    (lambda (condition stream)
 864      (format stream
 865              "~@<  ~? ~:@_~?~:>"
 866              (simple-condition-format-control condition)
 867              (simple-condition-format-arguments condition)
 868              "~@<This is probably a bug in SBCL itself. (Alternatively, ~
 869               SBCL might have been corrupted by bad user code, e.g. by an ~
 870               undefined Lisp operation like ~S, or by stray pointers from ~
 871               alien code or from unsafe Lisp code; or there might be a bug ~
 872               in the OS or hardware that SBCL is running on.) If it seems to ~
 873               be a bug in SBCL itself, the maintainers would like to know ~
 874               about it. Bug reports are welcome on the SBCL ~
 875               mailing lists, which you can find at ~
 876               <http://sbcl.sourceforge.net/>.~:@>"
 877              '((fmakunbound 'compile))))))
 878 (defun bug (format-control &rest format-arguments)
 879   (error 'bug
 880          :format-control format-control
 881          :format-arguments format-arguments))
 882
 883 ;;; a condition for use in stubs for operations which aren't supported
 884 ;;; on some platforms
 885 ;;;
 886 ;;; E.g. in sbcl-0.7.0.5, it might be appropriate to do something like
 887 ;;;   #-(or freebsd linux)
 888 ;;;   (defun load-foreign (&rest rest)
 889 ;;;     (error 'unsupported-operator :name 'load-foreign))
 890 ;;;   #+(or freebsd linux)
 891 ;;;   (defun load-foreign ... actual definition ...)
 892 ;;; By signalling a standard condition in this case, we make it
 893 ;;; possible for test code to distinguish between (1) intentionally
 894 ;;; unimplemented and (2) unintentionally just screwed up somehow.
 895 ;;; (Before this condition was defined, test code tried to deal with
 896 ;;; this by checking for FBOUNDP, but that didn't work reliably. In
 897 ;;; sbcl-0.7.0, a a package screwup left the definition of
 898 ;;; LOAD-FOREIGN in the wrong package, so it was unFBOUNDP even on
 899 ;;; architectures where it was supposed to be supported, and the
 900 ;;; regression tests cheerfully passed because they assumed that
 901 ;;; unFBOUNDPness meant they were running on an system which didn't
 902 ;;; support the extension.)
 903 (define-condition unsupported-operator (cell-error) ()
 904   (:report
 905    (lambda (condition stream)
 906      (format stream
 907              "unsupported on this platform (OS, CPU, whatever): ~S"
 908              (cell-error-name condition)))))
 909 \f
 910 ;;; (:ansi-cl :function remove)
 911 ;;; (:ansi-cl :section (a b c))
 912 ;;; (:ansi-cl :glossary "similar")
 913 ;;;
 914 ;;; (:sbcl :node "...")
 915 ;;;
 916 ;;; FIXME: this is not the right place for this.
 917 (defun print-reference (reference stream)
 918   (ecase (car reference)
 919     (:ansi-cl
 920      (format stream "The ANSI Standard")
 921      (format stream ", ")
 922      (destructuring-bind (type data) (cdr reference)
 923        (ecase type
 924          (:function (format stream "Function ~S" data))
 925          (:special-operator (format stream "Special Operator ~S" data))
 926          (:macro (format stream "Macro ~S" data))
 927          (:section (format stream "Section ~{~D~^.~}" data))
 928          (:glossary (format stream "Glossary Entry ~S" data)))))
 929     (:sbcl
 930      (format stream "The SBCL Manual")
 931      (format stream ", ")
 932      (destructuring-bind (type data) (cdr reference)
 933        (ecase type
 934          (:node (format stream "Node ~S" data)))))
 935     ;; FIXME: other documents (e.g. AMOP, Franz documentation :-)
 936     ))
 937 (define-condition reference-condition ()
 938   ((references :initarg :references :reader reference-condition-references)))
 939 (defvar *print-condition-references* t)
 940 (def!method print-object :around ((o reference-condition) s)
 941   (call-next-method)
 942   (unless (or *print-escape* *print-readably*)
 943     (when *print-condition-references*
 944       (format s "~&See also:~%")
 945       (pprint-logical-block (s nil :per-line-prefix "  ")
 946         (do* ((rs (reference-condition-references o) (cdr rs))
 947               (r (car rs) (car rs)))
 948              ((null rs))
 949           (print-reference r s)
 950           (unless (null (cdr rs))
 951             (terpri s)))))))
 952
 953 (define-condition duplicate-definition (reference-condition warning)
 954   ((name :initarg :name :reader duplicate-definition-name))
 955   (:report (lambda (c s)
 956              (format s "~@<Duplicate definition for ~S found in ~
 957                         one file.~@:>"
 958                      (duplicate-definition-name c))))
 959   (:default-initargs :references (list '(:ansi-cl :section (3 2 2 3)))))
 960
 961 (define-condition package-at-variance (reference-condition simple-warning)
 962   ()
 963   (:default-initargs :references (list '(:ansi-cl :macro defpackage))))
 964
 965 (define-condition defconstant-uneql (reference-condition error)
 966   ((name :initarg :name :reader defconstant-uneql-name)
 967    (old-value :initarg :old-value :reader defconstant-uneql-old-value)
 968    (new-value :initarg :new-value :reader defconstant-uneql-new-value))
 969   (:report
 970    (lambda (condition stream)
 971      (format stream
 972              "~@<The constant ~S is being redefined (from ~S to ~S)~@:>"
 973              (defconstant-uneql-name condition)
 974              (defconstant-uneql-old-value condition)
 975              (defconstant-uneql-new-value condition))))
 976   (:default-initargs :references (list '(:ansi-cl :macro defconstant)
 977                                        '(:sbcl :node "Idiosyncrasies"))))
 978
 979 (define-condition array-initial-element-mismatch
 980     (reference-condition simple-warning)
 981   ()
 982   (:default-initargs
 983       :references (list '(:ansi-cl :function make-array)
 984                         '(:ansi-cl :function upgraded-array-element-type))))
 985
 986 (define-condition type-warning (reference-condition simple-warning)
 987   ()
 988   (:default-initargs :references (list '(:sbcl :node "Handling of Types"))))
 989
 990 (define-condition local-argument-mismatch (reference-condition simple-warning)
 991   ()
 992   (:default-initargs :references (list '(:ansi-cl :section (3 2 2 3)))))
 993
 994 (define-condition format-args-mismatch (reference-condition)
 995   ()
 996   (:default-initargs :references (list '(:ansi-cl :section (22 3 10 2)))))
 997
 998 (define-condition format-too-few-args-warning
 999     (format-args-mismatch simple-warning)
1000   ())
1001 (define-condition format-too-many-args-warning
1002     (format-args-mismatch simple-style-warning)
1003   ())
1004 \f
1005 ;;;; restart definitions
1006
1007 (define-condition abort-failure (control-error) ()
1008   (:report
1009    "An ABORT restart was found that failed to transfer control dynamically."))
1010
1011 (defun abort (&optional condition)
1012   #!+sb-doc
1013   "Transfer control to a restart named ABORT, signalling a CONTROL-ERROR if
1014    none exists."
1015   (invoke-restart (find-restart-or-control-error 'abort condition))
1016   ;; ABORT signals an error in case there was a restart named ABORT
1017   ;; that did not transfer control dynamically. This could happen with
1018   ;; RESTART-BIND.
1019   (error 'abort-failure))
1020
1021 (defun muffle-warning (&optional condition)
1022   #!+sb-doc
1023   "Transfer control to a restart named MUFFLE-WARNING, signalling a
1024    CONTROL-ERROR if none exists."
1025   (invoke-restart (find-restart-or-control-error 'muffle-warning condition)))
1026
1027 (macrolet ((define-nil-returning-restart (name args doc)
1028              #!-sb-doc (declare (ignore doc))
1029              `(defun ,name (,@args &optional condition)
1030                 #!+sb-doc ,doc
1031                 ;; FIXME: Perhaps this shared logic should be pulled out into
1032                 ;; FLET MAYBE-INVOKE-RESTART? See whether it shrinks code..
1033                 (let ((restart (find-restart ',name condition)))
1034                   (when restart
1035                     (invoke-restart restart ,@args))))))
1036   (define-nil-returning-restart continue ()
1037     "Transfer control to a restart named CONTINUE, or return NIL if none exists.")
1038   (define-nil-returning-restart store-value (value)
1039     "Transfer control and VALUE to a restart named STORE-VALUE, or return NIL if
1040    none exists.")
1041   (define-nil-returning-restart use-value (value)
1042     "Transfer control and VALUE to a restart named USE-VALUE, or return NIL if
1043    none exists."))
1044
1045 (/show0 "condition.lisp end of file")
1046