src/code/condition.lisp

   1 ;;;; stuff originally from CMU CL's error.lisp which can or should
   2 ;;;; come late (mostly related to the CONDITION class itself)
   3 ;;;;
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!KERNEL")
  15 \f
  16 ;;;; miscellaneous support utilities
  17
  18 ;;; Signalling an error when trying to print an error condition is
  19 ;;; generally a PITA, so whatever the failure encountered when
  20 ;;; wondering about FILE-POSITION within a condition printer, 'tis
  21 ;;; better silently to give up than to try to complain.
  22 (defun file-position-or-nil-for-error (stream &optional (pos nil posp))
  23   ;; Arguably FILE-POSITION shouldn't be signalling errors at all; but
  24   ;; "NIL if this cannot be determined" in the ANSI spec doesn't seem
  25   ;; absolutely unambiguously to prohibit errors when, e.g., STREAM
  26   ;; has been closed so that FILE-POSITION is a nonsense question. So
  27   ;; my (WHN) impression is that the conservative approach is to
  28   ;; IGNORE-ERRORS. (I encountered this failure from within a homebrew
  29   ;; defsystemish operation where the ERROR-STREAM had been CL:CLOSEd,
  30   ;; I think by nonlocally exiting through a WITH-OPEN-FILE, by the
  31   ;; time an error was reported.)
  32   (if posp
  33       (ignore-errors (file-position stream pos))
  34       (ignore-errors (file-position stream))))
  35 \f
  36 ;;;; the CONDITION class
  37
  38 (/show0 "condition.lisp 20")
  39
  40 (eval-when (:compile-toplevel :load-toplevel :execute)
  41
  42 (/show0 "condition.lisp 24")
  43
  44 (def!struct (condition-classoid (:include classoid)
  45                                 (:constructor make-condition-classoid))
  46   ;; list of CONDITION-SLOT structures for the direct slots of this
  47   ;; class
  48   (slots nil :type list)
  49   ;; list of CONDITION-SLOT structures for all of the effective class
  50   ;; slots of this class
  51   (class-slots nil :type list)
  52   ;; report function or NIL
  53   (report nil :type (or function null))
  54   ;; list of alternating initargs and initforms
  55   (default-initargs () :type list)
  56   ;; class precedence list as a list of CLASS objects, with all
  57   ;; non-CONDITION classes removed
  58   (cpl () :type list)
  59   ;; a list of all the effective instance allocation slots of this
  60   ;; class that have a non-constant initform or default-initarg.
  61   ;; Values for these slots must be computed in the dynamic
  62   ;; environment of MAKE-CONDITION.
  63   (hairy-slots nil :type list))
  64
  65 (/show0 "condition.lisp 49")
  66
  67 ) ; EVAL-WHEN
  68
  69 (!defstruct-with-alternate-metaclass condition
  70   :slot-names (actual-initargs assigned-slots)
  71   :boa-constructor %make-condition-object
  72   :superclass-name t
  73   :metaclass-name condition-classoid
  74   :metaclass-constructor make-condition-classoid
  75   :dd-type structure)
  76
  77 (defun make-condition-object (actual-initargs)
  78   (%make-condition-object actual-initargs nil))
  79
  80 (defstruct (condition-slot (:copier nil))
  81   (name (missing-arg) :type symbol)
  82   ;; list of all applicable initargs
  83   (initargs (missing-arg) :type list)
  84   ;; names of reader and writer functions
  85   (readers (missing-arg) :type list)
  86   (writers (missing-arg) :type list)
  87   ;; true if :INITFORM was specified
  88   (initform-p (missing-arg) :type (member t nil))
  89   ;; If this is a function, call it with no args. Otherwise, it's the
  90   ;; actual value.
  91   (initform (missing-arg) :type t)
  92   ;; allocation of this slot, or NIL until defaulted
  93   (allocation nil :type (member :instance :class nil))
  94   ;; If ALLOCATION is :CLASS, this is a cons whose car holds the value.
  95   (cell nil :type (or cons null))
  96   ;; slot documentation
  97   (documentation nil :type (or string null)))
  98
  99 ;;; KLUDGE: It's not clear to me why CONDITION-CLASS has itself listed
 100 ;;; in its CPL, while other classes derived from CONDITION-CLASS don't
 101 ;;; have themselves listed in their CPLs. This behavior is inherited
 102 ;;; from CMU CL, and didn't seem to be explained there, and I haven't
 103 ;;; figured out whether it's right. -- WHN 19990612
 104 (eval-when (:compile-toplevel :load-toplevel :execute)
 105   (/show0 "condition.lisp 103")
 106   (let ((condition-class (locally
 107                            ;; KLUDGE: There's a DEFTRANSFORM
 108                            ;; FIND-CLASSOID for constant class names
 109                            ;; which creates fast but
 110                            ;; non-cold-loadable, non-compact code. In
 111                            ;; this context, we'd rather have compact,
 112                            ;; cold-loadable code. -- WHN 19990928
 113                            (declare (notinline find-classoid))
 114                            (find-classoid 'condition))))
 115     (setf (condition-classoid-cpl condition-class)
 116           (list condition-class)))
 117   (/show0 "condition.lisp 103"))
 118
 119 (setf (condition-classoid-report (locally
 120                                    ;; KLUDGE: There's a DEFTRANSFORM
 121                                    ;; FIND-CLASSOID for constant class
 122                                    ;; names which creates fast but
 123                                    ;; non-cold-loadable, non-compact
 124                                    ;; code. In this context, we'd
 125                                    ;; rather have compact,
 126                                    ;; cold-loadable code. -- WHN
 127                                    ;; 19990928
 128                                    (declare (notinline find-classoid))
 129                                    (find-classoid 'condition)))
 130       (lambda (cond stream)
 131         (format stream "Condition ~S was signalled." (type-of cond))))
 132
 133 (eval-when (:compile-toplevel :load-toplevel :execute)
 134
 135 (defun find-condition-layout (name parent-types)
 136   (let* ((cpl (remove-duplicates
 137                (reverse
 138                 (reduce #'append
 139                         (mapcar (lambda (x)
 140                                   (condition-classoid-cpl
 141                                    (find-classoid x)))
 142                                 parent-types)))))
 143          (cond-layout (info :type :compiler-layout 'condition))
 144          (olayout (info :type :compiler-layout name))
 145          ;; FIXME: Does this do the right thing in case of multiple
 146          ;; inheritance? A quick look at DEFINE-CONDITION didn't make
 147          ;; it obvious what ANSI intends to be done in the case of
 148          ;; multiple inheritance, so it's not actually clear what the
 149          ;; right thing is..
 150          (new-inherits
 151           (order-layout-inherits (concatenate 'simple-vector
 152                                               (layout-inherits cond-layout)
 153                                               (mapcar #'classoid-layout cpl)))))
 154     (if (and olayout
 155              (not (mismatch (layout-inherits olayout) new-inherits)))
 156         olayout
 157         (make-layout :classoid (make-undefined-classoid name)
 158                      :inherits new-inherits
 159                      :depthoid -1
 160                      :length (layout-length cond-layout)))))
 161
 162 ) ; EVAL-WHEN
 163
 164 ;;; FIXME: ANSI's definition of DEFINE-CONDITION says
 165 ;;;   Condition reporting is mediated through the PRINT-OBJECT method
 166 ;;;   for the condition type in question, with *PRINT-ESCAPE* always
 167 ;;;   being nil. Specifying (:REPORT REPORT-NAME) in the definition of
 168 ;;;   a condition type C is equivalent to:
 169 ;;;     (defmethod print-object ((x c) stream)
 170 ;;;       (if *print-escape* (call-next-method) (report-name x stream)))
 171 ;;; The current code doesn't seem to quite match that.
 172 (def!method print-object ((x condition) stream)
 173   (if *print-escape*
 174       (print-unreadable-object (x stream :type t :identity t))
 175       ;; KLUDGE: A comment from CMU CL here said
 176       ;;   7/13/98 BUG? CPL is not sorted and results here depend on order of
 177       ;;   superclasses in define-condition call!
 178       (dolist (class (condition-classoid-cpl (classoid-of x))
 179                      (error "no REPORT? shouldn't happen!"))
 180         (let ((report (condition-classoid-report class)))
 181           (when report
 182             (return (funcall report x stream)))))))
 183 \f
 184 ;;;; slots of CONDITION objects
 185
 186 (defvar *empty-condition-slot* '(empty))
 187
 188 (defun find-slot-default (class slot)
 189   (let ((initargs (condition-slot-initargs slot))
 190         (cpl (condition-classoid-cpl class)))
 191     (dolist (class cpl)
 192       (let ((default-initargs (condition-classoid-default-initargs class)))
 193         (dolist (initarg initargs)
 194           (let ((val (getf default-initargs initarg *empty-condition-slot*)))
 195             (unless (eq val *empty-condition-slot*)
 196               (return-from find-slot-default
 197                            (if (functionp val)
 198                                (funcall val)
 199                                val)))))))
 200
 201     (if (condition-slot-initform-p slot)
 202         (let ((initform (condition-slot-initform slot)))
 203           (if (functionp initform)
 204               (funcall initform)
 205               initform))
 206         (error "unbound condition slot: ~S" (condition-slot-name slot)))))
 207
 208 (defun find-condition-class-slot (condition-class slot-name)
 209   (dolist (sclass
 210            (condition-classoid-cpl condition-class)
 211            (error "There is no slot named ~S in ~S."
 212                   slot-name condition-class))
 213     (dolist (slot (condition-classoid-slots sclass))
 214       (when (eq (condition-slot-name slot) slot-name)
 215         (return-from find-condition-class-slot slot)))))
 216
 217 (defun condition-writer-function (condition new-value name)
 218   (dolist (cslot (condition-classoid-class-slots
 219                   (layout-classoid (%instance-layout condition)))
 220                  (setf (getf (condition-assigned-slots condition) name)
 221                        new-value))
 222     (when (eq (condition-slot-name cslot) name)
 223       (return (setf (car (condition-slot-cell cslot)) new-value)))))
 224
 225 (defun condition-reader-function (condition name)
 226   (let ((class (layout-classoid (%instance-layout condition))))
 227     (dolist (cslot (condition-classoid-class-slots class))
 228       (when (eq (condition-slot-name cslot) name)
 229         (return-from condition-reader-function
 230                      (car (condition-slot-cell cslot)))))
 231     (let ((val (getf (condition-assigned-slots condition) name
 232                      *empty-condition-slot*)))
 233       (if (eq val *empty-condition-slot*)
 234           (let ((actual-initargs (condition-actual-initargs condition))
 235                 (slot (find-condition-class-slot class name)))
 236             (unless slot
 237               (error "missing slot ~S of ~S" name condition))
 238             (do ((initargs actual-initargs (cddr initargs)))
 239                 ((endp initargs)
 240                  (setf (getf (condition-assigned-slots condition) name)
 241                        (find-slot-default class slot)))
 242               (when (member (car initargs) (condition-slot-initargs slot))
 243                 (return-from condition-reader-function
 244                   (setf (getf (condition-assigned-slots condition)
 245                               name)
 246                         (cadr initargs))))))
 247           val))))
 248 \f
 249 ;;;; MAKE-CONDITION
 250
 251 (defun make-condition (type &rest args)
 252   #!+sb-doc
 253   "Make an instance of a condition object using the specified initargs."
 254   ;; Note: ANSI specifies no exceptional situations in this function.
 255   ;; signalling simple-type-error would not be wrong.
 256   (let* ((type (or (and (symbolp type) (find-classoid type nil))
 257                     type))
 258          (class (typecase type
 259                   (condition-classoid type)
 260                   (class
 261                    ;; Punt to CLOS.
 262                    (return-from make-condition (apply #'make-instance type args)))
 263                   (classoid
 264                    (error 'simple-type-error
 265                           :datum type
 266                           :expected-type 'condition-class
 267                           :format-control "~S is not a condition class."
 268                           :format-arguments (list type)))
 269                   (t
 270                    (error 'simple-type-error
 271                           :datum type
 272                           :expected-type 'condition-class
 273                           :format-control "Bad type argument:~%  ~S"
 274                           :format-arguments (list type)))))
 275          (res (make-condition-object args)))
 276     (setf (%instance-layout res) (classoid-layout class))
 277     ;; Set any class slots with initargs present in this call.
 278     (dolist (cslot (condition-classoid-class-slots class))
 279       (dolist (initarg (condition-slot-initargs cslot))
 280         (let ((val (getf args initarg *empty-condition-slot*)))
 281           (unless (eq val *empty-condition-slot*)
 282             (setf (car (condition-slot-cell cslot)) val)))))
 283     ;; Default any slots with non-constant defaults now.
 284     (dolist (hslot (condition-classoid-hairy-slots class))
 285       (when (dolist (initarg (condition-slot-initargs hslot) t)
 286               (unless (eq (getf args initarg *empty-condition-slot*)
 287                           *empty-condition-slot*)
 288                 (return nil)))
 289         (setf (getf (condition-assigned-slots res) (condition-slot-name hslot))
 290               (find-slot-default class hslot))))
 291     res))
 292 \f
 293 ;;;; DEFINE-CONDITION
 294
 295 (eval-when (:compile-toplevel :load-toplevel :execute)
 296 (defun %compiler-define-condition (name direct-supers layout
 297                                    all-readers all-writers)
 298   (with-single-package-locked-error
 299       (:symbol name "defining ~A as a condition")
 300     (sb!xc:proclaim `(ftype (function (t) t) ,@all-readers))
 301     (sb!xc:proclaim `(ftype (function (t t) t) ,@all-writers))
 302     (multiple-value-bind (class old-layout)
 303         (insured-find-classoid name
 304                                #'condition-classoid-p
 305                                #'make-condition-classoid)
 306       (setf (layout-classoid layout) class)
 307       (setf (classoid-direct-superclasses class)
 308             (mapcar #'find-classoid direct-supers))
 309       (cond ((not old-layout)
 310              (register-layout layout))
 311             ((not *type-system-initialized*)
 312              (setf (layout-classoid old-layout) class)
 313              (setq layout old-layout)
 314              (unless (eq (classoid-layout class) layout)
 315                (register-layout layout)))
 316             ((redefine-layout-warning "current"
 317                                       old-layout
 318                                       "new"
 319                                       (layout-length layout)
 320                                       (layout-inherits layout)
 321                                       (layout-depthoid layout)
 322                                       (layout-n-untagged-slots layout))
 323              (register-layout layout :invalidate t))
 324             ((not (classoid-layout class))
 325              (register-layout layout)))
 326
 327       (setf (layout-info layout)
 328             (locally
 329                 ;; KLUDGE: There's a FIND-CLASS DEFTRANSFORM for constant class
 330                 ;; names which creates fast but non-cold-loadable, non-compact
 331                 ;; code. In this context, we'd rather have compact, cold-loadable
 332                 ;; code. -- WHN 19990928
 333                 (declare (notinline find-classoid))
 334               (layout-info (classoid-layout (find-classoid 'condition)))))
 335
 336       (setf (find-classoid name) class)
 337
 338       ;; Initialize CPL slot.
 339       (setf (condition-classoid-cpl class)
 340             (remove-if-not #'condition-classoid-p
 341                            (std-compute-class-precedence-list class)))))
 342   (values))
 343 ) ; EVAL-WHEN
 344
 345 ;;; Compute the effective slots of CLASS, copying inherited slots and
 346 ;;; destructively modifying direct slots.
 347 ;;;
 348 ;;; FIXME: It'd be nice to explain why it's OK to destructively modify
 349 ;;; direct slots. Presumably it follows from the semantics of
 350 ;;; inheritance and redefinition of conditions, but finding the cite
 351 ;;; and documenting it here would be good. (Or, if this is not in fact
 352 ;;; ANSI-compliant, fixing it would also be good.:-)
 353 (defun compute-effective-slots (class)
 354   (collect ((res (copy-list (condition-classoid-slots class))))
 355     (dolist (sclass (cdr (condition-classoid-cpl class)))
 356       (dolist (sslot (condition-classoid-slots sclass))
 357         (let ((found (find (condition-slot-name sslot) (res)
 358                            :key #'condition-slot-name)))
 359           (cond (found
 360                  (setf (condition-slot-initargs found)
 361                        (union (condition-slot-initargs found)
 362                               (condition-slot-initargs sslot)))
 363                  (unless (condition-slot-initform-p found)
 364                    (setf (condition-slot-initform-p found)
 365                          (condition-slot-initform-p sslot))
 366                    (setf (condition-slot-initform found)
 367                          (condition-slot-initform sslot)))
 368                  (unless (condition-slot-allocation found)
 369                    (setf (condition-slot-allocation found)
 370                          (condition-slot-allocation sslot))))
 371                 (t
 372                  (res (copy-structure sslot)))))))
 373     (res)))
 374
 375 ;;; Early definitions of slot accessor creators.
 376 ;;;
 377 ;;; Slot accessors must be generic functions, but ANSI does not seem
 378 ;;; to specify any of them, and we cannot support it before end of
 379 ;;; warm init. So we use ordinary functions inside SBCL, and switch to
 380 ;;; GFs only at the end of building.
 381 (declaim (notinline install-condition-slot-reader
 382                     install-condition-slot-writer))
 383 (defun install-condition-slot-reader (name condition slot-name)
 384   (declare (ignore condition))
 385   (setf (fdefinition name)
 386         (lambda (condition)
 387           (condition-reader-function condition slot-name))))
 388 (defun install-condition-slot-writer (name condition slot-name)
 389   (declare (ignore condition))
 390   (setf (fdefinition name)
 391         (lambda (new-value condition)
 392           (condition-writer-function condition new-value slot-name))))
 393
 394 (defvar *define-condition-hooks* nil)
 395
 396 (defun %define-condition (name parent-types layout slots documentation
 397                           report default-initargs all-readers all-writers
 398                           source-location)
 399   (with-single-package-locked-error
 400       (:symbol name "defining ~A as a condition")
 401     (%compiler-define-condition name parent-types layout all-readers all-writers)
 402     (sb!c:with-source-location (source-location)
 403       (setf (layout-source-location layout)
 404             source-location))
 405     (let ((class (find-classoid name)))
 406       (setf (condition-classoid-slots class) slots)
 407       (setf (condition-classoid-report class) report)
 408       (setf (condition-classoid-default-initargs class) default-initargs)
 409       (setf (fdocumentation name 'type) documentation)
 410
 411       (dolist (slot slots)
 412
 413         ;; Set up reader and writer functions.
 414         (let ((slot-name (condition-slot-name slot)))
 415           (dolist (reader (condition-slot-readers slot))
 416             (install-condition-slot-reader reader name slot-name))
 417           (dolist (writer (condition-slot-writers slot))
 418             (install-condition-slot-writer writer name slot-name))))
 419
 420       ;; Compute effective slots and set up the class and hairy slots
 421       ;; (subsets of the effective slots.)
 422       (let ((eslots (compute-effective-slots class))
 423             (e-def-initargs
 424              (reduce #'append
 425                      (mapcar #'condition-classoid-default-initargs
 426                            (condition-classoid-cpl class)))))
 427         (dolist (slot eslots)
 428           (ecase (condition-slot-allocation slot)
 429             (:class
 430              (unless (condition-slot-cell slot)
 431                (setf (condition-slot-cell slot)
 432                      (list (if (condition-slot-initform-p slot)
 433                                (let ((initform (condition-slot-initform slot)))
 434                                  (if (functionp initform)
 435                                      (funcall initform)
 436                                      initform))
 437                                *empty-condition-slot*))))
 438              (push slot (condition-classoid-class-slots class)))
 439             ((:instance nil)
 440              (setf (condition-slot-allocation slot) :instance)
 441              (when (or (functionp (condition-slot-initform slot))
 442                        (dolist (initarg (condition-slot-initargs slot) nil)
 443                          (when (functionp (getf e-def-initargs initarg))
 444                            (return t))))
 445                (push slot (condition-classoid-hairy-slots class)))))))
 446       (when (boundp '*define-condition-hooks*)
 447         (dolist (fun *define-condition-hooks*)
 448           (funcall fun class))))
 449     name))
 450
 451 (defmacro define-condition (name (&rest parent-types) (&rest slot-specs)
 452                                  &body options)
 453   #!+sb-doc
 454   "DEFINE-CONDITION Name (Parent-Type*) (Slot-Spec*) Option*
 455    Define NAME as a condition type. This new type inherits slots and its
 456    report function from the specified PARENT-TYPEs. A slot spec is a list of:
 457      (slot-name :reader <rname> :initarg <iname> {Option Value}*
 458
 459    The DEFINE-CLASS slot options :ALLOCATION, :INITFORM, [slot] :DOCUMENTATION
 460    and :TYPE and the overall options :DEFAULT-INITARGS and
 461    [type] :DOCUMENTATION are also allowed.
 462
 463    The :REPORT option is peculiar to DEFINE-CONDITION. Its argument is either
 464    a string or a two-argument lambda or function name. If a function, the
 465    function is called with the condition and stream to report the condition.
 466    If a string, the string is printed.
 467
 468    Condition types are classes, but (as allowed by ANSI and not as described in
 469    CLtL2) are neither STANDARD-OBJECTs nor STRUCTURE-OBJECTs. WITH-SLOTS and
 470    SLOT-VALUE may not be used on condition objects."
 471   (let* ((parent-types (or parent-types '(condition)))
 472          (layout (find-condition-layout name parent-types))
 473          (documentation nil)
 474          (report nil)
 475          (default-initargs ()))
 476     (collect ((slots)
 477               (all-readers nil append)
 478               (all-writers nil append))
 479       (dolist (spec slot-specs)
 480         (when (keywordp spec)
 481           (warn "Keyword slot name indicates probable syntax error:~%  ~S"
 482                 spec))
 483         (let* ((spec (if (consp spec) spec (list spec)))
 484                (slot-name (first spec))
 485                (allocation :instance)
 486                (initform-p nil)
 487                documentation
 488                initform)
 489           (collect ((initargs)
 490                     (readers)
 491                     (writers))
 492             (do ((options (rest spec) (cddr options)))
 493                 ((null options))
 494               (unless (and (consp options) (consp (cdr options)))
 495                 (error "malformed condition slot spec:~%  ~S." spec))
 496               (let ((arg (second options)))
 497                 (case (first options)
 498                   (:reader (readers arg))
 499                   (:writer (writers arg))
 500                   (:accessor
 501                    (readers arg)
 502                    (writers `(setf ,arg)))
 503                   (:initform
 504                    (when initform-p
 505                      (error "more than one :INITFORM in ~S" spec))
 506                    (setq initform-p t)
 507                    (setq initform arg))
 508                   (:initarg (initargs arg))
 509                   (:allocation
 510                    (setq allocation arg))
 511                   (:documentation
 512                    (when documentation
 513                      (error "more than one :DOCUMENTATION in ~S" spec))
 514                    (unless (stringp arg)
 515                      (error "slot :DOCUMENTATION argument is not a string: ~S"
 516                             arg))
 517                    (setq documentation arg))
 518                   (:type)
 519                   (t
 520                    (error "unknown slot option:~%  ~S" (first options))))))
 521
 522             (all-readers (readers))
 523             (all-writers (writers))
 524             (slots `(make-condition-slot
 525                      :name ',slot-name
 526                      :initargs ',(initargs)
 527                      :readers ',(readers)
 528                      :writers ',(writers)
 529                      :initform-p ',initform-p
 530                      :documentation ',documentation
 531                      :initform
 532                      ,(if (sb!xc:constantp initform)
 533                           `',(constant-form-value initform)
 534                           `#'(lambda () ,initform)))))))
 535
 536       (dolist (option options)
 537         (unless (consp option)
 538           (error "bad option:~%  ~S" option))
 539         (case (first option)
 540           (:documentation (setq documentation (second option)))
 541           (:report
 542            (let ((arg (second option)))
 543              (setq report
 544                    (if (stringp arg)
 545                        `#'(lambda (condition stream)
 546                           (declare (ignore condition))
 547                           (write-string ,arg stream))
 548                        `#'(lambda (condition stream)
 549                           (funcall #',arg condition stream))))))
 550           (:default-initargs
 551            (do ((initargs (rest option) (cddr initargs)))
 552                ((endp initargs))
 553              (let ((val (second initargs)))
 554                (setq default-initargs
 555                      (list* `',(first initargs)
 556                             (if (sb!xc:constantp val)
 557                                 `',(constant-form-value val)
 558                                 `#'(lambda () ,val))
 559                             default-initargs)))))
 560           (t
 561            (error "unknown option: ~S" (first option)))))
 562
 563       `(progn
 564          (eval-when (:compile-toplevel)
 565            (%compiler-define-condition ',name ',parent-types ',layout
 566                                        ',(all-readers) ',(all-writers)))
 567          (eval-when (:load-toplevel :execute)
 568            (%define-condition ',name
 569                               ',parent-types
 570                               ',layout
 571                               (list ,@(slots))
 572                               ,documentation
 573                               ,report
 574                               (list ,@default-initargs)
 575                               ',(all-readers)
 576                               ',(all-writers)
 577                               (sb!c:source-location)))))))
 578 \f
 579 ;;;; DESCRIBE on CONDITIONs
 580
 581 ;;; a function to be used as the guts of DESCRIBE-OBJECT (CONDITION T)
 582 ;;; eventually (once we get CLOS up and running so that we can define
 583 ;;; methods)
 584 (defun describe-condition (condition stream)
 585   (format stream
 586           "~&~@<~S ~_is a ~S. ~_Its slot values are ~_~S.~:>~%"
 587           condition
 588           (type-of condition)
 589           (concatenate 'list
 590                        (condition-actual-initargs condition)
 591                        (condition-assigned-slots condition))))
 592 \f
 593 ;;;; various CONDITIONs specified by ANSI
 594
 595 (define-condition serious-condition (condition) ())
 596
 597 (define-condition error (serious-condition) ())
 598
 599 (define-condition warning (condition) ())
 600 (define-condition style-warning (warning) ())
 601
 602 (defun simple-condition-printer (condition stream)
 603   (apply #'format
 604          stream
 605          (simple-condition-format-control condition)
 606          (simple-condition-format-arguments condition)))
 607
 608 (define-condition simple-condition ()
 609   ((format-control :reader simple-condition-format-control
 610                    :initarg :format-control
 611                    :type format-control)
 612    (format-arguments :reader simple-condition-format-arguments
 613                      :initarg :format-arguments
 614                      :initform '()
 615                      :type list))
 616   (:report simple-condition-printer))
 617
 618 (define-condition simple-warning (simple-condition warning) ())
 619
 620 (define-condition simple-error (simple-condition error) ())
 621
 622 ;;; not specified by ANSI, but too useful not to have around.
 623 (define-condition simple-style-warning (simple-condition style-warning) ())
 624
 625 (define-condition storage-condition (serious-condition) ())
 626
 627 (define-condition type-error (error)
 628   ((datum :reader type-error-datum :initarg :datum)
 629    (expected-type :reader type-error-expected-type :initarg :expected-type))
 630   (:report
 631    (lambda (condition stream)
 632      (format stream
 633              "~@<The value ~2I~:_~S ~I~_is not of type ~2I~_~S.~:>"
 634              (type-error-datum condition)
 635              (type-error-expected-type condition)))))
 636
 637 (define-condition simple-type-error (simple-condition type-error) ())
 638
 639 (define-condition program-error (error) ())
 640 (define-condition parse-error   (error) ())
 641 (define-condition control-error (error) ())
 642 (define-condition stream-error  (error)
 643   ((stream :reader stream-error-stream :initarg :stream)))
 644
 645 (define-condition end-of-file (stream-error) ()
 646   (:report
 647    (lambda (condition stream)
 648      (format stream
 649              "end of file on ~S"
 650              (stream-error-stream condition)))))
 651
 652 (define-condition file-error (error)
 653   ((pathname :reader file-error-pathname :initarg :pathname))
 654   (:report
 655    (lambda (condition stream)
 656      (format stream "error on file ~S" (file-error-pathname condition)))))
 657
 658 (define-condition package-error (error)
 659   ((package :reader package-error-package :initarg :package)))
 660
 661 (define-condition cell-error (error)
 662   ((name :reader cell-error-name :initarg :name)))
 663
 664 (def!method print-object ((condition cell-error) stream)
 665   (if (and *print-escape* (slot-boundp condition 'name))
 666       (print-unreadable-object (condition stream :type t :identity t)
 667         (princ (cell-error-name condition) stream))
 668       (call-next-method)))
 669
 670 (define-condition unbound-variable (cell-error) ()
 671   (:report
 672    (lambda (condition stream)
 673      (format stream
 674              "The variable ~S is unbound."
 675              (cell-error-name condition)))))
 676
 677 (define-condition undefined-function (cell-error) ()
 678   (:report
 679    (lambda (condition stream)
 680      (format stream
 681              "The function ~S is undefined."
 682              (cell-error-name condition)))))
 683
 684 (define-condition special-form-function (undefined-function) ()
 685   (:report
 686    (lambda (condition stream)
 687      (format stream
 688              "Cannot FUNCALL the SYMBOL-FUNCTION of special operator ~S."
 689              (cell-error-name condition)))))
 690
 691 (define-condition arithmetic-error (error)
 692   ((operation :reader arithmetic-error-operation
 693               :initarg :operation
 694               :initform nil)
 695    (operands :reader arithmetic-error-operands
 696              :initarg :operands))
 697   (:report (lambda (condition stream)
 698              (format stream
 699                      "arithmetic error ~S signalled"
 700                      (type-of condition))
 701              (when (arithmetic-error-operation condition)
 702                (format stream
 703                        "~%Operation was ~S, operands ~S."
 704                        (arithmetic-error-operation condition)
 705                        (arithmetic-error-operands condition))))))
 706
 707 (define-condition division-by-zero         (arithmetic-error) ())
 708 (define-condition floating-point-overflow  (arithmetic-error) ())
 709 (define-condition floating-point-underflow (arithmetic-error) ())
 710 (define-condition floating-point-inexact   (arithmetic-error) ())
 711 (define-condition floating-point-invalid-operation (arithmetic-error) ())
 712
 713 (define-condition print-not-readable (error)
 714   ((object :reader print-not-readable-object :initarg :object))
 715   (:report
 716    (lambda (condition stream)
 717      (let ((obj (print-not-readable-object condition))
 718            (*print-array* nil))
 719        (format stream "~S cannot be printed readably." obj)))))
 720
 721 (define-condition reader-error (parse-error stream-error) ()
 722   (:report (lambda (condition stream)
 723              (%report-reader-error condition stream))))
 724
 725 ;;; a READER-ERROR whose REPORTing is controlled by FORMAT-CONTROL and
 726 ;;; FORMAT-ARGS (the usual case for READER-ERRORs signalled from
 727 ;;; within SBCL itself)
 728 ;;;
 729 ;;; (Inheriting CL:SIMPLE-CONDITION here isn't quite consistent with
 730 ;;; the letter of the ANSI spec: this is not a condition signalled by
 731 ;;; SIGNAL when a format-control is supplied by the function's first
 732 ;;; argument. It seems to me (WHN) to be basically in the spirit of
 733 ;;; the spec, but if not, it'd be straightforward to do our own
 734 ;;; DEFINE-CONDITION SB-INT:SIMPLISTIC-CONDITION with
 735 ;;; FORMAT-CONTROL and FORMAT-ARGS slots, and use that condition in
 736 ;;; place of CL:SIMPLE-CONDITION here.)
 737 (define-condition simple-reader-error (reader-error simple-condition)
 738   ()
 739   (:report (lambda (condition stream)
 740              (%report-reader-error condition stream :simple t))))
 741
 742 ;;; base REPORTing of a READER-ERROR
 743 ;;;
 744 ;;; When SIMPLE, we expect and use SIMPLE-CONDITION-ish FORMAT-CONTROL
 745 ;;; and FORMAT-ARGS slots.
 746 (defun %report-reader-error (condition stream &key simple)
 747   (let* ((error-stream (stream-error-stream condition))
 748          (pos (file-position-or-nil-for-error error-stream)))
 749     (let (lineno colno)
 750       (when (and pos
 751                  (< pos sb!xc:array-dimension-limit)
 752                  ;; KLUDGE: lseek() (which is what FILE-POSITION
 753                  ;; reduces to on file-streams) is undefined on
 754                  ;; "some devices", which in practice means that it
 755                  ;; can claim to succeed on /dev/stdin on Darwin
 756                  ;; and Solaris.  This is obviously bad news,
 757                  ;; because the READ-SEQUENCE below will then
 758                  ;; block, not complete, and the report will never
 759                  ;; be printed.  As a workaround, we exclude
 760                  ;; interactive streams from this attempt to report
 761                  ;; positions.  -- CSR, 2003-08-21
 762                  (not (interactive-stream-p error-stream))
 763                  (file-position error-stream :start))
 764         (let ((string
 765                (make-string pos
 766                             :element-type (stream-element-type
 767                                            error-stream))))
 768           (when (= pos (read-sequence string error-stream))
 769             (setq lineno (1+ (count #\Newline string))
 770                   colno (- pos
 771                            (or (position #\Newline string :from-end t) -1)
 772                            1))))
 773         (file-position-or-nil-for-error error-stream pos))
 774       (pprint-logical-block (stream nil)
 775         (format stream
 776                 "~S ~@[at ~W ~]~
 777                     ~@[(line ~W~]~@[, column ~W) ~]~
 778                     on ~S"
 779                 (class-name (class-of condition))
 780                 pos lineno colno error-stream)
 781         (when simple
 782           (format stream ":~2I~_~?"
 783                   (simple-condition-format-control condition)
 784                   (simple-condition-format-arguments condition)))))))
 785 \f
 786 ;;;; special SBCL extension conditions
 787
 788 ;;; an error apparently caused by a bug in SBCL itself
 789 ;;;
 790 ;;; Note that we don't make any serious effort to use this condition
 791 ;;; for *all* errors in SBCL itself. E.g. type errors and array
 792 ;;; indexing errors can occur in functions called from SBCL code, and
 793 ;;; will just end up as ordinary TYPE-ERROR or invalid index error,
 794 ;;; because the signalling code has no good way to know that the
 795 ;;; underlying problem is a bug in SBCL. But in the fairly common case
 796 ;;; that the signalling code does know that it's found a bug in SBCL,
 797 ;;; this condition is appropriate, reusing boilerplate and helping
 798 ;;; users to recognize it as an SBCL bug.
 799 (define-condition bug (simple-error)
 800   ()
 801   (:report
 802    (lambda (condition stream)
 803      (format stream
 804              "~@<  ~? ~:@_~?~:>"
 805              (simple-condition-format-control condition)
 806              (simple-condition-format-arguments condition)
 807              "~@<This is probably a bug in SBCL itself. (Alternatively, ~
 808               SBCL might have been corrupted by bad user code, e.g. by an ~
 809               undefined Lisp operation like ~S, or by stray pointers from ~
 810               alien code or from unsafe Lisp code; or there might be a bug ~
 811               in the OS or hardware that SBCL is running on.) If it seems to ~
 812               be a bug in SBCL itself, the maintainers would like to know ~
 813               about it. Bug reports are welcome on the SBCL ~
 814               mailing lists, which you can find at ~
 815               <http://sbcl.sourceforge.net/>.~:@>"
 816              '((fmakunbound 'compile))))))
 817
 818 (define-condition simple-storage-condition (storage-condition simple-condition) ())
 819
 820 ;;; a condition for use in stubs for operations which aren't supported
 821 ;;; on some platforms
 822 ;;;
 823 ;;; E.g. in sbcl-0.7.0.5, it might be appropriate to do something like
 824 ;;;   #-(or freebsd linux)
 825 ;;;   (defun load-foreign (&rest rest)
 826 ;;;     (error 'unsupported-operator :name 'load-foreign))
 827 ;;;   #+(or freebsd linux)
 828 ;;;   (defun load-foreign ... actual definition ...)
 829 ;;; By signalling a standard condition in this case, we make it
 830 ;;; possible for test code to distinguish between (1) intentionally
 831 ;;; unimplemented and (2) unintentionally just screwed up somehow.
 832 ;;; (Before this condition was defined, test code tried to deal with
 833 ;;; this by checking for FBOUNDP, but that didn't work reliably. In
 834 ;;; sbcl-0.7.0, a package screwup left the definition of
 835 ;;; LOAD-FOREIGN in the wrong package, so it was unFBOUNDP even on
 836 ;;; architectures where it was supposed to be supported, and the
 837 ;;; regression tests cheerfully passed because they assumed that
 838 ;;; unFBOUNDPness meant they were running on an system which didn't
 839 ;;; support the extension.)
 840 (define-condition unsupported-operator (simple-error) ())
 841 \f
 842 ;;; (:ansi-cl :function remove)
 843 ;;; (:ansi-cl :section (a b c))
 844 ;;; (:ansi-cl :glossary "similar")
 845 ;;;
 846 ;;; (:sbcl :node "...")
 847 ;;; (:sbcl :variable *ed-functions*)
 848 ;;;
 849 ;;; FIXME: this is not the right place for this.
 850 (defun print-reference (reference stream)
 851   (ecase (car reference)
 852     (:amop
 853      (format stream "AMOP")
 854      (format stream ", ")
 855      (destructuring-bind (type data) (cdr reference)
 856        (ecase type
 857          (:readers "Readers for ~:(~A~) Metaobjects"
 858                    (substitute #\  #\- (symbol-name data)))
 859          (:initialization
 860           (format stream "Initialization of ~:(~A~) Metaobjects"
 861                   (substitute #\  #\- (symbol-name data))))
 862          (:generic-function (format stream "Generic Function ~S" data))
 863          (:function (format stream "Function ~S" data))
 864          (:section (format stream "Section ~{~D~^.~}" data)))))
 865     (:ansi-cl
 866      (format stream "The ANSI Standard")
 867      (format stream ", ")
 868      (destructuring-bind (type data) (cdr reference)
 869        (ecase type
 870          (:function (format stream "Function ~S" data))
 871          (:special-operator (format stream "Special Operator ~S" data))
 872          (:macro (format stream "Macro ~S" data))
 873          (:section (format stream "Section ~{~D~^.~}" data))
 874          (:glossary (format stream "Glossary entry for ~S" data))
 875          (:issue (format stream "writeup for Issue ~A" data)))))
 876     (:sbcl
 877      (format stream "The SBCL Manual")
 878      (format stream ", ")
 879      (destructuring-bind (type data) (cdr reference)
 880        (ecase type
 881          (:node (format stream "Node ~S" data))
 882          (:variable (format stream "Variable ~S" data))
 883          (:function (format stream "Function ~S" data)))))
 884     ;; FIXME: other documents (e.g. CLIM, Franz documentation :-)
 885     ))
 886 (define-condition reference-condition ()
 887   ((references :initarg :references :reader reference-condition-references)))
 888 (defvar *print-condition-references* t)
 889 (def!method print-object :around ((o reference-condition) s)
 890   (call-next-method)
 891   (unless (or *print-escape* *print-readably*)
 892     (when (and *print-condition-references*
 893                (reference-condition-references o))
 894       (format s "~&See also:~%")
 895       (pprint-logical-block (s nil :per-line-prefix "  ")
 896         (do* ((rs (reference-condition-references o) (cdr rs))
 897               (r (car rs) (car rs)))
 898              ((null rs))
 899           (print-reference r s)
 900           (unless (null (cdr rs))
 901             (terpri s)))))))
 902
 903 (define-condition duplicate-definition (reference-condition warning)
 904   ((name :initarg :name :reader duplicate-definition-name))
 905   (:report (lambda (c s)
 906              (format s "~@<Duplicate definition for ~S found in ~
 907                         one file.~@:>"
 908                      (duplicate-definition-name c))))
 909   (:default-initargs :references (list '(:ansi-cl :section (3 2 2 3)))))
 910
 911 (define-condition constant-modified (reference-condition warning)
 912   ((fun-name :initarg :fun-name :reader constant-modified-fun-name))
 913   (:report (lambda (c s)
 914              (format s "~@<Destructive function ~S called on ~
 915                         constant data.~@:>"
 916                      (constant-modified-fun-name c))))
 917   (:default-initargs :references (list '(:ansi-cl :special-operator quote)
 918                                        '(:ansi-cl :section (3 2 2 3)))))
 919
 920 (define-condition package-at-variance (reference-condition simple-warning)
 921   ()
 922   (:default-initargs :references (list '(:ansi-cl :macro defpackage))))
 923
 924 (define-condition defconstant-uneql (reference-condition error)
 925   ((name :initarg :name :reader defconstant-uneql-name)
 926    (old-value :initarg :old-value :reader defconstant-uneql-old-value)
 927    (new-value :initarg :new-value :reader defconstant-uneql-new-value))
 928   (:report
 929    (lambda (condition stream)
 930      (format stream
 931              "~@<The constant ~S is being redefined (from ~S to ~S)~@:>"
 932              (defconstant-uneql-name condition)
 933              (defconstant-uneql-old-value condition)
 934              (defconstant-uneql-new-value condition))))
 935   (:default-initargs :references (list '(:ansi-cl :macro defconstant)
 936                                        '(:sbcl :node "Idiosyncrasies"))))
 937
 938 (define-condition array-initial-element-mismatch
 939     (reference-condition simple-warning)
 940   ()
 941   (:default-initargs
 942       :references (list
 943                    '(:ansi-cl :function make-array)
 944                    '(:ansi-cl :function sb!xc:upgraded-array-element-type))))
 945
 946 (define-condition displaced-to-array-too-small-error
 947     (reference-condition simple-error)
 948   ()
 949   (:default-initargs
 950       :references (list '(:ansi-cl :function adjust-array))))
 951
 952 (define-condition type-warning (reference-condition simple-warning)
 953   ()
 954   (:default-initargs :references (list '(:sbcl :node "Handling of Types"))))
 955
 956 (define-condition local-argument-mismatch (reference-condition simple-warning)
 957   ()
 958   (:default-initargs :references (list '(:ansi-cl :section (3 2 2 3)))))
 959
 960 (define-condition format-args-mismatch (reference-condition)
 961   ()
 962   (:default-initargs :references (list '(:ansi-cl :section (22 3 10 2)))))
 963
 964 (define-condition format-too-few-args-warning
 965     (format-args-mismatch simple-warning)
 966   ())
 967 (define-condition format-too-many-args-warning
 968     (format-args-mismatch simple-style-warning)
 969   ())
 970
 971 (define-condition extension-failure (reference-condition simple-error)
 972   ())
 973
 974 (define-condition structure-initarg-not-keyword
 975     (reference-condition simple-style-warning)
 976   ()
 977   (:default-initargs :references (list '(:ansi-cl :section (2 4 8 13)))))
 978
 979 #!+sb-package-locks
 980 (progn
 981
 982 (define-condition package-lock-violation (reference-condition package-error)
 983   ((format-control :initform nil :initarg :format-control
 984                    :reader package-error-format-control)
 985    (format-arguments :initform nil :initarg :format-arguments
 986                      :reader package-error-format-arguments))
 987   (:report
 988    (lambda (condition stream)
 989      (let ((control (package-error-format-control condition)))
 990        (if control
 991            (apply #'format stream
 992                   (format nil "~~@<Lock on package ~A violated when ~A.~~:@>"
 993                           (package-name (package-error-package condition))
 994                           control)
 995                   (package-error-format-arguments condition))
 996            (format stream "~@<Lock on package ~A violated.~:@>"
 997                    (package-name (package-error-package condition)))))))
 998   ;; no :default-initargs -- reference-stuff provided by the
 999   ;; signalling form in target-package.lisp
1000   #!+sb-doc
1001   (:documentation
1002    "Subtype of CL:PACKAGE-ERROR. A subtype of this error is signalled
1003 when a package-lock is violated."))
1004
1005 (define-condition package-locked-error (package-lock-violation) ()
1006   #!+sb-doc
1007   (:documentation
1008    "Subtype of SB-EXT:PACKAGE-LOCK-VIOLATION. An error of this type is
1009 signalled when an operation on a package violates a package lock."))
1010
1011 (define-condition symbol-package-locked-error (package-lock-violation)
1012   ((symbol :initarg :symbol :reader package-locked-error-symbol))
1013   #!+sb-doc
1014   (:documentation
1015    "Subtype of SB-EXT:PACKAGE-LOCK-VIOLATION. An error of this type is
1016 signalled when an operation on a symbol violates a package lock. The
1017 symbol that caused the violation is accessed by the function
1018 SB-EXT:PACKAGE-LOCKED-ERROR-SYMBOL."))
1019
1020 ) ; progn
1021
1022 (define-condition undefined-alien-error (cell-error) ()
1023   (:report
1024    (lambda (condition stream)
1025      (if (slot-boundp condition 'name)
1026          (format stream "Undefined alien: ~S" (cell-error-name condition))
1027          (format stream "Undefined alien symbol.")))))
1028
1029 (define-condition undefined-alien-variable-error (undefined-alien-error) ()
1030   (:report
1031    (lambda (condition stream)
1032      (declare (ignore condition))
1033      (format stream "Attempt to access an undefined alien variable."))))
1034
1035 (define-condition undefined-alien-function-error (undefined-alien-error) ()
1036   (:report
1037    (lambda (condition stream)
1038      (declare (ignore condition))
1039      (format stream "Attempt to call an undefined alien function."))))
1040
1041 \f
1042 ;;;; various other (not specified by ANSI) CONDITIONs
1043 ;;;;
1044 ;;;; These might logically belong in other files; they're here, after
1045 ;;;; setup of CONDITION machinery, only because that makes it easier to
1046 ;;;; get cold init to work.
1047
1048 ;;; OAOOM warning: see cross-condition.lisp
1049 (define-condition encapsulated-condition (condition)
1050   ((condition :initarg :condition :reader encapsulated-condition)))
1051
1052 (define-condition values-type-error (type-error)
1053   ()
1054   (:report
1055    (lambda (condition stream)
1056      (format stream
1057              "~@<The values set ~2I~:_[~{~S~^ ~}] ~I~_is not of type ~2I~_~S.~:>"
1058              (type-error-datum condition)
1059              (type-error-expected-type condition)))))
1060
1061 ;;; KLUDGE: a condition for floating point errors when we can't or
1062 ;;; won't figure out what type they are. (In FreeBSD and OpenBSD we
1063 ;;; don't know how, at least as of sbcl-0.6.7; in Linux we probably
1064 ;;; know how but the old code was broken by the conversion to POSIX
1065 ;;; signal handling and hasn't been fixed as of sbcl-0.6.7.)
1066 ;;;
1067 ;;; FIXME: Perhaps this should also be a base class for all
1068 ;;; floating point exceptions?
1069 (define-condition floating-point-exception (arithmetic-error)
1070   ((flags :initarg :traps
1071           :initform nil
1072           :reader floating-point-exception-traps))
1073   (:report (lambda (condition stream)
1074              (format stream
1075                      "An arithmetic error ~S was signalled.~%"
1076                      (type-of condition))
1077              (let ((traps (floating-point-exception-traps condition)))
1078                (if traps
1079                    (format stream
1080                            "Trapping conditions are: ~%~{ ~S~^~}~%"
1081                            traps)
1082                    (write-line
1083                     "No traps are enabled? How can this be?"
1084                     stream))))))
1085
1086 (define-condition index-too-large-error (type-error)
1087   ()
1088   (:report
1089    (lambda (condition stream)
1090      (format stream
1091              "The index ~S is too large."
1092              (type-error-datum condition)))))
1093
1094 (define-condition bounding-indices-bad-error (reference-condition type-error)
1095   ((object :reader bounding-indices-bad-object :initarg :object))
1096   (:report
1097    (lambda (condition stream)
1098      (let* ((datum (type-error-datum condition))
1099             (start (car datum))
1100             (end (cdr datum))
1101             (object (bounding-indices-bad-object condition)))
1102        (etypecase object
1103          (sequence
1104           (format stream
1105                   "The bounding indices ~S and ~S are bad ~
1106                    for a sequence of length ~S."
1107                   start end (length object)))
1108          (array
1109           ;; from WITH-ARRAY-DATA
1110           (format stream
1111                   "The START and END parameters ~S and ~S are ~
1112                    bad for an array of total size ~S."
1113                   start end (array-total-size object)))))))
1114   (:default-initargs
1115       :references
1116       (list '(:ansi-cl :glossary "bounding index designator")
1117             '(:ansi-cl :issue "SUBSEQ-OUT-OF-BOUNDS:IS-AN-ERROR"))))
1118
1119 (define-condition nil-array-accessed-error (reference-condition type-error)
1120   ()
1121   (:report (lambda (condition stream)
1122              (declare (ignore condition))
1123              (format stream
1124                      "An attempt to access an array of element-type ~
1125                       NIL was made.  Congratulations!")))
1126   (:default-initargs
1127       :references (list '(:ansi-cl :function sb!xc:upgraded-array-element-type)
1128                         '(:ansi-cl :section (15 1 2 1))
1129                         '(:ansi-cl :section (15 1 2 2)))))
1130
1131 (define-condition namestring-parse-error (parse-error)
1132   ((complaint :reader namestring-parse-error-complaint :initarg :complaint)
1133    (args :reader namestring-parse-error-args :initarg :args :initform nil)
1134    (namestring :reader namestring-parse-error-namestring :initarg :namestring)
1135    (offset :reader namestring-parse-error-offset :initarg :offset))
1136   (:report
1137    (lambda (condition stream)
1138      (format stream
1139              "parse error in namestring: ~?~%  ~A~%  ~V@T^"
1140              (namestring-parse-error-complaint condition)
1141              (namestring-parse-error-args condition)
1142              (namestring-parse-error-namestring condition)
1143              (namestring-parse-error-offset condition)))))
1144
1145 (define-condition simple-package-error (simple-condition package-error) ())
1146
1147 (define-condition simple-reader-package-error (simple-reader-error) ())
1148
1149 (define-condition reader-eof-error (end-of-file)
1150   ((context :reader reader-eof-error-context :initarg :context))
1151   (:report
1152    (lambda (condition stream)
1153      (format stream
1154              "unexpected end of file on ~S ~A"
1155              (stream-error-stream condition)
1156              (reader-eof-error-context condition)))))
1157
1158 (define-condition reader-impossible-number-error (simple-reader-error)
1159   ((error :reader reader-impossible-number-error-error :initarg :error))
1160   (:report
1161    (lambda (condition stream)
1162      (let ((error-stream (stream-error-stream condition)))
1163        (format stream
1164                "READER-ERROR ~@[at ~W ~]on ~S:~%~?~%Original error: ~A"
1165                (file-position-or-nil-for-error error-stream) error-stream
1166                (simple-condition-format-control condition)
1167                (simple-condition-format-arguments condition)
1168                (reader-impossible-number-error-error condition))))))
1169
1170 (define-condition timeout (serious-condition)
1171   ((seconds :initarg :seconds :initform nil :reader timeout-seconds))
1172   (:report (lambda (condition stream)
1173              (format stream "Timeout occurred~@[ after ~A seconds~]."
1174                      (timeout-seconds condition)))))
1175
1176 (define-condition io-timeout (stream-error timeout)
1177   ((direction :reader io-timeout-direction :initarg :direction))
1178   (:report
1179    (lambda (condition stream)
1180      (declare (type stream stream))
1181      (format stream
1182              "I/O timeout ~(~A~)ing ~S."
1183              (io-timeout-direction condition)
1184              (stream-error-stream condition)))))
1185
1186 (define-condition deadline-timeout (timeout) ()
1187   (:report (lambda (condition stream)
1188              (format stream "A deadline was reached after ~A seconds."
1189                      (timeout-seconds condition)))))
1190
1191 (define-condition declaration-type-conflict-error (reference-condition
1192                                                    simple-error)
1193   ()
1194   (:default-initargs
1195       :format-control "symbol ~S cannot be both the name of a type and the name of a declaration"
1196     :references (list '(:ansi-cl :section (3 8 21)))))
1197
1198 ;;; Single stepping conditions
1199
1200 (define-condition step-condition ()
1201   ((form :initarg :form :reader step-condition-form))
1202
1203   #!+sb-doc
1204   (:documentation "Common base class of single-stepping conditions.
1205 STEP-CONDITION-FORM holds a string representation of the form being
1206 stepped."))
1207
1208 #!+sb-doc
1209 (setf (fdocumentation 'step-condition-form 'function)
1210       "Form associated with the STEP-CONDITION.")
1211
1212 (define-condition step-form-condition (step-condition)
1213   ((args :initarg :args :reader step-condition-args))
1214   (:report
1215    (lambda (condition stream)
1216      (let ((*print-circle* t)
1217            (*print-pretty* t)
1218            (*print-readably* nil))
1219        (format stream
1220                  "Evaluating call:~%~<  ~@;~A~:>~%~
1221                   ~:[With arguments:~%~{  ~S~%~}~;With unknown arguments~]~%"
1222                (list (step-condition-form condition))
1223                (eq (step-condition-args condition) :unknown)
1224                (step-condition-args condition)))))
1225   #!+sb-doc
1226   (:documentation "Condition signalled by code compiled with
1227 single-stepping information when about to execute a form.
1228 STEP-CONDITION-FORM holds the form, STEP-CONDITION-PATHNAME holds the
1229 pathname of the original file or NIL, and STEP-CONDITION-SOURCE-PATH
1230 holds the source-path to the original form within that file or NIL.
1231 Associated with this condition are always the restarts STEP-INTO,
1232 STEP-NEXT, and STEP-CONTINUE."))
1233
1234 #!+sb-doc
1235 (setf (fdocumentation 'step-condition-source-path 'function)
1236       "Source-path of the original form associated with the
1237 STEP-FORM-CONDITION or NIL."
1238       (fdocumentation 'step-condition-pathname 'function)
1239       "Pathname of the original source-file associated with the
1240 STEP-FORM-CONDITION or NIL.")
1241
1242 (define-condition step-result-condition (step-condition)
1243   ((result :initarg :result :reader step-condition-result)))
1244
1245 #!+sb-doc
1246 (setf (fdocumentation 'step-condition-result 'function)
1247       "Return values associated with STEP-VALUES-CONDITION as a list,
1248 or the variable value associated with STEP-VARIABLE-CONDITION.")
1249
1250 (define-condition step-values-condition (step-result-condition)
1251   ()
1252   #!+sb-doc
1253   (:documentation "Condition signalled by code compiled with
1254 single-stepping information after executing a form.
1255 STEP-CONDITION-FORM holds the form, and STEP-CONDITION-RESULT holds
1256 the values returned by the form as a list. No associated restarts."))
1257
1258 (define-condition step-finished-condition (step-condition)
1259   ()
1260   (:report
1261    (lambda (condition stream)
1262      (declare (ignore condition))
1263      (format stream "Returning from STEP")))
1264   #!+sb-doc
1265   (:documentation "Condition signaled when STEP returns."))
1266
1267 \f
1268 ;;;; restart definitions
1269
1270 (define-condition abort-failure (control-error) ()
1271   (:report
1272    "An ABORT restart was found that failed to transfer control dynamically."))
1273
1274 (defun abort (&optional condition)
1275   #!+sb-doc
1276   "Transfer control to a restart named ABORT, signalling a CONTROL-ERROR if
1277    none exists."
1278   (invoke-restart (find-restart-or-control-error 'abort condition))
1279   ;; ABORT signals an error in case there was a restart named ABORT
1280   ;; that did not transfer control dynamically. This could happen with
1281   ;; RESTART-BIND.
1282   (error 'abort-failure))
1283
1284 (defun muffle-warning (&optional condition)
1285   #!+sb-doc
1286   "Transfer control to a restart named MUFFLE-WARNING, signalling a
1287    CONTROL-ERROR if none exists."
1288   (invoke-restart (find-restart-or-control-error 'muffle-warning condition)))
1289
1290 (defun try-restart (name condition &rest arguments)
1291   (let ((restart (find-restart name condition)))
1292     (when restart
1293       (apply #'invoke-restart restart arguments))))
1294
1295 (macrolet ((define-nil-returning-restart (name args doc)
1296              #!-sb-doc (declare (ignore doc))
1297              `(defun ,name (,@args &optional condition)
1298                 #!+sb-doc ,doc
1299                 (try-restart ',name condition ,@args))))
1300   (define-nil-returning-restart continue ()
1301     "Transfer control to a restart named CONTINUE, or return NIL if none exists.")
1302   (define-nil-returning-restart store-value (value)
1303     "Transfer control and VALUE to a restart named STORE-VALUE, or return NIL if
1304    none exists.")
1305   (define-nil-returning-restart use-value (value)
1306     "Transfer control and VALUE to a restart named USE-VALUE, or return NIL if
1307    none exists."))
1308
1309 ;;; single-stepping restarts
1310
1311 (macrolet ((def (name doc)
1312                #!-sb-doc (declare (ignore doc))
1313                `(defun ,name (condition)
1314                  #!+sb-doc ,doc
1315                  (invoke-restart (find-restart-or-control-error ',name condition)))))
1316   (def step-continue
1317       "Transfers control to the STEP-CONTINUE restart associated with
1318 the condition, continuing execution without stepping. Signals a
1319 CONTROL-ERROR if the restart does not exist.")
1320   (def step-next
1321       "Transfers control to the STEP-NEXT restart associated with the
1322 condition, executing the current form without stepping and continuing
1323 stepping with the next form. Signals CONTROL-ERROR is the restart does
1324 not exists.")
1325   (def step-into
1326       "Transfers control to the STEP-INTO restart associated with the
1327 condition, stepping into the current form. Signals a CONTROL-ERROR is
1328 the restart does not exist."))
1329
1330 (/show0 "condition.lisp end of file")
1331