src/code/debug.lisp

   1 ;;;; the debugger
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!DEBUG")
  13 \f
  14 ;;;; variables and constants
  15
  16 ;;; things to consider when tweaking these values:
  17 ;;;   * We're afraid to just default them to NIL and NIL, in case the
  18 ;;;     user inadvertently causes a hairy data structure to be printed
  19 ;;;     when he inadvertently enters the debugger.
  20 ;;;   * We don't want to truncate output too much. These days anyone
  21 ;;;     can easily run their Lisp in a windowing system or under Emacs,
  22 ;;;     so it's not the end of the world even if the worst case is a
  23 ;;;     few thousand lines of output.
  24 ;;;   * As condition :REPORT methods are converted to use the pretty
  25 ;;;     printer, they acquire *PRINT-LEVEL* constraints, so e.g. under
  26 ;;;     sbcl-0.7.1.28's old value of *DEBUG-PRINT-LEVEL*=3, an
  27 ;;;     ARG-COUNT-ERROR printed as
  28 ;;;       error while parsing arguments to DESTRUCTURING-BIND:
  29 ;;;         invalid number of elements in
  30 ;;;           #
  31 ;;;         to satisfy lambda list
  32 ;;;           #:
  33 ;;;         exactly 2 expected, but 5 found
  34 (defvar *debug-print-level* 5
  35   #!+sb-doc
  36   "*PRINT-LEVEL* for the debugger")
  37 (defvar *debug-print-length* 7
  38   #!+sb-doc
  39   "*PRINT-LENGTH* for the debugger")
  40
  41 (defvar *debug-readtable*
  42   ;; KLUDGE: This can't be initialized in a cold toplevel form,
  43   ;; because the *STANDARD-READTABLE* isn't initialized until after
  44   ;; cold toplevel forms have run. So instead we initialize it
  45   ;; immediately after *STANDARD-READTABLE*. -- WHN 20000205
  46   nil
  47   #!+sb-doc
  48   "*READTABLE* for the debugger")
  49
  50 (defvar *in-the-debugger* nil
  51   #!+sb-doc
  52   "This is T while in the debugger.")
  53
  54 ;;; nestedness inside debugger command loops
  55 (defvar *debug-command-level* 0)
  56
  57 ;;; If this is bound before the debugger is invoked, it is used as the
  58 ;;; stack top by the debugger.
  59 (defvar *stack-top-hint* nil)
  60
  61 (defvar *stack-top* nil)
  62 (defvar *real-stack-top* nil)
  63
  64 (defvar *current-frame* nil)
  65
  66 ;;; Beginner-oriented help messages are important because you end up
  67 ;;; in the debugger whenever something bad happens, or if you try to
  68 ;;; get out of the system with Ctrl-C or (EXIT) or EXIT or whatever.
  69 ;;; But after memorizing them the wasted screen space gets annoying..
  70 (defvar *debug-beginner-help-p* t
  71   "Should the debugger display beginner-oriented help messages?")
  72
  73 (defun debug-prompt (stream)
  74   (format stream
  75           "~%~W~:[~;[~W~]] "
  76           (sb!di:frame-number *current-frame*)
  77           (> *debug-command-level* 1)
  78           *debug-command-level*))
  79
  80 (defparameter *debug-help-string*
  81 "The prompt is square brackets, with number(s) indicating the current control
  82   stack level and, if you've entered the debugger recursively, how deeply
  83   recursed you are.
  84 Any command -- including the name of a restart -- may be uniquely abbreviated.
  85 The debugger rebinds various special variables for controlling i/o, sometimes
  86   to defaults (much like WITH-STANDARD-IO-SYNTAX does) and sometimes to
  87   its own special values, e.g. SB-DEBUG:*DEBUG-PRINT-LEVEL*.
  88 Debug commands do not affect *, //, and similar variables, but evaluation in
  89   the debug loop does affect these variables.
  90 SB-DEBUG:*FLUSH-DEBUG-ERRORS* controls whether errors at the debug prompt
  91   drop you deeper into the debugger.
  92
  93 Getting in and out of the debugger:
  94   RESTART  invokes restart numbered as shown (prompt if not given).
  95   ERROR    prints the error condition and restart cases.
  96   The number of any restart, or its name, or a unique abbreviation for its
  97     name, is a valid command, and is the same as using RESTART to invoke that
  98     restart.
  99
 100 Changing frames:
 101   U      up frame     D    down frame
 102   B  bottom frame     F n  frame n (n=0 for top frame)
 103
 104 Inspecting frames:
 105   BACKTRACE [n]  shows n frames going down the stack.
 106   LIST-LOCALS, L lists locals in current function.
 107   PRINT, P       displays current function call.
 108   SOURCE [n]     displays frame's source form with n levels of enclosing forms.
 109
 110 Breakpoints and steps:
 111   LIST-LOCATIONS [{function | :C}]   List the locations for breakpoints.
 112                                      Specify :C for the current frame.
 113     Abbreviation: LL
 114   LIST-BREAKPOINTS                   List the active breakpoints.
 115     Abbreviations: LB, LBP
 116   DELETE-BREAKPOINT [n]              Remove breakpoint n or all breakpoints.
 117     Abbreviations: DEL, DBP
 118   BREAKPOINT {n | :end | :start} [:break form] [:function function]
 119              [{:print form}*] [:condition form]
 120                                      Set a breakpoint.
 121     Abbreviations: BR, BP
 122   STEP [n]                           Step to the next location or step n times.
 123
 124 Function and macro commands:
 125  (SB-DEBUG:DEBUG-RETURN expression)
 126     Exit the debugger, returning expression's values from the current frame.
 127  (SB-DEBUG:ARG n)
 128     Return the n'th argument in the current frame.
 129  (SB-DEBUG:VAR string-or-symbol [id])
 130     Returns the value of the specified variable in the current frame.
 131
 132 Other commands:
 133   SLURP   Discard all pending input on *STANDARD-INPUT*. (This can be
 134           useful when the debugger was invoked to handle an error in
 135           deeply nested input syntax, and now the reader is confused.)")
 136 \f
 137 ;;; This is used to communicate to DEBUG-LOOP that we are at a step breakpoint.
 138 (define-condition step-condition (simple-condition) ())
 139 \f
 140 ;;;; breakpoint state
 141
 142 (defvar *only-block-start-locations* nil
 143   #!+sb-doc
 144   "When true, the LIST-LOCATIONS command only displays block start locations.
 145    Otherwise, all locations are displayed.")
 146
 147 (defvar *print-location-kind* nil
 148   #!+sb-doc
 149   "When true, list the code location type in the LIST-LOCATIONS command.")
 150
 151 ;;; a list of the types of code-locations that should not be stepped
 152 ;;; to and should not be listed when listing breakpoints
 153 (defvar *bad-code-location-types* '(:call-site :internal-error))
 154 (declaim (type list *bad-code-location-types*))
 155
 156 ;;; code locations of the possible breakpoints
 157 (defvar *possible-breakpoints*)
 158 (declaim (type list *possible-breakpoints*))
 159
 160 ;;; a list of the made and active breakpoints, each is a
 161 ;;; BREAKPOINT-INFO structure
 162 (defvar *breakpoints* nil)
 163 (declaim (type list *breakpoints*))
 164
 165 ;;; a list of BREAKPOINT-INFO structures of the made and active step
 166 ;;; breakpoints
 167 (defvar *step-breakpoints* nil)
 168 (declaim (type list *step-breakpoints*))
 169
 170 ;;; the number of times left to step
 171 (defvar *number-of-steps* 1)
 172 (declaim (type integer *number-of-steps*))
 173
 174 ;;; This is used when listing and setting breakpoints.
 175 (defvar *default-breakpoint-debug-fun* nil)
 176 (declaim (type (or list sb!di:debug-fun) *default-breakpoint-debug-fun*))
 177 \f
 178 ;;;; code location utilities
 179
 180 ;;; Return the first code-location in the passed debug block.
 181 (defun first-code-location (debug-block)
 182   (let ((found nil)
 183         (first-code-location nil))
 184     (sb!di:do-debug-block-locations (code-location debug-block)
 185       (unless found
 186         (setf first-code-location code-location)
 187         (setf found t)))
 188     first-code-location))
 189
 190 ;;; Return a list of the next code-locations following the one passed.
 191 ;;; One of the *BAD-CODE-LOCATION-TYPES* will not be returned.
 192 (defun next-code-locations (code-location)
 193   (let ((debug-block (sb!di:code-location-debug-block code-location))
 194         (block-code-locations nil))
 195     (sb!di:do-debug-block-locations (block-code-location debug-block)
 196       (unless (member (sb!di:code-location-kind block-code-location)
 197                       *bad-code-location-types*)
 198         (push block-code-location block-code-locations)))
 199     (setf block-code-locations (nreverse block-code-locations))
 200     (let* ((code-loc-list (rest (member code-location block-code-locations
 201                                         :test #'sb!di:code-location=)))
 202            (next-list (cond (code-loc-list
 203                              (list (first code-loc-list)))
 204                             ((map 'list #'first-code-location
 205                                   (sb!di:debug-block-successors debug-block)))
 206                             (t nil))))
 207       (when (and (= (length next-list) 1)
 208                  (sb!di:code-location= (first next-list) code-location))
 209         (setf next-list (next-code-locations (first next-list))))
 210       next-list)))
 211
 212 ;;; Return a list of code-locations of the possible breakpoints of DEBUG-FUN.
 213 (defun possible-breakpoints (debug-fun)
 214   (let ((possible-breakpoints nil))
 215     (sb!di:do-debug-fun-blocks (debug-block debug-fun)
 216       (unless (sb!di:debug-block-elsewhere-p debug-block)
 217         (if *only-block-start-locations*
 218             (push (first-code-location debug-block) possible-breakpoints)
 219             (sb!di:do-debug-block-locations (code-location debug-block)
 220               (when (not (member (sb!di:code-location-kind code-location)
 221                                  *bad-code-location-types*))
 222                 (push code-location possible-breakpoints))))))
 223     (nreverse possible-breakpoints)))
 224
 225 ;;; Search the info-list for the item passed (CODE-LOCATION,
 226 ;;; DEBUG-FUN, or BREAKPOINT-INFO). If the item passed is a debug
 227 ;;; function then kind will be compared if it was specified. The kind
 228 ;;; if also compared if a breakpoint-info is passed since it's in the
 229 ;;; breakpoint. The info structure is returned if found.
 230 (defun location-in-list (place info-list &optional (kind nil))
 231   (when (breakpoint-info-p place)
 232     (setf kind (sb!di:breakpoint-kind (breakpoint-info-breakpoint place)))
 233     (setf place (breakpoint-info-place place)))
 234   (cond ((sb!di:code-location-p place)
 235          (find place info-list
 236                :key #'breakpoint-info-place
 237                :test (lambda (x y) (and (sb!di:code-location-p y)
 238                                         (sb!di:code-location= x y)))))
 239         (t
 240          (find place info-list
 241                :test (lambda (x-debug-fun y-info)
 242                        (let ((y-place (breakpoint-info-place y-info))
 243                              (y-breakpoint (breakpoint-info-breakpoint
 244                                             y-info)))
 245                          (and (sb!di:debug-fun-p y-place)
 246                               (eq x-debug-fun y-place)
 247                               (or (not kind)
 248                                   (eq kind (sb!di:breakpoint-kind
 249                                             y-breakpoint))))))))))
 250
 251 ;;; If LOC is an unknown location, then try to find the block start
 252 ;;; location. Used by source printing to some information instead of
 253 ;;; none for the user.
 254 (defun maybe-block-start-location (loc)
 255   (if (sb!di:code-location-unknown-p loc)
 256       (let* ((block (sb!di:code-location-debug-block loc))
 257              (start (sb!di:do-debug-block-locations (loc block)
 258                       (return loc))))
 259         (cond ((and (not (sb!di:debug-block-elsewhere-p block))
 260                     start)
 261                ;; FIXME: Why output on T instead of *DEBUG-FOO* or something?
 262                (format t "~%unknown location: using block start~%")
 263                start)
 264               (t
 265                loc)))
 266       loc))
 267 \f
 268 ;;;; the BREAKPOINT-INFO structure
 269
 270 ;;; info about a made breakpoint
 271 (defstruct (breakpoint-info (:copier nil)
 272                             (:constructor %make-breakpoint-info))
 273   ;; where we are going to stop
 274   (place (missing-arg)
 275          :type (or sb!di:code-location sb!di:debug-fun)
 276          :read-only t)
 277   ;; the breakpoint returned by SB!DI:MAKE-BREAKPOINT
 278   (breakpoint (missing-arg) :type sb!di:breakpoint :read-only t)
 279   ;; the function returned from SB!DI:PREPROCESS-FOR-EVAL. If result is
 280   ;; non-NIL, drop into the debugger.
 281   (break #'identity :type function :read-only t)
 282   ;; the function returned from SB!DI:PREPROCESS-FOR-EVAL. If result is
 283   ;; non-NIL, eval (each) print and print results.
 284   (condition #'identity :type function :read-only t)
 285   ;; the list of functions from SB!DI:PREPROCESS-FOR-EVAL to evaluate.
 286   ;; Results are conditionally printed. CAR of each element is the
 287   ;; function, CDR is the form it goes with.
 288   (print nil :type list :read-only t)
 289   ;; the number used when listing the possible breakpoints within a
 290   ;; function; or could also be a symbol such as START or END
 291   (code-location-selector (missing-arg) :type (or symbol integer) :read-only t)
 292   ;; the number used when listing the active breakpoints, and when
 293   ;; deleting breakpoints
 294   (breakpoint-number (missing-arg) :type integer) :read-only t)
 295
 296 (defun create-breakpoint-info (place breakpoint code-location-selector
 297                                      &key (break #'identity)
 298                                      (condition #'identity) (print nil))
 299   (setf *breakpoints*
 300         (sort *breakpoints* #'< :key #'breakpoint-info-breakpoint-number))
 301   (let ((breakpoint-number
 302          (do ((i 1 (incf i)) (breakpoints *breakpoints* (rest breakpoints)))
 303              ((or (> i (length *breakpoints*))
 304                   (not (= i (breakpoint-info-breakpoint-number
 305                              (first breakpoints)))))
 306
 307               i))))
 308     (%make-breakpoint-info :place place
 309                            :breakpoint breakpoint
 310                            :code-location-selector code-location-selector
 311                            :breakpoint-number breakpoint-number
 312                            :break break
 313                            :condition condition
 314                            :print print)))
 315
 316 (defun print-breakpoint-info (breakpoint-info)
 317   (let ((place (breakpoint-info-place breakpoint-info))
 318         (bp-number (breakpoint-info-breakpoint-number breakpoint-info)))
 319     (case (sb!di:breakpoint-kind (breakpoint-info-breakpoint breakpoint-info))
 320       (:code-location
 321        (print-code-location-source-form place 0)
 322        (format t
 323                "~&~S: ~S in ~S"
 324                bp-number
 325                (breakpoint-info-code-location-selector breakpoint-info)
 326                (sb!di:debug-fun-name (sb!di:code-location-debug-fun place))))
 327       (:fun-start
 328        (format t "~&~S: FUN-START in ~S" bp-number
 329                (sb!di:debug-fun-name place)))
 330       (:fun-end
 331        (format t "~&~S: FUN-END in ~S" bp-number
 332                (sb!di:debug-fun-name place))))))
 333 \f
 334 ;;;; MAIN-HOOK-FUN for steps and breakpoints
 335
 336 ;;; This must be passed as the hook function. It keeps track of where
 337 ;;; STEP breakpoints are.
 338 (defun main-hook-fun (current-frame breakpoint &optional return-vals
 339                                     fun-end-cookie)
 340   (setf *default-breakpoint-debug-fun*
 341         (sb!di:frame-debug-fun current-frame))
 342   (dolist (step-info *step-breakpoints*)
 343     (sb!di:delete-breakpoint (breakpoint-info-breakpoint step-info))
 344     (let ((bp-info (location-in-list step-info *breakpoints*)))
 345       (when bp-info
 346         (sb!di:activate-breakpoint (breakpoint-info-breakpoint bp-info)))))
 347   (let ((*stack-top-hint* current-frame)
 348         (step-hit-info
 349          (location-in-list (sb!di:breakpoint-what breakpoint)
 350                            *step-breakpoints*
 351                            (sb!di:breakpoint-kind breakpoint)))
 352         (bp-hit-info
 353          (location-in-list (sb!di:breakpoint-what breakpoint)
 354                            *breakpoints*
 355                            (sb!di:breakpoint-kind breakpoint)))
 356         (break)
 357         (condition)
 358         (string ""))
 359     (setf *step-breakpoints* nil)
 360     (labels ((build-string (str)
 361                (setf string (concatenate 'string string str)))
 362              (print-common-info ()
 363                (build-string
 364                 (with-output-to-string (*standard-output*)
 365                   (when fun-end-cookie
 366                     (format t "~%Return values: ~S" return-vals))
 367                   (when condition
 368                     (when (breakpoint-info-print bp-hit-info)
 369                       (format t "~%")
 370                       (print-frame-call current-frame))
 371                     (dolist (print (breakpoint-info-print bp-hit-info))
 372                       (format t "~& ~S = ~S" (rest print)
 373                               (funcall (first print) current-frame))))))))
 374       (when bp-hit-info
 375         (setf break (funcall (breakpoint-info-break bp-hit-info)
 376                              current-frame))
 377         (setf condition (funcall (breakpoint-info-condition bp-hit-info)
 378                                  current-frame)))
 379       (cond ((and bp-hit-info step-hit-info (= 1 *number-of-steps*))
 380              (build-string (format nil "~&*Step (to a breakpoint)*"))
 381              (print-common-info)
 382              (break string))
 383             ((and bp-hit-info step-hit-info break)
 384              (build-string (format nil "~&*Step (to a breakpoint)*"))
 385              (print-common-info)
 386              (break string))
 387             ((and bp-hit-info step-hit-info)
 388              (print-common-info)
 389              (format t "~A" string)
 390              (decf *number-of-steps*)
 391              (set-step-breakpoint current-frame))
 392             ((and step-hit-info (= 1 *number-of-steps*))
 393              (build-string "*Step*")
 394              (break (make-condition 'step-condition :format-control string)))
 395             (step-hit-info
 396              (decf *number-of-steps*)
 397              (set-step-breakpoint current-frame))
 398             (bp-hit-info
 399              (when break
 400                (build-string (format nil "~&*Breakpoint hit*")))
 401              (print-common-info)
 402              (if break
 403                  (break string)
 404                  (format t "~A" string)))
 405             (t
 406              (break "unknown breakpoint"))))))
 407 \f
 408 ;;; Set breakpoints at the next possible code-locations. After calling
 409 ;;; this, either (CONTINUE) if in the debugger or just let program flow
 410 ;;; return if in a hook function.
 411 (defun set-step-breakpoint (frame)
 412   (cond
 413    ((sb!di:debug-block-elsewhere-p (sb!di:code-location-debug-block
 414                                     (sb!di:frame-code-location frame)))
 415     ;; FIXME: FORMAT T is used for error output here and elsewhere in
 416     ;; the debug code.
 417     (format t "cannot step, in elsewhere code~%"))
 418    (t
 419     (let* ((code-location (sb!di:frame-code-location frame))
 420            (next-code-locations (next-code-locations code-location)))
 421       (cond
 422        (next-code-locations
 423         (dolist (code-location next-code-locations)
 424           (let ((bp-info (location-in-list code-location *breakpoints*)))
 425             (when bp-info
 426               (sb!di:deactivate-breakpoint (breakpoint-info-breakpoint
 427                                             bp-info))))
 428           (let ((bp (sb!di:make-breakpoint #'main-hook-fun code-location
 429                                            :kind :code-location)))
 430             (sb!di:activate-breakpoint bp)
 431             (push (create-breakpoint-info code-location bp 0)
 432                   *step-breakpoints*))))
 433        (t
 434         (let* ((debug-fun (sb!di:frame-debug-fun *current-frame*))
 435                (bp (sb!di:make-breakpoint #'main-hook-fun debug-fun
 436                                           :kind :fun-end)))
 437           (sb!di:activate-breakpoint bp)
 438           (push (create-breakpoint-info debug-fun bp 0)
 439                 *step-breakpoints*))))))))
 440 \f
 441 ;;;; STEP
 442
 443 ;;; ANSI specifies that this macro shall exist, even if only as a
 444 ;;; trivial placeholder like this.
 445 (defmacro step (form)
 446   "a trivial placeholder implementation of the CL:STEP macro required by
 447    the ANSI spec"
 448   `(progn
 449      ,form))
 450 \f
 451 ;;;; BACKTRACE
 452
 453 (defun backtrace (&optional (count most-positive-fixnum)
 454                             (*standard-output* *debug-io*))
 455   #!+sb-doc
 456   "Show a listing of the call stack going down from the current frame. In the
 457    debugger, the current frame is indicated by the prompt. COUNT is how many
 458    frames to show."
 459   (fresh-line *standard-output*)
 460   (do ((frame (if *in-the-debugger* *current-frame* (sb!di:top-frame))
 461               (sb!di:frame-down frame))
 462        (count count (1- count)))
 463       ((or (null frame) (zerop count)))
 464     (print-frame-call frame :number t))
 465   (fresh-line *standard-output*)
 466   (values))
 467 \f
 468 ;;;; frame printing
 469
 470 (eval-when (:compile-toplevel :execute)
 471
 472 ;;; This is a convenient way to express what to do for each type of
 473 ;;; lambda-list element.
 474 (sb!xc:defmacro lambda-list-element-dispatch (element
 475                                               &key
 476                                               required
 477                                               optional
 478                                               rest
 479                                               keyword
 480                                               deleted)
 481   `(etypecase ,element
 482      (sb!di:debug-var
 483       ,@required)
 484      (cons
 485       (ecase (car ,element)
 486         (:optional ,@optional)
 487         (:rest ,@rest)
 488         (:keyword ,@keyword)))
 489      (symbol
 490       (aver (eq ,element :deleted))
 491       ,@deleted)))
 492
 493 (sb!xc:defmacro lambda-var-dispatch (variable location deleted valid other)
 494   (let ((var (gensym)))
 495     `(let ((,var ,variable))
 496        (cond ((eq ,var :deleted) ,deleted)
 497              ((eq (sb!di:debug-var-validity ,var ,location) :valid)
 498               ,valid)
 499              (t ,other)))))
 500
 501 ) ; EVAL-WHEN
 502
 503 ;;; This is used in constructing arg lists for debugger printing when
 504 ;;; the arg list is unavailable, some arg is unavailable or unused, etc.
 505 (defstruct (unprintable-object
 506             (:constructor make-unprintable-object (string))
 507             (:print-object (lambda (x s)
 508                              (print-unreadable-object (x s)
 509                                (write-string (unprintable-object-string x)
 510                                              s))))
 511             (:copier nil))
 512   string)
 513
 514 ;;; Print FRAME with verbosity level 1. If we hit a &REST arg, then
 515 ;;; print as many of the values as possible, punting the loop over
 516 ;;; lambda-list variables since any other arguments will be in the
 517 ;;; &REST arg's list of values.
 518 (defun print-frame-call-1 (frame)
 519   (let ((debug-fun (sb!di:frame-debug-fun frame))
 520         (loc (sb!di:frame-code-location frame))
 521         (reversed-args nil))
 522
 523     ;; Construct function arguments in REVERSED-ARGS.
 524     (handler-case
 525         (dolist (ele (sb!di:debug-fun-lambda-list debug-fun))
 526           (lambda-list-element-dispatch ele
 527             :required ((push (frame-call-arg ele loc frame) reversed-args))
 528             :optional ((push (frame-call-arg (second ele) loc frame)
 529                              reversed-args))
 530             :keyword ((push (second ele) reversed-args)
 531                       (push (frame-call-arg (third ele) loc frame)
 532                             reversed-args))
 533             :deleted ((push (frame-call-arg ele loc frame) reversed-args))
 534             :rest ((lambda-var-dispatch (second ele) loc
 535                      nil
 536                      (progn
 537                        (setf reversed-args
 538                              (append (reverse (sb!di:debug-var-value
 539                                                (second ele) frame))
 540                                      reversed-args))
 541                        (return))
 542                      (push (make-unprintable-object
 543                             "unavailable &REST argument")
 544                            reversed-args)))))
 545       (sb!di:lambda-list-unavailable
 546        ()
 547        (push (make-unprintable-object "lambda list unavailable")
 548              reversed-args)))
 549
 550     (pprint-logical-block (*standard-output* nil :prefix "(" :suffix ")")
 551       (let ((args (nreverse (mapcar #'ensure-printable-object reversed-args))))
 552         ;; Since we go to some trouble to make nice informative function
 553         ;; names like (PRINT-OBJECT :AROUND (CLOWN T)), let's make sure
 554         ;; that they aren't truncated by *PRINT-LENGTH* and *PRINT-LEVEL*.
 555         (let ((*print-length* nil)
 556               (*print-level* nil))
 557           (prin1 (ensure-printable-object (sb!di:debug-fun-name debug-fun))))
 558         ;; For the function arguments, we can just print normally.
 559         (format t "~{ ~_~S~}" args)))
 560
 561     (when (sb!di:debug-fun-kind debug-fun)
 562       (write-char #\[)
 563       (prin1 (sb!di:debug-fun-kind debug-fun))
 564       (write-char #\]))))
 565
 566 (defun ensure-printable-object (object)
 567   (handler-case
 568       (with-open-stream (out (make-broadcast-stream))
 569         (prin1 object out)
 570         object)
 571     (error (cond)
 572       (declare (ignore cond))
 573       (make-unprintable-object "error printing object"))))
 574
 575 (defun frame-call-arg (var location frame)
 576   (lambda-var-dispatch var location
 577     (make-unprintable-object "unused argument")
 578     (sb!di:debug-var-value var frame)
 579     (make-unprintable-object "unavailable argument")))
 580
 581 ;;; Prints a representation of the function call causing FRAME to
 582 ;;; exist. VERBOSITY indicates the level of information to output;
 583 ;;; zero indicates just printing the DEBUG-FUN's name, and one
 584 ;;; indicates displaying call-like, one-liner format with argument
 585 ;;; values.
 586 (defun print-frame-call (frame &key (verbosity 1) (number nil))
 587   (cond
 588    ((zerop verbosity)
 589     (when number
 590       (format t "~&~S: " (sb!di:frame-number frame)))
 591     (format t "~S" frame))
 592    (t
 593     (when number
 594       (format t "~&~S: " (sb!di:frame-number frame)))
 595     (print-frame-call-1 frame)))
 596   (when (>= verbosity 2)
 597     (let ((loc (sb!di:frame-code-location frame)))
 598       (handler-case
 599           (progn
 600             (sb!di:code-location-debug-block loc)
 601             (format t "~%source: ")
 602             (print-code-location-source-form loc 0))
 603         (sb!di:debug-condition (ignore) ignore)
 604         (error (c) (format t "error finding source: ~A" c))))))
 605 \f
 606 ;;;; INVOKE-DEBUGGER
 607
 608 (defvar *debugger-hook* nil
 609   #!+sb-doc
 610   "This is either NIL or a function of two arguments, a condition and the value
 611    of *DEBUGGER-HOOK*. This function can either handle the condition or return
 612    which causes the standard debugger to execute. The system passes the value
 613    of this variable to the function because it binds *DEBUGGER-HOOK* to NIL
 614    around the invocation.")
 615
 616 ;;; These are bound on each invocation of INVOKE-DEBUGGER.
 617 (defvar *debug-restarts*)
 618 (defvar *debug-condition*)
 619 (defvar *nested-debug-condition*)
 620
 621 (defun invoke-debugger (condition)
 622   #!+sb-doc
 623   "Enter the debugger."
 624   (let ((old-hook *debugger-hook*))
 625     (when old-hook
 626       (let ((*debugger-hook* nil))
 627         (funcall old-hook condition old-hook))))
 628   ;; FIXME: No-one seems to know what this is for. Nothing is noticeably
 629   ;; broken on sunos...
 630   #!-sunos (sb!unix:unix-sigsetmask 0)
 631
 632   ;; Elsewhere in the system, we use the SANE-PACKAGE function for
 633   ;; this, but here causing an exception just as we're trying to handle
 634   ;; an exception would be confusing, so instead we use a special hack.
 635   (unless (and (packagep *package*)
 636                (package-name *package*))
 637     (setf *package* (find-package :cl-user))
 638     (format *error-output*
 639             "The value of ~S was not an undeleted PACKAGE. It has been
 640 reset to ~S."
 641             '*package* *package*))
 642   (let (;; Save *PACKAGE* to protect it from WITH-STANDARD-IO-SYNTAX.
 643         (original-package *package*))
 644     (with-standard-io-syntax
 645      (let* ((*debug-condition* condition)
 646             (*debug-restarts* (compute-restarts condition))
 647             ;; We want the i/o subsystem to be in a known, useful
 648             ;; state, regardless of where the debugger was invoked in
 649             ;; the program. WITH-STANDARD-IO-SYNTAX does some of that,
 650             ;; but
 651             ;;   1. It doesn't affect our internal special variables
 652             ;;      like *CURRENT-LEVEL-IN-PRINT*.
 653             ;;   2. It isn't customizable.
 654             ;;   3. It doesn't set *PRINT-READABLY* or *PRINT-PRETTY*
 655             ;;      to the same value as the toplevel default.
 656             ;;   4. It sets *PACKAGE* to COMMON-LISP-USER, which is not
 657             ;;      helpful behavior for a debugger.
 658             ;; We try to remedy all these problems with explicit
 659             ;; rebindings here.
 660             (sb!kernel:*current-level-in-print* 0)
 661             (*print-length* *debug-print-length*)
 662             (*print-level* *debug-print-level*)
 663             (*readtable* *debug-readtable*)
 664             (*print-readably* nil)
 665             (*print-pretty* t)
 666             (*package* original-package)
 667             (*nested-debug-condition* nil))
 668
 669        ;; Before we start our own output, finish any pending output.
 670        ;; Otherwise, if the user tried to track the progress of
 671        ;; his program using PRINT statements, he'd tend to lose
 672        ;; the last line of output or so, and get confused.
 673        (flush-standard-output-streams)
 674
 675        ;; (The initial output here goes to *ERROR-OUTPUT*, because the
 676        ;; initial output is not interactive, just an error message,
 677        ;; and when people redirect *ERROR-OUTPUT*, they could
 678        ;; reasonably expect to see error messages logged there,
 679        ;; regardless of what the debugger does afterwards.)
 680        (handler-case
 681            (format *error-output*
 682                    "~2&~@<debugger invoked on condition of type ~S: ~
 683                     ~2I~_~A~:>~%"
 684                    (type-of *debug-condition*)
 685                    *debug-condition*)
 686          (error (condition)
 687            (setf *nested-debug-condition* condition)
 688            (let ((ndc-type (type-of *nested-debug-condition*)))
 689              (format *error-output*
 690                      "~&~@<(A ~S was caught when trying to print ~S when ~
 691                       entering the debugger. Printing was aborted and the ~
 692                       ~S was stored in ~S.)~@:>~%"
 693                      ndc-type
 694                      '*debug-condition*
 695                      ndc-type
 696                      '*nested-debug-condition*))
 697            (when (typep condition 'cell-error)
 698              ;; what we really want to know when it's e.g. an UNBOUND-VARIABLE:
 699              (format *error-output*
 700                      "~&(CELL-ERROR-NAME ~S) = ~S~%"
 701                      '*debug-condition*
 702                      (cell-error-name *debug-condition*)))))
 703
 704        ;; After the initial error/condition/whatever announcement to
 705        ;; *ERROR-OUTPUT*, we become interactive, and should talk on
 706        ;; *DEBUG-IO* from now on. (KLUDGE: This is a normative
 707        ;; statement, not a description of reality.:-| There's a lot of
 708        ;; older debugger code which was written to do i/o on whatever
 709        ;; stream was in fashion at the time, and not all of it has
 710        ;; been converted to behave this way. -- WHN 2000-11-16)
 711        (let (;; FIXME: Rebinding *STANDARD-OUTPUT* here seems wrong,
 712              ;; violating the principle of least surprise, and making
 713              ;; it impossible for the user to do reasonable things
 714              ;; like using PRINT at the debugger prompt to send output
 715              ;; to the program's ordinary (possibly
 716              ;; redirected-to-a-file) *STANDARD-OUTPUT*. (CMU CL
 717              ;; used to rebind *STANDARD-INPUT* here too, but that's
 718              ;; been fixed already.)
 719              (*standard-output* *debug-io*)
 720              ;; This seems reasonable: e.g. if the user has redirected
 721              ;; *ERROR-OUTPUT* to some log file, it's probably wrong
 722              ;; to send errors which occur in interactive debugging to
 723              ;; that file, and right to send them to *DEBUG-IO*.
 724              (*error-output* *debug-io*))
 725          (unless (typep condition 'step-condition)
 726            (when *debug-beginner-help-p*
 727              (format *debug-io*
 728                      "~%~@<Within the debugger, you can type HELP for help. ~
 729                       At any command prompt (within the debugger or not) you ~
 730                       can type (SB-EXT:QUIT) to terminate the SBCL ~
 731                       executable. The condition which caused the debugger to ~
 732                       be entered is bound to ~S. You can suppress this ~
 733                       message by clearing ~S.~:@>~2%"
 734                      '*debug-condition*
 735                      '*debug-beginner-help-p*))
 736            (show-restarts *debug-restarts* *debug-io*))
 737          (internal-debug))))))
 738
 739 (defun show-restarts (restarts s)
 740   (cond ((null restarts)
 741          (format s
 742                  "~&(no restarts: If you didn't do this on purpose, ~
 743                   please report it as a bug.)~%"))
 744         (t
 745          (format s "~&restarts:~%")
 746          (let ((count 0)
 747                (names-used '(nil))
 748                (max-name-len 0))
 749            (dolist (restart restarts)
 750              (let ((name (restart-name restart)))
 751                (when name
 752                  (let ((len (length (princ-to-string name))))
 753                    (when (> len max-name-len)
 754                      (setf max-name-len len))))))
 755            (unless (zerop max-name-len)
 756              (incf max-name-len 3))
 757            (dolist (restart restarts)
 758              (let ((name (restart-name restart)))
 759                (cond ((member name names-used)
 760                       (format s "~& ~2D: ~V@T~A~%" count max-name-len restart))
 761                      (t
 762                       (format s "~& ~2D: [~VA] ~A~%"
 763                               count (- max-name-len 3) name restart)
 764                       (push name names-used))))
 765              (incf count))))))
 766
 767 ;;; This calls DEBUG-LOOP, performing some simple initializations
 768 ;;; before doing so. INVOKE-DEBUGGER calls this to actually get into
 769 ;;; the debugger. SB!KERNEL::ERROR-ERROR calls this in emergencies
 770 ;;; to get into a debug prompt as quickly as possible with as little
 771 ;;; risk as possible for stepping on whatever is causing recursive
 772 ;;; errors.
 773 (defun internal-debug ()
 774   (let ((*in-the-debugger* t)
 775         (*read-suppress* nil))
 776     (unless (typep *debug-condition* 'step-condition)
 777       (clear-input *debug-io*))
 778     #!-mp (debug-loop)
 779     #!+mp (sb!mp:without-scheduling (debug-loop))))
 780 \f
 781 ;;;; DEBUG-LOOP
 782
 783 ;;; Note: This defaulted to T in CMU CL. The changed default in SBCL
 784 ;;; was motivated by desire to play nicely with ILISP.
 785 (defvar *flush-debug-errors* nil
 786   #!+sb-doc
 787   "When set, avoid calling INVOKE-DEBUGGER recursively when errors occur while
 788    executing in the debugger.")
 789
 790 (defun debug-loop ()
 791   (let* ((*debug-command-level* (1+ *debug-command-level*))
 792          (*real-stack-top* (sb!di:top-frame))
 793          (*stack-top* (or *stack-top-hint* *real-stack-top*))
 794          (*stack-top-hint* nil)
 795          (*current-frame* *stack-top*))
 796     (handler-bind ((sb!di:debug-condition
 797                     (lambda (condition)
 798                       (princ condition *debug-io*)
 799                       (/show0 "handling d-c by THROWing DEBUG-LOOP-CATCHER")
 800                       (throw 'debug-loop-catcher nil))))
 801       (fresh-line)
 802       (print-frame-call *current-frame* :verbosity 2)
 803       (loop
 804         (catch 'debug-loop-catcher
 805           (handler-bind ((error (lambda (condition)
 806                                   (when *flush-debug-errors*
 807                                     (clear-input *debug-io*)
 808                                     (princ condition)
 809                                     ;; FIXME: Doing input on *DEBUG-IO*
 810                                     ;; and output on T seems broken.
 811                                     (format t
 812                                             "~&error flushed (because ~
 813                                              ~S is set)"
 814                                             '*flush-debug-errors*)
 815                                     (/show0 "throwing DEBUG-LOOP-CATCHER")
 816                                     (throw 'debug-loop-catcher nil)))))
 817             ;; We have to bind LEVEL for the restart function created by
 818             ;; WITH-SIMPLE-RESTART.
 819             (let ((level *debug-command-level*)
 820                   (restart-commands (make-restart-commands)))
 821               (with-simple-restart (abort
 822                                    "Reduce debugger level (to debug level ~W)."
 823                                     level)
 824                 (debug-prompt *debug-io*)
 825                 (force-output *debug-io*)
 826                 (let ((input (sb!int:get-stream-command *debug-io*)))
 827                   (cond (input
 828                          (let ((cmd-fun (debug-command-p
 829                                          (sb!int:stream-command-name input)
 830                                          restart-commands)))
 831                            (cond
 832                             ((not cmd-fun)
 833                              (error "unknown stream-command: ~S" input))
 834                             ((consp cmd-fun)
 835                              (error "ambiguous debugger command: ~S" cmd-fun))
 836                             (t
 837                              (apply cmd-fun
 838                                     (sb!int:stream-command-args input))))))
 839                         (t
 840                          (let* ((exp (read *debug-io*))
 841                                 (cmd-fun (debug-command-p exp
 842                                                           restart-commands)))
 843                            (cond ((not cmd-fun)
 844                                   (debug-eval-print exp))
 845                                  ((consp cmd-fun)
 846                                   (format t
 847                                           "~&Your command, ~S, is ambiguous:~%"
 848                                           exp)
 849                                   (dolist (ele cmd-fun)
 850                                     (format t "   ~A~%" ele)))
 851                                  (t
 852                                   (funcall cmd-fun)))))))))))))))
 853
 854 ;;; FIXME: We could probably use INTERACTIVE-EVAL for much of this logic.
 855 (defun debug-eval-print (expr)
 856   (/noshow "entering DEBUG-EVAL-PRINT" expr)
 857   (/noshow (fboundp 'compile))
 858   (setq +++ ++ ++ + + - - expr)
 859   (let* ((values (multiple-value-list (eval -)))
 860          (*standard-output* *debug-io*))
 861     (/noshow "done with EVAL in DEBUG-EVAL-PRINT")
 862     (fresh-line)
 863     (if values (prin1 (car values)))
 864     (dolist (x (cdr values))
 865       (fresh-line)
 866       (prin1 x))
 867     (setq /// // // / / values)
 868     (setq *** ** ** * * (car values))
 869     ;; Make sure that nobody passes back an unbound marker.
 870     (unless (boundp '*)
 871       (setq * nil)
 872       (fresh-line)
 873       ;; FIXME: The way INTERACTIVE-EVAL does this seems better.
 874       (princ "Setting * to NIL (was unbound marker)."))))
 875 \f
 876 ;;;; debug loop functions
 877
 878 ;;; These commands are functions, not really commands, so that users
 879 ;;; can get their hands on the values returned.
 880
 881 (eval-when (:execute :compile-toplevel)
 882
 883 (sb!xc:defmacro define-var-operation (ref-or-set &optional value-var)
 884   `(let* ((temp (etypecase name
 885                   (symbol (sb!di:debug-fun-symbol-vars
 886                            (sb!di:frame-debug-fun *current-frame*)
 887                            name))
 888                   (simple-string (sb!di:ambiguous-debug-vars
 889                                   (sb!di:frame-debug-fun *current-frame*)
 890                                   name))))
 891           (location (sb!di:frame-code-location *current-frame*))
 892           ;; Let's only deal with valid variables.
 893           (vars (remove-if-not (lambda (v)
 894                                  (eq (sb!di:debug-var-validity v location)
 895                                      :valid))
 896                                temp)))
 897      (declare (list vars))
 898      (cond ((null vars)
 899             (error "No known valid variables match ~S." name))
 900            ((= (length vars) 1)
 901             ,(ecase ref-or-set
 902                (:ref
 903                 '(sb!di:debug-var-value (car vars) *current-frame*))
 904                (:set
 905                 `(setf (sb!di:debug-var-value (car vars) *current-frame*)
 906                        ,value-var))))
 907            (t
 908             ;; Since we have more than one, first see whether we have
 909             ;; any variables that exactly match the specification.
 910             (let* ((name (etypecase name
 911                            (symbol (symbol-name name))
 912                            (simple-string name)))
 913                    ;; FIXME: REMOVE-IF-NOT is deprecated, use STRING/=
 914                    ;; instead.
 915                    (exact (remove-if-not (lambda (v)
 916                                            (string= (sb!di:debug-var-symbol-name v)
 917                                                     name))
 918                                          vars))
 919                    (vars (or exact vars)))
 920               (declare (simple-string name)
 921                        (list exact vars))
 922               (cond
 923                ;; Check now for only having one variable.
 924                ((= (length vars) 1)
 925                 ,(ecase ref-or-set
 926                    (:ref
 927                     '(sb!di:debug-var-value (car vars) *current-frame*))
 928                    (:set
 929                     `(setf (sb!di:debug-var-value (car vars) *current-frame*)
 930                            ,value-var))))
 931                ;; If there weren't any exact matches, flame about
 932                ;; ambiguity unless all the variables have the same
 933                ;; name.
 934                ((and (not exact)
 935                      (find-if-not
 936                       (lambda (v)
 937                         (string= (sb!di:debug-var-symbol-name v)
 938                                  (sb!di:debug-var-symbol-name (car vars))))
 939                       (cdr vars)))
 940                 (error "specification ambiguous:~%~{   ~A~%~}"
 941                        (mapcar #'sb!di:debug-var-symbol-name
 942                                (delete-duplicates
 943                                 vars :test #'string=
 944                                 :key #'sb!di:debug-var-symbol-name))))
 945                ;; All names are the same, so see whether the user
 946                ;; ID'ed one of them.
 947                (id-supplied
 948                 (let ((v (find id vars :key #'sb!di:debug-var-id)))
 949                   (unless v
 950                     (error
 951                      "invalid variable ID, ~W: should have been one of ~S"
 952                      id
 953                      (mapcar #'sb!di:debug-var-id vars)))
 954                   ,(ecase ref-or-set
 955                      (:ref
 956                       '(sb!di:debug-var-value v *current-frame*))
 957                      (:set
 958                       `(setf (sb!di:debug-var-value v *current-frame*)
 959                              ,value-var)))))
 960                (t
 961                 (error "Specify variable ID to disambiguate ~S. Use one of ~S."
 962                        name
 963                        (mapcar #'sb!di:debug-var-id vars)))))))))
 964
 965 ) ; EVAL-WHEN
 966
 967 ;;; FIXME: This doesn't work. It would be real nice we could make it
 968 ;;; work! Alas, it doesn't seem to work in CMU CL X86 either..
 969 (defun var (name &optional (id 0 id-supplied))
 970   #!+sb-doc
 971   "Return a variable's value if possible. NAME is a simple-string or symbol.
 972    If it is a simple-string, it is an initial substring of the variable's name.
 973    If name is a symbol, it has the same name and package as the variable whose
 974    value this function returns. If the symbol is uninterned, then the variable
 975    has the same name as the symbol, but it has no package.
 976
 977    If name is the initial substring of variables with different names, then
 978    this return no values after displaying the ambiguous names. If name
 979    determines multiple variables with the same name, then you must use the
 980    optional id argument to specify which one you want. If you left id
 981    unspecified, then this returns no values after displaying the distinguishing
 982    id values.
 983
 984    The result of this function is limited to the availability of variable
 985    information. This is SETF'able."
 986   (define-var-operation :ref))
 987 (defun (setf var) (value name &optional (id 0 id-supplied))
 988   (define-var-operation :set value))
 989
 990 ;;; This returns the COUNT'th arg as the user sees it from args, the
 991 ;;; result of SB!DI:DEBUG-FUN-LAMBDA-LIST. If this returns a
 992 ;;; potential DEBUG-VAR from the lambda-list, then the second value is
 993 ;;; T. If this returns a keyword symbol or a value from a rest arg,
 994 ;;; then the second value is NIL.
 995 (declaim (ftype (function (index list)) nth-arg))
 996 (defun nth-arg (count args)
 997   (let ((n count))
 998     (dolist (ele args (error "The argument specification ~S is out of range."
 999                              n))
1000       (lambda-list-element-dispatch ele
1001         :required ((if (zerop n) (return (values ele t))))
1002         :optional ((if (zerop n) (return (values (second ele) t))))
1003         :keyword ((cond ((zerop n)
1004                          (return (values (second ele) nil)))
1005                         ((zerop (decf n))
1006                          (return (values (third ele) t)))))
1007         :deleted ((if (zerop n) (return (values ele t))))
1008         :rest ((let ((var (second ele)))
1009                  (lambda-var-dispatch var (sb!di:frame-code-location
1010                                            *current-frame*)
1011                    (error "unused &REST argument before n'th
1012 argument")
1013                    (dolist (value
1014                             (sb!di:debug-var-value var *current-frame*)
1015                             (error
1016                              "The argument specification ~S is out of range."
1017                              n))
1018                      (if (zerop n)
1019                          (return-from nth-arg (values value nil))
1020                          (decf n)))
1021                    (error "invalid &REST argument before n'th argument")))))
1022       (decf n))))
1023
1024 (defun arg (n)
1025   #!+sb-doc
1026   "Return the N'th argument's value if possible. Argument zero is the first
1027    argument in a frame's default printed representation. Count keyword/value
1028    pairs as separate arguments."
1029   (multiple-value-bind (var lambda-var-p)
1030       (nth-arg n (handler-case (sb!di:debug-fun-lambda-list
1031                                 (sb!di:frame-debug-fun *current-frame*))
1032                    (sb!di:lambda-list-unavailable ()
1033                      (error "No argument values are available."))))
1034     (if lambda-var-p
1035         (lambda-var-dispatch var (sb!di:frame-code-location *current-frame*)
1036           (error "Unused arguments have no values.")
1037           (sb!di:debug-var-value var *current-frame*)
1038           (error "invalid argument value"))
1039         var)))
1040 \f
1041 ;;;; machinery for definition of debug loop commands
1042
1043 (defvar *debug-commands* nil)
1044
1045 ;;; Interface to *DEBUG-COMMANDS*. No required arguments in args are
1046 ;;; permitted.
1047 (defmacro !def-debug-command (name args &rest body)
1048   (let ((fun-name (symbolicate name "-DEBUG-COMMAND")))
1049     `(progn
1050        (setf *debug-commands*
1051              (remove ,name *debug-commands* :key #'car :test #'string=))
1052        (defun ,fun-name ,args
1053          (unless *in-the-debugger*
1054            (error "invoking debugger command while outside the debugger"))
1055          ,@body)
1056        (push (cons ,name #',fun-name) *debug-commands*)
1057        ',fun-name)))
1058
1059 (defun !def-debug-command-alias (new-name existing-name)
1060   (let ((pair (assoc existing-name *debug-commands* :test #'string=)))
1061     (unless pair (error "unknown debug command name: ~S" existing-name))
1062     (push (cons new-name (cdr pair)) *debug-commands*))
1063   new-name)
1064
1065 ;;; This takes a symbol and uses its name to find a debugger command,
1066 ;;; using initial substring matching. It returns the command function
1067 ;;; if form identifies only one command, but if form is ambiguous,
1068 ;;; this returns a list of the command names. If there are no matches,
1069 ;;; this returns nil. Whenever the loop that looks for a set of
1070 ;;; possibilities encounters an exact name match, we return that
1071 ;;; command function immediately.
1072 (defun debug-command-p (form &optional other-commands)
1073   (if (or (symbolp form) (integerp form))
1074       (let* ((name
1075               (if (symbolp form)
1076                   (symbol-name form)
1077                   (format nil "~W" form)))
1078              (len (length name))
1079              (res nil))
1080         (declare (simple-string name)
1081                  (fixnum len)
1082                  (list res))
1083
1084         ;; Find matching commands, punting if exact match.
1085         (flet ((match-command (ele)
1086                  (let* ((str (car ele))
1087                         (str-len (length str)))
1088                    (declare (simple-string str)
1089                             (fixnum str-len))
1090                    (cond ((< str-len len))
1091                          ((= str-len len)
1092                           (when (string= name str :end1 len :end2 len)
1093                             (return-from debug-command-p (cdr ele))))
1094                          ((string= name str :end1 len :end2 len)
1095                           (push ele res))))))
1096           (mapc #'match-command *debug-commands*)
1097           (mapc #'match-command other-commands))
1098
1099         ;; Return the right value.
1100         (cond ((not res) nil)
1101               ((= (length res) 1)
1102                (cdar res))
1103               (t ; Just return the names.
1104                (do ((cmds res (cdr cmds)))
1105                    ((not cmds) res)
1106                  (setf (car cmds) (caar cmds))))))))
1107
1108 ;;; Return a list of debug commands (in the same format as
1109 ;;; *DEBUG-COMMANDS*) that invoke each active restart.
1110 ;;;
1111 ;;; Two commands are made for each restart: one for the number, and
1112 ;;; one for the restart name (unless it's been shadowed by an earlier
1113 ;;; restart of the same name, or it is NIL).
1114 (defun make-restart-commands (&optional (restarts *debug-restarts*))
1115   (let ((commands)
1116         (num 0))                        ; better be the same as show-restarts!
1117     (dolist (restart restarts)
1118       (let ((name (string (restart-name restart))))
1119         (let ((restart-fun
1120                 (lambda ()
1121                   (/show0 "in restart-command closure, about to i-r-i")
1122                   (invoke-restart-interactively restart))))
1123           (push (cons (prin1-to-string num) restart-fun) commands)
1124           (unless (or (null (restart-name restart))
1125                       (find name commands :key #'car :test #'string=))
1126             (push (cons name restart-fun) commands))))
1127     (incf num))
1128   commands))
1129 \f
1130 ;;;; frame-changing commands
1131
1132 (!def-debug-command "UP" ()
1133   (let ((next (sb!di:frame-up *current-frame*)))
1134     (cond (next
1135            (setf *current-frame* next)
1136            (print-frame-call next))
1137           (t
1138            (format t "~&Top of stack.")))))
1139
1140 (!def-debug-command "DOWN" ()
1141   (let ((next (sb!di:frame-down *current-frame*)))
1142     (cond (next
1143            (setf *current-frame* next)
1144            (print-frame-call next))
1145           (t
1146            (format t "~&Bottom of stack.")))))
1147
1148 (!def-debug-command-alias "D" "DOWN")
1149
1150 ;;; CMU CL had this command, but SBCL doesn't, since it's redundant
1151 ;;; with "FRAME 0", and it interferes with abbreviations for the
1152 ;;; TOPLEVEL restart.
1153 ;;;(!def-debug-command "TOP" ()
1154 ;;;  (do ((prev *current-frame* lead)
1155 ;;;       (lead (sb!di:frame-up *current-frame*) (sb!di:frame-up lead)))
1156 ;;;      ((null lead)
1157 ;;;       (setf *current-frame* prev)
1158 ;;;       (print-frame-call prev))))
1159
1160 (!def-debug-command "BOTTOM" ()
1161   (do ((prev *current-frame* lead)
1162        (lead (sb!di:frame-down *current-frame*) (sb!di:frame-down lead)))
1163       ((null lead)
1164        (setf *current-frame* prev)
1165        (print-frame-call prev))))
1166
1167 (!def-debug-command-alias "B" "BOTTOM")
1168
1169 (!def-debug-command "FRAME" (&optional
1170                              (n (read-prompting-maybe "frame number: ")))
1171   (setf *current-frame*
1172         (multiple-value-bind (next-frame-fun limit-string)
1173             (if (< n (sb!di:frame-number *current-frame*))
1174                 (values #'sb!di:frame-up "top")
1175               (values #'sb!di:frame-down "bottom"))
1176           (do ((frame *current-frame*))
1177               ((= n (sb!di:frame-number frame))
1178                frame)
1179             (let ((next-frame (funcall next-frame-fun frame)))
1180               (cond (next-frame
1181                      (setf frame next-frame))
1182                     (t
1183                      (format t
1184                              "The ~A of the stack was encountered.~%"
1185                              limit-string)
1186                      (return frame)))))))
1187   (print-frame-call *current-frame*))
1188
1189 (!def-debug-command-alias "F" "FRAME")
1190 \f
1191 ;;;; commands for entering and leaving the debugger
1192
1193 ;;; CMU CL supported this QUIT debug command, but SBCL provides this
1194 ;;; functionality with a restart instead. (The QUIT debug command was
1195 ;;; removed because it's confusing to have "quit" mean two different
1196 ;;; things in the system, "restart the top level REPL" in the debugger
1197 ;;; and "terminate the Lisp system" as the SB-EXT:QUIT function.)
1198 ;;;
1199 ;;;(!def-debug-command "QUIT" ()
1200 ;;;  (throw 'sb!impl::toplevel-catcher nil))
1201
1202 ;;; CMU CL supported this GO debug command, but SBCL doesn't -- in
1203 ;;; SBCL you just type the CONTINUE restart name instead (or "RESTART
1204 ;;; CONTINUE", that's OK too).
1205
1206 ;;;(!def-debug-command "GO" ()
1207 ;;;  (continue *debug-condition*)
1208 ;;;  (error "There is no restart named CONTINUE."))
1209
1210 (!def-debug-command "RESTART" ()
1211   (/show0 "doing RESTART debug-command")
1212   (let ((num (read-if-available :prompt)))
1213     (when (eq num :prompt)
1214       (show-restarts *debug-restarts* *debug-io*)
1215       (write-string "restart: ")
1216       (force-output)
1217       (setf num (read *debug-io*)))
1218     (let ((restart (typecase num
1219                      (unsigned-byte
1220                       (nth num *debug-restarts*))
1221                      (symbol
1222                       (find num *debug-restarts* :key #'restart-name
1223                             :test (lambda (sym1 sym2)
1224                                     (string= (symbol-name sym1)
1225                                              (symbol-name sym2)))))
1226                      (t
1227                       (format t "~S is invalid as a restart name.~%" num)
1228                       (return-from restart-debug-command nil)))))
1229       (/show0 "got RESTART")
1230       (if restart
1231           (invoke-restart-interactively restart)
1232           ;; FIXME: Even if this isn't handled by WARN, it probably
1233           ;; shouldn't go to *STANDARD-OUTPUT*, but *ERROR-OUTPUT* or
1234           ;; *QUERY-IO* or something. Look through this file to
1235           ;; straighten out stream usage.
1236           (princ "There is no such restart.")))))
1237 \f
1238 ;;;; information commands
1239
1240 (!def-debug-command "HELP" ()
1241   ;; CMU CL had a little toy pager here, but "if you aren't running
1242   ;; ILISP (or a smart windowing system, or something) you deserve to
1243   ;; lose", so we've dropped it in SBCL. However, in case some
1244   ;; desperate holdout is running this on a dumb terminal somewhere,
1245   ;; we tell him where to find the message stored as a string.
1246   (format *debug-io*
1247           "~&~A~2%(The HELP string is stored in ~S.)~%"
1248           *debug-help-string*
1249           '*debug-help-string*))
1250
1251 (!def-debug-command-alias "?" "HELP")
1252
1253 (!def-debug-command "ERROR" ()
1254   (format *debug-io* "~A~%" *debug-condition*)
1255   (show-restarts *debug-restarts* *debug-io*))
1256
1257 (!def-debug-command "BACKTRACE" ()
1258   (backtrace (read-if-available most-positive-fixnum)))
1259
1260 (!def-debug-command "PRINT" ()
1261   (print-frame-call *current-frame*))
1262
1263 (!def-debug-command-alias "P" "PRINT")
1264
1265 (!def-debug-command "LIST-LOCALS" ()
1266   (let ((d-fun (sb!di:frame-debug-fun *current-frame*)))
1267     (if (sb!di:debug-var-info-available d-fun)
1268         (let ((*standard-output* *debug-io*)
1269               (location (sb!di:frame-code-location *current-frame*))
1270               (prefix (read-if-available nil))
1271               (any-p nil)
1272               (any-valid-p nil))
1273           (dolist (v (sb!di:ambiguous-debug-vars
1274                         d-fun
1275                         (if prefix (string prefix) "")))
1276             (setf any-p t)
1277             (when (eq (sb!di:debug-var-validity v location) :valid)
1278               (setf any-valid-p t)
1279               (format t "~S~:[#~W~;~*~]  =  ~S~%"
1280                       (sb!di:debug-var-symbol v)
1281                       (zerop (sb!di:debug-var-id v))
1282                       (sb!di:debug-var-id v)
1283                       (sb!di:debug-var-value v *current-frame*))))
1284
1285           (cond
1286            ((not any-p)
1287             (format t "There are no local variables ~@[starting with ~A ~]~
1288                        in the function."
1289                     prefix))
1290            ((not any-valid-p)
1291             (format t "All variables ~@[starting with ~A ~]currently ~
1292                        have invalid values."
1293                     prefix))))
1294         (write-line "There is no variable information available."))))
1295
1296 (!def-debug-command-alias "L" "LIST-LOCALS")
1297
1298 (!def-debug-command "SOURCE" ()
1299   (fresh-line)
1300   (print-code-location-source-form (sb!di:frame-code-location *current-frame*)
1301                                    (read-if-available 0)))
1302 \f
1303 ;;;; source location printing
1304
1305 ;;; We cache a stream to the last valid file debug source so that we
1306 ;;; won't have to repeatedly open the file.
1307 ;;;
1308 ;;; KLUDGE: This sounds like a bug, not a feature. Opening files is fast
1309 ;;; in the 1990s, so the benefit is negligible, less important than the
1310 ;;; potential of extra confusion if someone changes the source during
1311 ;;; a debug session and the change doesn't show up. And removing this
1312 ;;; would simplify the system, which I like. -- WHN 19990903
1313 (defvar *cached-debug-source* nil)
1314 (declaim (type (or sb!di:debug-source null) *cached-debug-source*))
1315 (defvar *cached-source-stream* nil)
1316 (declaim (type (or stream null) *cached-source-stream*))
1317
1318 ;;; To suppress the read-time evaluation #. macro during source read,
1319 ;;; *READTABLE* is modified. *READTABLE* is cached to avoid
1320 ;;; copying it each time, and invalidated when the
1321 ;;; *CACHED-DEBUG-SOURCE* has changed.
1322 (defvar *cached-readtable* nil)
1323 (declaim (type (or readtable null) *cached-readtable*))
1324
1325 (pushnew (lambda ()
1326            (setq *cached-debug-source* nil *cached-source-stream* nil
1327                  *cached-readtable* nil))
1328          *before-save-initializations*)
1329
1330 ;;; We also cache the last toplevel form that we printed a source for
1331 ;;; so that we don't have to do repeated reads and calls to
1332 ;;; FORM-NUMBER-TRANSLATIONS.
1333 (defvar *cached-toplevel-form-offset* nil)
1334 (declaim (type (or index null) *cached-toplevel-form-offset*))
1335 (defvar *cached-toplevel-form*)
1336 (defvar *cached-form-number-translations*)
1337
1338 ;;; Given a code location, return the associated form-number
1339 ;;; translations and the actual top level form. We check our cache ---
1340 ;;; if there is a miss, we dispatch on the kind of the debug source.
1341 (defun get-toplevel-form (location)
1342   (let ((d-source (sb!di:code-location-debug-source location)))
1343     (if (and (eq d-source *cached-debug-source*)
1344              (eql (sb!di:code-location-toplevel-form-offset location)
1345                   *cached-toplevel-form-offset*))
1346         (values *cached-form-number-translations* *cached-toplevel-form*)
1347         (let* ((offset (sb!di:code-location-toplevel-form-offset location))
1348                (res
1349                 (ecase (sb!di:debug-source-from d-source)
1350                   (:file (get-file-toplevel-form location))
1351                   (:lisp (svref (sb!di:debug-source-name d-source) offset)))))
1352           (setq *cached-toplevel-form-offset* offset)
1353           (values (setq *cached-form-number-translations*
1354                         (sb!di:form-number-translations res offset))
1355                   (setq *cached-toplevel-form* res))))))
1356
1357 ;;; Locate the source file (if it still exists) and grab the top level
1358 ;;; form. If the file is modified, we use the top level form offset
1359 ;;; instead of the recorded character offset.
1360 (defun get-file-toplevel-form (location)
1361   (let* ((d-source (sb!di:code-location-debug-source location))
1362          (tlf-offset (sb!di:code-location-toplevel-form-offset location))
1363          (local-tlf-offset (- tlf-offset
1364                               (sb!di:debug-source-root-number d-source)))
1365          (char-offset
1366           (aref (or (sb!di:debug-source-start-positions d-source)
1367                     (error "no start positions map"))
1368                 local-tlf-offset))
1369          (name (sb!di:debug-source-name d-source)))
1370     (unless (eq d-source *cached-debug-source*)
1371       (unless (and *cached-source-stream*
1372                    (equal (pathname *cached-source-stream*)
1373                           (pathname name)))
1374         (setq *cached-readtable* nil)
1375         (when *cached-source-stream* (close *cached-source-stream*))
1376         (setq *cached-source-stream* (open name :if-does-not-exist nil))
1377         (unless *cached-source-stream*
1378           (error "The source file no longer exists:~%  ~A" (namestring name)))
1379         (format t "~%; file: ~A~%" (namestring name)))
1380
1381         (setq *cached-debug-source*
1382               (if (= (sb!di:debug-source-created d-source)
1383                      (file-write-date name))
1384                   d-source nil)))
1385
1386     (cond
1387      ((eq *cached-debug-source* d-source)
1388       (file-position *cached-source-stream* char-offset))
1389      (t
1390       (format t "~%; File has been modified since compilation:~%;   ~A~@
1391                  ; Using form offset instead of character position.~%"
1392               (namestring name))
1393       (file-position *cached-source-stream* 0)
1394       (let ((*read-suppress* t))
1395         (dotimes (i local-tlf-offset)
1396           (read *cached-source-stream*)))))
1397     (unless *cached-readtable*
1398       (setq *cached-readtable* (copy-readtable))
1399       (set-dispatch-macro-character
1400        #\# #\.
1401        (lambda (stream sub-char &rest rest)
1402          (declare (ignore rest sub-char))
1403          (let ((token (read stream t nil t)))
1404            (format nil "#.~S" token)))
1405        *cached-readtable*))
1406     (let ((*readtable* *cached-readtable*))
1407       (read *cached-source-stream*))))
1408
1409 (defun print-code-location-source-form (location context)
1410   (let* ((location (maybe-block-start-location location))
1411          (form-num (sb!di:code-location-form-number location)))
1412     (multiple-value-bind (translations form) (get-toplevel-form location)
1413       (unless (< form-num (length translations))
1414         (error "The source path no longer exists."))
1415       (prin1 (sb!di:source-path-context form
1416                                         (svref translations form-num)
1417                                         context)))))
1418 \f
1419 ;;; breakpoint and step commands
1420
1421 ;;; Step to the next code-location.
1422 (!def-debug-command "STEP" ()
1423   (setf *number-of-steps* (read-if-available 1))
1424   (set-step-breakpoint *current-frame*)
1425   (continue *debug-condition*)
1426   (error "couldn't continue"))
1427
1428 ;;; List possible breakpoint locations, which ones are active, and
1429 ;;; where the CONTINUE restart will transfer control. Set
1430 ;;; *POSSIBLE-BREAKPOINTS* to the code-locations which can then be
1431 ;;; used by sbreakpoint.
1432 (!def-debug-command "LIST-LOCATIONS" ()
1433   (let ((df (read-if-available *default-breakpoint-debug-fun*)))
1434     (cond ((consp df)
1435            (setf df (sb!di:fun-debug-fun (eval df)))
1436            (setf *default-breakpoint-debug-fun* df))
1437           ((or (eq ':c df)
1438                (not *default-breakpoint-debug-fun*))
1439            (setf df (sb!di:frame-debug-fun *current-frame*))
1440            (setf *default-breakpoint-debug-fun* df)))
1441     (setf *possible-breakpoints* (possible-breakpoints df)))
1442   (let ((continue-at (sb!di:frame-code-location *current-frame*)))
1443     (let ((active (location-in-list *default-breakpoint-debug-fun*
1444                                     *breakpoints* :fun-start))
1445           (here (sb!di:code-location=
1446                  (sb!di:debug-fun-start-location
1447                   *default-breakpoint-debug-fun*) continue-at)))
1448       (when (or active here)
1449         (format t "::FUN-START ")
1450         (when active (format t " *Active*"))
1451         (when here (format t " *Continue here*"))))
1452
1453     (let ((prev-location nil)
1454           (prev-num 0)
1455           (this-num 0))
1456       (flet ((flush ()
1457                (when prev-location
1458                  (let ((this-num (1- this-num)))
1459                    (if (= prev-num this-num)
1460                        (format t "~&~W: " prev-num)
1461                        (format t "~&~W-~W: " prev-num this-num)))
1462                  (print-code-location-source-form prev-location 0)
1463                  (when *print-location-kind*
1464                    (format t "~S " (sb!di:code-location-kind prev-location)))
1465                  (when (location-in-list prev-location *breakpoints*)
1466                    (format t " *Active*"))
1467                  (when (sb!di:code-location= prev-location continue-at)
1468                    (format t " *Continue here*")))))
1469
1470         (dolist (code-location *possible-breakpoints*)
1471           (when (or *print-location-kind*
1472                     (location-in-list code-location *breakpoints*)
1473                     (sb!di:code-location= code-location continue-at)
1474                     (not prev-location)
1475                     (not (eq (sb!di:code-location-debug-source code-location)
1476                              (sb!di:code-location-debug-source prev-location)))
1477                     (not (eq (sb!di:code-location-toplevel-form-offset
1478                               code-location)
1479                              (sb!di:code-location-toplevel-form-offset
1480                               prev-location)))
1481                     (not (eq (sb!di:code-location-form-number code-location)
1482                              (sb!di:code-location-form-number prev-location))))
1483             (flush)
1484             (setq prev-location code-location  prev-num this-num))
1485
1486           (incf this-num))))
1487
1488     (when (location-in-list *default-breakpoint-debug-fun*
1489                             *breakpoints*
1490                             :fun-end)
1491       (format t "~&::FUN-END *Active* "))))
1492
1493 (!def-debug-command-alias "LL" "LIST-LOCATIONS")
1494
1495 ;;; Set breakpoint at the given number.
1496 (!def-debug-command "BREAKPOINT" ()
1497   (let ((index (read-prompting-maybe "location number, :START, or :END: "))
1498         (break t)
1499         (condition t)
1500         (print nil)
1501         (print-functions nil)
1502         (function nil)
1503         (bp)
1504         (place *default-breakpoint-debug-fun*))
1505     (flet ((get-command-line ()
1506              (let ((command-line nil)
1507                    (unique '(nil)))
1508                (loop
1509                  (let ((next-input (read-if-available unique)))
1510                    (when (eq next-input unique) (return))
1511                    (push next-input command-line)))
1512                (nreverse command-line)))
1513            (set-vars-from-command-line (command-line)
1514              (do ((arg (pop command-line) (pop command-line)))
1515                  ((not arg))
1516                (ecase arg
1517                  (:condition (setf condition (pop command-line)))
1518                  (:print (push (pop command-line) print))
1519                  (:break (setf break (pop command-line)))
1520                  (:function
1521                   (setf function (eval (pop command-line)))
1522                   (setf *default-breakpoint-debug-fun*
1523                         (sb!di:fun-debug-fun function))
1524                   (setf place *default-breakpoint-debug-fun*)
1525                   (setf *possible-breakpoints*
1526                         (possible-breakpoints
1527                          *default-breakpoint-debug-fun*))))))
1528            (setup-fun-start ()
1529              (let ((code-loc (sb!di:debug-fun-start-location place)))
1530                (setf bp (sb!di:make-breakpoint #'main-hook-fun
1531                                                place
1532                                                :kind :fun-start))
1533                (setf break (sb!di:preprocess-for-eval break code-loc))
1534                (setf condition (sb!di:preprocess-for-eval condition code-loc))
1535                (dolist (form print)
1536                  (push (cons (sb!di:preprocess-for-eval form code-loc) form)
1537                        print-functions))))
1538            (setup-fun-end ()
1539              (setf bp
1540                    (sb!di:make-breakpoint #'main-hook-fun
1541                                           place
1542                                           :kind :fun-end))
1543              (setf break
1544                    ;; FIXME: These and any other old (COERCE `(LAMBDA ..) ..)
1545                    ;; forms should be converted to shiny new (LAMBDA ..) forms.
1546                    ;; (Search the sources for "coerce.*\(lambda".)
1547                    (coerce `(lambda (dummy)
1548                               (declare (ignore dummy)) ,break)
1549                            'function))
1550              (setf condition (coerce `(lambda (dummy)
1551                                         (declare (ignore dummy)) ,condition)
1552                                      'function))
1553              (dolist (form print)
1554                (push (cons
1555                       (coerce `(lambda (dummy)
1556                                  (declare (ignore dummy)) ,form) 'function)
1557                       form)
1558                      print-functions)))
1559            (setup-code-location ()
1560              (setf place (nth index *possible-breakpoints*))
1561              (setf bp (sb!di:make-breakpoint #'main-hook-fun place
1562                                              :kind :code-location))
1563              (dolist (form print)
1564                (push (cons
1565                       (sb!di:preprocess-for-eval form place)
1566                       form)
1567                      print-functions))
1568              (setf break (sb!di:preprocess-for-eval break place))
1569              (setf condition (sb!di:preprocess-for-eval condition place))))
1570       (set-vars-from-command-line (get-command-line))
1571       (cond
1572        ((or (eq index :start) (eq index :s))
1573         (setup-fun-start))
1574        ((or (eq index :end) (eq index :e))
1575         (setup-fun-end))
1576        (t
1577         (setup-code-location)))
1578       (sb!di:activate-breakpoint bp)
1579       (let* ((new-bp-info (create-breakpoint-info place bp index
1580                                                   :break break
1581                                                   :print print-functions
1582                                                   :condition condition))
1583              (old-bp-info (location-in-list new-bp-info *breakpoints*)))
1584         (when old-bp-info
1585           (sb!di:deactivate-breakpoint (breakpoint-info-breakpoint
1586                                         old-bp-info))
1587           (setf *breakpoints* (remove old-bp-info *breakpoints*))
1588           (format t "previous breakpoint removed~%"))
1589         (push new-bp-info *breakpoints*))
1590       (print-breakpoint-info (first *breakpoints*))
1591       (format t "~&added"))))
1592
1593 (!def-debug-command-alias "BP" "BREAKPOINT")
1594
1595 ;;; List all breakpoints which are set.
1596 (!def-debug-command "LIST-BREAKPOINTS" ()
1597   (setf *breakpoints*
1598         (sort *breakpoints* #'< :key #'breakpoint-info-breakpoint-number))
1599   (dolist (info *breakpoints*)
1600     (print-breakpoint-info info)))
1601
1602 (!def-debug-command-alias "LB" "LIST-BREAKPOINTS")
1603 (!def-debug-command-alias "LBP" "LIST-BREAKPOINTS")
1604
1605 ;;; Remove breakpoint N, or remove all breakpoints if no N given.
1606 (!def-debug-command "DELETE-BREAKPOINT" ()
1607   (let* ((index (read-if-available nil))
1608          (bp-info
1609           (find index *breakpoints* :key #'breakpoint-info-breakpoint-number)))
1610     (cond (bp-info
1611            (sb!di:delete-breakpoint (breakpoint-info-breakpoint bp-info))
1612            (setf *breakpoints* (remove bp-info *breakpoints*))
1613            (format t "breakpoint ~S removed~%" index))
1614           (index (format t "The breakpoint doesn't exist."))
1615           (t
1616            (dolist (ele *breakpoints*)
1617              (sb!di:delete-breakpoint (breakpoint-info-breakpoint ele)))
1618            (setf *breakpoints* nil)
1619            (format t "all breakpoints deleted~%")))))
1620
1621 (!def-debug-command-alias "DBP" "DELETE-BREAKPOINT")
1622 \f
1623 ;;; miscellaneous commands
1624
1625 (!def-debug-command "DESCRIBE" ()
1626   (let* ((curloc (sb!di:frame-code-location *current-frame*))
1627          (debug-fun (sb!di:code-location-debug-fun curloc))
1628          (function (sb!di:debug-fun-fun debug-fun)))
1629     (if function
1630         (describe function)
1631         (format t "can't figure out the function for this frame"))))
1632
1633 (!def-debug-command "SLURP" ()
1634   (loop while (read-char-no-hang *standard-input*)))
1635 \f
1636 ;;;; debug loop command utilities
1637
1638 (defun read-prompting-maybe (prompt)
1639   (unless (sb!int:listen-skip-whitespace *debug-io*)
1640     (princ prompt)
1641     (force-output))
1642   (read *debug-io*))
1643
1644 (defun read-if-available (default)
1645   (if (sb!int:listen-skip-whitespace *debug-io*)
1646       (read *debug-io*)
1647       default))