src/code/condition.lisp

   1 ;;;; stuff originally from CMU CL's error.lisp which can or should
   2 ;;;; come late (mostly related to the CONDITION class itself)
   3 ;;;;
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!KERNEL")
  15 \f
  16 ;;;; miscellaneous support utilities
  17
  18 ;;; Signalling an error when trying to print an error condition is
  19 ;;; generally a PITA, so whatever the failure encountered when
  20 ;;; wondering about FILE-POSITION within a condition printer, 'tis
  21 ;;; better silently to give up than to try to complain.
  22 (defun file-position-or-nil-for-error (stream &optional (pos nil posp))
  23   ;; Arguably FILE-POSITION shouldn't be signalling errors at all; but
  24   ;; "NIL if this cannot be determined" in the ANSI spec doesn't seem
  25   ;; absolutely unambiguously to prohibit errors when, e.g., STREAM
  26   ;; has been closed so that FILE-POSITION is a nonsense question. So
  27   ;; my (WHN) impression is that the conservative approach is to
  28   ;; IGNORE-ERRORS. (I encountered this failure from within a homebrew
  29   ;; defsystemish operation where the ERROR-STREAM had been CL:CLOSEd,
  30   ;; I think by nonlocally exiting through a WITH-OPEN-FILE, by the
  31   ;; time an error was reported.)
  32   (if posp
  33       (ignore-errors (file-position stream pos))
  34       (ignore-errors (file-position stream))))
  35 \f
  36 ;;;; the CONDITION class
  37
  38 (/show0 "condition.lisp 20")
  39
  40 (eval-when (:compile-toplevel :load-toplevel :execute)
  41
  42 (/show0 "condition.lisp 24")
  43
  44 (def!struct (condition-classoid (:include classoid)
  45                                 (:constructor make-condition-classoid))
  46   ;; list of CONDITION-SLOT structures for the direct slots of this
  47   ;; class
  48   (slots nil :type list)
  49   ;; list of CONDITION-SLOT structures for all of the effective class
  50   ;; slots of this class
  51   (class-slots nil :type list)
  52   ;; report function or NIL
  53   (report nil :type (or function null))
  54   ;; list of alternating initargs and initforms
  55   (default-initargs () :type list)
  56   ;; class precedence list as a list of CLASS objects, with all
  57   ;; non-CONDITION classes removed
  58   (cpl () :type list)
  59   ;; a list of all the effective instance allocation slots of this
  60   ;; class that have a non-constant initform or default-initarg.
  61   ;; Values for these slots must be computed in the dynamic
  62   ;; environment of MAKE-CONDITION.
  63   (hairy-slots nil :type list))
  64
  65 (/show0 "condition.lisp 49")
  66
  67 ) ; EVAL-WHEN
  68
  69 (!defstruct-with-alternate-metaclass condition
  70   :slot-names (actual-initargs assigned-slots)
  71   :boa-constructor %make-condition-object
  72   :superclass-name t
  73   :metaclass-name condition-classoid
  74   :metaclass-constructor make-condition-classoid
  75   :dd-type structure)
  76
  77 (defun make-condition-object (actual-initargs)
  78   (%make-condition-object actual-initargs nil))
  79
  80 (defstruct (condition-slot (:copier nil))
  81   (name (missing-arg) :type symbol)
  82   ;; list of all applicable initargs
  83   (initargs (missing-arg) :type list)
  84   ;; names of reader and writer functions
  85   (readers (missing-arg) :type list)
  86   (writers (missing-arg) :type list)
  87   ;; true if :INITFORM was specified
  88   (initform-p (missing-arg) :type (member t nil))
  89   ;; If this is a function, call it with no args. Otherwise, it's the
  90   ;; actual value.
  91   (initform (missing-arg) :type t)
  92   ;; allocation of this slot, or NIL until defaulted
  93   (allocation nil :type (member :instance :class nil))
  94   ;; If ALLOCATION is :CLASS, this is a cons whose car holds the value.
  95   (cell nil :type (or cons null))
  96   ;; slot documentation
  97   (documentation nil :type (or string null)))
  98
  99 ;;; KLUDGE: It's not clear to me why CONDITION-CLASS has itself listed
 100 ;;; in its CPL, while other classes derived from CONDITION-CLASS don't
 101 ;;; have themselves listed in their CPLs. This behavior is inherited
 102 ;;; from CMU CL, and didn't seem to be explained there, and I haven't
 103 ;;; figured out whether it's right. -- WHN 19990612
 104 (eval-when (:compile-toplevel :load-toplevel :execute)
 105   (/show0 "condition.lisp 103")
 106   (let ((condition-class (locally
 107                            ;; KLUDGE: There's a DEFTRANSFORM
 108                            ;; FIND-CLASSOID for constant class names
 109                            ;; which creates fast but
 110                            ;; non-cold-loadable, non-compact code. In
 111                            ;; this context, we'd rather have compact,
 112                            ;; cold-loadable code. -- WHN 19990928
 113                            (declare (notinline find-classoid))
 114                            (find-classoid 'condition))))
 115     (setf (condition-classoid-cpl condition-class)
 116           (list condition-class)))
 117   (/show0 "condition.lisp 103"))
 118
 119 (setf (condition-classoid-report (locally
 120                                    ;; KLUDGE: There's a DEFTRANSFORM
 121                                    ;; FIND-CLASSOID for constant class
 122                                    ;; names which creates fast but
 123                                    ;; non-cold-loadable, non-compact
 124                                    ;; code. In this context, we'd
 125                                    ;; rather have compact,
 126                                    ;; cold-loadable code. -- WHN
 127                                    ;; 19990928
 128                                    (declare (notinline find-classoid))
 129                                    (find-classoid 'condition)))
 130       (lambda (cond stream)
 131         (format stream "Condition ~S was signalled." (type-of cond))))
 132
 133 (eval-when (:compile-toplevel :load-toplevel :execute)
 134
 135 (defun find-condition-layout (name parent-types)
 136   (let* ((cpl (remove-duplicates
 137                (reverse
 138                 (reduce #'append
 139                         (mapcar (lambda (x)
 140                                   (condition-classoid-cpl
 141                                    (find-classoid x)))
 142                                 parent-types)))))
 143          (cond-layout (info :type :compiler-layout 'condition))
 144          (olayout (info :type :compiler-layout name))
 145          ;; FIXME: Does this do the right thing in case of multiple
 146          ;; inheritance? A quick look at DEFINE-CONDITION didn't make
 147          ;; it obvious what ANSI intends to be done in the case of
 148          ;; multiple inheritance, so it's not actually clear what the
 149          ;; right thing is..
 150          (new-inherits
 151           (order-layout-inherits (concatenate 'simple-vector
 152                                               (layout-inherits cond-layout)
 153                                               (mapcar #'classoid-layout cpl)))))
 154     (if (and olayout
 155              (not (mismatch (layout-inherits olayout) new-inherits)))
 156         olayout
 157         (make-layout :classoid (make-undefined-classoid name)
 158                      :inherits new-inherits
 159                      :depthoid -1
 160                      :length (layout-length cond-layout)))))
 161
 162 ) ; EVAL-WHEN
 163
 164 ;;; FIXME: ANSI's definition of DEFINE-CONDITION says
 165 ;;;   Condition reporting is mediated through the PRINT-OBJECT method
 166 ;;;   for the condition type in question, with *PRINT-ESCAPE* always
 167 ;;;   being nil. Specifying (:REPORT REPORT-NAME) in the definition of
 168 ;;;   a condition type C is equivalent to:
 169 ;;;     (defmethod print-object ((x c) stream)
 170 ;;;       (if *print-escape* (call-next-method) (report-name x stream)))
 171 ;;; The current code doesn't seem to quite match that.
 172 (def!method print-object ((x condition) stream)
 173   (if *print-escape*
 174       (if (and (typep x 'simple-condition) (slot-value x 'format-control))
 175           (print-unreadable-object (x stream :type t :identity t)
 176             (write (simple-condition-format-control x)
 177                    :stream stream
 178                    :lines 1))
 179           (print-unreadable-object (x stream :type t :identity t)))
 180       ;; KLUDGE: A comment from CMU CL here said
 181       ;;   7/13/98 BUG? CPL is not sorted and results here depend on order of
 182       ;;   superclasses in define-condition call!
 183       (dolist (class (condition-classoid-cpl (classoid-of x))
 184                      (error "no REPORT? shouldn't happen!"))
 185         (let ((report (condition-classoid-report class)))
 186           (when report
 187             (return (funcall report x stream)))))))
 188 \f
 189 ;;;; slots of CONDITION objects
 190
 191 (defvar *empty-condition-slot* '(empty))
 192
 193 (defun find-slot-default (class slot)
 194   (let ((initargs (condition-slot-initargs slot))
 195         (cpl (condition-classoid-cpl class)))
 196     (dolist (class cpl)
 197       (let ((default-initargs (condition-classoid-default-initargs class)))
 198         (dolist (initarg initargs)
 199           (let ((val (getf default-initargs initarg *empty-condition-slot*)))
 200             (unless (eq val *empty-condition-slot*)
 201               (return-from find-slot-default
 202                            (if (functionp val)
 203                                (funcall val)
 204                                val)))))))
 205
 206     (if (condition-slot-initform-p slot)
 207         (let ((initform (condition-slot-initform slot)))
 208           (if (functionp initform)
 209               (funcall initform)
 210               initform))
 211         (error "unbound condition slot: ~S" (condition-slot-name slot)))))
 212
 213 (defun find-condition-class-slot (condition-class slot-name)
 214   (dolist (sclass
 215            (condition-classoid-cpl condition-class)
 216            (error "There is no slot named ~S in ~S."
 217                   slot-name condition-class))
 218     (dolist (slot (condition-classoid-slots sclass))
 219       (when (eq (condition-slot-name slot) slot-name)
 220         (return-from find-condition-class-slot slot)))))
 221
 222 (defun condition-writer-function (condition new-value name)
 223   (dolist (cslot (condition-classoid-class-slots
 224                   (layout-classoid (%instance-layout condition)))
 225                  (setf (getf (condition-assigned-slots condition) name)
 226                        new-value))
 227     (when (eq (condition-slot-name cslot) name)
 228       (return (setf (car (condition-slot-cell cslot)) new-value)))))
 229
 230 (defun condition-reader-function (condition name)
 231   (let ((class (layout-classoid (%instance-layout condition))))
 232     (dolist (cslot (condition-classoid-class-slots class))
 233       (when (eq (condition-slot-name cslot) name)
 234         (return-from condition-reader-function
 235                      (car (condition-slot-cell cslot)))))
 236     (let ((val (getf (condition-assigned-slots condition) name
 237                      *empty-condition-slot*)))
 238       (if (eq val *empty-condition-slot*)
 239           (let ((actual-initargs (condition-actual-initargs condition))
 240                 (slot (find-condition-class-slot class name)))
 241             (unless slot
 242               (error "missing slot ~S of ~S" name condition))
 243             (do ((initargs actual-initargs (cddr initargs)))
 244                 ((endp initargs)
 245                  (setf (getf (condition-assigned-slots condition) name)
 246                        (find-slot-default class slot)))
 247               (when (member (car initargs) (condition-slot-initargs slot))
 248                 (return-from condition-reader-function
 249                   (setf (getf (condition-assigned-slots condition)
 250                               name)
 251                         (cadr initargs))))))
 252           val))))
 253 \f
 254 ;;;; MAKE-CONDITION
 255
 256 (defun make-condition (type &rest args)
 257   #!+sb-doc
 258   "Make an instance of a condition object using the specified initargs."
 259   ;; Note: ANSI specifies no exceptional situations in this function.
 260   ;; signalling simple-type-error would not be wrong.
 261   (let* ((type (or (and (symbolp type) (find-classoid type nil))
 262                     type))
 263          (class (typecase type
 264                   (condition-classoid type)
 265                   (class
 266                    ;; Punt to CLOS.
 267                    (return-from make-condition (apply #'make-instance type args)))
 268                   (classoid
 269                    (error 'simple-type-error
 270                           :datum type
 271                           :expected-type 'condition-class
 272                           :format-control "~S is not a condition class."
 273                           :format-arguments (list type)))
 274                   (t
 275                    (error 'simple-type-error
 276                           :datum type
 277                           :expected-type 'condition-class
 278                           :format-control "Bad type argument:~%  ~S"
 279                           :format-arguments (list type)))))
 280          (res (make-condition-object args)))
 281     (setf (%instance-layout res) (classoid-layout class))
 282     ;; Set any class slots with initargs present in this call.
 283     (dolist (cslot (condition-classoid-class-slots class))
 284       (dolist (initarg (condition-slot-initargs cslot))
 285         (let ((val (getf args initarg *empty-condition-slot*)))
 286           (unless (eq val *empty-condition-slot*)
 287             (setf (car (condition-slot-cell cslot)) val)))))
 288     ;; Default any slots with non-constant defaults now.
 289     (dolist (hslot (condition-classoid-hairy-slots class))
 290       (when (dolist (initarg (condition-slot-initargs hslot) t)
 291               (unless (eq (getf args initarg *empty-condition-slot*)
 292                           *empty-condition-slot*)
 293                 (return nil)))
 294         (setf (getf (condition-assigned-slots res) (condition-slot-name hslot))
 295               (find-slot-default class hslot))))
 296     res))
 297 \f
 298 ;;;; DEFINE-CONDITION
 299
 300 (eval-when (:compile-toplevel :load-toplevel :execute)
 301 (defun %compiler-define-condition (name direct-supers layout
 302                                    all-readers all-writers)
 303   (with-single-package-locked-error
 304       (:symbol name "defining ~A as a condition")
 305     (sb!xc:proclaim `(ftype (function (t) t) ,@all-readers))
 306     (sb!xc:proclaim `(ftype (function (t t) t) ,@all-writers))
 307     (multiple-value-bind (class old-layout)
 308         (insured-find-classoid name
 309                                #'condition-classoid-p
 310                                #'make-condition-classoid)
 311       (setf (layout-classoid layout) class)
 312       (setf (classoid-direct-superclasses class)
 313             (mapcar #'find-classoid direct-supers))
 314       (cond ((not old-layout)
 315              (register-layout layout))
 316             ((not *type-system-initialized*)
 317              (setf (layout-classoid old-layout) class)
 318              (setq layout old-layout)
 319              (unless (eq (classoid-layout class) layout)
 320                (register-layout layout)))
 321             ((redefine-layout-warning "current"
 322                                       old-layout
 323                                       "new"
 324                                       (layout-length layout)
 325                                       (layout-inherits layout)
 326                                       (layout-depthoid layout)
 327                                       (layout-n-untagged-slots layout))
 328              (register-layout layout :invalidate t))
 329             ((not (classoid-layout class))
 330              (register-layout layout)))
 331
 332       (setf (layout-info layout)
 333             (locally
 334                 ;; KLUDGE: There's a FIND-CLASS DEFTRANSFORM for constant class
 335                 ;; names which creates fast but non-cold-loadable, non-compact
 336                 ;; code. In this context, we'd rather have compact, cold-loadable
 337                 ;; code. -- WHN 19990928
 338                 (declare (notinline find-classoid))
 339               (layout-info (classoid-layout (find-classoid 'condition)))))
 340
 341       (setf (find-classoid name) class)
 342
 343       ;; Initialize CPL slot.
 344       (setf (condition-classoid-cpl class)
 345             (remove-if-not #'condition-classoid-p
 346                            (std-compute-class-precedence-list class)))))
 347   (values))
 348 ) ; EVAL-WHEN
 349
 350 ;;; Compute the effective slots of CLASS, copying inherited slots and
 351 ;;; destructively modifying direct slots.
 352 ;;;
 353 ;;; FIXME: It'd be nice to explain why it's OK to destructively modify
 354 ;;; direct slots. Presumably it follows from the semantics of
 355 ;;; inheritance and redefinition of conditions, but finding the cite
 356 ;;; and documenting it here would be good. (Or, if this is not in fact
 357 ;;; ANSI-compliant, fixing it would also be good.:-)
 358 (defun compute-effective-slots (class)
 359   (collect ((res (copy-list (condition-classoid-slots class))))
 360     (dolist (sclass (cdr (condition-classoid-cpl class)))
 361       (dolist (sslot (condition-classoid-slots sclass))
 362         (let ((found (find (condition-slot-name sslot) (res)
 363                            :key #'condition-slot-name)))
 364           (cond (found
 365                  (setf (condition-slot-initargs found)
 366                        (union (condition-slot-initargs found)
 367                               (condition-slot-initargs sslot)))
 368                  (unless (condition-slot-initform-p found)
 369                    (setf (condition-slot-initform-p found)
 370                          (condition-slot-initform-p sslot))
 371                    (setf (condition-slot-initform found)
 372                          (condition-slot-initform sslot)))
 373                  (unless (condition-slot-allocation found)
 374                    (setf (condition-slot-allocation found)
 375                          (condition-slot-allocation sslot))))
 376                 (t
 377                  (res (copy-structure sslot)))))))
 378     (res)))
 379
 380 ;;; Early definitions of slot accessor creators.
 381 ;;;
 382 ;;; Slot accessors must be generic functions, but ANSI does not seem
 383 ;;; to specify any of them, and we cannot support it before end of
 384 ;;; warm init. So we use ordinary functions inside SBCL, and switch to
 385 ;;; GFs only at the end of building.
 386 (declaim (notinline install-condition-slot-reader
 387                     install-condition-slot-writer))
 388 (defun install-condition-slot-reader (name condition slot-name)
 389   (declare (ignore condition))
 390   (setf (fdefinition name)
 391         (lambda (condition)
 392           (condition-reader-function condition slot-name))))
 393 (defun install-condition-slot-writer (name condition slot-name)
 394   (declare (ignore condition))
 395   (setf (fdefinition name)
 396         (lambda (new-value condition)
 397           (condition-writer-function condition new-value slot-name))))
 398
 399 (defvar *define-condition-hooks* nil)
 400
 401 (defun %define-condition (name parent-types layout slots documentation
 402                           report default-initargs all-readers all-writers
 403                           source-location)
 404   (with-single-package-locked-error
 405       (:symbol name "defining ~A as a condition")
 406     (%compiler-define-condition name parent-types layout all-readers all-writers)
 407     (sb!c:with-source-location (source-location)
 408       (setf (layout-source-location layout)
 409             source-location))
 410     (let ((class (find-classoid name)))
 411       (setf (condition-classoid-slots class) slots)
 412       (setf (condition-classoid-report class) report)
 413       (setf (condition-classoid-default-initargs class) default-initargs)
 414       (setf (fdocumentation name 'type) documentation)
 415
 416       (dolist (slot slots)
 417
 418         ;; Set up reader and writer functions.
 419         (let ((slot-name (condition-slot-name slot)))
 420           (dolist (reader (condition-slot-readers slot))
 421             (install-condition-slot-reader reader name slot-name))
 422           (dolist (writer (condition-slot-writers slot))
 423             (install-condition-slot-writer writer name slot-name))))
 424
 425       ;; Compute effective slots and set up the class and hairy slots
 426       ;; (subsets of the effective slots.)
 427       (let ((eslots (compute-effective-slots class))
 428             (e-def-initargs
 429              (reduce #'append
 430                      (mapcar #'condition-classoid-default-initargs
 431                            (condition-classoid-cpl class)))))
 432         (dolist (slot eslots)
 433           (ecase (condition-slot-allocation slot)
 434             (:class
 435              (unless (condition-slot-cell slot)
 436                (setf (condition-slot-cell slot)
 437                      (list (if (condition-slot-initform-p slot)
 438                                (let ((initform (condition-slot-initform slot)))
 439                                  (if (functionp initform)
 440                                      (funcall initform)
 441                                      initform))
 442                                *empty-condition-slot*))))
 443              (push slot (condition-classoid-class-slots class)))
 444             ((:instance nil)
 445              (setf (condition-slot-allocation slot) :instance)
 446              (when (or (functionp (condition-slot-initform slot))
 447                        (dolist (initarg (condition-slot-initargs slot) nil)
 448                          (when (functionp (getf e-def-initargs initarg))
 449                            (return t))))
 450                (push slot (condition-classoid-hairy-slots class)))))))
 451       (when (boundp '*define-condition-hooks*)
 452         (dolist (fun *define-condition-hooks*)
 453           (funcall fun class))))
 454     name))
 455
 456 (defmacro define-condition (name (&rest parent-types) (&rest slot-specs)
 457                                  &body options)
 458   #!+sb-doc
 459   "DEFINE-CONDITION Name (Parent-Type*) (Slot-Spec*) Option*
 460    Define NAME as a condition type. This new type inherits slots and its
 461    report function from the specified PARENT-TYPEs. A slot spec is a list of:
 462      (slot-name :reader <rname> :initarg <iname> {Option Value}*
 463
 464    The DEFINE-CLASS slot options :ALLOCATION, :INITFORM, [slot] :DOCUMENTATION
 465    and :TYPE and the overall options :DEFAULT-INITARGS and
 466    [type] :DOCUMENTATION are also allowed.
 467
 468    The :REPORT option is peculiar to DEFINE-CONDITION. Its argument is either
 469    a string or a two-argument lambda or function name. If a function, the
 470    function is called with the condition and stream to report the condition.
 471    If a string, the string is printed.
 472
 473    Condition types are classes, but (as allowed by ANSI and not as described in
 474    CLtL2) are neither STANDARD-OBJECTs nor STRUCTURE-OBJECTs. WITH-SLOTS and
 475    SLOT-VALUE may not be used on condition objects."
 476   (let* ((parent-types (or parent-types '(condition)))
 477          (layout (find-condition-layout name parent-types))
 478          (documentation nil)
 479          (report nil)
 480          (default-initargs ()))
 481     (collect ((slots)
 482               (all-readers nil append)
 483               (all-writers nil append))
 484       (dolist (spec slot-specs)
 485         (when (keywordp spec)
 486           (warn "Keyword slot name indicates probable syntax error:~%  ~S"
 487                 spec))
 488         (let* ((spec (if (consp spec) spec (list spec)))
 489                (slot-name (first spec))
 490                (allocation :instance)
 491                (initform-p nil)
 492                documentation
 493                initform)
 494           (collect ((initargs)
 495                     (readers)
 496                     (writers))
 497             (do ((options (rest spec) (cddr options)))
 498                 ((null options))
 499               (unless (and (consp options) (consp (cdr options)))
 500                 (error "malformed condition slot spec:~%  ~S." spec))
 501               (let ((arg (second options)))
 502                 (case (first options)
 503                   (:reader (readers arg))
 504                   (:writer (writers arg))
 505                   (:accessor
 506                    (readers arg)
 507                    (writers `(setf ,arg)))
 508                   (:initform
 509                    (when initform-p
 510                      (error "more than one :INITFORM in ~S" spec))
 511                    (setq initform-p t)
 512                    (setq initform arg))
 513                   (:initarg (initargs arg))
 514                   (:allocation
 515                    (setq allocation arg))
 516                   (:documentation
 517                    (when documentation
 518                      (error "more than one :DOCUMENTATION in ~S" spec))
 519                    (unless (stringp arg)
 520                      (error "slot :DOCUMENTATION argument is not a string: ~S"
 521                             arg))
 522                    (setq documentation arg))
 523                   (:type)
 524                   (t
 525                    (error "unknown slot option:~%  ~S" (first options))))))
 526
 527             (all-readers (readers))
 528             (all-writers (writers))
 529             (slots `(make-condition-slot
 530                      :name ',slot-name
 531                      :initargs ',(initargs)
 532                      :readers ',(readers)
 533                      :writers ',(writers)
 534                      :initform-p ',initform-p
 535                      :documentation ',documentation
 536                      :initform
 537                      ,(if (sb!xc:constantp initform)
 538                           `',(constant-form-value initform)
 539                           `#'(lambda () ,initform)))))))
 540
 541       (dolist (option options)
 542         (unless (consp option)
 543           (error "bad option:~%  ~S" option))
 544         (case (first option)
 545           (:documentation (setq documentation (second option)))
 546           (:report
 547            (let ((arg (second option)))
 548              (setq report
 549                    (if (stringp arg)
 550                        `#'(lambda (condition stream)
 551                           (declare (ignore condition))
 552                           (write-string ,arg stream))
 553                        `#'(lambda (condition stream)
 554                           (funcall #',arg condition stream))))))
 555           (:default-initargs
 556            (do ((initargs (rest option) (cddr initargs)))
 557                ((endp initargs))
 558              (let ((val (second initargs)))
 559                (setq default-initargs
 560                      (list* `',(first initargs)
 561                             (if (sb!xc:constantp val)
 562                                 `',(constant-form-value val)
 563                                 `#'(lambda () ,val))
 564                             default-initargs)))))
 565           (t
 566            (error "unknown option: ~S" (first option)))))
 567
 568       `(progn
 569          (eval-when (:compile-toplevel)
 570            (%compiler-define-condition ',name ',parent-types ',layout
 571                                        ',(all-readers) ',(all-writers)))
 572          (eval-when (:load-toplevel :execute)
 573            (%define-condition ',name
 574                               ',parent-types
 575                               ',layout
 576                               (list ,@(slots))
 577                               ,documentation
 578                               ,report
 579                               (list ,@default-initargs)
 580                               ',(all-readers)
 581                               ',(all-writers)
 582                               (sb!c:source-location)))))))
 583 \f
 584 ;;;; various CONDITIONs specified by ANSI
 585
 586 (define-condition serious-condition (condition) ())
 587
 588 (define-condition error (serious-condition) ())
 589
 590 (define-condition warning (condition) ())
 591 (define-condition style-warning (warning) ())
 592
 593 (defun simple-condition-printer (condition stream)
 594   (let ((control (simple-condition-format-control condition)))
 595     (if control
 596         (apply #'format stream
 597                control
 598                (simple-condition-format-arguments condition))
 599         (error "No format-control for ~S" condition))))
 600
 601 (define-condition simple-condition ()
 602   ((format-control :reader simple-condition-format-control
 603                    :initarg :format-control
 604                    :initform nil
 605                    :type format-control)
 606    (format-arguments :reader simple-condition-format-arguments
 607                      :initarg :format-arguments
 608                      :initform nil
 609                      :type list))
 610   (:report simple-condition-printer))
 611
 612 (define-condition simple-warning (simple-condition warning) ())
 613
 614 (define-condition simple-error (simple-condition error) ())
 615
 616 (define-condition storage-condition (serious-condition) ())
 617
 618 (define-condition type-error (error)
 619   ((datum :reader type-error-datum :initarg :datum)
 620    (expected-type :reader type-error-expected-type :initarg :expected-type))
 621   (:report
 622    (lambda (condition stream)
 623      (format stream
 624              "~@<The value ~2I~:_~S ~I~_is not of type ~2I~_~S.~:>"
 625              (type-error-datum condition)
 626              (type-error-expected-type condition)))))
 627
 628 (def!method print-object ((condition type-error) stream)
 629   (if *print-escape*
 630       (flet ((maybe-string (thing)
 631                (ignore-errors
 632                  (write-to-string thing :lines 1 :readably nil :array nil :pretty t))))
 633         (let ((type (maybe-string (type-error-expected-type condition)))
 634               (datum (maybe-string (type-error-datum condition))))
 635           (if (and type datum)
 636               (print-unreadable-object (condition stream :type t)
 637                 (format stream "~@<expected-type: ~A ~_datum: ~A~:@>" type datum))
 638               (call-next-method))))
 639       (call-next-method)))
 640
 641 ;;; not specified by ANSI, but too useful not to have around.
 642 (define-condition simple-style-warning (simple-condition style-warning) ())
 643 (define-condition simple-type-error (simple-condition type-error) ())
 644
 645 ;; Can't have a function called SIMPLE-TYPE-ERROR or TYPE-ERROR...
 646 (declaim (ftype (sfunction (t t t &rest t) nil) bad-type))
 647 (defun bad-type (datum type control &rest arguments)
 648   (error 'simple-type-error
 649          :datum datum
 650          :expected-type type
 651          :format-control control
 652          :format-arguments arguments))
 653
 654 (define-condition program-error (error) ())
 655 (define-condition parse-error   (error) ())
 656 (define-condition control-error (error) ())
 657 (define-condition stream-error  (error)
 658   ((stream :reader stream-error-stream :initarg :stream)))
 659
 660 (define-condition end-of-file (stream-error) ()
 661   (:report
 662    (lambda (condition stream)
 663      (format stream
 664              "end of file on ~S"
 665              (stream-error-stream condition)))))
 666
 667 (define-condition closed-stream-error (stream-error) ()
 668   (:report
 669    (lambda (condition stream)
 670      (format stream "~S is closed" (stream-error-stream condition)))))
 671
 672 (define-condition file-error (error)
 673   ((pathname :reader file-error-pathname :initarg :pathname))
 674   (:report
 675    (lambda (condition stream)
 676      (format stream "error on file ~S" (file-error-pathname condition)))))
 677
 678 (define-condition package-error (error)
 679   ((package :reader package-error-package :initarg :package)))
 680
 681 (define-condition cell-error (error)
 682   ((name :reader cell-error-name :initarg :name)))
 683
 684 (def!method print-object ((condition cell-error) stream)
 685   (if (and *print-escape* (slot-boundp condition 'name))
 686       (print-unreadable-object (condition stream :type t :identity t)
 687         (princ (cell-error-name condition) stream))
 688       (call-next-method)))
 689
 690 (define-condition unbound-variable (cell-error) ()
 691   (:report
 692    (lambda (condition stream)
 693      (format stream
 694              "The variable ~S is unbound."
 695              (cell-error-name condition)))))
 696
 697 (define-condition undefined-function (cell-error) ()
 698   (:report
 699    (lambda (condition stream)
 700      (format stream
 701              "The function ~/sb-impl::print-symbol-with-prefix/ is undefined."
 702              (cell-error-name condition)))))
 703
 704 (define-condition special-form-function (undefined-function) ()
 705   (:report
 706    (lambda (condition stream)
 707      (format stream
 708              "Cannot FUNCALL the SYMBOL-FUNCTION of special operator ~S."
 709              (cell-error-name condition)))))
 710
 711 (define-condition arithmetic-error (error)
 712   ((operation :reader arithmetic-error-operation
 713               :initarg :operation
 714               :initform nil)
 715    (operands :reader arithmetic-error-operands
 716              :initarg :operands))
 717   (:report (lambda (condition stream)
 718              (format stream
 719                      "arithmetic error ~S signalled"
 720                      (type-of condition))
 721              (when (arithmetic-error-operation condition)
 722                (format stream
 723                        "~%Operation was ~S, operands ~S."
 724                        (arithmetic-error-operation condition)
 725                        (arithmetic-error-operands condition))))))
 726
 727 (define-condition division-by-zero         (arithmetic-error) ())
 728 (define-condition floating-point-overflow  (arithmetic-error) ())
 729 (define-condition floating-point-underflow (arithmetic-error) ())
 730 (define-condition floating-point-inexact   (arithmetic-error) ())
 731 (define-condition floating-point-invalid-operation (arithmetic-error) ())
 732
 733 (define-condition print-not-readable (error)
 734   ((object :reader print-not-readable-object :initarg :object))
 735   (:report
 736    (lambda (condition stream)
 737      (let ((obj (print-not-readable-object condition))
 738            (*print-array* nil))
 739        (format stream "~S cannot be printed readably." obj)))))
 740
 741 (define-condition reader-error (parse-error stream-error) ()
 742   (:report (lambda (condition stream)
 743              (%report-reader-error condition stream))))
 744
 745 ;;; a READER-ERROR whose REPORTing is controlled by FORMAT-CONTROL and
 746 ;;; FORMAT-ARGS (the usual case for READER-ERRORs signalled from
 747 ;;; within SBCL itself)
 748 ;;;
 749 ;;; (Inheriting CL:SIMPLE-CONDITION here isn't quite consistent with
 750 ;;; the letter of the ANSI spec: this is not a condition signalled by
 751 ;;; SIGNAL when a format-control is supplied by the function's first
 752 ;;; argument. It seems to me (WHN) to be basically in the spirit of
 753 ;;; the spec, but if not, it'd be straightforward to do our own
 754 ;;; DEFINE-CONDITION SB-INT:SIMPLISTIC-CONDITION with
 755 ;;; FORMAT-CONTROL and FORMAT-ARGS slots, and use that condition in
 756 ;;; place of CL:SIMPLE-CONDITION here.)
 757 (define-condition simple-reader-error (reader-error simple-condition)
 758   ()
 759   (:report (lambda (condition stream)
 760              (%report-reader-error condition stream :simple t))))
 761
 762 ;;; base REPORTing of a READER-ERROR
 763 ;;;
 764 ;;; When SIMPLE, we expect and use SIMPLE-CONDITION-ish FORMAT-CONTROL
 765 ;;; and FORMAT-ARGS slots.
 766 (defun %report-reader-error (condition stream &key simple)
 767   (let* ((error-stream (stream-error-stream condition))
 768          (pos (file-position-or-nil-for-error error-stream)))
 769     (when (and pos (plusp pos))
 770       ;; FILE-POSITION is the next character -- error is at the previous one.
 771       (decf pos))
 772     (let (lineno colno)
 773       (when (and pos
 774                  (< pos sb!xc:array-dimension-limit)
 775                  ;; KLUDGE: lseek() (which is what FILE-POSITION
 776                  ;; reduces to on file-streams) is undefined on
 777                  ;; "some devices", which in practice means that it
 778                  ;; can claim to succeed on /dev/stdin on Darwin
 779                  ;; and Solaris.  This is obviously bad news,
 780                  ;; because the READ-SEQUENCE below will then
 781                  ;; block, not complete, and the report will never
 782                  ;; be printed.  As a workaround, we exclude
 783                  ;; interactive streams from this attempt to report
 784                  ;; positions.  -- CSR, 2003-08-21
 785                  (not (interactive-stream-p error-stream))
 786                  (file-position error-stream :start))
 787         (let ((string
 788                (make-string pos
 789                             :element-type (stream-element-type
 790                                            error-stream))))
 791           (when (= pos (read-sequence string error-stream))
 792             ;; Lines count from 1, columns from 0. It's stupid and traditional.
 793             (setq lineno (1+ (count #\Newline string))
 794                   colno (- pos (or (position #\Newline string :from-end t) 0)))))
 795         (file-position-or-nil-for-error error-stream pos))
 796       (pprint-logical-block (stream nil)
 797         (if simple
 798             (apply #'format stream
 799                    (simple-condition-format-control condition)
 800                    (simple-condition-format-arguments condition))
 801             (prin1 (class-name (class-of condition)) stream))
 802         (format stream "~2I~@[~_~_~:{~:(~A~): ~S~:^, ~:_~}~]~_~_Stream: ~S"
 803                 (remove-if-not #'second
 804                                (list (list :line lineno)
 805                                      (list :column colno)
 806                                      (list :file-position pos)))
 807                 error-stream)))))
 808 \f
 809 ;;;; special SBCL extension conditions
 810
 811 ;;; an error apparently caused by a bug in SBCL itself
 812 ;;;
 813 ;;; Note that we don't make any serious effort to use this condition
 814 ;;; for *all* errors in SBCL itself. E.g. type errors and array
 815 ;;; indexing errors can occur in functions called from SBCL code, and
 816 ;;; will just end up as ordinary TYPE-ERROR or invalid index error,
 817 ;;; because the signalling code has no good way to know that the
 818 ;;; underlying problem is a bug in SBCL. But in the fairly common case
 819 ;;; that the signalling code does know that it's found a bug in SBCL,
 820 ;;; this condition is appropriate, reusing boilerplate and helping
 821 ;;; users to recognize it as an SBCL bug.
 822 (define-condition bug (simple-error)
 823   ()
 824   (:report
 825    (lambda (condition stream)
 826      (format stream
 827              "~@<  ~? ~:@_~?~:>"
 828              (simple-condition-format-control condition)
 829              (simple-condition-format-arguments condition)
 830              "~@<This is probably a bug in SBCL itself. (Alternatively, ~
 831               SBCL might have been corrupted by bad user code, e.g. by an ~
 832               undefined Lisp operation like ~S, or by stray pointers from ~
 833               alien code or from unsafe Lisp code; or there might be a bug ~
 834               in the OS or hardware that SBCL is running on.) If it seems to ~
 835               be a bug in SBCL itself, the maintainers would like to know ~
 836               about it. Bug reports are welcome on the SBCL ~
 837               mailing lists, which you can find at ~
 838               <http://sbcl.sourceforge.net/>.~:@>"
 839              '((fmakunbound 'compile))))))
 840
 841 (define-condition simple-storage-condition (storage-condition simple-condition)
 842   ())
 843
 844 ;;; a condition for use in stubs for operations which aren't supported
 845 ;;; on some platforms
 846 ;;;
 847 ;;; E.g. in sbcl-0.7.0.5, it might be appropriate to do something like
 848 ;;;   #-(or freebsd linux)
 849 ;;;   (defun load-foreign (&rest rest)
 850 ;;;     (error 'unsupported-operator :name 'load-foreign))
 851 ;;;   #+(or freebsd linux)
 852 ;;;   (defun load-foreign ... actual definition ...)
 853 ;;; By signalling a standard condition in this case, we make it
 854 ;;; possible for test code to distinguish between (1) intentionally
 855 ;;; unimplemented and (2) unintentionally just screwed up somehow.
 856 ;;; (Before this condition was defined, test code tried to deal with
 857 ;;; this by checking for FBOUNDP, but that didn't work reliably. In
 858 ;;; sbcl-0.7.0, a package screwup left the definition of
 859 ;;; LOAD-FOREIGN in the wrong package, so it was unFBOUNDP even on
 860 ;;; architectures where it was supposed to be supported, and the
 861 ;;; regression tests cheerfully passed because they assumed that
 862 ;;; unFBOUNDPness meant they were running on an system which didn't
 863 ;;; support the extension.)
 864 (define-condition unsupported-operator (simple-error) ())
 865 \f
 866 ;;; (:ansi-cl :function remove)
 867 ;;; (:ansi-cl :section (a b c))
 868 ;;; (:ansi-cl :glossary "similar")
 869 ;;;
 870 ;;; (:sbcl :node "...")
 871 ;;; (:sbcl :variable *ed-functions*)
 872 ;;;
 873 ;;; FIXME: this is not the right place for this.
 874 (defun print-reference (reference stream)
 875   (ecase (car reference)
 876     (:amop
 877      (format stream "AMOP")
 878      (format stream ", ")
 879      (destructuring-bind (type data) (cdr reference)
 880        (ecase type
 881          (:readers "Readers for ~:(~A~) Metaobjects"
 882                    (substitute #\  #\- (symbol-name data)))
 883          (:initialization
 884           (format stream "Initialization of ~:(~A~) Metaobjects"
 885                   (substitute #\  #\- (symbol-name data))))
 886          (:generic-function (format stream "Generic Function ~S" data))
 887          (:function (format stream "Function ~S" data))
 888          (:section (format stream "Section ~{~D~^.~}" data)))))
 889     (:ansi-cl
 890      (format stream "The ANSI Standard")
 891      (format stream ", ")
 892      (destructuring-bind (type data) (cdr reference)
 893        (ecase type
 894          (:function (format stream "Function ~S" data))
 895          (:special-operator (format stream "Special Operator ~S" data))
 896          (:macro (format stream "Macro ~S" data))
 897          (:section (format stream "Section ~{~D~^.~}" data))
 898          (:glossary (format stream "Glossary entry for ~S" data))
 899          (:issue (format stream "writeup for Issue ~A" data)))))
 900     (:sbcl
 901      (format stream "The SBCL Manual")
 902      (format stream ", ")
 903      (destructuring-bind (type data) (cdr reference)
 904        (ecase type
 905          (:node (format stream "Node ~S" data))
 906          (:variable (format stream "Variable ~S" data))
 907          (:function (format stream "Function ~S" data)))))
 908     ;; FIXME: other documents (e.g. CLIM, Franz documentation :-)
 909     ))
 910 (define-condition reference-condition ()
 911   ((references :initarg :references :reader reference-condition-references)))
 912 (defvar *print-condition-references* t)
 913 (def!method print-object :around ((o reference-condition) s)
 914   (call-next-method)
 915   (unless (or *print-escape* *print-readably*)
 916     (when (and *print-condition-references*
 917                (reference-condition-references o))
 918       (format s "~&See also:~%")
 919       (pprint-logical-block (s nil :per-line-prefix "  ")
 920         (do* ((rs (reference-condition-references o) (cdr rs))
 921               (r (car rs) (car rs)))
 922              ((null rs))
 923           (print-reference r s)
 924           (unless (null (cdr rs))
 925             (terpri s)))))))
 926
 927 (define-condition simple-reference-error (reference-condition simple-error)
 928   ())
 929
 930 (define-condition simple-reference-warning (reference-condition simple-warning)
 931   ())
 932
 933 (define-condition arguments-out-of-domain-error
 934     (arithmetic-error reference-condition)
 935   ())
 936
 937 (define-condition duplicate-definition (reference-condition warning)
 938   ((name :initarg :name :reader duplicate-definition-name))
 939   (:report (lambda (c s)
 940              (format s "~@<Duplicate definition for ~S found in ~
 941                         one file.~@:>"
 942                      (duplicate-definition-name c))))
 943   (:default-initargs :references (list '(:ansi-cl :section (3 2 2 3)))))
 944
 945 (define-condition constant-modified (reference-condition warning)
 946   ((fun-name :initarg :fun-name :reader constant-modified-fun-name))
 947   (:report (lambda (c s)
 948              (format s "~@<Destructive function ~S called on ~
 949                         constant data.~@:>"
 950                      (constant-modified-fun-name c))))
 951   (:default-initargs :references (list '(:ansi-cl :special-operator quote)
 952                                        '(:ansi-cl :section (3 2 2 3)))))
 953
 954 (define-condition package-at-variance (reference-condition simple-warning)
 955   ()
 956   (:default-initargs :references (list '(:ansi-cl :macro defpackage))))
 957
 958 (define-condition defconstant-uneql (reference-condition error)
 959   ((name :initarg :name :reader defconstant-uneql-name)
 960    (old-value :initarg :old-value :reader defconstant-uneql-old-value)
 961    (new-value :initarg :new-value :reader defconstant-uneql-new-value))
 962   (:report
 963    (lambda (condition stream)
 964      (format stream
 965              "~@<The constant ~S is being redefined (from ~S to ~S)~@:>"
 966              (defconstant-uneql-name condition)
 967              (defconstant-uneql-old-value condition)
 968              (defconstant-uneql-new-value condition))))
 969   (:default-initargs :references (list '(:ansi-cl :macro defconstant)
 970                                        '(:sbcl :node "Idiosyncrasies"))))
 971
 972 (define-condition array-initial-element-mismatch
 973     (reference-condition simple-warning)
 974   ()
 975   (:default-initargs
 976       :references (list
 977                    '(:ansi-cl :function make-array)
 978                    '(:ansi-cl :function sb!xc:upgraded-array-element-type))))
 979
 980 (define-condition type-warning (reference-condition simple-warning)
 981   ()
 982   (:default-initargs :references (list '(:sbcl :node "Handling of Types"))))
 983 (define-condition type-style-warning (reference-condition simple-style-warning)
 984   ()
 985   (:default-initargs :references (list '(:sbcl :node "Handling of Types"))))
 986
 987 (define-condition local-argument-mismatch (reference-condition simple-warning)
 988   ()
 989   (:default-initargs :references (list '(:ansi-cl :section (3 2 2 3)))))
 990
 991 (define-condition format-args-mismatch (reference-condition)
 992   ()
 993   (:default-initargs :references (list '(:ansi-cl :section (22 3 10 2)))))
 994
 995 (define-condition format-too-few-args-warning
 996     (format-args-mismatch simple-warning)
 997   ())
 998 (define-condition format-too-many-args-warning
 999     (format-args-mismatch simple-style-warning)
1000   ())
1001
1002 (define-condition implicit-generic-function-warning (style-warning)
1003   ((name :initarg :name :reader implicit-generic-function-name))
1004   (:report
1005    (lambda (condition stream)
1006      (format stream "~@<Implicitly creating new generic function ~S.~:@>"
1007              (implicit-generic-function-name condition)))))
1008
1009 (define-condition extension-failure (reference-condition simple-error)
1010   ())
1011
1012 (define-condition structure-initarg-not-keyword
1013     (reference-condition simple-style-warning)
1014   ()
1015   (:default-initargs :references (list '(:ansi-cl :section (2 4 8 13)))))
1016
1017 #!+sb-package-locks
1018 (progn
1019
1020 (define-condition package-lock-violation (package-error
1021                                           reference-condition
1022                                           simple-condition)
1023   ((current-package :initform *package*
1024                     :reader package-lock-violation-in-package))
1025   (:report
1026    (lambda (condition stream)
1027      (let ((control (simple-condition-format-control condition))
1028            (error-package (package-name (package-error-package condition)))
1029            (current-package (package-name (package-lock-violation-in-package condition))))
1030        (if control
1031            (apply #'format stream
1032                   (format nil "~~@<Lock on package ~A violated when ~A while in package ~A.~~:@>"
1033                           error-package
1034                           control
1035                           current-package)
1036                   (simple-condition-format-arguments condition))
1037            (format stream "~@<Lock on package ~A violated while in package ~A.~:@>"
1038                    error-package
1039                    current-package)))))
1040   ;; no :default-initargs -- reference-stuff provided by the
1041   ;; signalling form in target-package.lisp
1042   #!+sb-doc
1043   (:documentation
1044    "Subtype of CL:PACKAGE-ERROR. A subtype of this error is signalled
1045 when a package-lock is violated."))
1046
1047 (define-condition package-locked-error (package-lock-violation) ()
1048   #!+sb-doc
1049   (:documentation
1050    "Subtype of SB-EXT:PACKAGE-LOCK-VIOLATION. An error of this type is
1051 signalled when an operation on a package violates a package lock."))
1052
1053 (define-condition symbol-package-locked-error (package-lock-violation)
1054   ((symbol :initarg :symbol :reader package-locked-error-symbol))
1055   #!+sb-doc
1056   (:documentation
1057    "Subtype of SB-EXT:PACKAGE-LOCK-VIOLATION. An error of this type is
1058 signalled when an operation on a symbol violates a package lock. The
1059 symbol that caused the violation is accessed by the function
1060 SB-EXT:PACKAGE-LOCKED-ERROR-SYMBOL."))
1061
1062 ) ; progn
1063
1064 (define-condition undefined-alien-error (cell-error) ()
1065   (:report
1066    (lambda (condition stream)
1067      (if (slot-boundp condition 'name)
1068          (format stream "Undefined alien: ~S" (cell-error-name condition))
1069          (format stream "Undefined alien symbol.")))))
1070
1071 (define-condition undefined-alien-variable-error (undefined-alien-error) ()
1072   (:report
1073    (lambda (condition stream)
1074      (declare (ignore condition))
1075      (format stream "Attempt to access an undefined alien variable."))))
1076
1077 (define-condition undefined-alien-function-error (undefined-alien-error) ()
1078   (:report
1079    (lambda (condition stream)
1080      (declare (ignore condition))
1081      (format stream "Attempt to call an undefined alien function."))))
1082
1083 \f
1084 ;;;; various other (not specified by ANSI) CONDITIONs
1085 ;;;;
1086 ;;;; These might logically belong in other files; they're here, after
1087 ;;;; setup of CONDITION machinery, only because that makes it easier to
1088 ;;;; get cold init to work.
1089
1090 ;;; OAOOM warning: see cross-condition.lisp
1091 (define-condition encapsulated-condition (condition)
1092   ((condition :initarg :condition :reader encapsulated-condition)))
1093
1094 ;;; KLUDGE: a condition for floating point errors when we can't or
1095 ;;; won't figure out what type they are. (In FreeBSD and OpenBSD we
1096 ;;; don't know how, at least as of sbcl-0.6.7; in Linux we probably
1097 ;;; know how but the old code was broken by the conversion to POSIX
1098 ;;; signal handling and hasn't been fixed as of sbcl-0.6.7.)
1099 ;;;
1100 ;;; FIXME: Perhaps this should also be a base class for all
1101 ;;; floating point exceptions?
1102 (define-condition floating-point-exception (arithmetic-error)
1103   ((flags :initarg :traps
1104           :initform nil
1105           :reader floating-point-exception-traps))
1106   (:report (lambda (condition stream)
1107              (format stream
1108                      "An arithmetic error ~S was signalled.~%"
1109                      (type-of condition))
1110              (let ((traps (floating-point-exception-traps condition)))
1111                (if traps
1112                    (format stream
1113                            "Trapping conditions are: ~%~{ ~S~^~}~%"
1114                            traps)
1115                    (write-line
1116                     "No traps are enabled? How can this be?"
1117                     stream))))))
1118
1119 (define-condition invalid-array-index-error (type-error)
1120   ((array :initarg :array :reader invalid-array-index-error-array)
1121    (axis :initarg :axis :reader invalid-array-index-error-axis))
1122   (:report
1123    (lambda (condition stream)
1124      (let ((array (invalid-array-index-error-array condition)))
1125        (format stream "Index ~W out of bounds for ~@[axis ~W of ~]~S, ~
1126                        should be nonnegative and <~W."
1127                (type-error-datum condition)
1128                (when (> (array-rank array) 1)
1129                  (invalid-array-index-error-axis condition))
1130                (type-of array)
1131                ;; Extract the bound from (INTEGER 0 (BOUND))
1132                (caaddr (type-error-expected-type condition)))))))
1133
1134 (define-condition invalid-array-error (reference-condition type-error) ()
1135   (:report
1136    (lambda (condition stream)
1137      (let ((*print-array* nil))
1138        (format stream
1139                "~@<Displaced array originally of type ~S has been invalidated ~
1140                 due its displaced-to array ~S having become too small to hold ~
1141                 it: the displaced array's dimensions have all been set to zero ~
1142                 to trap accesses to it.~:@>"
1143                (type-error-expected-type condition)
1144                (array-displacement (type-error-datum condition))))))
1145   (:default-initargs
1146       :references
1147       (list '(:ansi-cl :function adjust-array))))
1148
1149 (define-condition index-too-large-error (type-error)
1150   ()
1151   (:report
1152    (lambda (condition stream)
1153      (format stream
1154              "The index ~S is too large."
1155              (type-error-datum condition)))))
1156
1157 (define-condition bounding-indices-bad-error (reference-condition type-error)
1158   ((object :reader bounding-indices-bad-object :initarg :object))
1159   (:report
1160    (lambda (condition stream)
1161      (let* ((datum (type-error-datum condition))
1162             (start (car datum))
1163             (end (cdr datum))
1164             (object (bounding-indices-bad-object condition)))
1165        (etypecase object
1166          (sequence
1167           (format stream
1168                   "The bounding indices ~S and ~S are bad ~
1169                    for a sequence of length ~S."
1170                   start end (length object)))
1171          (array
1172           ;; from WITH-ARRAY-DATA
1173           (format stream
1174                   "The START and END parameters ~S and ~S are ~
1175                    bad for an array of total size ~S."
1176                   start end (array-total-size object)))))))
1177   (:default-initargs
1178       :references
1179       (list '(:ansi-cl :glossary "bounding index designator")
1180             '(:ansi-cl :issue "SUBSEQ-OUT-OF-BOUNDS:IS-AN-ERROR"))))
1181
1182 (define-condition nil-array-accessed-error (reference-condition type-error)
1183   ()
1184   (:report (lambda (condition stream)
1185              (declare (ignore condition))
1186              (format stream
1187                      "An attempt to access an array of element-type ~
1188                       NIL was made.  Congratulations!")))
1189   (:default-initargs
1190       :references (list '(:ansi-cl :function sb!xc:upgraded-array-element-type)
1191                         '(:ansi-cl :section (15 1 2 1))
1192                         '(:ansi-cl :section (15 1 2 2)))))
1193
1194 (define-condition namestring-parse-error (parse-error)
1195   ((complaint :reader namestring-parse-error-complaint :initarg :complaint)
1196    (args :reader namestring-parse-error-args :initarg :args :initform nil)
1197    (namestring :reader namestring-parse-error-namestring :initarg :namestring)
1198    (offset :reader namestring-parse-error-offset :initarg :offset))
1199   (:report
1200    (lambda (condition stream)
1201      (format stream
1202              "parse error in namestring: ~?~%  ~A~%  ~V@T^"
1203              (namestring-parse-error-complaint condition)
1204              (namestring-parse-error-args condition)
1205              (namestring-parse-error-namestring condition)
1206              (namestring-parse-error-offset condition)))))
1207
1208 (define-condition simple-package-error (simple-condition package-error) ())
1209
1210 (define-condition simple-reader-package-error (simple-reader-error) ())
1211
1212 (define-condition reader-eof-error (end-of-file)
1213   ((context :reader reader-eof-error-context :initarg :context))
1214   (:report
1215    (lambda (condition stream)
1216      (format stream
1217              "unexpected end of file on ~S ~A"
1218              (stream-error-stream condition)
1219              (reader-eof-error-context condition)))))
1220
1221 (define-condition reader-impossible-number-error (simple-reader-error)
1222   ((error :reader reader-impossible-number-error-error :initarg :error))
1223   (:report
1224    (lambda (condition stream)
1225      (let ((error-stream (stream-error-stream condition)))
1226        (format stream
1227                "READER-ERROR ~@[at ~W ~]on ~S:~%~?~%Original error: ~A"
1228                (file-position-or-nil-for-error error-stream) error-stream
1229                (simple-condition-format-control condition)
1230                (simple-condition-format-arguments condition)
1231                (reader-impossible-number-error-error condition))))))
1232
1233 (define-condition standard-readtable-modified-error (reference-condition error)
1234   ((operation :initarg :operation :reader standard-readtable-modified-operation))
1235   (:report (lambda (condition stream)
1236              (format stream "~S would modify the standard readtable."
1237                      (standard-readtable-modified-operation condition))))
1238   (:default-initargs :references `((:ansi-cl :section (2 1 1 2))
1239                                    (:ansi-cl :glossary "standard readtable"))))
1240
1241 (define-condition standard-pprint-dispatch-table-modified-error
1242     (reference-condition error)
1243   ((operation :initarg :operation
1244               :reader standard-pprint-dispatch-table-modified-operation))
1245   (:report (lambda (condition stream)
1246              (format stream "~S would modify the standard pprint dispatch table."
1247                      (standard-pprint-dispatch-table-modified-operation
1248                       condition))))
1249   (:default-initargs
1250       :references `((:ansi-cl :glossary "standard pprint dispatch table"))))
1251
1252 (define-condition timeout (serious-condition)
1253   ((seconds :initarg :seconds :initform nil :reader timeout-seconds))
1254   (:report (lambda (condition stream)
1255              (format stream "Timeout occurred~@[ after ~A seconds~]."
1256                      (timeout-seconds condition)))))
1257
1258 (define-condition io-timeout (stream-error timeout)
1259   ((direction :reader io-timeout-direction :initarg :direction))
1260   (:report
1261    (lambda (condition stream)
1262      (declare (type stream stream))
1263      (format stream
1264              "I/O timeout while doing ~(~A~) on ~S."
1265              (io-timeout-direction condition)
1266              (stream-error-stream condition)))))
1267
1268 (define-condition deadline-timeout (timeout) ()
1269   (:report (lambda (condition stream)
1270              (format stream "A deadline was reached after ~A seconds."
1271                      (timeout-seconds condition)))))
1272
1273 (define-condition declaration-type-conflict-error (reference-condition
1274                                                    simple-error)
1275   ()
1276   (:default-initargs
1277       :format-control "symbol ~S cannot be both the name of a type and the name of a declaration"
1278     :references (list '(:ansi-cl :section (3 8 21)))))
1279
1280 ;;; Single stepping conditions
1281
1282 (define-condition step-condition ()
1283   ((form :initarg :form :reader step-condition-form))
1284
1285   #!+sb-doc
1286   (:documentation "Common base class of single-stepping conditions.
1287 STEP-CONDITION-FORM holds a string representation of the form being
1288 stepped."))
1289
1290 #!+sb-doc
1291 (setf (fdocumentation 'step-condition-form 'function)
1292       "Form associated with the STEP-CONDITION.")
1293
1294 (define-condition step-form-condition (step-condition)
1295   ((args :initarg :args :reader step-condition-args))
1296   (:report
1297    (lambda (condition stream)
1298      (let ((*print-circle* t)
1299            (*print-pretty* t)
1300            (*print-readably* nil))
1301        (format stream
1302                  "Evaluating call:~%~<  ~@;~A~:>~%~
1303                   ~:[With arguments:~%~{  ~S~%~}~;With unknown arguments~]~%"
1304                (list (step-condition-form condition))
1305                (eq (step-condition-args condition) :unknown)
1306                (step-condition-args condition)))))
1307   #!+sb-doc
1308   (:documentation "Condition signalled by code compiled with
1309 single-stepping information when about to execute a form.
1310 STEP-CONDITION-FORM holds the form, STEP-CONDITION-PATHNAME holds the
1311 pathname of the original file or NIL, and STEP-CONDITION-SOURCE-PATH
1312 holds the source-path to the original form within that file or NIL.
1313 Associated with this condition are always the restarts STEP-INTO,
1314 STEP-NEXT, and STEP-CONTINUE."))
1315
1316 (define-condition step-result-condition (step-condition)
1317   ((result :initarg :result :reader step-condition-result)))
1318
1319 #!+sb-doc
1320 (setf (fdocumentation 'step-condition-result 'function)
1321       "Return values associated with STEP-VALUES-CONDITION as a list,
1322 or the variable value associated with STEP-VARIABLE-CONDITION.")
1323
1324 (define-condition step-values-condition (step-result-condition)
1325   ()
1326   #!+sb-doc
1327   (:documentation "Condition signalled by code compiled with
1328 single-stepping information after executing a form.
1329 STEP-CONDITION-FORM holds the form, and STEP-CONDITION-RESULT holds
1330 the values returned by the form as a list. No associated restarts."))
1331
1332 (define-condition step-finished-condition (step-condition)
1333   ()
1334   (:report
1335    (lambda (condition stream)
1336      (declare (ignore condition))
1337      (format stream "Returning from STEP")))
1338   #!+sb-doc
1339   (:documentation "Condition signaled when STEP returns."))
1340 \f
1341 ;;; A knob for muffling warnings, mostly for use while loading files.
1342 (defvar *muffled-warnings* 'uninteresting-redefinition
1343   "A type that ought to specify a subtype of WARNING.  Whenever a
1344 warning is signaled, if the warning if of this type and is not
1345 handled by any other handler, it will be muffled.")
1346 \f
1347 ;;; Various STYLE-WARNING signaled in the system.
1348 ;; For the moment, we're only getting into the details for function
1349 ;; redefinitions, but other redefinitions could be done later
1350 ;; (e.g. methods).
1351 (define-condition redefinition-warning (style-warning)
1352   ((name
1353     :initarg :name
1354     :reader redefinition-warning-name)
1355    (new-location
1356     :initarg :new-location
1357     :reader redefinition-warning-new-location)))
1358
1359 (define-condition function-redefinition-warning (redefinition-warning)
1360   ((new-function
1361     :initarg :new-function
1362     :reader function-redefinition-warning-new-function)))
1363
1364 (define-condition redefinition-with-defun (function-redefinition-warning)
1365   ()
1366   (:report (lambda (warning stream)
1367              (format stream "redefining ~/sb-impl::print-symbol-with-prefix/ ~
1368                              in DEFUN"
1369                      (redefinition-warning-name warning)))))
1370
1371 (define-condition redefinition-with-defmacro (function-redefinition-warning)
1372   ()
1373   (:report (lambda (warning stream)
1374              (format stream "redefining ~/sb-impl::print-symbol-with-prefix/ ~
1375                              in DEFMACRO"
1376                      (redefinition-warning-name warning)))))
1377
1378 (define-condition redefinition-with-defgeneric (redefinition-warning)
1379   ()
1380   (:report (lambda (warning stream)
1381              (format stream "redefining ~/sb-impl::print-symbol-with-prefix/ ~
1382                              in DEFGENERIC"
1383                      (redefinition-warning-name warning)))))
1384
1385 (define-condition redefinition-with-defmethod (redefinition-warning)
1386   ((qualifiers :initarg :qualifiers
1387                :reader redefinition-with-defmethod-qualifiers)
1388    (specializers :initarg :specializers
1389                  :reader redefinition-with-defmethod-specializers)
1390    (new-location :initarg :new-location
1391                  :reader redefinition-with-defmethod-new-location)
1392    (old-method :initarg :old-method
1393                :reader redefinition-with-defmethod-old-method))
1394   (:report (lambda (warning stream)
1395              (format stream "redefining ~S~{ ~S~} ~S in DEFMETHOD"
1396                      (redefinition-warning-name warning)
1397                      (redefinition-with-defmethod-qualifiers warning)
1398                      (redefinition-with-defmethod-specializers warning)))))
1399
1400 ;;;; Deciding which redefinitions are "interesting".
1401
1402 (defun function-file-namestring (function)
1403   #!+sb-eval
1404   (when (typep function 'sb!eval:interpreted-function)
1405     (return-from function-file-namestring
1406       (sb!c:definition-source-location-namestring
1407           (sb!eval:interpreted-function-source-location function))))
1408   (let* ((fun (sb!kernel:%fun-fun function))
1409          (code (sb!kernel:fun-code-header fun))
1410          (debug-info (sb!kernel:%code-debug-info code))
1411          (debug-source (when debug-info
1412                          (sb!c::debug-info-source debug-info)))
1413          (namestring (when debug-source
1414                        (sb!c::debug-source-namestring debug-source))))
1415     namestring))
1416
1417 (defun interesting-function-redefinition-warning-p (warning old)
1418   (let ((new (function-redefinition-warning-new-function warning))
1419         (source-location (redefinition-warning-new-location warning)))
1420     (or
1421      ;; Compiled->Interpreted is interesting.
1422      (and (typep old 'compiled-function)
1423           (typep new '(not compiled-function)))
1424      ;; FIN->Regular is interesting.
1425      (and (typep old 'funcallable-instance)
1426           (typep new '(not funcallable-instance)))
1427      ;; Different file or unknown location is interesting.
1428      (let* ((old-namestring (function-file-namestring old))
1429             (new-namestring
1430              (or (function-file-namestring new)
1431                  (when source-location
1432                    (sb!c::definition-source-location-namestring source-location)))))
1433        (and (or (not old-namestring)
1434                 (not new-namestring)
1435                 (not (string= old-namestring new-namestring))))))))
1436
1437 (defun uninteresting-ordinary-function-redefinition-p (warning)
1438   (and
1439    ;; There's garbage in various places when the first DEFUN runs in
1440    ;; cold-init.
1441    sb!kernel::*cold-init-complete-p*
1442    (typep warning 'redefinition-with-defun)
1443    ;; Shared logic.
1444    (let ((name (redefinition-warning-name warning)))
1445      (not (interesting-function-redefinition-warning-p
1446            warning (or (fdefinition name) (macro-function name)))))))
1447
1448 (defun uninteresting-macro-redefinition-p (warning)
1449   (and
1450    (typep warning 'redefinition-with-defmacro)
1451    ;; Shared logic.
1452    (let ((name (redefinition-warning-name warning)))
1453      (not (interesting-function-redefinition-warning-p
1454            warning (or (macro-function name) (fdefinition name)))))))
1455
1456 (defun uninteresting-generic-function-redefinition-p (warning)
1457   (and
1458    (typep warning 'redefinition-with-defgeneric)
1459    ;; Can't use the shared logic above, since GF's don't get a "new"
1460    ;; definition -- rather the FIN-FUNCTION is set.
1461    (let* ((name (redefinition-warning-name warning))
1462           (old (fdefinition name))
1463           (old-location (when (typep old 'generic-function)
1464                           (sb!pcl::definition-source old)))
1465           (old-namestring (when old-location
1466                             (sb!c:definition-source-location-namestring old-location)))
1467           (new-location (redefinition-warning-new-location warning))
1468           (new-namestring (when new-location
1469                            (sb!c:definition-source-location-namestring new-location))))
1470      (and old-namestring
1471           new-namestring
1472           (string= old-namestring new-namestring)))))
1473
1474 (defun uninteresting-method-redefinition-p (warning)
1475   (and
1476    (typep warning 'redefinition-with-defmethod)
1477    ;; Can't use the shared logic above, since GF's don't get a "new"
1478    ;; definition -- rather the FIN-FUNCTION is set.
1479    (let* ((old-method (redefinition-with-defmethod-old-method warning))
1480           (old-location (sb!pcl::definition-source old-method))
1481           (old-namestring (when old-location
1482                             (sb!c:definition-source-location-namestring old-location)))
1483           (new-location (redefinition-warning-new-location warning))
1484           (new-namestring (when new-location
1485                             (sb!c:definition-source-location-namestring new-location))))
1486          (and new-namestring
1487               old-namestring
1488               (string= new-namestring old-namestring)))))
1489
1490 (deftype uninteresting-redefinition ()
1491   '(or (satisfies uninteresting-ordinary-function-redefinition-p)
1492        (satisfies uninteresting-macro-redefinition-p)
1493        (satisfies uninteresting-generic-function-redefinition-p)
1494        (satisfies uninteresting-method-redefinition-p)))
1495
1496 (define-condition redefinition-with-deftransform (redefinition-warning)
1497   ((transform :initarg :transform
1498               :reader redefinition-with-deftransform-transform))
1499   (:report (lambda (warning stream)
1500              (format stream "Overwriting ~S"
1501                      (redefinition-with-deftransform-transform warning)))))
1502 \f
1503 ;;; Various other STYLE-WARNINGS
1504 (define-condition dubious-asterisks-around-variable-name
1505     (style-warning simple-condition)
1506   ()
1507   (:report (lambda (warning stream)
1508              (format stream "~@?, even though the name follows~@
1509 the usual naming convention (names like *FOO*) for special variables"
1510                      (simple-condition-format-control warning)
1511                      (simple-condition-format-arguments warning)))))
1512
1513 (define-condition asterisks-around-lexical-variable-name
1514     (dubious-asterisks-around-variable-name)
1515   ())
1516
1517 (define-condition asterisks-around-constant-variable-name
1518     (dubious-asterisks-around-variable-name)
1519   ())
1520
1521 ;; We call this UNDEFINED-ALIEN-STYLE-WARNING because there are some
1522 ;; subclasses of ERROR above having to do with undefined aliens.
1523 (define-condition undefined-alien-style-warning (style-warning)
1524   ((symbol :initarg :symbol :reader undefined-alien-symbol))
1525   (:report (lambda (warning stream)
1526              (format stream "Undefined alien: ~S"
1527                      (undefined-alien-symbol warning)))))
1528
1529 #!+sb-eval
1530 (define-condition lexical-environment-too-complex (style-warning)
1531   ((form :initarg :form :reader lexical-environment-too-complex-form)
1532    (lexenv :initarg :lexenv :reader lexical-environment-too-complex-lexenv))
1533   (:report (lambda (warning stream)
1534              (format stream
1535                      "~@<Native lexical environment too complex for ~
1536                          SB-EVAL to evaluate ~S, falling back to ~
1537                          SIMPLE-EVAL-IN-LEXENV.  Lexenv: ~S~:@>"
1538                      (lexical-environment-too-complex-form warning)
1539                      (lexical-environment-too-complex-lexenv warning)))))
1540
1541 ;; Although this has -ERROR- in the name, it's just a STYLE-WARNING.
1542 (define-condition character-decoding-error-in-comment (style-warning)
1543   ((stream :initarg :stream :reader decoding-error-in-comment-stream)
1544    (position :initarg :position :reader decoding-error-in-comment-position))
1545   (:report (lambda (warning stream)
1546              (format stream
1547                       "Character decoding error in a ~A-comment at ~
1548                       position ~A reading source stream ~A, ~
1549                       resyncing."
1550                       (decoding-error-in-comment-macro warning)
1551                       (decoding-error-in-comment-position warning)
1552                       (decoding-error-in-comment-stream warning)))))
1553
1554 (define-condition character-decoding-error-in-macro-char-comment
1555     (character-decoding-error-in-comment)
1556   ((char :initform #\; :initarg :char
1557          :reader character-decoding-error-in-macro-char-comment-char)))
1558
1559 (define-condition character-decoding-error-in-dispatch-macro-char-comment
1560     (character-decoding-error-in-comment)
1561   ;; ANSI doesn't give a way for a reader function invoked by a
1562   ;; dispatch macro character to determine which dispatch character
1563   ;; was used, so if a user wants to signal one of these from a custom
1564   ;; comment reader, he'll have to supply the :DISP-CHAR himself.
1565   ((disp-char :initform #\# :initarg :disp-char
1566               :reader character-decoding-error-in-macro-char-comment-disp-char)
1567    (sub-char :initarg :sub-char
1568              :reader character-decoding-error-in-macro-char-comment-sub-char)))
1569
1570 (defun decoding-error-in-comment-macro (warning)
1571   (etypecase warning
1572     (character-decoding-error-in-macro-char-comment
1573      (character-decoding-error-in-macro-char-comment-char warning))
1574     (character-decoding-error-in-dispatch-macro-char-comment
1575      (format
1576       nil "~C~C"
1577       (character-decoding-error-in-macro-char-comment-disp-char warning)
1578       (character-decoding-error-in-macro-char-comment-sub-char warning)))))
1579
1580 (define-condition deprecated-eval-when-situations (style-warning)
1581   ((situations :initarg :situations
1582                :reader deprecated-eval-when-situations-situations))
1583   (:report (lambda (warning stream)
1584              (format stream "using deprecated EVAL-WHEN situation names~{ ~S~}"
1585                      (deprecated-eval-when-situations-situations warning)))))
1586
1587 (define-condition proclamation-mismatch (style-warning)
1588   ((name :initarg :name :reader proclamation-mismatch-name)
1589    (old :initarg :old :reader proclamation-mismatch-old)
1590    (new :initarg :new :reader proclamation-mismatch-new)))
1591
1592 (define-condition type-proclamation-mismatch (proclamation-mismatch)
1593   ()
1594   (:report (lambda (warning stream)
1595              (format stream
1596                      "The new TYPE proclamation~% ~S for ~S does not ~
1597                      match the old TYPE proclamation ~S"
1598                      (proclamation-mismatch-new warning)
1599                      (proclamation-mismatch-name warning)
1600                      (proclamation-mismatch-old warning)))))
1601
1602 (define-condition ftype-proclamation-mismatch (proclamation-mismatch)
1603   ()
1604   (:report (lambda (warning stream)
1605              (format stream
1606                      "The new FTYPE proclamation~% ~S for ~S does not ~
1607                      match the old FTYPE proclamation ~S"
1608                      (proclamation-mismatch-new warning)
1609                      (proclamation-mismatch-name warning)
1610                      (proclamation-mismatch-old warning)))))
1611 \f
1612 ;;;; deprecation conditions
1613
1614 (define-condition deprecation-condition ()
1615   ((name :initarg :name :reader deprecated-name)
1616    (replacement :initarg :replacement :reader deprecated-name-replacement)
1617    (since :initarg :since :reader deprecated-since)
1618    (runtime-error :initarg :runtime-error :reader deprecated-name-runtime-error)))
1619
1620 (def!method print-object ((condition deprecation-condition) stream)
1621   (let ((*package* (find-package :keyword)))
1622     (if *print-escape*
1623         (print-unreadable-object (condition stream :type t)
1624           (format stream "~S is deprecated~@[, use ~S~]"
1625                   (deprecated-name condition)
1626                   (deprecated-name-replacement condition)))
1627         (format stream "~@<~S has been deprecated as of SBCL ~A~
1628                         ~@[, use ~S instead~].~:@>"
1629                 (deprecated-name condition)
1630                 (deprecated-since condition)
1631                 (deprecated-name-replacement condition)))))
1632
1633 (define-condition early-deprecation-warning (style-warning deprecation-condition)
1634   ())
1635
1636 (def!method print-object :after ((warning early-deprecation-warning) stream)
1637   (unless *print-escape*
1638     (let ((*package* (find-package :keyword)))
1639       (format stream "~%~@<~:@_In future SBCL versions ~S will signal a full warning ~
1640                       at compile-time.~:@>"
1641               (deprecated-name warning)))))
1642
1643 (define-condition late-deprecation-warning (warning deprecation-condition)
1644   ())
1645
1646 (def!method print-object :after ((warning late-deprecation-warning) stream)
1647   (unless *print-escape*
1648     (when (deprecated-name-runtime-error warning)
1649       (let ((*package* (find-package :keyword)))
1650         (format stream "~%~@<~:@_In future SBCL versions ~S will signal a runtime error.~:@>"
1651                 (deprecated-name warning))))))
1652
1653 (define-condition final-deprecation-warning (warning deprecation-condition)
1654   ())
1655
1656 (def!method print-object :after ((warning final-deprecation-warning) stream)
1657   (unless *print-escape*
1658     (when (deprecated-name-runtime-error warning)
1659       (let ((*package* (find-package :keyword)))
1660         (format stream "~%~@<~:@_An error will be signaled at runtime for ~S.~:@>"
1661                 (deprecated-name warning))))))
1662
1663 (define-condition deprecation-error (error deprecation-condition)
1664   ())
1665 \f
1666 ;;;; restart definitions
1667
1668 (define-condition abort-failure (control-error) ()
1669   (:report
1670    "An ABORT restart was found that failed to transfer control dynamically."))
1671
1672 (defun abort (&optional condition)
1673   #!+sb-doc
1674   "Transfer control to a restart named ABORT, signalling a CONTROL-ERROR if
1675    none exists."
1676   (invoke-restart (find-restart-or-control-error 'abort condition))
1677   ;; ABORT signals an error in case there was a restart named ABORT
1678   ;; that did not transfer control dynamically. This could happen with
1679   ;; RESTART-BIND.
1680   (error 'abort-failure))
1681
1682 (defun muffle-warning (&optional condition)
1683   #!+sb-doc
1684   "Transfer control to a restart named MUFFLE-WARNING, signalling a
1685    CONTROL-ERROR if none exists."
1686   (invoke-restart (find-restart-or-control-error 'muffle-warning condition)))
1687
1688 (defun try-restart (name condition &rest arguments)
1689   (let ((restart (find-restart name condition)))
1690     (when restart
1691       (apply #'invoke-restart restart arguments))))
1692
1693 (macrolet ((define-nil-returning-restart (name args doc)
1694              #!-sb-doc (declare (ignore doc))
1695              `(defun ,name (,@args &optional condition)
1696                 #!+sb-doc ,doc
1697                 (try-restart ',name condition ,@args))))
1698   (define-nil-returning-restart continue ()
1699     "Transfer control to a restart named CONTINUE, or return NIL if none exists.")
1700   (define-nil-returning-restart store-value (value)
1701     "Transfer control and VALUE to a restart named STORE-VALUE, or return NIL if
1702    none exists.")
1703   (define-nil-returning-restart use-value (value)
1704     "Transfer control and VALUE to a restart named USE-VALUE, or return NIL if
1705    none exists."))
1706
1707 ;;; single-stepping restarts
1708
1709 (macrolet ((def (name doc)
1710                #!-sb-doc (declare (ignore doc))
1711                `(defun ,name (condition)
1712                  #!+sb-doc ,doc
1713                  (invoke-restart (find-restart-or-control-error ',name condition)))))
1714   (def step-continue
1715       "Transfers control to the STEP-CONTINUE restart associated with
1716 the condition, continuing execution without stepping. Signals a
1717 CONTROL-ERROR if the restart does not exist.")
1718   (def step-next
1719       "Transfers control to the STEP-NEXT restart associated with the
1720 condition, executing the current form without stepping and continuing
1721 stepping with the next form. Signals CONTROL-ERROR is the restart does
1722 not exists.")
1723   (def step-into
1724       "Transfers control to the STEP-INTO restart associated with the
1725 condition, stepping into the current form. Signals a CONTROL-ERROR is
1726 the restart does not exist."))
1727
1728 (/show0 "condition.lisp end of file")
1729