src/code/debug.lisp

   1 ;;;; the debugger
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!DEBUG")
  13 \f
  14 ;;;; variables and constants
  15
  16 (defvar *debug-print-level* 3
  17   #!+sb-doc
  18   "*PRINT-LEVEL* for the debugger")
  19
  20 (defvar *debug-print-length* 5
  21   #!+sb-doc
  22   "*PRINT-LENGTH* for the debugger")
  23
  24 (defvar *debug-readtable*
  25   ;; KLUDGE: This can't be initialized in a cold toplevel form,
  26   ;; because the *STANDARD-READTABLE* isn't initialized until after
  27   ;; cold toplevel forms have run. So instead we initialize it
  28   ;; immediately after *STANDARD-READTABLE*. -- WHN 20000205
  29   nil
  30   #!+sb-doc
  31   "*READTABLE* for the debugger")
  32
  33 (defvar *in-the-debugger* nil
  34   #!+sb-doc
  35   "This is T while in the debugger.")
  36
  37 ;;; nestedness inside debugger command loops
  38 (defvar *debug-command-level* 0)
  39
  40 (defvar *stack-top-hint* nil
  41   #!+sb-doc
  42   "If this is bound before the debugger is invoked, it is used as the stack
  43    top by the debugger.")
  44 (defvar *stack-top* nil)
  45 (defvar *real-stack-top* nil)
  46
  47 (defvar *current-frame* nil)
  48
  49 (defun debug-prompt (stream)
  50
  51   ;; old behavior, will probably go away in sbcl-0.7.x
  52   (format stream "~%~D" (sb!di:frame-number *current-frame*))
  53   (dotimes (i *debug-command-level*)
  54     (write-char #\] stream))
  55   (write-char #\space stream)
  56
  57   ;; planned new behavior, delayed since it will break ILISP
  58   #+nil
  59   (format stream
  60           "~%~D~:[~;[~D~]] "
  61           (sb!di:frame-number *current-frame*)
  62           (> *debug-command-level* 1)
  63           *debug-command-level*))
  64
  65 (defparameter *debug-help-string*
  66 "The prompt is right square brackets, the number indicating how many
  67   recursive command loops you are in.
  68 Any command may be uniquely abbreviated.
  69 The debugger rebinds various special variables for controlling i/o, sometimes
  70   to defaults (much like WITH-STANDARD-IO-SYNTAX does) and sometimes to
  71   its own special values, e.g. SB-DEBUG:*DEBUG-PRINT-LEVEL*.
  72 Debug commands do not affect * and friends, but evaluation in the debug loop
  73   does affect these variables.
  74 SB-DEBUG:*FLUSH-DEBUG-ERRORS* controls whether errors at the debug prompt
  75   drop you into deeper into the debugger.
  76
  77 Getting in and out of the debugger:
  78   RESTART  invokes restart numbered as shown (prompt if not given).
  79   ERROR    prints the error condition and restart cases.
  80   The name of any restart, or its number, is a valid command, and is the same
  81     as using RESTART to invoke that restart.
  82
  83 Changing frames:
  84   U      up frame     D    down frame
  85   B  bottom frame     F n  frame n (n=0 for top frame)
  86
  87 Inspecting frames:
  88   BACKTRACE [n]  shows n frames going down the stack.
  89   LIST-LOCALS, L lists locals in current function.
  90   PRINT, P       displays current function call.
  91   SOURCE [n]     displays frame's source form with n levels of enclosing forms.
  92
  93 Breakpoints and steps:
  94   LIST-LOCATIONS [{function | :C}]   List the locations for breakpoints.
  95                                      Specify :C for the current frame.
  96     Abbreviation: LL
  97   LIST-BREAKPOINTS                   List the active breakpoints.
  98     Abbreviations: LB, LBP
  99   DELETE-BREAKPOINT [n]              Remove breakpoint n or all breakpoints.
 100     Abbreviations: DEL, DBP
 101   BREAKPOINT {n | :end | :start} [:break form] [:function function]
 102              [{:print form}*] [:condition form]
 103                                      Set a breakpoint.
 104     Abbreviations: BR, BP
 105   STEP [n]                           Step to the next location or step n times.
 106
 107 Function and macro commands:
 108  (SB-DEBUG:DEBUG-RETURN expression)
 109     Exit the debugger, returning expression's values from the current frame.
 110  (SB-DEBUG:ARG n)
 111     Return the n'th argument in the current frame.
 112  (SB-DEBUG:VAR string-or-symbol [id])
 113     Returns the value of the specified variable in the current frame.")
 114 \f
 115 ;;; This is used to communicate to DEBUG-LOOP that we are at a step breakpoint.
 116 (define-condition step-condition (simple-condition) ())
 117 \f
 118 ;;;; breakpoint state
 119
 120 (defvar *only-block-start-locations* nil
 121   #!+sb-doc
 122   "When true, the LIST-LOCATIONS command only displays block start locations.
 123    Otherwise, all locations are displayed.")
 124
 125 (defvar *print-location-kind* nil
 126   #!+sb-doc
 127   "When true, list the code location type in the LIST-LOCATIONS command.")
 128
 129 ;;; a list of the types of code-locations that should not be stepped to and
 130 ;;; should not be listed when listing breakpoints
 131 (defvar *bad-code-location-types* '(:call-site :internal-error))
 132 (declaim (type list *bad-code-location-types*))
 133
 134 ;;; code locations of the possible breakpoints
 135 (defvar *possible-breakpoints*)
 136 (declaim (type list *possible-breakpoints*))
 137
 138 ;;; a list of the made and active breakpoints, each is a breakpoint-info
 139 ;;; structure
 140 (defvar *breakpoints* nil)
 141 (declaim (type list *breakpoints*))
 142
 143 ;;; a list of breakpoint-info structures of the made and active step
 144 ;;; breakpoints
 145 (defvar *step-breakpoints* nil)
 146 (declaim (type list *step-breakpoints*))
 147
 148 ;;; the number of times left to step
 149 (defvar *number-of-steps* 1)
 150 (declaim (type integer *number-of-steps*))
 151
 152 ;;; This is used when listing and setting breakpoints.
 153 (defvar *default-breakpoint-debug-function* nil)
 154 (declaim (type (or list sb!di:debug-function) *default-breakpoint-debug-function*))
 155 \f
 156 ;;;; code location utilities
 157
 158 ;;; Return the first code-location in the passed debug block.
 159 (defun first-code-location (debug-block)
 160   (let ((found nil)
 161         (first-code-location nil))
 162     (sb!di:do-debug-block-locations (code-location debug-block)
 163       (unless found
 164         (setf first-code-location code-location)
 165         (setf found t)))
 166     first-code-location))
 167
 168 ;;; Return a list of the next code-locations following the one passed. One of
 169 ;;; the *BAD-CODE-LOCATION-TYPES* will not be returned.
 170 (defun next-code-locations (code-location)
 171   (let ((debug-block (sb!di:code-location-debug-block code-location))
 172         (block-code-locations nil))
 173     (sb!di:do-debug-block-locations (block-code-location debug-block)
 174       (unless (member (sb!di:code-location-kind block-code-location)
 175                       *bad-code-location-types*)
 176         (push block-code-location block-code-locations)))
 177     (setf block-code-locations (nreverse block-code-locations))
 178     (let* ((code-loc-list (rest (member code-location block-code-locations
 179                                         :test #'sb!di:code-location=)))
 180            (next-list (cond (code-loc-list
 181                              (list (first code-loc-list)))
 182                             ((map 'list #'first-code-location
 183                                   (sb!di:debug-block-successors debug-block)))
 184                             (t nil))))
 185       (when (and (= (length next-list) 1)
 186                  (sb!di:code-location= (first next-list) code-location))
 187         (setf next-list (next-code-locations (first next-list))))
 188       next-list)))
 189
 190 ;;; Returns a list of code-locations of the possible breakpoints of the
 191 ;;; debug-function passed.
 192 (defun possible-breakpoints (debug-function)
 193   (let ((possible-breakpoints nil))
 194     (sb!di:do-debug-function-blocks (debug-block debug-function)
 195       (unless (sb!di:debug-block-elsewhere-p debug-block)
 196         (if *only-block-start-locations*
 197             (push (first-code-location debug-block) possible-breakpoints)
 198             (sb!di:do-debug-block-locations (code-location debug-block)
 199               (when (not (member (sb!di:code-location-kind code-location)
 200                                  *bad-code-location-types*))
 201                 (push code-location possible-breakpoints))))))
 202     (nreverse possible-breakpoints)))
 203
 204 ;;; Searches the info-list for the item passed (code-location, debug-function,
 205 ;;; or breakpoint-info). If the item passed is a debug function then kind will
 206 ;;; be compared if it was specified. The kind if also compared if a
 207 ;;; breakpoint-info is passed since it's in the breakpoint. The info structure
 208 ;;; is returned if found.
 209 (defun location-in-list (place info-list &optional (kind nil))
 210   (when (breakpoint-info-p place)
 211     (setf kind (sb!di:breakpoint-kind (breakpoint-info-breakpoint place)))
 212     (setf place (breakpoint-info-place place)))
 213   (cond ((sb!di:code-location-p place)
 214          (find place info-list
 215                :key #'breakpoint-info-place
 216                :test #'(lambda (x y) (and (sb!di:code-location-p y)
 217                                           (sb!di:code-location= x y)))))
 218         (t
 219          (find place info-list
 220                :test #'(lambda (x-debug-function y-info)
 221                          (let ((y-place (breakpoint-info-place y-info))
 222                                (y-breakpoint (breakpoint-info-breakpoint
 223                                               y-info)))
 224                            (and (sb!di:debug-function-p y-place)
 225                                 (eq x-debug-function y-place)
 226                                 (or (not kind)
 227                                     (eq kind (sb!di:breakpoint-kind
 228                                               y-breakpoint))))))))))
 229
 230 ;;; If Loc is an unknown location, then try to find the block start location.
 231 ;;; Used by source printing to some information instead of none for the user.
 232 (defun maybe-block-start-location (loc)
 233   (if (sb!di:code-location-unknown-p loc)
 234       (let* ((block (sb!di:code-location-debug-block loc))
 235              (start (sb!di:do-debug-block-locations (loc block)
 236                       (return loc))))
 237         (cond ((and (not (sb!di:debug-block-elsewhere-p block))
 238                     start)
 239                ;; FIXME: Why output on T instead of *DEBUG-FOO* or something?
 240                (format t "~%unknown location: using block start~%")
 241                start)
 242               (t
 243                loc)))
 244       loc))
 245 \f
 246 ;;;; the BREAKPOINT-INFO structure
 247
 248 ;;; info about a made breakpoint
 249 (defstruct breakpoint-info
 250   ;; where we are going to stop
 251   (place (required-argument)
 252          :type (or sb!di:code-location sb!di:debug-function))
 253   ;; the breakpoint returned by sb!di:make-breakpoint
 254   (breakpoint (required-argument) :type sb!di:breakpoint)
 255   ;; the function returned from sb!di:preprocess-for-eval. If result is
 256   ;; non-NIL, drop into the debugger.
 257   (break #'identity :type function)
 258   ;; the function returned from sb!di:preprocess-for-eval. If result is
 259   ;; non-NIL, eval (each) print and print results.
 260   (condition #'identity :type function)
 261   ;; the list of functions from sb!di:preprocess-for-eval to evaluate. Results
 262   ;; are conditionally printed. Car of each element is the function, cdr is the
 263   ;; form it goes with.
 264   (print nil :type list)
 265   ;; the number used when listing the possible breakpoints within a function.
 266   ;; Could also be a symbol such as start or end.
 267   (code-location-number (required-argument) :type (or symbol integer))
 268   ;; the number used when listing the breakpoints active and to delete
 269   ;; breakpoints
 270   (breakpoint-number (required-argument) :type integer))
 271
 272 ;;; Return a new BREAKPOINT-INFO structure with the info passed.
 273 (defun create-breakpoint-info (place breakpoint code-location-number
 274                                      &key (break #'identity)
 275                                      (condition #'identity) (print nil))
 276   (setf *breakpoints*
 277         (sort *breakpoints* #'< :key #'breakpoint-info-breakpoint-number))
 278   (let ((breakpoint-number
 279          (do ((i 1 (incf i)) (breakpoints *breakpoints* (rest breakpoints)))
 280              ((or (> i (length *breakpoints*))
 281                   (not (= i (breakpoint-info-breakpoint-number
 282                              (first breakpoints)))))
 283
 284               i))))
 285     (make-breakpoint-info :place place :breakpoint breakpoint
 286                           :code-location-number code-location-number
 287                           :breakpoint-number breakpoint-number
 288                           :break break :condition condition :print print)))
 289
 290 ;;; Print the breakpoint info for the breakpoint-info structure passed.
 291 (defun print-breakpoint-info (breakpoint-info)
 292   (let ((place (breakpoint-info-place breakpoint-info))
 293         (bp-number (breakpoint-info-breakpoint-number breakpoint-info))
 294         (loc-number (breakpoint-info-code-location-number breakpoint-info)))
 295     (case (sb!di:breakpoint-kind (breakpoint-info-breakpoint breakpoint-info))
 296       (:code-location
 297        (print-code-location-source-form place 0)
 298        (format t
 299                "~&~S: ~S in ~S"
 300                bp-number
 301                loc-number
 302                (sb!di:debug-function-name (sb!di:code-location-debug-function
 303                                            place))))
 304       (:function-start
 305        (format t "~&~S: FUNCTION-START in ~S" bp-number
 306                (sb!di:debug-function-name place)))
 307       (:function-end
 308        (format t "~&~S: FUNCTION-END in ~S" bp-number
 309                (sb!di:debug-function-name place))))))
 310 \f
 311 ;;;; MAIN-HOOK-FUNCTION for steps and breakpoints
 312
 313 ;;; This must be passed as the hook function. It keeps track of where step
 314 ;;; breakpoints are.
 315 (defun main-hook-function (current-frame breakpoint &optional return-vals
 316                                          function-end-cookie)
 317   (setf *default-breakpoint-debug-function*
 318         (sb!di:frame-debug-function current-frame))
 319   (dolist (step-info *step-breakpoints*)
 320     (sb!di:delete-breakpoint (breakpoint-info-breakpoint step-info))
 321     (let ((bp-info (location-in-list step-info *breakpoints*)))
 322       (when bp-info
 323         (sb!di:activate-breakpoint (breakpoint-info-breakpoint bp-info)))))
 324   (let ((*stack-top-hint* current-frame)
 325         (step-hit-info
 326          (location-in-list (sb!di:breakpoint-what breakpoint)
 327                            *step-breakpoints*
 328                            (sb!di:breakpoint-kind breakpoint)))
 329         (bp-hit-info
 330          (location-in-list (sb!di:breakpoint-what breakpoint)
 331                            *breakpoints*
 332                            (sb!di:breakpoint-kind breakpoint)))
 333         (break)
 334         (condition)
 335         (string ""))
 336     (setf *step-breakpoints* nil)
 337     (labels ((build-string (str)
 338                (setf string (concatenate 'string string str)))
 339              (print-common-info ()
 340                (build-string
 341                 (with-output-to-string (*standard-output*)
 342                   (when function-end-cookie
 343                     (format t "~%Return values: ~S" return-vals))
 344                   (when condition
 345                     (when (breakpoint-info-print bp-hit-info)
 346                       (format t "~%")
 347                       (print-frame-call current-frame))
 348                     (dolist (print (breakpoint-info-print bp-hit-info))
 349                       (format t "~& ~S = ~S" (rest print)
 350                               (funcall (first print) current-frame))))))))
 351       (when bp-hit-info
 352         (setf break (funcall (breakpoint-info-break bp-hit-info)
 353                              current-frame))
 354         (setf condition (funcall (breakpoint-info-condition bp-hit-info)
 355                                  current-frame)))
 356       (cond ((and bp-hit-info step-hit-info (= 1 *number-of-steps*))
 357              (build-string (format nil "~&*Step (to a breakpoint)*"))
 358              (print-common-info)
 359              (break string))
 360             ((and bp-hit-info step-hit-info break)
 361              (build-string (format nil "~&*Step (to a breakpoint)*"))
 362              (print-common-info)
 363              (break string))
 364             ((and bp-hit-info step-hit-info)
 365              (print-common-info)
 366              (format t "~A" string)
 367              (decf *number-of-steps*)
 368              (set-step-breakpoint current-frame))
 369             ((and step-hit-info (= 1 *number-of-steps*))
 370              (build-string "*Step*")
 371              (break (make-condition 'step-condition :format-control string)))
 372             (step-hit-info
 373              (decf *number-of-steps*)
 374              (set-step-breakpoint current-frame))
 375             (bp-hit-info
 376              (when break
 377                (build-string (format nil "~&*Breakpoint hit*")))
 378              (print-common-info)
 379              (if break
 380                  (break string)
 381                  (format t "~A" string)))
 382             (t
 383              (break "error in main-hook-function: unknown breakpoint"))))))
 384 \f
 385 ;;; Set breakpoints at the next possible code-locations. After calling
 386 ;;; this, either (CONTINUE) if in the debugger or just let program flow
 387 ;;; return if in a hook function.
 388 (defun set-step-breakpoint (frame)
 389   (cond
 390    ((sb!di:debug-block-elsewhere-p (sb!di:code-location-debug-block
 391                                     (sb!di:frame-code-location frame)))
 392     ;; FIXME: FORMAT T is used for error output here and elsewhere in
 393     ;; the debug code.
 394     (format t "cannot step, in elsewhere code~%"))
 395    (t
 396     (let* ((code-location (sb!di:frame-code-location frame))
 397            (next-code-locations (next-code-locations code-location)))
 398       (cond
 399        (next-code-locations
 400         (dolist (code-location next-code-locations)
 401           (let ((bp-info (location-in-list code-location *breakpoints*)))
 402             (when bp-info
 403               (sb!di:deactivate-breakpoint (breakpoint-info-breakpoint
 404                                             bp-info))))
 405           (let ((bp (sb!di:make-breakpoint #'main-hook-function code-location
 406                                            :kind :code-location)))
 407             (sb!di:activate-breakpoint bp)
 408             (push (create-breakpoint-info code-location bp 0)
 409                   *step-breakpoints*))))
 410        (t
 411         (let* ((debug-function (sb!di:frame-debug-function *current-frame*))
 412                (bp (sb!di:make-breakpoint #'main-hook-function debug-function
 413                                           :kind :function-end)))
 414           (sb!di:activate-breakpoint bp)
 415           (push (create-breakpoint-info debug-function bp 0)
 416                 *step-breakpoints*))))))))
 417 \f
 418 ;;;; STEP
 419
 420 ;;; ANSI specifies that this macro shall exist, even if only as a
 421 ;;; trivial placeholder like this.
 422 (defmacro step (form)
 423   "a trivial placeholder implementation of the CL:STEP macro required by
 424    the ANSI spec"
 425   `(progn
 426      ,form))
 427 \f
 428 ;;;; BACKTRACE
 429
 430 (defun backtrace (&optional (count most-positive-fixnum)
 431                             (*standard-output* *debug-io*))
 432   #!+sb-doc
 433   "Show a listing of the call stack going down from the current frame. In the
 434    debugger, the current frame is indicated by the prompt. Count is how many
 435    frames to show."
 436   (fresh-line *standard-output*)
 437   (do ((frame (if *in-the-debugger* *current-frame* (sb!di:top-frame))
 438               (sb!di:frame-down frame))
 439        (count count (1- count)))
 440       ((or (null frame) (zerop count)))
 441     (print-frame-call frame :number t))
 442   (fresh-line *standard-output*)
 443   (values))
 444 \f
 445 ;;;; frame printing
 446
 447 (eval-when (:compile-toplevel :execute)
 448
 449 ;;; This is a convenient way to express what to do for each type of lambda-list
 450 ;;; element.
 451 (sb!xc:defmacro lambda-list-element-dispatch (element
 452                                               &key
 453                                               required
 454                                               optional
 455                                               rest
 456                                               keyword
 457                                               deleted)
 458   `(etypecase ,element
 459      (sb!di:debug-var
 460       ,@required)
 461      (cons
 462       (ecase (car ,element)
 463         (:optional ,@optional)
 464         (:rest ,@rest)
 465         (:keyword ,@keyword)))
 466      (symbol
 467       (assert (eq ,element :deleted))
 468       ,@deleted)))
 469
 470 (sb!xc:defmacro lambda-var-dispatch (variable location deleted valid other)
 471   (let ((var (gensym)))
 472     `(let ((,var ,variable))
 473        (cond ((eq ,var :deleted) ,deleted)
 474              ((eq (sb!di:debug-var-validity ,var ,location) :valid)
 475               ,valid)
 476              (t ,other)))))
 477
 478 ) ; EVAL-WHEN
 479
 480 ;;; This is used in constructing arg lists for debugger printing when
 481 ;;; the arg list is unavailable, some arg is unavailable or unused,
 482 ;;; etc.
 483 (defstruct (unprintable-object
 484             (:constructor make-unprintable-object (string))
 485             (:print-object (lambda (x s)
 486                              (print-unreadable-object (x s :type t)
 487                                (write-string (unprintable-object-string x)
 488                                              s)))))
 489   string)
 490
 491 ;;; Print FRAME with verbosity level 1. If we hit a &REST arg, then
 492 ;;; print as many of the values as possible, punting the loop over
 493 ;;; lambda-list variables since any other arguments will be in the
 494 ;;; &REST arg's list of values.
 495 (defun print-frame-call-1 (frame)
 496   (let* ((d-fun (sb!di:frame-debug-function frame))
 497          (loc (sb!di:frame-code-location frame))
 498          (results (list (sb!di:debug-function-name d-fun))))
 499     (handler-case
 500         (dolist (ele (sb!di:debug-function-lambda-list d-fun))
 501           (lambda-list-element-dispatch ele
 502             :required ((push (frame-call-arg ele loc frame) results))
 503             :optional ((push (frame-call-arg (second ele) loc frame) results))
 504             :keyword ((push (second ele) results)
 505                       (push (frame-call-arg (third ele) loc frame) results))
 506             :deleted ((push (frame-call-arg ele loc frame) results))
 507             :rest ((lambda-var-dispatch (second ele) loc
 508                      nil
 509                      (progn
 510                        (setf results
 511                              (append (reverse (sb!di:debug-var-value
 512                                                (second ele) frame))
 513                                      results))
 514                        (return))
 515                      (push (make-unprintable-object
 516                             "unavailable &REST argument")
 517                            results)))))
 518       (sb!di:lambda-list-unavailable
 519        ()
 520        (push (make-unprintable-object "lambda list unavailable") results)))
 521     (pprint-logical-block (*standard-output* nil)
 522       (let ((x (nreverse (mapcar #'ensure-printable-object results))))
 523         (format t "(~@<~S~{ ~_~S~}~:>)" (first x) (rest x))))
 524     (when (sb!di:debug-function-kind d-fun)
 525       (write-char #\[)
 526       (prin1 (sb!di:debug-function-kind d-fun))
 527       (write-char #\]))))
 528
 529 (defun ensure-printable-object (object)
 530   (handler-case
 531       (with-open-stream (out (make-broadcast-stream))
 532         (prin1 object out)
 533         object)
 534     (error (cond)
 535       (declare (ignore cond))
 536       (make-unprintable-object "error printing object"))))
 537
 538 (defun frame-call-arg (var location frame)
 539   (lambda-var-dispatch var location
 540     (make-unprintable-object "unused argument")
 541     (sb!di:debug-var-value var frame)
 542     (make-unprintable-object "unavailable argument")))
 543
 544 ;;; Prints a representation of the function call causing FRAME to
 545 ;;; exist. VERBOSITY indicates the level of information to output;
 546 ;;; zero indicates just printing the debug-function's name, and one
 547 ;;; indicates displaying call-like, one-liner format with argument
 548 ;;; values.
 549 (defun print-frame-call (frame &key (verbosity 1) (number nil))
 550   (cond
 551    ((zerop verbosity)
 552     (when number
 553       (format t "~&~S: " (sb!di:frame-number frame)))
 554     (format t "~S" frame))
 555    (t
 556     (when number
 557       (format t "~&~S: " (sb!di:frame-number frame)))
 558     (print-frame-call-1 frame)))
 559   (when (>= verbosity 2)
 560     (let ((loc (sb!di:frame-code-location frame)))
 561       (handler-case
 562           (progn
 563             (sb!di:code-location-debug-block loc)
 564             (format t "~%source: ")
 565             (print-code-location-source-form loc 0))
 566         (sb!di:debug-condition (ignore) ignore)
 567         (error (c) (format t "error finding source: ~A" c))))))
 568 \f
 569 ;;;; INVOKE-DEBUGGER
 570
 571 (defvar *debugger-hook* nil
 572   #!+sb-doc
 573   "This is either NIL or a function of two arguments, a condition and the value
 574    of *DEBUGGER-HOOK*. This function can either handle the condition or return
 575    which causes the standard debugger to execute. The system passes the value
 576    of this variable to the function because it binds *DEBUGGER-HOOK* to NIL
 577    around the invocation.")
 578
 579 ;;; These are bound on each invocation of INVOKE-DEBUGGER.
 580 (defvar *debug-restarts*)
 581 (defvar *debug-condition*)
 582
 583 ;;; Print *DEBUG-CONDITION*, taking care to avoid recursive invocation
 584 ;;; of the debugger in case of a problem (e.g. a bug in the PRINT-OBJECT
 585 ;;; method for *DEBUG-CONDITION*).
 586 (defun princ-debug-condition-carefully (stream)
 587   (handler-case (princ *debug-condition* stream)
 588     (error (condition)
 589            (format stream
 590                    "  (caught ~S when trying to print ~S)"
 591                    (type-of condition)
 592                    '*debug-condition*)))
 593   *debug-condition*)
 594
 595 (defun invoke-debugger (condition)
 596   #!+sb-doc
 597   "Enter the debugger."
 598   (let ((old-hook *debugger-hook*))
 599     (when old-hook
 600       (let ((*debugger-hook* nil))
 601         (funcall old-hook condition old-hook))))
 602   (sb!unix:unix-sigsetmask 0)
 603
 604   ;; Elsewhere in the system, we use the SANE-PACKAGE function for
 605   ;; this, but here causing an exception just as we're trying to handle
 606   ;; an exception would be confusing, so instead we use a special hack.
 607   (unless (and (packagep *package*)
 608                (package-name *package*))
 609     (setf *package* (find-package :cl-user))
 610     (format *error-output*
 611             "The value of ~S was not an undeleted PACKAGE. It has been
 612 reset to ~S."
 613             '*package* *package*))
 614   (let (;; Save *PACKAGE* to protect it from WITH-STANDARD-IO-SYNTAX.
 615         (original-package *package*))
 616     (with-standard-io-syntax
 617      (let* ((*debug-condition* condition)
 618             (*debug-restarts* (compute-restarts condition))
 619             ;; We want the i/o subsystem to be in a known, useful
 620             ;; state, regardless of where the debugger was invoked in
 621             ;; the program. WITH-STANDARD-IO-SYNTAX does some of that,
 622             ;; but
 623             ;;   1. It doesn't affect our internal special variables
 624             ;;      like *CURRENT-LEVEL*.
 625             ;;   2. It isn't customizable.
 626             ;;   3. It doesn't set *PRINT-READABLY* or *PRINT-PRETTY*
 627             ;;      to the same value as the toplevel default.
 628             ;;   4. It sets *PACKAGE* to COMMON-LISP-USER, which is not
 629             ;;      helpful behavior for a debugger.
 630             ;; We try to remedy all these problems with explicit
 631             ;; rebindings here.
 632             (sb!kernel:*current-level* 0)
 633             (*print-length* *debug-print-length*)
 634             (*print-level* *debug-print-level*)
 635             (*readtable* *debug-readtable*)
 636             (*print-readably* nil)
 637             (*print-pretty* t)
 638             (*package* original-package))
 639
 640        ;; Before we start our own output, finish any pending output.
 641        ;; Otherwise, if the user tried to track the progress of
 642        ;; his program using PRINT statements, he'd tend to lose
 643        ;; the last line of output or so, and get confused.
 644        (flush-standard-output-streams)
 645
 646        ;; The initial output here goes to *ERROR-OUTPUT*, because the
 647        ;; initial output is not interactive, just an error message,
 648        ;; and when people redirect *ERROR-OUTPUT*, they could
 649        ;; reasonably expect to see error messages logged there,
 650        ;; regardless of what the debugger does afterwards.
 651        (format *error-output*
 652                "~2&debugger invoked on condition of type ~S:~%  "
 653                (type-of *debug-condition*))
 654        (princ-debug-condition-carefully *error-output*)
 655        (terpri *error-output*)
 656
 657        ;; After the initial error/condition/whatever announcement to
 658        ;; *ERROR-OUTPUT*, we become interactive, and should talk on
 659        ;; *DEBUG-IO* from now on. (KLUDGE: This is a normative
 660        ;; statement, not a description of reality.:-| There's a lot of
 661        ;; older debugger code which was written to do i/o on whatever
 662        ;; stream was in fashion at the time, and not all of it has
 663        ;; been converted to behave this way. -- WHN 2000-11-16)
 664        (let (;; FIXME: The first two bindings here seem wrong,
 665              ;; violating the principle of least surprise, and making
 666              ;; it impossible for the user to do reasonable things
 667              ;; like using PRINT at the debugger prompt to send output
 668              ;; to the program's ordinary (possibly
 669              ;; redirected-to-a-file) *STANDARD-OUTPUT*, or using
 670              ;; PEEK-CHAR or some such thing on the program's ordinary
 671              ;; (possibly also redirected) *STANDARD-INPUT*.
 672              (*standard-input* *debug-io*)
 673              (*standard-output* *debug-io*)
 674              ;; This seems reasonable: e.g. if the user has redirected
 675              ;; *ERROR-OUTPUT* to some log file, it's probably wrong
 676              ;; to send errors which occur in interactive debugging to
 677              ;; that file, and right to send them to *DEBUG-IO*.
 678              (*error-output* *debug-io*))
 679          (unless (typep condition 'step-condition)
 680            (format *debug-io*
 681                    "~%~@<Within the debugger, you can type HELP for help. At ~
 682                    any command prompt (within the debugger or not) you can ~
 683                    type (SB-EXT:QUIT) to terminate the SBCL executable. ~
 684                    The condition which caused the debugger to be entered ~
 685                    is bound to ~S.~:@>~2%"
 686                    '*debug-condition*)
 687            (show-restarts *debug-restarts* *debug-io*)
 688            (terpri *debug-io*))
 689          (internal-debug))))))
 690
 691 (defun show-restarts (restarts s)
 692   (when restarts
 693     (format s "~&restarts:~%")
 694     (let ((count 0)
 695           (names-used '(nil))
 696           (max-name-len 0))
 697       (dolist (restart restarts)
 698         (let ((name (restart-name restart)))
 699           (when name
 700             (let ((len (length (princ-to-string name))))
 701               (when (> len max-name-len)
 702                 (setf max-name-len len))))))
 703       (unless (zerop max-name-len)
 704         (incf max-name-len 3))
 705       (dolist (restart restarts)
 706         (let ((name (restart-name restart)))
 707           (cond ((member name names-used)
 708                  (format s "~& ~2D: ~@VT~A~%" count max-name-len restart))
 709                 (t
 710                  (format s "~& ~2D: [~VA] ~A~%"
 711                          count (- max-name-len 3) name restart)
 712                  (push name names-used))))
 713         (incf count)))))
 714
 715 ;;; This calls DEBUG-LOOP, performing some simple initializations
 716 ;;; before doing so. INVOKE-DEBUGGER calls this to actually get into
 717 ;;; the debugger. SB!KERNEL::ERROR-ERROR calls this in emergencies
 718 ;;; to get into a debug prompt as quickly as possible with as little
 719 ;;; risk as possible for stepping on whatever is causing recursive
 720 ;;; errors.
 721 (defun internal-debug ()
 722   (let ((*in-the-debugger* t)
 723         (*read-suppress* nil))
 724     (unless (typep *debug-condition* 'step-condition)
 725       (clear-input *debug-io*))
 726     #!-mp (debug-loop)
 727     #!+mp (sb!mp:without-scheduling (debug-loop))))
 728 \f
 729 ;;;; DEBUG-LOOP
 730
 731 ;;; Note: This defaulted to T in CMU CL. The changed default in SBCL
 732 ;;; was motivated by desire to play nicely with ILISP.
 733 (defvar *flush-debug-errors* nil
 734   #!+sb-doc
 735   "When set, avoid calling INVOKE-DEBUGGER recursively when errors occur while
 736    executing in the debugger.")
 737
 738 (defun debug-loop ()
 739   (let* ((*debug-command-level* (1+ *debug-command-level*))
 740          (*real-stack-top* (sb!di:top-frame))
 741          (*stack-top* (or *stack-top-hint* *real-stack-top*))
 742          (*stack-top-hint* nil)
 743          (*current-frame* *stack-top*))
 744     (handler-bind ((sb!di:debug-condition (lambda (condition)
 745                                             (princ condition *debug-io*)
 746                                             (throw 'debug-loop-catcher nil))))
 747       (fresh-line)
 748       (print-frame-call *current-frame* :verbosity 2)
 749       (loop
 750         (catch 'debug-loop-catcher
 751           (handler-bind ((error #'(lambda (condition)
 752                                     (when *flush-debug-errors*
 753                                       (clear-input *debug-io*)
 754                                       (princ condition)
 755                                       ;; FIXME: Doing input on *DEBUG-IO*
 756                                       ;; and output on T seems broken.
 757                                       (format t
 758                                               "~&error flushed (because ~
 759                                                ~S is set)"
 760                                               '*flush-debug-errors*)
 761                                       (throw 'debug-loop-catcher nil)))))
 762             ;; We have to bind level for the restart function created by
 763             ;; WITH-SIMPLE-RESTART.
 764             (let ((level *debug-command-level*)
 765                   (restart-commands (make-restart-commands)))
 766               (with-simple-restart (abort
 767                                    "Reduce debugger level (to debug level ~D)."
 768                                     level)
 769                 (debug-prompt *debug-io*)
 770                 (force-output *debug-io*)
 771                 (let ((input (sb!int:get-stream-command *debug-io*)))
 772                   (cond (input
 773                          (let ((cmd-fun (debug-command-p
 774                                          (sb!int:stream-command-name input)
 775                                          restart-commands)))
 776                            (cond
 777                             ((not cmd-fun)
 778                              (error "unknown stream-command: ~S" input))
 779                             ((consp cmd-fun)
 780                              (error "ambiguous debugger command: ~S" cmd-fun))
 781                             (t
 782                              (apply cmd-fun
 783                                     (sb!int:stream-command-args input))))))
 784                         (t
 785                          (let* ((exp (read))
 786                                 (cmd-fun (debug-command-p exp
 787                                                           restart-commands)))
 788                            (cond ((not cmd-fun)
 789                                   (debug-eval-print exp))
 790                                  ((consp cmd-fun)
 791                                   (format t
 792                                           "~&Your command, ~S, is ambiguous:~%"
 793                                           exp)
 794                                   (dolist (ele cmd-fun)
 795                                     (format t "   ~A~%" ele)))
 796                                  (t
 797                                   (funcall cmd-fun)))))))))))))))
 798
 799 (defvar *auto-eval-in-frame* t
 800   #!+sb-doc
 801   "When set (the default), evaluations in the debugger's command loop occur
 802    relative to the current frame's environment without the need of debugger
 803    forms that explicitly control this kind of evaluation.")
 804
 805 ;;; FIXME: We could probably use INTERACTIVE-EVAL for much of this logic.
 806 (defun debug-eval-print (exp)
 807   (setq +++ ++ ++ + + - - exp)
 808   (let* ((values (multiple-value-list
 809                   (if (and (fboundp 'compile) *auto-eval-in-frame*)
 810                       (sb!di:eval-in-frame *current-frame* -)
 811                       (eval -))))
 812          (*standard-output* *debug-io*))
 813     (fresh-line)
 814     (if values (prin1 (car values)))
 815     (dolist (x (cdr values))
 816       (fresh-line)
 817       (prin1 x))
 818     (setq /// // // / / values)
 819     (setq *** ** ** * * (car values))
 820     ;; Make sure that nobody passes back an unbound marker.
 821     (unless (boundp '*)
 822       (setq * nil)
 823       (fresh-line)
 824       ;; FIXME: The way INTERACTIVE-EVAL does this seems better.
 825       (princ "Setting * to NIL (was unbound marker)."))))
 826 \f
 827 ;;;; debug loop functions
 828
 829 ;;; These commands are functions, not really commands, so that users can get
 830 ;;; their hands on the values returned.
 831
 832 (eval-when (:execute :compile-toplevel)
 833
 834 (sb!xc:defmacro define-var-operation (ref-or-set &optional value-var)
 835   `(let* ((temp (etypecase name
 836                   (symbol (sb!di:debug-function-symbol-variables
 837                            (sb!di:frame-debug-function *current-frame*)
 838                            name))
 839                   (simple-string (sb!di:ambiguous-debug-vars
 840                                   (sb!di:frame-debug-function *current-frame*)
 841                                   name))))
 842           (location (sb!di:frame-code-location *current-frame*))
 843           ;; Let's only deal with valid variables.
 844           (vars (remove-if-not #'(lambda (v)
 845                                    (eq (sb!di:debug-var-validity v location)
 846                                        :valid))
 847                                temp)))
 848      (declare (list vars))
 849      (cond ((null vars)
 850             (error "No known valid variables match ~S." name))
 851            ((= (length vars) 1)
 852             ,(ecase ref-or-set
 853                (:ref
 854                 '(sb!di:debug-var-value (car vars) *current-frame*))
 855                (:set
 856                 `(setf (sb!di:debug-var-value (car vars) *current-frame*)
 857                        ,value-var))))
 858            (t
 859             ;; Since we have more than one, first see whether we have any
 860             ;; variables that exactly match the specification.
 861             (let* ((name (etypecase name
 862                            (symbol (symbol-name name))
 863                            (simple-string name)))
 864                    ;; FIXME: REMOVE-IF-NOT is deprecated, use STRING/=
 865                    ;; instead.
 866                    (exact (remove-if-not (lambda (v)
 867                                            (string= (sb!di:debug-var-symbol-name v)
 868                                                     name))
 869                                          vars))
 870                    (vars (or exact vars)))
 871               (declare (simple-string name)
 872                        (list exact vars))
 873               (cond
 874                ;; Check now for only having one variable.
 875                ((= (length vars) 1)
 876                 ,(ecase ref-or-set
 877                    (:ref
 878                     '(sb!di:debug-var-value (car vars) *current-frame*))
 879                    (:set
 880                     `(setf (sb!di:debug-var-value (car vars) *current-frame*)
 881                            ,value-var))))
 882                ;; If there weren't any exact matches, flame about
 883                ;; ambiguity unless all the variables have the same
 884                ;; name.
 885                ((and (not exact)
 886                      (find-if-not
 887                       #'(lambda (v)
 888                           (string= (sb!di:debug-var-symbol-name v)
 889                                    (sb!di:debug-var-symbol-name (car vars))))
 890                       (cdr vars)))
 891                 (error "specification ambiguous:~%~{   ~A~%~}"
 892                        (mapcar #'sb!di:debug-var-symbol-name
 893                                (delete-duplicates
 894                                 vars :test #'string=
 895                                 :key #'sb!di:debug-var-symbol-name))))
 896                ;; All names are the same, so see whether the user
 897                ;; ID'ed one of them.
 898                (id-supplied
 899                 (let ((v (find id vars :key #'sb!di:debug-var-id)))
 900                   (unless v
 901                     (error
 902                      "invalid variable ID, ~D: should have been one of ~S"
 903                      id
 904                      (mapcar #'sb!di:debug-var-id vars)))
 905                   ,(ecase ref-or-set
 906                      (:ref
 907                       '(sb!di:debug-var-value v *current-frame*))
 908                      (:set
 909                       `(setf (sb!di:debug-var-value v *current-frame*)
 910                              ,value-var)))))
 911                (t
 912                 (error "Specify variable ID to disambiguate ~S. Use one of ~S."
 913                        name
 914                        (mapcar #'sb!di:debug-var-id vars)))))))))
 915
 916 ) ; EVAL-WHEN
 917
 918 (defun var (name &optional (id 0 id-supplied))
 919   #!+sb-doc
 920   "Returns a variable's value if possible. Name is a simple-string or symbol.
 921    If it is a simple-string, it is an initial substring of the variable's name.
 922    If name is a symbol, it has the same name and package as the variable whose
 923    value this function returns. If the symbol is uninterned, then the variable
 924    has the same name as the symbol, but it has no package.
 925
 926    If name is the initial substring of variables with different names, then
 927    this return no values after displaying the ambiguous names. If name
 928    determines multiple variables with the same name, then you must use the
 929    optional id argument to specify which one you want. If you left id
 930    unspecified, then this returns no values after displaying the distinguishing
 931    id values.
 932
 933    The result of this function is limited to the availability of variable
 934    information. This is SETF'able."
 935   (define-var-operation :ref))
 936 (defun (setf var) (value name &optional (id 0 id-supplied))
 937   (define-var-operation :set value))
 938
 939 ;;; This returns the COUNT'th arg as the user sees it from args, the
 940 ;;; result of SB!DI:DEBUG-FUNCTION-LAMBDA-LIST. If this returns a
 941 ;;; potential DEBUG-VAR from the lambda-list, then the second value is
 942 ;;; T. If this returns a keyword symbol or a value from a rest arg,
 943 ;;; then the second value is NIL.
 944 (declaim (ftype (function (index list)) nth-arg))
 945 (defun nth-arg (count args)
 946   (let ((n count))
 947     (dolist (ele args (error "The argument specification ~S is out of range."
 948                              n))
 949       (lambda-list-element-dispatch ele
 950         :required ((if (zerop n) (return (values ele t))))
 951         :optional ((if (zerop n) (return (values (second ele) t))))
 952         :keyword ((cond ((zerop n)
 953                          (return (values (second ele) nil)))
 954                         ((zerop (decf n))
 955                          (return (values (third ele) t)))))
 956         :deleted ((if (zerop n) (return (values ele t))))
 957         :rest ((let ((var (second ele)))
 958                  (lambda-var-dispatch var (sb!di:frame-code-location
 959                                            *current-frame*)
 960                    (error "unused &REST argument before n'th argument")
 961                    (dolist (value
 962                             (sb!di:debug-var-value var *current-frame*)
 963                             (error
 964                              "The argument specification ~S is out of range."
 965                              n))
 966                      (if (zerop n)
 967                          (return-from nth-arg (values value nil))
 968                          (decf n)))
 969                    (error "invalid &REST argument before n'th argument")))))
 970       (decf n))))
 971
 972 (defun arg (n)
 973   #!+sb-doc
 974   "Returns the N'th argument's value if possible. Argument zero is the first
 975    argument in a frame's default printed representation. Count keyword/value
 976    pairs as separate arguments."
 977   (multiple-value-bind (var lambda-var-p)
 978       (nth-arg n (handler-case (sb!di:debug-function-lambda-list
 979                                 (sb!di:frame-debug-function *current-frame*))
 980                    (sb!di:lambda-list-unavailable ()
 981                      (error "No argument values are available."))))
 982     (if lambda-var-p
 983         (lambda-var-dispatch var (sb!di:frame-code-location *current-frame*)
 984           (error "Unused arguments have no values.")
 985           (sb!di:debug-var-value var *current-frame*)
 986           (error "invalid argument value"))
 987         var)))
 988 \f
 989 ;;;; machinery for definition of debug loop commands
 990
 991 (defvar *debug-commands* nil)
 992
 993 ;;; Interface to *DEBUG-COMMANDS*. No required arguments in args are
 994 ;;; permitted.
 995 ;;;
 996 ;;; FIXME: This is not needed in the target Lisp system.
 997 (defmacro def-debug-command (name args &rest body)
 998   (let ((fun-name (intern (concatenate 'simple-string name "-DEBUG-COMMAND"))))
 999     `(progn
1000        (setf *debug-commands*
1001              (remove ,name *debug-commands* :key #'car :test #'string=))
1002        (defun ,fun-name ,args
1003          (unless *in-the-debugger*
1004            (error "invoking debugger command while outside the debugger"))
1005          ,@body)
1006        (push (cons ,name #',fun-name) *debug-commands*)
1007        ',fun-name)))
1008
1009 (defun def-debug-command-alias (new-name existing-name)
1010   (let ((pair (assoc existing-name *debug-commands* :test #'string=)))
1011     (unless pair (error "unknown debug command name: ~S" existing-name))
1012     (push (cons new-name (cdr pair)) *debug-commands*))
1013   new-name)
1014
1015 ;;; This takes a symbol and uses its name to find a debugger command, using
1016 ;;; initial substring matching. It returns the command function if form
1017 ;;; identifies only one command, but if form is ambiguous, this returns a list
1018 ;;; of the command names. If there are no matches, this returns nil. Whenever
1019 ;;; the loop that looks for a set of possibilities encounters an exact name
1020 ;;; match, we return that command function immediately.
1021 (defun debug-command-p (form &optional other-commands)
1022   (if (or (symbolp form) (integerp form))
1023       (let* ((name
1024               (if (symbolp form)
1025                   (symbol-name form)
1026                   (format nil "~D" form)))
1027              (len (length name))
1028              (res nil))
1029         (declare (simple-string name)
1030                  (fixnum len)
1031                  (list res))
1032
1033         ;; Find matching commands, punting if exact match.
1034         (flet ((match-command (ele)
1035                  (let* ((str (car ele))
1036                         (str-len (length str)))
1037                    (declare (simple-string str)
1038                             (fixnum str-len))
1039                    (cond ((< str-len len))
1040                          ((= str-len len)
1041                           (when (string= name str :end1 len :end2 len)
1042                             (return-from debug-command-p (cdr ele))))
1043                          ((string= name str :end1 len :end2 len)
1044                           (push ele res))))))
1045           (mapc #'match-command *debug-commands*)
1046           (mapc #'match-command other-commands))
1047
1048         ;; Return the right value.
1049         (cond ((not res) nil)
1050               ((= (length res) 1)
1051                (cdar res))
1052               (t ; Just return the names.
1053                (do ((cmds res (cdr cmds)))
1054                    ((not cmds) res)
1055                  (setf (car cmds) (caar cmds))))))))
1056
1057 ;;; Returns a list of debug commands (in the same format as *debug-commands*)
1058 ;;; that invoke each active restart.
1059 ;;;
1060 ;;; Two commands are made for each restart: one for the number, and one for
1061 ;;; the restart name (unless it's been shadowed by an earlier restart of the
1062 ;;; same name).
1063 (defun make-restart-commands (&optional (restarts *debug-restarts*))
1064   (let ((commands)
1065         (num 0))                        ; better be the same as show-restarts!
1066     (dolist (restart restarts)
1067       (let ((name (string (restart-name restart))))
1068         (unless (find name commands :key #'car :test #'string=)
1069           (let ((restart-fun
1070                  #'(lambda ()
1071                      (invoke-restart-interactively restart))))
1072             (push (cons name restart-fun) commands)
1073             (push (cons (format nil "~D" num) restart-fun) commands))))
1074       (incf num))
1075     commands))
1076 \f
1077 ;;;; frame-changing commands
1078
1079 (def-debug-command "UP" ()
1080   (let ((next (sb!di:frame-up *current-frame*)))
1081     (cond (next
1082            (setf *current-frame* next)
1083            (print-frame-call next))
1084           (t
1085            (format t "~&Top of stack.")))))
1086
1087 (def-debug-command "DOWN" ()
1088   (let ((next (sb!di:frame-down *current-frame*)))
1089     (cond (next
1090            (setf *current-frame* next)
1091            (print-frame-call next))
1092           (t
1093            (format t "~&Bottom of stack.")))))
1094
1095 (def-debug-command-alias "D" "DOWN")
1096
1097 ;;; CMU CL had this command, but SBCL doesn't, since
1098 ;;; it's redundant with "FRAME 0", and it interferes with abbreviations
1099 ;;; for the TOPLEVEL restart.
1100 ;;;(def-debug-command "TOP" ()
1101 ;;;  (do ((prev *current-frame* lead)
1102 ;;;       (lead (sb!di:frame-up *current-frame*) (sb!di:frame-up lead)))
1103 ;;;      ((null lead)
1104 ;;;       (setf *current-frame* prev)
1105 ;;;       (print-frame-call prev))))
1106
1107 (def-debug-command "BOTTOM" ()
1108   (do ((prev *current-frame* lead)
1109        (lead (sb!di:frame-down *current-frame*) (sb!di:frame-down lead)))
1110       ((null lead)
1111        (setf *current-frame* prev)
1112        (print-frame-call prev))))
1113
1114 (def-debug-command-alias "B" "BOTTOM")
1115
1116 (def-debug-command "FRAME" (&optional
1117                             (n (read-prompting-maybe "frame number: ")))
1118   (setf *current-frame*
1119         (multiple-value-bind (next-frame-fun limit-string)
1120             (if (< n (sb!di:frame-number *current-frame*))
1121                 (values #'sb!di:frame-up "top")
1122               (values #'sb!di:frame-down "bottom"))
1123           (do ((frame *current-frame*))
1124               ((= n (sb!di:frame-number frame))
1125                frame)
1126             (let ((next-frame (funcall next-frame-fun frame)))
1127               (cond (next-frame
1128                      (setf frame next-frame))
1129                     (t
1130                      (format t
1131                              "The ~A of the stack was encountered.~%"
1132                              limit-string)
1133                      (return frame)))))))
1134   (print-frame-call *current-frame*))
1135
1136 (def-debug-command-alias "F" "FRAME")
1137 \f
1138 ;;;; commands for entering and leaving the debugger
1139
1140 ;;; CMU CL supported this QUIT debug command, but SBCL provides this
1141 ;;; functionality with a restart instead. (The QUIT debug command was
1142 ;;; removed because it's confusing to have "quit" mean two different
1143 ;;; things in the system, "restart the top level REPL" in the debugger
1144 ;;; and "terminate the Lisp system" as the SB-EXT:QUIT function.)
1145 ;;;
1146 ;;;(def-debug-command "QUIT" ()
1147 ;;;  (throw 'sb!impl::top-level-catcher nil))
1148
1149 ;;; CMU CL supported this GO debug command, but SBCL doesn't -- just
1150 ;;; type the CONTINUE restart name.
1151 ;;;(def-debug-command "GO" ()
1152 ;;;  (continue *debug-condition*)
1153 ;;;  (error "There is no restart named CONTINUE."))
1154
1155 (def-debug-command "RESTART" ()
1156   (let ((num (read-if-available :prompt)))
1157     (when (eq num :prompt)
1158       (show-restarts *debug-restarts* *debug-io*)
1159       (write-string "restart: ")
1160       (force-output)
1161       (setf num (read *standard-input*)))
1162     (let ((restart (typecase num
1163                      (unsigned-byte
1164                       (nth num *debug-restarts*))
1165                      (symbol
1166                       (find num *debug-restarts* :key #'restart-name
1167                             :test #'(lambda (sym1 sym2)
1168                                       (string= (symbol-name sym1)
1169                                                (symbol-name sym2)))))
1170                      (t
1171                       (format t "~S is invalid as a restart name.~%" num)
1172                       (return-from restart-debug-command nil)))))
1173       (if restart
1174           (invoke-restart-interactively restart)
1175           ;; FIXME: Even if this isn't handled by WARN, it probably
1176           ;; shouldn't go to *STANDARD-OUTPUT*, but *ERROR-OUTPUT* or
1177           ;; *QUERY-IO* or something. Look through this file to
1178           ;; straighten out stream usage.
1179           (princ "There is no such restart.")))))
1180 \f
1181 ;;;; information commands
1182
1183 (def-debug-command "HELP" ()
1184   ;; CMU CL had a little toy pager here, but "if you aren't running
1185   ;; ILISP (or a smart windowing system, or something) you deserve to
1186   ;; lose", so we've dropped it in SBCL. However, in case some
1187   ;; desperate holdout is running this on a dumb terminal somewhere,
1188   ;; we tell him where to find the message stored as a string.
1189   (format *debug-io*
1190           "~&~a~2%(The HELP string is stored in ~S.)~%"
1191           *debug-help-string*
1192           '*debug-help-string*))
1193
1194 (def-debug-command-alias "?" "HELP")
1195
1196 (def-debug-command "ERROR" ()
1197   (format *debug-io* "~A~%" *debug-condition*)
1198   (show-restarts *debug-restarts* *debug-io*))
1199
1200 (def-debug-command "BACKTRACE" ()
1201   (backtrace (read-if-available most-positive-fixnum)))
1202
1203 (def-debug-command "PRINT" ()
1204   (print-frame-call *current-frame*))
1205
1206 (def-debug-command-alias "P" "PRINT")
1207
1208 (def-debug-command "LIST-LOCALS" ()
1209   (let ((d-fun (sb!di:frame-debug-function *current-frame*)))
1210     (if (sb!di:debug-var-info-available d-fun)
1211         (let ((*standard-output* *debug-io*)
1212               (location (sb!di:frame-code-location *current-frame*))
1213               (prefix (read-if-available nil))
1214               (any-p nil)
1215               (any-valid-p nil))
1216           (dolist (v (sb!di:ambiguous-debug-vars
1217                         d-fun
1218                         (if prefix (string prefix) "")))
1219             (setf any-p t)
1220             (when (eq (sb!di:debug-var-validity v location) :valid)
1221               (setf any-valid-p t)
1222               (format t "~S~:[#~D~;~*~]  =  ~S~%"
1223                       (sb!di:debug-var-symbol v)
1224                       (zerop (sb!di:debug-var-id v))
1225                       (sb!di:debug-var-id v)
1226                       (sb!di:debug-var-value v *current-frame*))))
1227
1228           (cond
1229            ((not any-p)
1230             (format t "There are no local variables ~@[starting with ~A ~]~
1231                        in the function."
1232                     prefix))
1233            ((not any-valid-p)
1234             (format t "All variables ~@[starting with ~A ~]currently ~
1235                        have invalid values."
1236                     prefix))))
1237         (write-line "There is no variable information available."))))
1238
1239 (def-debug-command-alias "L" "LIST-LOCALS")
1240
1241 (def-debug-command "SOURCE" ()
1242   (fresh-line)
1243   (print-code-location-source-form (sb!di:frame-code-location *current-frame*)
1244                                    (read-if-available 0)))
1245 \f
1246 ;;;; source location printing
1247
1248 ;;; We cache a stream to the last valid file debug source so that we
1249 ;;; won't have to repeatedly open the file.
1250 ;;;
1251 ;;; KLUDGE: This sounds like a bug, not a feature. Opening files is fast
1252 ;;; in the 1990s, so the benefit is negligible, less important than the
1253 ;;; potential of extra confusion if someone changes the source during
1254 ;;; a debug session and the change doesn't show up. And removing this
1255 ;;; would simplify the system, which I like. -- WHN 19990903
1256 (defvar *cached-debug-source* nil)
1257 (declaim (type (or sb!di:debug-source null) *cached-debug-source*))
1258 (defvar *cached-source-stream* nil)
1259 (declaim (type (or stream null) *cached-source-stream*))
1260
1261 ;;; To suppress the read-time evaluation #. macro during source read,
1262 ;;; *READTABLE* is modified. *READTABLE* is cached to avoid
1263 ;;; copying it each time, and invalidated when the
1264 ;;; *CACHED-DEBUG-SOURCE* has changed.
1265 (defvar *cached-readtable* nil)
1266 (declaim (type (or readtable null) *cached-readtable*))
1267
1268 (pushnew #'(lambda ()
1269              (setq *cached-debug-source* nil *cached-source-stream* nil
1270                    *cached-readtable* nil))
1271          sb!int:*before-save-initializations*)
1272
1273 ;;; We also cache the last top-level form that we printed a source for
1274 ;;; so that we don't have to do repeated reads and calls to
1275 ;;; FORM-NUMBER-TRANSLATIONS.
1276 (defvar *cached-top-level-form-offset* nil)
1277 (declaim (type (or index null) *cached-top-level-form-offset*))
1278 (defvar *cached-top-level-form*)
1279 (defvar *cached-form-number-translations*)
1280
1281 ;;; Given a code location, return the associated form-number
1282 ;;; translations and the actual top-level form. We check our cache ---
1283 ;;; if there is a miss, we dispatch on the kind of the debug source.
1284 (defun get-top-level-form (location)
1285   (let ((d-source (sb!di:code-location-debug-source location)))
1286     (if (and (eq d-source *cached-debug-source*)
1287              (eql (sb!di:code-location-top-level-form-offset location)
1288                   *cached-top-level-form-offset*))
1289         (values *cached-form-number-translations* *cached-top-level-form*)
1290         (let* ((offset (sb!di:code-location-top-level-form-offset location))
1291                (res
1292                 (ecase (sb!di:debug-source-from d-source)
1293                   (:file (get-file-top-level-form location))
1294                   (:lisp (svref (sb!di:debug-source-name d-source) offset)))))
1295           (setq *cached-top-level-form-offset* offset)
1296           (values (setq *cached-form-number-translations*
1297                         (sb!di:form-number-translations res offset))
1298                   (setq *cached-top-level-form* res))))))
1299
1300 ;;; Locate the source file (if it still exists) and grab the top-level
1301 ;;; form. If the file is modified, we use the top-level-form offset
1302 ;;; instead of the recorded character offset.
1303 (defun get-file-top-level-form (location)
1304   (let* ((d-source (sb!di:code-location-debug-source location))
1305          (tlf-offset (sb!di:code-location-top-level-form-offset location))
1306          (local-tlf-offset (- tlf-offset
1307                               (sb!di:debug-source-root-number d-source)))
1308          (char-offset
1309           (aref (or (sb!di:debug-source-start-positions d-source)
1310                     (error "no start positions map"))
1311                 local-tlf-offset))
1312          (name (sb!di:debug-source-name d-source)))
1313     (unless (eq d-source *cached-debug-source*)
1314       (unless (and *cached-source-stream*
1315                    (equal (pathname *cached-source-stream*)
1316                           (pathname name)))
1317         (setq *cached-readtable* nil)
1318         (when *cached-source-stream* (close *cached-source-stream*))
1319         (setq *cached-source-stream* (open name :if-does-not-exist nil))
1320         (unless *cached-source-stream*
1321           (error "The source file no longer exists:~%  ~A" (namestring name)))
1322         (format t "~%; file: ~A~%" (namestring name)))
1323
1324         (setq *cached-debug-source*
1325               (if (= (sb!di:debug-source-created d-source)
1326                      (file-write-date name))
1327                   d-source nil)))
1328
1329     (cond
1330      ((eq *cached-debug-source* d-source)
1331       (file-position *cached-source-stream* char-offset))
1332      (t
1333       (format t "~%; File has been modified since compilation:~%;   ~A~@
1334                  ; Using form offset instead of character position.~%"
1335               (namestring name))
1336       (file-position *cached-source-stream* 0)
1337       (let ((*read-suppress* t))
1338         (dotimes (i local-tlf-offset)
1339           (read *cached-source-stream*)))))
1340     (unless *cached-readtable*
1341       (setq *cached-readtable* (copy-readtable))
1342       (set-dispatch-macro-character
1343        #\# #\.
1344        #'(lambda (stream sub-char &rest rest)
1345            (declare (ignore rest sub-char))
1346            (let ((token (read stream t nil t)))
1347              (format nil "#.~S" token)))
1348        *cached-readtable*))
1349     (let ((*readtable* *cached-readtable*))
1350       (read *cached-source-stream*))))
1351
1352 (defun print-code-location-source-form (location context)
1353   (let* ((location (maybe-block-start-location location))
1354          (form-num (sb!di:code-location-form-number location)))
1355     (multiple-value-bind (translations form) (get-top-level-form location)
1356       (unless (< form-num (length translations))
1357         (error "The source path no longer exists."))
1358       (prin1 (sb!di:source-path-context form
1359                                         (svref translations form-num)
1360                                         context)))))
1361 \f
1362 ;;; breakpoint and step commands
1363
1364 ;;; Step to the next code-location.
1365 (def-debug-command "STEP" ()
1366   (setf *number-of-steps* (read-if-available 1))
1367   (set-step-breakpoint *current-frame*)
1368   (continue *debug-condition*)
1369   (error "couldn't continue"))
1370
1371 ;;; List possible breakpoint locations, which ones are active, and
1372 ;;; where the CONTINUE restart will transfer control. Set
1373 ;;; *POSSIBLE-BREAKPOINTS* to the code-locations which can then be
1374 ;;; used by sbreakpoint.
1375 (def-debug-command "LIST-LOCATIONS" ()
1376   (let ((df (read-if-available *default-breakpoint-debug-function*)))
1377     (cond ((consp df)
1378            (setf df (sb!di:function-debug-function (eval df)))
1379            (setf *default-breakpoint-debug-function* df))
1380           ((or (eq ':c df)
1381                (not *default-breakpoint-debug-function*))
1382            (setf df (sb!di:frame-debug-function *current-frame*))
1383            (setf *default-breakpoint-debug-function* df)))
1384     (setf *possible-breakpoints* (possible-breakpoints df)))
1385   (let ((continue-at (sb!di:frame-code-location *current-frame*)))
1386     (let ((active (location-in-list *default-breakpoint-debug-function*
1387                                     *breakpoints* :function-start))
1388           (here (sb!di:code-location=
1389                  (sb!di:debug-function-start-location
1390                   *default-breakpoint-debug-function*) continue-at)))
1391       (when (or active here)
1392         (format t "::FUNCTION-START ")
1393         (when active (format t " *Active*"))
1394         (when here (format t " *Continue here*"))))
1395
1396     (let ((prev-location nil)
1397           (prev-num 0)
1398           (this-num 0))
1399       (flet ((flush ()
1400                (when prev-location
1401                  (let ((this-num (1- this-num)))
1402                    (if (= prev-num this-num)
1403                        (format t "~&~D: " prev-num)
1404                        (format t "~&~D-~D: " prev-num this-num)))
1405                  (print-code-location-source-form prev-location 0)
1406                  (when *print-location-kind*
1407                    (format t "~S " (sb!di:code-location-kind prev-location)))
1408                  (when (location-in-list prev-location *breakpoints*)
1409                    (format t " *Active*"))
1410                  (when (sb!di:code-location= prev-location continue-at)
1411                    (format t " *Continue here*")))))
1412
1413         (dolist (code-location *possible-breakpoints*)
1414           (when (or *print-location-kind*
1415                     (location-in-list code-location *breakpoints*)
1416                     (sb!di:code-location= code-location continue-at)
1417                     (not prev-location)
1418                     (not (eq (sb!di:code-location-debug-source code-location)
1419                              (sb!di:code-location-debug-source prev-location)))
1420                     (not (eq (sb!di:code-location-top-level-form-offset
1421                               code-location)
1422                              (sb!di:code-location-top-level-form-offset
1423                               prev-location)))
1424                     (not (eq (sb!di:code-location-form-number code-location)
1425                              (sb!di:code-location-form-number prev-location))))
1426             (flush)
1427             (setq prev-location code-location  prev-num this-num))
1428
1429           (incf this-num))))
1430
1431     (when (location-in-list *default-breakpoint-debug-function*
1432                             *breakpoints*
1433                             :function-end)
1434       (format t "~&::FUNCTION-END *Active* "))))
1435
1436 (def-debug-command-alias "LL" "LIST-LOCATIONS")
1437
1438 ;;; Set breakpoint at the given number.
1439 (def-debug-command "BREAKPOINT" ()
1440   (let ((index (read-prompting-maybe "location number, :START, or :END: "))
1441         (break t)
1442         (condition t)
1443         (print nil)
1444         (print-functions nil)
1445         (function nil)
1446         (bp)
1447         (place *default-breakpoint-debug-function*))
1448     (flet ((get-command-line ()
1449              (let ((command-line nil)
1450                    (unique '(nil)))
1451                (loop
1452                  (let ((next-input (read-if-available unique)))
1453                    (when (eq next-input unique) (return))
1454                    (push next-input command-line)))
1455                (nreverse command-line)))
1456            (set-vars-from-command-line (command-line)
1457              (do ((arg (pop command-line) (pop command-line)))
1458                  ((not arg))
1459                (ecase arg
1460                  (:condition (setf condition (pop command-line)))
1461                  (:print (push (pop command-line) print))
1462                  (:break (setf break (pop command-line)))
1463                  (:function
1464                   (setf function (eval (pop command-line)))
1465                   (setf *default-breakpoint-debug-function*
1466                         (sb!di:function-debug-function function))
1467                   (setf place *default-breakpoint-debug-function*)
1468                   (setf *possible-breakpoints*
1469                         (possible-breakpoints
1470                          *default-breakpoint-debug-function*))))))
1471            (setup-function-start ()
1472              (let ((code-loc (sb!di:debug-function-start-location place)))
1473                (setf bp (sb!di:make-breakpoint #'main-hook-function
1474                                                place
1475                                                :kind :function-start))
1476                (setf break (sb!di:preprocess-for-eval break code-loc))
1477                (setf condition (sb!di:preprocess-for-eval condition code-loc))
1478                (dolist (form print)
1479                  (push (cons (sb!di:preprocess-for-eval form code-loc) form)
1480                        print-functions))))
1481            (setup-function-end ()
1482              (setf bp
1483                    (sb!di:make-breakpoint #'main-hook-function
1484                                           place
1485                                           :kind :function-end))
1486              (setf break
1487                    ;; FIXME: These and any other old (COERCE `(LAMBDA ..) ..)
1488                    ;; forms should be converted to shiny new (LAMBDA ..) forms.
1489                    ;; (Search the sources for "coerce.*\(lambda".)
1490                    (coerce `(lambda (dummy)
1491                               (declare (ignore dummy)) ,break)
1492                            'function))
1493              (setf condition (coerce `(lambda (dummy)
1494                                         (declare (ignore dummy)) ,condition)
1495                                      'function))
1496              (dolist (form print)
1497                (push (cons
1498                       (coerce `(lambda (dummy)
1499                                  (declare (ignore dummy)) ,form) 'function)
1500                       form)
1501                      print-functions)))
1502            (setup-code-location ()
1503              (setf place (nth index *possible-breakpoints*))
1504              (setf bp (sb!di:make-breakpoint #'main-hook-function
1505                                              place
1506                                              :kind :code-location))
1507              (dolist (form print)
1508                (push (cons
1509                       (sb!di:preprocess-for-eval form place)
1510                       form)
1511                      print-functions))
1512              (setf break (sb!di:preprocess-for-eval break place))
1513              (setf condition (sb!di:preprocess-for-eval condition place))))
1514       (set-vars-from-command-line (get-command-line))
1515       (cond
1516        ((or (eq index :start) (eq index :s))
1517         (setup-function-start))
1518        ((or (eq index :end) (eq index :e))
1519         (setup-function-end))
1520        (t
1521         (setup-code-location)))
1522       (sb!di:activate-breakpoint bp)
1523       (let* ((new-bp-info (create-breakpoint-info place bp index
1524                                                   :break break
1525                                                   :print print-functions
1526                                                   :condition condition))
1527              (old-bp-info (location-in-list new-bp-info *breakpoints*)))
1528         (when old-bp-info
1529           (sb!di:deactivate-breakpoint (breakpoint-info-breakpoint
1530                                         old-bp-info))
1531           (setf *breakpoints* (remove old-bp-info *breakpoints*))
1532           (format t "previous breakpoint removed~%"))
1533         (push new-bp-info *breakpoints*))
1534       (print-breakpoint-info (first *breakpoints*))
1535       (format t "~&added"))))
1536
1537 (def-debug-command-alias "BP" "BREAKPOINT")
1538
1539 ;;; List all breakpoints which are set.
1540 (def-debug-command "LIST-BREAKPOINTS" ()
1541   (setf *breakpoints*
1542         (sort *breakpoints* #'< :key #'breakpoint-info-breakpoint-number))
1543   (dolist (info *breakpoints*)
1544     (print-breakpoint-info info)))
1545
1546 (def-debug-command-alias "LB" "LIST-BREAKPOINTS")
1547 (def-debug-command-alias "LBP" "LIST-BREAKPOINTS")
1548
1549 ;;; Remove breakpoint N, or remove all breakpoints if no N given.
1550 (def-debug-command "DELETE-BREAKPOINT" ()
1551   (let* ((index (read-if-available nil))
1552          (bp-info
1553           (find index *breakpoints* :key #'breakpoint-info-breakpoint-number)))
1554     (cond (bp-info
1555            (sb!di:delete-breakpoint (breakpoint-info-breakpoint bp-info))
1556            (setf *breakpoints* (remove bp-info *breakpoints*))
1557            (format t "breakpoint ~S removed~%" index))
1558           (index (format t "The breakpoint doesn't exist."))
1559           (t
1560            (dolist (ele *breakpoints*)
1561              (sb!di:delete-breakpoint (breakpoint-info-breakpoint ele)))
1562            (setf *breakpoints* nil)
1563            (format t "all breakpoints deleted~%")))))
1564
1565 (def-debug-command-alias "DBP" "DELETE-BREAKPOINT")
1566 \f
1567 ;;; miscellaneous commands
1568
1569 (def-debug-command "DESCRIBE" ()
1570   (let* ((curloc (sb!di:frame-code-location *current-frame*))
1571          (debug-fun (sb!di:code-location-debug-function curloc))
1572          (function (sb!di:debug-function-function debug-fun)))
1573     (if function
1574         (describe function)
1575         (format t "can't figure out the function for this frame"))))
1576 \f
1577 ;;;; debug loop command utilities
1578
1579 (defun read-prompting-maybe (prompt &optional (in *standard-input*)
1580                                     (out *standard-output*))
1581   (unless (sb!int:listen-skip-whitespace in)
1582     (princ prompt out)
1583     (force-output out))
1584   (read in))
1585
1586 (defun read-if-available (default &optional (stream *standard-input*))
1587   (if (sb!int:listen-skip-whitespace stream)
1588       (read stream)
1589       default))