src/code/condition.lisp

   1 ;;;; stuff originally from CMU CL's error.lisp which can or should
   2 ;;;; come late (mostly related to the CONDITION class itself)
   3 ;;;;
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!KERNEL")
  15 \f
  16 ;;;; miscellaneous support utilities
  17
  18 ;;; Signalling an error when trying to print an error condition is
  19 ;;; generally a PITA, so whatever the failure encountered when
  20 ;;; wondering about FILE-POSITION within a condition printer, 'tis
  21 ;;; better silently to give up than to try to complain.
  22 (defun file-position-or-nil-for-error (stream &optional (pos nil posp))
  23   ;; Arguably FILE-POSITION shouldn't be signalling errors at all; but
  24   ;; "NIL if this cannot be determined" in the ANSI spec doesn't seem
  25   ;; absolutely unambiguously to prohibit errors when, e.g., STREAM
  26   ;; has been closed so that FILE-POSITION is a nonsense question. So
  27   ;; my (WHN) impression is that the conservative approach is to
  28   ;; IGNORE-ERRORS. (I encountered this failure from within a homebrew
  29   ;; defsystemish operation where the ERROR-STREAM had been CL:CLOSEd,
  30   ;; I think by nonlocally exiting through a WITH-OPEN-FILE, by the
  31   ;; time an error was reported.)
  32   (if posp
  33       (ignore-errors (file-position stream pos))
  34       (ignore-errors (file-position stream))))
  35 \f
  36 ;;;; the CONDITION class
  37
  38 (/show0 "condition.lisp 20")
  39
  40 (eval-when (:compile-toplevel :load-toplevel :execute)
  41
  42 (/show0 "condition.lisp 24")
  43
  44 (def!struct (condition-classoid (:include classoid)
  45                                 (:constructor make-condition-classoid))
  46   ;; list of CONDITION-SLOT structures for the direct slots of this
  47   ;; class
  48   (slots nil :type list)
  49   ;; list of CONDITION-SLOT structures for all of the effective class
  50   ;; slots of this class
  51   (class-slots nil :type list)
  52   ;; report function or NIL
  53   (report nil :type (or function null))
  54   ;; list of alternating initargs and initforms
  55   (default-initargs () :type list)
  56   ;; class precedence list as a list of CLASS objects, with all
  57   ;; non-CONDITION classes removed
  58   (cpl () :type list)
  59   ;; a list of all the effective instance allocation slots of this
  60   ;; class that have a non-constant initform or default-initarg.
  61   ;; Values for these slots must be computed in the dynamic
  62   ;; environment of MAKE-CONDITION.
  63   (hairy-slots nil :type list))
  64
  65 (/show0 "condition.lisp 49")
  66
  67 ) ; EVAL-WHEN
  68
  69 (!defstruct-with-alternate-metaclass condition
  70   :slot-names (actual-initargs assigned-slots)
  71   :boa-constructor %make-condition-object
  72   :superclass-name t
  73   :metaclass-name condition-classoid
  74   :metaclass-constructor make-condition-classoid
  75   :dd-type structure)
  76
  77 (defun make-condition-object (actual-initargs)
  78   (%make-condition-object actual-initargs nil))
  79
  80 (defstruct (condition-slot (:copier nil))
  81   (name (missing-arg) :type symbol)
  82   ;; list of all applicable initargs
  83   (initargs (missing-arg) :type list)
  84   ;; names of reader and writer functions
  85   (readers (missing-arg) :type list)
  86   (writers (missing-arg) :type list)
  87   ;; true if :INITFORM was specified
  88   (initform-p (missing-arg) :type (member t nil))
  89   ;; If this is a function, call it with no args. Otherwise, it's the
  90   ;; actual value.
  91   (initform (missing-arg) :type t)
  92   ;; allocation of this slot, or NIL until defaulted
  93   (allocation nil :type (member :instance :class nil))
  94   ;; If ALLOCATION is :CLASS, this is a cons whose car holds the value.
  95   (cell nil :type (or cons null))
  96   ;; slot documentation
  97   (documentation nil :type (or string null)))
  98
  99 ;;; KLUDGE: It's not clear to me why CONDITION-CLASS has itself listed
 100 ;;; in its CPL, while other classes derived from CONDITION-CLASS don't
 101 ;;; have themselves listed in their CPLs. This behavior is inherited
 102 ;;; from CMU CL, and didn't seem to be explained there, and I haven't
 103 ;;; figured out whether it's right. -- WHN 19990612
 104 (eval-when (:compile-toplevel :load-toplevel :execute)
 105   (/show0 "condition.lisp 103")
 106   (let ((condition-class (locally
 107                            ;; KLUDGE: There's a DEFTRANSFORM
 108                            ;; FIND-CLASSOID for constant class names
 109                            ;; which creates fast but
 110                            ;; non-cold-loadable, non-compact code. In
 111                            ;; this context, we'd rather have compact,
 112                            ;; cold-loadable code. -- WHN 19990928
 113                            (declare (notinline find-classoid))
 114                            (find-classoid 'condition))))
 115     (setf (condition-classoid-cpl condition-class)
 116           (list condition-class)))
 117   (/show0 "condition.lisp 103"))
 118
 119 (setf (condition-classoid-report (locally
 120                                    ;; KLUDGE: There's a DEFTRANSFORM
 121                                    ;; FIND-CLASSOID for constant class
 122                                    ;; names which creates fast but
 123                                    ;; non-cold-loadable, non-compact
 124                                    ;; code. In this context, we'd
 125                                    ;; rather have compact,
 126                                    ;; cold-loadable code. -- WHN
 127                                    ;; 19990928
 128                                    (declare (notinline find-classoid))
 129                                    (find-classoid 'condition)))
 130       (lambda (cond stream)
 131         (format stream "Condition ~S was signalled." (type-of cond))))
 132
 133 (eval-when (:compile-toplevel :load-toplevel :execute)
 134
 135 (defun find-condition-layout (name parent-types)
 136   (let* ((cpl (remove-duplicates
 137                (reverse
 138                 (reduce #'append
 139                         (mapcar (lambda (x)
 140                                   (condition-classoid-cpl
 141                                    (find-classoid x)))
 142                                 parent-types)))))
 143          (cond-layout (info :type :compiler-layout 'condition))
 144          (olayout (info :type :compiler-layout name))
 145          ;; FIXME: Does this do the right thing in case of multiple
 146          ;; inheritance? A quick look at DEFINE-CONDITION didn't make
 147          ;; it obvious what ANSI intends to be done in the case of
 148          ;; multiple inheritance, so it's not actually clear what the
 149          ;; right thing is..
 150          (new-inherits
 151           (order-layout-inherits (concatenate 'simple-vector
 152                                               (layout-inherits cond-layout)
 153                                               (mapcar #'classoid-layout cpl)))))
 154     (if (and olayout
 155              (not (mismatch (layout-inherits olayout) new-inherits)))
 156         olayout
 157         (make-layout :classoid (make-undefined-classoid name)
 158                      :inherits new-inherits
 159                      :depthoid -1
 160                      :length (layout-length cond-layout)))))
 161
 162 ) ; EVAL-WHEN
 163
 164 ;;; FIXME: ANSI's definition of DEFINE-CONDITION says
 165 ;;;   Condition reporting is mediated through the PRINT-OBJECT method
 166 ;;;   for the condition type in question, with *PRINT-ESCAPE* always
 167 ;;;   being nil. Specifying (:REPORT REPORT-NAME) in the definition of
 168 ;;;   a condition type C is equivalent to:
 169 ;;;     (defmethod print-object ((x c) stream)
 170 ;;;       (if *print-escape* (call-next-method) (report-name x stream)))
 171 ;;; The current code doesn't seem to quite match that.
 172 (def!method print-object ((x condition) stream)
 173   (if *print-escape*
 174       (if (and (typep x 'simple-condition) (slot-boundp x 'format-control))
 175           (print-unreadable-object (x stream :type t :identity t)
 176             (format stream "~S" (simple-condition-format-control x)))
 177           (print-unreadable-object (x stream :type t :identity t)))
 178       ;; KLUDGE: A comment from CMU CL here said
 179       ;;   7/13/98 BUG? CPL is not sorted and results here depend on order of
 180       ;;   superclasses in define-condition call!
 181       (dolist (class (condition-classoid-cpl (classoid-of x))
 182                      (error "no REPORT? shouldn't happen!"))
 183         (let ((report (condition-classoid-report class)))
 184           (when report
 185             (return (funcall report x stream)))))))
 186 \f
 187 ;;;; slots of CONDITION objects
 188
 189 (defvar *empty-condition-slot* '(empty))
 190
 191 (defun find-slot-default (class slot)
 192   (let ((initargs (condition-slot-initargs slot))
 193         (cpl (condition-classoid-cpl class)))
 194     (dolist (class cpl)
 195       (let ((default-initargs (condition-classoid-default-initargs class)))
 196         (dolist (initarg initargs)
 197           (let ((val (getf default-initargs initarg *empty-condition-slot*)))
 198             (unless (eq val *empty-condition-slot*)
 199               (return-from find-slot-default
 200                            (if (functionp val)
 201                                (funcall val)
 202                                val)))))))
 203
 204     (if (condition-slot-initform-p slot)
 205         (let ((initform (condition-slot-initform slot)))
 206           (if (functionp initform)
 207               (funcall initform)
 208               initform))
 209         (error "unbound condition slot: ~S" (condition-slot-name slot)))))
 210
 211 (defun find-condition-class-slot (condition-class slot-name)
 212   (dolist (sclass
 213            (condition-classoid-cpl condition-class)
 214            (error "There is no slot named ~S in ~S."
 215                   slot-name condition-class))
 216     (dolist (slot (condition-classoid-slots sclass))
 217       (when (eq (condition-slot-name slot) slot-name)
 218         (return-from find-condition-class-slot slot)))))
 219
 220 (defun condition-writer-function (condition new-value name)
 221   (dolist (cslot (condition-classoid-class-slots
 222                   (layout-classoid (%instance-layout condition)))
 223                  (setf (getf (condition-assigned-slots condition) name)
 224                        new-value))
 225     (when (eq (condition-slot-name cslot) name)
 226       (return (setf (car (condition-slot-cell cslot)) new-value)))))
 227
 228 (defun condition-reader-function (condition name)
 229   (let ((class (layout-classoid (%instance-layout condition))))
 230     (dolist (cslot (condition-classoid-class-slots class))
 231       (when (eq (condition-slot-name cslot) name)
 232         (return-from condition-reader-function
 233                      (car (condition-slot-cell cslot)))))
 234     (let ((val (getf (condition-assigned-slots condition) name
 235                      *empty-condition-slot*)))
 236       (if (eq val *empty-condition-slot*)
 237           (let ((actual-initargs (condition-actual-initargs condition))
 238                 (slot (find-condition-class-slot class name)))
 239             (unless slot
 240               (error "missing slot ~S of ~S" name condition))
 241             (do ((initargs actual-initargs (cddr initargs)))
 242                 ((endp initargs)
 243                  (setf (getf (condition-assigned-slots condition) name)
 244                        (find-slot-default class slot)))
 245               (when (member (car initargs) (condition-slot-initargs slot))
 246                 (return-from condition-reader-function
 247                   (setf (getf (condition-assigned-slots condition)
 248                               name)
 249                         (cadr initargs))))))
 250           val))))
 251 \f
 252 ;;;; MAKE-CONDITION
 253
 254 (defun make-condition (type &rest args)
 255   #!+sb-doc
 256   "Make an instance of a condition object using the specified initargs."
 257   ;; Note: ANSI specifies no exceptional situations in this function.
 258   ;; signalling simple-type-error would not be wrong.
 259   (let* ((type (or (and (symbolp type) (find-classoid type nil))
 260                     type))
 261          (class (typecase type
 262                   (condition-classoid type)
 263                   (class
 264                    ;; Punt to CLOS.
 265                    (return-from make-condition (apply #'make-instance type args)))
 266                   (classoid
 267                    (error 'simple-type-error
 268                           :datum type
 269                           :expected-type 'condition-class
 270                           :format-control "~S is not a condition class."
 271                           :format-arguments (list type)))
 272                   (t
 273                    (error 'simple-type-error
 274                           :datum type
 275                           :expected-type 'condition-class
 276                           :format-control "Bad type argument:~%  ~S"
 277                           :format-arguments (list type)))))
 278          (res (make-condition-object args)))
 279     (setf (%instance-layout res) (classoid-layout class))
 280     ;; Set any class slots with initargs present in this call.
 281     (dolist (cslot (condition-classoid-class-slots class))
 282       (dolist (initarg (condition-slot-initargs cslot))
 283         (let ((val (getf args initarg *empty-condition-slot*)))
 284           (unless (eq val *empty-condition-slot*)
 285             (setf (car (condition-slot-cell cslot)) val)))))
 286     ;; Default any slots with non-constant defaults now.
 287     (dolist (hslot (condition-classoid-hairy-slots class))
 288       (when (dolist (initarg (condition-slot-initargs hslot) t)
 289               (unless (eq (getf args initarg *empty-condition-slot*)
 290                           *empty-condition-slot*)
 291                 (return nil)))
 292         (setf (getf (condition-assigned-slots res) (condition-slot-name hslot))
 293               (find-slot-default class hslot))))
 294     res))
 295 \f
 296 ;;;; DEFINE-CONDITION
 297
 298 (eval-when (:compile-toplevel :load-toplevel :execute)
 299 (defun %compiler-define-condition (name direct-supers layout
 300                                    all-readers all-writers)
 301   (with-single-package-locked-error
 302       (:symbol name "defining ~A as a condition")
 303     (sb!xc:proclaim `(ftype (function (t) t) ,@all-readers))
 304     (sb!xc:proclaim `(ftype (function (t t) t) ,@all-writers))
 305     (multiple-value-bind (class old-layout)
 306         (insured-find-classoid name
 307                                #'condition-classoid-p
 308                                #'make-condition-classoid)
 309       (setf (layout-classoid layout) class)
 310       (setf (classoid-direct-superclasses class)
 311             (mapcar #'find-classoid direct-supers))
 312       (cond ((not old-layout)
 313              (register-layout layout))
 314             ((not *type-system-initialized*)
 315              (setf (layout-classoid old-layout) class)
 316              (setq layout old-layout)
 317              (unless (eq (classoid-layout class) layout)
 318                (register-layout layout)))
 319             ((redefine-layout-warning "current"
 320                                       old-layout
 321                                       "new"
 322                                       (layout-length layout)
 323                                       (layout-inherits layout)
 324                                       (layout-depthoid layout)
 325                                       (layout-n-untagged-slots layout))
 326              (register-layout layout :invalidate t))
 327             ((not (classoid-layout class))
 328              (register-layout layout)))
 329
 330       (setf (layout-info layout)
 331             (locally
 332                 ;; KLUDGE: There's a FIND-CLASS DEFTRANSFORM for constant class
 333                 ;; names which creates fast but non-cold-loadable, non-compact
 334                 ;; code. In this context, we'd rather have compact, cold-loadable
 335                 ;; code. -- WHN 19990928
 336                 (declare (notinline find-classoid))
 337               (layout-info (classoid-layout (find-classoid 'condition)))))
 338
 339       (setf (find-classoid name) class)
 340
 341       ;; Initialize CPL slot.
 342       (setf (condition-classoid-cpl class)
 343             (remove-if-not #'condition-classoid-p
 344                            (std-compute-class-precedence-list class)))))
 345   (values))
 346 ) ; EVAL-WHEN
 347
 348 ;;; Compute the effective slots of CLASS, copying inherited slots and
 349 ;;; destructively modifying direct slots.
 350 ;;;
 351 ;;; FIXME: It'd be nice to explain why it's OK to destructively modify
 352 ;;; direct slots. Presumably it follows from the semantics of
 353 ;;; inheritance and redefinition of conditions, but finding the cite
 354 ;;; and documenting it here would be good. (Or, if this is not in fact
 355 ;;; ANSI-compliant, fixing it would also be good.:-)
 356 (defun compute-effective-slots (class)
 357   (collect ((res (copy-list (condition-classoid-slots class))))
 358     (dolist (sclass (cdr (condition-classoid-cpl class)))
 359       (dolist (sslot (condition-classoid-slots sclass))
 360         (let ((found (find (condition-slot-name sslot) (res)
 361                            :key #'condition-slot-name)))
 362           (cond (found
 363                  (setf (condition-slot-initargs found)
 364                        (union (condition-slot-initargs found)
 365                               (condition-slot-initargs sslot)))
 366                  (unless (condition-slot-initform-p found)
 367                    (setf (condition-slot-initform-p found)
 368                          (condition-slot-initform-p sslot))
 369                    (setf (condition-slot-initform found)
 370                          (condition-slot-initform sslot)))
 371                  (unless (condition-slot-allocation found)
 372                    (setf (condition-slot-allocation found)
 373                          (condition-slot-allocation sslot))))
 374                 (t
 375                  (res (copy-structure sslot)))))))
 376     (res)))
 377
 378 ;;; Early definitions of slot accessor creators.
 379 ;;;
 380 ;;; Slot accessors must be generic functions, but ANSI does not seem
 381 ;;; to specify any of them, and we cannot support it before end of
 382 ;;; warm init. So we use ordinary functions inside SBCL, and switch to
 383 ;;; GFs only at the end of building.
 384 (declaim (notinline install-condition-slot-reader
 385                     install-condition-slot-writer))
 386 (defun install-condition-slot-reader (name condition slot-name)
 387   (declare (ignore condition))
 388   (setf (fdefinition name)
 389         (lambda (condition)
 390           (condition-reader-function condition slot-name))))
 391 (defun install-condition-slot-writer (name condition slot-name)
 392   (declare (ignore condition))
 393   (setf (fdefinition name)
 394         (lambda (new-value condition)
 395           (condition-writer-function condition new-value slot-name))))
 396
 397 (defvar *define-condition-hooks* nil)
 398
 399 (defun %define-condition (name parent-types layout slots documentation
 400                           report default-initargs all-readers all-writers
 401                           source-location)
 402   (with-single-package-locked-error
 403       (:symbol name "defining ~A as a condition")
 404     (%compiler-define-condition name parent-types layout all-readers all-writers)
 405     (sb!c:with-source-location (source-location)
 406       (setf (layout-source-location layout)
 407             source-location))
 408     (let ((class (find-classoid name)))
 409       (setf (condition-classoid-slots class) slots)
 410       (setf (condition-classoid-report class) report)
 411       (setf (condition-classoid-default-initargs class) default-initargs)
 412       (setf (fdocumentation name 'type) documentation)
 413
 414       (dolist (slot slots)
 415
 416         ;; Set up reader and writer functions.
 417         (let ((slot-name (condition-slot-name slot)))
 418           (dolist (reader (condition-slot-readers slot))
 419             (install-condition-slot-reader reader name slot-name))
 420           (dolist (writer (condition-slot-writers slot))
 421             (install-condition-slot-writer writer name slot-name))))
 422
 423       ;; Compute effective slots and set up the class and hairy slots
 424       ;; (subsets of the effective slots.)
 425       (let ((eslots (compute-effective-slots class))
 426             (e-def-initargs
 427              (reduce #'append
 428                      (mapcar #'condition-classoid-default-initargs
 429                            (condition-classoid-cpl class)))))
 430         (dolist (slot eslots)
 431           (ecase (condition-slot-allocation slot)
 432             (:class
 433              (unless (condition-slot-cell slot)
 434                (setf (condition-slot-cell slot)
 435                      (list (if (condition-slot-initform-p slot)
 436                                (let ((initform (condition-slot-initform slot)))
 437                                  (if (functionp initform)
 438                                      (funcall initform)
 439                                      initform))
 440                                *empty-condition-slot*))))
 441              (push slot (condition-classoid-class-slots class)))
 442             ((:instance nil)
 443              (setf (condition-slot-allocation slot) :instance)
 444              (when (or (functionp (condition-slot-initform slot))
 445                        (dolist (initarg (condition-slot-initargs slot) nil)
 446                          (when (functionp (getf e-def-initargs initarg))
 447                            (return t))))
 448                (push slot (condition-classoid-hairy-slots class)))))))
 449       (when (boundp '*define-condition-hooks*)
 450         (dolist (fun *define-condition-hooks*)
 451           (funcall fun class))))
 452     name))
 453
 454 (defmacro define-condition (name (&rest parent-types) (&rest slot-specs)
 455                                  &body options)
 456   #!+sb-doc
 457   "DEFINE-CONDITION Name (Parent-Type*) (Slot-Spec*) Option*
 458    Define NAME as a condition type. This new type inherits slots and its
 459    report function from the specified PARENT-TYPEs. A slot spec is a list of:
 460      (slot-name :reader <rname> :initarg <iname> {Option Value}*
 461
 462    The DEFINE-CLASS slot options :ALLOCATION, :INITFORM, [slot] :DOCUMENTATION
 463    and :TYPE and the overall options :DEFAULT-INITARGS and
 464    [type] :DOCUMENTATION are also allowed.
 465
 466    The :REPORT option is peculiar to DEFINE-CONDITION. Its argument is either
 467    a string or a two-argument lambda or function name. If a function, the
 468    function is called with the condition and stream to report the condition.
 469    If a string, the string is printed.
 470
 471    Condition types are classes, but (as allowed by ANSI and not as described in
 472    CLtL2) are neither STANDARD-OBJECTs nor STRUCTURE-OBJECTs. WITH-SLOTS and
 473    SLOT-VALUE may not be used on condition objects."
 474   (let* ((parent-types (or parent-types '(condition)))
 475          (layout (find-condition-layout name parent-types))
 476          (documentation nil)
 477          (report nil)
 478          (default-initargs ()))
 479     (collect ((slots)
 480               (all-readers nil append)
 481               (all-writers nil append))
 482       (dolist (spec slot-specs)
 483         (when (keywordp spec)
 484           (warn "Keyword slot name indicates probable syntax error:~%  ~S"
 485                 spec))
 486         (let* ((spec (if (consp spec) spec (list spec)))
 487                (slot-name (first spec))
 488                (allocation :instance)
 489                (initform-p nil)
 490                documentation
 491                initform)
 492           (collect ((initargs)
 493                     (readers)
 494                     (writers))
 495             (do ((options (rest spec) (cddr options)))
 496                 ((null options))
 497               (unless (and (consp options) (consp (cdr options)))
 498                 (error "malformed condition slot spec:~%  ~S." spec))
 499               (let ((arg (second options)))
 500                 (case (first options)
 501                   (:reader (readers arg))
 502                   (:writer (writers arg))
 503                   (:accessor
 504                    (readers arg)
 505                    (writers `(setf ,arg)))
 506                   (:initform
 507                    (when initform-p
 508                      (error "more than one :INITFORM in ~S" spec))
 509                    (setq initform-p t)
 510                    (setq initform arg))
 511                   (:initarg (initargs arg))
 512                   (:allocation
 513                    (setq allocation arg))
 514                   (:documentation
 515                    (when documentation
 516                      (error "more than one :DOCUMENTATION in ~S" spec))
 517                    (unless (stringp arg)
 518                      (error "slot :DOCUMENTATION argument is not a string: ~S"
 519                             arg))
 520                    (setq documentation arg))
 521                   (:type)
 522                   (t
 523                    (error "unknown slot option:~%  ~S" (first options))))))
 524
 525             (all-readers (readers))
 526             (all-writers (writers))
 527             (slots `(make-condition-slot
 528                      :name ',slot-name
 529                      :initargs ',(initargs)
 530                      :readers ',(readers)
 531                      :writers ',(writers)
 532                      :initform-p ',initform-p
 533                      :documentation ',documentation
 534                      :initform
 535                      ,(if (sb!xc:constantp initform)
 536                           `',(constant-form-value initform)
 537                           `#'(lambda () ,initform)))))))
 538
 539       (dolist (option options)
 540         (unless (consp option)
 541           (error "bad option:~%  ~S" option))
 542         (case (first option)
 543           (:documentation (setq documentation (second option)))
 544           (:report
 545            (let ((arg (second option)))
 546              (setq report
 547                    (if (stringp arg)
 548                        `#'(lambda (condition stream)
 549                           (declare (ignore condition))
 550                           (write-string ,arg stream))
 551                        `#'(lambda (condition stream)
 552                           (funcall #',arg condition stream))))))
 553           (:default-initargs
 554            (do ((initargs (rest option) (cddr initargs)))
 555                ((endp initargs))
 556              (let ((val (second initargs)))
 557                (setq default-initargs
 558                      (list* `',(first initargs)
 559                             (if (sb!xc:constantp val)
 560                                 `',(constant-form-value val)
 561                                 `#'(lambda () ,val))
 562                             default-initargs)))))
 563           (t
 564            (error "unknown option: ~S" (first option)))))
 565
 566       `(progn
 567          (eval-when (:compile-toplevel)
 568            (%compiler-define-condition ',name ',parent-types ',layout
 569                                        ',(all-readers) ',(all-writers)))
 570          (eval-when (:load-toplevel :execute)
 571            (%define-condition ',name
 572                               ',parent-types
 573                               ',layout
 574                               (list ,@(slots))
 575                               ,documentation
 576                               ,report
 577                               (list ,@default-initargs)
 578                               ',(all-readers)
 579                               ',(all-writers)
 580                               (sb!c:source-location)))))))
 581 \f
 582 ;;;; various CONDITIONs specified by ANSI
 583
 584 (define-condition serious-condition (condition) ())
 585
 586 (define-condition error (serious-condition) ())
 587
 588 (define-condition warning (condition) ())
 589 (define-condition style-warning (warning) ())
 590
 591 (defun simple-condition-printer (condition stream)
 592   (apply #'format
 593          stream
 594          (simple-condition-format-control condition)
 595          (simple-condition-format-arguments condition)))
 596
 597 (define-condition simple-condition ()
 598   ((format-control :reader simple-condition-format-control
 599                    :initarg :format-control
 600                    :type format-control)
 601    (format-arguments :reader simple-condition-format-arguments
 602                      :initarg :format-arguments
 603                      :initform '()
 604                      :type list))
 605   (:report simple-condition-printer))
 606
 607 (define-condition simple-warning (simple-condition warning) ())
 608
 609 (define-condition simple-error (simple-condition error) ())
 610
 611 (define-condition storage-condition (serious-condition) ())
 612
 613 (define-condition type-error (error)
 614   ((datum :reader type-error-datum :initarg :datum)
 615    (expected-type :reader type-error-expected-type :initarg :expected-type))
 616   (:report
 617    (lambda (condition stream)
 618      (format stream
 619              "~@<The value ~2I~:_~S ~I~_is not of type ~2I~_~S.~:>"
 620              (type-error-datum condition)
 621              (type-error-expected-type condition)))))
 622
 623 ;;; not specified by ANSI, but too useful not to have around.
 624 (define-condition simple-style-warning (simple-condition style-warning) ())
 625 (define-condition simple-type-error (simple-condition type-error) ())
 626
 627 (define-condition program-error (error) ())
 628 (define-condition parse-error   (error) ())
 629 (define-condition control-error (error) ())
 630 (define-condition stream-error  (error)
 631   ((stream :reader stream-error-stream :initarg :stream)))
 632
 633 (define-condition end-of-file (stream-error) ()
 634   (:report
 635    (lambda (condition stream)
 636      (format stream
 637              "end of file on ~S"
 638              (stream-error-stream condition)))))
 639
 640 (define-condition closed-stream-error (stream-error) ()
 641   (:report
 642    (lambda (condition stream)
 643      (format stream "~S is closed" (stream-error-stream condition)))))
 644
 645 (define-condition file-error (error)
 646   ((pathname :reader file-error-pathname :initarg :pathname))
 647   (:report
 648    (lambda (condition stream)
 649      (format stream "error on file ~S" (file-error-pathname condition)))))
 650
 651 (define-condition package-error (error)
 652   ((package :reader package-error-package :initarg :package)))
 653
 654 (define-condition cell-error (error)
 655   ((name :reader cell-error-name :initarg :name)))
 656
 657 (def!method print-object ((condition cell-error) stream)
 658   (if (and *print-escape* (slot-boundp condition 'name))
 659       (print-unreadable-object (condition stream :type t :identity t)
 660         (princ (cell-error-name condition) stream))
 661       (call-next-method)))
 662
 663 (define-condition unbound-variable (cell-error) ()
 664   (:report
 665    (lambda (condition stream)
 666      (format stream
 667              "The variable ~S is unbound."
 668              (cell-error-name condition)))))
 669
 670 (define-condition undefined-function (cell-error) ()
 671   (:report
 672    (lambda (condition stream)
 673      (format stream
 674              "The function ~S is undefined."
 675              (cell-error-name condition)))))
 676
 677 (define-condition special-form-function (undefined-function) ()
 678   (:report
 679    (lambda (condition stream)
 680      (format stream
 681              "Cannot FUNCALL the SYMBOL-FUNCTION of special operator ~S."
 682              (cell-error-name condition)))))
 683
 684 (define-condition arithmetic-error (error)
 685   ((operation :reader arithmetic-error-operation
 686               :initarg :operation
 687               :initform nil)
 688    (operands :reader arithmetic-error-operands
 689              :initarg :operands))
 690   (:report (lambda (condition stream)
 691              (format stream
 692                      "arithmetic error ~S signalled"
 693                      (type-of condition))
 694              (when (arithmetic-error-operation condition)
 695                (format stream
 696                        "~%Operation was ~S, operands ~S."
 697                        (arithmetic-error-operation condition)
 698                        (arithmetic-error-operands condition))))))
 699
 700 (define-condition division-by-zero         (arithmetic-error) ())
 701 (define-condition floating-point-overflow  (arithmetic-error) ())
 702 (define-condition floating-point-underflow (arithmetic-error) ())
 703 (define-condition floating-point-inexact   (arithmetic-error) ())
 704 (define-condition floating-point-invalid-operation (arithmetic-error) ())
 705
 706 (define-condition print-not-readable (error)
 707   ((object :reader print-not-readable-object :initarg :object))
 708   (:report
 709    (lambda (condition stream)
 710      (let ((obj (print-not-readable-object condition))
 711            (*print-array* nil))
 712        (format stream "~S cannot be printed readably." obj)))))
 713
 714 (define-condition reader-error (parse-error stream-error) ()
 715   (:report (lambda (condition stream)
 716              (%report-reader-error condition stream))))
 717
 718 ;;; a READER-ERROR whose REPORTing is controlled by FORMAT-CONTROL and
 719 ;;; FORMAT-ARGS (the usual case for READER-ERRORs signalled from
 720 ;;; within SBCL itself)
 721 ;;;
 722 ;;; (Inheriting CL:SIMPLE-CONDITION here isn't quite consistent with
 723 ;;; the letter of the ANSI spec: this is not a condition signalled by
 724 ;;; SIGNAL when a format-control is supplied by the function's first
 725 ;;; argument. It seems to me (WHN) to be basically in the spirit of
 726 ;;; the spec, but if not, it'd be straightforward to do our own
 727 ;;; DEFINE-CONDITION SB-INT:SIMPLISTIC-CONDITION with
 728 ;;; FORMAT-CONTROL and FORMAT-ARGS slots, and use that condition in
 729 ;;; place of CL:SIMPLE-CONDITION here.)
 730 (define-condition simple-reader-error (reader-error simple-condition)
 731   ()
 732   (:report (lambda (condition stream)
 733              (%report-reader-error condition stream :simple t))))
 734
 735 ;;; base REPORTing of a READER-ERROR
 736 ;;;
 737 ;;; When SIMPLE, we expect and use SIMPLE-CONDITION-ish FORMAT-CONTROL
 738 ;;; and FORMAT-ARGS slots.
 739 (defun %report-reader-error (condition stream &key simple)
 740   (let* ((error-stream (stream-error-stream condition))
 741          (pos (file-position-or-nil-for-error error-stream)))
 742     (let (lineno colno)
 743       (when (and pos
 744                  (< pos sb!xc:array-dimension-limit)
 745                  ;; KLUDGE: lseek() (which is what FILE-POSITION
 746                  ;; reduces to on file-streams) is undefined on
 747                  ;; "some devices", which in practice means that it
 748                  ;; can claim to succeed on /dev/stdin on Darwin
 749                  ;; and Solaris.  This is obviously bad news,
 750                  ;; because the READ-SEQUENCE below will then
 751                  ;; block, not complete, and the report will never
 752                  ;; be printed.  As a workaround, we exclude
 753                  ;; interactive streams from this attempt to report
 754                  ;; positions.  -- CSR, 2003-08-21
 755                  (not (interactive-stream-p error-stream))
 756                  (file-position error-stream :start))
 757         (let ((string
 758                (make-string pos
 759                             :element-type (stream-element-type
 760                                            error-stream))))
 761           (when (= pos (read-sequence string error-stream))
 762             (setq lineno (1+ (count #\Newline string))
 763                   colno (- pos
 764                            (or (position #\Newline string :from-end t) -1)
 765                            1))))
 766         (file-position-or-nil-for-error error-stream pos))
 767       (pprint-logical-block (stream nil)
 768         (format stream
 769                 "~S ~@[at ~W ~]~
 770                     ~@[(line ~W~]~@[, column ~W) ~]~
 771                     on ~S"
 772                 (class-name (class-of condition))
 773                 pos lineno colno error-stream)
 774         (when simple
 775           (format stream ":~2I~_~?"
 776                   (simple-condition-format-control condition)
 777                   (simple-condition-format-arguments condition)))))))
 778 \f
 779 ;;;; special SBCL extension conditions
 780
 781 ;;; an error apparently caused by a bug in SBCL itself
 782 ;;;
 783 ;;; Note that we don't make any serious effort to use this condition
 784 ;;; for *all* errors in SBCL itself. E.g. type errors and array
 785 ;;; indexing errors can occur in functions called from SBCL code, and
 786 ;;; will just end up as ordinary TYPE-ERROR or invalid index error,
 787 ;;; because the signalling code has no good way to know that the
 788 ;;; underlying problem is a bug in SBCL. But in the fairly common case
 789 ;;; that the signalling code does know that it's found a bug in SBCL,
 790 ;;; this condition is appropriate, reusing boilerplate and helping
 791 ;;; users to recognize it as an SBCL bug.
 792 (define-condition bug (simple-error)
 793   ()
 794   (:report
 795    (lambda (condition stream)
 796      (format stream
 797              "~@<  ~? ~:@_~?~:>"
 798              (simple-condition-format-control condition)
 799              (simple-condition-format-arguments condition)
 800              "~@<This is probably a bug in SBCL itself. (Alternatively, ~
 801               SBCL might have been corrupted by bad user code, e.g. by an ~
 802               undefined Lisp operation like ~S, or by stray pointers from ~
 803               alien code or from unsafe Lisp code; or there might be a bug ~
 804               in the OS or hardware that SBCL is running on.) If it seems to ~
 805               be a bug in SBCL itself, the maintainers would like to know ~
 806               about it. Bug reports are welcome on the SBCL ~
 807               mailing lists, which you can find at ~
 808               <http://sbcl.sourceforge.net/>.~:@>"
 809              '((fmakunbound 'compile))))))
 810
 811 (define-condition simple-storage-condition (storage-condition simple-condition)
 812   ())
 813
 814 ;;; a condition for use in stubs for operations which aren't supported
 815 ;;; on some platforms
 816 ;;;
 817 ;;; E.g. in sbcl-0.7.0.5, it might be appropriate to do something like
 818 ;;;   #-(or freebsd linux)
 819 ;;;   (defun load-foreign (&rest rest)
 820 ;;;     (error 'unsupported-operator :name 'load-foreign))
 821 ;;;   #+(or freebsd linux)
 822 ;;;   (defun load-foreign ... actual definition ...)
 823 ;;; By signalling a standard condition in this case, we make it
 824 ;;; possible for test code to distinguish between (1) intentionally
 825 ;;; unimplemented and (2) unintentionally just screwed up somehow.
 826 ;;; (Before this condition was defined, test code tried to deal with
 827 ;;; this by checking for FBOUNDP, but that didn't work reliably. In
 828 ;;; sbcl-0.7.0, a package screwup left the definition of
 829 ;;; LOAD-FOREIGN in the wrong package, so it was unFBOUNDP even on
 830 ;;; architectures where it was supposed to be supported, and the
 831 ;;; regression tests cheerfully passed because they assumed that
 832 ;;; unFBOUNDPness meant they were running on an system which didn't
 833 ;;; support the extension.)
 834 (define-condition unsupported-operator (simple-error) ())
 835 \f
 836 ;;; (:ansi-cl :function remove)
 837 ;;; (:ansi-cl :section (a b c))
 838 ;;; (:ansi-cl :glossary "similar")
 839 ;;;
 840 ;;; (:sbcl :node "...")
 841 ;;; (:sbcl :variable *ed-functions*)
 842 ;;;
 843 ;;; FIXME: this is not the right place for this.
 844 (defun print-reference (reference stream)
 845   (ecase (car reference)
 846     (:amop
 847      (format stream "AMOP")
 848      (format stream ", ")
 849      (destructuring-bind (type data) (cdr reference)
 850        (ecase type
 851          (:readers "Readers for ~:(~A~) Metaobjects"
 852                    (substitute #\  #\- (symbol-name data)))
 853          (:initialization
 854           (format stream "Initialization of ~:(~A~) Metaobjects"
 855                   (substitute #\  #\- (symbol-name data))))
 856          (:generic-function (format stream "Generic Function ~S" data))
 857          (:function (format stream "Function ~S" data))
 858          (:section (format stream "Section ~{~D~^.~}" data)))))
 859     (:ansi-cl
 860      (format stream "The ANSI Standard")
 861      (format stream ", ")
 862      (destructuring-bind (type data) (cdr reference)
 863        (ecase type
 864          (:function (format stream "Function ~S" data))
 865          (:special-operator (format stream "Special Operator ~S" data))
 866          (:macro (format stream "Macro ~S" data))
 867          (:section (format stream "Section ~{~D~^.~}" data))
 868          (:glossary (format stream "Glossary entry for ~S" data))
 869          (:issue (format stream "writeup for Issue ~A" data)))))
 870     (:sbcl
 871      (format stream "The SBCL Manual")
 872      (format stream ", ")
 873      (destructuring-bind (type data) (cdr reference)
 874        (ecase type
 875          (:node (format stream "Node ~S" data))
 876          (:variable (format stream "Variable ~S" data))
 877          (:function (format stream "Function ~S" data)))))
 878     ;; FIXME: other documents (e.g. CLIM, Franz documentation :-)
 879     ))
 880 (define-condition reference-condition ()
 881   ((references :initarg :references :reader reference-condition-references)))
 882 (defvar *print-condition-references* t)
 883 (def!method print-object :around ((o reference-condition) s)
 884   (call-next-method)
 885   (unless (or *print-escape* *print-readably*)
 886     (when (and *print-condition-references*
 887                (reference-condition-references o))
 888       (format s "~&See also:~%")
 889       (pprint-logical-block (s nil :per-line-prefix "  ")
 890         (do* ((rs (reference-condition-references o) (cdr rs))
 891               (r (car rs) (car rs)))
 892              ((null rs))
 893           (print-reference r s)
 894           (unless (null (cdr rs))
 895             (terpri s)))))))
 896
 897 (define-condition simple-reference-error (reference-condition simple-error)
 898   ())
 899
 900 (define-condition simple-reference-warning (reference-condition simple-warning)
 901   ())
 902
 903 (define-condition duplicate-definition (reference-condition warning)
 904   ((name :initarg :name :reader duplicate-definition-name))
 905   (:report (lambda (c s)
 906              (format s "~@<Duplicate definition for ~S found in ~
 907                         one file.~@:>"
 908                      (duplicate-definition-name c))))
 909   (:default-initargs :references (list '(:ansi-cl :section (3 2 2 3)))))
 910
 911 (define-condition constant-modified (reference-condition warning)
 912   ((fun-name :initarg :fun-name :reader constant-modified-fun-name))
 913   (:report (lambda (c s)
 914              (format s "~@<Destructive function ~S called on ~
 915                         constant data.~@:>"
 916                      (constant-modified-fun-name c))))
 917   (:default-initargs :references (list '(:ansi-cl :special-operator quote)
 918                                        '(:ansi-cl :section (3 2 2 3)))))
 919
 920 (define-condition package-at-variance (reference-condition simple-warning)
 921   ()
 922   (:default-initargs :references (list '(:ansi-cl :macro defpackage))))
 923
 924 (define-condition defconstant-uneql (reference-condition error)
 925   ((name :initarg :name :reader defconstant-uneql-name)
 926    (old-value :initarg :old-value :reader defconstant-uneql-old-value)
 927    (new-value :initarg :new-value :reader defconstant-uneql-new-value))
 928   (:report
 929    (lambda (condition stream)
 930      (format stream
 931              "~@<The constant ~S is being redefined (from ~S to ~S)~@:>"
 932              (defconstant-uneql-name condition)
 933              (defconstant-uneql-old-value condition)
 934              (defconstant-uneql-new-value condition))))
 935   (:default-initargs :references (list '(:ansi-cl :macro defconstant)
 936                                        '(:sbcl :node "Idiosyncrasies"))))
 937
 938 (define-condition array-initial-element-mismatch
 939     (reference-condition simple-warning)
 940   ()
 941   (:default-initargs
 942       :references (list
 943                    '(:ansi-cl :function make-array)
 944                    '(:ansi-cl :function sb!xc:upgraded-array-element-type))))
 945
 946 (define-condition type-warning (reference-condition simple-warning)
 947   ()
 948   (:default-initargs :references (list '(:sbcl :node "Handling of Types"))))
 949 (define-condition type-style-warning (reference-condition simple-style-warning)
 950   ()
 951   (:default-initargs :references (list '(:sbcl :node "Handling of Types"))))
 952
 953 (define-condition local-argument-mismatch (reference-condition simple-warning)
 954   ()
 955   (:default-initargs :references (list '(:ansi-cl :section (3 2 2 3)))))
 956
 957 (define-condition format-args-mismatch (reference-condition)
 958   ()
 959   (:default-initargs :references (list '(:ansi-cl :section (22 3 10 2)))))
 960
 961 (define-condition format-too-few-args-warning
 962     (format-args-mismatch simple-warning)
 963   ())
 964 (define-condition format-too-many-args-warning
 965     (format-args-mismatch simple-style-warning)
 966   ())
 967
 968 (define-condition implicit-generic-function-warning (style-warning)
 969   ((name :initarg :name :reader implicit-generic-function-name))
 970   (:report
 971    (lambda (condition stream)
 972      (format stream "~@<Implicitly creating new generic function ~S.~:@>"
 973              (implicit-generic-function-name condition)))))
 974
 975 (define-condition extension-failure (reference-condition simple-error)
 976   ())
 977
 978 (define-condition structure-initarg-not-keyword
 979     (reference-condition simple-style-warning)
 980   ()
 981   (:default-initargs :references (list '(:ansi-cl :section (2 4 8 13)))))
 982
 983 #!+sb-package-locks
 984 (progn
 985
 986 (define-condition package-lock-violation (reference-condition package-error)
 987   ((format-control :initform nil :initarg :format-control
 988                    :reader package-error-format-control)
 989    (format-arguments :initform nil :initarg :format-arguments
 990                      :reader package-error-format-arguments))
 991   (:report
 992    (lambda (condition stream)
 993      (let ((control (package-error-format-control condition)))
 994        (if control
 995            (apply #'format stream
 996                   (format nil "~~@<Lock on package ~A violated when ~A.~~:@>"
 997                           (package-name (package-error-package condition))
 998                           control)
 999                   (package-error-format-arguments condition))
1000            (format stream "~@<Lock on package ~A violated.~:@>"
1001                    (package-name (package-error-package condition)))))))
1002   ;; no :default-initargs -- reference-stuff provided by the
1003   ;; signalling form in target-package.lisp
1004   #!+sb-doc
1005   (:documentation
1006    "Subtype of CL:PACKAGE-ERROR. A subtype of this error is signalled
1007 when a package-lock is violated."))
1008
1009 (define-condition package-locked-error (package-lock-violation) ()
1010   #!+sb-doc
1011   (:documentation
1012    "Subtype of SB-EXT:PACKAGE-LOCK-VIOLATION. An error of this type is
1013 signalled when an operation on a package violates a package lock."))
1014
1015 (define-condition symbol-package-locked-error (package-lock-violation)
1016   ((symbol :initarg :symbol :reader package-locked-error-symbol))
1017   #!+sb-doc
1018   (:documentation
1019    "Subtype of SB-EXT:PACKAGE-LOCK-VIOLATION. An error of this type is
1020 signalled when an operation on a symbol violates a package lock. The
1021 symbol that caused the violation is accessed by the function
1022 SB-EXT:PACKAGE-LOCKED-ERROR-SYMBOL."))
1023
1024 ) ; progn
1025
1026 (define-condition undefined-alien-error (cell-error) ()
1027   (:report
1028    (lambda (condition stream)
1029      (if (slot-boundp condition 'name)
1030          (format stream "Undefined alien: ~S" (cell-error-name condition))
1031          (format stream "Undefined alien symbol.")))))
1032
1033 (define-condition undefined-alien-variable-error (undefined-alien-error) ()
1034   (:report
1035    (lambda (condition stream)
1036      (declare (ignore condition))
1037      (format stream "Attempt to access an undefined alien variable."))))
1038
1039 (define-condition undefined-alien-function-error (undefined-alien-error) ()
1040   (:report
1041    (lambda (condition stream)
1042      (declare (ignore condition))
1043      (format stream "Attempt to call an undefined alien function."))))
1044
1045 \f
1046 ;;;; various other (not specified by ANSI) CONDITIONs
1047 ;;;;
1048 ;;;; These might logically belong in other files; they're here, after
1049 ;;;; setup of CONDITION machinery, only because that makes it easier to
1050 ;;;; get cold init to work.
1051
1052 ;;; OAOOM warning: see cross-condition.lisp
1053 (define-condition encapsulated-condition (condition)
1054   ((condition :initarg :condition :reader encapsulated-condition)))
1055
1056 (define-condition values-type-error (type-error)
1057   ()
1058   (:report
1059    (lambda (condition stream)
1060      (format stream
1061              "~@<The values set ~2I~:_[~{~S~^ ~}] ~I~_is not of type ~2I~_~S.~:>"
1062              (type-error-datum condition)
1063              (type-error-expected-type condition)))))
1064
1065 ;;; KLUDGE: a condition for floating point errors when we can't or
1066 ;;; won't figure out what type they are. (In FreeBSD and OpenBSD we
1067 ;;; don't know how, at least as of sbcl-0.6.7; in Linux we probably
1068 ;;; know how but the old code was broken by the conversion to POSIX
1069 ;;; signal handling and hasn't been fixed as of sbcl-0.6.7.)
1070 ;;;
1071 ;;; FIXME: Perhaps this should also be a base class for all
1072 ;;; floating point exceptions?
1073 (define-condition floating-point-exception (arithmetic-error)
1074   ((flags :initarg :traps
1075           :initform nil
1076           :reader floating-point-exception-traps))
1077   (:report (lambda (condition stream)
1078              (format stream
1079                      "An arithmetic error ~S was signalled.~%"
1080                      (type-of condition))
1081              (let ((traps (floating-point-exception-traps condition)))
1082                (if traps
1083                    (format stream
1084                            "Trapping conditions are: ~%~{ ~S~^~}~%"
1085                            traps)
1086                    (write-line
1087                     "No traps are enabled? How can this be?"
1088                     stream))))))
1089
1090 (define-condition invalid-array-index-error (type-error)
1091   ((array :initarg :array :reader invalid-array-index-error-array)
1092    (axis :initarg :axis :reader invalid-array-index-error-axis))
1093   (:report
1094    (lambda (condition stream)
1095      (let ((array (invalid-array-index-error-array condition)))
1096        (format stream "Index ~W out of bounds for ~@[axis ~W of ~]~S, ~
1097                        should be nonnegative and <~W."
1098                (type-error-datum condition)
1099                (when (> (array-rank array) 1)
1100                  (invalid-array-index-error-axis condition))
1101                (type-of array)
1102                ;; Extract the bound from (INTEGER 0 (BOUND))
1103                (caaddr (type-error-expected-type condition)))))))
1104
1105 (define-condition invalid-array-error (reference-condition type-error) ()
1106   (:report
1107    (lambda (condition stream)
1108      (let ((*print-array* nil))
1109        (format stream
1110                "~@<Displaced array originally of type ~S has been invalidated ~
1111                 due its displaced-to array ~S having become too small to hold ~
1112                 it: the displaced array's dimensions have all been set to zero ~
1113                 to trap accesses to it.~:@>"
1114                (type-error-expected-type condition)
1115                (array-displacement (type-error-datum condition))))))
1116   (:default-initargs
1117       :references
1118       (list '(:ansi-cl :function adjust-array))))
1119
1120 (define-condition index-too-large-error (type-error)
1121   ()
1122   (:report
1123    (lambda (condition stream)
1124      (format stream
1125              "The index ~S is too large."
1126              (type-error-datum condition)))))
1127
1128 (define-condition bounding-indices-bad-error (reference-condition type-error)
1129   ((object :reader bounding-indices-bad-object :initarg :object))
1130   (:report
1131    (lambda (condition stream)
1132      (let* ((datum (type-error-datum condition))
1133             (start (car datum))
1134             (end (cdr datum))
1135             (object (bounding-indices-bad-object condition)))
1136        (etypecase object
1137          (sequence
1138           (format stream
1139                   "The bounding indices ~S and ~S are bad ~
1140                    for a sequence of length ~S."
1141                   start end (length object)))
1142          (array
1143           ;; from WITH-ARRAY-DATA
1144           (format stream
1145                   "The START and END parameters ~S and ~S are ~
1146                    bad for an array of total size ~S."
1147                   start end (array-total-size object)))))))
1148   (:default-initargs
1149       :references
1150       (list '(:ansi-cl :glossary "bounding index designator")
1151             '(:ansi-cl :issue "SUBSEQ-OUT-OF-BOUNDS:IS-AN-ERROR"))))
1152
1153 (define-condition nil-array-accessed-error (reference-condition type-error)
1154   ()
1155   (:report (lambda (condition stream)
1156              (declare (ignore condition))
1157              (format stream
1158                      "An attempt to access an array of element-type ~
1159                       NIL was made.  Congratulations!")))
1160   (:default-initargs
1161       :references (list '(:ansi-cl :function sb!xc:upgraded-array-element-type)
1162                         '(:ansi-cl :section (15 1 2 1))
1163                         '(:ansi-cl :section (15 1 2 2)))))
1164
1165 (define-condition namestring-parse-error (parse-error)
1166   ((complaint :reader namestring-parse-error-complaint :initarg :complaint)
1167    (args :reader namestring-parse-error-args :initarg :args :initform nil)
1168    (namestring :reader namestring-parse-error-namestring :initarg :namestring)
1169    (offset :reader namestring-parse-error-offset :initarg :offset))
1170   (:report
1171    (lambda (condition stream)
1172      (format stream
1173              "parse error in namestring: ~?~%  ~A~%  ~V@T^"
1174              (namestring-parse-error-complaint condition)
1175              (namestring-parse-error-args condition)
1176              (namestring-parse-error-namestring condition)
1177              (namestring-parse-error-offset condition)))))
1178
1179 (define-condition simple-package-error (simple-condition package-error) ())
1180
1181 (define-condition simple-reader-package-error (simple-reader-error) ())
1182
1183 (define-condition reader-eof-error (end-of-file)
1184   ((context :reader reader-eof-error-context :initarg :context))
1185   (:report
1186    (lambda (condition stream)
1187      (format stream
1188              "unexpected end of file on ~S ~A"
1189              (stream-error-stream condition)
1190              (reader-eof-error-context condition)))))
1191
1192 (define-condition reader-impossible-number-error (simple-reader-error)
1193   ((error :reader reader-impossible-number-error-error :initarg :error))
1194   (:report
1195    (lambda (condition stream)
1196      (let ((error-stream (stream-error-stream condition)))
1197        (format stream
1198                "READER-ERROR ~@[at ~W ~]on ~S:~%~?~%Original error: ~A"
1199                (file-position-or-nil-for-error error-stream) error-stream
1200                (simple-condition-format-control condition)
1201                (simple-condition-format-arguments condition)
1202                (reader-impossible-number-error-error condition))))))
1203
1204 (define-condition standard-readtable-modified-error (reference-condition error)
1205   ((operation :initarg :operation :reader standard-readtable-modified-operation))
1206   (:report (lambda (condition stream)
1207              (format stream "~S would modify the standard readtable."
1208                      (standard-readtable-modified-operation condition))))
1209   (:default-initargs :references `((:ansi-cl :section (2 1 1 2))
1210                                    (:ansi-cl :glossary "standard readtable"))))
1211
1212 (define-condition standard-pprint-dispatch-table-modified-error
1213     (reference-condition error)
1214   ((operation :initarg :operation
1215               :reader standard-pprint-dispatch-table-modified-operation))
1216   (:report (lambda (condition stream)
1217              (format stream "~S would modify the standard pprint dispatch table."
1218                      (standard-pprint-dispatch-table-modified-operation
1219                       condition))))
1220   (:default-initargs
1221       :references `((:ansi-cl :glossary "standard pprint dispatch table"))))
1222
1223 (define-condition timeout (serious-condition)
1224   ((seconds :initarg :seconds :initform nil :reader timeout-seconds))
1225   (:report (lambda (condition stream)
1226              (format stream "Timeout occurred~@[ after ~A seconds~]."
1227                      (timeout-seconds condition)))))
1228
1229 (define-condition io-timeout (stream-error timeout)
1230   ((direction :reader io-timeout-direction :initarg :direction))
1231   (:report
1232    (lambda (condition stream)
1233      (declare (type stream stream))
1234      (format stream
1235              "I/O timeout ~(~A~)ing ~S."
1236              (io-timeout-direction condition)
1237              (stream-error-stream condition)))))
1238
1239 (define-condition deadline-timeout (timeout) ()
1240   (:report (lambda (condition stream)
1241              (format stream "A deadline was reached after ~A seconds."
1242                      (timeout-seconds condition)))))
1243
1244 (define-condition declaration-type-conflict-error (reference-condition
1245                                                    simple-error)
1246   ()
1247   (:default-initargs
1248       :format-control "symbol ~S cannot be both the name of a type and the name of a declaration"
1249     :references (list '(:ansi-cl :section (3 8 21)))))
1250
1251 ;;; Single stepping conditions
1252
1253 (define-condition step-condition ()
1254   ((form :initarg :form :reader step-condition-form))
1255
1256   #!+sb-doc
1257   (:documentation "Common base class of single-stepping conditions.
1258 STEP-CONDITION-FORM holds a string representation of the form being
1259 stepped."))
1260
1261 #!+sb-doc
1262 (setf (fdocumentation 'step-condition-form 'function)
1263       "Form associated with the STEP-CONDITION.")
1264
1265 (define-condition step-form-condition (step-condition)
1266   ((args :initarg :args :reader step-condition-args))
1267   (:report
1268    (lambda (condition stream)
1269      (let ((*print-circle* t)
1270            (*print-pretty* t)
1271            (*print-readably* nil))
1272        (format stream
1273                  "Evaluating call:~%~<  ~@;~A~:>~%~
1274                   ~:[With arguments:~%~{  ~S~%~}~;With unknown arguments~]~%"
1275                (list (step-condition-form condition))
1276                (eq (step-condition-args condition) :unknown)
1277                (step-condition-args condition)))))
1278   #!+sb-doc
1279   (:documentation "Condition signalled by code compiled with
1280 single-stepping information when about to execute a form.
1281 STEP-CONDITION-FORM holds the form, STEP-CONDITION-PATHNAME holds the
1282 pathname of the original file or NIL, and STEP-CONDITION-SOURCE-PATH
1283 holds the source-path to the original form within that file or NIL.
1284 Associated with this condition are always the restarts STEP-INTO,
1285 STEP-NEXT, and STEP-CONTINUE."))
1286
1287 (define-condition step-result-condition (step-condition)
1288   ((result :initarg :result :reader step-condition-result)))
1289
1290 #!+sb-doc
1291 (setf (fdocumentation 'step-condition-result 'function)
1292       "Return values associated with STEP-VALUES-CONDITION as a list,
1293 or the variable value associated with STEP-VARIABLE-CONDITION.")
1294
1295 (define-condition step-values-condition (step-result-condition)
1296   ()
1297   #!+sb-doc
1298   (:documentation "Condition signalled by code compiled with
1299 single-stepping information after executing a form.
1300 STEP-CONDITION-FORM holds the form, and STEP-CONDITION-RESULT holds
1301 the values returned by the form as a list. No associated restarts."))
1302
1303 (define-condition step-finished-condition (step-condition)
1304   ()
1305   (:report
1306    (lambda (condition stream)
1307      (declare (ignore condition))
1308      (format stream "Returning from STEP")))
1309   #!+sb-doc
1310   (:documentation "Condition signaled when STEP returns."))
1311 \f
1312 ;;; A knob for muffling warnings, mostly for use while loading files.
1313 (defvar *muffled-warnings* 'uninteresting-redefinition
1314   "A type that ought to specify a subtype of WARNING.  Whenever a
1315 warning is signaled, if the warning if of this type and is not
1316 handled by any other handler, it will be muffled.")
1317 \f
1318 ;;; Various STYLE-WARNING signaled in the system.
1319 ;; For the moment, we're only getting into the details for function
1320 ;; redefinitions, but other redefinitions could be done later
1321 ;; (e.g. methods).
1322 (define-condition redefinition-warning (style-warning)
1323   ())
1324
1325 (define-condition function-redefinition-warning (redefinition-warning)
1326   ((name :initarg :name :reader function-redefinition-warning-name)
1327    (old :initarg :old :reader function-redefinition-warning-old-fdefinition)
1328    ;; For DEFGENERIC and perhaps others, the redefinition
1329    ;; destructively modifies the original, rather than storing a new
1330    ;; object, so there's no NEW here, but only in subclasses.
1331    ))
1332
1333 (define-condition redefinition-with-defun (function-redefinition-warning)
1334   ((new :initarg :new :reader redefinition-with-defun-new-fdefinition)
1335    ;; KLUDGE: it would be nice to fix the unreasonably late
1336    ;; back-patching of DEBUG-SOURCEs in the DEBUG-INFO during
1337    ;; fasloading and just use the new fdefinition, but for the moment
1338    ;; we'll compare the SOURCE-LOCATION created during DEFUN with the
1339    ;; previous DEBUG-SOURCE.
1340    (new-location :initarg :new-location
1341               :reader redefinition-with-defun-new-location))
1342   (:report (lambda (warning stream)
1343              (format stream "redefining ~S in DEFUN"
1344                      (function-redefinition-warning-name warning)))))
1345
1346 (define-condition redefinition-with-defgeneric (function-redefinition-warning)
1347   ((new-location :initarg :new-location
1348                  :reader redefinition-with-defgeneric-new-location))
1349   (:report (lambda (warning stream)
1350              (format stream "redefining ~S in DEFGENERIC"
1351                      (function-redefinition-warning-name warning)))))
1352
1353 (define-condition redefinition-with-defmethod (redefinition-warning)
1354   ((gf :initarg :generic-function
1355        :reader redefinition-with-defmethod-generic-function)
1356    (qualifiers :initarg :qualifiers
1357                :reader redefinition-with-defmethod-qualifiers)
1358    (specializers :initarg :specializers
1359                  :reader redefinition-with-defmethod-specializers)
1360    (new-location :initarg :new-location
1361                  :reader redefinition-with-defmethod-new-location)
1362    (old-method :initarg :old-method
1363                :reader redefinition-with-defmethod-old-method))
1364   (:report (lambda (warning stream)
1365              (format stream "redefining ~S~{ ~S~} ~S in DEFMETHOD"
1366                      (redefinition-with-defmethod-generic-function warning)
1367                      (redefinition-with-defmethod-qualifiers warning)
1368                      (redefinition-with-defmethod-specializers warning)))))
1369
1370 ;; FIXME: see the FIXMEs in defmacro.lisp, then maybe instantiate this.
1371 (define-condition redefinition-with-defmacro (function-redefinition-warning)
1372   ())
1373
1374 ;; Here are a few predicates for what people might find interesting
1375 ;; about redefinitions.
1376
1377 ;; DEFUN can replace a generic function with an ordinary function.
1378 ;; (Attempting to replace an ordinary function with a generic one
1379 ;; causes an error, though.)
1380 (defun redefinition-replaces-generic-function-p (warning)
1381   (and (typep warning 'redefinition-with-defun)
1382        (typep (function-redefinition-warning-old-fdefinition warning)
1383               'generic-function)))
1384
1385 (defun redefinition-replaces-compiled-function-with-interpreted-p (warning)
1386   (and (typep warning 'redefinition-with-defun)
1387        (compiled-function-p
1388         (function-redefinition-warning-old-fdefinition warning))
1389        (not (compiled-function-p
1390              (redefinition-with-defun-new-fdefinition warning)))))
1391
1392 ;; Most people seem to agree that re-running a DEFUN in a file is
1393 ;; completely uninteresting.
1394 (defun uninteresting-ordinary-function-redefinition-p (warning)
1395   ;; OAOO violation: this duplicates code in SB-INTROSPECT.
1396   ;; Additionally, there are some functions that aren't
1397   ;; funcallable-instances for which finding the source location is
1398   ;; complicated (e.g. DEFSTRUCT-defined predicates and accessors),
1399   ;; but I don't think they're defined with %DEFUN, so the warning
1400   ;; isn't raised.
1401   (flet ((fdefinition-file-namestring (fdefn)
1402            #!+sb-eval
1403            (when (typep fdefn 'sb!eval:interpreted-function)
1404              (return-from fdefinition-file-namestring
1405                (sb!c:definition-source-location-namestring
1406                    (sb!eval:interpreted-function-source-location fdefn))))
1407            ;; All the following accesses are guarded with conditionals
1408            ;; because it's not clear whether any of the slots we're
1409            ;; chasing down are guaranteed to be filled in.
1410            (let* ((fdefn
1411                    ;; KLUDGE: although this looks like it only works
1412                    ;; for %SIMPLE-FUNs, in fact there's a pun such
1413                    ;; that %SIMPLE-FUN-SELF returns the simple-fun
1414                    ;; object for closures and
1415                    ;; funcallable-instances. -- CSR, circa 2005
1416                    (sb!kernel:%simple-fun-self fdefn))
1417                   (code (if fdefn (sb!kernel:fun-code-header fdefn)))
1418                   (debug-info (if code (sb!kernel:%code-debug-info code)))
1419                   (debug-source (if debug-info
1420                                     (sb!c::debug-info-source debug-info)))
1421                   (namestring (if debug-source
1422                                   (sb!c::debug-source-namestring debug-source))))
1423              namestring)))
1424     (and
1425      ;; There's garbage in various places when the first DEFUN runs in
1426      ;; cold-init.
1427      sb!kernel::*cold-init-complete-p*
1428      (typep warning 'redefinition-with-defun)
1429      (let ((old-fdefn
1430             (function-redefinition-warning-old-fdefinition warning))
1431            (new-fdefn
1432             (redefinition-with-defun-new-fdefinition warning)))
1433        ;; Replacing a compiled function with a compiled function is
1434        ;; clearly uninteresting, and we'll say arbitrarily that
1435        ;; replacing an interpreted function with an interpreted
1436        ;; function is uninteresting, too, but leave out the
1437        ;; compiled-to-interpreted case.
1438        (when (or (typep
1439                   old-fdefn
1440                   '(or #!+sb-eval sb!eval:interpreted-function))
1441                  (and (typep old-fdefn
1442                              '(and compiled-function
1443                                (not funcallable-instance)))
1444                       ;; Since this is a REDEFINITION-WITH-DEFUN,
1445                       ;; NEW-FDEFN can't be a FUNCALLABLE-INSTANCE.
1446                       (typep new-fdefn 'compiled-function)))
1447          (let* ((old-namestring (fdefinition-file-namestring old-fdefn))
1448                 (new-namestring
1449                  (or (fdefinition-file-namestring new-fdefn)
1450                      (let ((srcloc
1451                             (redefinition-with-defun-new-location warning)))
1452                        (if srcloc
1453                             (sb!c::definition-source-location-namestring
1454                                 srcloc))))))
1455            (and old-namestring
1456                 new-namestring
1457                 (equal old-namestring new-namestring))))))))
1458
1459 (defun uninteresting-generic-function-redefinition-p (warning)
1460   (and (typep warning 'redefinition-with-defgeneric)
1461        (let* ((old-fdefn
1462                (function-redefinition-warning-old-fdefinition warning))
1463               (old-location
1464                (if (typep old-fdefn 'generic-function)
1465                    (sb!pcl::definition-source old-fdefn)))
1466               (old-namestring
1467                (if old-location
1468                    (sb!c:definition-source-location-namestring old-location)))
1469               (new-location
1470                (redefinition-with-defgeneric-new-location warning))
1471               (new-namestring
1472                (if new-location
1473                    (sb!c:definition-source-location-namestring new-location))))
1474          (and old-namestring
1475               new-namestring
1476               (equal old-namestring new-namestring)))))
1477
1478 (defun uninteresting-method-redefinition-p (warning)
1479   (and (typep warning 'redefinition-with-defmethod)
1480        (let* ((old-method (redefinition-with-defmethod-old-method warning))
1481               (old-location (sb!pcl::definition-source old-method))
1482               (old-namestring (if old-location
1483                                   (sb!c:definition-source-location-namestring
1484                                       old-location)))
1485               (new-location (redefinition-with-defmethod-new-location warning))
1486               (new-namestring (if new-location
1487                                   (sb!c:definition-source-location-namestring
1488                                       new-location))))
1489          (and new-namestring
1490               old-namestring
1491               (equal new-namestring old-namestring)))))
1492
1493 (deftype uninteresting-redefinition ()
1494   '(or (satisfies uninteresting-ordinary-function-redefinition-p)
1495        (satisfies uninteresting-generic-function-redefinition-p)
1496        (satisfies uninteresting-method-redefinition-p)))
1497
1498 (define-condition redefinition-with-deftransform (redefinition-warning)
1499   ((transform :initarg :transform
1500               :reader redefinition-with-deftransform-transform))
1501   (:report (lambda (warning stream)
1502              (format stream "Overwriting ~S"
1503                      (redefinition-with-deftransform-transform warning)))))
1504 \f
1505 ;;; Various other STYLE-WARNINGS
1506 (define-condition dubious-asterisks-around-variable-name
1507     (style-warning simple-condition)
1508   ()
1509   (:report (lambda (warning stream)
1510              (format stream "~@?, even though the name follows~@
1511 the usual naming convention (names like *FOO*) for special variables"
1512                      (simple-condition-format-control warning)
1513                      (simple-condition-format-arguments warning)))))
1514
1515 (define-condition asterisks-around-lexical-variable-name
1516     (dubious-asterisks-around-variable-name)
1517   ())
1518
1519 (define-condition asterisks-around-constant-variable-name
1520     (dubious-asterisks-around-variable-name)
1521   ())
1522
1523 ;; We call this UNDEFINED-ALIEN-STYLE-WARNING because there are some
1524 ;; subclasses of ERROR above having to do with undefined aliens.
1525 (define-condition undefined-alien-style-warning (style-warning)
1526   ((symbol :initarg :symbol :reader undefined-alien-symbol))
1527   (:report (lambda (warning stream)
1528              (format stream "Undefined alien: ~S"
1529                      (undefined-alien-symbol warning)))))
1530
1531 #!+sb-eval
1532 (define-condition lexical-environment-too-complex (style-warning)
1533   ((form :initarg :form :reader lexical-environment-too-complex-form)
1534    (lexenv :initarg :lexenv :reader lexical-environment-too-complex-lexenv))
1535   (:report (lambda (warning stream)
1536              (format stream
1537                      "~@<Native lexical environment too complex for ~
1538                          SB-EVAL to evaluate ~S, falling back to ~
1539                          SIMPLE-EVAL-IN-LEXENV.  Lexenv: ~S~:@>"
1540                      (lexical-environment-too-complex-form warning)
1541                      (lexical-environment-too-complex-lexenv warning)))))
1542
1543 ;; Although this has -ERROR- in the name, it's just a STYLE-WARNING.
1544 (define-condition character-decoding-error-in-comment (style-warning)
1545   ((stream :initarg :stream :reader decoding-error-in-comment-stream)
1546    (position :initarg :position :reader decoding-error-in-comment-position))
1547   (:report (lambda (warning stream)
1548              (format stream
1549                       "Character decoding error in a ~A-comment at ~
1550                       position ~A reading source stream ~A, ~
1551                       resyncing."
1552                       (decoding-error-in-comment-macro warning)
1553                       (decoding-error-in-comment-position warning)
1554                       (decoding-error-in-comment-stream warning)))))
1555
1556 (define-condition character-decoding-error-in-macro-char-comment
1557     (character-decoding-error-in-comment)
1558   ((char :initform #\; :initarg :char
1559          :reader character-decoding-error-in-macro-char-comment-char)))
1560
1561 (define-condition character-decoding-error-in-dispatch-macro-char-comment
1562     (character-decoding-error-in-comment)
1563   ;; ANSI doesn't give a way for a reader function invoked by a
1564   ;; dispatch macro character to determine which dispatch character
1565   ;; was used, so if a user wants to signal one of these from a custom
1566   ;; comment reader, he'll have to supply the :DISP-CHAR himself.
1567   ((disp-char :initform #\# :initarg :disp-char
1568               :reader character-decoding-error-in-macro-char-comment-disp-char)
1569    (sub-char :initarg :sub-char
1570              :reader character-decoding-error-in-macro-char-comment-sub-char)))
1571
1572 (defun decoding-error-in-comment-macro (warning)
1573   (etypecase warning
1574     (character-decoding-error-in-macro-char-comment
1575      (character-decoding-error-in-macro-char-comment-char warning))
1576     (character-decoding-error-in-dispatch-macro-char-comment
1577      (format
1578       nil "~C~C"
1579       (character-decoding-error-in-macro-char-comment-disp-char warning)
1580       (character-decoding-error-in-macro-char-comment-sub-char warning)))))
1581
1582 (define-condition deprecated-eval-when-situations (style-warning)
1583   ((situations :initarg :situations
1584                :reader deprecated-eval-when-situations-situations))
1585   (:report (lambda (warning stream)
1586              (format stream "using deprecated EVAL-WHEN situation names~{ ~S~}"
1587                      (deprecated-eval-when-situations-situations warning)))))
1588
1589 (define-condition proclamation-mismatch (style-warning)
1590   ((name :initarg :name :reader proclamation-mismatch-name)
1591    (old :initarg :old :reader proclamation-mismatch-old)
1592    (new :initarg :new :reader proclamation-mismatch-new)))
1593
1594 (define-condition type-proclamation-mismatch (proclamation-mismatch)
1595   ()
1596   (:report (lambda (warning stream)
1597              (format stream
1598                      "The new TYPE proclamation~% ~S for ~S does not ~
1599                      match the old TYPE proclamation ~S"
1600                      (proclamation-mismatch-new warning)
1601                      (proclamation-mismatch-name warning)
1602                      (proclamation-mismatch-old warning)))))
1603
1604 (define-condition ftype-proclamation-mismatch (proclamation-mismatch)
1605   ()
1606   (:report (lambda (warning stream)
1607              (format stream
1608                      "The new FTYPE proclamation~% ~S for ~S does not ~
1609                      match the old FTYPE proclamation ~S"
1610                      (proclamation-mismatch-new warning)
1611                      (proclamation-mismatch-name warning)
1612                      (proclamation-mismatch-old warning)))))
1613 \f
1614 ;;;; restart definitions
1615
1616 (define-condition abort-failure (control-error) ()
1617   (:report
1618    "An ABORT restart was found that failed to transfer control dynamically."))
1619
1620 (defun abort (&optional condition)
1621   #!+sb-doc
1622   "Transfer control to a restart named ABORT, signalling a CONTROL-ERROR if
1623    none exists."
1624   (invoke-restart (find-restart-or-control-error 'abort condition))
1625   ;; ABORT signals an error in case there was a restart named ABORT
1626   ;; that did not transfer control dynamically. This could happen with
1627   ;; RESTART-BIND.
1628   (error 'abort-failure))
1629
1630 (defun muffle-warning (&optional condition)
1631   #!+sb-doc
1632   "Transfer control to a restart named MUFFLE-WARNING, signalling a
1633    CONTROL-ERROR if none exists."
1634   (invoke-restart (find-restart-or-control-error 'muffle-warning condition)))
1635
1636 (defun try-restart (name condition &rest arguments)
1637   (let ((restart (find-restart name condition)))
1638     (when restart
1639       (apply #'invoke-restart restart arguments))))
1640
1641 (macrolet ((define-nil-returning-restart (name args doc)
1642              #!-sb-doc (declare (ignore doc))
1643              `(defun ,name (,@args &optional condition)
1644                 #!+sb-doc ,doc
1645                 (try-restart ',name condition ,@args))))
1646   (define-nil-returning-restart continue ()
1647     "Transfer control to a restart named CONTINUE, or return NIL if none exists.")
1648   (define-nil-returning-restart store-value (value)
1649     "Transfer control and VALUE to a restart named STORE-VALUE, or return NIL if
1650    none exists.")
1651   (define-nil-returning-restart use-value (value)
1652     "Transfer control and VALUE to a restart named USE-VALUE, or return NIL if
1653    none exists."))
1654
1655 ;;; single-stepping restarts
1656
1657 (macrolet ((def (name doc)
1658                #!-sb-doc (declare (ignore doc))
1659                `(defun ,name (condition)
1660                  #!+sb-doc ,doc
1661                  (invoke-restart (find-restart-or-control-error ',name condition)))))
1662   (def step-continue
1663       "Transfers control to the STEP-CONTINUE restart associated with
1664 the condition, continuing execution without stepping. Signals a
1665 CONTROL-ERROR if the restart does not exist.")
1666   (def step-next
1667       "Transfers control to the STEP-NEXT restart associated with the
1668 condition, executing the current form without stepping and continuing
1669 stepping with the next form. Signals CONTROL-ERROR is the restart does
1670 not exists.")
1671   (def step-into
1672       "Transfers control to the STEP-INTO restart associated with the
1673 condition, stepping into the current form. Signals a CONTROL-ERROR is
1674 the restart does not exist."))
1675
1676 (/show0 "condition.lisp end of file")
1677