src/code/condition.lisp

   1 ;;;; stuff originally from CMU CL's error.lisp which can or should
   2 ;;;; come late (mostly related to the CONDITION class itself)
   3 ;;;;
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!KERNEL")
  15 \f
  16 ;;;; miscellaneous support utilities
  17
  18 ;;; Signalling an error when trying to print an error condition is
  19 ;;; generally a PITA, so whatever the failure encountered when
  20 ;;; wondering about FILE-POSITION within a condition printer, 'tis
  21 ;;; better silently to give up than to try to complain.
  22 (defun file-position-or-nil-for-error (stream &optional (pos nil posp))
  23   ;; Arguably FILE-POSITION shouldn't be signalling errors at all; but
  24   ;; "NIL if this cannot be determined" in the ANSI spec doesn't seem
  25   ;; absolutely unambiguously to prohibit errors when, e.g., STREAM
  26   ;; has been closed so that FILE-POSITION is a nonsense question. So
  27   ;; my (WHN) impression is that the conservative approach is to
  28   ;; IGNORE-ERRORS. (I encountered this failure from within a homebrew
  29   ;; defsystemish operation where the ERROR-STREAM had been CL:CLOSEd,
  30   ;; I think by nonlocally exiting through a WITH-OPEN-FILE, by the
  31   ;; time an error was reported.)
  32   (if posp
  33       (ignore-errors (file-position stream pos))
  34       (ignore-errors (file-position stream))))
  35 \f
  36 ;;;; the CONDITION class
  37
  38 (/show0 "condition.lisp 20")
  39
  40 (eval-when (:compile-toplevel :load-toplevel :execute)
  41
  42 (/show0 "condition.lisp 24")
  43
  44 (def!struct (condition-classoid (:include classoid)
  45                                 (:constructor make-condition-classoid))
  46   ;; list of CONDITION-SLOT structures for the direct slots of this
  47   ;; class
  48   (slots nil :type list)
  49   ;; list of CONDITION-SLOT structures for all of the effective class
  50   ;; slots of this class
  51   (class-slots nil :type list)
  52   ;; report function or NIL
  53   (report nil :type (or function null))
  54   ;; list of alternating initargs and initforms
  55   (default-initargs () :type list)
  56   ;; class precedence list as a list of CLASS objects, with all
  57   ;; non-CONDITION classes removed
  58   (cpl () :type list)
  59   ;; a list of all the effective instance allocation slots of this
  60   ;; class that have a non-constant initform or default-initarg.
  61   ;; Values for these slots must be computed in the dynamic
  62   ;; environment of MAKE-CONDITION.
  63   (hairy-slots nil :type list))
  64
  65 (/show0 "condition.lisp 49")
  66
  67 ) ; EVAL-WHEN
  68
  69 (!defstruct-with-alternate-metaclass condition
  70   :slot-names (actual-initargs assigned-slots)
  71   :boa-constructor %make-condition-object
  72   :superclass-name t
  73   :metaclass-name condition-classoid
  74   :metaclass-constructor make-condition-classoid
  75   :dd-type structure)
  76
  77 (defun make-condition-object (actual-initargs)
  78   (%make-condition-object actual-initargs nil))
  79
  80 (defstruct (condition-slot (:copier nil))
  81   (name (missing-arg) :type symbol)
  82   ;; list of all applicable initargs
  83   (initargs (missing-arg) :type list)
  84   ;; names of reader and writer functions
  85   (readers (missing-arg) :type list)
  86   (writers (missing-arg) :type list)
  87   ;; true if :INITFORM was specified
  88   (initform-p (missing-arg) :type (member t nil))
  89   ;; If this is a function, call it with no args. Otherwise, it's the
  90   ;; actual value.
  91   (initform (missing-arg) :type t)
  92   ;; allocation of this slot, or NIL until defaulted
  93   (allocation nil :type (member :instance :class nil))
  94   ;; If ALLOCATION is :CLASS, this is a cons whose car holds the value.
  95   (cell nil :type (or cons null))
  96   ;; slot documentation
  97   (documentation nil :type (or string null)))
  98
  99 ;;; KLUDGE: It's not clear to me why CONDITION-CLASS has itself listed
 100 ;;; in its CPL, while other classes derived from CONDITION-CLASS don't
 101 ;;; have themselves listed in their CPLs. This behavior is inherited
 102 ;;; from CMU CL, and didn't seem to be explained there, and I haven't
 103 ;;; figured out whether it's right. -- WHN 19990612
 104 (eval-when (:compile-toplevel :load-toplevel :execute)
 105   (/show0 "condition.lisp 103")
 106   (let ((condition-class (locally
 107                            ;; KLUDGE: There's a DEFTRANSFORM
 108                            ;; FIND-CLASSOID for constant class names
 109                            ;; which creates fast but
 110                            ;; non-cold-loadable, non-compact code. In
 111                            ;; this context, we'd rather have compact,
 112                            ;; cold-loadable code. -- WHN 19990928
 113                            (declare (notinline find-classoid))
 114                            (find-classoid 'condition))))
 115     (setf (condition-classoid-cpl condition-class)
 116           (list condition-class)))
 117   (/show0 "condition.lisp 103"))
 118
 119 (setf (condition-classoid-report (locally
 120                                    ;; KLUDGE: There's a DEFTRANSFORM
 121                                    ;; FIND-CLASSOID for constant class
 122                                    ;; names which creates fast but
 123                                    ;; non-cold-loadable, non-compact
 124                                    ;; code. In this context, we'd
 125                                    ;; rather have compact,
 126                                    ;; cold-loadable code. -- WHN
 127                                    ;; 19990928
 128                                    (declare (notinline find-classoid))
 129                                    (find-classoid 'condition)))
 130       (lambda (cond stream)
 131         (format stream "Condition ~S was signalled." (type-of cond))))
 132
 133 (eval-when (:compile-toplevel :load-toplevel :execute)
 134
 135 (defun find-condition-layout (name parent-types)
 136   (let* ((cpl (remove-duplicates
 137                (reverse
 138                 (reduce #'append
 139                         (mapcar (lambda (x)
 140                                   (condition-classoid-cpl
 141                                    (find-classoid x)))
 142                                 parent-types)))))
 143          (cond-layout (info :type :compiler-layout 'condition))
 144          (olayout (info :type :compiler-layout name))
 145          ;; FIXME: Does this do the right thing in case of multiple
 146          ;; inheritance? A quick look at DEFINE-CONDITION didn't make
 147          ;; it obvious what ANSI intends to be done in the case of
 148          ;; multiple inheritance, so it's not actually clear what the
 149          ;; right thing is..
 150          (new-inherits
 151           (order-layout-inherits (concatenate 'simple-vector
 152                                               (layout-inherits cond-layout)
 153                                               (mapcar #'classoid-layout cpl)))))
 154     (if (and olayout
 155              (not (mismatch (layout-inherits olayout) new-inherits)))
 156         olayout
 157         (make-layout :classoid (make-undefined-classoid name)
 158                      :inherits new-inherits
 159                      :depthoid -1
 160                      :length (layout-length cond-layout)))))
 161
 162 ) ; EVAL-WHEN
 163
 164 ;;; FIXME: ANSI's definition of DEFINE-CONDITION says
 165 ;;;   Condition reporting is mediated through the PRINT-OBJECT method
 166 ;;;   for the condition type in question, with *PRINT-ESCAPE* always
 167 ;;;   being nil. Specifying (:REPORT REPORT-NAME) in the definition of
 168 ;;;   a condition type C is equivalent to:
 169 ;;;     (defmethod print-object ((x c) stream)
 170 ;;;       (if *print-escape* (call-next-method) (report-name x stream)))
 171 ;;; The current code doesn't seem to quite match that.
 172 (def!method print-object ((x condition) stream)
 173   (if *print-escape*
 174       (print-unreadable-object (x stream :type t :identity t))
 175       ;; KLUDGE: A comment from CMU CL here said
 176       ;;   7/13/98 BUG? CPL is not sorted and results here depend on order of
 177       ;;   superclasses in define-condition call!
 178       (dolist (class (condition-classoid-cpl (classoid-of x))
 179                      (error "no REPORT? shouldn't happen!"))
 180         (let ((report (condition-classoid-report class)))
 181           (when report
 182             (return (funcall report x stream)))))))
 183 \f
 184 ;;;; slots of CONDITION objects
 185
 186 (defvar *empty-condition-slot* '(empty))
 187
 188 (defun find-slot-default (class slot)
 189   (let ((initargs (condition-slot-initargs slot))
 190         (cpl (condition-classoid-cpl class)))
 191     (dolist (class cpl)
 192       (let ((default-initargs (condition-classoid-default-initargs class)))
 193         (dolist (initarg initargs)
 194           (let ((val (getf default-initargs initarg *empty-condition-slot*)))
 195             (unless (eq val *empty-condition-slot*)
 196               (return-from find-slot-default
 197                            (if (functionp val)
 198                                (funcall val)
 199                                val)))))))
 200
 201     (if (condition-slot-initform-p slot)
 202         (let ((initform (condition-slot-initform slot)))
 203           (if (functionp initform)
 204               (funcall initform)
 205               initform))
 206         (error "unbound condition slot: ~S" (condition-slot-name slot)))))
 207
 208 (defun find-condition-class-slot (condition-class slot-name)
 209   (dolist (sclass
 210            (condition-classoid-cpl condition-class)
 211            (error "There is no slot named ~S in ~S."
 212                   slot-name condition-class))
 213     (dolist (slot (condition-classoid-slots sclass))
 214       (when (eq (condition-slot-name slot) slot-name)
 215         (return-from find-condition-class-slot slot)))))
 216
 217 (defun condition-writer-function (condition new-value name)
 218   (dolist (cslot (condition-classoid-class-slots
 219                   (layout-classoid (%instance-layout condition)))
 220                  (setf (getf (condition-assigned-slots condition) name)
 221                        new-value))
 222     (when (eq (condition-slot-name cslot) name)
 223       (return (setf (car (condition-slot-cell cslot)) new-value)))))
 224
 225 (defun condition-reader-function (condition name)
 226   (let ((class (layout-classoid (%instance-layout condition))))
 227     (dolist (cslot (condition-classoid-class-slots class))
 228       (when (eq (condition-slot-name cslot) name)
 229         (return-from condition-reader-function
 230                      (car (condition-slot-cell cslot)))))
 231     (let ((val (getf (condition-assigned-slots condition) name
 232                      *empty-condition-slot*)))
 233       (if (eq val *empty-condition-slot*)
 234           (let ((actual-initargs (condition-actual-initargs condition))
 235                 (slot (find-condition-class-slot class name)))
 236             (unless slot
 237               (error "missing slot ~S of ~S" name condition))
 238             (do ((initargs actual-initargs (cddr initargs)))
 239                 ((endp initargs)
 240                  (setf (getf (condition-assigned-slots condition) name)
 241                        (find-slot-default class slot)))
 242               (when (member (car initargs) (condition-slot-initargs slot))
 243                 (return-from condition-reader-function
 244                   (setf (getf (condition-assigned-slots condition)
 245                               name)
 246                         (cadr initargs))))))
 247           val))))
 248 \f
 249 ;;;; MAKE-CONDITION
 250
 251 (defun make-condition (type &rest args)
 252   #!+sb-doc
 253   "Make an instance of a condition object using the specified initargs."
 254   ;; Note: ANSI specifies no exceptional situations in this function.
 255   ;; signalling simple-type-error would not be wrong.
 256   (let* ((type (or (and (symbolp type) (find-classoid type nil))
 257                     type))
 258          (class (typecase type
 259                   (condition-classoid type)
 260                   (class
 261                    ;; Punt to CLOS.
 262                    (return-from make-condition (apply #'make-instance type args)))
 263                   (classoid
 264                    (error 'simple-type-error
 265                           :datum type
 266                           :expected-type 'condition-class
 267                           :format-control "~S is not a condition class."
 268                           :format-arguments (list type)))
 269                   (t
 270                    (error 'simple-type-error
 271                           :datum type
 272                           :expected-type 'condition-class
 273                           :format-control "Bad type argument:~%  ~S"
 274                           :format-arguments (list type)))))
 275          (res (make-condition-object args)))
 276     (setf (%instance-layout res) (classoid-layout class))
 277     ;; Set any class slots with initargs present in this call.
 278     (dolist (cslot (condition-classoid-class-slots class))
 279       (dolist (initarg (condition-slot-initargs cslot))
 280         (let ((val (getf args initarg *empty-condition-slot*)))
 281           (unless (eq val *empty-condition-slot*)
 282             (setf (car (condition-slot-cell cslot)) val)))))
 283     ;; Default any slots with non-constant defaults now.
 284     (dolist (hslot (condition-classoid-hairy-slots class))
 285       (when (dolist (initarg (condition-slot-initargs hslot) t)
 286               (unless (eq (getf args initarg *empty-condition-slot*)
 287                           *empty-condition-slot*)
 288                 (return nil)))
 289         (setf (getf (condition-assigned-slots res) (condition-slot-name hslot))
 290               (find-slot-default class hslot))))
 291     res))
 292 \f
 293 ;;;; DEFINE-CONDITION
 294
 295 (eval-when (:compile-toplevel :load-toplevel :execute)
 296 (defun %compiler-define-condition (name direct-supers layout
 297                                    all-readers all-writers)
 298   (with-single-package-locked-error
 299       (:symbol name "defining ~A as a condition")
 300     (sb!xc:proclaim `(ftype (function (t) t) ,@all-readers))
 301     (sb!xc:proclaim `(ftype (function (t t) t) ,@all-writers))
 302     (multiple-value-bind (class old-layout)
 303         (insured-find-classoid name
 304                                #'condition-classoid-p
 305                                #'make-condition-classoid)
 306       (setf (layout-classoid layout) class)
 307       (setf (classoid-direct-superclasses class)
 308             (mapcar #'find-classoid direct-supers))
 309       (cond ((not old-layout)
 310              (register-layout layout))
 311             ((not *type-system-initialized*)
 312              (setf (layout-classoid old-layout) class)
 313              (setq layout old-layout)
 314              (unless (eq (classoid-layout class) layout)
 315                (register-layout layout)))
 316             ((redefine-layout-warning "current"
 317                                       old-layout
 318                                       "new"
 319                                       (layout-length layout)
 320                                       (layout-inherits layout)
 321                                       (layout-depthoid layout)
 322                                       (layout-n-untagged-slots layout))
 323              (register-layout layout :invalidate t))
 324             ((not (classoid-layout class))
 325              (register-layout layout)))
 326
 327       (setf (layout-info layout)
 328             (locally
 329                 ;; KLUDGE: There's a FIND-CLASS DEFTRANSFORM for constant class
 330                 ;; names which creates fast but non-cold-loadable, non-compact
 331                 ;; code. In this context, we'd rather have compact, cold-loadable
 332                 ;; code. -- WHN 19990928
 333                 (declare (notinline find-classoid))
 334               (layout-info (classoid-layout (find-classoid 'condition)))))
 335
 336       (setf (find-classoid name) class)
 337
 338       ;; Initialize CPL slot.
 339       (setf (condition-classoid-cpl class)
 340             (remove-if-not #'condition-classoid-p
 341                            (std-compute-class-precedence-list class)))))
 342   (values))
 343 ) ; EVAL-WHEN
 344
 345 ;;; Compute the effective slots of CLASS, copying inherited slots and
 346 ;;; destructively modifying direct slots.
 347 ;;;
 348 ;;; FIXME: It'd be nice to explain why it's OK to destructively modify
 349 ;;; direct slots. Presumably it follows from the semantics of
 350 ;;; inheritance and redefinition of conditions, but finding the cite
 351 ;;; and documenting it here would be good. (Or, if this is not in fact
 352 ;;; ANSI-compliant, fixing it would also be good.:-)
 353 (defun compute-effective-slots (class)
 354   (collect ((res (copy-list (condition-classoid-slots class))))
 355     (dolist (sclass (cdr (condition-classoid-cpl class)))
 356       (dolist (sslot (condition-classoid-slots sclass))
 357         (let ((found (find (condition-slot-name sslot) (res)
 358                            :key #'condition-slot-name)))
 359           (cond (found
 360                  (setf (condition-slot-initargs found)
 361                        (union (condition-slot-initargs found)
 362                               (condition-slot-initargs sslot)))
 363                  (unless (condition-slot-initform-p found)
 364                    (setf (condition-slot-initform-p found)
 365                          (condition-slot-initform-p sslot))
 366                    (setf (condition-slot-initform found)
 367                          (condition-slot-initform sslot)))
 368                  (unless (condition-slot-allocation found)
 369                    (setf (condition-slot-allocation found)
 370                          (condition-slot-allocation sslot))))
 371                 (t
 372                  (res (copy-structure sslot)))))))
 373     (res)))
 374
 375 ;;; Early definitions of slot accessor creators.
 376 ;;;
 377 ;;; Slot accessors must be generic functions, but ANSI does not seem
 378 ;;; to specify any of them, and we cannot support it before end of
 379 ;;; warm init. So we use ordinary functions inside SBCL, and switch to
 380 ;;; GFs only at the end of building.
 381 (declaim (notinline install-condition-slot-reader
 382                     install-condition-slot-writer))
 383 (defun install-condition-slot-reader (name condition slot-name)
 384   (declare (ignore condition))
 385   (setf (fdefinition name)
 386         (lambda (condition)
 387           (condition-reader-function condition slot-name))))
 388 (defun install-condition-slot-writer (name condition slot-name)
 389   (declare (ignore condition))
 390   (setf (fdefinition name)
 391         (lambda (new-value condition)
 392           (condition-writer-function condition new-value slot-name))))
 393
 394 (defvar *define-condition-hooks* nil)
 395
 396 (defun %define-condition (name parent-types layout slots documentation
 397                           report default-initargs all-readers all-writers
 398                           source-location)
 399   (with-single-package-locked-error
 400       (:symbol name "defining ~A as a condition")
 401     (%compiler-define-condition name parent-types layout all-readers all-writers)
 402     (sb!c:with-source-location (source-location)
 403       (setf (layout-source-location layout)
 404             source-location))
 405     (let ((class (find-classoid name)))
 406       (setf (condition-classoid-slots class) slots)
 407       (setf (condition-classoid-report class) report)
 408       (setf (condition-classoid-default-initargs class) default-initargs)
 409       (setf (fdocumentation name 'type) documentation)
 410
 411       (dolist (slot slots)
 412
 413         ;; Set up reader and writer functions.
 414         (let ((slot-name (condition-slot-name slot)))
 415           (dolist (reader (condition-slot-readers slot))
 416             (install-condition-slot-reader reader name slot-name))
 417           (dolist (writer (condition-slot-writers slot))
 418             (install-condition-slot-writer writer name slot-name))))
 419
 420       ;; Compute effective slots and set up the class and hairy slots
 421       ;; (subsets of the effective slots.)
 422       (let ((eslots (compute-effective-slots class))
 423             (e-def-initargs
 424              (reduce #'append
 425                      (mapcar #'condition-classoid-default-initargs
 426                            (condition-classoid-cpl class)))))
 427         (dolist (slot eslots)
 428           (ecase (condition-slot-allocation slot)
 429             (:class
 430              (unless (condition-slot-cell slot)
 431                (setf (condition-slot-cell slot)
 432                      (list (if (condition-slot-initform-p slot)
 433                                (let ((initform (condition-slot-initform slot)))
 434                                  (if (functionp initform)
 435                                      (funcall initform)
 436                                      initform))
 437                                *empty-condition-slot*))))
 438              (push slot (condition-classoid-class-slots class)))
 439             ((:instance nil)
 440              (setf (condition-slot-allocation slot) :instance)
 441              (when (or (functionp (condition-slot-initform slot))
 442                        (dolist (initarg (condition-slot-initargs slot) nil)
 443                          (when (functionp (getf e-def-initargs initarg))
 444                            (return t))))
 445                (push slot (condition-classoid-hairy-slots class)))))))
 446       (when (boundp '*define-condition-hooks*)
 447         (dolist (fun *define-condition-hooks*)
 448           (funcall fun class))))
 449     name))
 450
 451 (defmacro define-condition (name (&rest parent-types) (&rest slot-specs)
 452                                  &body options)
 453   #!+sb-doc
 454   "DEFINE-CONDITION Name (Parent-Type*) (Slot-Spec*) Option*
 455    Define NAME as a condition type. This new type inherits slots and its
 456    report function from the specified PARENT-TYPEs. A slot spec is a list of:
 457      (slot-name :reader <rname> :initarg <iname> {Option Value}*
 458
 459    The DEFINE-CLASS slot options :ALLOCATION, :INITFORM, [slot] :DOCUMENTATION
 460    and :TYPE and the overall options :DEFAULT-INITARGS and
 461    [type] :DOCUMENTATION are also allowed.
 462
 463    The :REPORT option is peculiar to DEFINE-CONDITION. Its argument is either
 464    a string or a two-argument lambda or function name. If a function, the
 465    function is called with the condition and stream to report the condition.
 466    If a string, the string is printed.
 467
 468    Condition types are classes, but (as allowed by ANSI and not as described in
 469    CLtL2) are neither STANDARD-OBJECTs nor STRUCTURE-OBJECTs. WITH-SLOTS and
 470    SLOT-VALUE may not be used on condition objects."
 471   (let* ((parent-types (or parent-types '(condition)))
 472          (layout (find-condition-layout name parent-types))
 473          (documentation nil)
 474          (report nil)
 475          (default-initargs ()))
 476     (collect ((slots)
 477               (all-readers nil append)
 478               (all-writers nil append))
 479       (dolist (spec slot-specs)
 480         (when (keywordp spec)
 481           (warn "Keyword slot name indicates probable syntax error:~%  ~S"
 482                 spec))
 483         (let* ((spec (if (consp spec) spec (list spec)))
 484                (slot-name (first spec))
 485                (allocation :instance)
 486                (initform-p nil)
 487                documentation
 488                initform)
 489           (collect ((initargs)
 490                     (readers)
 491                     (writers))
 492             (do ((options (rest spec) (cddr options)))
 493                 ((null options))
 494               (unless (and (consp options) (consp (cdr options)))
 495                 (error "malformed condition slot spec:~%  ~S." spec))
 496               (let ((arg (second options)))
 497                 (case (first options)
 498                   (:reader (readers arg))
 499                   (:writer (writers arg))
 500                   (:accessor
 501                    (readers arg)
 502                    (writers `(setf ,arg)))
 503                   (:initform
 504                    (when initform-p
 505                      (error "more than one :INITFORM in ~S" spec))
 506                    (setq initform-p t)
 507                    (setq initform arg))
 508                   (:initarg (initargs arg))
 509                   (:allocation
 510                    (setq allocation arg))
 511                   (:documentation
 512                    (when documentation
 513                      (error "more than one :DOCUMENTATION in ~S" spec))
 514                    (unless (stringp arg)
 515                      (error "slot :DOCUMENTATION argument is not a string: ~S"
 516                             arg))
 517                    (setq documentation arg))
 518                   (:type)
 519                   (t
 520                    (error "unknown slot option:~%  ~S" (first options))))))
 521
 522             (all-readers (readers))
 523             (all-writers (writers))
 524             (slots `(make-condition-slot
 525                      :name ',slot-name
 526                      :initargs ',(initargs)
 527                      :readers ',(readers)
 528                      :writers ',(writers)
 529                      :initform-p ',initform-p
 530                      :documentation ',documentation
 531                      :initform
 532                      ,(if (sb!xc:constantp initform)
 533                           `',(constant-form-value initform)
 534                           `#'(lambda () ,initform)))))))
 535
 536       (dolist (option options)
 537         (unless (consp option)
 538           (error "bad option:~%  ~S" option))
 539         (case (first option)
 540           (:documentation (setq documentation (second option)))
 541           (:report
 542            (let ((arg (second option)))
 543              (setq report
 544                    (if (stringp arg)
 545                        `#'(lambda (condition stream)
 546                           (declare (ignore condition))
 547                           (write-string ,arg stream))
 548                        `#'(lambda (condition stream)
 549                           (funcall #',arg condition stream))))))
 550           (:default-initargs
 551            (do ((initargs (rest option) (cddr initargs)))
 552                ((endp initargs))
 553              (let ((val (second initargs)))
 554                (setq default-initargs
 555                      (list* `',(first initargs)
 556                             (if (sb!xc:constantp val)
 557                                 `',(constant-form-value val)
 558                                 `#'(lambda () ,val))
 559                             default-initargs)))))
 560           (t
 561            (error "unknown option: ~S" (first option)))))
 562
 563       `(progn
 564          (eval-when (:compile-toplevel)
 565            (%compiler-define-condition ',name ',parent-types ',layout
 566                                        ',(all-readers) ',(all-writers)))
 567          (eval-when (:load-toplevel :execute)
 568            (%define-condition ',name
 569                               ',parent-types
 570                               ',layout
 571                               (list ,@(slots))
 572                               ,documentation
 573                               ,report
 574                               (list ,@default-initargs)
 575                               ',(all-readers)
 576                               ',(all-writers)
 577                               (sb!c:source-location)))))))
 578 \f
 579 ;;;; DESCRIBE on CONDITIONs
 580
 581 ;;; a function to be used as the guts of DESCRIBE-OBJECT (CONDITION T)
 582 ;;; eventually (once we get CLOS up and running so that we can define
 583 ;;; methods)
 584 (defun describe-condition (condition stream)
 585   (format stream
 586           "~&~@<~S ~_is a ~S. ~_Its slot values are ~_~S.~:>~%"
 587           condition
 588           (type-of condition)
 589           (concatenate 'list
 590                        (condition-actual-initargs condition)
 591                        (condition-assigned-slots condition))))
 592 \f
 593 ;;;; various CONDITIONs specified by ANSI
 594
 595 (define-condition serious-condition (condition) ())
 596
 597 (define-condition error (serious-condition) ())
 598
 599 (define-condition warning (condition) ())
 600 (define-condition style-warning (warning) ())
 601
 602 (defun simple-condition-printer (condition stream)
 603   (apply #'format
 604          stream
 605          (simple-condition-format-control condition)
 606          (simple-condition-format-arguments condition)))
 607
 608 (define-condition simple-condition ()
 609   ((format-control :reader simple-condition-format-control
 610                    :initarg :format-control
 611                    :type format-control)
 612    (format-arguments :reader simple-condition-format-arguments
 613                      :initarg :format-arguments
 614                      :initform '()
 615                      :type list))
 616   (:report simple-condition-printer))
 617
 618 (define-condition simple-warning (simple-condition warning) ())
 619
 620 (define-condition simple-error (simple-condition error) ())
 621
 622 (define-condition storage-condition (serious-condition) ())
 623
 624 (define-condition type-error (error)
 625   ((datum :reader type-error-datum :initarg :datum)
 626    (expected-type :reader type-error-expected-type :initarg :expected-type))
 627   (:report
 628    (lambda (condition stream)
 629      (format stream
 630              "~@<The value ~2I~:_~S ~I~_is not of type ~2I~_~S.~:>"
 631              (type-error-datum condition)
 632              (type-error-expected-type condition)))))
 633
 634 ;;; not specified by ANSI, but too useful not to have around.
 635 (define-condition simple-style-warning (simple-condition style-warning) ())
 636 (define-condition simple-type-error (simple-condition type-error) ())
 637
 638 (define-condition program-error (error) ())
 639 (define-condition parse-error   (error) ())
 640 (define-condition control-error (error) ())
 641 (define-condition stream-error  (error)
 642   ((stream :reader stream-error-stream :initarg :stream)))
 643
 644 (define-condition end-of-file (stream-error) ()
 645   (:report
 646    (lambda (condition stream)
 647      (format stream
 648              "end of file on ~S"
 649              (stream-error-stream condition)))))
 650
 651 (define-condition closed-stream-error (stream-error) ()
 652   (:report
 653    (lambda (condition stream)
 654      (format stream "~S is closed" (stream-error-stream condition)))))
 655
 656 (define-condition file-error (error)
 657   ((pathname :reader file-error-pathname :initarg :pathname))
 658   (:report
 659    (lambda (condition stream)
 660      (format stream "error on file ~S" (file-error-pathname condition)))))
 661
 662 (define-condition package-error (error)
 663   ((package :reader package-error-package :initarg :package)))
 664
 665 (define-condition cell-error (error)
 666   ((name :reader cell-error-name :initarg :name)))
 667
 668 (def!method print-object ((condition cell-error) stream)
 669   (if (and *print-escape* (slot-boundp condition 'name))
 670       (print-unreadable-object (condition stream :type t :identity t)
 671         (princ (cell-error-name condition) stream))
 672       (call-next-method)))
 673
 674 (define-condition unbound-variable (cell-error) ()
 675   (:report
 676    (lambda (condition stream)
 677      (format stream
 678              "The variable ~S is unbound."
 679              (cell-error-name condition)))))
 680
 681 (define-condition undefined-function (cell-error) ()
 682   (:report
 683    (lambda (condition stream)
 684      (format stream
 685              "The function ~S is undefined."
 686              (cell-error-name condition)))))
 687
 688 (define-condition special-form-function (undefined-function) ()
 689   (:report
 690    (lambda (condition stream)
 691      (format stream
 692              "Cannot FUNCALL the SYMBOL-FUNCTION of special operator ~S."
 693              (cell-error-name condition)))))
 694
 695 (define-condition arithmetic-error (error)
 696   ((operation :reader arithmetic-error-operation
 697               :initarg :operation
 698               :initform nil)
 699    (operands :reader arithmetic-error-operands
 700              :initarg :operands))
 701   (:report (lambda (condition stream)
 702              (format stream
 703                      "arithmetic error ~S signalled"
 704                      (type-of condition))
 705              (when (arithmetic-error-operation condition)
 706                (format stream
 707                        "~%Operation was ~S, operands ~S."
 708                        (arithmetic-error-operation condition)
 709                        (arithmetic-error-operands condition))))))
 710
 711 (define-condition division-by-zero         (arithmetic-error) ())
 712 (define-condition floating-point-overflow  (arithmetic-error) ())
 713 (define-condition floating-point-underflow (arithmetic-error) ())
 714 (define-condition floating-point-inexact   (arithmetic-error) ())
 715 (define-condition floating-point-invalid-operation (arithmetic-error) ())
 716
 717 (define-condition print-not-readable (error)
 718   ((object :reader print-not-readable-object :initarg :object))
 719   (:report
 720    (lambda (condition stream)
 721      (let ((obj (print-not-readable-object condition))
 722            (*print-array* nil))
 723        (format stream "~S cannot be printed readably." obj)))))
 724
 725 (define-condition reader-error (parse-error stream-error) ()
 726   (:report (lambda (condition stream)
 727              (%report-reader-error condition stream))))
 728
 729 ;;; a READER-ERROR whose REPORTing is controlled by FORMAT-CONTROL and
 730 ;;; FORMAT-ARGS (the usual case for READER-ERRORs signalled from
 731 ;;; within SBCL itself)
 732 ;;;
 733 ;;; (Inheriting CL:SIMPLE-CONDITION here isn't quite consistent with
 734 ;;; the letter of the ANSI spec: this is not a condition signalled by
 735 ;;; SIGNAL when a format-control is supplied by the function's first
 736 ;;; argument. It seems to me (WHN) to be basically in the spirit of
 737 ;;; the spec, but if not, it'd be straightforward to do our own
 738 ;;; DEFINE-CONDITION SB-INT:SIMPLISTIC-CONDITION with
 739 ;;; FORMAT-CONTROL and FORMAT-ARGS slots, and use that condition in
 740 ;;; place of CL:SIMPLE-CONDITION here.)
 741 (define-condition simple-reader-error (reader-error simple-condition)
 742   ()
 743   (:report (lambda (condition stream)
 744              (%report-reader-error condition stream :simple t))))
 745
 746 ;;; base REPORTing of a READER-ERROR
 747 ;;;
 748 ;;; When SIMPLE, we expect and use SIMPLE-CONDITION-ish FORMAT-CONTROL
 749 ;;; and FORMAT-ARGS slots.
 750 (defun %report-reader-error (condition stream &key simple)
 751   (let* ((error-stream (stream-error-stream condition))
 752          (pos (file-position-or-nil-for-error error-stream)))
 753     (let (lineno colno)
 754       (when (and pos
 755                  (< pos sb!xc:array-dimension-limit)
 756                  ;; KLUDGE: lseek() (which is what FILE-POSITION
 757                  ;; reduces to on file-streams) is undefined on
 758                  ;; "some devices", which in practice means that it
 759                  ;; can claim to succeed on /dev/stdin on Darwin
 760                  ;; and Solaris.  This is obviously bad news,
 761                  ;; because the READ-SEQUENCE below will then
 762                  ;; block, not complete, and the report will never
 763                  ;; be printed.  As a workaround, we exclude
 764                  ;; interactive streams from this attempt to report
 765                  ;; positions.  -- CSR, 2003-08-21
 766                  (not (interactive-stream-p error-stream))
 767                  (file-position error-stream :start))
 768         (let ((string
 769                (make-string pos
 770                             :element-type (stream-element-type
 771                                            error-stream))))
 772           (when (= pos (read-sequence string error-stream))
 773             (setq lineno (1+ (count #\Newline string))
 774                   colno (- pos
 775                            (or (position #\Newline string :from-end t) -1)
 776                            1))))
 777         (file-position-or-nil-for-error error-stream pos))
 778       (pprint-logical-block (stream nil)
 779         (format stream
 780                 "~S ~@[at ~W ~]~
 781                     ~@[(line ~W~]~@[, column ~W) ~]~
 782                     on ~S"
 783                 (class-name (class-of condition))
 784                 pos lineno colno error-stream)
 785         (when simple
 786           (format stream ":~2I~_~?"
 787                   (simple-condition-format-control condition)
 788                   (simple-condition-format-arguments condition)))))))
 789 \f
 790 ;;;; special SBCL extension conditions
 791
 792 ;;; an error apparently caused by a bug in SBCL itself
 793 ;;;
 794 ;;; Note that we don't make any serious effort to use this condition
 795 ;;; for *all* errors in SBCL itself. E.g. type errors and array
 796 ;;; indexing errors can occur in functions called from SBCL code, and
 797 ;;; will just end up as ordinary TYPE-ERROR or invalid index error,
 798 ;;; because the signalling code has no good way to know that the
 799 ;;; underlying problem is a bug in SBCL. But in the fairly common case
 800 ;;; that the signalling code does know that it's found a bug in SBCL,
 801 ;;; this condition is appropriate, reusing boilerplate and helping
 802 ;;; users to recognize it as an SBCL bug.
 803 (define-condition bug (simple-error)
 804   ()
 805   (:report
 806    (lambda (condition stream)
 807      (format stream
 808              "~@<  ~? ~:@_~?~:>"
 809              (simple-condition-format-control condition)
 810              (simple-condition-format-arguments condition)
 811              "~@<This is probably a bug in SBCL itself. (Alternatively, ~
 812               SBCL might have been corrupted by bad user code, e.g. by an ~
 813               undefined Lisp operation like ~S, or by stray pointers from ~
 814               alien code or from unsafe Lisp code; or there might be a bug ~
 815               in the OS or hardware that SBCL is running on.) If it seems to ~
 816               be a bug in SBCL itself, the maintainers would like to know ~
 817               about it. Bug reports are welcome on the SBCL ~
 818               mailing lists, which you can find at ~
 819               <http://sbcl.sourceforge.net/>.~:@>"
 820              '((fmakunbound 'compile))))))
 821
 822 (define-condition simple-storage-condition (storage-condition simple-condition)
 823   ())
 824
 825 ;;; a condition for use in stubs for operations which aren't supported
 826 ;;; on some platforms
 827 ;;;
 828 ;;; E.g. in sbcl-0.7.0.5, it might be appropriate to do something like
 829 ;;;   #-(or freebsd linux)
 830 ;;;   (defun load-foreign (&rest rest)
 831 ;;;     (error 'unsupported-operator :name 'load-foreign))
 832 ;;;   #+(or freebsd linux)
 833 ;;;   (defun load-foreign ... actual definition ...)
 834 ;;; By signalling a standard condition in this case, we make it
 835 ;;; possible for test code to distinguish between (1) intentionally
 836 ;;; unimplemented and (2) unintentionally just screwed up somehow.
 837 ;;; (Before this condition was defined, test code tried to deal with
 838 ;;; this by checking for FBOUNDP, but that didn't work reliably. In
 839 ;;; sbcl-0.7.0, a package screwup left the definition of
 840 ;;; LOAD-FOREIGN in the wrong package, so it was unFBOUNDP even on
 841 ;;; architectures where it was supposed to be supported, and the
 842 ;;; regression tests cheerfully passed because they assumed that
 843 ;;; unFBOUNDPness meant they were running on an system which didn't
 844 ;;; support the extension.)
 845 (define-condition unsupported-operator (simple-error) ())
 846 \f
 847 ;;; (:ansi-cl :function remove)
 848 ;;; (:ansi-cl :section (a b c))
 849 ;;; (:ansi-cl :glossary "similar")
 850 ;;;
 851 ;;; (:sbcl :node "...")
 852 ;;; (:sbcl :variable *ed-functions*)
 853 ;;;
 854 ;;; FIXME: this is not the right place for this.
 855 (defun print-reference (reference stream)
 856   (ecase (car reference)
 857     (:amop
 858      (format stream "AMOP")
 859      (format stream ", ")
 860      (destructuring-bind (type data) (cdr reference)
 861        (ecase type
 862          (:readers "Readers for ~:(~A~) Metaobjects"
 863                    (substitute #\  #\- (symbol-name data)))
 864          (:initialization
 865           (format stream "Initialization of ~:(~A~) Metaobjects"
 866                   (substitute #\  #\- (symbol-name data))))
 867          (:generic-function (format stream "Generic Function ~S" data))
 868          (:function (format stream "Function ~S" data))
 869          (:section (format stream "Section ~{~D~^.~}" data)))))
 870     (:ansi-cl
 871      (format stream "The ANSI Standard")
 872      (format stream ", ")
 873      (destructuring-bind (type data) (cdr reference)
 874        (ecase type
 875          (:function (format stream "Function ~S" data))
 876          (:special-operator (format stream "Special Operator ~S" data))
 877          (:macro (format stream "Macro ~S" data))
 878          (:section (format stream "Section ~{~D~^.~}" data))
 879          (:glossary (format stream "Glossary entry for ~S" data))
 880          (:issue (format stream "writeup for Issue ~A" data)))))
 881     (:sbcl
 882      (format stream "The SBCL Manual")
 883      (format stream ", ")
 884      (destructuring-bind (type data) (cdr reference)
 885        (ecase type
 886          (:node (format stream "Node ~S" data))
 887          (:variable (format stream "Variable ~S" data))
 888          (:function (format stream "Function ~S" data)))))
 889     ;; FIXME: other documents (e.g. CLIM, Franz documentation :-)
 890     ))
 891 (define-condition reference-condition ()
 892   ((references :initarg :references :reader reference-condition-references)))
 893 (defvar *print-condition-references* t)
 894 (def!method print-object :around ((o reference-condition) s)
 895   (call-next-method)
 896   (unless (or *print-escape* *print-readably*)
 897     (when (and *print-condition-references*
 898                (reference-condition-references o))
 899       (format s "~&See also:~%")
 900       (pprint-logical-block (s nil :per-line-prefix "  ")
 901         (do* ((rs (reference-condition-references o) (cdr rs))
 902               (r (car rs) (car rs)))
 903              ((null rs))
 904           (print-reference r s)
 905           (unless (null (cdr rs))
 906             (terpri s)))))))
 907
 908 (define-condition simple-reference-error (reference-condition simple-error)
 909   ())
 910
 911 (define-condition simple-reference-warning (reference-condition simple-warning)
 912   ())
 913
 914 (define-condition duplicate-definition (reference-condition warning)
 915   ((name :initarg :name :reader duplicate-definition-name))
 916   (:report (lambda (c s)
 917              (format s "~@<Duplicate definition for ~S found in ~
 918                         one file.~@:>"
 919                      (duplicate-definition-name c))))
 920   (:default-initargs :references (list '(:ansi-cl :section (3 2 2 3)))))
 921
 922 (define-condition constant-modified (reference-condition warning)
 923   ((fun-name :initarg :fun-name :reader constant-modified-fun-name))
 924   (:report (lambda (c s)
 925              (format s "~@<Destructive function ~S called on ~
 926                         constant data.~@:>"
 927                      (constant-modified-fun-name c))))
 928   (:default-initargs :references (list '(:ansi-cl :special-operator quote)
 929                                        '(:ansi-cl :section (3 2 2 3)))))
 930
 931 (define-condition package-at-variance (reference-condition simple-warning)
 932   ()
 933   (:default-initargs :references (list '(:ansi-cl :macro defpackage))))
 934
 935 (define-condition defconstant-uneql (reference-condition error)
 936   ((name :initarg :name :reader defconstant-uneql-name)
 937    (old-value :initarg :old-value :reader defconstant-uneql-old-value)
 938    (new-value :initarg :new-value :reader defconstant-uneql-new-value))
 939   (:report
 940    (lambda (condition stream)
 941      (format stream
 942              "~@<The constant ~S is being redefined (from ~S to ~S)~@:>"
 943              (defconstant-uneql-name condition)
 944              (defconstant-uneql-old-value condition)
 945              (defconstant-uneql-new-value condition))))
 946   (:default-initargs :references (list '(:ansi-cl :macro defconstant)
 947                                        '(:sbcl :node "Idiosyncrasies"))))
 948
 949 (define-condition array-initial-element-mismatch
 950     (reference-condition simple-warning)
 951   ()
 952   (:default-initargs
 953       :references (list
 954                    '(:ansi-cl :function make-array)
 955                    '(:ansi-cl :function sb!xc:upgraded-array-element-type))))
 956
 957 (define-condition type-warning (reference-condition simple-warning)
 958   ()
 959   (:default-initargs :references (list '(:sbcl :node "Handling of Types"))))
 960
 961 (define-condition local-argument-mismatch (reference-condition simple-warning)
 962   ()
 963   (:default-initargs :references (list '(:ansi-cl :section (3 2 2 3)))))
 964
 965 (define-condition format-args-mismatch (reference-condition)
 966   ()
 967   (:default-initargs :references (list '(:ansi-cl :section (22 3 10 2)))))
 968
 969 (define-condition format-too-few-args-warning
 970     (format-args-mismatch simple-warning)
 971   ())
 972 (define-condition format-too-many-args-warning
 973     (format-args-mismatch simple-style-warning)
 974   ())
 975
 976 (define-condition implicit-generic-function-warning (style-warning)
 977   ((name :initarg :name :reader implicit-generic-function-name))
 978   (:report
 979    (lambda (condition stream)
 980      (format stream "~@<Implicitly creating new generic function ~S.~:@>"
 981              (implicit-generic-function-name condition)))))
 982
 983 (define-condition extension-failure (reference-condition simple-error)
 984   ())
 985
 986 (define-condition structure-initarg-not-keyword
 987     (reference-condition simple-style-warning)
 988   ()
 989   (:default-initargs :references (list '(:ansi-cl :section (2 4 8 13)))))
 990
 991 #!+sb-package-locks
 992 (progn
 993
 994 (define-condition package-lock-violation (reference-condition package-error)
 995   ((format-control :initform nil :initarg :format-control
 996                    :reader package-error-format-control)
 997    (format-arguments :initform nil :initarg :format-arguments
 998                      :reader package-error-format-arguments))
 999   (:report
1000    (lambda (condition stream)
1001      (let ((control (package-error-format-control condition)))
1002        (if control
1003            (apply #'format stream
1004                   (format nil "~~@<Lock on package ~A violated when ~A.~~:@>"
1005                           (package-name (package-error-package condition))
1006                           control)
1007                   (package-error-format-arguments condition))
1008            (format stream "~@<Lock on package ~A violated.~:@>"
1009                    (package-name (package-error-package condition)))))))
1010   ;; no :default-initargs -- reference-stuff provided by the
1011   ;; signalling form in target-package.lisp
1012   #!+sb-doc
1013   (:documentation
1014    "Subtype of CL:PACKAGE-ERROR. A subtype of this error is signalled
1015 when a package-lock is violated."))
1016
1017 (define-condition package-locked-error (package-lock-violation) ()
1018   #!+sb-doc
1019   (:documentation
1020    "Subtype of SB-EXT:PACKAGE-LOCK-VIOLATION. An error of this type is
1021 signalled when an operation on a package violates a package lock."))
1022
1023 (define-condition symbol-package-locked-error (package-lock-violation)
1024   ((symbol :initarg :symbol :reader package-locked-error-symbol))
1025   #!+sb-doc
1026   (:documentation
1027    "Subtype of SB-EXT:PACKAGE-LOCK-VIOLATION. An error of this type is
1028 signalled when an operation on a symbol violates a package lock. The
1029 symbol that caused the violation is accessed by the function
1030 SB-EXT:PACKAGE-LOCKED-ERROR-SYMBOL."))
1031
1032 ) ; progn
1033
1034 (define-condition undefined-alien-error (cell-error) ()
1035   (:report
1036    (lambda (condition stream)
1037      (if (slot-boundp condition 'name)
1038          (format stream "Undefined alien: ~S" (cell-error-name condition))
1039          (format stream "Undefined alien symbol.")))))
1040
1041 (define-condition undefined-alien-variable-error (undefined-alien-error) ()
1042   (:report
1043    (lambda (condition stream)
1044      (declare (ignore condition))
1045      (format stream "Attempt to access an undefined alien variable."))))
1046
1047 (define-condition undefined-alien-function-error (undefined-alien-error) ()
1048   (:report
1049    (lambda (condition stream)
1050      (declare (ignore condition))
1051      (format stream "Attempt to call an undefined alien function."))))
1052
1053 \f
1054 ;;;; various other (not specified by ANSI) CONDITIONs
1055 ;;;;
1056 ;;;; These might logically belong in other files; they're here, after
1057 ;;;; setup of CONDITION machinery, only because that makes it easier to
1058 ;;;; get cold init to work.
1059
1060 ;;; OAOOM warning: see cross-condition.lisp
1061 (define-condition encapsulated-condition (condition)
1062   ((condition :initarg :condition :reader encapsulated-condition)))
1063
1064 (define-condition values-type-error (type-error)
1065   ()
1066   (:report
1067    (lambda (condition stream)
1068      (format stream
1069              "~@<The values set ~2I~:_[~{~S~^ ~}] ~I~_is not of type ~2I~_~S.~:>"
1070              (type-error-datum condition)
1071              (type-error-expected-type condition)))))
1072
1073 ;;; KLUDGE: a condition for floating point errors when we can't or
1074 ;;; won't figure out what type they are. (In FreeBSD and OpenBSD we
1075 ;;; don't know how, at least as of sbcl-0.6.7; in Linux we probably
1076 ;;; know how but the old code was broken by the conversion to POSIX
1077 ;;; signal handling and hasn't been fixed as of sbcl-0.6.7.)
1078 ;;;
1079 ;;; FIXME: Perhaps this should also be a base class for all
1080 ;;; floating point exceptions?
1081 (define-condition floating-point-exception (arithmetic-error)
1082   ((flags :initarg :traps
1083           :initform nil
1084           :reader floating-point-exception-traps))
1085   (:report (lambda (condition stream)
1086              (format stream
1087                      "An arithmetic error ~S was signalled.~%"
1088                      (type-of condition))
1089              (let ((traps (floating-point-exception-traps condition)))
1090                (if traps
1091                    (format stream
1092                            "Trapping conditions are: ~%~{ ~S~^~}~%"
1093                            traps)
1094                    (write-line
1095                     "No traps are enabled? How can this be?"
1096                     stream))))))
1097
1098 (define-condition invalid-array-index-error (type-error)
1099   ((array :initarg :array :reader invalid-array-index-error-array)
1100    (axis :initarg :axis :reader invalid-array-index-error-axis))
1101   (:report
1102    (lambda (condition stream)
1103      (let ((array (invalid-array-index-error-array condition)))
1104        (format stream "Index ~W out of bounds for ~@[axis ~W of ~]~S, ~
1105                        should be nonnegative and <~W."
1106                (type-error-datum condition)
1107                (when (> (array-rank array) 1)
1108                  (invalid-array-index-error-axis condition))
1109                (type-of array)
1110                ;; Extract the bound from (INTEGER 0 (BOUND))
1111                (caaddr (type-error-expected-type condition)))))))
1112
1113 (define-condition invalid-array-error (reference-condition type-error) ()
1114   (:report
1115    (lambda (condition stream)
1116      (let ((*print-array* nil))
1117        (format stream
1118                "~@<Displaced array originally of type ~S has been invalidated ~
1119                 due its displaced-to array ~S having become too small to hold ~
1120                 it: the displaced array's dimensions have all been set to zero ~
1121                 to trap accesses to it.~:@>"
1122                (type-error-expected-type condition)
1123                (array-displacement (type-error-datum condition))))))
1124   (:default-initargs
1125       :references
1126       (list '(:ansi-cl :function adjust-array))))
1127
1128 (define-condition index-too-large-error (type-error)
1129   ()
1130   (:report
1131    (lambda (condition stream)
1132      (format stream
1133              "The index ~S is too large."
1134              (type-error-datum condition)))))
1135
1136 (define-condition bounding-indices-bad-error (reference-condition type-error)
1137   ((object :reader bounding-indices-bad-object :initarg :object))
1138   (:report
1139    (lambda (condition stream)
1140      (let* ((datum (type-error-datum condition))
1141             (start (car datum))
1142             (end (cdr datum))
1143             (object (bounding-indices-bad-object condition)))
1144        (etypecase object
1145          (sequence
1146           (format stream
1147                   "The bounding indices ~S and ~S are bad ~
1148                    for a sequence of length ~S."
1149                   start end (length object)))
1150          (array
1151           ;; from WITH-ARRAY-DATA
1152           (format stream
1153                   "The START and END parameters ~S and ~S are ~
1154                    bad for an array of total size ~S."
1155                   start end (array-total-size object)))))))
1156   (:default-initargs
1157       :references
1158       (list '(:ansi-cl :glossary "bounding index designator")
1159             '(:ansi-cl :issue "SUBSEQ-OUT-OF-BOUNDS:IS-AN-ERROR"))))
1160
1161 (define-condition nil-array-accessed-error (reference-condition type-error)
1162   ()
1163   (:report (lambda (condition stream)
1164              (declare (ignore condition))
1165              (format stream
1166                      "An attempt to access an array of element-type ~
1167                       NIL was made.  Congratulations!")))
1168   (:default-initargs
1169       :references (list '(:ansi-cl :function sb!xc:upgraded-array-element-type)
1170                         '(:ansi-cl :section (15 1 2 1))
1171                         '(:ansi-cl :section (15 1 2 2)))))
1172
1173 (define-condition namestring-parse-error (parse-error)
1174   ((complaint :reader namestring-parse-error-complaint :initarg :complaint)
1175    (args :reader namestring-parse-error-args :initarg :args :initform nil)
1176    (namestring :reader namestring-parse-error-namestring :initarg :namestring)
1177    (offset :reader namestring-parse-error-offset :initarg :offset))
1178   (:report
1179    (lambda (condition stream)
1180      (format stream
1181              "parse error in namestring: ~?~%  ~A~%  ~V@T^"
1182              (namestring-parse-error-complaint condition)
1183              (namestring-parse-error-args condition)
1184              (namestring-parse-error-namestring condition)
1185              (namestring-parse-error-offset condition)))))
1186
1187 (define-condition simple-package-error (simple-condition package-error) ())
1188
1189 (define-condition simple-reader-package-error (simple-reader-error) ())
1190
1191 (define-condition reader-eof-error (end-of-file)
1192   ((context :reader reader-eof-error-context :initarg :context))
1193   (:report
1194    (lambda (condition stream)
1195      (format stream
1196              "unexpected end of file on ~S ~A"
1197              (stream-error-stream condition)
1198              (reader-eof-error-context condition)))))
1199
1200 (define-condition reader-impossible-number-error (simple-reader-error)
1201   ((error :reader reader-impossible-number-error-error :initarg :error))
1202   (:report
1203    (lambda (condition stream)
1204      (let ((error-stream (stream-error-stream condition)))
1205        (format stream
1206                "READER-ERROR ~@[at ~W ~]on ~S:~%~?~%Original error: ~A"
1207                (file-position-or-nil-for-error error-stream) error-stream
1208                (simple-condition-format-control condition)
1209                (simple-condition-format-arguments condition)
1210                (reader-impossible-number-error-error condition))))))
1211
1212 (define-condition standard-readtable-modified-error (reference-condition error)
1213   ((operation :initarg :operation :reader standard-readtable-modified-operation))
1214   (:report (lambda (condition stream)
1215              (format stream "~S would modify the standard readtable."
1216                      (standard-readtable-modified-operation condition))))
1217   (:default-initargs :references `((:ansi-cl :section (2 1 1 2))
1218                                    (:ansi-cl :glossary "standard readtable"))))
1219
1220 (define-condition timeout (serious-condition)
1221   ((seconds :initarg :seconds :initform nil :reader timeout-seconds))
1222   (:report (lambda (condition stream)
1223              (format stream "Timeout occurred~@[ after ~A seconds~]."
1224                      (timeout-seconds condition)))))
1225
1226 (define-condition io-timeout (stream-error timeout)
1227   ((direction :reader io-timeout-direction :initarg :direction))
1228   (:report
1229    (lambda (condition stream)
1230      (declare (type stream stream))
1231      (format stream
1232              "I/O timeout ~(~A~)ing ~S."
1233              (io-timeout-direction condition)
1234              (stream-error-stream condition)))))
1235
1236 (define-condition deadline-timeout (timeout) ()
1237   (:report (lambda (condition stream)
1238              (format stream "A deadline was reached after ~A seconds."
1239                      (timeout-seconds condition)))))
1240
1241 (define-condition declaration-type-conflict-error (reference-condition
1242                                                    simple-error)
1243   ()
1244   (:default-initargs
1245       :format-control "symbol ~S cannot be both the name of a type and the name of a declaration"
1246     :references (list '(:ansi-cl :section (3 8 21)))))
1247
1248 ;;; Single stepping conditions
1249
1250 (define-condition step-condition ()
1251   ((form :initarg :form :reader step-condition-form))
1252
1253   #!+sb-doc
1254   (:documentation "Common base class of single-stepping conditions.
1255 STEP-CONDITION-FORM holds a string representation of the form being
1256 stepped."))
1257
1258 #!+sb-doc
1259 (setf (fdocumentation 'step-condition-form 'function)
1260       "Form associated with the STEP-CONDITION.")
1261
1262 (define-condition step-form-condition (step-condition)
1263   ((args :initarg :args :reader step-condition-args))
1264   (:report
1265    (lambda (condition stream)
1266      (let ((*print-circle* t)
1267            (*print-pretty* t)
1268            (*print-readably* nil))
1269        (format stream
1270                  "Evaluating call:~%~<  ~@;~A~:>~%~
1271                   ~:[With arguments:~%~{  ~S~%~}~;With unknown arguments~]~%"
1272                (list (step-condition-form condition))
1273                (eq (step-condition-args condition) :unknown)
1274                (step-condition-args condition)))))
1275   #!+sb-doc
1276   (:documentation "Condition signalled by code compiled with
1277 single-stepping information when about to execute a form.
1278 STEP-CONDITION-FORM holds the form, STEP-CONDITION-PATHNAME holds the
1279 pathname of the original file or NIL, and STEP-CONDITION-SOURCE-PATH
1280 holds the source-path to the original form within that file or NIL.
1281 Associated with this condition are always the restarts STEP-INTO,
1282 STEP-NEXT, and STEP-CONTINUE."))
1283
1284 #!+sb-doc
1285 (setf (fdocumentation 'step-condition-source-path 'function)
1286       "Source-path of the original form associated with the
1287 STEP-FORM-CONDITION or NIL."
1288       (fdocumentation 'step-condition-pathname 'function)
1289       "Pathname of the original source-file associated with the
1290 STEP-FORM-CONDITION or NIL.")
1291
1292 (define-condition step-result-condition (step-condition)
1293   ((result :initarg :result :reader step-condition-result)))
1294
1295 #!+sb-doc
1296 (setf (fdocumentation 'step-condition-result 'function)
1297       "Return values associated with STEP-VALUES-CONDITION as a list,
1298 or the variable value associated with STEP-VARIABLE-CONDITION.")
1299
1300 (define-condition step-values-condition (step-result-condition)
1301   ()
1302   #!+sb-doc
1303   (:documentation "Condition signalled by code compiled with
1304 single-stepping information after executing a form.
1305 STEP-CONDITION-FORM holds the form, and STEP-CONDITION-RESULT holds
1306 the values returned by the form as a list. No associated restarts."))
1307
1308 (define-condition step-finished-condition (step-condition)
1309   ()
1310   (:report
1311    (lambda (condition stream)
1312      (declare (ignore condition))
1313      (format stream "Returning from STEP")))
1314   #!+sb-doc
1315   (:documentation "Condition signaled when STEP returns."))
1316 \f
1317 ;;; A knob for muffling warnings, mostly for use while loading files.
1318 (defvar *muffled-warnings* 'uninteresting-redefinition
1319   "A type that ought to specify a subtype of WARNING.  Whenever a
1320 warning is signaled, if the warning if of this type and is not
1321 handled by any other handler, it will be muffled.")
1322 \f
1323 ;;; Various STYLE-WARNING signaled in the system.
1324 ;; For the moment, we're only getting into the details for function
1325 ;; redefinitions, but other redefinitions could be done later
1326 ;; (e.g. methods).
1327 (define-condition redefinition-warning (style-warning)
1328   ())
1329
1330 (define-condition function-redefinition-warning (redefinition-warning)
1331   ((name :initarg :name :reader function-redefinition-warning-name)
1332    (old :initarg :old :reader function-redefinition-warning-old-fdefinition)
1333    ;; For DEFGENERIC and perhaps others, the redefinition
1334    ;; destructively modifies the original, rather than storing a new
1335    ;; object, so there's no NEW here, but only in subclasses.
1336    ))
1337
1338 (define-condition redefinition-with-defun (function-redefinition-warning)
1339   ((new :initarg :new :reader redefinition-with-defun-new-fdefinition)
1340    ;; KLUDGE: it would be nice to fix the unreasonably late
1341    ;; back-patching of DEBUG-SOURCEs in the DEBUG-INFO during
1342    ;; fasloading and just use the new fdefinition, but for the moment
1343    ;; we'll compare the SOURCE-LOCATION created during DEFUN with the
1344    ;; previous DEBUG-SOURCE.
1345    (new-location :initarg :new-location
1346               :reader redefinition-with-defun-new-location))
1347   (:report (lambda (warning stream)
1348              (format stream "redefining ~S in DEFUN"
1349                      (function-redefinition-warning-name warning)))))
1350
1351 (define-condition redefinition-with-defgeneric (function-redefinition-warning)
1352   ((new-location :initarg :new-location
1353                  :reader redefinition-with-defgeneric-new-location))
1354   (:report (lambda (warning stream)
1355              (format stream "redefining ~S in DEFGENERIC"
1356                      (function-redefinition-warning-name warning)))))
1357
1358 (define-condition redefinition-with-defmethod (redefinition-warning)
1359   ((gf :initarg :generic-function
1360        :reader redefinition-with-defmethod-generic-function)
1361    (qualifiers :initarg :qualifiers
1362                :reader redefinition-with-defmethod-qualifiers)
1363    (specializers :initarg :specializers
1364                  :reader redefinition-with-defmethod-specializers)
1365    (new-location :initarg :new-location
1366                  :reader redefinition-with-defmethod-new-location)
1367    (old-method :initarg :old-method
1368                :reader redefinition-with-defmethod-old-method))
1369   (:report (lambda (warning stream)
1370              (format stream "redefining ~S~{ ~S~} ~S in DEFMETHOD"
1371                      (redefinition-with-defmethod-generic-function warning)
1372                      (redefinition-with-defmethod-qualifiers warning)
1373                      (redefinition-with-defmethod-specializers warning)))))
1374
1375 ;; FIXME: see the FIXMEs in defmacro.lisp, then maybe instantiate this.
1376 (define-condition redefinition-with-defmacro (function-redefinition-warning)
1377   ())
1378
1379 ;; Here are a few predicates for what people might find interesting
1380 ;; about redefinitions.
1381
1382 ;; DEFUN can replace a generic function with an ordinary function.
1383 ;; (Attempting to replace an ordinary function with a generic one
1384 ;; causes an error, though.)
1385 (defun redefinition-replaces-generic-function-p (warning)
1386   (and (typep warning 'redefinition-with-defun)
1387        (typep (function-redefinition-warning-old-fdefinition warning)
1388               'generic-function)))
1389
1390 (defun redefinition-replaces-compiled-function-with-interpreted-p (warning)
1391   (and (typep warning 'redefinition-with-defun)
1392        (compiled-function-p
1393         (function-redefinition-warning-old-fdefinition warning))
1394        (not (compiled-function-p
1395              (redefinition-with-defun-new-fdefinition warning)))))
1396
1397 ;; Most people seem to agree that re-running a DEFUN in a file is
1398 ;; completely uninteresting.
1399 (defun uninteresting-ordinary-function-redefinition-p (warning)
1400   ;; OAOO violation: this duplicates code in SB-INTROSPECT.
1401   ;; Additionally, there are some functions that aren't
1402   ;; funcallable-instances for which finding the source location is
1403   ;; complicated (e.g. DEFSTRUCT-defined predicates and accessors),
1404   ;; but I don't think they're defined with %DEFUN, so the warning
1405   ;; isn't raised.
1406   (flet ((fdefinition-file-namestring (fdefn)
1407            #!+sb-eval
1408            (when (typep fdefn 'sb!eval:interpreted-function)
1409              (return-from fdefinition-file-namestring
1410                (sb!c:definition-source-location-namestring
1411                    (sb!eval:interpreted-function-source-location fdefn))))
1412            ;; All the following accesses are guarded with conditionals
1413            ;; because it's not clear whether any of the slots we're
1414            ;; chasing down are guaranteed to be filled in.
1415            (let* ((fdefn
1416                    ;; KLUDGE: although this looks like it only works
1417                    ;; for %SIMPLE-FUNs, in fact there's a pun such
1418                    ;; that %SIMPLE-FUN-SELF returns the simple-fun
1419                    ;; object for closures and
1420                    ;; funcallable-instances. -- CSR, circa 2005
1421                    (sb!kernel:%simple-fun-self fdefn))
1422                   (code (if fdefn (sb!kernel:fun-code-header fdefn)))
1423                   (debug-info (if code (sb!kernel:%code-debug-info code)))
1424                   (debug-source (if debug-info
1425                                     (sb!c::debug-info-source debug-info)))
1426                   (namestring (if debug-source
1427                                   (sb!c::debug-source-namestring debug-source))))
1428              namestring)))
1429     (and
1430      ;; There's garbage in various places when the first DEFUN runs in
1431      ;; cold-init.
1432      sb!kernel::*cold-init-complete-p*
1433      (typep warning 'redefinition-with-defun)
1434      (let ((old-fdefn
1435             (function-redefinition-warning-old-fdefinition warning))
1436            (new-fdefn
1437             (redefinition-with-defun-new-fdefinition warning)))
1438        ;; Replacing a compiled function with a compiled function is
1439        ;; clearly uninteresting, and we'll say arbitrarily that
1440        ;; replacing an interpreted function with an interpreted
1441        ;; function is uninteresting, too, but leave out the
1442        ;; compiled-to-interpreted case.
1443        (when (or (typep
1444                   old-fdefn
1445                   '(or #!+sb-eval sb!eval:interpreted-function))
1446                  (and (typep old-fdefn
1447                              '(and compiled-function
1448                                (not funcallable-instance)))
1449                       ;; Since this is a REDEFINITION-WITH-DEFUN,
1450                       ;; NEW-FDEFN can't be a FUNCALLABLE-INSTANCE.
1451                       (typep new-fdefn 'compiled-function)))
1452          (let* ((old-namestring (fdefinition-file-namestring old-fdefn))
1453                 (new-namestring
1454                  (or (fdefinition-file-namestring new-fdefn)
1455                      (let ((srcloc
1456                             (redefinition-with-defun-new-location warning)))
1457                        (if srcloc
1458                             (sb!c::definition-source-location-namestring
1459                                 srcloc))))))
1460            (and old-namestring
1461                 new-namestring
1462                 (equal old-namestring new-namestring))))))))
1463
1464 (defun uninteresting-generic-function-redefinition-p (warning)
1465   (and (typep warning 'redefinition-with-defgeneric)
1466        (let* ((old-fdefn
1467                (function-redefinition-warning-old-fdefinition warning))
1468               (old-location
1469                (if (typep old-fdefn 'generic-function)
1470                    (sb!pcl::definition-source old-fdefn)))
1471               (old-namestring
1472                (if old-location
1473                    (sb!c:definition-source-location-namestring old-location)))
1474               (new-location
1475                (redefinition-with-defgeneric-new-location warning))
1476               (new-namestring
1477                (if new-location
1478                    (sb!c:definition-source-location-namestring new-location))))
1479          (and old-namestring
1480               new-namestring
1481               (equal old-namestring new-namestring)))))
1482
1483 (defun uninteresting-method-redefinition-p (warning)
1484   (and (typep warning 'redefinition-with-defmethod)
1485        (let* ((old-method (redefinition-with-defmethod-old-method warning))
1486               (old-location (sb!pcl::definition-source old-method))
1487               (old-namestring (if old-location
1488                                   (sb!c:definition-source-location-namestring
1489                                       old-location)))
1490               (new-location (redefinition-with-defmethod-new-location warning))
1491               (new-namestring (if new-location
1492                                   (sb!c:definition-source-location-namestring
1493                                       new-location))))
1494          (and new-namestring
1495               old-namestring
1496               (equal new-namestring old-namestring)))))
1497
1498 (deftype uninteresting-redefinition ()
1499   '(or (satisfies uninteresting-ordinary-function-redefinition-p)
1500        (satisfies uninteresting-generic-function-redefinition-p)
1501        (satisfies uninteresting-method-redefinition-p)))
1502
1503 (define-condition redefinition-with-deftransform (redefinition-warning)
1504   ((transform :initarg :transform
1505               :reader redefinition-with-deftransform-transform))
1506   (:report (lambda (warning stream)
1507              (format stream "Overwriting ~S"
1508                      (redefinition-with-deftransform-transform warning)))))
1509 \f
1510 ;;; Various other STYLE-WARNINGS
1511 (define-condition dubious-asterisks-around-variable-name
1512     (style-warning simple-condition)
1513   ()
1514   (:report (lambda (warning stream)
1515              (format stream "~@?, even though the name follows~@
1516 the usual naming convention (names like *FOO*) for special variables"
1517                      (simple-condition-format-control warning)
1518                      (simple-condition-format-arguments warning)))))
1519
1520 (define-condition asterisks-around-lexical-variable-name
1521     (dubious-asterisks-around-variable-name)
1522   ())
1523
1524 (define-condition asterisks-around-constant-variable-name
1525     (dubious-asterisks-around-variable-name)
1526   ())
1527
1528 ;; We call this UNDEFINED-ALIEN-STYLE-WARNING because there are some
1529 ;; subclasses of ERROR above having to do with undefined aliens.
1530 (define-condition undefined-alien-style-warning (style-warning)
1531   ((symbol :initarg :symbol :reader undefined-alien-symbol))
1532   (:report (lambda (warning stream)
1533              (format stream "Undefined alien: ~S"
1534                      (undefined-alien-symbol warning)))))
1535
1536 #!+sb-eval
1537 (define-condition lexical-environment-too-complex (style-warning)
1538   ((form :initarg :form :reader lexical-environment-too-complex-form)
1539    (lexenv :initarg :lexenv :reader lexical-environment-too-complex-lexenv))
1540   (:report (lambda (warning stream)
1541              (format stream
1542                      "~@<Native lexical environment too complex for ~
1543                          SB-EVAL to evaluate ~S, falling back to ~
1544                          SIMPLE-EVAL-IN-LEXENV.  Lexenv: ~S~:@>"
1545                      (lexical-environment-too-complex-form warning)
1546                      (lexical-environment-too-complex-lexenv warning)))))
1547
1548 ;; Although this has -ERROR- in the name, it's just a STYLE-WARNING.
1549 (define-condition character-decoding-error-in-comment (style-warning)
1550   ((stream :initarg :stream :reader decoding-error-in-comment-stream)
1551    (position :initarg :position :reader decoding-error-in-comment-position))
1552   (:report (lambda (warning stream)
1553              (format stream
1554                       "Character decoding error in a ~A-comment at ~
1555                       position ~A reading source stream ~A, ~
1556                       resyncing."
1557                       (decoding-error-in-comment-macro warning)
1558                       (decoding-error-in-comment-position warning)
1559                       (decoding-error-in-comment-stream warning)))))
1560
1561 (define-condition character-decoding-error-in-macro-char-comment
1562     (character-decoding-error-in-comment)
1563   ((char :initform #\; :initarg :char
1564          :reader character-decoding-error-in-macro-char-comment-char)))
1565
1566 (define-condition character-decoding-error-in-dispatch-macro-char-comment
1567     (character-decoding-error-in-comment)
1568   ;; ANSI doesn't give a way for a reader function invoked by a
1569   ;; dispatch macro character to determine which dispatch character
1570   ;; was used, so if a user wants to signal one of these from a custom
1571   ;; comment reader, he'll have to supply the :DISP-CHAR himself.
1572   ((disp-char :initform #\# :initarg :disp-char
1573               :reader character-decoding-error-in-macro-char-comment-disp-char)
1574    (sub-char :initarg :sub-char
1575              :reader character-decoding-error-in-macro-char-comment-sub-char)))
1576
1577 (defun decoding-error-in-comment-macro (warning)
1578   (etypecase warning
1579     (character-decoding-error-in-macro-char-comment
1580      (character-decoding-error-in-macro-char-comment-char warning))
1581     (character-decoding-error-in-dispatch-macro-char-comment
1582      (format
1583       nil "~C~C"
1584       (character-decoding-error-in-macro-char-comment-disp-char warning)
1585       (character-decoding-error-in-macro-char-comment-sub-char warning)))))
1586
1587 (define-condition deprecated-eval-when-situations (style-warning)
1588   ((situations :initarg :situations
1589                :reader deprecated-eval-when-situations-situations))
1590   (:report (lambda (warning stream)
1591              (format stream "using deprecated EVAL-WHEN situation names~{ ~S~}"
1592                      (deprecated-eval-when-situations-situations warning)))))
1593
1594 (define-condition proclamation-mismatch (style-warning)
1595   ((name :initarg :name :reader proclamation-mismatch-name)
1596    (old :initarg :old :reader proclamation-mismatch-old)
1597    (new :initarg :new :reader proclamation-mismatch-new)))
1598
1599 (define-condition type-proclamation-mismatch (proclamation-mismatch)
1600   ()
1601   (:report (lambda (warning stream)
1602              (format stream
1603                      "The new TYPE proclamation~% ~S for ~S does not ~
1604                      match the old TYPE proclamation ~S"
1605                      (proclamation-mismatch-new warning)
1606                      (proclamation-mismatch-name warning)
1607                      (proclamation-mismatch-old warning)))))
1608
1609 (define-condition ftype-proclamation-mismatch (proclamation-mismatch)
1610   ()
1611   (:report (lambda (warning stream)
1612              (format stream
1613                      "The new FTYPE proclamation~% ~S for ~S does not ~
1614                      match the old FTYPE proclamation ~S"
1615                      (proclamation-mismatch-new warning)
1616                      (proclamation-mismatch-name warning)
1617                      (proclamation-mismatch-old warning)))))
1618 \f
1619 ;;;; restart definitions
1620
1621 (define-condition abort-failure (control-error) ()
1622   (:report
1623    "An ABORT restart was found that failed to transfer control dynamically."))
1624
1625 (defun abort (&optional condition)
1626   #!+sb-doc
1627   "Transfer control to a restart named ABORT, signalling a CONTROL-ERROR if
1628    none exists."
1629   (invoke-restart (find-restart-or-control-error 'abort condition))
1630   ;; ABORT signals an error in case there was a restart named ABORT
1631   ;; that did not transfer control dynamically. This could happen with
1632   ;; RESTART-BIND.
1633   (error 'abort-failure))
1634
1635 (defun muffle-warning (&optional condition)
1636   #!+sb-doc
1637   "Transfer control to a restart named MUFFLE-WARNING, signalling a
1638    CONTROL-ERROR if none exists."
1639   (invoke-restart (find-restart-or-control-error 'muffle-warning condition)))
1640
1641 (defun try-restart (name condition &rest arguments)
1642   (let ((restart (find-restart name condition)))
1643     (when restart
1644       (apply #'invoke-restart restart arguments))))
1645
1646 (macrolet ((define-nil-returning-restart (name args doc)
1647              #!-sb-doc (declare (ignore doc))
1648              `(defun ,name (,@args &optional condition)
1649                 #!+sb-doc ,doc
1650                 (try-restart ',name condition ,@args))))
1651   (define-nil-returning-restart continue ()
1652     "Transfer control to a restart named CONTINUE, or return NIL if none exists.")
1653   (define-nil-returning-restart store-value (value)
1654     "Transfer control and VALUE to a restart named STORE-VALUE, or return NIL if
1655    none exists.")
1656   (define-nil-returning-restart use-value (value)
1657     "Transfer control and VALUE to a restart named USE-VALUE, or return NIL if
1658    none exists."))
1659
1660 ;;; single-stepping restarts
1661
1662 (macrolet ((def (name doc)
1663                #!-sb-doc (declare (ignore doc))
1664                `(defun ,name (condition)
1665                  #!+sb-doc ,doc
1666                  (invoke-restart (find-restart-or-control-error ',name condition)))))
1667   (def step-continue
1668       "Transfers control to the STEP-CONTINUE restart associated with
1669 the condition, continuing execution without stepping. Signals a
1670 CONTROL-ERROR if the restart does not exist.")
1671   (def step-next
1672       "Transfers control to the STEP-NEXT restart associated with the
1673 condition, executing the current form without stepping and continuing
1674 stepping with the next form. Signals CONTROL-ERROR is the restart does
1675 not exists.")
1676   (def step-into
1677       "Transfers control to the STEP-INTO restart associated with the
1678 condition, stepping into the current form. Signals a CONTROL-ERROR is
1679 the restart does not exist."))
1680
1681 (/show0 "condition.lisp end of file")
1682