src/code/condition.lisp

   1 ;;;; stuff originally from CMU CL's error.lisp which can or should
   2 ;;;; come late (mostly related to the CONDITION class itself)
   3 ;;;;
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!KERNEL")
  15 \f
  16 ;;;; the CONDITION class
  17
  18 (/show0 "condition.lisp 20")
  19
  20 (eval-when (:compile-toplevel :load-toplevel :execute)
  21
  22 (/show0 "condition.lisp 24")
  23
  24 (def!struct (condition-classoid (:include slot-classoid)
  25                                 (:constructor make-condition-classoid))
  26   ;; list of CONDITION-SLOT structures for the direct slots of this
  27   ;; class
  28   (slots nil :type list)
  29   ;; list of CONDITION-SLOT structures for all of the effective class
  30   ;; slots of this class
  31   (class-slots nil :type list)
  32   ;; report function or NIL
  33   (report nil :type (or function null))
  34   ;; list of alternating initargs and initforms
  35   (default-initargs () :type list)
  36   ;; class precedence list as a list of CLASS objects, with all
  37   ;; non-CONDITION classes removed
  38   (cpl () :type list)
  39   ;; a list of all the effective instance allocation slots of this
  40   ;; class that have a non-constant initform or default-initarg.
  41   ;; Values for these slots must be computed in the dynamic
  42   ;; environment of MAKE-CONDITION.
  43   (hairy-slots nil :type list))
  44
  45 (/show0 "condition.lisp 49")
  46
  47 ) ; EVAL-WHEN
  48
  49 (!defstruct-with-alternate-metaclass condition
  50   :slot-names (actual-initargs assigned-slots)
  51   :boa-constructor %make-condition-object
  52   :superclass-name instance
  53   :metaclass-name condition-classoid
  54   :metaclass-constructor make-condition-classoid
  55   :dd-type structure)
  56
  57 (defun make-condition-object (actual-initargs)
  58   (%make-condition-object actual-initargs nil))
  59
  60 (defstruct (condition-slot (:copier nil))
  61   (name (missing-arg) :type symbol)
  62   ;; list of all applicable initargs
  63   (initargs (missing-arg) :type list)
  64   ;; names of reader and writer functions
  65   (readers (missing-arg) :type list)
  66   (writers (missing-arg) :type list)
  67   ;; true if :INITFORM was specified
  68   (initform-p (missing-arg) :type (member t nil))
  69   ;; If this is a function, call it with no args. Otherwise, it's the
  70   ;; actual value.
  71   (initform (missing-arg) :type t)
  72   ;; allocation of this slot, or NIL until defaulted
  73   (allocation nil :type (member :instance :class nil))
  74   ;; If ALLOCATION is :CLASS, this is a cons whose car holds the value.
  75   (cell nil :type (or cons null))
  76   ;; slot documentation
  77   (documentation nil :type (or string null)))
  78
  79 ;;; KLUDGE: It's not clear to me why CONDITION-CLASS has itself listed
  80 ;;; in its CPL, while other classes derived from CONDITION-CLASS don't
  81 ;;; have themselves listed in their CPLs. This behavior is inherited
  82 ;;; from CMU CL, and didn't seem to be explained there, and I haven't
  83 ;;; figured out whether it's right. -- WHN 19990612
  84 (eval-when (:compile-toplevel :load-toplevel :execute)
  85   (/show0 "condition.lisp 103")
  86   (let ((condition-class (locally
  87                            ;; KLUDGE: There's a DEFTRANSFORM
  88                            ;; FIND-CLASSOID for constant class names
  89                            ;; which creates fast but
  90                            ;; non-cold-loadable, non-compact code. In
  91                            ;; this context, we'd rather have compact,
  92                            ;; cold-loadable code. -- WHN 19990928
  93                            (declare (notinline find-classoid))
  94                            (find-classoid 'condition))))
  95     (setf (condition-classoid-cpl condition-class)
  96           (list condition-class)))
  97   (/show0 "condition.lisp 103"))
  98
  99 (setf (condition-classoid-report (locally
 100                                    ;; KLUDGE: There's a DEFTRANSFORM
 101                                    ;; FIND-CLASSOID for constant class
 102                                    ;; names which creates fast but
 103                                    ;; non-cold-loadable, non-compact
 104                                    ;; code. In this context, we'd
 105                                    ;; rather have compact,
 106                                    ;; cold-loadable code. -- WHN
 107                                    ;; 19990928
 108                                    (declare (notinline find-classoid))
 109                                    (find-classoid 'condition)))
 110       (lambda (cond stream)
 111         (format stream "Condition ~S was signalled." (type-of cond))))
 112
 113 (eval-when (:compile-toplevel :load-toplevel :execute)
 114
 115 (defun find-condition-layout (name parent-types)
 116   (let* ((cpl (remove-duplicates
 117                (reverse
 118                 (reduce #'append
 119                         (mapcar (lambda (x)
 120                                   (condition-classoid-cpl
 121                                    (find-classoid x)))
 122                                 parent-types)))))
 123          (cond-layout (info :type :compiler-layout 'condition))
 124          (olayout (info :type :compiler-layout name))
 125          ;; FIXME: Does this do the right thing in case of multiple
 126          ;; inheritance? A quick look at DEFINE-CONDITION didn't make
 127          ;; it obvious what ANSI intends to be done in the case of
 128          ;; multiple inheritance, so it's not actually clear what the
 129          ;; right thing is..
 130          (new-inherits
 131           (order-layout-inherits (concatenate 'simple-vector
 132                                               (layout-inherits cond-layout)
 133                                               (mapcar #'classoid-layout cpl)))))
 134     (if (and olayout
 135              (not (mismatch (layout-inherits olayout) new-inherits)))
 136         olayout
 137         (make-layout :classoid (make-undefined-classoid name)
 138                      :inherits new-inherits
 139                      :depthoid -1
 140                      :length (layout-length cond-layout)))))
 141
 142 ) ; EVAL-WHEN
 143
 144 ;;; FIXME: ANSI's definition of DEFINE-CONDITION says
 145 ;;;   Condition reporting is mediated through the PRINT-OBJECT method
 146 ;;;   for the condition type in question, with *PRINT-ESCAPE* always
 147 ;;;   being nil. Specifying (:REPORT REPORT-NAME) in the definition of
 148 ;;;   a condition type C is equivalent to:
 149 ;;;     (defmethod print-object ((x c) stream)
 150 ;;;       (if *print-escape* (call-next-method) (report-name x stream)))
 151 ;;; The current code doesn't seem to quite match that.
 152 (def!method print-object ((x condition) stream)
 153   (if *print-escape*
 154       (print-unreadable-object (x stream :type t :identity t))
 155       ;; KLUDGE: A comment from CMU CL here said
 156       ;;   7/13/98 BUG? CPL is not sorted and results here depend on order of
 157       ;;   superclasses in define-condition call!
 158       (dolist (class (condition-classoid-cpl (classoid-of x))
 159                      (error "no REPORT? shouldn't happen!"))
 160         (let ((report (condition-classoid-report class)))
 161           (when report
 162             (return (funcall report x stream)))))))
 163 \f
 164 ;;;; slots of CONDITION objects
 165
 166 (defvar *empty-condition-slot* '(empty))
 167
 168 (defun find-slot-default (class slot)
 169   (let ((initargs (condition-slot-initargs slot))
 170         (cpl (condition-classoid-cpl class)))
 171     (dolist (class cpl)
 172       (let ((default-initargs (condition-classoid-default-initargs class)))
 173         (dolist (initarg initargs)
 174           (let ((val (getf default-initargs initarg *empty-condition-slot*)))
 175             (unless (eq val *empty-condition-slot*)
 176               (return-from find-slot-default
 177                            (if (functionp val)
 178                                (funcall val)
 179                                val)))))))
 180
 181     (if (condition-slot-initform-p slot)
 182         (let ((initform (condition-slot-initform slot)))
 183           (if (functionp initform)
 184               (funcall initform)
 185               initform))
 186         (error "unbound condition slot: ~S" (condition-slot-name slot)))))
 187
 188 (defun find-condition-class-slot (condition-class slot-name)
 189   (dolist (sclass
 190            (condition-classoid-cpl condition-class)
 191            (error "There is no slot named ~S in ~S."
 192                   slot-name condition-class))
 193     (dolist (slot (condition-classoid-slots sclass))
 194       (when (eq (condition-slot-name slot) slot-name)
 195         (return-from find-condition-class-slot slot)))))
 196
 197 (defun condition-writer-function (condition new-value name)
 198   (dolist (cslot (condition-classoid-class-slots
 199                   (layout-classoid (%instance-layout condition)))
 200                  (setf (getf (condition-assigned-slots condition) name)
 201                        new-value))
 202     (when (eq (condition-slot-name cslot) name)
 203       (return (setf (car (condition-slot-cell cslot)) new-value)))))
 204
 205 (defun condition-reader-function (condition name)
 206   (let ((class (layout-classoid (%instance-layout condition))))
 207     (dolist (cslot (condition-classoid-class-slots class))
 208       (when (eq (condition-slot-name cslot) name)
 209         (return-from condition-reader-function
 210                      (car (condition-slot-cell cslot)))))
 211     (let ((val (getf (condition-assigned-slots condition) name
 212                      *empty-condition-slot*)))
 213       (if (eq val *empty-condition-slot*)
 214           (let ((actual-initargs (condition-actual-initargs condition))
 215                 (slot (find-condition-class-slot class name)))
 216             (unless slot
 217               (error "missing slot ~S of ~S" name condition))
 218             (do ((initargs actual-initargs (cddr initargs)))
 219                 ((endp initargs)
 220                  (setf (getf (condition-assigned-slots condition) name)
 221                        (find-slot-default class slot)))
 222               (when (member (car initargs) (condition-slot-initargs slot))
 223                 (return-from condition-reader-function
 224                   (setf (getf (condition-assigned-slots condition)
 225                               name)
 226                         (cadr initargs))))))
 227           val))))
 228 \f
 229 ;;;; MAKE-CONDITION
 230
 231 (defun make-condition (thing &rest args)
 232   #!+sb-doc
 233   "Make an instance of a condition object using the specified initargs."
 234   ;; Note: ANSI specifies no exceptional situations in this function.
 235   ;; signalling simple-type-error would not be wrong.
 236   (let* ((thing (if (symbolp thing)
 237                     (find-classoid thing)
 238                     thing))
 239          (class (typecase thing
 240                   (condition-classoid thing)
 241                   (classoid
 242                    (error 'simple-type-error
 243                           :datum thing
 244                           :expected-type 'condition-class
 245                           :format-control "~S is not a condition class."
 246                           :format-arguments (list thing)))
 247                   (t
 248                    (error 'simple-type-error
 249                           :datum thing
 250                           :expected-type 'condition-class
 251                           :format-control "bad thing for class argument:~%  ~S"
 252                           :format-arguments (list thing)))))
 253          (res (make-condition-object args)))
 254     (setf (%instance-layout res) (classoid-layout class))
 255     ;; Set any class slots with initargs present in this call.
 256     (dolist (cslot (condition-classoid-class-slots class))
 257       (dolist (initarg (condition-slot-initargs cslot))
 258         (let ((val (getf args initarg *empty-condition-slot*)))
 259           (unless (eq val *empty-condition-slot*)
 260             (setf (car (condition-slot-cell cslot)) val)))))
 261     ;; Default any slots with non-constant defaults now.
 262     (dolist (hslot (condition-classoid-hairy-slots class))
 263       (when (dolist (initarg (condition-slot-initargs hslot) t)
 264               (unless (eq (getf args initarg *empty-condition-slot*)
 265                           *empty-condition-slot*)
 266                 (return nil)))
 267         (setf (getf (condition-assigned-slots res) (condition-slot-name hslot))
 268               (find-slot-default class hslot))))
 269     res))
 270 \f
 271 ;;;; DEFINE-CONDITION
 272
 273 (eval-when (:compile-toplevel :load-toplevel :execute)
 274 (defun %compiler-define-condition (name direct-supers layout
 275                                    all-readers all-writers)
 276   (with-single-package-locked-error
 277       (:symbol name "defining ~A as a condition")
 278     (sb!xc:proclaim `(ftype (function (t) t) ,@all-readers))
 279     (sb!xc:proclaim `(ftype (function (t t) t) ,@all-writers))
 280     (multiple-value-bind (class old-layout)
 281         (insured-find-classoid name
 282                                #'condition-classoid-p
 283                                #'make-condition-classoid)
 284       (setf (layout-classoid layout) class)
 285       (setf (classoid-direct-superclasses class)
 286             (mapcar #'find-classoid direct-supers))
 287       (cond ((not old-layout)
 288              (register-layout layout))
 289             ((not *type-system-initialized*)
 290              (setf (layout-classoid old-layout) class)
 291              (setq layout old-layout)
 292              (unless (eq (classoid-layout class) layout)
 293                (register-layout layout)))
 294             ((redefine-layout-warning "current"
 295                                       old-layout
 296                                       "new"
 297                                       (layout-length layout)
 298                                       (layout-inherits layout)
 299                                       (layout-depthoid layout))
 300              (register-layout layout :invalidate t))
 301             ((not (classoid-layout class))
 302              (register-layout layout)))
 303
 304       (setf (layout-info layout)
 305             (locally
 306                 ;; KLUDGE: There's a FIND-CLASS DEFTRANSFORM for constant class
 307                 ;; names which creates fast but non-cold-loadable, non-compact
 308                 ;; code. In this context, we'd rather have compact, cold-loadable
 309                 ;; code. -- WHN 19990928
 310                 (declare (notinline find-classoid))
 311               (layout-info (classoid-layout (find-classoid 'condition)))))
 312
 313       (setf (find-classoid name) class)
 314
 315       ;; Initialize CPL slot.
 316       (setf (condition-classoid-cpl class)
 317             (remove-if-not #'condition-classoid-p
 318                            (std-compute-class-precedence-list class)))))
 319   (values))
 320 ) ; EVAL-WHEN
 321
 322 ;;; Compute the effective slots of CLASS, copying inherited slots and
 323 ;;; destructively modifying direct slots.
 324 ;;;
 325 ;;; FIXME: It'd be nice to explain why it's OK to destructively modify
 326 ;;; direct slots. Presumably it follows from the semantics of
 327 ;;; inheritance and redefinition of conditions, but finding the cite
 328 ;;; and documenting it here would be good. (Or, if this is not in fact
 329 ;;; ANSI-compliant, fixing it would also be good.:-)
 330 (defun compute-effective-slots (class)
 331   (collect ((res (copy-list (condition-classoid-slots class))))
 332     (dolist (sclass (cdr (condition-classoid-cpl class)))
 333       (dolist (sslot (condition-classoid-slots sclass))
 334         (let ((found (find (condition-slot-name sslot) (res)
 335                            :key #'condition-slot-name)))
 336           (cond (found
 337                  (setf (condition-slot-initargs found)
 338                        (union (condition-slot-initargs found)
 339                               (condition-slot-initargs sslot)))
 340                  (unless (condition-slot-initform-p found)
 341                    (setf (condition-slot-initform-p found)
 342                          (condition-slot-initform-p sslot))
 343                    (setf (condition-slot-initform found)
 344                          (condition-slot-initform sslot)))
 345                  (unless (condition-slot-allocation found)
 346                    (setf (condition-slot-allocation found)
 347                          (condition-slot-allocation sslot))))
 348                 (t
 349                  (res (copy-structure sslot)))))))
 350     (res)))
 351
 352 ;;; Early definitions of slot accessor creators.
 353 ;;;
 354 ;;; Slot accessors must be generic functions, but ANSI does not seem
 355 ;;; to specify any of them, and we cannot support it before end of
 356 ;;; warm init. So we use ordinary functions inside SBCL, and switch to
 357 ;;; GFs only at the end of building.
 358 (declaim (notinline install-condition-slot-reader
 359                     install-condition-slot-writer))
 360 (defun install-condition-slot-reader (name condition slot-name)
 361   (declare (ignore condition))
 362   (setf (fdefinition name)
 363         (lambda (condition)
 364           (condition-reader-function condition slot-name))))
 365 (defun install-condition-slot-writer (name condition slot-name)
 366   (declare (ignore condition))
 367   (setf (fdefinition name)
 368         (lambda (new-value condition)
 369           (condition-writer-function condition new-value slot-name))))
 370
 371 (defun %define-condition (name parent-types layout slots documentation
 372                           report default-initargs all-readers all-writers)
 373   (with-single-package-locked-error
 374       (:symbol name "defining ~A as a condition")
 375     (%compiler-define-condition name parent-types layout all-readers all-writers)
 376     (let ((class (find-classoid name)))
 377       (setf (condition-classoid-slots class) slots)
 378       (setf (condition-classoid-report class) report)
 379       (setf (condition-classoid-default-initargs class) default-initargs)
 380       (setf (fdocumentation name 'type) documentation)
 381
 382       (dolist (slot slots)
 383
 384         ;; Set up reader and writer functions.
 385         (let ((slot-name (condition-slot-name slot)))
 386           (dolist (reader (condition-slot-readers slot))
 387             (install-condition-slot-reader reader name slot-name))
 388           (dolist (writer (condition-slot-writers slot))
 389             (install-condition-slot-writer writer name slot-name))))
 390
 391       ;; Compute effective slots and set up the class and hairy slots
 392       ;; (subsets of the effective slots.)
 393       (let ((eslots (compute-effective-slots class))
 394             (e-def-initargs
 395              (reduce #'append
 396                      (mapcar #'condition-classoid-default-initargs
 397                            (condition-classoid-cpl class)))))
 398         (dolist (slot eslots)
 399           (ecase (condition-slot-allocation slot)
 400             (:class
 401              (unless (condition-slot-cell slot)
 402                (setf (condition-slot-cell slot)
 403                      (list (if (condition-slot-initform-p slot)
 404                                (let ((initform (condition-slot-initform slot)))
 405                                  (if (functionp initform)
 406                                      (funcall initform)
 407                                      initform))
 408                                *empty-condition-slot*))))
 409              (push slot (condition-classoid-class-slots class)))
 410             ((:instance nil)
 411              (setf (condition-slot-allocation slot) :instance)
 412              (when (or (functionp (condition-slot-initform slot))
 413                        (dolist (initarg (condition-slot-initargs slot) nil)
 414                          (when (functionp (getf e-def-initargs initarg))
 415                            (return t))))
 416                (push slot (condition-classoid-hairy-slots class))))))))
 417     name))
 418
 419 (defmacro define-condition (name (&rest parent-types) (&rest slot-specs)
 420                                  &body options)
 421   #!+sb-doc
 422   "DEFINE-CONDITION Name (Parent-Type*) (Slot-Spec*) Option*
 423    Define NAME as a condition type. This new type inherits slots and its
 424    report function from the specified PARENT-TYPEs. A slot spec is a list of:
 425      (slot-name :reader <rname> :initarg <iname> {Option Value}*
 426
 427    The DEFINE-CLASS slot options :ALLOCATION, :INITFORM, [slot] :DOCUMENTATION
 428    and :TYPE and the overall options :DEFAULT-INITARGS and
 429    [type] :DOCUMENTATION are also allowed.
 430
 431    The :REPORT option is peculiar to DEFINE-CONDITION. Its argument is either
 432    a string or a two-argument lambda or function name. If a function, the
 433    function is called with the condition and stream to report the condition.
 434    If a string, the string is printed.
 435
 436    Condition types are classes, but (as allowed by ANSI and not as described in
 437    CLtL2) are neither STANDARD-OBJECTs nor STRUCTURE-OBJECTs. WITH-SLOTS and
 438    SLOT-VALUE may not be used on condition objects."
 439   (let* ((parent-types (or parent-types '(condition)))
 440          (layout (find-condition-layout name parent-types))
 441          (documentation nil)
 442          (report nil)
 443          (default-initargs ()))
 444     (collect ((slots)
 445               (all-readers nil append)
 446               (all-writers nil append))
 447       (dolist (spec slot-specs)
 448         (when (keywordp spec)
 449           (warn "Keyword slot name indicates probable syntax error:~%  ~S"
 450                 spec))
 451         (let* ((spec (if (consp spec) spec (list spec)))
 452                (slot-name (first spec))
 453                (allocation :instance)
 454                (initform-p nil)
 455                documentation
 456                initform)
 457           (collect ((initargs)
 458                     (readers)
 459                     (writers))
 460             (do ((options (rest spec) (cddr options)))
 461                 ((null options))
 462               (unless (and (consp options) (consp (cdr options)))
 463                 (error "malformed condition slot spec:~%  ~S." spec))
 464               (let ((arg (second options)))
 465                 (case (first options)
 466                   (:reader (readers arg))
 467                   (:writer (writers arg))
 468                   (:accessor
 469                    (readers arg)
 470                    (writers `(setf ,arg)))
 471                   (:initform
 472                    (when initform-p
 473                      (error "more than one :INITFORM in ~S" spec))
 474                    (setq initform-p t)
 475                    (setq initform arg))
 476                   (:initarg (initargs arg))
 477                   (:allocation
 478                    (setq allocation arg))
 479                   (:documentation
 480                    (when documentation
 481                      (error "more than one :DOCUMENTATION in ~S" spec))
 482                    (unless (stringp arg)
 483                      (error "slot :DOCUMENTATION argument is not a string: ~S"
 484                             arg))
 485                    (setq documentation arg))
 486                   (:type)
 487                   (t
 488                    (error "unknown slot option:~%  ~S" (first options))))))
 489
 490             (all-readers (readers))
 491             (all-writers (writers))
 492             (slots `(make-condition-slot
 493                      :name ',slot-name
 494                      :initargs ',(initargs)
 495                      :readers ',(readers)
 496                      :writers ',(writers)
 497                      :initform-p ',initform-p
 498                      :documentation ',documentation
 499                      :initform
 500                      ,(if (constantp initform)
 501                           `',(eval initform)
 502                           `#'(lambda () ,initform)))))))
 503
 504       (dolist (option options)
 505         (unless (consp option)
 506           (error "bad option:~%  ~S" option))
 507         (case (first option)
 508           (:documentation (setq documentation (second option)))
 509           (:report
 510            (let ((arg (second option)))
 511              (setq report
 512                    (if (stringp arg)
 513                        `#'(lambda (condition stream)
 514                           (declare (ignore condition))
 515                           (write-string ,arg stream))
 516                        `#'(lambda (condition stream)
 517                           (funcall #',arg condition stream))))))
 518           (:default-initargs
 519            (do ((initargs (rest option) (cddr initargs)))
 520                ((endp initargs))
 521              (let ((val (second initargs)))
 522                (setq default-initargs
 523                      (list* `',(first initargs)
 524                             (if (constantp val)
 525                                 `',(eval val)
 526                                 `#'(lambda () ,val))
 527                             default-initargs)))))
 528           (t
 529            (error "unknown option: ~S" (first option)))))
 530
 531       `(progn
 532          (eval-when (:compile-toplevel)
 533            (%compiler-define-condition ',name ',parent-types ',layout
 534                                        ',(all-readers) ',(all-writers)))
 535          (eval-when (:load-toplevel :execute)
 536            (%define-condition ',name
 537                               ',parent-types
 538                               ',layout
 539                               (list ,@(slots))
 540                               ,documentation
 541                               ,report
 542                               (list ,@default-initargs)
 543                               ',(all-readers)
 544                               ',(all-writers)))))))
 545 \f
 546 ;;;; DESCRIBE on CONDITIONs
 547
 548 ;;; a function to be used as the guts of DESCRIBE-OBJECT (CONDITION T)
 549 ;;; eventually (once we get CLOS up and running so that we can define
 550 ;;; methods)
 551 (defun describe-condition (condition stream)
 552   (format stream
 553           "~&~@<~S ~_is a ~S. ~_Its slot values are ~_~S.~:>~%"
 554           condition
 555           (type-of condition)
 556           (concatenate 'list
 557                        (condition-actual-initargs condition)
 558                        (condition-assigned-slots condition))))
 559 \f
 560 ;;;; MAKE-LOAD-FORM equivalent for conditions.
 561
 562 ;;; We need this to be able to dump arbitrary encapsulated conditions
 563 ;;; with MAKE-LOAD-FORM for COMPILED-PROGRAM-ERRORs. Unfortunately
 564 ;;; ANSI specifies that MAKE-LOAD-FORM for conditions should signal an
 565 ;;; error, despite the fact that it also specifies that the
 566 ;;; file-compiler should use MAKE-LOAD-FORM for conditions. Bah.
 567 ;;; Badness results if this is called before PCL is in place. Unlike
 568 ;;; real make-load-form we return just a single form, so that it can
 569 ;;; easily be embedded in the surrounding condition.
 570 (defun make-condition-load-form (condition &optional env)
 571   (with-unique-names (instance)
 572     (multiple-value-bind (create init)
 573         (make-load-form-saving-slots condition :environment env)
 574       (let ((fixed-init (subst instance condition init)))
 575         `(let ((,instance ,create))
 576           ,fixed-init
 577           ,instance)))))
 578 \f
 579 ;;;; various CONDITIONs specified by ANSI
 580
 581 (define-condition serious-condition (condition) ())
 582
 583 (define-condition error (serious-condition) ())
 584
 585 (define-condition warning (condition) ())
 586 (define-condition style-warning (warning) ())
 587
 588 (defun simple-condition-printer (condition stream)
 589   (apply #'format
 590          stream
 591          (simple-condition-format-control condition)
 592          (simple-condition-format-arguments condition)))
 593
 594 (define-condition simple-condition ()
 595   ((format-control :reader simple-condition-format-control
 596                    :initarg :format-control
 597                    :type format-control)
 598    (format-arguments :reader simple-condition-format-arguments
 599                      :initarg :format-arguments
 600                      :initform '()
 601                      :type list))
 602   (:report simple-condition-printer))
 603
 604 (define-condition simple-warning (simple-condition warning) ())
 605
 606 (define-condition simple-error (simple-condition error) ())
 607
 608 ;;; not specified by ANSI, but too useful not to have around.
 609 (define-condition simple-style-warning (simple-condition style-warning) ())
 610
 611 (define-condition storage-condition (serious-condition) ())
 612
 613 (define-condition type-error (error)
 614   ((datum :reader type-error-datum :initarg :datum)
 615    (expected-type :reader type-error-expected-type :initarg :expected-type))
 616   (:report
 617    (lambda (condition stream)
 618      (format stream
 619              "~@<The value ~2I~:_~S ~I~_is not of type ~2I~_~S.~:>"
 620              (type-error-datum condition)
 621              (type-error-expected-type condition)))))
 622
 623 (define-condition simple-type-error (simple-condition type-error) ())
 624
 625 (define-condition program-error (error) ())
 626 (define-condition parse-error   (error) ())
 627 (define-condition control-error (error) ())
 628 (define-condition stream-error  (error)
 629   ((stream :reader stream-error-stream :initarg :stream)))
 630
 631 (define-condition end-of-file (stream-error) ()
 632   (:report
 633    (lambda (condition stream)
 634      (format stream
 635              "end of file on ~S"
 636              (stream-error-stream condition)))))
 637
 638 (define-condition file-error (error)
 639   ((pathname :reader file-error-pathname :initarg :pathname))
 640   (:report
 641    (lambda (condition stream)
 642      (format stream "error on file ~S" (file-error-pathname condition)))))
 643
 644 (define-condition package-error (error)
 645   ((package :reader package-error-package :initarg :package)))
 646
 647 (define-condition cell-error (error)
 648   ((name :reader cell-error-name :initarg :name)))
 649
 650 (define-condition unbound-variable (cell-error) ()
 651   (:report
 652    (lambda (condition stream)
 653      (format stream
 654              "The variable ~S is unbound."
 655              (cell-error-name condition)))))
 656
 657 (define-condition undefined-function (cell-error) ()
 658   (:report
 659    (lambda (condition stream)
 660      (format stream
 661              "The function ~S is undefined."
 662              (cell-error-name condition)))))
 663
 664 (define-condition special-form-function (undefined-function) ()
 665   (:report
 666    (lambda (condition stream)
 667      (format stream
 668              "Cannot FUNCALL the SYMBOL-FUNCTION of special operator ~S."
 669              (cell-error-name condition)))))
 670
 671 (define-condition arithmetic-error (error)
 672   ((operation :reader arithmetic-error-operation
 673               :initarg :operation
 674               :initform nil)
 675    (operands :reader arithmetic-error-operands
 676              :initarg :operands))
 677   (:report (lambda (condition stream)
 678              (format stream
 679                      "arithmetic error ~S signalled"
 680                      (type-of condition))
 681              (when (arithmetic-error-operation condition)
 682                (format stream
 683                        "~%Operation was ~S, operands ~S."
 684                        (arithmetic-error-operation condition)
 685                        (arithmetic-error-operands condition))))))
 686
 687 (define-condition division-by-zero         (arithmetic-error) ())
 688 (define-condition floating-point-overflow  (arithmetic-error) ())
 689 (define-condition floating-point-underflow (arithmetic-error) ())
 690 (define-condition floating-point-inexact   (arithmetic-error) ())
 691 (define-condition floating-point-invalid-operation (arithmetic-error) ())
 692
 693 (define-condition print-not-readable (error)
 694   ((object :reader print-not-readable-object :initarg :object))
 695   (:report
 696    (lambda (condition stream)
 697      (let ((obj (print-not-readable-object condition))
 698            (*print-array* nil))
 699        (format stream "~S cannot be printed readably." obj)))))
 700
 701 (define-condition reader-error (parse-error stream-error)
 702   ((format-control
 703     :reader reader-error-format-control
 704     :initarg :format-control)
 705    (format-arguments
 706     :reader reader-error-format-arguments
 707     :initarg :format-arguments
 708     :initform '()))
 709   (:report
 710    (lambda (condition stream)
 711      (let* ((error-stream (stream-error-stream condition))
 712             (pos (file-position error-stream)))
 713        (let (lineno colno)
 714          (when (and pos
 715                     (< pos sb!xc:array-dimension-limit)
 716                     ;; KLUDGE: lseek() (which is what FILE-POSITION
 717                     ;; reduces to on file-streams) is undefined on
 718                     ;; "some devices", which in practice means that it
 719                     ;; can claim to succeed on /dev/stdin on Darwin
 720                     ;; and Solaris.  This is obviously bad news,
 721                     ;; because the READ-SEQUENCE below will then
 722                     ;; block, not complete, and the report will never
 723                     ;; be printed.  As a workaround, we exclude
 724                     ;; interactive streams from this attempt to report
 725                     ;; positions.  -- CSR, 2003-08-21
 726                     (not (interactive-stream-p error-stream))
 727                     (file-position error-stream :start))
 728            (let ((string
 729                   (make-string pos
 730                                :element-type (stream-element-type error-stream))))
 731              (when (= pos (read-sequence string error-stream))
 732                (setq lineno (1+ (count #\Newline string))
 733                      colno (- pos
 734                               (or (position #\Newline string :from-end t) -1)
 735                               1))))
 736            (file-position error-stream pos))
 737          (format stream
 738                  "READER-ERROR ~@[at ~W ~]~
 739                   ~@[(line ~W~]~@[, column ~W) ~]~
 740                   on ~S:~%~?"
 741                  pos lineno colno error-stream
 742                  (reader-error-format-control condition)
 743                  (reader-error-format-arguments condition)))))))
 744 \f
 745 ;;;; special SBCL extension conditions
 746
 747 ;;; an error apparently caused by a bug in SBCL itself
 748 ;;;
 749 ;;; Note that we don't make any serious effort to use this condition
 750 ;;; for *all* errors in SBCL itself. E.g. type errors and array
 751 ;;; indexing errors can occur in functions called from SBCL code, and
 752 ;;; will just end up as ordinary TYPE-ERROR or invalid index error,
 753 ;;; because the signalling code has no good way to know that the
 754 ;;; underlying problem is a bug in SBCL. But in the fairly common case
 755 ;;; that the signalling code does know that it's found a bug in SBCL,
 756 ;;; this condition is appropriate, reusing boilerplate and helping
 757 ;;; users to recognize it as an SBCL bug.
 758 (define-condition bug (simple-error)
 759   ()
 760   (:report
 761    (lambda (condition stream)
 762      (format stream
 763              "~@<  ~? ~:@_~?~:>"
 764              (simple-condition-format-control condition)
 765              (simple-condition-format-arguments condition)
 766              "~@<This is probably a bug in SBCL itself. (Alternatively, ~
 767               SBCL might have been corrupted by bad user code, e.g. by an ~
 768               undefined Lisp operation like ~S, or by stray pointers from ~
 769               alien code or from unsafe Lisp code; or there might be a bug ~
 770               in the OS or hardware that SBCL is running on.) If it seems to ~
 771               be a bug in SBCL itself, the maintainers would like to know ~
 772               about it. Bug reports are welcome on the SBCL ~
 773               mailing lists, which you can find at ~
 774               <http://sbcl.sourceforge.net/>.~:@>"
 775              '((fmakunbound 'compile))))))
 776
 777 ;;; a condition for use in stubs for operations which aren't supported
 778 ;;; on some platforms
 779 ;;;
 780 ;;; E.g. in sbcl-0.7.0.5, it might be appropriate to do something like
 781 ;;;   #-(or freebsd linux)
 782 ;;;   (defun load-foreign (&rest rest)
 783 ;;;     (error 'unsupported-operator :name 'load-foreign))
 784 ;;;   #+(or freebsd linux)
 785 ;;;   (defun load-foreign ... actual definition ...)
 786 ;;; By signalling a standard condition in this case, we make it
 787 ;;; possible for test code to distinguish between (1) intentionally
 788 ;;; unimplemented and (2) unintentionally just screwed up somehow.
 789 ;;; (Before this condition was defined, test code tried to deal with
 790 ;;; this by checking for FBOUNDP, but that didn't work reliably. In
 791 ;;; sbcl-0.7.0, a a package screwup left the definition of
 792 ;;; LOAD-FOREIGN in the wrong package, so it was unFBOUNDP even on
 793 ;;; architectures where it was supposed to be supported, and the
 794 ;;; regression tests cheerfully passed because they assumed that
 795 ;;; unFBOUNDPness meant they were running on an system which didn't
 796 ;;; support the extension.)
 797 (define-condition unsupported-operator (cell-error) ()
 798   (:report
 799    (lambda (condition stream)
 800      (format stream
 801              "unsupported on this platform (OS, CPU, whatever): ~S"
 802              (cell-error-name condition)))))
 803 \f
 804 ;;; (:ansi-cl :function remove)
 805 ;;; (:ansi-cl :section (a b c))
 806 ;;; (:ansi-cl :glossary "similar")
 807 ;;;
 808 ;;; (:sbcl :node "...")
 809 ;;; (:sbcl :variable *ed-functions*)
 810 ;;;
 811 ;;; FIXME: this is not the right place for this.
 812 (defun print-reference (reference stream)
 813   (ecase (car reference)
 814     (:ansi-cl
 815      (format stream "The ANSI Standard")
 816      (format stream ", ")
 817      (destructuring-bind (type data) (cdr reference)
 818        (ecase type
 819          (:function (format stream "Function ~S" data))
 820          (:special-operator (format stream "Special Operator ~S" data))
 821          (:macro (format stream "Macro ~S" data))
 822          (:section (format stream "Section ~{~D~^.~}" data))
 823          (:glossary (format stream "Glossary entry for ~S" data))
 824          (:issue (format stream "writeup for Issue ~A" data)))))
 825     (:sbcl
 826      (format stream "The SBCL Manual")
 827      (format stream ", ")
 828      (destructuring-bind (type data) (cdr reference)
 829        (ecase type
 830          (:node (format stream "Node ~S" data))
 831          (:variable (format stream "Variable ~S" data)))))
 832     ;; FIXME: other documents (e.g. AMOP, Franz documentation :-)
 833     ))
 834 (define-condition reference-condition ()
 835   ((references :initarg :references :reader reference-condition-references)))
 836 (defvar *print-condition-references* t)
 837 (def!method print-object :around ((o reference-condition) s)
 838   (call-next-method)
 839   (unless (or *print-escape* *print-readably*)
 840     (when *print-condition-references*
 841       (format s "~&See also:~%")
 842       (pprint-logical-block (s nil :per-line-prefix "  ")
 843         (do* ((rs (reference-condition-references o) (cdr rs))
 844               (r (car rs) (car rs)))
 845              ((null rs))
 846           (print-reference r s)
 847           (unless (null (cdr rs))
 848             (terpri s)))))))
 849
 850 (define-condition duplicate-definition (reference-condition warning)
 851   ((name :initarg :name :reader duplicate-definition-name))
 852   (:report (lambda (c s)
 853              (format s "~@<Duplicate definition for ~S found in ~
 854                         one file.~@:>"
 855                      (duplicate-definition-name c))))
 856   (:default-initargs :references (list '(:ansi-cl :section (3 2 2 3)))))
 857
 858 (define-condition package-at-variance (reference-condition simple-warning)
 859   ()
 860   (:default-initargs :references (list '(:ansi-cl :macro defpackage))))
 861
 862 (define-condition defconstant-uneql (reference-condition error)
 863   ((name :initarg :name :reader defconstant-uneql-name)
 864    (old-value :initarg :old-value :reader defconstant-uneql-old-value)
 865    (new-value :initarg :new-value :reader defconstant-uneql-new-value))
 866   (:report
 867    (lambda (condition stream)
 868      (format stream
 869              "~@<The constant ~S is being redefined (from ~S to ~S)~@:>"
 870              (defconstant-uneql-name condition)
 871              (defconstant-uneql-old-value condition)
 872              (defconstant-uneql-new-value condition))))
 873   (:default-initargs :references (list '(:ansi-cl :macro defconstant)
 874                                        '(:sbcl :node "Idiosyncrasies"))))
 875
 876 (define-condition array-initial-element-mismatch
 877     (reference-condition simple-warning)
 878   ()
 879   (:default-initargs
 880       :references (list
 881                    '(:ansi-cl :function make-array)
 882                    '(:ansi-cl :function sb!xc:upgraded-array-element-type))))
 883
 884 (define-condition displaced-to-array-too-small-error
 885     (reference-condition simple-error)
 886   ()
 887   (:default-initargs
 888       :references (list '(:ansi-cl :function adjust-array))))
 889
 890 (define-condition type-warning (reference-condition simple-warning)
 891   ()
 892   (:default-initargs :references (list '(:sbcl :node "Handling of Types"))))
 893
 894 (define-condition local-argument-mismatch (reference-condition simple-warning)
 895   ()
 896   (:default-initargs :references (list '(:ansi-cl :section (3 2 2 3)))))
 897
 898 (define-condition format-args-mismatch (reference-condition)
 899   ()
 900   (:default-initargs :references (list '(:ansi-cl :section (22 3 10 2)))))
 901
 902 (define-condition format-too-few-args-warning
 903     (format-args-mismatch simple-warning)
 904   ())
 905 (define-condition format-too-many-args-warning
 906     (format-args-mismatch simple-style-warning)
 907   ())
 908
 909 (define-condition extension-failure (reference-condition simple-error)
 910   ())
 911
 912 #!+sb-package-locks
 913 (progn
 914
 915 (define-condition package-lock-violation (reference-condition package-error)
 916   ((format-control :initform nil :initarg :format-control
 917                    :reader package-error-format-control)
 918    (format-arguments :initform nil :initarg :format-arguments
 919                      :reader package-error-format-arguments))
 920   (:report
 921    (lambda (condition stream)
 922      (let ((control (package-error-format-control condition)))
 923        (if control
 924            (apply #'format stream
 925                   (format nil "~~@<Lock on package ~A violated when ~A.~~:@>"
 926                           (package-name (package-error-package condition))
 927                           control)
 928                   (package-error-format-arguments condition))
 929            (format stream "~@<Lock on package ~A violated.~:@>"
 930                    (package-name (package-error-package condition)))))))
 931   ;; no :default-initargs -- reference-stuff provided by the
 932   ;; signalling form in target-package.lisp
 933   #!+sb-doc
 934   (:documentation
 935    "Subtype of CL:PACKAGE-ERROR. A subtype of this error is signalled
 936 when a package-lock is violated."))
 937
 938 (define-condition package-locked-error (package-lock-violation) ()
 939   #!+sb-doc
 940   (:documentation
 941    "Subtype of SB-EXT:PACKAGE-LOCK-VIOLATION. An error of this type is
 942 signalled when an operation on a package violates a package lock."))
 943
 944 (define-condition symbol-package-locked-error (package-lock-violation)
 945   ((symbol :initarg :symbol :reader package-locked-error-symbol))
 946   #!+sb-doc
 947   (:documentation
 948    "Subtype of SB-EXT:PACKAGE-LOCK-VIOLATION. An error of this type is
 949 signalled when an operation on a symbol violates a package lock. The
 950 symbol that caused the violation is accessed by the function
 951 SB-EXT:PACKAGE-LOCKED-ERROR-SYMBOL."))
 952
 953 ) ; progn
 954 \f
 955 ;;;; various other (not specified by ANSI) CONDITIONs
 956 ;;;;
 957 ;;;; These might logically belong in other files; they're here, after
 958 ;;;; setup of CONDITION machinery, only because that makes it easier to
 959 ;;;; get cold init to work.
 960
 961 (define-condition encapsulated-condition (condition)
 962   ((condition :initarg :condition :reader encapsulated-condition)))
 963
 964 ;;; This comes to play if we have multiple levels of encapsulated
 965 ;;; errors and we need to dump them with MAKE-CONDITION-LOAD-FORM.
 966 ;;; Should not see much/any use, but better to have it.
 967 (def!method make-load-form ((condition encapsulated-condition) &optional env)
 968   `(make-condition 'encapsulated-condition
 969     :condition ,(make-condition-load-form (encapsulated-condition condition) env)))
 970
 971 (define-condition values-type-error (type-error)
 972   ()
 973   (:report
 974    (lambda (condition stream)
 975      (format stream
 976              "~@<The values set ~2I~:_[~{~S~^ ~}] ~I~_is not of type ~2I~_~S.~:>"
 977              (type-error-datum condition)
 978              (type-error-expected-type condition)))))
 979
 980 ;;; KLUDGE: a condition for floating point errors when we can't or
 981 ;;; won't figure out what type they are. (In FreeBSD and OpenBSD we
 982 ;;; don't know how, at least as of sbcl-0.6.7; in Linux we probably
 983 ;;; know how but the old code was broken by the conversion to POSIX
 984 ;;; signal handling and hasn't been fixed as of sbcl-0.6.7.)
 985 ;;;
 986 ;;; FIXME: Perhaps this should also be a base class for all
 987 ;;; floating point exceptions?
 988 (define-condition floating-point-exception (arithmetic-error)
 989   ((flags :initarg :traps
 990           :initform nil
 991           :reader floating-point-exception-traps))
 992   (:report (lambda (condition stream)
 993              (format stream
 994                      "An arithmetic error ~S was signalled.~%"
 995                      (type-of condition))
 996              (let ((traps (floating-point-exception-traps condition)))
 997                (if traps
 998                    (format stream
 999                            "Trapping conditions are: ~%~{ ~S~^~}~%"
1000                            traps)
1001                    (write-line
1002                     "No traps are enabled? How can this be?"
1003                     stream))))))
1004
1005 (define-condition index-too-large-error (type-error)
1006   ()
1007   (:report
1008    (lambda (condition stream)
1009      (format stream
1010              "The index ~S is too large."
1011              (type-error-datum condition)))))
1012
1013 (define-condition bounding-indices-bad-error (reference-condition type-error)
1014   ((object :reader bounding-indices-bad-object :initarg :object))
1015   (:report
1016    (lambda (condition stream)
1017      (let* ((datum (type-error-datum condition))
1018             (start (car datum))
1019             (end (cdr datum))
1020             (object (bounding-indices-bad-object condition)))
1021        (etypecase object
1022          (sequence
1023           (format stream
1024                   "The bounding indices ~S and ~S are bad ~
1025                    for a sequence of length ~S."
1026                   start end (length object)))
1027          (array
1028           ;; from WITH-ARRAY-DATA
1029           (format stream
1030                   "The START and END parameters ~S and ~S are ~
1031                    bad for an array of total size ~S."
1032                   start end (array-total-size object)))))))
1033   (:default-initargs
1034       :references
1035       (list '(:ansi-cl :glossary "bounding index designator")
1036             '(:ansi-cl :issue "SUBSEQ-OUT-OF-BOUNDS:IS-AN-ERROR"))))
1037
1038 (define-condition nil-array-accessed-error (reference-condition type-error)
1039   ()
1040   (:report (lambda (condition stream)
1041              (declare (ignore condition))
1042              (format stream
1043                      "An attempt to access an array of element-type ~
1044                       NIL was made.  Congratulations!")))
1045   (:default-initargs
1046       :references (list '(:ansi-cl :function sb!xc:upgraded-array-element-type)
1047                         '(:ansi-cl :section (15 1 2 1))
1048                         '(:ansi-cl :section (15 1 2 2)))))
1049
1050 (define-condition io-timeout (stream-error)
1051   ((direction :reader io-timeout-direction :initarg :direction))
1052   (:report
1053    (lambda (condition stream)
1054      (declare (type stream stream))
1055      (format stream
1056              "I/O timeout ~(~A~)ing ~S"
1057              (io-timeout-direction condition)
1058              (stream-error-stream condition)))))
1059
1060 (define-condition namestring-parse-error (parse-error)
1061   ((complaint :reader namestring-parse-error-complaint :initarg :complaint)
1062    (args :reader namestring-parse-error-args :initarg :args :initform nil)
1063    (namestring :reader namestring-parse-error-namestring :initarg :namestring)
1064    (offset :reader namestring-parse-error-offset :initarg :offset))
1065   (:report
1066    (lambda (condition stream)
1067      (format stream
1068              "parse error in namestring: ~?~%  ~A~%  ~V@T^"
1069              (namestring-parse-error-complaint condition)
1070              (namestring-parse-error-args condition)
1071              (namestring-parse-error-namestring condition)
1072              (namestring-parse-error-offset condition)))))
1073
1074 (define-condition simple-package-error (simple-condition package-error) ())
1075
1076 (define-condition reader-package-error (reader-error) ())
1077
1078 (define-condition reader-eof-error (end-of-file)
1079   ((context :reader reader-eof-error-context :initarg :context))
1080   (:report
1081    (lambda (condition stream)
1082      (format stream
1083              "unexpected end of file on ~S ~A"
1084              (stream-error-stream condition)
1085              (reader-eof-error-context condition)))))
1086
1087 (define-condition reader-impossible-number-error (reader-error)
1088   ((error :reader reader-impossible-number-error-error :initarg :error))
1089   (:report
1090    (lambda (condition stream)
1091      (let ((error-stream (stream-error-stream condition)))
1092        (format stream "READER-ERROR ~@[at ~W ~]on ~S:~%~?~%Original error: ~A"
1093                (file-position error-stream) error-stream
1094                (reader-error-format-control condition)
1095                (reader-error-format-arguments condition)
1096                (reader-impossible-number-error-error condition))))))
1097
1098 (define-condition timeout (serious-condition) ())
1099 \f
1100 ;;;; restart definitions
1101
1102 (define-condition abort-failure (control-error) ()
1103   (:report
1104    "An ABORT restart was found that failed to transfer control dynamically."))
1105
1106 (defun abort (&optional condition)
1107   #!+sb-doc
1108   "Transfer control to a restart named ABORT, signalling a CONTROL-ERROR if
1109    none exists."
1110   (invoke-restart (find-restart-or-control-error 'abort condition))
1111   ;; ABORT signals an error in case there was a restart named ABORT
1112   ;; that did not transfer control dynamically. This could happen with
1113   ;; RESTART-BIND.
1114   (error 'abort-failure))
1115
1116 (defun muffle-warning (&optional condition)
1117   #!+sb-doc
1118   "Transfer control to a restart named MUFFLE-WARNING, signalling a
1119    CONTROL-ERROR if none exists."
1120   (invoke-restart (find-restart-or-control-error 'muffle-warning condition)))
1121
1122 (macrolet ((define-nil-returning-restart (name args doc)
1123              #!-sb-doc (declare (ignore doc))
1124              `(defun ,name (,@args &optional condition)
1125                 #!+sb-doc ,doc
1126                 ;; FIXME: Perhaps this shared logic should be pulled out into
1127                 ;; FLET MAYBE-INVOKE-RESTART? See whether it shrinks code..
1128                 (let ((restart (find-restart ',name condition)))
1129                   (when restart
1130                     (invoke-restart restart ,@args))))))
1131   (define-nil-returning-restart continue ()
1132     "Transfer control to a restart named CONTINUE, or return NIL if none exists.")
1133   (define-nil-returning-restart store-value (value)
1134     "Transfer control and VALUE to a restart named STORE-VALUE, or return NIL if
1135    none exists.")
1136   (define-nil-returning-restart use-value (value)
1137     "Transfer control and VALUE to a restart named USE-VALUE, or return NIL if
1138    none exists."))
1139
1140 (/show0 "condition.lisp end of file")
1141