src/code/condition.lisp

   1 ;;;; stuff originally from CMU CL's error.lisp which can or should
   2 ;;;; come late (mostly related to the CONDITION class itself)
   3 ;;;;
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!KERNEL")
  15 \f
  16 ;;;; miscellaneous support utilities
  17
  18 ;;; Signalling an error when trying to print an error condition is
  19 ;;; generally a PITA, so whatever the failure encountered when
  20 ;;; wondering about FILE-POSITION within a condition printer, 'tis
  21 ;;; better silently to give up than to try to complain.
  22 (defun file-position-or-nil-for-error (stream &optional (pos nil posp))
  23   ;; Arguably FILE-POSITION shouldn't be signalling errors at all; but
  24   ;; "NIL if this cannot be determined" in the ANSI spec doesn't seem
  25   ;; absolutely unambiguously to prohibit errors when, e.g., STREAM
  26   ;; has been closed so that FILE-POSITION is a nonsense question. So
  27   ;; my (WHN) impression is that the conservative approach is to
  28   ;; IGNORE-ERRORS. (I encountered this failure from within a homebrew
  29   ;; defsystemish operation where the ERROR-STREAM had been CL:CLOSEd,
  30   ;; I think by nonlocally exiting through a WITH-OPEN-FILE, by the
  31   ;; time an error was reported.)
  32   (if posp
  33       (ignore-errors (file-position stream pos))
  34       (ignore-errors (file-position stream))))
  35 \f
  36 ;;;; the CONDITION class
  37
  38 (/show0 "condition.lisp 20")
  39
  40 (eval-when (:compile-toplevel :load-toplevel :execute)
  41
  42 (/show0 "condition.lisp 24")
  43
  44 (def!struct (condition-classoid (:include classoid)
  45                                 (:constructor make-condition-classoid))
  46   ;; list of CONDITION-SLOT structures for the direct slots of this
  47   ;; class
  48   (slots nil :type list)
  49   ;; list of CONDITION-SLOT structures for all of the effective class
  50   ;; slots of this class
  51   (class-slots nil :type list)
  52   ;; report function or NIL
  53   (report nil :type (or function null))
  54   ;; list of alternating initargs and initforms
  55   (default-initargs () :type list)
  56   ;; class precedence list as a list of CLASS objects, with all
  57   ;; non-CONDITION classes removed
  58   (cpl () :type list)
  59   ;; a list of all the effective instance allocation slots of this
  60   ;; class that have a non-constant initform or default-initarg.
  61   ;; Values for these slots must be computed in the dynamic
  62   ;; environment of MAKE-CONDITION.
  63   (hairy-slots nil :type list))
  64
  65 (/show0 "condition.lisp 49")
  66
  67 ) ; EVAL-WHEN
  68
  69 (!defstruct-with-alternate-metaclass condition
  70   :slot-names (actual-initargs assigned-slots)
  71   :boa-constructor %make-condition-object
  72   :superclass-name t
  73   :metaclass-name condition-classoid
  74   :metaclass-constructor make-condition-classoid
  75   :dd-type structure)
  76
  77 (defun make-condition-object (actual-initargs)
  78   (%make-condition-object actual-initargs nil))
  79
  80 (defstruct (condition-slot (:copier nil))
  81   (name (missing-arg) :type symbol)
  82   ;; list of all applicable initargs
  83   (initargs (missing-arg) :type list)
  84   ;; names of reader and writer functions
  85   (readers (missing-arg) :type list)
  86   (writers (missing-arg) :type list)
  87   ;; true if :INITFORM was specified
  88   (initform-p (missing-arg) :type (member t nil))
  89   ;; If this is a function, call it with no args. Otherwise, it's the
  90   ;; actual value.
  91   (initform (missing-arg) :type t)
  92   ;; allocation of this slot, or NIL until defaulted
  93   (allocation nil :type (member :instance :class nil))
  94   ;; If ALLOCATION is :CLASS, this is a cons whose car holds the value.
  95   (cell nil :type (or cons null))
  96   ;; slot documentation
  97   (documentation nil :type (or string null)))
  98
  99 ;;; KLUDGE: It's not clear to me why CONDITION-CLASS has itself listed
 100 ;;; in its CPL, while other classes derived from CONDITION-CLASS don't
 101 ;;; have themselves listed in their CPLs. This behavior is inherited
 102 ;;; from CMU CL, and didn't seem to be explained there, and I haven't
 103 ;;; figured out whether it's right. -- WHN 19990612
 104 (eval-when (:compile-toplevel :load-toplevel :execute)
 105   (/show0 "condition.lisp 103")
 106   (let ((condition-class (locally
 107                            ;; KLUDGE: There's a DEFTRANSFORM
 108                            ;; FIND-CLASSOID for constant class names
 109                            ;; which creates fast but
 110                            ;; non-cold-loadable, non-compact code. In
 111                            ;; this context, we'd rather have compact,
 112                            ;; cold-loadable code. -- WHN 19990928
 113                            (declare (notinline find-classoid))
 114                            (find-classoid 'condition))))
 115     (setf (condition-classoid-cpl condition-class)
 116           (list condition-class)))
 117   (/show0 "condition.lisp 103"))
 118
 119 (setf (condition-classoid-report (locally
 120                                    ;; KLUDGE: There's a DEFTRANSFORM
 121                                    ;; FIND-CLASSOID for constant class
 122                                    ;; names which creates fast but
 123                                    ;; non-cold-loadable, non-compact
 124                                    ;; code. In this context, we'd
 125                                    ;; rather have compact,
 126                                    ;; cold-loadable code. -- WHN
 127                                    ;; 19990928
 128                                    (declare (notinline find-classoid))
 129                                    (find-classoid 'condition)))
 130       (lambda (cond stream)
 131         (format stream "Condition ~S was signalled." (type-of cond))))
 132
 133 (eval-when (:compile-toplevel :load-toplevel :execute)
 134
 135 (defun find-condition-layout (name parent-types)
 136   (let* ((cpl (remove-duplicates
 137                (reverse
 138                 (reduce #'append
 139                         (mapcar (lambda (x)
 140                                   (condition-classoid-cpl
 141                                    (find-classoid x)))
 142                                 parent-types)))))
 143          (cond-layout (info :type :compiler-layout 'condition))
 144          (olayout (info :type :compiler-layout name))
 145          ;; FIXME: Does this do the right thing in case of multiple
 146          ;; inheritance? A quick look at DEFINE-CONDITION didn't make
 147          ;; it obvious what ANSI intends to be done in the case of
 148          ;; multiple inheritance, so it's not actually clear what the
 149          ;; right thing is..
 150          (new-inherits
 151           (order-layout-inherits (concatenate 'simple-vector
 152                                               (layout-inherits cond-layout)
 153                                               (mapcar #'classoid-layout cpl)))))
 154     (if (and olayout
 155              (not (mismatch (layout-inherits olayout) new-inherits)))
 156         olayout
 157         (make-layout :classoid (make-undefined-classoid name)
 158                      :inherits new-inherits
 159                      :depthoid -1
 160                      :length (layout-length cond-layout)))))
 161
 162 ) ; EVAL-WHEN
 163
 164 ;;; FIXME: ANSI's definition of DEFINE-CONDITION says
 165 ;;;   Condition reporting is mediated through the PRINT-OBJECT method
 166 ;;;   for the condition type in question, with *PRINT-ESCAPE* always
 167 ;;;   being nil. Specifying (:REPORT REPORT-NAME) in the definition of
 168 ;;;   a condition type C is equivalent to:
 169 ;;;     (defmethod print-object ((x c) stream)
 170 ;;;       (if *print-escape* (call-next-method) (report-name x stream)))
 171 ;;; The current code doesn't seem to quite match that.
 172 (def!method print-object ((x condition) stream)
 173   (if *print-escape*
 174       (if (and (typep x 'simple-condition) (slot-boundp x 'format-control))
 175           (print-unreadable-object (x stream :type t :identity t)
 176             (format stream "~S" (simple-condition-format-control x)))
 177           (print-unreadable-object (x stream :type t :identity t)))
 178       ;; KLUDGE: A comment from CMU CL here said
 179       ;;   7/13/98 BUG? CPL is not sorted and results here depend on order of
 180       ;;   superclasses in define-condition call!
 181       (dolist (class (condition-classoid-cpl (classoid-of x))
 182                      (error "no REPORT? shouldn't happen!"))
 183         (let ((report (condition-classoid-report class)))
 184           (when report
 185             (return (funcall report x stream)))))))
 186 \f
 187 ;;;; slots of CONDITION objects
 188
 189 (defvar *empty-condition-slot* '(empty))
 190
 191 (defun find-slot-default (class slot)
 192   (let ((initargs (condition-slot-initargs slot))
 193         (cpl (condition-classoid-cpl class)))
 194     (dolist (class cpl)
 195       (let ((default-initargs (condition-classoid-default-initargs class)))
 196         (dolist (initarg initargs)
 197           (let ((val (getf default-initargs initarg *empty-condition-slot*)))
 198             (unless (eq val *empty-condition-slot*)
 199               (return-from find-slot-default
 200                            (if (functionp val)
 201                                (funcall val)
 202                                val)))))))
 203
 204     (if (condition-slot-initform-p slot)
 205         (let ((initform (condition-slot-initform slot)))
 206           (if (functionp initform)
 207               (funcall initform)
 208               initform))
 209         (error "unbound condition slot: ~S" (condition-slot-name slot)))))
 210
 211 (defun find-condition-class-slot (condition-class slot-name)
 212   (dolist (sclass
 213            (condition-classoid-cpl condition-class)
 214            (error "There is no slot named ~S in ~S."
 215                   slot-name condition-class))
 216     (dolist (slot (condition-classoid-slots sclass))
 217       (when (eq (condition-slot-name slot) slot-name)
 218         (return-from find-condition-class-slot slot)))))
 219
 220 (defun condition-writer-function (condition new-value name)
 221   (dolist (cslot (condition-classoid-class-slots
 222                   (layout-classoid (%instance-layout condition)))
 223                  (setf (getf (condition-assigned-slots condition) name)
 224                        new-value))
 225     (when (eq (condition-slot-name cslot) name)
 226       (return (setf (car (condition-slot-cell cslot)) new-value)))))
 227
 228 (defun condition-reader-function (condition name)
 229   (let ((class (layout-classoid (%instance-layout condition))))
 230     (dolist (cslot (condition-classoid-class-slots class))
 231       (when (eq (condition-slot-name cslot) name)
 232         (return-from condition-reader-function
 233                      (car (condition-slot-cell cslot)))))
 234     (let ((val (getf (condition-assigned-slots condition) name
 235                      *empty-condition-slot*)))
 236       (if (eq val *empty-condition-slot*)
 237           (let ((actual-initargs (condition-actual-initargs condition))
 238                 (slot (find-condition-class-slot class name)))
 239             (unless slot
 240               (error "missing slot ~S of ~S" name condition))
 241             (do ((initargs actual-initargs (cddr initargs)))
 242                 ((endp initargs)
 243                  (setf (getf (condition-assigned-slots condition) name)
 244                        (find-slot-default class slot)))
 245               (when (member (car initargs) (condition-slot-initargs slot))
 246                 (return-from condition-reader-function
 247                   (setf (getf (condition-assigned-slots condition)
 248                               name)
 249                         (cadr initargs))))))
 250           val))))
 251 \f
 252 ;;;; MAKE-CONDITION
 253
 254 (defun make-condition (type &rest args)
 255   #!+sb-doc
 256   "Make an instance of a condition object using the specified initargs."
 257   ;; Note: ANSI specifies no exceptional situations in this function.
 258   ;; signalling simple-type-error would not be wrong.
 259   (let* ((type (or (and (symbolp type) (find-classoid type nil))
 260                     type))
 261          (class (typecase type
 262                   (condition-classoid type)
 263                   (class
 264                    ;; Punt to CLOS.
 265                    (return-from make-condition (apply #'make-instance type args)))
 266                   (classoid
 267                    (error 'simple-type-error
 268                           :datum type
 269                           :expected-type 'condition-class
 270                           :format-control "~S is not a condition class."
 271                           :format-arguments (list type)))
 272                   (t
 273                    (error 'simple-type-error
 274                           :datum type
 275                           :expected-type 'condition-class
 276                           :format-control "Bad type argument:~%  ~S"
 277                           :format-arguments (list type)))))
 278          (res (make-condition-object args)))
 279     (setf (%instance-layout res) (classoid-layout class))
 280     ;; Set any class slots with initargs present in this call.
 281     (dolist (cslot (condition-classoid-class-slots class))
 282       (dolist (initarg (condition-slot-initargs cslot))
 283         (let ((val (getf args initarg *empty-condition-slot*)))
 284           (unless (eq val *empty-condition-slot*)
 285             (setf (car (condition-slot-cell cslot)) val)))))
 286     ;; Default any slots with non-constant defaults now.
 287     (dolist (hslot (condition-classoid-hairy-slots class))
 288       (when (dolist (initarg (condition-slot-initargs hslot) t)
 289               (unless (eq (getf args initarg *empty-condition-slot*)
 290                           *empty-condition-slot*)
 291                 (return nil)))
 292         (setf (getf (condition-assigned-slots res) (condition-slot-name hslot))
 293               (find-slot-default class hslot))))
 294     res))
 295 \f
 296 ;;;; DEFINE-CONDITION
 297
 298 (eval-when (:compile-toplevel :load-toplevel :execute)
 299 (defun %compiler-define-condition (name direct-supers layout
 300                                    all-readers all-writers)
 301   (with-single-package-locked-error
 302       (:symbol name "defining ~A as a condition")
 303     (sb!xc:proclaim `(ftype (function (t) t) ,@all-readers))
 304     (sb!xc:proclaim `(ftype (function (t t) t) ,@all-writers))
 305     (multiple-value-bind (class old-layout)
 306         (insured-find-classoid name
 307                                #'condition-classoid-p
 308                                #'make-condition-classoid)
 309       (setf (layout-classoid layout) class)
 310       (setf (classoid-direct-superclasses class)
 311             (mapcar #'find-classoid direct-supers))
 312       (cond ((not old-layout)
 313              (register-layout layout))
 314             ((not *type-system-initialized*)
 315              (setf (layout-classoid old-layout) class)
 316              (setq layout old-layout)
 317              (unless (eq (classoid-layout class) layout)
 318                (register-layout layout)))
 319             ((redefine-layout-warning "current"
 320                                       old-layout
 321                                       "new"
 322                                       (layout-length layout)
 323                                       (layout-inherits layout)
 324                                       (layout-depthoid layout)
 325                                       (layout-n-untagged-slots layout))
 326              (register-layout layout :invalidate t))
 327             ((not (classoid-layout class))
 328              (register-layout layout)))
 329
 330       (setf (layout-info layout)
 331             (locally
 332                 ;; KLUDGE: There's a FIND-CLASS DEFTRANSFORM for constant class
 333                 ;; names which creates fast but non-cold-loadable, non-compact
 334                 ;; code. In this context, we'd rather have compact, cold-loadable
 335                 ;; code. -- WHN 19990928
 336                 (declare (notinline find-classoid))
 337               (layout-info (classoid-layout (find-classoid 'condition)))))
 338
 339       (setf (find-classoid name) class)
 340
 341       ;; Initialize CPL slot.
 342       (setf (condition-classoid-cpl class)
 343             (remove-if-not #'condition-classoid-p
 344                            (std-compute-class-precedence-list class)))))
 345   (values))
 346 ) ; EVAL-WHEN
 347
 348 ;;; Compute the effective slots of CLASS, copying inherited slots and
 349 ;;; destructively modifying direct slots.
 350 ;;;
 351 ;;; FIXME: It'd be nice to explain why it's OK to destructively modify
 352 ;;; direct slots. Presumably it follows from the semantics of
 353 ;;; inheritance and redefinition of conditions, but finding the cite
 354 ;;; and documenting it here would be good. (Or, if this is not in fact
 355 ;;; ANSI-compliant, fixing it would also be good.:-)
 356 (defun compute-effective-slots (class)
 357   (collect ((res (copy-list (condition-classoid-slots class))))
 358     (dolist (sclass (cdr (condition-classoid-cpl class)))
 359       (dolist (sslot (condition-classoid-slots sclass))
 360         (let ((found (find (condition-slot-name sslot) (res)
 361                            :key #'condition-slot-name)))
 362           (cond (found
 363                  (setf (condition-slot-initargs found)
 364                        (union (condition-slot-initargs found)
 365                               (condition-slot-initargs sslot)))
 366                  (unless (condition-slot-initform-p found)
 367                    (setf (condition-slot-initform-p found)
 368                          (condition-slot-initform-p sslot))
 369                    (setf (condition-slot-initform found)
 370                          (condition-slot-initform sslot)))
 371                  (unless (condition-slot-allocation found)
 372                    (setf (condition-slot-allocation found)
 373                          (condition-slot-allocation sslot))))
 374                 (t
 375                  (res (copy-structure sslot)))))))
 376     (res)))
 377
 378 ;;; Early definitions of slot accessor creators.
 379 ;;;
 380 ;;; Slot accessors must be generic functions, but ANSI does not seem
 381 ;;; to specify any of them, and we cannot support it before end of
 382 ;;; warm init. So we use ordinary functions inside SBCL, and switch to
 383 ;;; GFs only at the end of building.
 384 (declaim (notinline install-condition-slot-reader
 385                     install-condition-slot-writer))
 386 (defun install-condition-slot-reader (name condition slot-name)
 387   (declare (ignore condition))
 388   (setf (fdefinition name)
 389         (lambda (condition)
 390           (condition-reader-function condition slot-name))))
 391 (defun install-condition-slot-writer (name condition slot-name)
 392   (declare (ignore condition))
 393   (setf (fdefinition name)
 394         (lambda (new-value condition)
 395           (condition-writer-function condition new-value slot-name))))
 396
 397 (defvar *define-condition-hooks* nil)
 398
 399 (defun %define-condition (name parent-types layout slots documentation
 400                           report default-initargs all-readers all-writers
 401                           source-location)
 402   (with-single-package-locked-error
 403       (:symbol name "defining ~A as a condition")
 404     (%compiler-define-condition name parent-types layout all-readers all-writers)
 405     (sb!c:with-source-location (source-location)
 406       (setf (layout-source-location layout)
 407             source-location))
 408     (let ((class (find-classoid name)))
 409       (setf (condition-classoid-slots class) slots)
 410       (setf (condition-classoid-report class) report)
 411       (setf (condition-classoid-default-initargs class) default-initargs)
 412       (setf (fdocumentation name 'type) documentation)
 413
 414       (dolist (slot slots)
 415
 416         ;; Set up reader and writer functions.
 417         (let ((slot-name (condition-slot-name slot)))
 418           (dolist (reader (condition-slot-readers slot))
 419             (install-condition-slot-reader reader name slot-name))
 420           (dolist (writer (condition-slot-writers slot))
 421             (install-condition-slot-writer writer name slot-name))))
 422
 423       ;; Compute effective slots and set up the class and hairy slots
 424       ;; (subsets of the effective slots.)
 425       (let ((eslots (compute-effective-slots class))
 426             (e-def-initargs
 427              (reduce #'append
 428                      (mapcar #'condition-classoid-default-initargs
 429                            (condition-classoid-cpl class)))))
 430         (dolist (slot eslots)
 431           (ecase (condition-slot-allocation slot)
 432             (:class
 433              (unless (condition-slot-cell slot)
 434                (setf (condition-slot-cell slot)
 435                      (list (if (condition-slot-initform-p slot)
 436                                (let ((initform (condition-slot-initform slot)))
 437                                  (if (functionp initform)
 438                                      (funcall initform)
 439                                      initform))
 440                                *empty-condition-slot*))))
 441              (push slot (condition-classoid-class-slots class)))
 442             ((:instance nil)
 443              (setf (condition-slot-allocation slot) :instance)
 444              (when (or (functionp (condition-slot-initform slot))
 445                        (dolist (initarg (condition-slot-initargs slot) nil)
 446                          (when (functionp (getf e-def-initargs initarg))
 447                            (return t))))
 448                (push slot (condition-classoid-hairy-slots class)))))))
 449       (when (boundp '*define-condition-hooks*)
 450         (dolist (fun *define-condition-hooks*)
 451           (funcall fun class))))
 452     name))
 453
 454 (defmacro define-condition (name (&rest parent-types) (&rest slot-specs)
 455                                  &body options)
 456   #!+sb-doc
 457   "DEFINE-CONDITION Name (Parent-Type*) (Slot-Spec*) Option*
 458    Define NAME as a condition type. This new type inherits slots and its
 459    report function from the specified PARENT-TYPEs. A slot spec is a list of:
 460      (slot-name :reader <rname> :initarg <iname> {Option Value}*
 461
 462    The DEFINE-CLASS slot options :ALLOCATION, :INITFORM, [slot] :DOCUMENTATION
 463    and :TYPE and the overall options :DEFAULT-INITARGS and
 464    [type] :DOCUMENTATION are also allowed.
 465
 466    The :REPORT option is peculiar to DEFINE-CONDITION. Its argument is either
 467    a string or a two-argument lambda or function name. If a function, the
 468    function is called with the condition and stream to report the condition.
 469    If a string, the string is printed.
 470
 471    Condition types are classes, but (as allowed by ANSI and not as described in
 472    CLtL2) are neither STANDARD-OBJECTs nor STRUCTURE-OBJECTs. WITH-SLOTS and
 473    SLOT-VALUE may not be used on condition objects."
 474   (let* ((parent-types (or parent-types '(condition)))
 475          (layout (find-condition-layout name parent-types))
 476          (documentation nil)
 477          (report nil)
 478          (default-initargs ()))
 479     (collect ((slots)
 480               (all-readers nil append)
 481               (all-writers nil append))
 482       (dolist (spec slot-specs)
 483         (when (keywordp spec)
 484           (warn "Keyword slot name indicates probable syntax error:~%  ~S"
 485                 spec))
 486         (let* ((spec (if (consp spec) spec (list spec)))
 487                (slot-name (first spec))
 488                (allocation :instance)
 489                (initform-p nil)
 490                documentation
 491                initform)
 492           (collect ((initargs)
 493                     (readers)
 494                     (writers))
 495             (do ((options (rest spec) (cddr options)))
 496                 ((null options))
 497               (unless (and (consp options) (consp (cdr options)))
 498                 (error "malformed condition slot spec:~%  ~S." spec))
 499               (let ((arg (second options)))
 500                 (case (first options)
 501                   (:reader (readers arg))
 502                   (:writer (writers arg))
 503                   (:accessor
 504                    (readers arg)
 505                    (writers `(setf ,arg)))
 506                   (:initform
 507                    (when initform-p
 508                      (error "more than one :INITFORM in ~S" spec))
 509                    (setq initform-p t)
 510                    (setq initform arg))
 511                   (:initarg (initargs arg))
 512                   (:allocation
 513                    (setq allocation arg))
 514                   (:documentation
 515                    (when documentation
 516                      (error "more than one :DOCUMENTATION in ~S" spec))
 517                    (unless (stringp arg)
 518                      (error "slot :DOCUMENTATION argument is not a string: ~S"
 519                             arg))
 520                    (setq documentation arg))
 521                   (:type)
 522                   (t
 523                    (error "unknown slot option:~%  ~S" (first options))))))
 524
 525             (all-readers (readers))
 526             (all-writers (writers))
 527             (slots `(make-condition-slot
 528                      :name ',slot-name
 529                      :initargs ',(initargs)
 530                      :readers ',(readers)
 531                      :writers ',(writers)
 532                      :initform-p ',initform-p
 533                      :documentation ',documentation
 534                      :initform
 535                      ,(if (sb!xc:constantp initform)
 536                           `',(constant-form-value initform)
 537                           `#'(lambda () ,initform)))))))
 538
 539       (dolist (option options)
 540         (unless (consp option)
 541           (error "bad option:~%  ~S" option))
 542         (case (first option)
 543           (:documentation (setq documentation (second option)))
 544           (:report
 545            (let ((arg (second option)))
 546              (setq report
 547                    (if (stringp arg)
 548                        `#'(lambda (condition stream)
 549                           (declare (ignore condition))
 550                           (write-string ,arg stream))
 551                        `#'(lambda (condition stream)
 552                           (funcall #',arg condition stream))))))
 553           (:default-initargs
 554            (do ((initargs (rest option) (cddr initargs)))
 555                ((endp initargs))
 556              (let ((val (second initargs)))
 557                (setq default-initargs
 558                      (list* `',(first initargs)
 559                             (if (sb!xc:constantp val)
 560                                 `',(constant-form-value val)
 561                                 `#'(lambda () ,val))
 562                             default-initargs)))))
 563           (t
 564            (error "unknown option: ~S" (first option)))))
 565
 566       `(progn
 567          (eval-when (:compile-toplevel)
 568            (%compiler-define-condition ',name ',parent-types ',layout
 569                                        ',(all-readers) ',(all-writers)))
 570          (eval-when (:load-toplevel :execute)
 571            (%define-condition ',name
 572                               ',parent-types
 573                               ',layout
 574                               (list ,@(slots))
 575                               ,documentation
 576                               ,report
 577                               (list ,@default-initargs)
 578                               ',(all-readers)
 579                               ',(all-writers)
 580                               (sb!c:source-location)))))))
 581 \f
 582 ;;;; various CONDITIONs specified by ANSI
 583
 584 (define-condition serious-condition (condition) ())
 585
 586 (define-condition error (serious-condition) ())
 587
 588 (define-condition warning (condition) ())
 589 (define-condition style-warning (warning) ())
 590
 591 (defun simple-condition-printer (condition stream)
 592   (apply #'format
 593          stream
 594          (simple-condition-format-control condition)
 595          (simple-condition-format-arguments condition)))
 596
 597 (define-condition simple-condition ()
 598   ((format-control :reader simple-condition-format-control
 599                    :initarg :format-control
 600                    :type format-control)
 601    (format-arguments :reader simple-condition-format-arguments
 602                      :initarg :format-arguments
 603                      :initform '()
 604                      :type list))
 605   (:report simple-condition-printer))
 606
 607 (define-condition simple-warning (simple-condition warning) ())
 608
 609 (define-condition simple-error (simple-condition error) ())
 610
 611 (define-condition storage-condition (serious-condition) ())
 612
 613 (define-condition type-error (error)
 614   ((datum :reader type-error-datum :initarg :datum)
 615    (expected-type :reader type-error-expected-type :initarg :expected-type))
 616   (:report
 617    (lambda (condition stream)
 618      (format stream
 619              "~@<The value ~2I~:_~S ~I~_is not of type ~2I~_~S.~:>"
 620              (type-error-datum condition)
 621              (type-error-expected-type condition)))))
 622
 623 ;;; not specified by ANSI, but too useful not to have around.
 624 (define-condition simple-style-warning (simple-condition style-warning) ())
 625 (define-condition simple-type-error (simple-condition type-error) ())
 626
 627 (define-condition program-error (error) ())
 628 (define-condition parse-error   (error) ())
 629 (define-condition control-error (error) ())
 630 (define-condition stream-error  (error)
 631   ((stream :reader stream-error-stream :initarg :stream)))
 632
 633 (define-condition end-of-file (stream-error) ()
 634   (:report
 635    (lambda (condition stream)
 636      (format stream
 637              "end of file on ~S"
 638              (stream-error-stream condition)))))
 639
 640 (define-condition closed-stream-error (stream-error) ()
 641   (:report
 642    (lambda (condition stream)
 643      (format stream "~S is closed" (stream-error-stream condition)))))
 644
 645 (define-condition file-error (error)
 646   ((pathname :reader file-error-pathname :initarg :pathname))
 647   (:report
 648    (lambda (condition stream)
 649      (format stream "error on file ~S" (file-error-pathname condition)))))
 650
 651 (define-condition package-error (error)
 652   ((package :reader package-error-package :initarg :package)))
 653
 654 (define-condition cell-error (error)
 655   ((name :reader cell-error-name :initarg :name)))
 656
 657 (def!method print-object ((condition cell-error) stream)
 658   (if (and *print-escape* (slot-boundp condition 'name))
 659       (print-unreadable-object (condition stream :type t :identity t)
 660         (princ (cell-error-name condition) stream))
 661       (call-next-method)))
 662
 663 (define-condition unbound-variable (cell-error) ()
 664   (:report
 665    (lambda (condition stream)
 666      (format stream
 667              "The variable ~S is unbound."
 668              (cell-error-name condition)))))
 669
 670 (define-condition undefined-function (cell-error) ()
 671   (:report
 672    (lambda (condition stream)
 673      (format stream
 674              "The function ~S is undefined."
 675              (cell-error-name condition)))))
 676
 677 (define-condition special-form-function (undefined-function) ()
 678   (:report
 679    (lambda (condition stream)
 680      (format stream
 681              "Cannot FUNCALL the SYMBOL-FUNCTION of special operator ~S."
 682              (cell-error-name condition)))))
 683
 684 (define-condition arithmetic-error (error)
 685   ((operation :reader arithmetic-error-operation
 686               :initarg :operation
 687               :initform nil)
 688    (operands :reader arithmetic-error-operands
 689              :initarg :operands))
 690   (:report (lambda (condition stream)
 691              (format stream
 692                      "arithmetic error ~S signalled"
 693                      (type-of condition))
 694              (when (arithmetic-error-operation condition)
 695                (format stream
 696                        "~%Operation was ~S, operands ~S."
 697                        (arithmetic-error-operation condition)
 698                        (arithmetic-error-operands condition))))))
 699
 700 (define-condition division-by-zero         (arithmetic-error) ())
 701 (define-condition floating-point-overflow  (arithmetic-error) ())
 702 (define-condition floating-point-underflow (arithmetic-error) ())
 703 (define-condition floating-point-inexact   (arithmetic-error) ())
 704 (define-condition floating-point-invalid-operation (arithmetic-error) ())
 705
 706 (define-condition print-not-readable (error)
 707   ((object :reader print-not-readable-object :initarg :object))
 708   (:report
 709    (lambda (condition stream)
 710      (let ((obj (print-not-readable-object condition))
 711            (*print-array* nil))
 712        (format stream "~S cannot be printed readably." obj)))))
 713
 714 (define-condition reader-error (parse-error stream-error) ()
 715   (:report (lambda (condition stream)
 716              (%report-reader-error condition stream))))
 717
 718 ;;; a READER-ERROR whose REPORTing is controlled by FORMAT-CONTROL and
 719 ;;; FORMAT-ARGS (the usual case for READER-ERRORs signalled from
 720 ;;; within SBCL itself)
 721 ;;;
 722 ;;; (Inheriting CL:SIMPLE-CONDITION here isn't quite consistent with
 723 ;;; the letter of the ANSI spec: this is not a condition signalled by
 724 ;;; SIGNAL when a format-control is supplied by the function's first
 725 ;;; argument. It seems to me (WHN) to be basically in the spirit of
 726 ;;; the spec, but if not, it'd be straightforward to do our own
 727 ;;; DEFINE-CONDITION SB-INT:SIMPLISTIC-CONDITION with
 728 ;;; FORMAT-CONTROL and FORMAT-ARGS slots, and use that condition in
 729 ;;; place of CL:SIMPLE-CONDITION here.)
 730 (define-condition simple-reader-error (reader-error simple-condition)
 731   ()
 732   (:report (lambda (condition stream)
 733              (%report-reader-error condition stream :simple t))))
 734
 735 ;;; base REPORTing of a READER-ERROR
 736 ;;;
 737 ;;; When SIMPLE, we expect and use SIMPLE-CONDITION-ish FORMAT-CONTROL
 738 ;;; and FORMAT-ARGS slots.
 739 (defun %report-reader-error (condition stream &key simple)
 740   (let* ((error-stream (stream-error-stream condition))
 741          (pos (file-position-or-nil-for-error error-stream)))
 742     (let (lineno colno)
 743       (when (and pos
 744                  (< pos sb!xc:array-dimension-limit)
 745                  ;; KLUDGE: lseek() (which is what FILE-POSITION
 746                  ;; reduces to on file-streams) is undefined on
 747                  ;; "some devices", which in practice means that it
 748                  ;; can claim to succeed on /dev/stdin on Darwin
 749                  ;; and Solaris.  This is obviously bad news,
 750                  ;; because the READ-SEQUENCE below will then
 751                  ;; block, not complete, and the report will never
 752                  ;; be printed.  As a workaround, we exclude
 753                  ;; interactive streams from this attempt to report
 754                  ;; positions.  -- CSR, 2003-08-21
 755                  (not (interactive-stream-p error-stream))
 756                  (file-position error-stream :start))
 757         (let ((string
 758                (make-string pos
 759                             :element-type (stream-element-type
 760                                            error-stream))))
 761           (when (= pos (read-sequence string error-stream))
 762             (setq lineno (1+ (count #\Newline string))
 763                   colno (- pos
 764                            (or (position #\Newline string :from-end t) -1)
 765                            1))))
 766         (file-position-or-nil-for-error error-stream pos))
 767       (pprint-logical-block (stream nil)
 768         (format stream
 769                 "~S ~@[at ~W ~]~
 770                     ~@[(line ~W~]~@[, column ~W) ~]~
 771                     on ~S"
 772                 (class-name (class-of condition))
 773                 pos lineno colno error-stream)
 774         (when simple
 775           (format stream ":~2I~_~?"
 776                   (simple-condition-format-control condition)
 777                   (simple-condition-format-arguments condition)))))))
 778 \f
 779 ;;;; special SBCL extension conditions
 780
 781 ;;; an error apparently caused by a bug in SBCL itself
 782 ;;;
 783 ;;; Note that we don't make any serious effort to use this condition
 784 ;;; for *all* errors in SBCL itself. E.g. type errors and array
 785 ;;; indexing errors can occur in functions called from SBCL code, and
 786 ;;; will just end up as ordinary TYPE-ERROR or invalid index error,
 787 ;;; because the signalling code has no good way to know that the
 788 ;;; underlying problem is a bug in SBCL. But in the fairly common case
 789 ;;; that the signalling code does know that it's found a bug in SBCL,
 790 ;;; this condition is appropriate, reusing boilerplate and helping
 791 ;;; users to recognize it as an SBCL bug.
 792 (define-condition bug (simple-error)
 793   ()
 794   (:report
 795    (lambda (condition stream)
 796      (format stream
 797              "~@<  ~? ~:@_~?~:>"
 798              (simple-condition-format-control condition)
 799              (simple-condition-format-arguments condition)
 800              "~@<This is probably a bug in SBCL itself. (Alternatively, ~
 801               SBCL might have been corrupted by bad user code, e.g. by an ~
 802               undefined Lisp operation like ~S, or by stray pointers from ~
 803               alien code or from unsafe Lisp code; or there might be a bug ~
 804               in the OS or hardware that SBCL is running on.) If it seems to ~
 805               be a bug in SBCL itself, the maintainers would like to know ~
 806               about it. Bug reports are welcome on the SBCL ~
 807               mailing lists, which you can find at ~
 808               <http://sbcl.sourceforge.net/>.~:@>"
 809              '((fmakunbound 'compile))))))
 810
 811 (define-condition simple-storage-condition (storage-condition simple-condition)
 812   ())
 813
 814 ;;; a condition for use in stubs for operations which aren't supported
 815 ;;; on some platforms
 816 ;;;
 817 ;;; E.g. in sbcl-0.7.0.5, it might be appropriate to do something like
 818 ;;;   #-(or freebsd linux)
 819 ;;;   (defun load-foreign (&rest rest)
 820 ;;;     (error 'unsupported-operator :name 'load-foreign))
 821 ;;;   #+(or freebsd linux)
 822 ;;;   (defun load-foreign ... actual definition ...)
 823 ;;; By signalling a standard condition in this case, we make it
 824 ;;; possible for test code to distinguish between (1) intentionally
 825 ;;; unimplemented and (2) unintentionally just screwed up somehow.
 826 ;;; (Before this condition was defined, test code tried to deal with
 827 ;;; this by checking for FBOUNDP, but that didn't work reliably. In
 828 ;;; sbcl-0.7.0, a package screwup left the definition of
 829 ;;; LOAD-FOREIGN in the wrong package, so it was unFBOUNDP even on
 830 ;;; architectures where it was supposed to be supported, and the
 831 ;;; regression tests cheerfully passed because they assumed that
 832 ;;; unFBOUNDPness meant they were running on an system which didn't
 833 ;;; support the extension.)
 834 (define-condition unsupported-operator (simple-error) ())
 835 \f
 836 ;;; (:ansi-cl :function remove)
 837 ;;; (:ansi-cl :section (a b c))
 838 ;;; (:ansi-cl :glossary "similar")
 839 ;;;
 840 ;;; (:sbcl :node "...")
 841 ;;; (:sbcl :variable *ed-functions*)
 842 ;;;
 843 ;;; FIXME: this is not the right place for this.
 844 (defun print-reference (reference stream)
 845   (ecase (car reference)
 846     (:amop
 847      (format stream "AMOP")
 848      (format stream ", ")
 849      (destructuring-bind (type data) (cdr reference)
 850        (ecase type
 851          (:readers "Readers for ~:(~A~) Metaobjects"
 852                    (substitute #\  #\- (symbol-name data)))
 853          (:initialization
 854           (format stream "Initialization of ~:(~A~) Metaobjects"
 855                   (substitute #\  #\- (symbol-name data))))
 856          (:generic-function (format stream "Generic Function ~S" data))
 857          (:function (format stream "Function ~S" data))
 858          (:section (format stream "Section ~{~D~^.~}" data)))))
 859     (:ansi-cl
 860      (format stream "The ANSI Standard")
 861      (format stream ", ")
 862      (destructuring-bind (type data) (cdr reference)
 863        (ecase type
 864          (:function (format stream "Function ~S" data))
 865          (:special-operator (format stream "Special Operator ~S" data))
 866          (:macro (format stream "Macro ~S" data))
 867          (:section (format stream "Section ~{~D~^.~}" data))
 868          (:glossary (format stream "Glossary entry for ~S" data))
 869          (:issue (format stream "writeup for Issue ~A" data)))))
 870     (:sbcl
 871      (format stream "The SBCL Manual")
 872      (format stream ", ")
 873      (destructuring-bind (type data) (cdr reference)
 874        (ecase type
 875          (:node (format stream "Node ~S" data))
 876          (:variable (format stream "Variable ~S" data))
 877          (:function (format stream "Function ~S" data)))))
 878     ;; FIXME: other documents (e.g. CLIM, Franz documentation :-)
 879     ))
 880 (define-condition reference-condition ()
 881   ((references :initarg :references :reader reference-condition-references)))
 882 (defvar *print-condition-references* t)
 883 (def!method print-object :around ((o reference-condition) s)
 884   (call-next-method)
 885   (unless (or *print-escape* *print-readably*)
 886     (when (and *print-condition-references*
 887                (reference-condition-references o))
 888       (format s "~&See also:~%")
 889       (pprint-logical-block (s nil :per-line-prefix "  ")
 890         (do* ((rs (reference-condition-references o) (cdr rs))
 891               (r (car rs) (car rs)))
 892              ((null rs))
 893           (print-reference r s)
 894           (unless (null (cdr rs))
 895             (terpri s)))))))
 896
 897 (define-condition simple-reference-error (reference-condition simple-error)
 898   ())
 899
 900 (define-condition simple-reference-warning (reference-condition simple-warning)
 901   ())
 902
 903 (define-condition duplicate-definition (reference-condition warning)
 904   ((name :initarg :name :reader duplicate-definition-name))
 905   (:report (lambda (c s)
 906              (format s "~@<Duplicate definition for ~S found in ~
 907                         one file.~@:>"
 908                      (duplicate-definition-name c))))
 909   (:default-initargs :references (list '(:ansi-cl :section (3 2 2 3)))))
 910
 911 (define-condition constant-modified (reference-condition warning)
 912   ((fun-name :initarg :fun-name :reader constant-modified-fun-name))
 913   (:report (lambda (c s)
 914              (format s "~@<Destructive function ~S called on ~
 915                         constant data.~@:>"
 916                      (constant-modified-fun-name c))))
 917   (:default-initargs :references (list '(:ansi-cl :special-operator quote)
 918                                        '(:ansi-cl :section (3 2 2 3)))))
 919
 920 (define-condition package-at-variance (reference-condition simple-warning)
 921   ()
 922   (:default-initargs :references (list '(:ansi-cl :macro defpackage))))
 923
 924 (define-condition defconstant-uneql (reference-condition error)
 925   ((name :initarg :name :reader defconstant-uneql-name)
 926    (old-value :initarg :old-value :reader defconstant-uneql-old-value)
 927    (new-value :initarg :new-value :reader defconstant-uneql-new-value))
 928   (:report
 929    (lambda (condition stream)
 930      (format stream
 931              "~@<The constant ~S is being redefined (from ~S to ~S)~@:>"
 932              (defconstant-uneql-name condition)
 933              (defconstant-uneql-old-value condition)
 934              (defconstant-uneql-new-value condition))))
 935   (:default-initargs :references (list '(:ansi-cl :macro defconstant)
 936                                        '(:sbcl :node "Idiosyncrasies"))))
 937
 938 (define-condition array-initial-element-mismatch
 939     (reference-condition simple-warning)
 940   ()
 941   (:default-initargs
 942       :references (list
 943                    '(:ansi-cl :function make-array)
 944                    '(:ansi-cl :function sb!xc:upgraded-array-element-type))))
 945
 946 (define-condition type-warning (reference-condition simple-warning)
 947   ()
 948   (:default-initargs :references (list '(:sbcl :node "Handling of Types"))))
 949
 950 (define-condition local-argument-mismatch (reference-condition simple-warning)
 951   ()
 952   (:default-initargs :references (list '(:ansi-cl :section (3 2 2 3)))))
 953
 954 (define-condition format-args-mismatch (reference-condition)
 955   ()
 956   (:default-initargs :references (list '(:ansi-cl :section (22 3 10 2)))))
 957
 958 (define-condition format-too-few-args-warning
 959     (format-args-mismatch simple-warning)
 960   ())
 961 (define-condition format-too-many-args-warning
 962     (format-args-mismatch simple-style-warning)
 963   ())
 964
 965 (define-condition implicit-generic-function-warning (style-warning)
 966   ((name :initarg :name :reader implicit-generic-function-name))
 967   (:report
 968    (lambda (condition stream)
 969      (format stream "~@<Implicitly creating new generic function ~S.~:@>"
 970              (implicit-generic-function-name condition)))))
 971
 972 (define-condition extension-failure (reference-condition simple-error)
 973   ())
 974
 975 (define-condition structure-initarg-not-keyword
 976     (reference-condition simple-style-warning)
 977   ()
 978   (:default-initargs :references (list '(:ansi-cl :section (2 4 8 13)))))
 979
 980 #!+sb-package-locks
 981 (progn
 982
 983 (define-condition package-lock-violation (reference-condition package-error)
 984   ((format-control :initform nil :initarg :format-control
 985                    :reader package-error-format-control)
 986    (format-arguments :initform nil :initarg :format-arguments
 987                      :reader package-error-format-arguments))
 988   (:report
 989    (lambda (condition stream)
 990      (let ((control (package-error-format-control condition)))
 991        (if control
 992            (apply #'format stream
 993                   (format nil "~~@<Lock on package ~A violated when ~A.~~:@>"
 994                           (package-name (package-error-package condition))
 995                           control)
 996                   (package-error-format-arguments condition))
 997            (format stream "~@<Lock on package ~A violated.~:@>"
 998                    (package-name (package-error-package condition)))))))
 999   ;; no :default-initargs -- reference-stuff provided by the
1000   ;; signalling form in target-package.lisp
1001   #!+sb-doc
1002   (:documentation
1003    "Subtype of CL:PACKAGE-ERROR. A subtype of this error is signalled
1004 when a package-lock is violated."))
1005
1006 (define-condition package-locked-error (package-lock-violation) ()
1007   #!+sb-doc
1008   (:documentation
1009    "Subtype of SB-EXT:PACKAGE-LOCK-VIOLATION. An error of this type is
1010 signalled when an operation on a package violates a package lock."))
1011
1012 (define-condition symbol-package-locked-error (package-lock-violation)
1013   ((symbol :initarg :symbol :reader package-locked-error-symbol))
1014   #!+sb-doc
1015   (:documentation
1016    "Subtype of SB-EXT:PACKAGE-LOCK-VIOLATION. An error of this type is
1017 signalled when an operation on a symbol violates a package lock. The
1018 symbol that caused the violation is accessed by the function
1019 SB-EXT:PACKAGE-LOCKED-ERROR-SYMBOL."))
1020
1021 ) ; progn
1022
1023 (define-condition undefined-alien-error (cell-error) ()
1024   (:report
1025    (lambda (condition stream)
1026      (if (slot-boundp condition 'name)
1027          (format stream "Undefined alien: ~S" (cell-error-name condition))
1028          (format stream "Undefined alien symbol.")))))
1029
1030 (define-condition undefined-alien-variable-error (undefined-alien-error) ()
1031   (:report
1032    (lambda (condition stream)
1033      (declare (ignore condition))
1034      (format stream "Attempt to access an undefined alien variable."))))
1035
1036 (define-condition undefined-alien-function-error (undefined-alien-error) ()
1037   (:report
1038    (lambda (condition stream)
1039      (declare (ignore condition))
1040      (format stream "Attempt to call an undefined alien function."))))
1041
1042 \f
1043 ;;;; various other (not specified by ANSI) CONDITIONs
1044 ;;;;
1045 ;;;; These might logically belong in other files; they're here, after
1046 ;;;; setup of CONDITION machinery, only because that makes it easier to
1047 ;;;; get cold init to work.
1048
1049 ;;; OAOOM warning: see cross-condition.lisp
1050 (define-condition encapsulated-condition (condition)
1051   ((condition :initarg :condition :reader encapsulated-condition)))
1052
1053 (define-condition values-type-error (type-error)
1054   ()
1055   (:report
1056    (lambda (condition stream)
1057      (format stream
1058              "~@<The values set ~2I~:_[~{~S~^ ~}] ~I~_is not of type ~2I~_~S.~:>"
1059              (type-error-datum condition)
1060              (type-error-expected-type condition)))))
1061
1062 ;;; KLUDGE: a condition for floating point errors when we can't or
1063 ;;; won't figure out what type they are. (In FreeBSD and OpenBSD we
1064 ;;; don't know how, at least as of sbcl-0.6.7; in Linux we probably
1065 ;;; know how but the old code was broken by the conversion to POSIX
1066 ;;; signal handling and hasn't been fixed as of sbcl-0.6.7.)
1067 ;;;
1068 ;;; FIXME: Perhaps this should also be a base class for all
1069 ;;; floating point exceptions?
1070 (define-condition floating-point-exception (arithmetic-error)
1071   ((flags :initarg :traps
1072           :initform nil
1073           :reader floating-point-exception-traps))
1074   (:report (lambda (condition stream)
1075              (format stream
1076                      "An arithmetic error ~S was signalled.~%"
1077                      (type-of condition))
1078              (let ((traps (floating-point-exception-traps condition)))
1079                (if traps
1080                    (format stream
1081                            "Trapping conditions are: ~%~{ ~S~^~}~%"
1082                            traps)
1083                    (write-line
1084                     "No traps are enabled? How can this be?"
1085                     stream))))))
1086
1087 (define-condition invalid-array-index-error (type-error)
1088   ((array :initarg :array :reader invalid-array-index-error-array)
1089    (axis :initarg :axis :reader invalid-array-index-error-axis))
1090   (:report
1091    (lambda (condition stream)
1092      (let ((array (invalid-array-index-error-array condition)))
1093        (format stream "Index ~W out of bounds for ~@[axis ~W of ~]~S, ~
1094                        should be nonnegative and <~W."
1095                (type-error-datum condition)
1096                (when (> (array-rank array) 1)
1097                  (invalid-array-index-error-axis condition))
1098                (type-of array)
1099                ;; Extract the bound from (INTEGER 0 (BOUND))
1100                (caaddr (type-error-expected-type condition)))))))
1101
1102 (define-condition invalid-array-error (reference-condition type-error) ()
1103   (:report
1104    (lambda (condition stream)
1105      (let ((*print-array* nil))
1106        (format stream
1107                "~@<Displaced array originally of type ~S has been invalidated ~
1108                 due its displaced-to array ~S having become too small to hold ~
1109                 it: the displaced array's dimensions have all been set to zero ~
1110                 to trap accesses to it.~:@>"
1111                (type-error-expected-type condition)
1112                (array-displacement (type-error-datum condition))))))
1113   (:default-initargs
1114       :references
1115       (list '(:ansi-cl :function adjust-array))))
1116
1117 (define-condition index-too-large-error (type-error)
1118   ()
1119   (:report
1120    (lambda (condition stream)
1121      (format stream
1122              "The index ~S is too large."
1123              (type-error-datum condition)))))
1124
1125 (define-condition bounding-indices-bad-error (reference-condition type-error)
1126   ((object :reader bounding-indices-bad-object :initarg :object))
1127   (:report
1128    (lambda (condition stream)
1129      (let* ((datum (type-error-datum condition))
1130             (start (car datum))
1131             (end (cdr datum))
1132             (object (bounding-indices-bad-object condition)))
1133        (etypecase object
1134          (sequence
1135           (format stream
1136                   "The bounding indices ~S and ~S are bad ~
1137                    for a sequence of length ~S."
1138                   start end (length object)))
1139          (array
1140           ;; from WITH-ARRAY-DATA
1141           (format stream
1142                   "The START and END parameters ~S and ~S are ~
1143                    bad for an array of total size ~S."
1144                   start end (array-total-size object)))))))
1145   (:default-initargs
1146       :references
1147       (list '(:ansi-cl :glossary "bounding index designator")
1148             '(:ansi-cl :issue "SUBSEQ-OUT-OF-BOUNDS:IS-AN-ERROR"))))
1149
1150 (define-condition nil-array-accessed-error (reference-condition type-error)
1151   ()
1152   (:report (lambda (condition stream)
1153              (declare (ignore condition))
1154              (format stream
1155                      "An attempt to access an array of element-type ~
1156                       NIL was made.  Congratulations!")))
1157   (:default-initargs
1158       :references (list '(:ansi-cl :function sb!xc:upgraded-array-element-type)
1159                         '(:ansi-cl :section (15 1 2 1))
1160                         '(:ansi-cl :section (15 1 2 2)))))
1161
1162 (define-condition namestring-parse-error (parse-error)
1163   ((complaint :reader namestring-parse-error-complaint :initarg :complaint)
1164    (args :reader namestring-parse-error-args :initarg :args :initform nil)
1165    (namestring :reader namestring-parse-error-namestring :initarg :namestring)
1166    (offset :reader namestring-parse-error-offset :initarg :offset))
1167   (:report
1168    (lambda (condition stream)
1169      (format stream
1170              "parse error in namestring: ~?~%  ~A~%  ~V@T^"
1171              (namestring-parse-error-complaint condition)
1172              (namestring-parse-error-args condition)
1173              (namestring-parse-error-namestring condition)
1174              (namestring-parse-error-offset condition)))))
1175
1176 (define-condition simple-package-error (simple-condition package-error) ())
1177
1178 (define-condition simple-reader-package-error (simple-reader-error) ())
1179
1180 (define-condition reader-eof-error (end-of-file)
1181   ((context :reader reader-eof-error-context :initarg :context))
1182   (:report
1183    (lambda (condition stream)
1184      (format stream
1185              "unexpected end of file on ~S ~A"
1186              (stream-error-stream condition)
1187              (reader-eof-error-context condition)))))
1188
1189 (define-condition reader-impossible-number-error (simple-reader-error)
1190   ((error :reader reader-impossible-number-error-error :initarg :error))
1191   (:report
1192    (lambda (condition stream)
1193      (let ((error-stream (stream-error-stream condition)))
1194        (format stream
1195                "READER-ERROR ~@[at ~W ~]on ~S:~%~?~%Original error: ~A"
1196                (file-position-or-nil-for-error error-stream) error-stream
1197                (simple-condition-format-control condition)
1198                (simple-condition-format-arguments condition)
1199                (reader-impossible-number-error-error condition))))))
1200
1201 (define-condition standard-readtable-modified-error (reference-condition error)
1202   ((operation :initarg :operation :reader standard-readtable-modified-operation))
1203   (:report (lambda (condition stream)
1204              (format stream "~S would modify the standard readtable."
1205                      (standard-readtable-modified-operation condition))))
1206   (:default-initargs :references `((:ansi-cl :section (2 1 1 2))
1207                                    (:ansi-cl :glossary "standard readtable"))))
1208
1209 (define-condition standard-pprint-dispatch-table-modified-error
1210     (reference-condition error)
1211   ((operation :initarg :operation
1212               :reader standard-pprint-dispatch-table-modified-operation))
1213   (:report (lambda (condition stream)
1214              (format stream "~S would modify the standard pprint dispatch table."
1215                      (standard-pprint-dispatch-table-modified-operation
1216                       condition))))
1217   (:default-initargs
1218       :references `((:ansi-cl :glossary "standard pprint dispatch table"))))
1219
1220 (define-condition timeout (serious-condition)
1221   ((seconds :initarg :seconds :initform nil :reader timeout-seconds))
1222   (:report (lambda (condition stream)
1223              (format stream "Timeout occurred~@[ after ~A seconds~]."
1224                      (timeout-seconds condition)))))
1225
1226 (define-condition io-timeout (stream-error timeout)
1227   ((direction :reader io-timeout-direction :initarg :direction))
1228   (:report
1229    (lambda (condition stream)
1230      (declare (type stream stream))
1231      (format stream
1232              "I/O timeout ~(~A~)ing ~S."
1233              (io-timeout-direction condition)
1234              (stream-error-stream condition)))))
1235
1236 (define-condition deadline-timeout (timeout) ()
1237   (:report (lambda (condition stream)
1238              (format stream "A deadline was reached after ~A seconds."
1239                      (timeout-seconds condition)))))
1240
1241 (define-condition declaration-type-conflict-error (reference-condition
1242                                                    simple-error)
1243   ()
1244   (:default-initargs
1245       :format-control "symbol ~S cannot be both the name of a type and the name of a declaration"
1246     :references (list '(:ansi-cl :section (3 8 21)))))
1247
1248 ;;; Single stepping conditions
1249
1250 (define-condition step-condition ()
1251   ((form :initarg :form :reader step-condition-form))
1252
1253   #!+sb-doc
1254   (:documentation "Common base class of single-stepping conditions.
1255 STEP-CONDITION-FORM holds a string representation of the form being
1256 stepped."))
1257
1258 #!+sb-doc
1259 (setf (fdocumentation 'step-condition-form 'function)
1260       "Form associated with the STEP-CONDITION.")
1261
1262 (define-condition step-form-condition (step-condition)
1263   ((args :initarg :args :reader step-condition-args))
1264   (:report
1265    (lambda (condition stream)
1266      (let ((*print-circle* t)
1267            (*print-pretty* t)
1268            (*print-readably* nil))
1269        (format stream
1270                  "Evaluating call:~%~<  ~@;~A~:>~%~
1271                   ~:[With arguments:~%~{  ~S~%~}~;With unknown arguments~]~%"
1272                (list (step-condition-form condition))
1273                (eq (step-condition-args condition) :unknown)
1274                (step-condition-args condition)))))
1275   #!+sb-doc
1276   (:documentation "Condition signalled by code compiled with
1277 single-stepping information when about to execute a form.
1278 STEP-CONDITION-FORM holds the form, STEP-CONDITION-PATHNAME holds the
1279 pathname of the original file or NIL, and STEP-CONDITION-SOURCE-PATH
1280 holds the source-path to the original form within that file or NIL.
1281 Associated with this condition are always the restarts STEP-INTO,
1282 STEP-NEXT, and STEP-CONTINUE."))
1283
1284 (define-condition step-result-condition (step-condition)
1285   ((result :initarg :result :reader step-condition-result)))
1286
1287 #!+sb-doc
1288 (setf (fdocumentation 'step-condition-result 'function)
1289       "Return values associated with STEP-VALUES-CONDITION as a list,
1290 or the variable value associated with STEP-VARIABLE-CONDITION.")
1291
1292 (define-condition step-values-condition (step-result-condition)
1293   ()
1294   #!+sb-doc
1295   (:documentation "Condition signalled by code compiled with
1296 single-stepping information after executing a form.
1297 STEP-CONDITION-FORM holds the form, and STEP-CONDITION-RESULT holds
1298 the values returned by the form as a list. No associated restarts."))
1299
1300 (define-condition step-finished-condition (step-condition)
1301   ()
1302   (:report
1303    (lambda (condition stream)
1304      (declare (ignore condition))
1305      (format stream "Returning from STEP")))
1306   #!+sb-doc
1307   (:documentation "Condition signaled when STEP returns."))
1308 \f
1309 ;;; A knob for muffling warnings, mostly for use while loading files.
1310 (defvar *muffled-warnings* 'uninteresting-redefinition
1311   "A type that ought to specify a subtype of WARNING.  Whenever a
1312 warning is signaled, if the warning if of this type and is not
1313 handled by any other handler, it will be muffled.")
1314 \f
1315 ;;; Various STYLE-WARNING signaled in the system.
1316 ;; For the moment, we're only getting into the details for function
1317 ;; redefinitions, but other redefinitions could be done later
1318 ;; (e.g. methods).
1319 (define-condition redefinition-warning (style-warning)
1320   ())
1321
1322 (define-condition function-redefinition-warning (redefinition-warning)
1323   ((name :initarg :name :reader function-redefinition-warning-name)
1324    (old :initarg :old :reader function-redefinition-warning-old-fdefinition)
1325    ;; For DEFGENERIC and perhaps others, the redefinition
1326    ;; destructively modifies the original, rather than storing a new
1327    ;; object, so there's no NEW here, but only in subclasses.
1328    ))
1329
1330 (define-condition redefinition-with-defun (function-redefinition-warning)
1331   ((new :initarg :new :reader redefinition-with-defun-new-fdefinition)
1332    ;; KLUDGE: it would be nice to fix the unreasonably late
1333    ;; back-patching of DEBUG-SOURCEs in the DEBUG-INFO during
1334    ;; fasloading and just use the new fdefinition, but for the moment
1335    ;; we'll compare the SOURCE-LOCATION created during DEFUN with the
1336    ;; previous DEBUG-SOURCE.
1337    (new-location :initarg :new-location
1338               :reader redefinition-with-defun-new-location))
1339   (:report (lambda (warning stream)
1340              (format stream "redefining ~S in DEFUN"
1341                      (function-redefinition-warning-name warning)))))
1342
1343 (define-condition redefinition-with-defgeneric (function-redefinition-warning)
1344   ((new-location :initarg :new-location
1345                  :reader redefinition-with-defgeneric-new-location))
1346   (:report (lambda (warning stream)
1347              (format stream "redefining ~S in DEFGENERIC"
1348                      (function-redefinition-warning-name warning)))))
1349
1350 (define-condition redefinition-with-defmethod (redefinition-warning)
1351   ((gf :initarg :generic-function
1352        :reader redefinition-with-defmethod-generic-function)
1353    (qualifiers :initarg :qualifiers
1354                :reader redefinition-with-defmethod-qualifiers)
1355    (specializers :initarg :specializers
1356                  :reader redefinition-with-defmethod-specializers)
1357    (new-location :initarg :new-location
1358                  :reader redefinition-with-defmethod-new-location)
1359    (old-method :initarg :old-method
1360                :reader redefinition-with-defmethod-old-method))
1361   (:report (lambda (warning stream)
1362              (format stream "redefining ~S~{ ~S~} ~S in DEFMETHOD"
1363                      (redefinition-with-defmethod-generic-function warning)
1364                      (redefinition-with-defmethod-qualifiers warning)
1365                      (redefinition-with-defmethod-specializers warning)))))
1366
1367 ;; FIXME: see the FIXMEs in defmacro.lisp, then maybe instantiate this.
1368 (define-condition redefinition-with-defmacro (function-redefinition-warning)
1369   ())
1370
1371 ;; Here are a few predicates for what people might find interesting
1372 ;; about redefinitions.
1373
1374 ;; DEFUN can replace a generic function with an ordinary function.
1375 ;; (Attempting to replace an ordinary function with a generic one
1376 ;; causes an error, though.)
1377 (defun redefinition-replaces-generic-function-p (warning)
1378   (and (typep warning 'redefinition-with-defun)
1379        (typep (function-redefinition-warning-old-fdefinition warning)
1380               'generic-function)))
1381
1382 (defun redefinition-replaces-compiled-function-with-interpreted-p (warning)
1383   (and (typep warning 'redefinition-with-defun)
1384        (compiled-function-p
1385         (function-redefinition-warning-old-fdefinition warning))
1386        (not (compiled-function-p
1387              (redefinition-with-defun-new-fdefinition warning)))))
1388
1389 ;; Most people seem to agree that re-running a DEFUN in a file is
1390 ;; completely uninteresting.
1391 (defun uninteresting-ordinary-function-redefinition-p (warning)
1392   ;; OAOO violation: this duplicates code in SB-INTROSPECT.
1393   ;; Additionally, there are some functions that aren't
1394   ;; funcallable-instances for which finding the source location is
1395   ;; complicated (e.g. DEFSTRUCT-defined predicates and accessors),
1396   ;; but I don't think they're defined with %DEFUN, so the warning
1397   ;; isn't raised.
1398   (flet ((fdefinition-file-namestring (fdefn)
1399            #!+sb-eval
1400            (when (typep fdefn 'sb!eval:interpreted-function)
1401              (return-from fdefinition-file-namestring
1402                (sb!c:definition-source-location-namestring
1403                    (sb!eval:interpreted-function-source-location fdefn))))
1404            ;; All the following accesses are guarded with conditionals
1405            ;; because it's not clear whether any of the slots we're
1406            ;; chasing down are guaranteed to be filled in.
1407            (let* ((fdefn
1408                    ;; KLUDGE: although this looks like it only works
1409                    ;; for %SIMPLE-FUNs, in fact there's a pun such
1410                    ;; that %SIMPLE-FUN-SELF returns the simple-fun
1411                    ;; object for closures and
1412                    ;; funcallable-instances. -- CSR, circa 2005
1413                    (sb!kernel:%simple-fun-self fdefn))
1414                   (code (if fdefn (sb!kernel:fun-code-header fdefn)))
1415                   (debug-info (if code (sb!kernel:%code-debug-info code)))
1416                   (debug-source (if debug-info
1417                                     (sb!c::debug-info-source debug-info)))
1418                   (namestring (if debug-source
1419                                   (sb!c::debug-source-namestring debug-source))))
1420              namestring)))
1421     (and
1422      ;; There's garbage in various places when the first DEFUN runs in
1423      ;; cold-init.
1424      sb!kernel::*cold-init-complete-p*
1425      (typep warning 'redefinition-with-defun)
1426      (let ((old-fdefn
1427             (function-redefinition-warning-old-fdefinition warning))
1428            (new-fdefn
1429             (redefinition-with-defun-new-fdefinition warning)))
1430        ;; Replacing a compiled function with a compiled function is
1431        ;; clearly uninteresting, and we'll say arbitrarily that
1432        ;; replacing an interpreted function with an interpreted
1433        ;; function is uninteresting, too, but leave out the
1434        ;; compiled-to-interpreted case.
1435        (when (or (typep
1436                   old-fdefn
1437                   '(or #!+sb-eval sb!eval:interpreted-function))
1438                  (and (typep old-fdefn
1439                              '(and compiled-function
1440                                (not funcallable-instance)))
1441                       ;; Since this is a REDEFINITION-WITH-DEFUN,
1442                       ;; NEW-FDEFN can't be a FUNCALLABLE-INSTANCE.
1443                       (typep new-fdefn 'compiled-function)))
1444          (let* ((old-namestring (fdefinition-file-namestring old-fdefn))
1445                 (new-namestring
1446                  (or (fdefinition-file-namestring new-fdefn)
1447                      (let ((srcloc
1448                             (redefinition-with-defun-new-location warning)))
1449                        (if srcloc
1450                             (sb!c::definition-source-location-namestring
1451                                 srcloc))))))
1452            (and old-namestring
1453                 new-namestring
1454                 (equal old-namestring new-namestring))))))))
1455
1456 (defun uninteresting-generic-function-redefinition-p (warning)
1457   (and (typep warning 'redefinition-with-defgeneric)
1458        (let* ((old-fdefn
1459                (function-redefinition-warning-old-fdefinition warning))
1460               (old-location
1461                (if (typep old-fdefn 'generic-function)
1462                    (sb!pcl::definition-source old-fdefn)))
1463               (old-namestring
1464                (if old-location
1465                    (sb!c:definition-source-location-namestring old-location)))
1466               (new-location
1467                (redefinition-with-defgeneric-new-location warning))
1468               (new-namestring
1469                (if new-location
1470                    (sb!c:definition-source-location-namestring new-location))))
1471          (and old-namestring
1472               new-namestring
1473               (equal old-namestring new-namestring)))))
1474
1475 (defun uninteresting-method-redefinition-p (warning)
1476   (and (typep warning 'redefinition-with-defmethod)
1477        (let* ((old-method (redefinition-with-defmethod-old-method warning))
1478               (old-location (sb!pcl::definition-source old-method))
1479               (old-namestring (if old-location
1480                                   (sb!c:definition-source-location-namestring
1481                                       old-location)))
1482               (new-location (redefinition-with-defmethod-new-location warning))
1483               (new-namestring (if new-location
1484                                   (sb!c:definition-source-location-namestring
1485                                       new-location))))
1486          (and new-namestring
1487               old-namestring
1488               (equal new-namestring old-namestring)))))
1489
1490 (deftype uninteresting-redefinition ()
1491   '(or (satisfies uninteresting-ordinary-function-redefinition-p)
1492        (satisfies uninteresting-generic-function-redefinition-p)
1493        (satisfies uninteresting-method-redefinition-p)))
1494
1495 (define-condition redefinition-with-deftransform (redefinition-warning)
1496   ((transform :initarg :transform
1497               :reader redefinition-with-deftransform-transform))
1498   (:report (lambda (warning stream)
1499              (format stream "Overwriting ~S"
1500                      (redefinition-with-deftransform-transform warning)))))
1501 \f
1502 ;;; Various other STYLE-WARNINGS
1503 (define-condition dubious-asterisks-around-variable-name
1504     (style-warning simple-condition)
1505   ()
1506   (:report (lambda (warning stream)
1507              (format stream "~@?, even though the name follows~@
1508 the usual naming convention (names like *FOO*) for special variables"
1509                      (simple-condition-format-control warning)
1510                      (simple-condition-format-arguments warning)))))
1511
1512 (define-condition asterisks-around-lexical-variable-name
1513     (dubious-asterisks-around-variable-name)
1514   ())
1515
1516 (define-condition asterisks-around-constant-variable-name
1517     (dubious-asterisks-around-variable-name)
1518   ())
1519
1520 ;; We call this UNDEFINED-ALIEN-STYLE-WARNING because there are some
1521 ;; subclasses of ERROR above having to do with undefined aliens.
1522 (define-condition undefined-alien-style-warning (style-warning)
1523   ((symbol :initarg :symbol :reader undefined-alien-symbol))
1524   (:report (lambda (warning stream)
1525              (format stream "Undefined alien: ~S"
1526                      (undefined-alien-symbol warning)))))
1527
1528 #!+sb-eval
1529 (define-condition lexical-environment-too-complex (style-warning)
1530   ((form :initarg :form :reader lexical-environment-too-complex-form)
1531    (lexenv :initarg :lexenv :reader lexical-environment-too-complex-lexenv))
1532   (:report (lambda (warning stream)
1533              (format stream
1534                      "~@<Native lexical environment too complex for ~
1535                          SB-EVAL to evaluate ~S, falling back to ~
1536                          SIMPLE-EVAL-IN-LEXENV.  Lexenv: ~S~:@>"
1537                      (lexical-environment-too-complex-form warning)
1538                      (lexical-environment-too-complex-lexenv warning)))))
1539
1540 ;; Although this has -ERROR- in the name, it's just a STYLE-WARNING.
1541 (define-condition character-decoding-error-in-comment (style-warning)
1542   ((stream :initarg :stream :reader decoding-error-in-comment-stream)
1543    (position :initarg :position :reader decoding-error-in-comment-position))
1544   (:report (lambda (warning stream)
1545              (format stream
1546                       "Character decoding error in a ~A-comment at ~
1547                       position ~A reading source stream ~A, ~
1548                       resyncing."
1549                       (decoding-error-in-comment-macro warning)
1550                       (decoding-error-in-comment-position warning)
1551                       (decoding-error-in-comment-stream warning)))))
1552
1553 (define-condition character-decoding-error-in-macro-char-comment
1554     (character-decoding-error-in-comment)
1555   ((char :initform #\; :initarg :char
1556          :reader character-decoding-error-in-macro-char-comment-char)))
1557
1558 (define-condition character-decoding-error-in-dispatch-macro-char-comment
1559     (character-decoding-error-in-comment)
1560   ;; ANSI doesn't give a way for a reader function invoked by a
1561   ;; dispatch macro character to determine which dispatch character
1562   ;; was used, so if a user wants to signal one of these from a custom
1563   ;; comment reader, he'll have to supply the :DISP-CHAR himself.
1564   ((disp-char :initform #\# :initarg :disp-char
1565               :reader character-decoding-error-in-macro-char-comment-disp-char)
1566    (sub-char :initarg :sub-char
1567              :reader character-decoding-error-in-macro-char-comment-sub-char)))
1568
1569 (defun decoding-error-in-comment-macro (warning)
1570   (etypecase warning
1571     (character-decoding-error-in-macro-char-comment
1572      (character-decoding-error-in-macro-char-comment-char warning))
1573     (character-decoding-error-in-dispatch-macro-char-comment
1574      (format
1575       nil "~C~C"
1576       (character-decoding-error-in-macro-char-comment-disp-char warning)
1577       (character-decoding-error-in-macro-char-comment-sub-char warning)))))
1578
1579 (define-condition deprecated-eval-when-situations (style-warning)
1580   ((situations :initarg :situations
1581                :reader deprecated-eval-when-situations-situations))
1582   (:report (lambda (warning stream)
1583              (format stream "using deprecated EVAL-WHEN situation names~{ ~S~}"
1584                      (deprecated-eval-when-situations-situations warning)))))
1585
1586 (define-condition proclamation-mismatch (style-warning)
1587   ((name :initarg :name :reader proclamation-mismatch-name)
1588    (old :initarg :old :reader proclamation-mismatch-old)
1589    (new :initarg :new :reader proclamation-mismatch-new)))
1590
1591 (define-condition type-proclamation-mismatch (proclamation-mismatch)
1592   ()
1593   (:report (lambda (warning stream)
1594              (format stream
1595                      "The new TYPE proclamation~% ~S for ~S does not ~
1596                      match the old TYPE proclamation ~S"
1597                      (proclamation-mismatch-new warning)
1598                      (proclamation-mismatch-name warning)
1599                      (proclamation-mismatch-old warning)))))
1600
1601 (define-condition ftype-proclamation-mismatch (proclamation-mismatch)
1602   ()
1603   (:report (lambda (warning stream)
1604              (format stream
1605                      "The new FTYPE proclamation~% ~S for ~S does not ~
1606                      match the old FTYPE proclamation ~S"
1607                      (proclamation-mismatch-new warning)
1608                      (proclamation-mismatch-name warning)
1609                      (proclamation-mismatch-old warning)))))
1610 \f
1611 ;;;; restart definitions
1612
1613 (define-condition abort-failure (control-error) ()
1614   (:report
1615    "An ABORT restart was found that failed to transfer control dynamically."))
1616
1617 (defun abort (&optional condition)
1618   #!+sb-doc
1619   "Transfer control to a restart named ABORT, signalling a CONTROL-ERROR if
1620    none exists."
1621   (invoke-restart (find-restart-or-control-error 'abort condition))
1622   ;; ABORT signals an error in case there was a restart named ABORT
1623   ;; that did not transfer control dynamically. This could happen with
1624   ;; RESTART-BIND.
1625   (error 'abort-failure))
1626
1627 (defun muffle-warning (&optional condition)
1628   #!+sb-doc
1629   "Transfer control to a restart named MUFFLE-WARNING, signalling a
1630    CONTROL-ERROR if none exists."
1631   (invoke-restart (find-restart-or-control-error 'muffle-warning condition)))
1632
1633 (defun try-restart (name condition &rest arguments)
1634   (let ((restart (find-restart name condition)))
1635     (when restart
1636       (apply #'invoke-restart restart arguments))))
1637
1638 (macrolet ((define-nil-returning-restart (name args doc)
1639              #!-sb-doc (declare (ignore doc))
1640              `(defun ,name (,@args &optional condition)
1641                 #!+sb-doc ,doc
1642                 (try-restart ',name condition ,@args))))
1643   (define-nil-returning-restart continue ()
1644     "Transfer control to a restart named CONTINUE, or return NIL if none exists.")
1645   (define-nil-returning-restart store-value (value)
1646     "Transfer control and VALUE to a restart named STORE-VALUE, or return NIL if
1647    none exists.")
1648   (define-nil-returning-restart use-value (value)
1649     "Transfer control and VALUE to a restart named USE-VALUE, or return NIL if
1650    none exists."))
1651
1652 ;;; single-stepping restarts
1653
1654 (macrolet ((def (name doc)
1655                #!-sb-doc (declare (ignore doc))
1656                `(defun ,name (condition)
1657                  #!+sb-doc ,doc
1658                  (invoke-restart (find-restart-or-control-error ',name condition)))))
1659   (def step-continue
1660       "Transfers control to the STEP-CONTINUE restart associated with
1661 the condition, continuing execution without stepping. Signals a
1662 CONTROL-ERROR if the restart does not exist.")
1663   (def step-next
1664       "Transfers control to the STEP-NEXT restart associated with the
1665 condition, executing the current form without stepping and continuing
1666 stepping with the next form. Signals CONTROL-ERROR is the restart does
1667 not exists.")
1668   (def step-into
1669       "Transfers control to the STEP-INTO restart associated with the
1670 condition, stepping into the current form. Signals a CONTROL-ERROR is
1671 the restart does not exist."))
1672
1673 (/show0 "condition.lisp end of file")
1674