src/code/condition.lisp

   1 ;;;; stuff originally from CMU CL's error.lisp which can or should
   2 ;;;; come late (mostly related to the CONDITION class itself)
   3 ;;;;
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!KERNEL")
  15 \f
  16 ;;;; miscellaneous support utilities
  17
  18 ;;; Signalling an error when trying to print an error condition is
  19 ;;; generally a PITA, so whatever the failure encountered when
  20 ;;; wondering about FILE-POSITION within a condition printer, 'tis
  21 ;;; better silently to give up than to try to complain.
  22 (defun file-position-or-nil-for-error (stream &optional (pos nil posp))
  23   ;; Arguably FILE-POSITION shouldn't be signalling errors at all; but
  24   ;; "NIL if this cannot be determined" in the ANSI spec doesn't seem
  25   ;; absolutely unambiguously to prohibit errors when, e.g., STREAM
  26   ;; has been closed so that FILE-POSITION is a nonsense question. So
  27   ;; my (WHN) impression is that the conservative approach is to
  28   ;; IGNORE-ERRORS. (I encountered this failure from within a homebrew
  29   ;; defsystemish operation where the ERROR-STREAM had been CL:CLOSEd,
  30   ;; I think by nonlocally exiting through a WITH-OPEN-FILE, by the
  31   ;; time an error was reported.)
  32   (if posp
  33       (ignore-errors (file-position stream pos))
  34       (ignore-errors (file-position stream))))
  35 \f
  36 ;;;; the CONDITION class
  37
  38 (/show0 "condition.lisp 20")
  39
  40 (eval-when (:compile-toplevel :load-toplevel :execute)
  41
  42 (/show0 "condition.lisp 24")
  43
  44 (def!struct (condition-classoid (:include classoid)
  45                                 (:constructor make-condition-classoid))
  46   ;; list of CONDITION-SLOT structures for the direct slots of this
  47   ;; class
  48   (slots nil :type list)
  49   ;; list of CONDITION-SLOT structures for all of the effective class
  50   ;; slots of this class
  51   (class-slots nil :type list)
  52   ;; report function or NIL
  53   (report nil :type (or function null))
  54   ;; list of alternating initargs and initforms
  55   (default-initargs () :type list)
  56   ;; class precedence list as a list of CLASS objects, with all
  57   ;; non-CONDITION classes removed
  58   (cpl () :type list)
  59   ;; a list of all the effective instance allocation slots of this
  60   ;; class that have a non-constant initform or default-initarg.
  61   ;; Values for these slots must be computed in the dynamic
  62   ;; environment of MAKE-CONDITION.
  63   (hairy-slots nil :type list))
  64
  65 (/show0 "condition.lisp 49")
  66
  67 ) ; EVAL-WHEN
  68
  69 (!defstruct-with-alternate-metaclass condition
  70   :slot-names (actual-initargs assigned-slots)
  71   :boa-constructor %make-condition-object
  72   :superclass-name t
  73   :metaclass-name condition-classoid
  74   :metaclass-constructor make-condition-classoid
  75   :dd-type structure)
  76
  77 (defun make-condition-object (actual-initargs)
  78   (%make-condition-object actual-initargs nil))
  79
  80 (defstruct (condition-slot (:copier nil))
  81   (name (missing-arg) :type symbol)
  82   ;; list of all applicable initargs
  83   (initargs (missing-arg) :type list)
  84   ;; names of reader and writer functions
  85   (readers (missing-arg) :type list)
  86   (writers (missing-arg) :type list)
  87   ;; true if :INITFORM was specified
  88   (initform-p (missing-arg) :type (member t nil))
  89   ;; If this is a function, call it with no args. Otherwise, it's the
  90   ;; actual value.
  91   (initform (missing-arg) :type t)
  92   ;; allocation of this slot, or NIL until defaulted
  93   (allocation nil :type (member :instance :class nil))
  94   ;; If ALLOCATION is :CLASS, this is a cons whose car holds the value.
  95   (cell nil :type (or cons null))
  96   ;; slot documentation
  97   (documentation nil :type (or string null)))
  98
  99 ;;; KLUDGE: It's not clear to me why CONDITION-CLASS has itself listed
 100 ;;; in its CPL, while other classes derived from CONDITION-CLASS don't
 101 ;;; have themselves listed in their CPLs. This behavior is inherited
 102 ;;; from CMU CL, and didn't seem to be explained there, and I haven't
 103 ;;; figured out whether it's right. -- WHN 19990612
 104 (eval-when (:compile-toplevel :load-toplevel :execute)
 105   (/show0 "condition.lisp 103")
 106   (let ((condition-class (locally
 107                            ;; KLUDGE: There's a DEFTRANSFORM
 108                            ;; FIND-CLASSOID for constant class names
 109                            ;; which creates fast but
 110                            ;; non-cold-loadable, non-compact code. In
 111                            ;; this context, we'd rather have compact,
 112                            ;; cold-loadable code. -- WHN 19990928
 113                            (declare (notinline find-classoid))
 114                            (find-classoid 'condition))))
 115     (setf (condition-classoid-cpl condition-class)
 116           (list condition-class)))
 117   (/show0 "condition.lisp 103"))
 118
 119 (setf (condition-classoid-report (locally
 120                                    ;; KLUDGE: There's a DEFTRANSFORM
 121                                    ;; FIND-CLASSOID for constant class
 122                                    ;; names which creates fast but
 123                                    ;; non-cold-loadable, non-compact
 124                                    ;; code. In this context, we'd
 125                                    ;; rather have compact,
 126                                    ;; cold-loadable code. -- WHN
 127                                    ;; 19990928
 128                                    (declare (notinline find-classoid))
 129                                    (find-classoid 'condition)))
 130       (lambda (cond stream)
 131         (format stream "Condition ~S was signalled." (type-of cond))))
 132
 133 (eval-when (:compile-toplevel :load-toplevel :execute)
 134
 135 (defun find-condition-layout (name parent-types)
 136   (let* ((cpl (remove-duplicates
 137                (reverse
 138                 (reduce #'append
 139                         (mapcar (lambda (x)
 140                                   (condition-classoid-cpl
 141                                    (find-classoid x)))
 142                                 parent-types)))))
 143          (cond-layout (info :type :compiler-layout 'condition))
 144          (olayout (info :type :compiler-layout name))
 145          ;; FIXME: Does this do the right thing in case of multiple
 146          ;; inheritance? A quick look at DEFINE-CONDITION didn't make
 147          ;; it obvious what ANSI intends to be done in the case of
 148          ;; multiple inheritance, so it's not actually clear what the
 149          ;; right thing is..
 150          (new-inherits
 151           (order-layout-inherits (concatenate 'simple-vector
 152                                               (layout-inherits cond-layout)
 153                                               (mapcar #'classoid-layout cpl)))))
 154     (if (and olayout
 155              (not (mismatch (layout-inherits olayout) new-inherits)))
 156         olayout
 157         (make-layout :classoid (make-undefined-classoid name)
 158                      :inherits new-inherits
 159                      :depthoid -1
 160                      :length (layout-length cond-layout)))))
 161
 162 ) ; EVAL-WHEN
 163
 164 ;;; FIXME: ANSI's definition of DEFINE-CONDITION says
 165 ;;;   Condition reporting is mediated through the PRINT-OBJECT method
 166 ;;;   for the condition type in question, with *PRINT-ESCAPE* always
 167 ;;;   being nil. Specifying (:REPORT REPORT-NAME) in the definition of
 168 ;;;   a condition type C is equivalent to:
 169 ;;;     (defmethod print-object ((x c) stream)
 170 ;;;       (if *print-escape* (call-next-method) (report-name x stream)))
 171 ;;; The current code doesn't seem to quite match that.
 172 (def!method print-object ((x condition) stream)
 173   (if *print-escape*
 174       (if (and (typep x 'simple-condition) (slot-boundp x 'format-control))
 175           (print-unreadable-object (x stream :type t :identity t)
 176             (format stream "~S" (simple-condition-format-control x)))
 177           (print-unreadable-object (x stream :type t :identity t)))
 178       ;; KLUDGE: A comment from CMU CL here said
 179       ;;   7/13/98 BUG? CPL is not sorted and results here depend on order of
 180       ;;   superclasses in define-condition call!
 181       (dolist (class (condition-classoid-cpl (classoid-of x))
 182                      (error "no REPORT? shouldn't happen!"))
 183         (let ((report (condition-classoid-report class)))
 184           (when report
 185             (return (funcall report x stream)))))))
 186 \f
 187 ;;;; slots of CONDITION objects
 188
 189 (defvar *empty-condition-slot* '(empty))
 190
 191 (defun find-slot-default (class slot)
 192   (let ((initargs (condition-slot-initargs slot))
 193         (cpl (condition-classoid-cpl class)))
 194     (dolist (class cpl)
 195       (let ((default-initargs (condition-classoid-default-initargs class)))
 196         (dolist (initarg initargs)
 197           (let ((val (getf default-initargs initarg *empty-condition-slot*)))
 198             (unless (eq val *empty-condition-slot*)
 199               (return-from find-slot-default
 200                            (if (functionp val)
 201                                (funcall val)
 202                                val)))))))
 203
 204     (if (condition-slot-initform-p slot)
 205         (let ((initform (condition-slot-initform slot)))
 206           (if (functionp initform)
 207               (funcall initform)
 208               initform))
 209         (error "unbound condition slot: ~S" (condition-slot-name slot)))))
 210
 211 (defun find-condition-class-slot (condition-class slot-name)
 212   (dolist (sclass
 213            (condition-classoid-cpl condition-class)
 214            (error "There is no slot named ~S in ~S."
 215                   slot-name condition-class))
 216     (dolist (slot (condition-classoid-slots sclass))
 217       (when (eq (condition-slot-name slot) slot-name)
 218         (return-from find-condition-class-slot slot)))))
 219
 220 (defun condition-writer-function (condition new-value name)
 221   (dolist (cslot (condition-classoid-class-slots
 222                   (layout-classoid (%instance-layout condition)))
 223                  (setf (getf (condition-assigned-slots condition) name)
 224                        new-value))
 225     (when (eq (condition-slot-name cslot) name)
 226       (return (setf (car (condition-slot-cell cslot)) new-value)))))
 227
 228 (defun condition-reader-function (condition name)
 229   (let ((class (layout-classoid (%instance-layout condition))))
 230     (dolist (cslot (condition-classoid-class-slots class))
 231       (when (eq (condition-slot-name cslot) name)
 232         (return-from condition-reader-function
 233                      (car (condition-slot-cell cslot)))))
 234     (let ((val (getf (condition-assigned-slots condition) name
 235                      *empty-condition-slot*)))
 236       (if (eq val *empty-condition-slot*)
 237           (let ((actual-initargs (condition-actual-initargs condition))
 238                 (slot (find-condition-class-slot class name)))
 239             (unless slot
 240               (error "missing slot ~S of ~S" name condition))
 241             (do ((initargs actual-initargs (cddr initargs)))
 242                 ((endp initargs)
 243                  (setf (getf (condition-assigned-slots condition) name)
 244                        (find-slot-default class slot)))
 245               (when (member (car initargs) (condition-slot-initargs slot))
 246                 (return-from condition-reader-function
 247                   (setf (getf (condition-assigned-slots condition)
 248                               name)
 249                         (cadr initargs))))))
 250           val))))
 251 \f
 252 ;;;; MAKE-CONDITION
 253
 254 (defun make-condition (type &rest args)
 255   #!+sb-doc
 256   "Make an instance of a condition object using the specified initargs."
 257   ;; Note: ANSI specifies no exceptional situations in this function.
 258   ;; signalling simple-type-error would not be wrong.
 259   (let* ((type (or (and (symbolp type) (find-classoid type nil))
 260                     type))
 261          (class (typecase type
 262                   (condition-classoid type)
 263                   (class
 264                    ;; Punt to CLOS.
 265                    (return-from make-condition (apply #'make-instance type args)))
 266                   (classoid
 267                    (error 'simple-type-error
 268                           :datum type
 269                           :expected-type 'condition-class
 270                           :format-control "~S is not a condition class."
 271                           :format-arguments (list type)))
 272                   (t
 273                    (error 'simple-type-error
 274                           :datum type
 275                           :expected-type 'condition-class
 276                           :format-control "Bad type argument:~%  ~S"
 277                           :format-arguments (list type)))))
 278          (res (make-condition-object args)))
 279     (setf (%instance-layout res) (classoid-layout class))
 280     ;; Set any class slots with initargs present in this call.
 281     (dolist (cslot (condition-classoid-class-slots class))
 282       (dolist (initarg (condition-slot-initargs cslot))
 283         (let ((val (getf args initarg *empty-condition-slot*)))
 284           (unless (eq val *empty-condition-slot*)
 285             (setf (car (condition-slot-cell cslot)) val)))))
 286     ;; Default any slots with non-constant defaults now.
 287     (dolist (hslot (condition-classoid-hairy-slots class))
 288       (when (dolist (initarg (condition-slot-initargs hslot) t)
 289               (unless (eq (getf args initarg *empty-condition-slot*)
 290                           *empty-condition-slot*)
 291                 (return nil)))
 292         (setf (getf (condition-assigned-slots res) (condition-slot-name hslot))
 293               (find-slot-default class hslot))))
 294     res))
 295 \f
 296 ;;;; DEFINE-CONDITION
 297
 298 (eval-when (:compile-toplevel :load-toplevel :execute)
 299 (defun %compiler-define-condition (name direct-supers layout
 300                                    all-readers all-writers)
 301   (with-single-package-locked-error
 302       (:symbol name "defining ~A as a condition")
 303     (sb!xc:proclaim `(ftype (function (t) t) ,@all-readers))
 304     (sb!xc:proclaim `(ftype (function (t t) t) ,@all-writers))
 305     (multiple-value-bind (class old-layout)
 306         (insured-find-classoid name
 307                                #'condition-classoid-p
 308                                #'make-condition-classoid)
 309       (setf (layout-classoid layout) class)
 310       (setf (classoid-direct-superclasses class)
 311             (mapcar #'find-classoid direct-supers))
 312       (cond ((not old-layout)
 313              (register-layout layout))
 314             ((not *type-system-initialized*)
 315              (setf (layout-classoid old-layout) class)
 316              (setq layout old-layout)
 317              (unless (eq (classoid-layout class) layout)
 318                (register-layout layout)))
 319             ((redefine-layout-warning "current"
 320                                       old-layout
 321                                       "new"
 322                                       (layout-length layout)
 323                                       (layout-inherits layout)
 324                                       (layout-depthoid layout)
 325                                       (layout-n-untagged-slots layout))
 326              (register-layout layout :invalidate t))
 327             ((not (classoid-layout class))
 328              (register-layout layout)))
 329
 330       (setf (layout-info layout)
 331             (locally
 332                 ;; KLUDGE: There's a FIND-CLASS DEFTRANSFORM for constant class
 333                 ;; names which creates fast but non-cold-loadable, non-compact
 334                 ;; code. In this context, we'd rather have compact, cold-loadable
 335                 ;; code. -- WHN 19990928
 336                 (declare (notinline find-classoid))
 337               (layout-info (classoid-layout (find-classoid 'condition)))))
 338
 339       (setf (find-classoid name) class)
 340
 341       ;; Initialize CPL slot.
 342       (setf (condition-classoid-cpl class)
 343             (remove-if-not #'condition-classoid-p
 344                            (std-compute-class-precedence-list class)))))
 345   (values))
 346 ) ; EVAL-WHEN
 347
 348 ;;; Compute the effective slots of CLASS, copying inherited slots and
 349 ;;; destructively modifying direct slots.
 350 ;;;
 351 ;;; FIXME: It'd be nice to explain why it's OK to destructively modify
 352 ;;; direct slots. Presumably it follows from the semantics of
 353 ;;; inheritance and redefinition of conditions, but finding the cite
 354 ;;; and documenting it here would be good. (Or, if this is not in fact
 355 ;;; ANSI-compliant, fixing it would also be good.:-)
 356 (defun compute-effective-slots (class)
 357   (collect ((res (copy-list (condition-classoid-slots class))))
 358     (dolist (sclass (cdr (condition-classoid-cpl class)))
 359       (dolist (sslot (condition-classoid-slots sclass))
 360         (let ((found (find (condition-slot-name sslot) (res)
 361                            :key #'condition-slot-name)))
 362           (cond (found
 363                  (setf (condition-slot-initargs found)
 364                        (union (condition-slot-initargs found)
 365                               (condition-slot-initargs sslot)))
 366                  (unless (condition-slot-initform-p found)
 367                    (setf (condition-slot-initform-p found)
 368                          (condition-slot-initform-p sslot))
 369                    (setf (condition-slot-initform found)
 370                          (condition-slot-initform sslot)))
 371                  (unless (condition-slot-allocation found)
 372                    (setf (condition-slot-allocation found)
 373                          (condition-slot-allocation sslot))))
 374                 (t
 375                  (res (copy-structure sslot)))))))
 376     (res)))
 377
 378 ;;; Early definitions of slot accessor creators.
 379 ;;;
 380 ;;; Slot accessors must be generic functions, but ANSI does not seem
 381 ;;; to specify any of them, and we cannot support it before end of
 382 ;;; warm init. So we use ordinary functions inside SBCL, and switch to
 383 ;;; GFs only at the end of building.
 384 (declaim (notinline install-condition-slot-reader
 385                     install-condition-slot-writer))
 386 (defun install-condition-slot-reader (name condition slot-name)
 387   (declare (ignore condition))
 388   (setf (fdefinition name)
 389         (lambda (condition)
 390           (condition-reader-function condition slot-name))))
 391 (defun install-condition-slot-writer (name condition slot-name)
 392   (declare (ignore condition))
 393   (setf (fdefinition name)
 394         (lambda (new-value condition)
 395           (condition-writer-function condition new-value slot-name))))
 396
 397 (defvar *define-condition-hooks* nil)
 398
 399 (defun %define-condition (name parent-types layout slots documentation
 400                           report default-initargs all-readers all-writers
 401                           source-location)
 402   (with-single-package-locked-error
 403       (:symbol name "defining ~A as a condition")
 404     (%compiler-define-condition name parent-types layout all-readers all-writers)
 405     (sb!c:with-source-location (source-location)
 406       (setf (layout-source-location layout)
 407             source-location))
 408     (let ((class (find-classoid name)))
 409       (setf (condition-classoid-slots class) slots)
 410       (setf (condition-classoid-report class) report)
 411       (setf (condition-classoid-default-initargs class) default-initargs)
 412       (setf (fdocumentation name 'type) documentation)
 413
 414       (dolist (slot slots)
 415
 416         ;; Set up reader and writer functions.
 417         (let ((slot-name (condition-slot-name slot)))
 418           (dolist (reader (condition-slot-readers slot))
 419             (install-condition-slot-reader reader name slot-name))
 420           (dolist (writer (condition-slot-writers slot))
 421             (install-condition-slot-writer writer name slot-name))))
 422
 423       ;; Compute effective slots and set up the class and hairy slots
 424       ;; (subsets of the effective slots.)
 425       (let ((eslots (compute-effective-slots class))
 426             (e-def-initargs
 427              (reduce #'append
 428                      (mapcar #'condition-classoid-default-initargs
 429                            (condition-classoid-cpl class)))))
 430         (dolist (slot eslots)
 431           (ecase (condition-slot-allocation slot)
 432             (:class
 433              (unless (condition-slot-cell slot)
 434                (setf (condition-slot-cell slot)
 435                      (list (if (condition-slot-initform-p slot)
 436                                (let ((initform (condition-slot-initform slot)))
 437                                  (if (functionp initform)
 438                                      (funcall initform)
 439                                      initform))
 440                                *empty-condition-slot*))))
 441              (push slot (condition-classoid-class-slots class)))
 442             ((:instance nil)
 443              (setf (condition-slot-allocation slot) :instance)
 444              (when (or (functionp (condition-slot-initform slot))
 445                        (dolist (initarg (condition-slot-initargs slot) nil)
 446                          (when (functionp (getf e-def-initargs initarg))
 447                            (return t))))
 448                (push slot (condition-classoid-hairy-slots class)))))))
 449       (when (boundp '*define-condition-hooks*)
 450         (dolist (fun *define-condition-hooks*)
 451           (funcall fun class))))
 452     name))
 453
 454 (defmacro define-condition (name (&rest parent-types) (&rest slot-specs)
 455                                  &body options)
 456   #!+sb-doc
 457   "DEFINE-CONDITION Name (Parent-Type*) (Slot-Spec*) Option*
 458    Define NAME as a condition type. This new type inherits slots and its
 459    report function from the specified PARENT-TYPEs. A slot spec is a list of:
 460      (slot-name :reader <rname> :initarg <iname> {Option Value}*
 461
 462    The DEFINE-CLASS slot options :ALLOCATION, :INITFORM, [slot] :DOCUMENTATION
 463    and :TYPE and the overall options :DEFAULT-INITARGS and
 464    [type] :DOCUMENTATION are also allowed.
 465
 466    The :REPORT option is peculiar to DEFINE-CONDITION. Its argument is either
 467    a string or a two-argument lambda or function name. If a function, the
 468    function is called with the condition and stream to report the condition.
 469    If a string, the string is printed.
 470
 471    Condition types are classes, but (as allowed by ANSI and not as described in
 472    CLtL2) are neither STANDARD-OBJECTs nor STRUCTURE-OBJECTs. WITH-SLOTS and
 473    SLOT-VALUE may not be used on condition objects."
 474   (let* ((parent-types (or parent-types '(condition)))
 475          (layout (find-condition-layout name parent-types))
 476          (documentation nil)
 477          (report nil)
 478          (default-initargs ()))
 479     (collect ((slots)
 480               (all-readers nil append)
 481               (all-writers nil append))
 482       (dolist (spec slot-specs)
 483         (when (keywordp spec)
 484           (warn "Keyword slot name indicates probable syntax error:~%  ~S"
 485                 spec))
 486         (let* ((spec (if (consp spec) spec (list spec)))
 487                (slot-name (first spec))
 488                (allocation :instance)
 489                (initform-p nil)
 490                documentation
 491                initform)
 492           (collect ((initargs)
 493                     (readers)
 494                     (writers))
 495             (do ((options (rest spec) (cddr options)))
 496                 ((null options))
 497               (unless (and (consp options) (consp (cdr options)))
 498                 (error "malformed condition slot spec:~%  ~S." spec))
 499               (let ((arg (second options)))
 500                 (case (first options)
 501                   (:reader (readers arg))
 502                   (:writer (writers arg))
 503                   (:accessor
 504                    (readers arg)
 505                    (writers `(setf ,arg)))
 506                   (:initform
 507                    (when initform-p
 508                      (error "more than one :INITFORM in ~S" spec))
 509                    (setq initform-p t)
 510                    (setq initform arg))
 511                   (:initarg (initargs arg))
 512                   (:allocation
 513                    (setq allocation arg))
 514                   (:documentation
 515                    (when documentation
 516                      (error "more than one :DOCUMENTATION in ~S" spec))
 517                    (unless (stringp arg)
 518                      (error "slot :DOCUMENTATION argument is not a string: ~S"
 519                             arg))
 520                    (setq documentation arg))
 521                   (:type)
 522                   (t
 523                    (error "unknown slot option:~%  ~S" (first options))))))
 524
 525             (all-readers (readers))
 526             (all-writers (writers))
 527             (slots `(make-condition-slot
 528                      :name ',slot-name
 529                      :initargs ',(initargs)
 530                      :readers ',(readers)
 531                      :writers ',(writers)
 532                      :initform-p ',initform-p
 533                      :documentation ',documentation
 534                      :initform
 535                      ,(if (sb!xc:constantp initform)
 536                           `',(constant-form-value initform)
 537                           `#'(lambda () ,initform)))))))
 538
 539       (dolist (option options)
 540         (unless (consp option)
 541           (error "bad option:~%  ~S" option))
 542         (case (first option)
 543           (:documentation (setq documentation (second option)))
 544           (:report
 545            (let ((arg (second option)))
 546              (setq report
 547                    (if (stringp arg)
 548                        `#'(lambda (condition stream)
 549                           (declare (ignore condition))
 550                           (write-string ,arg stream))
 551                        `#'(lambda (condition stream)
 552                           (funcall #',arg condition stream))))))
 553           (:default-initargs
 554            (do ((initargs (rest option) (cddr initargs)))
 555                ((endp initargs))
 556              (let ((val (second initargs)))
 557                (setq default-initargs
 558                      (list* `',(first initargs)
 559                             (if (sb!xc:constantp val)
 560                                 `',(constant-form-value val)
 561                                 `#'(lambda () ,val))
 562                             default-initargs)))))
 563           (t
 564            (error "unknown option: ~S" (first option)))))
 565
 566       `(progn
 567          (eval-when (:compile-toplevel)
 568            (%compiler-define-condition ',name ',parent-types ',layout
 569                                        ',(all-readers) ',(all-writers)))
 570          (eval-when (:load-toplevel :execute)
 571            (%define-condition ',name
 572                               ',parent-types
 573                               ',layout
 574                               (list ,@(slots))
 575                               ,documentation
 576                               ,report
 577                               (list ,@default-initargs)
 578                               ',(all-readers)
 579                               ',(all-writers)
 580                               (sb!c:source-location)))))))
 581 \f
 582 ;;;; various CONDITIONs specified by ANSI
 583
 584 (define-condition serious-condition (condition) ())
 585
 586 (define-condition error (serious-condition) ())
 587
 588 (define-condition warning (condition) ())
 589 (define-condition style-warning (warning) ())
 590
 591 (defun simple-condition-printer (condition stream)
 592   (apply #'format
 593          stream
 594          (simple-condition-format-control condition)
 595          (simple-condition-format-arguments condition)))
 596
 597 (define-condition simple-condition ()
 598   ((format-control :reader simple-condition-format-control
 599                    :initarg :format-control
 600                    :type format-control)
 601    (format-arguments :reader simple-condition-format-arguments
 602                      :initarg :format-arguments
 603                      :initform '()
 604                      :type list))
 605   (:report simple-condition-printer))
 606
 607 (define-condition simple-warning (simple-condition warning) ())
 608
 609 (define-condition simple-error (simple-condition error) ())
 610
 611 (define-condition storage-condition (serious-condition) ())
 612
 613 (define-condition type-error (error)
 614   ((datum :reader type-error-datum :initarg :datum)
 615    (expected-type :reader type-error-expected-type :initarg :expected-type))
 616   (:report
 617    (lambda (condition stream)
 618      (format stream
 619              "~@<The value ~2I~:_~S ~I~_is not of type ~2I~_~S.~:>"
 620              (type-error-datum condition)
 621              (type-error-expected-type condition)))))
 622
 623 ;;; not specified by ANSI, but too useful not to have around.
 624 (define-condition simple-style-warning (simple-condition style-warning) ())
 625 (define-condition simple-type-error (simple-condition type-error) ())
 626
 627 ;; Can't have a function called SIMPLE-TYPE-ERROR or TYPE-ERROR...
 628 (declaim (ftype (sfunction (t t t &rest t) nil) bad-type))
 629 (defun bad-type (datum type control &rest arguments)
 630   (error 'simple-type-error
 631          :datum datum
 632          :expected-type type
 633          :format-control control
 634          :format-arguments arguments))
 635
 636 (define-condition program-error (error) ())
 637 (define-condition parse-error   (error) ())
 638 (define-condition control-error (error) ())
 639 (define-condition stream-error  (error)
 640   ((stream :reader stream-error-stream :initarg :stream)))
 641
 642 (define-condition end-of-file (stream-error) ()
 643   (:report
 644    (lambda (condition stream)
 645      (format stream
 646              "end of file on ~S"
 647              (stream-error-stream condition)))))
 648
 649 (define-condition closed-stream-error (stream-error) ()
 650   (:report
 651    (lambda (condition stream)
 652      (format stream "~S is closed" (stream-error-stream condition)))))
 653
 654 (define-condition file-error (error)
 655   ((pathname :reader file-error-pathname :initarg :pathname))
 656   (:report
 657    (lambda (condition stream)
 658      (format stream "error on file ~S" (file-error-pathname condition)))))
 659
 660 (define-condition package-error (error)
 661   ((package :reader package-error-package :initarg :package)))
 662
 663 (define-condition cell-error (error)
 664   ((name :reader cell-error-name :initarg :name)))
 665
 666 (def!method print-object ((condition cell-error) stream)
 667   (if (and *print-escape* (slot-boundp condition 'name))
 668       (print-unreadable-object (condition stream :type t :identity t)
 669         (princ (cell-error-name condition) stream))
 670       (call-next-method)))
 671
 672 (define-condition unbound-variable (cell-error) ()
 673   (:report
 674    (lambda (condition stream)
 675      (format stream
 676              "The variable ~S is unbound."
 677              (cell-error-name condition)))))
 678
 679 (define-condition undefined-function (cell-error) ()
 680   (:report
 681    (lambda (condition stream)
 682      (format stream
 683              "The function ~/sb-impl::print-symbol-with-prefix/ is undefined."
 684              (cell-error-name condition)))))
 685
 686 (define-condition special-form-function (undefined-function) ()
 687   (:report
 688    (lambda (condition stream)
 689      (format stream
 690              "Cannot FUNCALL the SYMBOL-FUNCTION of special operator ~S."
 691              (cell-error-name condition)))))
 692
 693 (define-condition arithmetic-error (error)
 694   ((operation :reader arithmetic-error-operation
 695               :initarg :operation
 696               :initform nil)
 697    (operands :reader arithmetic-error-operands
 698              :initarg :operands))
 699   (:report (lambda (condition stream)
 700              (format stream
 701                      "arithmetic error ~S signalled"
 702                      (type-of condition))
 703              (when (arithmetic-error-operation condition)
 704                (format stream
 705                        "~%Operation was ~S, operands ~S."
 706                        (arithmetic-error-operation condition)
 707                        (arithmetic-error-operands condition))))))
 708
 709 (define-condition division-by-zero         (arithmetic-error) ())
 710 (define-condition floating-point-overflow  (arithmetic-error) ())
 711 (define-condition floating-point-underflow (arithmetic-error) ())
 712 (define-condition floating-point-inexact   (arithmetic-error) ())
 713 (define-condition floating-point-invalid-operation (arithmetic-error) ())
 714
 715 (define-condition print-not-readable (error)
 716   ((object :reader print-not-readable-object :initarg :object))
 717   (:report
 718    (lambda (condition stream)
 719      (let ((obj (print-not-readable-object condition))
 720            (*print-array* nil))
 721        (format stream "~S cannot be printed readably." obj)))))
 722
 723 (define-condition reader-error (parse-error stream-error) ()
 724   (:report (lambda (condition stream)
 725              (%report-reader-error condition stream))))
 726
 727 ;;; a READER-ERROR whose REPORTing is controlled by FORMAT-CONTROL and
 728 ;;; FORMAT-ARGS (the usual case for READER-ERRORs signalled from
 729 ;;; within SBCL itself)
 730 ;;;
 731 ;;; (Inheriting CL:SIMPLE-CONDITION here isn't quite consistent with
 732 ;;; the letter of the ANSI spec: this is not a condition signalled by
 733 ;;; SIGNAL when a format-control is supplied by the function's first
 734 ;;; argument. It seems to me (WHN) to be basically in the spirit of
 735 ;;; the spec, but if not, it'd be straightforward to do our own
 736 ;;; DEFINE-CONDITION SB-INT:SIMPLISTIC-CONDITION with
 737 ;;; FORMAT-CONTROL and FORMAT-ARGS slots, and use that condition in
 738 ;;; place of CL:SIMPLE-CONDITION here.)
 739 (define-condition simple-reader-error (reader-error simple-condition)
 740   ()
 741   (:report (lambda (condition stream)
 742              (%report-reader-error condition stream :simple t))))
 743
 744 ;;; base REPORTing of a READER-ERROR
 745 ;;;
 746 ;;; When SIMPLE, we expect and use SIMPLE-CONDITION-ish FORMAT-CONTROL
 747 ;;; and FORMAT-ARGS slots.
 748 (defun %report-reader-error (condition stream &key simple)
 749   (let* ((error-stream (stream-error-stream condition))
 750          (pos (file-position-or-nil-for-error error-stream)))
 751     (let (lineno colno)
 752       (when (and pos
 753                  (< pos sb!xc:array-dimension-limit)
 754                  ;; KLUDGE: lseek() (which is what FILE-POSITION
 755                  ;; reduces to on file-streams) is undefined on
 756                  ;; "some devices", which in practice means that it
 757                  ;; can claim to succeed on /dev/stdin on Darwin
 758                  ;; and Solaris.  This is obviously bad news,
 759                  ;; because the READ-SEQUENCE below will then
 760                  ;; block, not complete, and the report will never
 761                  ;; be printed.  As a workaround, we exclude
 762                  ;; interactive streams from this attempt to report
 763                  ;; positions.  -- CSR, 2003-08-21
 764                  (not (interactive-stream-p error-stream))
 765                  (file-position error-stream :start))
 766         (let ((string
 767                (make-string pos
 768                             :element-type (stream-element-type
 769                                            error-stream))))
 770           (when (= pos (read-sequence string error-stream))
 771             (setq lineno (1+ (count #\Newline string))
 772                   colno (- pos
 773                            (or (position #\Newline string :from-end t) -1)
 774                            1))))
 775         (file-position-or-nil-for-error error-stream pos))
 776       (pprint-logical-block (stream nil)
 777         (format stream
 778                 "~S ~@[at ~W ~]~
 779                     ~@[(line ~W~]~@[, column ~W) ~]~
 780                     on ~S"
 781                 (class-name (class-of condition))
 782                 pos lineno colno error-stream)
 783         (when simple
 784           (format stream ":~2I~_~?"
 785                   (simple-condition-format-control condition)
 786                   (simple-condition-format-arguments condition)))))))
 787 \f
 788 ;;;; special SBCL extension conditions
 789
 790 ;;; an error apparently caused by a bug in SBCL itself
 791 ;;;
 792 ;;; Note that we don't make any serious effort to use this condition
 793 ;;; for *all* errors in SBCL itself. E.g. type errors and array
 794 ;;; indexing errors can occur in functions called from SBCL code, and
 795 ;;; will just end up as ordinary TYPE-ERROR or invalid index error,
 796 ;;; because the signalling code has no good way to know that the
 797 ;;; underlying problem is a bug in SBCL. But in the fairly common case
 798 ;;; that the signalling code does know that it's found a bug in SBCL,
 799 ;;; this condition is appropriate, reusing boilerplate and helping
 800 ;;; users to recognize it as an SBCL bug.
 801 (define-condition bug (simple-error)
 802   ()
 803   (:report
 804    (lambda (condition stream)
 805      (format stream
 806              "~@<  ~? ~:@_~?~:>"
 807              (simple-condition-format-control condition)
 808              (simple-condition-format-arguments condition)
 809              "~@<This is probably a bug in SBCL itself. (Alternatively, ~
 810               SBCL might have been corrupted by bad user code, e.g. by an ~
 811               undefined Lisp operation like ~S, or by stray pointers from ~
 812               alien code or from unsafe Lisp code; or there might be a bug ~
 813               in the OS or hardware that SBCL is running on.) If it seems to ~
 814               be a bug in SBCL itself, the maintainers would like to know ~
 815               about it. Bug reports are welcome on the SBCL ~
 816               mailing lists, which you can find at ~
 817               <http://sbcl.sourceforge.net/>.~:@>"
 818              '((fmakunbound 'compile))))))
 819
 820 (define-condition simple-storage-condition (storage-condition simple-condition)
 821   ())
 822
 823 ;;; a condition for use in stubs for operations which aren't supported
 824 ;;; on some platforms
 825 ;;;
 826 ;;; E.g. in sbcl-0.7.0.5, it might be appropriate to do something like
 827 ;;;   #-(or freebsd linux)
 828 ;;;   (defun load-foreign (&rest rest)
 829 ;;;     (error 'unsupported-operator :name 'load-foreign))
 830 ;;;   #+(or freebsd linux)
 831 ;;;   (defun load-foreign ... actual definition ...)
 832 ;;; By signalling a standard condition in this case, we make it
 833 ;;; possible for test code to distinguish between (1) intentionally
 834 ;;; unimplemented and (2) unintentionally just screwed up somehow.
 835 ;;; (Before this condition was defined, test code tried to deal with
 836 ;;; this by checking for FBOUNDP, but that didn't work reliably. In
 837 ;;; sbcl-0.7.0, a package screwup left the definition of
 838 ;;; LOAD-FOREIGN in the wrong package, so it was unFBOUNDP even on
 839 ;;; architectures where it was supposed to be supported, and the
 840 ;;; regression tests cheerfully passed because they assumed that
 841 ;;; unFBOUNDPness meant they were running on an system which didn't
 842 ;;; support the extension.)
 843 (define-condition unsupported-operator (simple-error) ())
 844 \f
 845 ;;; (:ansi-cl :function remove)
 846 ;;; (:ansi-cl :section (a b c))
 847 ;;; (:ansi-cl :glossary "similar")
 848 ;;;
 849 ;;; (:sbcl :node "...")
 850 ;;; (:sbcl :variable *ed-functions*)
 851 ;;;
 852 ;;; FIXME: this is not the right place for this.
 853 (defun print-reference (reference stream)
 854   (ecase (car reference)
 855     (:amop
 856      (format stream "AMOP")
 857      (format stream ", ")
 858      (destructuring-bind (type data) (cdr reference)
 859        (ecase type
 860          (:readers "Readers for ~:(~A~) Metaobjects"
 861                    (substitute #\  #\- (symbol-name data)))
 862          (:initialization
 863           (format stream "Initialization of ~:(~A~) Metaobjects"
 864                   (substitute #\  #\- (symbol-name data))))
 865          (:generic-function (format stream "Generic Function ~S" data))
 866          (:function (format stream "Function ~S" data))
 867          (:section (format stream "Section ~{~D~^.~}" data)))))
 868     (:ansi-cl
 869      (format stream "The ANSI Standard")
 870      (format stream ", ")
 871      (destructuring-bind (type data) (cdr reference)
 872        (ecase type
 873          (:function (format stream "Function ~S" data))
 874          (:special-operator (format stream "Special Operator ~S" data))
 875          (:macro (format stream "Macro ~S" data))
 876          (:section (format stream "Section ~{~D~^.~}" data))
 877          (:glossary (format stream "Glossary entry for ~S" data))
 878          (:issue (format stream "writeup for Issue ~A" data)))))
 879     (:sbcl
 880      (format stream "The SBCL Manual")
 881      (format stream ", ")
 882      (destructuring-bind (type data) (cdr reference)
 883        (ecase type
 884          (:node (format stream "Node ~S" data))
 885          (:variable (format stream "Variable ~S" data))
 886          (:function (format stream "Function ~S" data)))))
 887     ;; FIXME: other documents (e.g. CLIM, Franz documentation :-)
 888     ))
 889 (define-condition reference-condition ()
 890   ((references :initarg :references :reader reference-condition-references)))
 891 (defvar *print-condition-references* t)
 892 (def!method print-object :around ((o reference-condition) s)
 893   (call-next-method)
 894   (unless (or *print-escape* *print-readably*)
 895     (when (and *print-condition-references*
 896                (reference-condition-references o))
 897       (format s "~&See also:~%")
 898       (pprint-logical-block (s nil :per-line-prefix "  ")
 899         (do* ((rs (reference-condition-references o) (cdr rs))
 900               (r (car rs) (car rs)))
 901              ((null rs))
 902           (print-reference r s)
 903           (unless (null (cdr rs))
 904             (terpri s)))))))
 905
 906 (define-condition simple-reference-error (reference-condition simple-error)
 907   ())
 908
 909 (define-condition simple-reference-warning (reference-condition simple-warning)
 910   ())
 911
 912 (define-condition arguments-out-of-domain-error
 913     (arithmetic-error reference-condition)
 914   ())
 915
 916 (define-condition duplicate-definition (reference-condition warning)
 917   ((name :initarg :name :reader duplicate-definition-name))
 918   (:report (lambda (c s)
 919              (format s "~@<Duplicate definition for ~S found in ~
 920                         one file.~@:>"
 921                      (duplicate-definition-name c))))
 922   (:default-initargs :references (list '(:ansi-cl :section (3 2 2 3)))))
 923
 924 (define-condition constant-modified (reference-condition warning)
 925   ((fun-name :initarg :fun-name :reader constant-modified-fun-name))
 926   (:report (lambda (c s)
 927              (format s "~@<Destructive function ~S called on ~
 928                         constant data.~@:>"
 929                      (constant-modified-fun-name c))))
 930   (:default-initargs :references (list '(:ansi-cl :special-operator quote)
 931                                        '(:ansi-cl :section (3 2 2 3)))))
 932
 933 (define-condition package-at-variance (reference-condition simple-warning)
 934   ()
 935   (:default-initargs :references (list '(:ansi-cl :macro defpackage))))
 936
 937 (define-condition defconstant-uneql (reference-condition error)
 938   ((name :initarg :name :reader defconstant-uneql-name)
 939    (old-value :initarg :old-value :reader defconstant-uneql-old-value)
 940    (new-value :initarg :new-value :reader defconstant-uneql-new-value))
 941   (:report
 942    (lambda (condition stream)
 943      (format stream
 944              "~@<The constant ~S is being redefined (from ~S to ~S)~@:>"
 945              (defconstant-uneql-name condition)
 946              (defconstant-uneql-old-value condition)
 947              (defconstant-uneql-new-value condition))))
 948   (:default-initargs :references (list '(:ansi-cl :macro defconstant)
 949                                        '(:sbcl :node "Idiosyncrasies"))))
 950
 951 (define-condition array-initial-element-mismatch
 952     (reference-condition simple-warning)
 953   ()
 954   (:default-initargs
 955       :references (list
 956                    '(:ansi-cl :function make-array)
 957                    '(:ansi-cl :function sb!xc:upgraded-array-element-type))))
 958
 959 (define-condition type-warning (reference-condition simple-warning)
 960   ()
 961   (:default-initargs :references (list '(:sbcl :node "Handling of Types"))))
 962 (define-condition type-style-warning (reference-condition simple-style-warning)
 963   ()
 964   (:default-initargs :references (list '(:sbcl :node "Handling of Types"))))
 965
 966 (define-condition local-argument-mismatch (reference-condition simple-warning)
 967   ()
 968   (:default-initargs :references (list '(:ansi-cl :section (3 2 2 3)))))
 969
 970 (define-condition format-args-mismatch (reference-condition)
 971   ()
 972   (:default-initargs :references (list '(:ansi-cl :section (22 3 10 2)))))
 973
 974 (define-condition format-too-few-args-warning
 975     (format-args-mismatch simple-warning)
 976   ())
 977 (define-condition format-too-many-args-warning
 978     (format-args-mismatch simple-style-warning)
 979   ())
 980
 981 (define-condition implicit-generic-function-warning (style-warning)
 982   ((name :initarg :name :reader implicit-generic-function-name))
 983   (:report
 984    (lambda (condition stream)
 985      (format stream "~@<Implicitly creating new generic function ~S.~:@>"
 986              (implicit-generic-function-name condition)))))
 987
 988 (define-condition extension-failure (reference-condition simple-error)
 989   ())
 990
 991 (define-condition structure-initarg-not-keyword
 992     (reference-condition simple-style-warning)
 993   ()
 994   (:default-initargs :references (list '(:ansi-cl :section (2 4 8 13)))))
 995
 996 #!+sb-package-locks
 997 (progn
 998
 999 (define-condition package-lock-violation (reference-condition package-error)
1000   ((format-control :initform nil :initarg :format-control
1001                    :reader package-error-format-control)
1002    (format-arguments :initform nil :initarg :format-arguments
1003                      :reader package-error-format-arguments))
1004   (:report
1005    (lambda (condition stream)
1006      (let ((control (package-error-format-control condition)))
1007        (if control
1008            (apply #'format stream
1009                   (format nil "~~@<Lock on package ~A violated when ~A.~~:@>"
1010                           (package-name (package-error-package condition))
1011                           control)
1012                   (package-error-format-arguments condition))
1013            (format stream "~@<Lock on package ~A violated.~:@>"
1014                    (package-name (package-error-package condition)))))))
1015   ;; no :default-initargs -- reference-stuff provided by the
1016   ;; signalling form in target-package.lisp
1017   #!+sb-doc
1018   (:documentation
1019    "Subtype of CL:PACKAGE-ERROR. A subtype of this error is signalled
1020 when a package-lock is violated."))
1021
1022 (define-condition package-locked-error (package-lock-violation) ()
1023   #!+sb-doc
1024   (:documentation
1025    "Subtype of SB-EXT:PACKAGE-LOCK-VIOLATION. An error of this type is
1026 signalled when an operation on a package violates a package lock."))
1027
1028 (define-condition symbol-package-locked-error (package-lock-violation)
1029   ((symbol :initarg :symbol :reader package-locked-error-symbol))
1030   #!+sb-doc
1031   (:documentation
1032    "Subtype of SB-EXT:PACKAGE-LOCK-VIOLATION. An error of this type is
1033 signalled when an operation on a symbol violates a package lock. The
1034 symbol that caused the violation is accessed by the function
1035 SB-EXT:PACKAGE-LOCKED-ERROR-SYMBOL."))
1036
1037 ) ; progn
1038
1039 (define-condition undefined-alien-error (cell-error) ()
1040   (:report
1041    (lambda (condition stream)
1042      (if (slot-boundp condition 'name)
1043          (format stream "Undefined alien: ~S" (cell-error-name condition))
1044          (format stream "Undefined alien symbol.")))))
1045
1046 (define-condition undefined-alien-variable-error (undefined-alien-error) ()
1047   (:report
1048    (lambda (condition stream)
1049      (declare (ignore condition))
1050      (format stream "Attempt to access an undefined alien variable."))))
1051
1052 (define-condition undefined-alien-function-error (undefined-alien-error) ()
1053   (:report
1054    (lambda (condition stream)
1055      (declare (ignore condition))
1056      (format stream "Attempt to call an undefined alien function."))))
1057
1058 \f
1059 ;;;; various other (not specified by ANSI) CONDITIONs
1060 ;;;;
1061 ;;;; These might logically belong in other files; they're here, after
1062 ;;;; setup of CONDITION machinery, only because that makes it easier to
1063 ;;;; get cold init to work.
1064
1065 ;;; OAOOM warning: see cross-condition.lisp
1066 (define-condition encapsulated-condition (condition)
1067   ((condition :initarg :condition :reader encapsulated-condition)))
1068
1069 (define-condition values-type-error (type-error)
1070   ()
1071   (:report
1072    (lambda (condition stream)
1073      (format stream
1074              "~@<The values set ~2I~:_[~{~S~^ ~}] ~I~_is not of type ~2I~_~S.~:>"
1075              (type-error-datum condition)
1076              (type-error-expected-type condition)))))
1077
1078 ;;; KLUDGE: a condition for floating point errors when we can't or
1079 ;;; won't figure out what type they are. (In FreeBSD and OpenBSD we
1080 ;;; don't know how, at least as of sbcl-0.6.7; in Linux we probably
1081 ;;; know how but the old code was broken by the conversion to POSIX
1082 ;;; signal handling and hasn't been fixed as of sbcl-0.6.7.)
1083 ;;;
1084 ;;; FIXME: Perhaps this should also be a base class for all
1085 ;;; floating point exceptions?
1086 (define-condition floating-point-exception (arithmetic-error)
1087   ((flags :initarg :traps
1088           :initform nil
1089           :reader floating-point-exception-traps))
1090   (:report (lambda (condition stream)
1091              (format stream
1092                      "An arithmetic error ~S was signalled.~%"
1093                      (type-of condition))
1094              (let ((traps (floating-point-exception-traps condition)))
1095                (if traps
1096                    (format stream
1097                            "Trapping conditions are: ~%~{ ~S~^~}~%"
1098                            traps)
1099                    (write-line
1100                     "No traps are enabled? How can this be?"
1101                     stream))))))
1102
1103 (define-condition invalid-array-index-error (type-error)
1104   ((array :initarg :array :reader invalid-array-index-error-array)
1105    (axis :initarg :axis :reader invalid-array-index-error-axis))
1106   (:report
1107    (lambda (condition stream)
1108      (let ((array (invalid-array-index-error-array condition)))
1109        (format stream "Index ~W out of bounds for ~@[axis ~W of ~]~S, ~
1110                        should be nonnegative and <~W."
1111                (type-error-datum condition)
1112                (when (> (array-rank array) 1)
1113                  (invalid-array-index-error-axis condition))
1114                (type-of array)
1115                ;; Extract the bound from (INTEGER 0 (BOUND))
1116                (caaddr (type-error-expected-type condition)))))))
1117
1118 (define-condition invalid-array-error (reference-condition type-error) ()
1119   (:report
1120    (lambda (condition stream)
1121      (let ((*print-array* nil))
1122        (format stream
1123                "~@<Displaced array originally of type ~S has been invalidated ~
1124                 due its displaced-to array ~S having become too small to hold ~
1125                 it: the displaced array's dimensions have all been set to zero ~
1126                 to trap accesses to it.~:@>"
1127                (type-error-expected-type condition)
1128                (array-displacement (type-error-datum condition))))))
1129   (:default-initargs
1130       :references
1131       (list '(:ansi-cl :function adjust-array))))
1132
1133 (define-condition index-too-large-error (type-error)
1134   ()
1135   (:report
1136    (lambda (condition stream)
1137      (format stream
1138              "The index ~S is too large."
1139              (type-error-datum condition)))))
1140
1141 (define-condition bounding-indices-bad-error (reference-condition type-error)
1142   ((object :reader bounding-indices-bad-object :initarg :object))
1143   (:report
1144    (lambda (condition stream)
1145      (let* ((datum (type-error-datum condition))
1146             (start (car datum))
1147             (end (cdr datum))
1148             (object (bounding-indices-bad-object condition)))
1149        (etypecase object
1150          (sequence
1151           (format stream
1152                   "The bounding indices ~S and ~S are bad ~
1153                    for a sequence of length ~S."
1154                   start end (length object)))
1155          (array
1156           ;; from WITH-ARRAY-DATA
1157           (format stream
1158                   "The START and END parameters ~S and ~S are ~
1159                    bad for an array of total size ~S."
1160                   start end (array-total-size object)))))))
1161   (:default-initargs
1162       :references
1163       (list '(:ansi-cl :glossary "bounding index designator")
1164             '(:ansi-cl :issue "SUBSEQ-OUT-OF-BOUNDS:IS-AN-ERROR"))))
1165
1166 (define-condition nil-array-accessed-error (reference-condition type-error)
1167   ()
1168   (:report (lambda (condition stream)
1169              (declare (ignore condition))
1170              (format stream
1171                      "An attempt to access an array of element-type ~
1172                       NIL was made.  Congratulations!")))
1173   (:default-initargs
1174       :references (list '(:ansi-cl :function sb!xc:upgraded-array-element-type)
1175                         '(:ansi-cl :section (15 1 2 1))
1176                         '(:ansi-cl :section (15 1 2 2)))))
1177
1178 (define-condition namestring-parse-error (parse-error)
1179   ((complaint :reader namestring-parse-error-complaint :initarg :complaint)
1180    (args :reader namestring-parse-error-args :initarg :args :initform nil)
1181    (namestring :reader namestring-parse-error-namestring :initarg :namestring)
1182    (offset :reader namestring-parse-error-offset :initarg :offset))
1183   (:report
1184    (lambda (condition stream)
1185      (format stream
1186              "parse error in namestring: ~?~%  ~A~%  ~V@T^"
1187              (namestring-parse-error-complaint condition)
1188              (namestring-parse-error-args condition)
1189              (namestring-parse-error-namestring condition)
1190              (namestring-parse-error-offset condition)))))
1191
1192 (define-condition simple-package-error (simple-condition package-error) ())
1193
1194 (define-condition simple-reader-package-error (simple-reader-error) ())
1195
1196 (define-condition reader-eof-error (end-of-file)
1197   ((context :reader reader-eof-error-context :initarg :context))
1198   (:report
1199    (lambda (condition stream)
1200      (format stream
1201              "unexpected end of file on ~S ~A"
1202              (stream-error-stream condition)
1203              (reader-eof-error-context condition)))))
1204
1205 (define-condition reader-impossible-number-error (simple-reader-error)
1206   ((error :reader reader-impossible-number-error-error :initarg :error))
1207   (:report
1208    (lambda (condition stream)
1209      (let ((error-stream (stream-error-stream condition)))
1210        (format stream
1211                "READER-ERROR ~@[at ~W ~]on ~S:~%~?~%Original error: ~A"
1212                (file-position-or-nil-for-error error-stream) error-stream
1213                (simple-condition-format-control condition)
1214                (simple-condition-format-arguments condition)
1215                (reader-impossible-number-error-error condition))))))
1216
1217 (define-condition standard-readtable-modified-error (reference-condition error)
1218   ((operation :initarg :operation :reader standard-readtable-modified-operation))
1219   (:report (lambda (condition stream)
1220              (format stream "~S would modify the standard readtable."
1221                      (standard-readtable-modified-operation condition))))
1222   (:default-initargs :references `((:ansi-cl :section (2 1 1 2))
1223                                    (:ansi-cl :glossary "standard readtable"))))
1224
1225 (define-condition standard-pprint-dispatch-table-modified-error
1226     (reference-condition error)
1227   ((operation :initarg :operation
1228               :reader standard-pprint-dispatch-table-modified-operation))
1229   (:report (lambda (condition stream)
1230              (format stream "~S would modify the standard pprint dispatch table."
1231                      (standard-pprint-dispatch-table-modified-operation
1232                       condition))))
1233   (:default-initargs
1234       :references `((:ansi-cl :glossary "standard pprint dispatch table"))))
1235
1236 (define-condition timeout (serious-condition)
1237   ((seconds :initarg :seconds :initform nil :reader timeout-seconds))
1238   (:report (lambda (condition stream)
1239              (format stream "Timeout occurred~@[ after ~A seconds~]."
1240                      (timeout-seconds condition)))))
1241
1242 (define-condition io-timeout (stream-error timeout)
1243   ((direction :reader io-timeout-direction :initarg :direction))
1244   (:report
1245    (lambda (condition stream)
1246      (declare (type stream stream))
1247      (format stream
1248              "I/O timeout ~(~A~)ing ~S."
1249              (io-timeout-direction condition)
1250              (stream-error-stream condition)))))
1251
1252 (define-condition deadline-timeout (timeout) ()
1253   (:report (lambda (condition stream)
1254              (format stream "A deadline was reached after ~A seconds."
1255                      (timeout-seconds condition)))))
1256
1257 (define-condition declaration-type-conflict-error (reference-condition
1258                                                    simple-error)
1259   ()
1260   (:default-initargs
1261       :format-control "symbol ~S cannot be both the name of a type and the name of a declaration"
1262     :references (list '(:ansi-cl :section (3 8 21)))))
1263
1264 ;;; Single stepping conditions
1265
1266 (define-condition step-condition ()
1267   ((form :initarg :form :reader step-condition-form))
1268
1269   #!+sb-doc
1270   (:documentation "Common base class of single-stepping conditions.
1271 STEP-CONDITION-FORM holds a string representation of the form being
1272 stepped."))
1273
1274 #!+sb-doc
1275 (setf (fdocumentation 'step-condition-form 'function)
1276       "Form associated with the STEP-CONDITION.")
1277
1278 (define-condition step-form-condition (step-condition)
1279   ((args :initarg :args :reader step-condition-args))
1280   (:report
1281    (lambda (condition stream)
1282      (let ((*print-circle* t)
1283            (*print-pretty* t)
1284            (*print-readably* nil))
1285        (format stream
1286                  "Evaluating call:~%~<  ~@;~A~:>~%~
1287                   ~:[With arguments:~%~{  ~S~%~}~;With unknown arguments~]~%"
1288                (list (step-condition-form condition))
1289                (eq (step-condition-args condition) :unknown)
1290                (step-condition-args condition)))))
1291   #!+sb-doc
1292   (:documentation "Condition signalled by code compiled with
1293 single-stepping information when about to execute a form.
1294 STEP-CONDITION-FORM holds the form, STEP-CONDITION-PATHNAME holds the
1295 pathname of the original file or NIL, and STEP-CONDITION-SOURCE-PATH
1296 holds the source-path to the original form within that file or NIL.
1297 Associated with this condition are always the restarts STEP-INTO,
1298 STEP-NEXT, and STEP-CONTINUE."))
1299
1300 (define-condition step-result-condition (step-condition)
1301   ((result :initarg :result :reader step-condition-result)))
1302
1303 #!+sb-doc
1304 (setf (fdocumentation 'step-condition-result 'function)
1305       "Return values associated with STEP-VALUES-CONDITION as a list,
1306 or the variable value associated with STEP-VARIABLE-CONDITION.")
1307
1308 (define-condition step-values-condition (step-result-condition)
1309   ()
1310   #!+sb-doc
1311   (:documentation "Condition signalled by code compiled with
1312 single-stepping information after executing a form.
1313 STEP-CONDITION-FORM holds the form, and STEP-CONDITION-RESULT holds
1314 the values returned by the form as a list. No associated restarts."))
1315
1316 (define-condition step-finished-condition (step-condition)
1317   ()
1318   (:report
1319    (lambda (condition stream)
1320      (declare (ignore condition))
1321      (format stream "Returning from STEP")))
1322   #!+sb-doc
1323   (:documentation "Condition signaled when STEP returns."))
1324 \f
1325 ;;; A knob for muffling warnings, mostly for use while loading files.
1326 (defvar *muffled-warnings* 'uninteresting-redefinition
1327   "A type that ought to specify a subtype of WARNING.  Whenever a
1328 warning is signaled, if the warning if of this type and is not
1329 handled by any other handler, it will be muffled.")
1330 \f
1331 ;;; Various STYLE-WARNING signaled in the system.
1332 ;; For the moment, we're only getting into the details for function
1333 ;; redefinitions, but other redefinitions could be done later
1334 ;; (e.g. methods).
1335 (define-condition redefinition-warning (style-warning)
1336   ())
1337
1338 (define-condition function-redefinition-warning (redefinition-warning)
1339   ((name :initarg :name :reader function-redefinition-warning-name)
1340    (old :initarg :old :reader function-redefinition-warning-old-fdefinition)
1341    ;; For DEFGENERIC and perhaps others, the redefinition
1342    ;; destructively modifies the original, rather than storing a new
1343    ;; object, so there's no NEW here, but only in subclasses.
1344    ))
1345
1346 (define-condition redefinition-with-defun (function-redefinition-warning)
1347   ((new :initarg :new :reader redefinition-with-defun-new-fdefinition)
1348    ;; KLUDGE: it would be nice to fix the unreasonably late
1349    ;; back-patching of DEBUG-SOURCEs in the DEBUG-INFO during
1350    ;; fasloading and just use the new fdefinition, but for the moment
1351    ;; we'll compare the SOURCE-LOCATION created during DEFUN with the
1352    ;; previous DEBUG-SOURCE.
1353    (new-location :initarg :new-location
1354               :reader redefinition-with-defun-new-location))
1355   (:report (lambda (warning stream)
1356              (format stream "redefining ~/sb-impl::print-symbol-with-prefix/ ~
1357                              in DEFUN"
1358                      (function-redefinition-warning-name warning)))))
1359
1360 (define-condition redefinition-with-defgeneric (function-redefinition-warning)
1361   ((new-location :initarg :new-location
1362                  :reader redefinition-with-defgeneric-new-location))
1363   (:report (lambda (warning stream)
1364              (format stream "redefining ~/sb-impl::print-symbol-with-prefix/ ~
1365                              in DEFGENERIC"
1366                      (function-redefinition-warning-name warning)))))
1367
1368 (define-condition redefinition-with-defmethod (redefinition-warning)
1369   ((gf :initarg :generic-function
1370        :reader redefinition-with-defmethod-generic-function)
1371    (qualifiers :initarg :qualifiers
1372                :reader redefinition-with-defmethod-qualifiers)
1373    (specializers :initarg :specializers
1374                  :reader redefinition-with-defmethod-specializers)
1375    (new-location :initarg :new-location
1376                  :reader redefinition-with-defmethod-new-location)
1377    (old-method :initarg :old-method
1378                :reader redefinition-with-defmethod-old-method))
1379   (:report (lambda (warning stream)
1380              (format stream "redefining ~S~{ ~S~} ~S in DEFMETHOD"
1381                      (redefinition-with-defmethod-generic-function warning)
1382                      (redefinition-with-defmethod-qualifiers warning)
1383                      (redefinition-with-defmethod-specializers warning)))))
1384
1385 ;; FIXME: see the FIXMEs in defmacro.lisp, then maybe instantiate this.
1386 (define-condition redefinition-with-defmacro (function-redefinition-warning)
1387   ())
1388
1389 ;; Here are a few predicates for what people might find interesting
1390 ;; about redefinitions.
1391
1392 ;; DEFUN can replace a generic function with an ordinary function.
1393 ;; (Attempting to replace an ordinary function with a generic one
1394 ;; causes an error, though.)
1395 (defun redefinition-replaces-generic-function-p (warning)
1396   (and (typep warning 'redefinition-with-defun)
1397        (typep (function-redefinition-warning-old-fdefinition warning)
1398               'generic-function)))
1399
1400 (defun redefinition-replaces-compiled-function-with-interpreted-p (warning)
1401   (and (typep warning 'redefinition-with-defun)
1402        (compiled-function-p
1403         (function-redefinition-warning-old-fdefinition warning))
1404        (not (compiled-function-p
1405              (redefinition-with-defun-new-fdefinition warning)))))
1406
1407 ;; Most people seem to agree that re-running a DEFUN in a file is
1408 ;; completely uninteresting.
1409 (defun uninteresting-ordinary-function-redefinition-p (warning)
1410   ;; OAOO violation: this duplicates code in SB-INTROSPECT.
1411   ;; Additionally, there are some functions that aren't
1412   ;; funcallable-instances for which finding the source location is
1413   ;; complicated (e.g. DEFSTRUCT-defined predicates and accessors),
1414   ;; but I don't think they're defined with %DEFUN, so the warning
1415   ;; isn't raised.
1416   (flet ((fdefinition-file-namestring (fdefn)
1417            #!+sb-eval
1418            (when (typep fdefn 'sb!eval:interpreted-function)
1419              (return-from fdefinition-file-namestring
1420                (sb!c:definition-source-location-namestring
1421                    (sb!eval:interpreted-function-source-location fdefn))))
1422            ;; All the following accesses are guarded with conditionals
1423            ;; because it's not clear whether any of the slots we're
1424            ;; chasing down are guaranteed to be filled in.
1425            (let* ((fdefn
1426                    ;; KLUDGE: although this looks like it only works
1427                    ;; for %SIMPLE-FUNs, in fact there's a pun such
1428                    ;; that %SIMPLE-FUN-SELF returns the simple-fun
1429                    ;; object for closures and
1430                    ;; funcallable-instances. -- CSR, circa 2005
1431                    (sb!kernel:%simple-fun-self fdefn))
1432                   (code (if fdefn (sb!kernel:fun-code-header fdefn)))
1433                   (debug-info (if code (sb!kernel:%code-debug-info code)))
1434                   (debug-source (if debug-info
1435                                     (sb!c::debug-info-source debug-info)))
1436                   (namestring (if debug-source
1437                                   (sb!c::debug-source-namestring debug-source))))
1438              namestring)))
1439     (and
1440      ;; There's garbage in various places when the first DEFUN runs in
1441      ;; cold-init.
1442      sb!kernel::*cold-init-complete-p*
1443      (typep warning 'redefinition-with-defun)
1444      (let ((old-fdefn
1445             (function-redefinition-warning-old-fdefinition warning))
1446            (new-fdefn
1447             (redefinition-with-defun-new-fdefinition warning)))
1448        ;; Replacing a compiled function with a compiled function is
1449        ;; clearly uninteresting, and we'll say arbitrarily that
1450        ;; replacing an interpreted function with an interpreted
1451        ;; function is uninteresting, too, but leave out the
1452        ;; compiled-to-interpreted case.
1453        (when (or (typep
1454                   old-fdefn
1455                   '(or #!+sb-eval sb!eval:interpreted-function))
1456                  (and (typep old-fdefn
1457                              '(and compiled-function
1458                                (not funcallable-instance)))
1459                       ;; Since this is a REDEFINITION-WITH-DEFUN,
1460                       ;; NEW-FDEFN can't be a FUNCALLABLE-INSTANCE.
1461                       (typep new-fdefn 'compiled-function)))
1462          (let* ((old-namestring (fdefinition-file-namestring old-fdefn))
1463                 (new-namestring
1464                  (or (fdefinition-file-namestring new-fdefn)
1465                      (let ((srcloc
1466                             (redefinition-with-defun-new-location warning)))
1467                        (if srcloc
1468                             (sb!c::definition-source-location-namestring
1469                                 srcloc))))))
1470            (and old-namestring
1471                 new-namestring
1472                 (equal old-namestring new-namestring))))))))
1473
1474 (defun uninteresting-generic-function-redefinition-p (warning)
1475   (and (typep warning 'redefinition-with-defgeneric)
1476        (let* ((old-fdefn
1477                (function-redefinition-warning-old-fdefinition warning))
1478               (old-location
1479                (if (typep old-fdefn 'generic-function)
1480                    (sb!pcl::definition-source old-fdefn)))
1481               (old-namestring
1482                (if old-location
1483                    (sb!c:definition-source-location-namestring old-location)))
1484               (new-location
1485                (redefinition-with-defgeneric-new-location warning))
1486               (new-namestring
1487                (if new-location
1488                    (sb!c:definition-source-location-namestring new-location))))
1489          (and old-namestring
1490               new-namestring
1491               (equal old-namestring new-namestring)))))
1492
1493 (defun uninteresting-method-redefinition-p (warning)
1494   (and (typep warning 'redefinition-with-defmethod)
1495        (let* ((old-method (redefinition-with-defmethod-old-method warning))
1496               (old-location (sb!pcl::definition-source old-method))
1497               (old-namestring (if old-location
1498                                   (sb!c:definition-source-location-namestring
1499                                       old-location)))
1500               (new-location (redefinition-with-defmethod-new-location warning))
1501               (new-namestring (if new-location
1502                                   (sb!c:definition-source-location-namestring
1503                                       new-location))))
1504          (and new-namestring
1505               old-namestring
1506               (equal new-namestring old-namestring)))))
1507
1508 (deftype uninteresting-redefinition ()
1509   '(or (satisfies uninteresting-ordinary-function-redefinition-p)
1510        (satisfies uninteresting-generic-function-redefinition-p)
1511        (satisfies uninteresting-method-redefinition-p)))
1512
1513 (define-condition redefinition-with-deftransform (redefinition-warning)
1514   ((transform :initarg :transform
1515               :reader redefinition-with-deftransform-transform))
1516   (:report (lambda (warning stream)
1517              (format stream "Overwriting ~S"
1518                      (redefinition-with-deftransform-transform warning)))))
1519 \f
1520 ;;; Various other STYLE-WARNINGS
1521 (define-condition dubious-asterisks-around-variable-name
1522     (style-warning simple-condition)
1523   ()
1524   (:report (lambda (warning stream)
1525              (format stream "~@?, even though the name follows~@
1526 the usual naming convention (names like *FOO*) for special variables"
1527                      (simple-condition-format-control warning)
1528                      (simple-condition-format-arguments warning)))))
1529
1530 (define-condition asterisks-around-lexical-variable-name
1531     (dubious-asterisks-around-variable-name)
1532   ())
1533
1534 (define-condition asterisks-around-constant-variable-name
1535     (dubious-asterisks-around-variable-name)
1536   ())
1537
1538 ;; We call this UNDEFINED-ALIEN-STYLE-WARNING because there are some
1539 ;; subclasses of ERROR above having to do with undefined aliens.
1540 (define-condition undefined-alien-style-warning (style-warning)
1541   ((symbol :initarg :symbol :reader undefined-alien-symbol))
1542   (:report (lambda (warning stream)
1543              (format stream "Undefined alien: ~S"
1544                      (undefined-alien-symbol warning)))))
1545
1546 #!+sb-eval
1547 (define-condition lexical-environment-too-complex (style-warning)
1548   ((form :initarg :form :reader lexical-environment-too-complex-form)
1549    (lexenv :initarg :lexenv :reader lexical-environment-too-complex-lexenv))
1550   (:report (lambda (warning stream)
1551              (format stream
1552                      "~@<Native lexical environment too complex for ~
1553                          SB-EVAL to evaluate ~S, falling back to ~
1554                          SIMPLE-EVAL-IN-LEXENV.  Lexenv: ~S~:@>"
1555                      (lexical-environment-too-complex-form warning)
1556                      (lexical-environment-too-complex-lexenv warning)))))
1557
1558 ;; Although this has -ERROR- in the name, it's just a STYLE-WARNING.
1559 (define-condition character-decoding-error-in-comment (style-warning)
1560   ((stream :initarg :stream :reader decoding-error-in-comment-stream)
1561    (position :initarg :position :reader decoding-error-in-comment-position))
1562   (:report (lambda (warning stream)
1563              (format stream
1564                       "Character decoding error in a ~A-comment at ~
1565                       position ~A reading source stream ~A, ~
1566                       resyncing."
1567                       (decoding-error-in-comment-macro warning)
1568                       (decoding-error-in-comment-position warning)
1569                       (decoding-error-in-comment-stream warning)))))
1570
1571 (define-condition character-decoding-error-in-macro-char-comment
1572     (character-decoding-error-in-comment)
1573   ((char :initform #\; :initarg :char
1574          :reader character-decoding-error-in-macro-char-comment-char)))
1575
1576 (define-condition character-decoding-error-in-dispatch-macro-char-comment
1577     (character-decoding-error-in-comment)
1578   ;; ANSI doesn't give a way for a reader function invoked by a
1579   ;; dispatch macro character to determine which dispatch character
1580   ;; was used, so if a user wants to signal one of these from a custom
1581   ;; comment reader, he'll have to supply the :DISP-CHAR himself.
1582   ((disp-char :initform #\# :initarg :disp-char
1583               :reader character-decoding-error-in-macro-char-comment-disp-char)
1584    (sub-char :initarg :sub-char
1585              :reader character-decoding-error-in-macro-char-comment-sub-char)))
1586
1587 (defun decoding-error-in-comment-macro (warning)
1588   (etypecase warning
1589     (character-decoding-error-in-macro-char-comment
1590      (character-decoding-error-in-macro-char-comment-char warning))
1591     (character-decoding-error-in-dispatch-macro-char-comment
1592      (format
1593       nil "~C~C"
1594       (character-decoding-error-in-macro-char-comment-disp-char warning)
1595       (character-decoding-error-in-macro-char-comment-sub-char warning)))))
1596
1597 (define-condition deprecated-eval-when-situations (style-warning)
1598   ((situations :initarg :situations
1599                :reader deprecated-eval-when-situations-situations))
1600   (:report (lambda (warning stream)
1601              (format stream "using deprecated EVAL-WHEN situation names~{ ~S~}"
1602                      (deprecated-eval-when-situations-situations warning)))))
1603
1604 (define-condition proclamation-mismatch (style-warning)
1605   ((name :initarg :name :reader proclamation-mismatch-name)
1606    (old :initarg :old :reader proclamation-mismatch-old)
1607    (new :initarg :new :reader proclamation-mismatch-new)))
1608
1609 (define-condition type-proclamation-mismatch (proclamation-mismatch)
1610   ()
1611   (:report (lambda (warning stream)
1612              (format stream
1613                      "The new TYPE proclamation~% ~S for ~S does not ~
1614                      match the old TYPE proclamation ~S"
1615                      (proclamation-mismatch-new warning)
1616                      (proclamation-mismatch-name warning)
1617                      (proclamation-mismatch-old warning)))))
1618
1619 (define-condition ftype-proclamation-mismatch (proclamation-mismatch)
1620   ()
1621   (:report (lambda (warning stream)
1622              (format stream
1623                      "The new FTYPE proclamation~% ~S for ~S does not ~
1624                      match the old FTYPE proclamation ~S"
1625                      (proclamation-mismatch-new warning)
1626                      (proclamation-mismatch-name warning)
1627                      (proclamation-mismatch-old warning)))))
1628 \f
1629 ;;;; restart definitions
1630
1631 (define-condition abort-failure (control-error) ()
1632   (:report
1633    "An ABORT restart was found that failed to transfer control dynamically."))
1634
1635 (defun abort (&optional condition)
1636   #!+sb-doc
1637   "Transfer control to a restart named ABORT, signalling a CONTROL-ERROR if
1638    none exists."
1639   (invoke-restart (find-restart-or-control-error 'abort condition))
1640   ;; ABORT signals an error in case there was a restart named ABORT
1641   ;; that did not transfer control dynamically. This could happen with
1642   ;; RESTART-BIND.
1643   (error 'abort-failure))
1644
1645 (defun muffle-warning (&optional condition)
1646   #!+sb-doc
1647   "Transfer control to a restart named MUFFLE-WARNING, signalling a
1648    CONTROL-ERROR if none exists."
1649   (invoke-restart (find-restart-or-control-error 'muffle-warning condition)))
1650
1651 (defun try-restart (name condition &rest arguments)
1652   (let ((restart (find-restart name condition)))
1653     (when restart
1654       (apply #'invoke-restart restart arguments))))
1655
1656 (macrolet ((define-nil-returning-restart (name args doc)
1657              #!-sb-doc (declare (ignore doc))
1658              `(defun ,name (,@args &optional condition)
1659                 #!+sb-doc ,doc
1660                 (try-restart ',name condition ,@args))))
1661   (define-nil-returning-restart continue ()
1662     "Transfer control to a restart named CONTINUE, or return NIL if none exists.")
1663   (define-nil-returning-restart store-value (value)
1664     "Transfer control and VALUE to a restart named STORE-VALUE, or return NIL if
1665    none exists.")
1666   (define-nil-returning-restart use-value (value)
1667     "Transfer control and VALUE to a restart named USE-VALUE, or return NIL if
1668    none exists."))
1669
1670 ;;; single-stepping restarts
1671
1672 (macrolet ((def (name doc)
1673                #!-sb-doc (declare (ignore doc))
1674                `(defun ,name (condition)
1675                  #!+sb-doc ,doc
1676                  (invoke-restart (find-restart-or-control-error ',name condition)))))
1677   (def step-continue
1678       "Transfers control to the STEP-CONTINUE restart associated with
1679 the condition, continuing execution without stepping. Signals a
1680 CONTROL-ERROR if the restart does not exist.")
1681   (def step-next
1682       "Transfers control to the STEP-NEXT restart associated with the
1683 condition, executing the current form without stepping and continuing
1684 stepping with the next form. Signals CONTROL-ERROR is the restart does
1685 not exists.")
1686   (def step-into
1687       "Transfers control to the STEP-INTO restart associated with the
1688 condition, stepping into the current form. Signals a CONTROL-ERROR is
1689 the restart does not exist."))
1690
1691 (/show0 "condition.lisp end of file")
1692