src/code/condition.lisp

   1 ;;;; stuff originally from CMU CL's error.lisp which can or should
   2 ;;;; come late (mostly related to the CONDITION class itself)
   3 ;;;;
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!KERNEL")
  15 \f
  16 ;;;; miscellaneous support utilities
  17
  18 ;;; Signalling an error when trying to print an error condition is
  19 ;;; generally a PITA, so whatever the failure encountered when
  20 ;;; wondering about FILE-POSITION within a condition printer, 'tis
  21 ;;; better silently to give up than to try to complain.
  22 (defun file-position-or-nil-for-error (stream &optional (pos nil posp))
  23   ;; Arguably FILE-POSITION shouldn't be signalling errors at all; but
  24   ;; "NIL if this cannot be determined" in the ANSI spec doesn't seem
  25   ;; absolutely unambiguously to prohibit errors when, e.g., STREAM
  26   ;; has been closed so that FILE-POSITION is a nonsense question. So
  27   ;; my (WHN) impression is that the conservative approach is to
  28   ;; IGNORE-ERRORS. (I encountered this failure from within a homebrew
  29   ;; defsystemish operation where the ERROR-STREAM had been CL:CLOSEd,
  30   ;; I think by nonlocally exiting through a WITH-OPEN-FILE, by the
  31   ;; time an error was reported.)
  32   (if posp
  33       (ignore-errors (file-position stream pos))
  34       (ignore-errors (file-position stream))))
  35 \f
  36 ;;;; the CONDITION class
  37
  38 (/show0 "condition.lisp 20")
  39
  40 (eval-when (:compile-toplevel :load-toplevel :execute)
  41
  42 (/show0 "condition.lisp 24")
  43
  44 (def!struct (condition-classoid (:include classoid)
  45                                 (:constructor make-condition-classoid))
  46   ;; list of CONDITION-SLOT structures for the direct slots of this
  47   ;; class
  48   (slots nil :type list)
  49   ;; list of CONDITION-SLOT structures for all of the effective class
  50   ;; slots of this class
  51   (class-slots nil :type list)
  52   ;; report function or NIL
  53   (report nil :type (or function null))
  54   ;; list of alternating initargs and initforms
  55   (default-initargs () :type list)
  56   ;; class precedence list as a list of CLASS objects, with all
  57   ;; non-CONDITION classes removed
  58   (cpl () :type list)
  59   ;; a list of all the effective instance allocation slots of this
  60   ;; class that have a non-constant initform or default-initarg.
  61   ;; Values for these slots must be computed in the dynamic
  62   ;; environment of MAKE-CONDITION.
  63   (hairy-slots nil :type list))
  64
  65 (/show0 "condition.lisp 49")
  66
  67 ) ; EVAL-WHEN
  68
  69 (!defstruct-with-alternate-metaclass condition
  70   :slot-names (actual-initargs assigned-slots)
  71   :boa-constructor %make-condition-object
  72   :superclass-name t
  73   :metaclass-name condition-classoid
  74   :metaclass-constructor make-condition-classoid
  75   :dd-type structure)
  76
  77 (defun make-condition-object (actual-initargs)
  78   (%make-condition-object actual-initargs nil))
  79
  80 (defstruct (condition-slot (:copier nil))
  81   (name (missing-arg) :type symbol)
  82   ;; list of all applicable initargs
  83   (initargs (missing-arg) :type list)
  84   ;; names of reader and writer functions
  85   (readers (missing-arg) :type list)
  86   (writers (missing-arg) :type list)
  87   ;; true if :INITFORM was specified
  88   (initform-p (missing-arg) :type (member t nil))
  89   ;; If this is a function, call it with no args. Otherwise, it's the
  90   ;; actual value.
  91   (initform (missing-arg) :type t)
  92   ;; allocation of this slot, or NIL until defaulted
  93   (allocation nil :type (member :instance :class nil))
  94   ;; If ALLOCATION is :CLASS, this is a cons whose car holds the value.
  95   (cell nil :type (or cons null))
  96   ;; slot documentation
  97   (documentation nil :type (or string null)))
  98
  99 ;;; KLUDGE: It's not clear to me why CONDITION-CLASS has itself listed
 100 ;;; in its CPL, while other classes derived from CONDITION-CLASS don't
 101 ;;; have themselves listed in their CPLs. This behavior is inherited
 102 ;;; from CMU CL, and didn't seem to be explained there, and I haven't
 103 ;;; figured out whether it's right. -- WHN 19990612
 104 (eval-when (:compile-toplevel :load-toplevel :execute)
 105   (/show0 "condition.lisp 103")
 106   (let ((condition-class (locally
 107                            ;; KLUDGE: There's a DEFTRANSFORM
 108                            ;; FIND-CLASSOID for constant class names
 109                            ;; which creates fast but
 110                            ;; non-cold-loadable, non-compact code. In
 111                            ;; this context, we'd rather have compact,
 112                            ;; cold-loadable code. -- WHN 19990928
 113                            (declare (notinline find-classoid))
 114                            (find-classoid 'condition))))
 115     (setf (condition-classoid-cpl condition-class)
 116           (list condition-class)))
 117   (/show0 "condition.lisp 103"))
 118
 119 (setf (condition-classoid-report (locally
 120                                    ;; KLUDGE: There's a DEFTRANSFORM
 121                                    ;; FIND-CLASSOID for constant class
 122                                    ;; names which creates fast but
 123                                    ;; non-cold-loadable, non-compact
 124                                    ;; code. In this context, we'd
 125                                    ;; rather have compact,
 126                                    ;; cold-loadable code. -- WHN
 127                                    ;; 19990928
 128                                    (declare (notinline find-classoid))
 129                                    (find-classoid 'condition)))
 130       (lambda (cond stream)
 131         (format stream "Condition ~S was signalled." (type-of cond))))
 132
 133 (eval-when (:compile-toplevel :load-toplevel :execute)
 134
 135 (defun find-condition-layout (name parent-types)
 136   (let* ((cpl (remove-duplicates
 137                (reverse
 138                 (reduce #'append
 139                         (mapcar (lambda (x)
 140                                   (condition-classoid-cpl
 141                                    (find-classoid x)))
 142                                 parent-types)))))
 143          (cond-layout (info :type :compiler-layout 'condition))
 144          (olayout (info :type :compiler-layout name))
 145          ;; FIXME: Does this do the right thing in case of multiple
 146          ;; inheritance? A quick look at DEFINE-CONDITION didn't make
 147          ;; it obvious what ANSI intends to be done in the case of
 148          ;; multiple inheritance, so it's not actually clear what the
 149          ;; right thing is..
 150          (new-inherits
 151           (order-layout-inherits (concatenate 'simple-vector
 152                                               (layout-inherits cond-layout)
 153                                               (mapcar #'classoid-layout cpl)))))
 154     (if (and olayout
 155              (not (mismatch (layout-inherits olayout) new-inherits)))
 156         olayout
 157         (make-layout :classoid (make-undefined-classoid name)
 158                      :inherits new-inherits
 159                      :depthoid -1
 160                      :length (layout-length cond-layout)))))
 161
 162 ) ; EVAL-WHEN
 163
 164 ;;; FIXME: ANSI's definition of DEFINE-CONDITION says
 165 ;;;   Condition reporting is mediated through the PRINT-OBJECT method
 166 ;;;   for the condition type in question, with *PRINT-ESCAPE* always
 167 ;;;   being nil. Specifying (:REPORT REPORT-NAME) in the definition of
 168 ;;;   a condition type C is equivalent to:
 169 ;;;     (defmethod print-object ((x c) stream)
 170 ;;;       (if *print-escape* (call-next-method) (report-name x stream)))
 171 ;;; The current code doesn't seem to quite match that.
 172 (def!method print-object ((x condition) stream)
 173   (if *print-escape*
 174       (print-unreadable-object (x stream :type t :identity t))
 175       ;; KLUDGE: A comment from CMU CL here said
 176       ;;   7/13/98 BUG? CPL is not sorted and results here depend on order of
 177       ;;   superclasses in define-condition call!
 178       (dolist (class (condition-classoid-cpl (classoid-of x))
 179                      (error "no REPORT? shouldn't happen!"))
 180         (let ((report (condition-classoid-report class)))
 181           (when report
 182             (return (funcall report x stream)))))))
 183 \f
 184 ;;;; slots of CONDITION objects
 185
 186 (defvar *empty-condition-slot* '(empty))
 187
 188 (defun find-slot-default (class slot)
 189   (let ((initargs (condition-slot-initargs slot))
 190         (cpl (condition-classoid-cpl class)))
 191     (dolist (class cpl)
 192       (let ((default-initargs (condition-classoid-default-initargs class)))
 193         (dolist (initarg initargs)
 194           (let ((val (getf default-initargs initarg *empty-condition-slot*)))
 195             (unless (eq val *empty-condition-slot*)
 196               (return-from find-slot-default
 197                            (if (functionp val)
 198                                (funcall val)
 199                                val)))))))
 200
 201     (if (condition-slot-initform-p slot)
 202         (let ((initform (condition-slot-initform slot)))
 203           (if (functionp initform)
 204               (funcall initform)
 205               initform))
 206         (error "unbound condition slot: ~S" (condition-slot-name slot)))))
 207
 208 (defun find-condition-class-slot (condition-class slot-name)
 209   (dolist (sclass
 210            (condition-classoid-cpl condition-class)
 211            (error "There is no slot named ~S in ~S."
 212                   slot-name condition-class))
 213     (dolist (slot (condition-classoid-slots sclass))
 214       (when (eq (condition-slot-name slot) slot-name)
 215         (return-from find-condition-class-slot slot)))))
 216
 217 (defun condition-writer-function (condition new-value name)
 218   (dolist (cslot (condition-classoid-class-slots
 219                   (layout-classoid (%instance-layout condition)))
 220                  (setf (getf (condition-assigned-slots condition) name)
 221                        new-value))
 222     (when (eq (condition-slot-name cslot) name)
 223       (return (setf (car (condition-slot-cell cslot)) new-value)))))
 224
 225 (defun condition-reader-function (condition name)
 226   (let ((class (layout-classoid (%instance-layout condition))))
 227     (dolist (cslot (condition-classoid-class-slots class))
 228       (when (eq (condition-slot-name cslot) name)
 229         (return-from condition-reader-function
 230                      (car (condition-slot-cell cslot)))))
 231     (let ((val (getf (condition-assigned-slots condition) name
 232                      *empty-condition-slot*)))
 233       (if (eq val *empty-condition-slot*)
 234           (let ((actual-initargs (condition-actual-initargs condition))
 235                 (slot (find-condition-class-slot class name)))
 236             (unless slot
 237               (error "missing slot ~S of ~S" name condition))
 238             (do ((initargs actual-initargs (cddr initargs)))
 239                 ((endp initargs)
 240                  (setf (getf (condition-assigned-slots condition) name)
 241                        (find-slot-default class slot)))
 242               (when (member (car initargs) (condition-slot-initargs slot))
 243                 (return-from condition-reader-function
 244                   (setf (getf (condition-assigned-slots condition)
 245                               name)
 246                         (cadr initargs))))))
 247           val))))
 248 \f
 249 ;;;; MAKE-CONDITION
 250
 251 (defun make-condition (type &rest args)
 252   #!+sb-doc
 253   "Make an instance of a condition object using the specified initargs."
 254   ;; Note: ANSI specifies no exceptional situations in this function.
 255   ;; signalling simple-type-error would not be wrong.
 256   (let* ((type (or (and (symbolp type) (find-classoid type nil))
 257                     type))
 258          (class (typecase type
 259                   (condition-classoid type)
 260                   (class
 261                    ;; Punt to CLOS.
 262                    (return-from make-condition (apply #'make-instance type args)))
 263                   (classoid
 264                    (error 'simple-type-error
 265                           :datum type
 266                           :expected-type 'condition-class
 267                           :format-control "~S is not a condition class."
 268                           :format-arguments (list type)))
 269                   (t
 270                    (error 'simple-type-error
 271                           :datum type
 272                           :expected-type 'condition-class
 273                           :format-control "Bad type argument:~%  ~S"
 274                           :format-arguments (list type)))))
 275          (res (make-condition-object args)))
 276     (setf (%instance-layout res) (classoid-layout class))
 277     ;; Set any class slots with initargs present in this call.
 278     (dolist (cslot (condition-classoid-class-slots class))
 279       (dolist (initarg (condition-slot-initargs cslot))
 280         (let ((val (getf args initarg *empty-condition-slot*)))
 281           (unless (eq val *empty-condition-slot*)
 282             (setf (car (condition-slot-cell cslot)) val)))))
 283     ;; Default any slots with non-constant defaults now.
 284     (dolist (hslot (condition-classoid-hairy-slots class))
 285       (when (dolist (initarg (condition-slot-initargs hslot) t)
 286               (unless (eq (getf args initarg *empty-condition-slot*)
 287                           *empty-condition-slot*)
 288                 (return nil)))
 289         (setf (getf (condition-assigned-slots res) (condition-slot-name hslot))
 290               (find-slot-default class hslot))))
 291     res))
 292 \f
 293 ;;;; DEFINE-CONDITION
 294
 295 (eval-when (:compile-toplevel :load-toplevel :execute)
 296 (defun %compiler-define-condition (name direct-supers layout
 297                                    all-readers all-writers)
 298   (with-single-package-locked-error
 299       (:symbol name "defining ~A as a condition")
 300     (sb!xc:proclaim `(ftype (function (t) t) ,@all-readers))
 301     (sb!xc:proclaim `(ftype (function (t t) t) ,@all-writers))
 302     (multiple-value-bind (class old-layout)
 303         (insured-find-classoid name
 304                                #'condition-classoid-p
 305                                #'make-condition-classoid)
 306       (setf (layout-classoid layout) class)
 307       (setf (classoid-direct-superclasses class)
 308             (mapcar #'find-classoid direct-supers))
 309       (cond ((not old-layout)
 310              (register-layout layout))
 311             ((not *type-system-initialized*)
 312              (setf (layout-classoid old-layout) class)
 313              (setq layout old-layout)
 314              (unless (eq (classoid-layout class) layout)
 315                (register-layout layout)))
 316             ((redefine-layout-warning "current"
 317                                       old-layout
 318                                       "new"
 319                                       (layout-length layout)
 320                                       (layout-inherits layout)
 321                                       (layout-depthoid layout)
 322                                       (layout-n-untagged-slots layout))
 323              (register-layout layout :invalidate t))
 324             ((not (classoid-layout class))
 325              (register-layout layout)))
 326
 327       (setf (layout-info layout)
 328             (locally
 329                 ;; KLUDGE: There's a FIND-CLASS DEFTRANSFORM for constant class
 330                 ;; names which creates fast but non-cold-loadable, non-compact
 331                 ;; code. In this context, we'd rather have compact, cold-loadable
 332                 ;; code. -- WHN 19990928
 333                 (declare (notinline find-classoid))
 334               (layout-info (classoid-layout (find-classoid 'condition)))))
 335
 336       (setf (find-classoid name) class)
 337
 338       ;; Initialize CPL slot.
 339       (setf (condition-classoid-cpl class)
 340             (remove-if-not #'condition-classoid-p
 341                            (std-compute-class-precedence-list class)))))
 342   (values))
 343 ) ; EVAL-WHEN
 344
 345 ;;; Compute the effective slots of CLASS, copying inherited slots and
 346 ;;; destructively modifying direct slots.
 347 ;;;
 348 ;;; FIXME: It'd be nice to explain why it's OK to destructively modify
 349 ;;; direct slots. Presumably it follows from the semantics of
 350 ;;; inheritance and redefinition of conditions, but finding the cite
 351 ;;; and documenting it here would be good. (Or, if this is not in fact
 352 ;;; ANSI-compliant, fixing it would also be good.:-)
 353 (defun compute-effective-slots (class)
 354   (collect ((res (copy-list (condition-classoid-slots class))))
 355     (dolist (sclass (cdr (condition-classoid-cpl class)))
 356       (dolist (sslot (condition-classoid-slots sclass))
 357         (let ((found (find (condition-slot-name sslot) (res)
 358                            :key #'condition-slot-name)))
 359           (cond (found
 360                  (setf (condition-slot-initargs found)
 361                        (union (condition-slot-initargs found)
 362                               (condition-slot-initargs sslot)))
 363                  (unless (condition-slot-initform-p found)
 364                    (setf (condition-slot-initform-p found)
 365                          (condition-slot-initform-p sslot))
 366                    (setf (condition-slot-initform found)
 367                          (condition-slot-initform sslot)))
 368                  (unless (condition-slot-allocation found)
 369                    (setf (condition-slot-allocation found)
 370                          (condition-slot-allocation sslot))))
 371                 (t
 372                  (res (copy-structure sslot)))))))
 373     (res)))
 374
 375 ;;; Early definitions of slot accessor creators.
 376 ;;;
 377 ;;; Slot accessors must be generic functions, but ANSI does not seem
 378 ;;; to specify any of them, and we cannot support it before end of
 379 ;;; warm init. So we use ordinary functions inside SBCL, and switch to
 380 ;;; GFs only at the end of building.
 381 (declaim (notinline install-condition-slot-reader
 382                     install-condition-slot-writer))
 383 (defun install-condition-slot-reader (name condition slot-name)
 384   (declare (ignore condition))
 385   (setf (fdefinition name)
 386         (lambda (condition)
 387           (condition-reader-function condition slot-name))))
 388 (defun install-condition-slot-writer (name condition slot-name)
 389   (declare (ignore condition))
 390   (setf (fdefinition name)
 391         (lambda (new-value condition)
 392           (condition-writer-function condition new-value slot-name))))
 393
 394 (defvar *define-condition-hooks* nil)
 395
 396 (defun %define-condition (name parent-types layout slots documentation
 397                           report default-initargs all-readers all-writers
 398                           source-location)
 399   (with-single-package-locked-error
 400       (:symbol name "defining ~A as a condition")
 401     (%compiler-define-condition name parent-types layout all-readers all-writers)
 402     (sb!c:with-source-location (source-location)
 403       (setf (layout-source-location layout)
 404             source-location))
 405     (let ((class (find-classoid name)))
 406       (setf (condition-classoid-slots class) slots)
 407       (setf (condition-classoid-report class) report)
 408       (setf (condition-classoid-default-initargs class) default-initargs)
 409       (setf (fdocumentation name 'type) documentation)
 410
 411       (dolist (slot slots)
 412
 413         ;; Set up reader and writer functions.
 414         (let ((slot-name (condition-slot-name slot)))
 415           (dolist (reader (condition-slot-readers slot))
 416             (install-condition-slot-reader reader name slot-name))
 417           (dolist (writer (condition-slot-writers slot))
 418             (install-condition-slot-writer writer name slot-name))))
 419
 420       ;; Compute effective slots and set up the class and hairy slots
 421       ;; (subsets of the effective slots.)
 422       (let ((eslots (compute-effective-slots class))
 423             (e-def-initargs
 424              (reduce #'append
 425                      (mapcar #'condition-classoid-default-initargs
 426                            (condition-classoid-cpl class)))))
 427         (dolist (slot eslots)
 428           (ecase (condition-slot-allocation slot)
 429             (:class
 430              (unless (condition-slot-cell slot)
 431                (setf (condition-slot-cell slot)
 432                      (list (if (condition-slot-initform-p slot)
 433                                (let ((initform (condition-slot-initform slot)))
 434                                  (if (functionp initform)
 435                                      (funcall initform)
 436                                      initform))
 437                                *empty-condition-slot*))))
 438              (push slot (condition-classoid-class-slots class)))
 439             ((:instance nil)
 440              (setf (condition-slot-allocation slot) :instance)
 441              (when (or (functionp (condition-slot-initform slot))
 442                        (dolist (initarg (condition-slot-initargs slot) nil)
 443                          (when (functionp (getf e-def-initargs initarg))
 444                            (return t))))
 445                (push slot (condition-classoid-hairy-slots class)))))))
 446       (when (boundp '*define-condition-hooks*)
 447         (dolist (fun *define-condition-hooks*)
 448           (funcall fun class))))
 449     name))
 450
 451 (defmacro define-condition (name (&rest parent-types) (&rest slot-specs)
 452                                  &body options)
 453   #!+sb-doc
 454   "DEFINE-CONDITION Name (Parent-Type*) (Slot-Spec*) Option*
 455    Define NAME as a condition type. This new type inherits slots and its
 456    report function from the specified PARENT-TYPEs. A slot spec is a list of:
 457      (slot-name :reader <rname> :initarg <iname> {Option Value}*
 458
 459    The DEFINE-CLASS slot options :ALLOCATION, :INITFORM, [slot] :DOCUMENTATION
 460    and :TYPE and the overall options :DEFAULT-INITARGS and
 461    [type] :DOCUMENTATION are also allowed.
 462
 463    The :REPORT option is peculiar to DEFINE-CONDITION. Its argument is either
 464    a string or a two-argument lambda or function name. If a function, the
 465    function is called with the condition and stream to report the condition.
 466    If a string, the string is printed.
 467
 468    Condition types are classes, but (as allowed by ANSI and not as described in
 469    CLtL2) are neither STANDARD-OBJECTs nor STRUCTURE-OBJECTs. WITH-SLOTS and
 470    SLOT-VALUE may not be used on condition objects."
 471   (let* ((parent-types (or parent-types '(condition)))
 472          (layout (find-condition-layout name parent-types))
 473          (documentation nil)
 474          (report nil)
 475          (default-initargs ()))
 476     (collect ((slots)
 477               (all-readers nil append)
 478               (all-writers nil append))
 479       (dolist (spec slot-specs)
 480         (when (keywordp spec)
 481           (warn "Keyword slot name indicates probable syntax error:~%  ~S"
 482                 spec))
 483         (let* ((spec (if (consp spec) spec (list spec)))
 484                (slot-name (first spec))
 485                (allocation :instance)
 486                (initform-p nil)
 487                documentation
 488                initform)
 489           (collect ((initargs)
 490                     (readers)
 491                     (writers))
 492             (do ((options (rest spec) (cddr options)))
 493                 ((null options))
 494               (unless (and (consp options) (consp (cdr options)))
 495                 (error "malformed condition slot spec:~%  ~S." spec))
 496               (let ((arg (second options)))
 497                 (case (first options)
 498                   (:reader (readers arg))
 499                   (:writer (writers arg))
 500                   (:accessor
 501                    (readers arg)
 502                    (writers `(setf ,arg)))
 503                   (:initform
 504                    (when initform-p
 505                      (error "more than one :INITFORM in ~S" spec))
 506                    (setq initform-p t)
 507                    (setq initform arg))
 508                   (:initarg (initargs arg))
 509                   (:allocation
 510                    (setq allocation arg))
 511                   (:documentation
 512                    (when documentation
 513                      (error "more than one :DOCUMENTATION in ~S" spec))
 514                    (unless (stringp arg)
 515                      (error "slot :DOCUMENTATION argument is not a string: ~S"
 516                             arg))
 517                    (setq documentation arg))
 518                   (:type)
 519                   (t
 520                    (error "unknown slot option:~%  ~S" (first options))))))
 521
 522             (all-readers (readers))
 523             (all-writers (writers))
 524             (slots `(make-condition-slot
 525                      :name ',slot-name
 526                      :initargs ',(initargs)
 527                      :readers ',(readers)
 528                      :writers ',(writers)
 529                      :initform-p ',initform-p
 530                      :documentation ',documentation
 531                      :initform
 532                      ,(if (sb!xc:constantp initform)
 533                           `',(constant-form-value initform)
 534                           `#'(lambda () ,initform)))))))
 535
 536       (dolist (option options)
 537         (unless (consp option)
 538           (error "bad option:~%  ~S" option))
 539         (case (first option)
 540           (:documentation (setq documentation (second option)))
 541           (:report
 542            (let ((arg (second option)))
 543              (setq report
 544                    (if (stringp arg)
 545                        `#'(lambda (condition stream)
 546                           (declare (ignore condition))
 547                           (write-string ,arg stream))
 548                        `#'(lambda (condition stream)
 549                           (funcall #',arg condition stream))))))
 550           (:default-initargs
 551            (do ((initargs (rest option) (cddr initargs)))
 552                ((endp initargs))
 553              (let ((val (second initargs)))
 554                (setq default-initargs
 555                      (list* `',(first initargs)
 556                             (if (sb!xc:constantp val)
 557                                 `',(constant-form-value val)
 558                                 `#'(lambda () ,val))
 559                             default-initargs)))))
 560           (t
 561            (error "unknown option: ~S" (first option)))))
 562
 563       `(progn
 564          (eval-when (:compile-toplevel)
 565            (%compiler-define-condition ',name ',parent-types ',layout
 566                                        ',(all-readers) ',(all-writers)))
 567          (eval-when (:load-toplevel :execute)
 568            (%define-condition ',name
 569                               ',parent-types
 570                               ',layout
 571                               (list ,@(slots))
 572                               ,documentation
 573                               ,report
 574                               (list ,@default-initargs)
 575                               ',(all-readers)
 576                               ',(all-writers)
 577                               (sb!c:source-location)))))))
 578 \f
 579 ;;;; DESCRIBE on CONDITIONs
 580
 581 ;;; a function to be used as the guts of DESCRIBE-OBJECT (CONDITION T)
 582 ;;; eventually (once we get CLOS up and running so that we can define
 583 ;;; methods)
 584 (defun describe-condition (condition stream)
 585   (format stream
 586           "~&~@<~S ~_is a ~S. ~_Its slot values are ~_~S.~:>~%"
 587           condition
 588           (type-of condition)
 589           (concatenate 'list
 590                        (condition-actual-initargs condition)
 591                        (condition-assigned-slots condition))))
 592 \f
 593 ;;;; various CONDITIONs specified by ANSI
 594
 595 (define-condition serious-condition (condition) ())
 596
 597 (define-condition error (serious-condition) ())
 598
 599 (define-condition warning (condition) ())
 600 (define-condition style-warning (warning) ())
 601
 602 (defun simple-condition-printer (condition stream)
 603   (apply #'format
 604          stream
 605          (simple-condition-format-control condition)
 606          (simple-condition-format-arguments condition)))
 607
 608 (define-condition simple-condition ()
 609   ((format-control :reader simple-condition-format-control
 610                    :initarg :format-control
 611                    :type format-control)
 612    (format-arguments :reader simple-condition-format-arguments
 613                      :initarg :format-arguments
 614                      :initform '()
 615                      :type list))
 616   (:report simple-condition-printer))
 617
 618 (define-condition simple-warning (simple-condition warning) ())
 619
 620 (define-condition simple-error (simple-condition error) ())
 621
 622 (define-condition storage-condition (serious-condition) ())
 623
 624 (define-condition type-error (error)
 625   ((datum :reader type-error-datum :initarg :datum)
 626    (expected-type :reader type-error-expected-type :initarg :expected-type))
 627   (:report
 628    (lambda (condition stream)
 629      (format stream
 630              "~@<The value ~2I~:_~S ~I~_is not of type ~2I~_~S.~:>"
 631              (type-error-datum condition)
 632              (type-error-expected-type condition)))))
 633
 634 ;;; not specified by ANSI, but too useful not to have around.
 635 (define-condition simple-style-warning (simple-condition style-warning) ())
 636 (define-condition simple-type-error (simple-condition type-error) ())
 637
 638 (define-condition program-error (error) ())
 639 (define-condition parse-error   (error) ())
 640 (define-condition control-error (error) ())
 641 (define-condition stream-error  (error)
 642   ((stream :reader stream-error-stream :initarg :stream)))
 643
 644 (define-condition end-of-file (stream-error) ()
 645   (:report
 646    (lambda (condition stream)
 647      (format stream
 648              "end of file on ~S"
 649              (stream-error-stream condition)))))
 650
 651 (define-condition closed-stream-error (stream-error) ()
 652   (:report
 653    (lambda (condition stream)
 654      (format stream "~S is closed" (stream-error-stream condition)))))
 655
 656 (define-condition file-error (error)
 657   ((pathname :reader file-error-pathname :initarg :pathname))
 658   (:report
 659    (lambda (condition stream)
 660      (format stream "error on file ~S" (file-error-pathname condition)))))
 661
 662 (define-condition package-error (error)
 663   ((package :reader package-error-package :initarg :package)))
 664
 665 (define-condition cell-error (error)
 666   ((name :reader cell-error-name :initarg :name)))
 667
 668 (def!method print-object ((condition cell-error) stream)
 669   (if (and *print-escape* (slot-boundp condition 'name))
 670       (print-unreadable-object (condition stream :type t :identity t)
 671         (princ (cell-error-name condition) stream))
 672       (call-next-method)))
 673
 674 (define-condition unbound-variable (cell-error) ()
 675   (:report
 676    (lambda (condition stream)
 677      (format stream
 678              "The variable ~S is unbound."
 679              (cell-error-name condition)))))
 680
 681 (define-condition undefined-function (cell-error) ()
 682   (:report
 683    (lambda (condition stream)
 684      (format stream
 685              "The function ~S is undefined."
 686              (cell-error-name condition)))))
 687
 688 (define-condition special-form-function (undefined-function) ()
 689   (:report
 690    (lambda (condition stream)
 691      (format stream
 692              "Cannot FUNCALL the SYMBOL-FUNCTION of special operator ~S."
 693              (cell-error-name condition)))))
 694
 695 (define-condition arithmetic-error (error)
 696   ((operation :reader arithmetic-error-operation
 697               :initarg :operation
 698               :initform nil)
 699    (operands :reader arithmetic-error-operands
 700              :initarg :operands))
 701   (:report (lambda (condition stream)
 702              (format stream
 703                      "arithmetic error ~S signalled"
 704                      (type-of condition))
 705              (when (arithmetic-error-operation condition)
 706                (format stream
 707                        "~%Operation was ~S, operands ~S."
 708                        (arithmetic-error-operation condition)
 709                        (arithmetic-error-operands condition))))))
 710
 711 (define-condition division-by-zero         (arithmetic-error) ())
 712 (define-condition floating-point-overflow  (arithmetic-error) ())
 713 (define-condition floating-point-underflow (arithmetic-error) ())
 714 (define-condition floating-point-inexact   (arithmetic-error) ())
 715 (define-condition floating-point-invalid-operation (arithmetic-error) ())
 716
 717 (define-condition print-not-readable (error)
 718   ((object :reader print-not-readable-object :initarg :object))
 719   (:report
 720    (lambda (condition stream)
 721      (let ((obj (print-not-readable-object condition))
 722            (*print-array* nil))
 723        (format stream "~S cannot be printed readably." obj)))))
 724
 725 (define-condition reader-error (parse-error stream-error) ()
 726   (:report (lambda (condition stream)
 727              (%report-reader-error condition stream))))
 728
 729 ;;; a READER-ERROR whose REPORTing is controlled by FORMAT-CONTROL and
 730 ;;; FORMAT-ARGS (the usual case for READER-ERRORs signalled from
 731 ;;; within SBCL itself)
 732 ;;;
 733 ;;; (Inheriting CL:SIMPLE-CONDITION here isn't quite consistent with
 734 ;;; the letter of the ANSI spec: this is not a condition signalled by
 735 ;;; SIGNAL when a format-control is supplied by the function's first
 736 ;;; argument. It seems to me (WHN) to be basically in the spirit of
 737 ;;; the spec, but if not, it'd be straightforward to do our own
 738 ;;; DEFINE-CONDITION SB-INT:SIMPLISTIC-CONDITION with
 739 ;;; FORMAT-CONTROL and FORMAT-ARGS slots, and use that condition in
 740 ;;; place of CL:SIMPLE-CONDITION here.)
 741 (define-condition simple-reader-error (reader-error simple-condition)
 742   ()
 743   (:report (lambda (condition stream)
 744              (%report-reader-error condition stream :simple t))))
 745
 746 ;;; base REPORTing of a READER-ERROR
 747 ;;;
 748 ;;; When SIMPLE, we expect and use SIMPLE-CONDITION-ish FORMAT-CONTROL
 749 ;;; and FORMAT-ARGS slots.
 750 (defun %report-reader-error (condition stream &key simple)
 751   (let* ((error-stream (stream-error-stream condition))
 752          (pos (file-position-or-nil-for-error error-stream)))
 753     (let (lineno colno)
 754       (when (and pos
 755                  (< pos sb!xc:array-dimension-limit)
 756                  ;; KLUDGE: lseek() (which is what FILE-POSITION
 757                  ;; reduces to on file-streams) is undefined on
 758                  ;; "some devices", which in practice means that it
 759                  ;; can claim to succeed on /dev/stdin on Darwin
 760                  ;; and Solaris.  This is obviously bad news,
 761                  ;; because the READ-SEQUENCE below will then
 762                  ;; block, not complete, and the report will never
 763                  ;; be printed.  As a workaround, we exclude
 764                  ;; interactive streams from this attempt to report
 765                  ;; positions.  -- CSR, 2003-08-21
 766                  (not (interactive-stream-p error-stream))
 767                  (file-position error-stream :start))
 768         (let ((string
 769                (make-string pos
 770                             :element-type (stream-element-type
 771                                            error-stream))))
 772           (when (= pos (read-sequence string error-stream))
 773             (setq lineno (1+ (count #\Newline string))
 774                   colno (- pos
 775                            (or (position #\Newline string :from-end t) -1)
 776                            1))))
 777         (file-position-or-nil-for-error error-stream pos))
 778       (pprint-logical-block (stream nil)
 779         (format stream
 780                 "~S ~@[at ~W ~]~
 781                     ~@[(line ~W~]~@[, column ~W) ~]~
 782                     on ~S"
 783                 (class-name (class-of condition))
 784                 pos lineno colno error-stream)
 785         (when simple
 786           (format stream ":~2I~_~?"
 787                   (simple-condition-format-control condition)
 788                   (simple-condition-format-arguments condition)))))))
 789 \f
 790 ;;;; special SBCL extension conditions
 791
 792 ;;; an error apparently caused by a bug in SBCL itself
 793 ;;;
 794 ;;; Note that we don't make any serious effort to use this condition
 795 ;;; for *all* errors in SBCL itself. E.g. type errors and array
 796 ;;; indexing errors can occur in functions called from SBCL code, and
 797 ;;; will just end up as ordinary TYPE-ERROR or invalid index error,
 798 ;;; because the signalling code has no good way to know that the
 799 ;;; underlying problem is a bug in SBCL. But in the fairly common case
 800 ;;; that the signalling code does know that it's found a bug in SBCL,
 801 ;;; this condition is appropriate, reusing boilerplate and helping
 802 ;;; users to recognize it as an SBCL bug.
 803 (define-condition bug (simple-error)
 804   ()
 805   (:report
 806    (lambda (condition stream)
 807      (format stream
 808              "~@<  ~? ~:@_~?~:>"
 809              (simple-condition-format-control condition)
 810              (simple-condition-format-arguments condition)
 811              "~@<This is probably a bug in SBCL itself. (Alternatively, ~
 812               SBCL might have been corrupted by bad user code, e.g. by an ~
 813               undefined Lisp operation like ~S, or by stray pointers from ~
 814               alien code or from unsafe Lisp code; or there might be a bug ~
 815               in the OS or hardware that SBCL is running on.) If it seems to ~
 816               be a bug in SBCL itself, the maintainers would like to know ~
 817               about it. Bug reports are welcome on the SBCL ~
 818               mailing lists, which you can find at ~
 819               <http://sbcl.sourceforge.net/>.~:@>"
 820              '((fmakunbound 'compile))))))
 821
 822 (define-condition simple-storage-condition (storage-condition simple-condition)
 823   ())
 824
 825 ;;; a condition for use in stubs for operations which aren't supported
 826 ;;; on some platforms
 827 ;;;
 828 ;;; E.g. in sbcl-0.7.0.5, it might be appropriate to do something like
 829 ;;;   #-(or freebsd linux)
 830 ;;;   (defun load-foreign (&rest rest)
 831 ;;;     (error 'unsupported-operator :name 'load-foreign))
 832 ;;;   #+(or freebsd linux)
 833 ;;;   (defun load-foreign ... actual definition ...)
 834 ;;; By signalling a standard condition in this case, we make it
 835 ;;; possible for test code to distinguish between (1) intentionally
 836 ;;; unimplemented and (2) unintentionally just screwed up somehow.
 837 ;;; (Before this condition was defined, test code tried to deal with
 838 ;;; this by checking for FBOUNDP, but that didn't work reliably. In
 839 ;;; sbcl-0.7.0, a package screwup left the definition of
 840 ;;; LOAD-FOREIGN in the wrong package, so it was unFBOUNDP even on
 841 ;;; architectures where it was supposed to be supported, and the
 842 ;;; regression tests cheerfully passed because they assumed that
 843 ;;; unFBOUNDPness meant they were running on an system which didn't
 844 ;;; support the extension.)
 845 (define-condition unsupported-operator (simple-error) ())
 846 \f
 847 ;;; (:ansi-cl :function remove)
 848 ;;; (:ansi-cl :section (a b c))
 849 ;;; (:ansi-cl :glossary "similar")
 850 ;;;
 851 ;;; (:sbcl :node "...")
 852 ;;; (:sbcl :variable *ed-functions*)
 853 ;;;
 854 ;;; FIXME: this is not the right place for this.
 855 (defun print-reference (reference stream)
 856   (ecase (car reference)
 857     (:amop
 858      (format stream "AMOP")
 859      (format stream ", ")
 860      (destructuring-bind (type data) (cdr reference)
 861        (ecase type
 862          (:readers "Readers for ~:(~A~) Metaobjects"
 863                    (substitute #\  #\- (symbol-name data)))
 864          (:initialization
 865           (format stream "Initialization of ~:(~A~) Metaobjects"
 866                   (substitute #\  #\- (symbol-name data))))
 867          (:generic-function (format stream "Generic Function ~S" data))
 868          (:function (format stream "Function ~S" data))
 869          (:section (format stream "Section ~{~D~^.~}" data)))))
 870     (:ansi-cl
 871      (format stream "The ANSI Standard")
 872      (format stream ", ")
 873      (destructuring-bind (type data) (cdr reference)
 874        (ecase type
 875          (:function (format stream "Function ~S" data))
 876          (:special-operator (format stream "Special Operator ~S" data))
 877          (:macro (format stream "Macro ~S" data))
 878          (:section (format stream "Section ~{~D~^.~}" data))
 879          (:glossary (format stream "Glossary entry for ~S" data))
 880          (:issue (format stream "writeup for Issue ~A" data)))))
 881     (:sbcl
 882      (format stream "The SBCL Manual")
 883      (format stream ", ")
 884      (destructuring-bind (type data) (cdr reference)
 885        (ecase type
 886          (:node (format stream "Node ~S" data))
 887          (:variable (format stream "Variable ~S" data))
 888          (:function (format stream "Function ~S" data)))))
 889     ;; FIXME: other documents (e.g. CLIM, Franz documentation :-)
 890     ))
 891 (define-condition reference-condition ()
 892   ((references :initarg :references :reader reference-condition-references)))
 893 (defvar *print-condition-references* t)
 894 (def!method print-object :around ((o reference-condition) s)
 895   (call-next-method)
 896   (unless (or *print-escape* *print-readably*)
 897     (when (and *print-condition-references*
 898                (reference-condition-references o))
 899       (format s "~&See also:~%")
 900       (pprint-logical-block (s nil :per-line-prefix "  ")
 901         (do* ((rs (reference-condition-references o) (cdr rs))
 902               (r (car rs) (car rs)))
 903              ((null rs))
 904           (print-reference r s)
 905           (unless (null (cdr rs))
 906             (terpri s)))))))
 907
 908 (define-condition simple-reference-error (reference-condition simple-error)
 909   ())
 910
 911 (define-condition simple-reference-warning (reference-condition simple-warning)
 912   ())
 913
 914 (define-condition duplicate-definition (reference-condition warning)
 915   ((name :initarg :name :reader duplicate-definition-name))
 916   (:report (lambda (c s)
 917              (format s "~@<Duplicate definition for ~S found in ~
 918                         one file.~@:>"
 919                      (duplicate-definition-name c))))
 920   (:default-initargs :references (list '(:ansi-cl :section (3 2 2 3)))))
 921
 922 (define-condition constant-modified (reference-condition warning)
 923   ((fun-name :initarg :fun-name :reader constant-modified-fun-name))
 924   (:report (lambda (c s)
 925              (format s "~@<Destructive function ~S called on ~
 926                         constant data.~@:>"
 927                      (constant-modified-fun-name c))))
 928   (:default-initargs :references (list '(:ansi-cl :special-operator quote)
 929                                        '(:ansi-cl :section (3 2 2 3)))))
 930
 931 (define-condition package-at-variance (reference-condition simple-warning)
 932   ()
 933   (:default-initargs :references (list '(:ansi-cl :macro defpackage))))
 934
 935 (define-condition defconstant-uneql (reference-condition error)
 936   ((name :initarg :name :reader defconstant-uneql-name)
 937    (old-value :initarg :old-value :reader defconstant-uneql-old-value)
 938    (new-value :initarg :new-value :reader defconstant-uneql-new-value))
 939   (:report
 940    (lambda (condition stream)
 941      (format stream
 942              "~@<The constant ~S is being redefined (from ~S to ~S)~@:>"
 943              (defconstant-uneql-name condition)
 944              (defconstant-uneql-old-value condition)
 945              (defconstant-uneql-new-value condition))))
 946   (:default-initargs :references (list '(:ansi-cl :macro defconstant)
 947                                        '(:sbcl :node "Idiosyncrasies"))))
 948
 949 (define-condition array-initial-element-mismatch
 950     (reference-condition simple-warning)
 951   ()
 952   (:default-initargs
 953       :references (list
 954                    '(:ansi-cl :function make-array)
 955                    '(:ansi-cl :function sb!xc:upgraded-array-element-type))))
 956
 957 (define-condition displaced-to-array-too-small-error
 958     (reference-condition simple-error)
 959   ()
 960   (:default-initargs
 961       :references (list '(:ansi-cl :function adjust-array))))
 962
 963 (define-condition type-warning (reference-condition simple-warning)
 964   ()
 965   (:default-initargs :references (list '(:sbcl :node "Handling of Types"))))
 966
 967 (define-condition local-argument-mismatch (reference-condition simple-warning)
 968   ()
 969   (:default-initargs :references (list '(:ansi-cl :section (3 2 2 3)))))
 970
 971 (define-condition format-args-mismatch (reference-condition)
 972   ()
 973   (:default-initargs :references (list '(:ansi-cl :section (22 3 10 2)))))
 974
 975 (define-condition format-too-few-args-warning
 976     (format-args-mismatch simple-warning)
 977   ())
 978 (define-condition format-too-many-args-warning
 979     (format-args-mismatch simple-style-warning)
 980   ())
 981
 982 (define-condition implicit-generic-function-warning (style-warning)
 983   ((name :initarg :name :reader implicit-generic-function-name))
 984   (:report
 985    (lambda (condition stream)
 986      (format stream "~@<Implicitly creating new generic function ~S.~:@>"
 987              (implicit-generic-function-name condition)))))
 988
 989 (define-condition extension-failure (reference-condition simple-error)
 990   ())
 991
 992 (define-condition structure-initarg-not-keyword
 993     (reference-condition simple-style-warning)
 994   ()
 995   (:default-initargs :references (list '(:ansi-cl :section (2 4 8 13)))))
 996
 997 #!+sb-package-locks
 998 (progn
 999
1000 (define-condition package-lock-violation (reference-condition package-error)
1001   ((format-control :initform nil :initarg :format-control
1002                    :reader package-error-format-control)
1003    (format-arguments :initform nil :initarg :format-arguments
1004                      :reader package-error-format-arguments))
1005   (:report
1006    (lambda (condition stream)
1007      (let ((control (package-error-format-control condition)))
1008        (if control
1009            (apply #'format stream
1010                   (format nil "~~@<Lock on package ~A violated when ~A.~~:@>"
1011                           (package-name (package-error-package condition))
1012                           control)
1013                   (package-error-format-arguments condition))
1014            (format stream "~@<Lock on package ~A violated.~:@>"
1015                    (package-name (package-error-package condition)))))))
1016   ;; no :default-initargs -- reference-stuff provided by the
1017   ;; signalling form in target-package.lisp
1018   #!+sb-doc
1019   (:documentation
1020    "Subtype of CL:PACKAGE-ERROR. A subtype of this error is signalled
1021 when a package-lock is violated."))
1022
1023 (define-condition package-locked-error (package-lock-violation) ()
1024   #!+sb-doc
1025   (:documentation
1026    "Subtype of SB-EXT:PACKAGE-LOCK-VIOLATION. An error of this type is
1027 signalled when an operation on a package violates a package lock."))
1028
1029 (define-condition symbol-package-locked-error (package-lock-violation)
1030   ((symbol :initarg :symbol :reader package-locked-error-symbol))
1031   #!+sb-doc
1032   (:documentation
1033    "Subtype of SB-EXT:PACKAGE-LOCK-VIOLATION. An error of this type is
1034 signalled when an operation on a symbol violates a package lock. The
1035 symbol that caused the violation is accessed by the function
1036 SB-EXT:PACKAGE-LOCKED-ERROR-SYMBOL."))
1037
1038 ) ; progn
1039
1040 (define-condition undefined-alien-error (cell-error) ()
1041   (:report
1042    (lambda (condition stream)
1043      (if (slot-boundp condition 'name)
1044          (format stream "Undefined alien: ~S" (cell-error-name condition))
1045          (format stream "Undefined alien symbol.")))))
1046
1047 (define-condition undefined-alien-variable-error (undefined-alien-error) ()
1048   (:report
1049    (lambda (condition stream)
1050      (declare (ignore condition))
1051      (format stream "Attempt to access an undefined alien variable."))))
1052
1053 (define-condition undefined-alien-function-error (undefined-alien-error) ()
1054   (:report
1055    (lambda (condition stream)
1056      (declare (ignore condition))
1057      (format stream "Attempt to call an undefined alien function."))))
1058
1059 \f
1060 ;;;; various other (not specified by ANSI) CONDITIONs
1061 ;;;;
1062 ;;;; These might logically belong in other files; they're here, after
1063 ;;;; setup of CONDITION machinery, only because that makes it easier to
1064 ;;;; get cold init to work.
1065
1066 ;;; OAOOM warning: see cross-condition.lisp
1067 (define-condition encapsulated-condition (condition)
1068   ((condition :initarg :condition :reader encapsulated-condition)))
1069
1070 (define-condition values-type-error (type-error)
1071   ()
1072   (:report
1073    (lambda (condition stream)
1074      (format stream
1075              "~@<The values set ~2I~:_[~{~S~^ ~}] ~I~_is not of type ~2I~_~S.~:>"
1076              (type-error-datum condition)
1077              (type-error-expected-type condition)))))
1078
1079 ;;; KLUDGE: a condition for floating point errors when we can't or
1080 ;;; won't figure out what type they are. (In FreeBSD and OpenBSD we
1081 ;;; don't know how, at least as of sbcl-0.6.7; in Linux we probably
1082 ;;; know how but the old code was broken by the conversion to POSIX
1083 ;;; signal handling and hasn't been fixed as of sbcl-0.6.7.)
1084 ;;;
1085 ;;; FIXME: Perhaps this should also be a base class for all
1086 ;;; floating point exceptions?
1087 (define-condition floating-point-exception (arithmetic-error)
1088   ((flags :initarg :traps
1089           :initform nil
1090           :reader floating-point-exception-traps))
1091   (:report (lambda (condition stream)
1092              (format stream
1093                      "An arithmetic error ~S was signalled.~%"
1094                      (type-of condition))
1095              (let ((traps (floating-point-exception-traps condition)))
1096                (if traps
1097                    (format stream
1098                            "Trapping conditions are: ~%~{ ~S~^~}~%"
1099                            traps)
1100                    (write-line
1101                     "No traps are enabled? How can this be?"
1102                     stream))))))
1103
1104 (define-condition index-too-large-error (type-error)
1105   ()
1106   (:report
1107    (lambda (condition stream)
1108      (format stream
1109              "The index ~S is too large."
1110              (type-error-datum condition)))))
1111
1112 (define-condition bounding-indices-bad-error (reference-condition type-error)
1113   ((object :reader bounding-indices-bad-object :initarg :object))
1114   (:report
1115    (lambda (condition stream)
1116      (let* ((datum (type-error-datum condition))
1117             (start (car datum))
1118             (end (cdr datum))
1119             (object (bounding-indices-bad-object condition)))
1120        (etypecase object
1121          (sequence
1122           (format stream
1123                   "The bounding indices ~S and ~S are bad ~
1124                    for a sequence of length ~S."
1125                   start end (length object)))
1126          (array
1127           ;; from WITH-ARRAY-DATA
1128           (format stream
1129                   "The START and END parameters ~S and ~S are ~
1130                    bad for an array of total size ~S."
1131                   start end (array-total-size object)))))))
1132   (:default-initargs
1133       :references
1134       (list '(:ansi-cl :glossary "bounding index designator")
1135             '(:ansi-cl :issue "SUBSEQ-OUT-OF-BOUNDS:IS-AN-ERROR"))))
1136
1137 (define-condition nil-array-accessed-error (reference-condition type-error)
1138   ()
1139   (:report (lambda (condition stream)
1140              (declare (ignore condition))
1141              (format stream
1142                      "An attempt to access an array of element-type ~
1143                       NIL was made.  Congratulations!")))
1144   (:default-initargs
1145       :references (list '(:ansi-cl :function sb!xc:upgraded-array-element-type)
1146                         '(:ansi-cl :section (15 1 2 1))
1147                         '(:ansi-cl :section (15 1 2 2)))))
1148
1149 (define-condition namestring-parse-error (parse-error)
1150   ((complaint :reader namestring-parse-error-complaint :initarg :complaint)
1151    (args :reader namestring-parse-error-args :initarg :args :initform nil)
1152    (namestring :reader namestring-parse-error-namestring :initarg :namestring)
1153    (offset :reader namestring-parse-error-offset :initarg :offset))
1154   (:report
1155    (lambda (condition stream)
1156      (format stream
1157              "parse error in namestring: ~?~%  ~A~%  ~V@T^"
1158              (namestring-parse-error-complaint condition)
1159              (namestring-parse-error-args condition)
1160              (namestring-parse-error-namestring condition)
1161              (namestring-parse-error-offset condition)))))
1162
1163 (define-condition simple-package-error (simple-condition package-error) ())
1164
1165 (define-condition simple-reader-package-error (simple-reader-error) ())
1166
1167 (define-condition reader-eof-error (end-of-file)
1168   ((context :reader reader-eof-error-context :initarg :context))
1169   (:report
1170    (lambda (condition stream)
1171      (format stream
1172              "unexpected end of file on ~S ~A"
1173              (stream-error-stream condition)
1174              (reader-eof-error-context condition)))))
1175
1176 (define-condition reader-impossible-number-error (simple-reader-error)
1177   ((error :reader reader-impossible-number-error-error :initarg :error))
1178   (:report
1179    (lambda (condition stream)
1180      (let ((error-stream (stream-error-stream condition)))
1181        (format stream
1182                "READER-ERROR ~@[at ~W ~]on ~S:~%~?~%Original error: ~A"
1183                (file-position-or-nil-for-error error-stream) error-stream
1184                (simple-condition-format-control condition)
1185                (simple-condition-format-arguments condition)
1186                (reader-impossible-number-error-error condition))))))
1187
1188 (define-condition standard-readtable-modified-error (reference-condition error)
1189   ((operation :initarg :operation :reader standard-readtable-modified-operation))
1190   (:report (lambda (condition stream)
1191              (format stream "~S would modify the standard readtable."
1192                      (standard-readtable-modified-operation condition))))
1193   (:default-initargs :references `((:ansi-cl :section (2 1 1 2))
1194                                    (:ansi-cl :glossary "standard readtable"))))
1195
1196 (define-condition timeout (serious-condition)
1197   ((seconds :initarg :seconds :initform nil :reader timeout-seconds))
1198   (:report (lambda (condition stream)
1199              (format stream "Timeout occurred~@[ after ~A seconds~]."
1200                      (timeout-seconds condition)))))
1201
1202 (define-condition io-timeout (stream-error timeout)
1203   ((direction :reader io-timeout-direction :initarg :direction))
1204   (:report
1205    (lambda (condition stream)
1206      (declare (type stream stream))
1207      (format stream
1208              "I/O timeout ~(~A~)ing ~S."
1209              (io-timeout-direction condition)
1210              (stream-error-stream condition)))))
1211
1212 (define-condition deadline-timeout (timeout) ()
1213   (:report (lambda (condition stream)
1214              (format stream "A deadline was reached after ~A seconds."
1215                      (timeout-seconds condition)))))
1216
1217 (define-condition declaration-type-conflict-error (reference-condition
1218                                                    simple-error)
1219   ()
1220   (:default-initargs
1221       :format-control "symbol ~S cannot be both the name of a type and the name of a declaration"
1222     :references (list '(:ansi-cl :section (3 8 21)))))
1223
1224 ;;; Single stepping conditions
1225
1226 (define-condition step-condition ()
1227   ((form :initarg :form :reader step-condition-form))
1228
1229   #!+sb-doc
1230   (:documentation "Common base class of single-stepping conditions.
1231 STEP-CONDITION-FORM holds a string representation of the form being
1232 stepped."))
1233
1234 #!+sb-doc
1235 (setf (fdocumentation 'step-condition-form 'function)
1236       "Form associated with the STEP-CONDITION.")
1237
1238 (define-condition step-form-condition (step-condition)
1239   ((args :initarg :args :reader step-condition-args))
1240   (:report
1241    (lambda (condition stream)
1242      (let ((*print-circle* t)
1243            (*print-pretty* t)
1244            (*print-readably* nil))
1245        (format stream
1246                  "Evaluating call:~%~<  ~@;~A~:>~%~
1247                   ~:[With arguments:~%~{  ~S~%~}~;With unknown arguments~]~%"
1248                (list (step-condition-form condition))
1249                (eq (step-condition-args condition) :unknown)
1250                (step-condition-args condition)))))
1251   #!+sb-doc
1252   (:documentation "Condition signalled by code compiled with
1253 single-stepping information when about to execute a form.
1254 STEP-CONDITION-FORM holds the form, STEP-CONDITION-PATHNAME holds the
1255 pathname of the original file or NIL, and STEP-CONDITION-SOURCE-PATH
1256 holds the source-path to the original form within that file or NIL.
1257 Associated with this condition are always the restarts STEP-INTO,
1258 STEP-NEXT, and STEP-CONTINUE."))
1259
1260 #!+sb-doc
1261 (setf (fdocumentation 'step-condition-source-path 'function)
1262       "Source-path of the original form associated with the
1263 STEP-FORM-CONDITION or NIL."
1264       (fdocumentation 'step-condition-pathname 'function)
1265       "Pathname of the original source-file associated with the
1266 STEP-FORM-CONDITION or NIL.")
1267
1268 (define-condition step-result-condition (step-condition)
1269   ((result :initarg :result :reader step-condition-result)))
1270
1271 #!+sb-doc
1272 (setf (fdocumentation 'step-condition-result 'function)
1273       "Return values associated with STEP-VALUES-CONDITION as a list,
1274 or the variable value associated with STEP-VARIABLE-CONDITION.")
1275
1276 (define-condition step-values-condition (step-result-condition)
1277   ()
1278   #!+sb-doc
1279   (:documentation "Condition signalled by code compiled with
1280 single-stepping information after executing a form.
1281 STEP-CONDITION-FORM holds the form, and STEP-CONDITION-RESULT holds
1282 the values returned by the form as a list. No associated restarts."))
1283
1284 (define-condition step-finished-condition (step-condition)
1285   ()
1286   (:report
1287    (lambda (condition stream)
1288      (declare (ignore condition))
1289      (format stream "Returning from STEP")))
1290   #!+sb-doc
1291   (:documentation "Condition signaled when STEP returns."))
1292 \f
1293 ;;; A knob for muffling warnings, mostly for use while loading files.
1294 (defvar *muffled-warnings* 'uninteresting-redefinition
1295   "A type that ought to specify a subtype of WARNING.  Whenever a
1296 warning is signaled, if the warning if of this type and is not
1297 handled by any other handler, it will be muffled.")
1298 \f
1299 ;;; Various STYLE-WARNING signaled in the system.
1300 ;; For the moment, we're only getting into the details for function
1301 ;; redefinitions, but other redefinitions could be done later
1302 ;; (e.g. methods).
1303 (define-condition redefinition-warning (style-warning)
1304   ())
1305
1306 (define-condition function-redefinition-warning (redefinition-warning)
1307   ((name :initarg :name :reader function-redefinition-warning-name)
1308    (old :initarg :old :reader function-redefinition-warning-old-fdefinition)
1309    ;; For DEFGENERIC and perhaps others, the redefinition
1310    ;; destructively modifies the original, rather than storing a new
1311    ;; object, so there's no NEW here, but only in subclasses.
1312    ))
1313
1314 (define-condition redefinition-with-defun (function-redefinition-warning)
1315   ((new :initarg :new :reader redefinition-with-defun-new-fdefinition)
1316    ;; KLUDGE: it would be nice to fix the unreasonably late
1317    ;; back-patching of DEBUG-SOURCEs in the DEBUG-INFO during
1318    ;; fasloading and just use the new fdefinition, but for the moment
1319    ;; we'll compare the SOURCE-LOCATION created during DEFUN with the
1320    ;; previous DEBUG-SOURCE.
1321    (new-location :initarg :new-location
1322               :reader redefinition-with-defun-new-location))
1323   (:report (lambda (warning stream)
1324              (format stream "redefining ~S in DEFUN"
1325                      (function-redefinition-warning-name warning)))))
1326
1327 (define-condition redefinition-with-defgeneric (function-redefinition-warning)
1328   ((new-location :initarg :new-location
1329                  :reader redefinition-with-defgeneric-new-location))
1330   (:report (lambda (warning stream)
1331              (format stream "redefining ~S in DEFGENERIC"
1332                      (function-redefinition-warning-name warning)))))
1333
1334 (define-condition redefinition-with-defmethod (redefinition-warning)
1335   ((gf :initarg :generic-function
1336        :reader redefinition-with-defmethod-generic-function)
1337    (qualifiers :initarg :qualifiers
1338                :reader redefinition-with-defmethod-qualifiers)
1339    (specializers :initarg :specializers
1340                  :reader redefinition-with-defmethod-specializers)
1341    (new-location :initarg :new-location
1342                  :reader redefinition-with-defmethod-new-location)
1343    (old-method :initarg :old-method
1344                :reader redefinition-with-defmethod-old-method))
1345   (:report (lambda (warning stream)
1346              (format stream "redefining ~S~{ ~S~} ~S in DEFMETHOD"
1347                      (redefinition-with-defmethod-generic-function warning)
1348                      (redefinition-with-defmethod-qualifiers warning)
1349                      (redefinition-with-defmethod-specializers warning)))))
1350
1351 ;; FIXME: see the FIXMEs in defmacro.lisp, then maybe instantiate this.
1352 (define-condition redefinition-with-defmacro (function-redefinition-warning)
1353   ())
1354
1355 ;; Here are a few predicates for what people might find interesting
1356 ;; about redefinitions.
1357
1358 ;; DEFUN can replace a generic function with an ordinary function.
1359 ;; (Attempting to replace an ordinary function with a generic one
1360 ;; causes an error, though.)
1361 (defun redefinition-replaces-generic-function-p (warning)
1362   (and (typep warning 'redefinition-with-defun)
1363        (typep (function-redefinition-warning-old-fdefinition warning)
1364               'generic-function)))
1365
1366 (defun redefinition-replaces-compiled-function-with-interpreted-p (warning)
1367   (and (typep warning 'redefinition-with-defun)
1368        (compiled-function-p
1369         (function-redefinition-warning-old-fdefinition warning))
1370        (not (compiled-function-p
1371              (redefinition-with-defun-new-fdefinition warning)))))
1372
1373 ;; Most people seem to agree that re-running a DEFUN in a file is
1374 ;; completely uninteresting.
1375 (defun uninteresting-ordinary-function-redefinition-p (warning)
1376   ;; OAOO violation: this duplicates code in SB-INTROSPECT.
1377   ;; Additionally, there are some functions that aren't
1378   ;; funcallable-instances for which finding the source location is
1379   ;; complicated (e.g. DEFSTRUCT-defined predicates and accessors),
1380   ;; but I don't think they're defined with %DEFUN, so the warning
1381   ;; isn't raised.
1382   (flet ((fdefinition-file-namestring (fdefn)
1383            #!+sb-eval
1384            (when (typep fdefn 'sb!eval:interpreted-function)
1385              (return-from fdefinition-file-namestring
1386                (sb!c:definition-source-location-namestring
1387                    (sb!eval:interpreted-function-source-location fdefn))))
1388            ;; All the following accesses are guarded with conditionals
1389            ;; because it's not clear whether any of the slots we're
1390            ;; chasing down are guaranteed to be filled in.
1391            (let* ((fdefn
1392                    ;; KLUDGE: although this looks like it only works
1393                    ;; for %SIMPLE-FUNs, in fact there's a pun such
1394                    ;; that %SIMPLE-FUN-SELF returns the simple-fun
1395                    ;; object for closures and
1396                    ;; funcallable-instances. -- CSR, circa 2005
1397                    (sb!kernel:%simple-fun-self fdefn))
1398                   (code (if fdefn (sb!kernel:fun-code-header fdefn)))
1399                   (debug-info (if code (sb!kernel:%code-debug-info code)))
1400                   (debug-source (if debug-info
1401                                     (sb!c::debug-info-source debug-info)))
1402                   (namestring (if debug-source
1403                                   (sb!c::debug-source-namestring debug-source))))
1404              namestring)))
1405     (and
1406      ;; There's garbage in various places when the first DEFUN runs in
1407      ;; cold-init.
1408      sb!kernel::*cold-init-complete-p*
1409      (typep warning 'redefinition-with-defun)
1410      (let ((old-fdefn
1411             (function-redefinition-warning-old-fdefinition warning))
1412            (new-fdefn
1413             (redefinition-with-defun-new-fdefinition warning)))
1414        ;; Replacing a compiled function with a compiled function is
1415        ;; clearly uninteresting, and we'll say arbitrarily that
1416        ;; replacing an interpreted function with an interpreted
1417        ;; function is uninteresting, too, but leave out the
1418        ;; compiled-to-interpreted case.
1419        (when (or (typep
1420                   old-fdefn
1421                   '(or #!+sb-eval sb!eval:interpreted-function))
1422                  (and (typep old-fdefn
1423                              '(and compiled-function
1424                                (not funcallable-instance)))
1425                       ;; Since this is a REDEFINITION-WITH-DEFUN,
1426                       ;; NEW-FDEFN can't be a FUNCALLABLE-INSTANCE.
1427                       (typep new-fdefn 'compiled-function)))
1428          (let* ((old-namestring (fdefinition-file-namestring old-fdefn))
1429                 (new-namestring
1430                  (or (fdefinition-file-namestring new-fdefn)
1431                      (let ((srcloc
1432                             (redefinition-with-defun-new-location warning)))
1433                        (if srcloc
1434                             (sb!c::definition-source-location-namestring
1435                                 srcloc))))))
1436            (and old-namestring
1437                 new-namestring
1438                 (equal old-namestring new-namestring))))))))
1439
1440 (defun uninteresting-generic-function-redefinition-p (warning)
1441   (and (typep warning 'redefinition-with-defgeneric)
1442        (let* ((old-fdefn
1443                (function-redefinition-warning-old-fdefinition warning))
1444               (old-location
1445                (if (typep old-fdefn 'generic-function)
1446                    (sb!pcl::definition-source old-fdefn)))
1447               (old-namestring
1448                (if old-location
1449                    (sb!c:definition-source-location-namestring old-location)))
1450               (new-location
1451                (redefinition-with-defgeneric-new-location warning))
1452               (new-namestring
1453                (if new-location
1454                    (sb!c:definition-source-location-namestring new-location))))
1455          (and old-namestring
1456               new-namestring
1457               (equal old-namestring new-namestring)))))
1458
1459 (defun uninteresting-method-redefinition-p (warning)
1460   (and (typep warning 'redefinition-with-defmethod)
1461        (let* ((old-method (redefinition-with-defmethod-old-method warning))
1462               (old-location (sb!pcl::definition-source old-method))
1463               (old-namestring (if old-location
1464                                   (sb!c:definition-source-location-namestring
1465                                       old-location)))
1466               (new-location (redefinition-with-defmethod-new-location warning))
1467               (new-namestring (if new-location
1468                                   (sb!c:definition-source-location-namestring
1469                                       new-location))))
1470          (and new-namestring
1471               old-namestring
1472               (equal new-namestring old-namestring)))))
1473
1474 (deftype uninteresting-redefinition ()
1475   '(or (satisfies uninteresting-ordinary-function-redefinition-p)
1476        (satisfies uninteresting-generic-function-redefinition-p)
1477        (satisfies uninteresting-method-redefinition-p)))
1478
1479 (define-condition redefinition-with-deftransform (redefinition-warning)
1480   ((transform :initarg :transform
1481               :reader redefinition-with-deftransform-transform))
1482   (:report (lambda (warning stream)
1483              (format stream "Overwriting ~S"
1484                      (redefinition-with-deftransform-transform warning)))))
1485 \f
1486 ;;; Various other STYLE-WARNINGS
1487 (define-condition dubious-asterisks-around-variable-name
1488     (style-warning simple-condition)
1489   ()
1490   (:report (lambda (warning stream)
1491              (format stream "~@?, even though the name follows~@
1492 the usual naming convention (names like *FOO*) for special variables"
1493                      (simple-condition-format-control warning)
1494                      (simple-condition-format-arguments warning)))))
1495
1496 (define-condition asterisks-around-lexical-variable-name
1497     (dubious-asterisks-around-variable-name)
1498   ())
1499
1500 (define-condition asterisks-around-constant-variable-name
1501     (dubious-asterisks-around-variable-name)
1502   ())
1503
1504 ;; We call this UNDEFINED-ALIEN-STYLE-WARNING because there are some
1505 ;; subclasses of ERROR above having to do with undefined aliens.
1506 (define-condition undefined-alien-style-warning (style-warning)
1507   ((symbol :initarg :symbol :reader undefined-alien-symbol))
1508   (:report (lambda (warning stream)
1509              (format stream "Undefined alien: ~S"
1510                      (undefined-alien-symbol warning)))))
1511
1512 #!+sb-eval
1513 (define-condition lexical-environment-too-complex (style-warning)
1514   ((form :initarg :form :reader lexical-environment-too-complex-form)
1515    (lexenv :initarg :lexenv :reader lexical-environment-too-complex-lexenv))
1516   (:report (lambda (warning stream)
1517              (format stream
1518                      "~@<Native lexical environment too complex for ~
1519                          SB-EVAL to evaluate ~S, falling back to ~
1520                          SIMPLE-EVAL-IN-LEXENV.  Lexenv: ~S~:@>"
1521                      (lexical-environment-too-complex-form warning)
1522                      (lexical-environment-too-complex-lexenv warning)))))
1523
1524 ;; Although this has -ERROR- in the name, it's just a STYLE-WARNING.
1525 (define-condition character-decoding-error-in-comment (style-warning)
1526   ((stream :initarg :stream :reader decoding-error-in-comment-stream)
1527    (position :initarg :position :reader decoding-error-in-comment-position))
1528   (:report (lambda (warning stream)
1529              (format stream
1530                       "Character decoding error in a ~A-comment at ~
1531                       position ~A reading source stream ~A, ~
1532                       resyncing."
1533                       (decoding-error-in-comment-macro warning)
1534                       (decoding-error-in-comment-position warning)
1535                       (decoding-error-in-comment-stream warning)))))
1536
1537 (define-condition character-decoding-error-in-macro-char-comment
1538     (character-decoding-error-in-comment)
1539   ((char :initform #\; :initarg :char
1540          :reader character-decoding-error-in-macro-char-comment-char)))
1541
1542 (define-condition character-decoding-error-in-dispatch-macro-char-comment
1543     (character-decoding-error-in-comment)
1544   ;; ANSI doesn't give a way for a reader function invoked by a
1545   ;; dispatch macro character to determine which dispatch character
1546   ;; was used, so if a user wants to signal one of these from a custom
1547   ;; comment reader, he'll have to supply the :DISP-CHAR himself.
1548   ((disp-char :initform #\# :initarg :disp-char
1549               :reader character-decoding-error-in-macro-char-comment-disp-char)
1550    (sub-char :initarg :sub-char
1551              :reader character-decoding-error-in-macro-char-comment-sub-char)))
1552
1553 (defun decoding-error-in-comment-macro (warning)
1554   (etypecase warning
1555     (character-decoding-error-in-macro-char-comment
1556      (character-decoding-error-in-macro-char-comment-char warning))
1557     (character-decoding-error-in-dispatch-macro-char-comment
1558      (format
1559       nil "~C~C"
1560       (character-decoding-error-in-macro-char-comment-disp-char warning)
1561       (character-decoding-error-in-macro-char-comment-sub-char warning)))))
1562
1563 (define-condition deprecated-eval-when-situations (style-warning)
1564   ((situations :initarg :situations
1565                :reader deprecated-eval-when-situations-situations))
1566   (:report (lambda (warning stream)
1567              (format stream "using deprecated EVAL-WHEN situation names~{ ~S~}"
1568                      (deprecated-eval-when-situations-situations warning)))))
1569
1570 (define-condition proclamation-mismatch (style-warning)
1571   ((name :initarg :name :reader proclamation-mismatch-name)
1572    (old :initarg :old :reader proclamation-mismatch-old)
1573    (new :initarg :new :reader proclamation-mismatch-new)))
1574
1575 (define-condition type-proclamation-mismatch (proclamation-mismatch)
1576   ()
1577   (:report (lambda (warning stream)
1578              (format stream
1579                      "The new TYPE proclamation~% ~S for ~S does not ~
1580                      match the old TYPE proclamation ~S"
1581                      (proclamation-mismatch-new warning)
1582                      (proclamation-mismatch-name warning)
1583                      (proclamation-mismatch-old warning)))))
1584
1585 (define-condition ftype-proclamation-mismatch (proclamation-mismatch)
1586   ()
1587   (:report (lambda (warning stream)
1588              (format stream
1589                      "The new FTYPE proclamation~% ~S for ~S does not ~
1590                      match the old FTYPE proclamation ~S"
1591                      (proclamation-mismatch-new warning)
1592                      (proclamation-mismatch-name warning)
1593                      (proclamation-mismatch-old warning)))))
1594 \f
1595 ;;;; restart definitions
1596
1597 (define-condition abort-failure (control-error) ()
1598   (:report
1599    "An ABORT restart was found that failed to transfer control dynamically."))
1600
1601 (defun abort (&optional condition)
1602   #!+sb-doc
1603   "Transfer control to a restart named ABORT, signalling a CONTROL-ERROR if
1604    none exists."
1605   (invoke-restart (find-restart-or-control-error 'abort condition))
1606   ;; ABORT signals an error in case there was a restart named ABORT
1607   ;; that did not transfer control dynamically. This could happen with
1608   ;; RESTART-BIND.
1609   (error 'abort-failure))
1610
1611 (defun muffle-warning (&optional condition)
1612   #!+sb-doc
1613   "Transfer control to a restart named MUFFLE-WARNING, signalling a
1614    CONTROL-ERROR if none exists."
1615   (invoke-restart (find-restart-or-control-error 'muffle-warning condition)))
1616
1617 (defun try-restart (name condition &rest arguments)
1618   (let ((restart (find-restart name condition)))
1619     (when restart
1620       (apply #'invoke-restart restart arguments))))
1621
1622 (macrolet ((define-nil-returning-restart (name args doc)
1623              #!-sb-doc (declare (ignore doc))
1624              `(defun ,name (,@args &optional condition)
1625                 #!+sb-doc ,doc
1626                 (try-restart ',name condition ,@args))))
1627   (define-nil-returning-restart continue ()
1628     "Transfer control to a restart named CONTINUE, or return NIL if none exists.")
1629   (define-nil-returning-restart store-value (value)
1630     "Transfer control and VALUE to a restart named STORE-VALUE, or return NIL if
1631    none exists.")
1632   (define-nil-returning-restart use-value (value)
1633     "Transfer control and VALUE to a restart named USE-VALUE, or return NIL if
1634    none exists."))
1635
1636 ;;; single-stepping restarts
1637
1638 (macrolet ((def (name doc)
1639                #!-sb-doc (declare (ignore doc))
1640                `(defun ,name (condition)
1641                  #!+sb-doc ,doc
1642                  (invoke-restart (find-restart-or-control-error ',name condition)))))
1643   (def step-continue
1644       "Transfers control to the STEP-CONTINUE restart associated with
1645 the condition, continuing execution without stepping. Signals a
1646 CONTROL-ERROR if the restart does not exist.")
1647   (def step-next
1648       "Transfers control to the STEP-NEXT restart associated with the
1649 condition, executing the current form without stepping and continuing
1650 stepping with the next form. Signals CONTROL-ERROR is the restart does
1651 not exists.")
1652   (def step-into
1653       "Transfers control to the STEP-INTO restart associated with the
1654 condition, stepping into the current form. Signals a CONTROL-ERROR is
1655 the restart does not exist."))
1656
1657 (/show0 "condition.lisp end of file")
1658