src/code/condition.lisp

   1 ;;;; stuff originally from CMU CL's error.lisp which can or should
   2 ;;;; come late (mostly related to the CONDITION class itself)
   3 ;;;;
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!KERNEL")
  15 \f
  16 ;;;; the CONDITION class
  17
  18 (/show0 "condition.lisp 20")
  19
  20 (eval-when (:compile-toplevel :load-toplevel :execute)
  21
  22 (/show0 "condition.lisp 24")
  23
  24 (def!struct (condition-classoid (:include slot-classoid)
  25                                 (:constructor make-condition-classoid))
  26   ;; list of CONDITION-SLOT structures for the direct slots of this
  27   ;; class
  28   (slots nil :type list)
  29   ;; list of CONDITION-SLOT structures for all of the effective class
  30   ;; slots of this class
  31   (class-slots nil :type list)
  32   ;; report function or NIL
  33   (report nil :type (or function null))
  34   ;; list of alternating initargs and initforms
  35   (default-initargs () :type list)
  36   ;; class precedence list as a list of CLASS objects, with all
  37   ;; non-CONDITION classes removed
  38   (cpl () :type list)
  39   ;; a list of all the effective instance allocation slots of this
  40   ;; class that have a non-constant initform or default-initarg.
  41   ;; Values for these slots must be computed in the dynamic
  42   ;; environment of MAKE-CONDITION.
  43   (hairy-slots nil :type list))
  44
  45 (/show0 "condition.lisp 49")
  46
  47 ) ; EVAL-WHEN
  48
  49 (!defstruct-with-alternate-metaclass condition
  50   :slot-names (actual-initargs assigned-slots)
  51   :boa-constructor %make-condition-object
  52   :superclass-name instance
  53   :metaclass-name condition-classoid
  54   :metaclass-constructor make-condition-classoid
  55   :dd-type structure)
  56
  57 (defun make-condition-object (actual-initargs)
  58   (%make-condition-object actual-initargs nil))
  59
  60 (defstruct (condition-slot (:copier nil))
  61   (name (missing-arg) :type symbol)
  62   ;; list of all applicable initargs
  63   (initargs (missing-arg) :type list)
  64   ;; names of reader and writer functions
  65   (readers (missing-arg) :type list)
  66   (writers (missing-arg) :type list)
  67   ;; true if :INITFORM was specified
  68   (initform-p (missing-arg) :type (member t nil))
  69   ;; If this is a function, call it with no args. Otherwise, it's the
  70   ;; actual value.
  71   (initform (missing-arg) :type t)
  72   ;; allocation of this slot, or NIL until defaulted
  73   (allocation nil :type (member :instance :class nil))
  74   ;; If ALLOCATION is :CLASS, this is a cons whose car holds the value.
  75   (cell nil :type (or cons null))
  76   ;; slot documentation
  77   (documentation nil :type (or string null)))
  78
  79 ;;; KLUDGE: It's not clear to me why CONDITION-CLASS has itself listed
  80 ;;; in its CPL, while other classes derived from CONDITION-CLASS don't
  81 ;;; have themselves listed in their CPLs. This behavior is inherited
  82 ;;; from CMU CL, and didn't seem to be explained there, and I haven't
  83 ;;; figured out whether it's right. -- WHN 19990612
  84 (eval-when (:compile-toplevel :load-toplevel :execute)
  85   (/show0 "condition.lisp 103")
  86   (let ((condition-class (locally
  87                            ;; KLUDGE: There's a DEFTRANSFORM
  88                            ;; FIND-CLASSOID for constant class names
  89                            ;; which creates fast but
  90                            ;; non-cold-loadable, non-compact code. In
  91                            ;; this context, we'd rather have compact,
  92                            ;; cold-loadable code. -- WHN 19990928
  93                            (declare (notinline find-classoid))
  94                            (find-classoid 'condition))))
  95     (setf (condition-classoid-cpl condition-class)
  96           (list condition-class)))
  97   (/show0 "condition.lisp 103"))
  98
  99 (setf (condition-classoid-report (locally
 100                                    ;; KLUDGE: There's a DEFTRANSFORM
 101                                    ;; FIND-CLASSOID for constant class
 102                                    ;; names which creates fast but
 103                                    ;; non-cold-loadable, non-compact
 104                                    ;; code. In this context, we'd
 105                                    ;; rather have compact,
 106                                    ;; cold-loadable code. -- WHN
 107                                    ;; 19990928
 108                                    (declare (notinline find-classoid))
 109                                    (find-classoid 'condition)))
 110       (lambda (cond stream)
 111         (format stream "Condition ~S was signalled." (type-of cond))))
 112
 113 (eval-when (:compile-toplevel :load-toplevel :execute)
 114
 115 (defun find-condition-layout (name parent-types)
 116   (let* ((cpl (remove-duplicates
 117                (reverse
 118                 (reduce #'append
 119                         (mapcar (lambda (x)
 120                                   (condition-classoid-cpl
 121                                    (find-classoid x)))
 122                                 parent-types)))))
 123          (cond-layout (info :type :compiler-layout 'condition))
 124          (olayout (info :type :compiler-layout name))
 125          ;; FIXME: Does this do the right thing in case of multiple
 126          ;; inheritance? A quick look at DEFINE-CONDITION didn't make
 127          ;; it obvious what ANSI intends to be done in the case of
 128          ;; multiple inheritance, so it's not actually clear what the
 129          ;; right thing is..
 130          (new-inherits
 131           (order-layout-inherits (concatenate 'simple-vector
 132                                               (layout-inherits cond-layout)
 133                                               (mapcar #'classoid-layout cpl)))))
 134     (if (and olayout
 135              (not (mismatch (layout-inherits olayout) new-inherits)))
 136         olayout
 137         (make-layout :classoid (make-undefined-classoid name)
 138                      :inherits new-inherits
 139                      :depthoid -1
 140                      :length (layout-length cond-layout)))))
 141
 142 ) ; EVAL-WHEN
 143
 144 ;;; FIXME: ANSI's definition of DEFINE-CONDITION says
 145 ;;;   Condition reporting is mediated through the PRINT-OBJECT method
 146 ;;;   for the condition type in question, with *PRINT-ESCAPE* always
 147 ;;;   being nil. Specifying (:REPORT REPORT-NAME) in the definition of
 148 ;;;   a condition type C is equivalent to:
 149 ;;;     (defmethod print-object ((x c) stream)
 150 ;;;       (if *print-escape* (call-next-method) (report-name x stream)))
 151 ;;; The current code doesn't seem to quite match that.
 152 (def!method print-object ((x condition) stream)
 153   (if *print-escape*
 154       (print-unreadable-object (x stream :type t :identity t))
 155       ;; KLUDGE: A comment from CMU CL here said
 156       ;;   7/13/98 BUG? CPL is not sorted and results here depend on order of
 157       ;;   superclasses in define-condition call!
 158       (dolist (class (condition-classoid-cpl (classoid-of x))
 159                      (error "no REPORT? shouldn't happen!"))
 160         (let ((report (condition-classoid-report class)))
 161           (when report
 162             (return (funcall report x stream)))))))
 163 \f
 164 ;;;; slots of CONDITION objects
 165
 166 (defvar *empty-condition-slot* '(empty))
 167
 168 (defun find-slot-default (class slot)
 169   (let ((initargs (condition-slot-initargs slot))
 170         (cpl (condition-classoid-cpl class)))
 171     (dolist (class cpl)
 172       (let ((default-initargs (condition-classoid-default-initargs class)))
 173         (dolist (initarg initargs)
 174           (let ((val (getf default-initargs initarg *empty-condition-slot*)))
 175             (unless (eq val *empty-condition-slot*)
 176               (return-from find-slot-default
 177                            (if (functionp val)
 178                                (funcall val)
 179                                val)))))))
 180
 181     (if (condition-slot-initform-p slot)
 182         (let ((initform (condition-slot-initform slot)))
 183           (if (functionp initform)
 184               (funcall initform)
 185               initform))
 186         (error "unbound condition slot: ~S" (condition-slot-name slot)))))
 187
 188 (defun find-condition-class-slot (condition-class slot-name)
 189   (dolist (sclass
 190            (condition-classoid-cpl condition-class)
 191            (error "There is no slot named ~S in ~S."
 192                   slot-name condition-class))
 193     (dolist (slot (condition-classoid-slots sclass))
 194       (when (eq (condition-slot-name slot) slot-name)
 195         (return-from find-condition-class-slot slot)))))
 196
 197 (defun condition-writer-function (condition new-value name)
 198   (dolist (cslot (condition-classoid-class-slots
 199                   (layout-classoid (%instance-layout condition)))
 200                  (setf (getf (condition-assigned-slots condition) name)
 201                        new-value))
 202     (when (eq (condition-slot-name cslot) name)
 203       (return (setf (car (condition-slot-cell cslot)) new-value)))))
 204
 205 (defun condition-reader-function (condition name)
 206   (let ((class (layout-classoid (%instance-layout condition))))
 207     (dolist (cslot (condition-classoid-class-slots class))
 208       (when (eq (condition-slot-name cslot) name)
 209         (return-from condition-reader-function
 210                      (car (condition-slot-cell cslot)))))
 211     (let ((val (getf (condition-assigned-slots condition) name
 212                      *empty-condition-slot*)))
 213       (if (eq val *empty-condition-slot*)
 214           (let ((actual-initargs (condition-actual-initargs condition))
 215                 (slot (find-condition-class-slot class name)))
 216             (unless slot
 217               (error "missing slot ~S of ~S" name condition))
 218             (do ((initargs actual-initargs (cddr initargs)))
 219                 ((endp initargs)
 220                  (setf (getf (condition-assigned-slots condition) name)
 221                        (find-slot-default class slot)))
 222               (when (member (car initargs) (condition-slot-initargs slot))
 223                 (return-from condition-reader-function
 224                   (setf (getf (condition-assigned-slots condition)
 225                               name)
 226                         (cadr initargs))))))
 227           val))))
 228 \f
 229 ;;;; MAKE-CONDITION
 230
 231 (defun make-condition (thing &rest args)
 232   #!+sb-doc
 233   "Make an instance of a condition object using the specified initargs."
 234   ;; Note: ANSI specifies no exceptional situations in this function.
 235   ;; signalling simple-type-error would not be wrong.
 236   (let* ((thing (if (symbolp thing)
 237                     (find-classoid thing)
 238                     thing))
 239          (class (typecase thing
 240                   (condition-classoid thing)
 241                   (classoid
 242                    (error 'simple-type-error
 243                           :datum thing
 244                           :expected-type 'condition-class
 245                           :format-control "~S is not a condition class."
 246                           :format-arguments (list thing)))
 247                   (t
 248                    (error 'simple-type-error
 249                           :datum thing
 250                           :expected-type 'condition-class
 251                           :format-control "bad thing for class argument:~%  ~S"
 252                           :format-arguments (list thing)))))
 253          (res (make-condition-object args)))
 254     (setf (%instance-layout res) (classoid-layout class))
 255     ;; Set any class slots with initargs present in this call.
 256     (dolist (cslot (condition-classoid-class-slots class))
 257       (dolist (initarg (condition-slot-initargs cslot))
 258         (let ((val (getf args initarg *empty-condition-slot*)))
 259           (unless (eq val *empty-condition-slot*)
 260             (setf (car (condition-slot-cell cslot)) val)))))
 261     ;; Default any slots with non-constant defaults now.
 262     (dolist (hslot (condition-classoid-hairy-slots class))
 263       (when (dolist (initarg (condition-slot-initargs hslot) t)
 264               (unless (eq (getf args initarg *empty-condition-slot*)
 265                           *empty-condition-slot*)
 266                 (return nil)))
 267         (setf (getf (condition-assigned-slots res) (condition-slot-name hslot))
 268               (find-slot-default class hslot))))
 269
 270     res))
 271 \f
 272 ;;;; DEFINE-CONDITION
 273
 274 (eval-when (:compile-toplevel :load-toplevel :execute)
 275 (defun %compiler-define-condition (name direct-supers layout)
 276   (multiple-value-bind (class old-layout)
 277       (insured-find-classoid name
 278                              #'condition-classoid-p
 279                              #'make-condition-classoid)
 280     (setf (layout-classoid layout) class)
 281     (setf (classoid-direct-superclasses class)
 282           (mapcar #'find-classoid direct-supers))
 283     (cond ((not old-layout)
 284            (register-layout layout))
 285           ((not *type-system-initialized*)
 286            (setf (layout-classoid old-layout) class)
 287            (setq layout old-layout)
 288            (unless (eq (classoid-layout class) layout)
 289              (register-layout layout)))
 290           ((redefine-layout-warning "current"
 291                                     old-layout
 292                                     "new"
 293                                     (layout-length layout)
 294                                     (layout-inherits layout)
 295                                     (layout-depthoid layout))
 296            (register-layout layout :invalidate t))
 297           ((not (classoid-layout class))
 298            (register-layout layout)))
 299
 300     (setf (layout-info layout)
 301           (locally
 302             ;; KLUDGE: There's a FIND-CLASS DEFTRANSFORM for constant class
 303             ;; names which creates fast but non-cold-loadable, non-compact
 304             ;; code. In this context, we'd rather have compact, cold-loadable
 305             ;; code. -- WHN 19990928
 306             (declare (notinline find-classoid))
 307             (layout-info (classoid-layout (find-classoid 'condition)))))
 308
 309     (setf (find-classoid name) class)
 310
 311     ;; Initialize CPL slot.
 312     (setf (condition-classoid-cpl class)
 313           (remove-if-not #'condition-classoid-p
 314                          (std-compute-class-precedence-list class))))
 315   (values))
 316
 317 ) ; EVAL-WHEN
 318
 319 ;;; Compute the effective slots of CLASS, copying inherited slots and
 320 ;;; destructively modifying direct slots.
 321 ;;;
 322 ;;; FIXME: It'd be nice to explain why it's OK to destructively modify
 323 ;;; direct slots. Presumably it follows from the semantics of
 324 ;;; inheritance and redefinition of conditions, but finding the cite
 325 ;;; and documenting it here would be good. (Or, if this is not in fact
 326 ;;; ANSI-compliant, fixing it would also be good.:-)
 327 (defun compute-effective-slots (class)
 328   (collect ((res (copy-list (condition-classoid-slots class))))
 329     (dolist (sclass (cdr (condition-classoid-cpl class)))
 330       (dolist (sslot (condition-classoid-slots sclass))
 331         (let ((found (find (condition-slot-name sslot) (res)
 332                            :key #'condition-slot-name)))
 333           (cond (found
 334                  (setf (condition-slot-initargs found)
 335                        (union (condition-slot-initargs found)
 336                               (condition-slot-initargs sslot)))
 337                  (unless (condition-slot-initform-p found)
 338                    (setf (condition-slot-initform-p found)
 339                          (condition-slot-initform-p sslot))
 340                    (setf (condition-slot-initform found)
 341                          (condition-slot-initform sslot)))
 342                  (unless (condition-slot-allocation found)
 343                    (setf (condition-slot-allocation found)
 344                          (condition-slot-allocation sslot))))
 345                 (t
 346                  (res (copy-structure sslot)))))))
 347     (res)))
 348
 349 ;;; Early definitions of slot accessor creators.
 350 ;;;
 351 ;;; Slot accessors must be generic functions, but ANSI does not seem
 352 ;;; to specify any of them, and we cannot support it before end of
 353 ;;; warm init. So we use ordinary functions inside SBCL, and switch to
 354 ;;; GFs only at the end of building.
 355 (declaim (notinline install-condition-slot-reader
 356                     install-condition-slot-writer))
 357 (defun install-condition-slot-reader (name condition slot-name)
 358   (declare (ignore condition))
 359   (setf (fdefinition name)
 360         (lambda (condition)
 361           (condition-reader-function condition slot-name))))
 362 (defun install-condition-slot-writer (name condition slot-name)
 363   (declare (ignore condition))
 364   (setf (fdefinition name)
 365         (lambda (new-value condition)
 366           (condition-writer-function condition new-value slot-name))))
 367
 368 (defun %define-condition (name slots documentation report default-initargs)
 369   (let ((class (find-classoid name)))
 370     (setf (condition-classoid-slots class) slots)
 371     (setf (condition-classoid-report class) report)
 372     (setf (condition-classoid-default-initargs class) default-initargs)
 373     (setf (fdocumentation name 'type) documentation)
 374
 375     (dolist (slot slots)
 376
 377       ;; Set up reader and writer functions.
 378       (let ((slot-name (condition-slot-name slot)))
 379         (dolist (reader (condition-slot-readers slot))
 380           (install-condition-slot-reader reader name slot-name))
 381         (dolist (writer (condition-slot-writers slot))
 382           (install-condition-slot-writer writer name slot-name))))
 383
 384     ;; Compute effective slots and set up the class and hairy slots
 385     ;; (subsets of the effective slots.)
 386     (let ((eslots (compute-effective-slots class))
 387           (e-def-initargs
 388            (reduce #'append
 389                    (mapcar #'condition-classoid-default-initargs
 390                            (condition-classoid-cpl class)))))
 391       (dolist (slot eslots)
 392         (ecase (condition-slot-allocation slot)
 393           (:class
 394            (unless (condition-slot-cell slot)
 395              (setf (condition-slot-cell slot)
 396                    (list (if (condition-slot-initform-p slot)
 397                              (let ((initform (condition-slot-initform slot)))
 398                                (if (functionp initform)
 399                                    (funcall initform)
 400                                    initform))
 401                              *empty-condition-slot*))))
 402            (push slot (condition-classoid-class-slots class)))
 403           ((:instance nil)
 404            (setf (condition-slot-allocation slot) :instance)
 405            (when (or (functionp (condition-slot-initform slot))
 406                      (dolist (initarg (condition-slot-initargs slot) nil)
 407                        (when (functionp (getf e-def-initargs initarg))
 408                          (return t))))
 409              (push slot (condition-classoid-hairy-slots class))))))))
 410   name)
 411
 412 (defmacro define-condition (name (&rest parent-types) (&rest slot-specs)
 413                                  &body options)
 414   #!+sb-doc
 415   "DEFINE-CONDITION Name (Parent-Type*) (Slot-Spec*) Option*
 416    Define NAME as a condition type. This new type inherits slots and its
 417    report function from the specified PARENT-TYPEs. A slot spec is a list of:
 418      (slot-name :reader <rname> :initarg <iname> {Option Value}*
 419
 420    The DEFINE-CLASS slot options :ALLOCATION, :INITFORM, [slot] :DOCUMENTATION
 421    and :TYPE and the overall options :DEFAULT-INITARGS and
 422    [type] :DOCUMENTATION are also allowed.
 423
 424    The :REPORT option is peculiar to DEFINE-CONDITION. Its argument is either
 425    a string or a two-argument lambda or function name. If a function, the
 426    function is called with the condition and stream to report the condition.
 427    If a string, the string is printed.
 428
 429    Condition types are classes, but (as allowed by ANSI and not as described in
 430    CLtL2) are neither STANDARD-OBJECTs nor STRUCTURE-OBJECTs. WITH-SLOTS and
 431    SLOT-VALUE may not be used on condition objects."
 432   (let* ((parent-types (or parent-types '(condition)))
 433          (layout (find-condition-layout name parent-types))
 434          (documentation nil)
 435          (report nil)
 436          (default-initargs ()))
 437     (collect ((slots)
 438               (all-readers nil append)
 439               (all-writers nil append))
 440       (dolist (spec slot-specs)
 441         (when (keywordp spec)
 442           (warn "Keyword slot name indicates probable syntax error:~%  ~S"
 443                 spec))
 444         (let* ((spec (if (consp spec) spec (list spec)))
 445                (slot-name (first spec))
 446                (allocation :instance)
 447                (initform-p nil)
 448                documentation
 449                initform)
 450           (collect ((initargs)
 451                     (readers)
 452                     (writers))
 453             (do ((options (rest spec) (cddr options)))
 454                 ((null options))
 455               (unless (and (consp options) (consp (cdr options)))
 456                 (error "malformed condition slot spec:~%  ~S." spec))
 457               (let ((arg (second options)))
 458                 (case (first options)
 459                   (:reader (readers arg))
 460                   (:writer (writers arg))
 461                   (:accessor
 462                    (readers arg)
 463                    (writers `(setf ,arg)))
 464                   (:initform
 465                    (when initform-p
 466                      (error "more than one :INITFORM in ~S" spec))
 467                    (setq initform-p t)
 468                    (setq initform arg))
 469                   (:initarg (initargs arg))
 470                   (:allocation
 471                    (setq allocation arg))
 472                   (:documentation
 473                    (when documentation
 474                      (error "more than one :DOCUMENTATION in ~S" spec))
 475                    (unless (stringp arg)
 476                      (error "slot :DOCUMENTATION argument is not a string: ~S"
 477                             arg))
 478                    (setq documentation arg))
 479                   (:type)
 480                   (t
 481                    (error "unknown slot option:~%  ~S" (first options))))))
 482
 483             (all-readers (readers))
 484             (all-writers (writers))
 485             (slots `(make-condition-slot
 486                      :name ',slot-name
 487                      :initargs ',(initargs)
 488                      :readers ',(readers)
 489                      :writers ',(writers)
 490                      :initform-p ',initform-p
 491                      :documentation ',documentation
 492                      :initform
 493                      ,(if (constantp initform)
 494                           `',(eval initform)
 495                           `#'(lambda () ,initform)))))))
 496
 497       (dolist (option options)
 498         (unless (consp option)
 499           (error "bad option:~%  ~S" option))
 500         (case (first option)
 501           (:documentation (setq documentation (second option)))
 502           (:report
 503            (let ((arg (second option)))
 504              (setq report
 505                    (if (stringp arg)
 506                        `#'(lambda (condition stream)
 507                           (declare (ignore condition))
 508                           (write-string ,arg stream))
 509                        `#'(lambda (condition stream)
 510                           (funcall #',arg condition stream))))))
 511           (:default-initargs
 512            (do ((initargs (rest option) (cddr initargs)))
 513                ((endp initargs))
 514              (let ((val (second initargs)))
 515                (setq default-initargs
 516                      (list* `',(first initargs)
 517                             (if (constantp val)
 518                                 `',(eval val)
 519                                 `#'(lambda () ,val))
 520                             default-initargs)))))
 521           (t
 522            (error "unknown option: ~S" (first option)))))
 523
 524       `(progn
 525          (eval-when (:compile-toplevel :load-toplevel :execute)
 526            (%compiler-define-condition ',name ',parent-types ',layout))
 527
 528          (declaim (ftype (function (t) t) ,@(all-readers)))
 529          (declaim (ftype (function (t t) t) ,@(all-writers)))
 530
 531          (%define-condition ',name
 532                             (list ,@(slots))
 533                             ,documentation
 534                             ,report
 535                             (list ,@default-initargs))))))
 536 \f
 537 ;;;; DESCRIBE on CONDITIONs
 538
 539 ;;; a function to be used as the guts of DESCRIBE-OBJECT (CONDITION T)
 540 ;;; eventually (once we get CLOS up and running so that we can define
 541 ;;; methods)
 542 (defun describe-condition (condition stream)
 543   (format stream
 544           "~&~@<~S ~_is a ~S. ~_Its slot values are ~_~S.~:>~%"
 545           condition
 546           (type-of condition)
 547           (concatenate 'list
 548                        (condition-actual-initargs condition)
 549                        (condition-assigned-slots condition))))
 550 \f
 551 ;;;; various CONDITIONs specified by ANSI
 552
 553 (define-condition serious-condition (condition) ())
 554
 555 (define-condition error (serious-condition) ())
 556
 557 (define-condition warning (condition) ())
 558 (define-condition style-warning (warning) ())
 559
 560 (defun simple-condition-printer (condition stream)
 561   (apply #'format
 562          stream
 563          (simple-condition-format-control condition)
 564          (simple-condition-format-arguments condition)))
 565
 566 (define-condition simple-condition ()
 567   ((format-control :reader simple-condition-format-control
 568                    :initarg :format-control)
 569    (format-arguments :reader simple-condition-format-arguments
 570                      :initarg :format-arguments
 571                      :initform '()))
 572   (:report simple-condition-printer))
 573
 574 (define-condition simple-warning (simple-condition warning) ())
 575
 576 (define-condition simple-error (simple-condition error) ())
 577
 578 (define-condition storage-condition (serious-condition) ())
 579
 580 (define-condition type-error (error)
 581   ((datum :reader type-error-datum :initarg :datum)
 582    (expected-type :reader type-error-expected-type :initarg :expected-type))
 583   (:report
 584    (lambda (condition stream)
 585      (format stream
 586              "~@<The value ~2I~:_~S ~I~_is not of type ~2I~_~S.~:>"
 587              (type-error-datum condition)
 588              (type-error-expected-type condition)))))
 589
 590 (define-condition simple-type-error (simple-condition type-error) ())
 591
 592 (define-condition program-error (error) ())
 593 (define-condition parse-error   (error) ())
 594 (define-condition control-error (error) ())
 595 (define-condition stream-error  (error)
 596   ((stream :reader stream-error-stream :initarg :stream)))
 597
 598 (define-condition end-of-file (stream-error) ()
 599   (:report
 600    (lambda (condition stream)
 601      (format stream
 602              "end of file on ~S"
 603              (stream-error-stream condition)))))
 604
 605 (define-condition file-error (error)
 606   ((pathname :reader file-error-pathname :initarg :pathname))
 607   (:report
 608    (lambda (condition stream)
 609      (format stream "error on file ~S" (file-error-pathname condition)))))
 610
 611 (define-condition package-error (error)
 612   ((package :reader package-error-package :initarg :package)))
 613
 614 (define-condition cell-error (error)
 615   ((name :reader cell-error-name :initarg :name)))
 616
 617 (define-condition unbound-variable (cell-error) ()
 618   (:report
 619    (lambda (condition stream)
 620      (format stream
 621              "The variable ~S is unbound."
 622              (cell-error-name condition)))))
 623
 624 (define-condition undefined-function (cell-error) ()
 625   (:report
 626    (lambda (condition stream)
 627      (format stream
 628              "The function ~S is undefined."
 629              (cell-error-name condition)))))
 630
 631 (define-condition special-form-function (undefined-function) ()
 632   (:report
 633    (lambda (condition stream)
 634      (format stream
 635              "Cannot FUNCALL the SYMBOL-FUNCTION of special operator ~S."
 636              (cell-error-name condition)))))
 637
 638 (define-condition arithmetic-error (error)
 639   ((operation :reader arithmetic-error-operation
 640               :initarg :operation
 641               :initform nil)
 642    (operands :reader arithmetic-error-operands
 643              :initarg :operands))
 644   (:report (lambda (condition stream)
 645              (format stream
 646                      "arithmetic error ~S signalled"
 647                      (type-of condition))
 648              (when (arithmetic-error-operation condition)
 649                (format stream
 650                        "~%Operation was ~S, operands ~S."
 651                        (arithmetic-error-operation condition)
 652                        (arithmetic-error-operands condition))))))
 653
 654 (define-condition division-by-zero         (arithmetic-error) ())
 655 (define-condition floating-point-overflow  (arithmetic-error) ())
 656 (define-condition floating-point-underflow (arithmetic-error) ())
 657 (define-condition floating-point-inexact   (arithmetic-error) ())
 658 (define-condition floating-point-invalid-operation (arithmetic-error) ())
 659
 660 (define-condition print-not-readable (error)
 661   ((object :reader print-not-readable-object :initarg :object))
 662   (:report
 663    (lambda (condition stream)
 664      (let ((obj (print-not-readable-object condition))
 665            (*print-array* nil))
 666        (format stream "~S cannot be printed readably." obj)))))
 667
 668 (define-condition reader-error (parse-error stream-error)
 669   ((format-control
 670     :reader reader-error-format-control
 671     :initarg :format-control)
 672    (format-arguments
 673     :reader reader-error-format-arguments
 674     :initarg :format-arguments
 675     :initform '()))
 676   (:report
 677    (lambda (condition stream)
 678      (let ((error-stream (stream-error-stream condition)))
 679        (format stream "READER-ERROR ~@[at ~W ~]on ~S:~%~?"
 680                (file-position error-stream) error-stream
 681                (reader-error-format-control condition)
 682                (reader-error-format-arguments condition))))))
 683 \f
 684 ;;;; various other (not specified by ANSI) CONDITIONs
 685 ;;;;
 686 ;;;; These might logically belong in other files; they're here, after
 687 ;;;; setup of CONDITION machinery, only because that makes it easier to
 688 ;;;; get cold init to work.
 689
 690 (define-condition values-type-error (type-error)
 691   ()
 692   (:report
 693    (lambda (condition stream)
 694      (format stream
 695              "~@<The values set ~2I~:_[~{~S~^ ~}] ~I~_is not of type ~2I~_~S.~:>"
 696              (type-error-datum condition)
 697              (type-error-expected-type condition)))))
 698
 699 ;;; KLUDGE: a condition for floating point errors when we can't or
 700 ;;; won't figure out what type they are. (In FreeBSD and OpenBSD we
 701 ;;; don't know how, at least as of sbcl-0.6.7; in Linux we probably
 702 ;;; know how but the old code was broken by the conversion to POSIX
 703 ;;; signal handling and hasn't been fixed as of sbcl-0.6.7.)
 704 ;;;
 705 ;;; FIXME: Perhaps this should also be a base class for all
 706 ;;; floating point exceptions?
 707 (define-condition floating-point-exception (arithmetic-error)
 708   ((flags :initarg :traps
 709           :initform nil
 710           :reader floating-point-exception-traps))
 711   (:report (lambda (condition stream)
 712              (format stream
 713                      "An arithmetic error ~S was signalled.~%"
 714                      (type-of condition))
 715              (let ((traps (floating-point-exception-traps condition)))
 716                (if traps
 717                    (format stream
 718                            "Trapping conditions are: ~%~{ ~S~^~}~%"
 719                            traps)
 720                    (write-line
 721                     "No traps are enabled? How can this be?"
 722                     stream))))))
 723
 724 (define-condition index-too-large-error (type-error)
 725   ()
 726   (:report
 727    (lambda (condition stream)
 728      (format stream
 729              "The index ~S is too large."
 730              (type-error-datum condition)))))
 731
 732 (define-condition bounding-indices-bad-error (type-error)
 733   ((object :reader bounding-indices-bad-object :initarg :object))
 734   (:report
 735    (lambda (condition stream)
 736      (let* ((datum (type-error-datum condition))
 737             (start (car datum))
 738             (end (cdr datum))
 739             (object (bounding-indices-bad-object condition)))
 740        (etypecase object
 741          (sequence
 742           (format stream
 743                   "The bounding indices ~S and ~S are bad for a sequence of length ~S."
 744                   start end (length object)))
 745          (array
 746           ;; from WITH-ARRAY-DATA
 747           (format stream
 748                   "The START and END parameters ~S and ~S are bad for an array of total size ~S."
 749                   start end (array-total-size object))))))))
 750
 751 (define-condition nil-array-accessed-error (type-error)
 752   ()
 753   (:report (lambda (condition stream)
 754              (format stream
 755                      "An attempt to access an array of element-type ~
 756                       NIL was made.  Congratulations!"))))
 757
 758 (define-condition io-timeout (stream-error)
 759   ((direction :reader io-timeout-direction :initarg :direction))
 760   (:report
 761    (lambda (condition stream)
 762      (declare (type stream stream))
 763      (format stream
 764              "I/O timeout ~(~A~)ing ~S"
 765              (io-timeout-direction condition)
 766              (stream-error-stream condition)))))
 767
 768 (define-condition namestring-parse-error (parse-error)
 769   ((complaint :reader namestring-parse-error-complaint :initarg :complaint)
 770    (args :reader namestring-parse-error-args :initarg :args :initform nil)
 771    (namestring :reader namestring-parse-error-namestring :initarg :namestring)
 772    (offset :reader namestring-parse-error-offset :initarg :offset))
 773   (:report
 774    (lambda (condition stream)
 775      (format stream
 776              "parse error in namestring: ~?~%  ~A~%  ~V@T^"
 777              (namestring-parse-error-complaint condition)
 778              (namestring-parse-error-args condition)
 779              (namestring-parse-error-namestring condition)
 780              (namestring-parse-error-offset condition)))))
 781
 782 (define-condition simple-package-error (simple-condition package-error) ())
 783
 784 (define-condition reader-package-error (reader-error) ())
 785
 786 (define-condition reader-eof-error (end-of-file)
 787   ((context :reader reader-eof-error-context :initarg :context))
 788   (:report
 789    (lambda (condition stream)
 790      (format stream
 791              "unexpected end of file on ~S ~A"
 792              (stream-error-stream condition)
 793              (reader-eof-error-context condition)))))
 794
 795 (define-condition reader-impossible-number-error (reader-error)
 796   ((error :reader reader-impossible-number-error-error :initarg :error))
 797   (:report
 798    (lambda (condition stream)
 799      (let ((error-stream (stream-error-stream condition)))
 800        (format stream "READER-ERROR ~@[at ~W ~]on ~S:~%~?~%Original error: ~A"
 801                (file-position error-stream) error-stream
 802                (reader-error-format-control condition)
 803                (reader-error-format-arguments condition)
 804                (reader-impossible-number-error-error condition))))))
 805
 806 (define-condition sb!ext::timeout (serious-condition) ())
 807
 808 (define-condition defconstant-uneql (error)
 809   ((name :initarg :name :reader defconstant-uneql-name)
 810    (old-value :initarg :old-value :reader defconstant-uneql-old-value)
 811    (new-value :initarg :new-value :reader defconstant-uneql-new-value))
 812   (:report
 813    (lambda (condition stream)
 814      (format stream
 815              "~@<The constant ~S is being redefined (from ~S to ~S)~@:>"
 816              (defconstant-uneql-name condition)
 817              (defconstant-uneql-old-value condition)
 818              (defconstant-uneql-new-value condition)))))
 819 \f
 820 ;;;; special SBCL extension conditions
 821
 822 ;;; an error apparently caused by a bug in SBCL itself
 823 ;;;
 824 ;;; Note that we don't make any serious effort to use this condition
 825 ;;; for *all* errors in SBCL itself. E.g. type errors and array
 826 ;;; indexing errors can occur in functions called from SBCL code, and
 827 ;;; will just end up as ordinary TYPE-ERROR or invalid index error,
 828 ;;; because the signalling code has no good way to know that the
 829 ;;; underlying problem is a bug in SBCL. But in the fairly common case
 830 ;;; that the signalling code does know that it's found a bug in SBCL,
 831 ;;; this condition is appropriate, reusing boilerplate and helping
 832 ;;; users to recognize it as an SBCL bug.
 833 (define-condition bug (simple-error)
 834   ()
 835   (:report
 836    (lambda (condition stream)
 837      (format stream
 838              "~@<  ~? ~:@_~?~:>"
 839              (simple-condition-format-control condition)
 840              (simple-condition-format-arguments condition)
 841              "~@<This is probably a bug in SBCL itself. (Alternatively, ~
 842               SBCL might have been corrupted by bad user code, e.g. by an ~
 843               undefined Lisp operation like ~S, or by stray pointers from ~
 844               alien code or from unsafe Lisp code; or there might be a bug ~
 845               in the OS or hardware that SBCL is running on.) If it seems to ~
 846               be a bug in SBCL itself, the maintainers would like to know ~
 847               about it. Bug reports are welcome on the SBCL ~
 848               mailing lists, which you can find at ~
 849               <http://sbcl.sourceforge.net/>.~:@>"
 850              '((fmakunbound 'compile))))))
 851 (defun bug (format-control &rest format-arguments)
 852   (error 'bug
 853          :format-control format-control
 854          :format-arguments format-arguments))
 855
 856 ;;; a condition for use in stubs for operations which aren't supported
 857 ;;; on some platforms
 858 ;;;
 859 ;;; E.g. in sbcl-0.7.0.5, it might be appropriate to do something like
 860 ;;;   #-(or freebsd linux)
 861 ;;;   (defun load-foreign (&rest rest)
 862 ;;;     (error 'unsupported-operator :name 'load-foreign))
 863 ;;;   #+(or freebsd linux)
 864 ;;;   (defun load-foreign ... actual definition ...)
 865 ;;; By signalling a standard condition in this case, we make it
 866 ;;; possible for test code to distinguish between (1) intentionally
 867 ;;; unimplemented and (2) unintentionally just screwed up somehow.
 868 ;;; (Before this condition was defined, test code tried to deal with
 869 ;;; this by checking for FBOUNDP, but that didn't work reliably. In
 870 ;;; sbcl-0.7.0, a a package screwup left the definition of
 871 ;;; LOAD-FOREIGN in the wrong package, so it was unFBOUNDP even on
 872 ;;; architectures where it was supposed to be supported, and the
 873 ;;; regression tests cheerfully passed because they assumed that
 874 ;;; unFBOUNDPness meant they were running on an system which didn't
 875 ;;; support the extension.)
 876 (define-condition unsupported-operator (cell-error) ()
 877   (:report
 878    (lambda (condition stream)
 879      (format stream
 880              "unsupported on this platform (OS, CPU, whatever): ~S"
 881              (cell-error-name condition)))))
 882 \f
 883 ;;;; restart definitions
 884
 885 (define-condition abort-failure (control-error) ()
 886   (:report
 887    "An ABORT restart was found that failed to transfer control dynamically."))
 888
 889 (defun abort (&optional condition)
 890   #!+sb-doc
 891   "Transfer control to a restart named ABORT, signalling a CONTROL-ERROR if
 892    none exists."
 893   (invoke-restart (find-restart-or-control-error 'abort condition))
 894   ;; ABORT signals an error in case there was a restart named ABORT
 895   ;; that did not transfer control dynamically. This could happen with
 896   ;; RESTART-BIND.
 897   (error 'abort-failure))
 898
 899 (defun muffle-warning (&optional condition)
 900   #!+sb-doc
 901   "Transfer control to a restart named MUFFLE-WARNING, signalling a
 902    CONTROL-ERROR if none exists."
 903   (invoke-restart (find-restart-or-control-error 'muffle-warning condition)))
 904
 905 (macrolet ((define-nil-returning-restart (name args doc)
 906              #!-sb-doc (declare (ignore doc))
 907              `(defun ,name (,@args &optional condition)
 908                 #!+sb-doc ,doc
 909                 ;; FIXME: Perhaps this shared logic should be pulled out into
 910                 ;; FLET MAYBE-INVOKE-RESTART? See whether it shrinks code..
 911                 (let ((restart (find-restart ',name condition)))
 912                   (when restart
 913                     (invoke-restart restart ,@args))))))
 914   (define-nil-returning-restart continue ()
 915     "Transfer control to a restart named CONTINUE, or return NIL if none exists.")
 916   (define-nil-returning-restart store-value (value)
 917     "Transfer control and VALUE to a restart named STORE-VALUE, or return NIL if
 918    none exists.")
 919   (define-nil-returning-restart use-value (value)
 920     "Transfer control and VALUE to a restart named USE-VALUE, or return NIL if
 921    none exists."))
 922
 923 (/show0 "condition.lisp end of file")
 924