src/code/debug.lisp

   1 ;;;; the debugger
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!DEBUG")
  13 \f
  14 ;;;; variables and constants
  15
  16 ;;; things to consider when tweaking these values:
  17 ;;;   * We're afraid to just default them to NIL and NIL, in case the
  18 ;;;     user inadvertently causes a hairy data structure to be printed
  19 ;;;     when he inadvertently enters the debugger.
  20 ;;;   * We don't want to truncate output too much. These days anyone
  21 ;;;     can easily run their Lisp in a windowing system or under Emacs,
  22 ;;;     so it's not the end of the world even if the worst case is a
  23 ;;;     few thousand lines of output.
  24 ;;;   * As condition :REPORT methods are converted to use the pretty
  25 ;;;     printer, they acquire *PRINT-LEVEL* constraints, so e.g. under
  26 ;;;     sbcl-0.7.1.28's old value of *DEBUG-PRINT-LEVEL*=3, an
  27 ;;;     ARG-COUNT-ERROR printed as
  28 ;;;       error while parsing arguments to DESTRUCTURING-BIND:
  29 ;;;         invalid number of elements in
  30 ;;;           #
  31 ;;;         to satisfy lambda list
  32 ;;;           #:
  33 ;;;         exactly 2 expected, but 5 found
  34 (defvar *debug-print-level* 5
  35   #!+sb-doc
  36   "*PRINT-LEVEL* for the debugger")
  37 (defvar *debug-print-length* 7
  38   #!+sb-doc
  39   "*PRINT-LENGTH* for the debugger")
  40
  41 (defvar *debug-readtable*
  42   ;; KLUDGE: This can't be initialized in a cold toplevel form,
  43   ;; because the *STANDARD-READTABLE* isn't initialized until after
  44   ;; cold toplevel forms have run. So instead we initialize it
  45   ;; immediately after *STANDARD-READTABLE*. -- WHN 20000205
  46   nil
  47   #!+sb-doc
  48   "*READTABLE* for the debugger")
  49
  50 (defvar *in-the-debugger* nil
  51   #!+sb-doc
  52   "This is T while in the debugger.")
  53
  54 ;;; nestedness inside debugger command loops
  55 (defvar *debug-command-level* 0)
  56
  57 ;;; If this is bound before the debugger is invoked, it is used as the
  58 ;;; stack top by the debugger.
  59 (defvar *stack-top-hint* nil)
  60
  61 (defvar *stack-top* nil)
  62 (defvar *real-stack-top* nil)
  63
  64 (defvar *current-frame* nil)
  65
  66 ;;; Beginner-oriented help messages are important because you end up
  67 ;;; in the debugger whenever something bad happens, or if you try to
  68 ;;; get out of the system with Ctrl-C or (EXIT) or EXIT or whatever.
  69 ;;; But after memorizing them the wasted screen space gets annoying..
  70 (defvar *debug-beginner-help-p* t
  71   "Should the debugger display beginner-oriented help messages?")
  72
  73 (defun debug-prompt (stream)
  74   (sb!thread::get-foreground)
  75   (format stream
  76           "~%~W~:[~;[~W~]] "
  77           (sb!di:frame-number *current-frame*)
  78           (> *debug-command-level* 1)
  79           *debug-command-level*))
  80
  81 (defparameter *debug-help-string*
  82 "The debug prompt is square brackets, with number(s) indicating the current
  83   control stack level and, if you've entered the debugger recursively, how
  84   deeply recursed you are.
  85 Any command -- including the name of a restart -- may be uniquely abbreviated.
  86 The debugger rebinds various special variables for controlling i/o, sometimes
  87   to defaults (much like WITH-STANDARD-IO-SYNTAX does) and sometimes to
  88   its own special values, e.g. SB-DEBUG:*DEBUG-PRINT-LEVEL*.
  89 Debug commands do not affect *, //, and similar variables, but evaluation in
  90   the debug loop does affect these variables.
  91 SB-DEBUG:*FLUSH-DEBUG-ERRORS* controls whether errors at the debug prompt
  92   drop you deeper into the debugger.
  93
  94 Getting in and out of the debugger:
  95   RESTART  invokes restart numbered as shown (prompt if not given).
  96   ERROR    prints the error condition and restart cases.
  97   The number of any restart, or its name, or a unique abbreviation for its
  98     name, is a valid command, and is the same as using RESTART to invoke
  99     that restart.
 100
 101 Changing frames:
 102   U      up frame     D    down frame
 103   B  bottom frame     F n  frame n (n=0 for top frame)
 104
 105 Inspecting frames:
 106   BACKTRACE [n]  shows n frames going down the stack.
 107   LIST-LOCALS, L lists locals in current function.
 108   PRINT, P       displays current function call.
 109   SOURCE [n]     displays frame's source form with n levels of enclosing forms.
 110
 111 Breakpoints and steps:
 112   LIST-LOCATIONS [{function | :C}]   List the locations for breakpoints.
 113                                      Specify :C for the current frame.
 114     Abbreviation: LL
 115   LIST-BREAKPOINTS                   List the active breakpoints.
 116     Abbreviations: LB, LBP
 117   DELETE-BREAKPOINT [n]              Remove breakpoint n or all breakpoints.
 118     Abbreviations: DEL, DBP
 119   BREAKPOINT {n | :end | :start} [:break form] [:function function]
 120              [{:print form}*] [:condition form]
 121                                      Set a breakpoint.
 122     Abbreviations: BR, BP
 123   STEP [n]                           Step to the next location or step n times.
 124
 125 Function and macro commands:
 126  (SB-DEBUG:ARG n)
 127     Return the n'th argument in the current frame.
 128  (SB-DEBUG:VAR string-or-symbol [id])
 129     Returns the value of the specified variable in the current frame.
 130
 131 Other commands:
 132   RETURN expr
 133     [EXPERIMENTAL] Return the values resulting from evaluation of expr
 134     from the current frame, if this frame was compiled with a sufficiently
 135     high DEBUG optimization quality.
 136   SLURP
 137     Discard all pending input on *STANDARD-INPUT*. (This can be
 138     useful when the debugger was invoked to handle an error in
 139     deeply nested input syntax, and now the reader is confused.)")
 140 \f
 141 ;;; This is used to communicate to DEBUG-LOOP that we are at a step breakpoint.
 142 (define-condition step-condition (simple-condition) ())
 143 \f
 144 ;;;; breakpoint state
 145
 146 (defvar *only-block-start-locations* nil
 147   #!+sb-doc
 148   "When true, the LIST-LOCATIONS command only displays block start locations.
 149    Otherwise, all locations are displayed.")
 150
 151 (defvar *print-location-kind* nil
 152   #!+sb-doc
 153   "When true, list the code location type in the LIST-LOCATIONS command.")
 154
 155 ;;; a list of the types of code-locations that should not be stepped
 156 ;;; to and should not be listed when listing breakpoints
 157 (defvar *bad-code-location-types* '(:call-site :internal-error))
 158 (declaim (type list *bad-code-location-types*))
 159
 160 ;;; code locations of the possible breakpoints
 161 (defvar *possible-breakpoints*)
 162 (declaim (type list *possible-breakpoints*))
 163
 164 ;;; a list of the made and active breakpoints, each is a
 165 ;;; BREAKPOINT-INFO structure
 166 (defvar *breakpoints* nil)
 167 (declaim (type list *breakpoints*))
 168
 169 ;;; a list of BREAKPOINT-INFO structures of the made and active step
 170 ;;; breakpoints
 171 (defvar *step-breakpoints* nil)
 172 (declaim (type list *step-breakpoints*))
 173
 174 ;;; the number of times left to step
 175 (defvar *number-of-steps* 1)
 176 (declaim (type integer *number-of-steps*))
 177
 178 ;;; This is used when listing and setting breakpoints.
 179 (defvar *default-breakpoint-debug-fun* nil)
 180 (declaim (type (or list sb!di:debug-fun) *default-breakpoint-debug-fun*))
 181 \f
 182 ;;;; code location utilities
 183
 184 ;;; Return the first code-location in the passed debug block.
 185 (defun first-code-location (debug-block)
 186   (let ((found nil)
 187         (first-code-location nil))
 188     (sb!di:do-debug-block-locations (code-location debug-block)
 189       (unless found
 190         (setf first-code-location code-location)
 191         (setf found t)))
 192     first-code-location))
 193
 194 ;;; Return a list of the next code-locations following the one passed.
 195 ;;; One of the *BAD-CODE-LOCATION-TYPES* will not be returned.
 196 (defun next-code-locations (code-location)
 197   (let ((debug-block (sb!di:code-location-debug-block code-location))
 198         (block-code-locations nil))
 199     (sb!di:do-debug-block-locations (block-code-location debug-block)
 200       (unless (member (sb!di:code-location-kind block-code-location)
 201                       *bad-code-location-types*)
 202         (push block-code-location block-code-locations)))
 203     (setf block-code-locations (nreverse block-code-locations))
 204     (let* ((code-loc-list (rest (member code-location block-code-locations
 205                                         :test #'sb!di:code-location=)))
 206            (next-list (cond (code-loc-list
 207                              (list (first code-loc-list)))
 208                             ((map 'list #'first-code-location
 209                                   (sb!di:debug-block-successors debug-block)))
 210                             (t nil))))
 211       (when (and (= (length next-list) 1)
 212                  (sb!di:code-location= (first next-list) code-location))
 213         (setf next-list (next-code-locations (first next-list))))
 214       next-list)))
 215
 216 ;;; Return a list of code-locations of the possible breakpoints of DEBUG-FUN.
 217 (defun possible-breakpoints (debug-fun)
 218   (let ((possible-breakpoints nil))
 219     (sb!di:do-debug-fun-blocks (debug-block debug-fun)
 220       (unless (sb!di:debug-block-elsewhere-p debug-block)
 221         (if *only-block-start-locations*
 222             (push (first-code-location debug-block) possible-breakpoints)
 223             (sb!di:do-debug-block-locations (code-location debug-block)
 224               (when (not (member (sb!di:code-location-kind code-location)
 225                                  *bad-code-location-types*))
 226                 (push code-location possible-breakpoints))))))
 227     (nreverse possible-breakpoints)))
 228
 229 ;;; Search the info-list for the item passed (CODE-LOCATION,
 230 ;;; DEBUG-FUN, or BREAKPOINT-INFO). If the item passed is a debug
 231 ;;; function then kind will be compared if it was specified. The kind
 232 ;;; if also compared if a breakpoint-info is passed since it's in the
 233 ;;; breakpoint. The info structure is returned if found.
 234 (defun location-in-list (place info-list &optional (kind nil))
 235   (when (breakpoint-info-p place)
 236     (setf kind (sb!di:breakpoint-kind (breakpoint-info-breakpoint place)))
 237     (setf place (breakpoint-info-place place)))
 238   (cond ((sb!di:code-location-p place)
 239          (find place info-list
 240                :key #'breakpoint-info-place
 241                :test (lambda (x y) (and (sb!di:code-location-p y)
 242                                         (sb!di:code-location= x y)))))
 243         (t
 244          (find place info-list
 245                :test (lambda (x-debug-fun y-info)
 246                        (let ((y-place (breakpoint-info-place y-info))
 247                              (y-breakpoint (breakpoint-info-breakpoint
 248                                             y-info)))
 249                          (and (sb!di:debug-fun-p y-place)
 250                               (eq x-debug-fun y-place)
 251                               (or (not kind)
 252                                   (eq kind (sb!di:breakpoint-kind
 253                                             y-breakpoint))))))))))
 254
 255 ;;; If LOC is an unknown location, then try to find the block start
 256 ;;; location. Used by source printing to some information instead of
 257 ;;; none for the user.
 258 (defun maybe-block-start-location (loc)
 259   (if (sb!di:code-location-unknown-p loc)
 260       (let* ((block (sb!di:code-location-debug-block loc))
 261              (start (sb!di:do-debug-block-locations (loc block)
 262                       (return loc))))
 263         (cond ((and (not (sb!di:debug-block-elsewhere-p block))
 264                     start)
 265                ;; FIXME: Why output on T instead of *DEBUG-FOO* or something?
 266                (format t "~%unknown location: using block start~%")
 267                start)
 268               (t
 269                loc)))
 270       loc))
 271 \f
 272 ;;;; the BREAKPOINT-INFO structure
 273
 274 ;;; info about a made breakpoint
 275 (defstruct (breakpoint-info (:copier nil)
 276                             (:constructor %make-breakpoint-info))
 277   ;; where we are going to stop
 278   (place (missing-arg)
 279          :type (or sb!di:code-location sb!di:debug-fun)
 280          :read-only t)
 281   ;; the breakpoint returned by SB!DI:MAKE-BREAKPOINT
 282   (breakpoint (missing-arg) :type sb!di:breakpoint :read-only t)
 283   ;; the function returned from SB!DI:PREPROCESS-FOR-EVAL. If result is
 284   ;; non-NIL, drop into the debugger.
 285   (break #'identity :type function :read-only t)
 286   ;; the function returned from SB!DI:PREPROCESS-FOR-EVAL. If result is
 287   ;; non-NIL, eval (each) print and print results.
 288   (condition #'identity :type function :read-only t)
 289   ;; the list of functions from SB!DI:PREPROCESS-FOR-EVAL to evaluate.
 290   ;; Results are conditionally printed. CAR of each element is the
 291   ;; function, CDR is the form it goes with.
 292   (print nil :type list :read-only t)
 293   ;; the number used when listing the possible breakpoints within a
 294   ;; function; or could also be a symbol such as START or END
 295   (code-location-selector (missing-arg) :type (or symbol integer) :read-only t)
 296   ;; the number used when listing the active breakpoints, and when
 297   ;; deleting breakpoints
 298   (breakpoint-number (missing-arg) :type integer :read-only t))
 299
 300 (defun create-breakpoint-info (place breakpoint code-location-selector
 301                                      &key (break #'identity)
 302                                      (condition #'identity) (print nil))
 303   (setf *breakpoints*
 304         (sort *breakpoints* #'< :key #'breakpoint-info-breakpoint-number))
 305   (let ((breakpoint-number
 306          (do ((i 1 (incf i)) (breakpoints *breakpoints* (rest breakpoints)))
 307              ((or (> i (length *breakpoints*))
 308                   (not (= i (breakpoint-info-breakpoint-number
 309                              (first breakpoints)))))
 310
 311               i))))
 312     (%make-breakpoint-info :place place
 313                            :breakpoint breakpoint
 314                            :code-location-selector code-location-selector
 315                            :breakpoint-number breakpoint-number
 316                            :break break
 317                            :condition condition
 318                            :print print)))
 319
 320 (defun print-breakpoint-info (breakpoint-info)
 321   (let ((place (breakpoint-info-place breakpoint-info))
 322         (bp-number (breakpoint-info-breakpoint-number breakpoint-info)))
 323     (case (sb!di:breakpoint-kind (breakpoint-info-breakpoint breakpoint-info))
 324       (:code-location
 325        (print-code-location-source-form place 0)
 326        (format t
 327                "~&~S: ~S in ~S"
 328                bp-number
 329                (breakpoint-info-code-location-selector breakpoint-info)
 330                (sb!di:debug-fun-name (sb!di:code-location-debug-fun place))))
 331       (:fun-start
 332        (format t "~&~S: FUN-START in ~S" bp-number
 333                (sb!di:debug-fun-name place)))
 334       (:fun-end
 335        (format t "~&~S: FUN-END in ~S" bp-number
 336                (sb!di:debug-fun-name place))))))
 337 \f
 338 ;;;; MAIN-HOOK-FUN for steps and breakpoints
 339
 340 ;;; This must be passed as the hook function. It keeps track of where
 341 ;;; STEP breakpoints are.
 342 (defun main-hook-fun (current-frame breakpoint &optional return-vals
 343                                     fun-end-cookie)
 344   (setf *default-breakpoint-debug-fun*
 345         (sb!di:frame-debug-fun current-frame))
 346   (dolist (step-info *step-breakpoints*)
 347     (sb!di:delete-breakpoint (breakpoint-info-breakpoint step-info))
 348     (let ((bp-info (location-in-list step-info *breakpoints*)))
 349       (when bp-info
 350         (sb!di:activate-breakpoint (breakpoint-info-breakpoint bp-info)))))
 351   (let ((*stack-top-hint* current-frame)
 352         (step-hit-info
 353          (location-in-list (sb!di:breakpoint-what breakpoint)
 354                            *step-breakpoints*
 355                            (sb!di:breakpoint-kind breakpoint)))
 356         (bp-hit-info
 357          (location-in-list (sb!di:breakpoint-what breakpoint)
 358                            *breakpoints*
 359                            (sb!di:breakpoint-kind breakpoint)))
 360         (break)
 361         (condition)
 362         (string ""))
 363     (setf *step-breakpoints* nil)
 364     (labels ((build-string (str)
 365                (setf string (concatenate 'string string str)))
 366              (print-common-info ()
 367                (build-string
 368                 (with-output-to-string (*standard-output*)
 369                   (when fun-end-cookie
 370                     (format t "~%Return values: ~S" return-vals))
 371                   (when condition
 372                     (when (breakpoint-info-print bp-hit-info)
 373                       (format t "~%")
 374                       (print-frame-call current-frame))
 375                     (dolist (print (breakpoint-info-print bp-hit-info))
 376                       (format t "~& ~S = ~S" (rest print)
 377                               (funcall (first print) current-frame))))))))
 378       (when bp-hit-info
 379         (setf break (funcall (breakpoint-info-break bp-hit-info)
 380                              current-frame))
 381         (setf condition (funcall (breakpoint-info-condition bp-hit-info)
 382                                  current-frame)))
 383       (cond ((and bp-hit-info step-hit-info (= 1 *number-of-steps*))
 384              (build-string (format nil "~&*Step (to a breakpoint)*"))
 385              (print-common-info)
 386              (break string))
 387             ((and bp-hit-info step-hit-info break)
 388              (build-string (format nil "~&*Step (to a breakpoint)*"))
 389              (print-common-info)
 390              (break string))
 391             ((and bp-hit-info step-hit-info)
 392              (print-common-info)
 393              (format t "~A" string)
 394              (decf *number-of-steps*)
 395              (set-step-breakpoint current-frame))
 396             ((and step-hit-info (= 1 *number-of-steps*))
 397              (build-string "*Step*")
 398              (break (make-condition 'step-condition :format-control string)))
 399             (step-hit-info
 400              (decf *number-of-steps*)
 401              (set-step-breakpoint current-frame))
 402             (bp-hit-info
 403              (when break
 404                (build-string (format nil "~&*Breakpoint hit*")))
 405              (print-common-info)
 406              (if break
 407                  (break string)
 408                  (format t "~A" string)))
 409             (t
 410              (break "unknown breakpoint"))))))
 411 \f
 412 ;;; Set breakpoints at the next possible code-locations. After calling
 413 ;;; this, either (CONTINUE) if in the debugger or just let program flow
 414 ;;; return if in a hook function.
 415 (defun set-step-breakpoint (frame)
 416   (cond
 417    ((sb!di:debug-block-elsewhere-p (sb!di:code-location-debug-block
 418                                     (sb!di:frame-code-location frame)))
 419     ;; FIXME: FORMAT T is used for error output here and elsewhere in
 420     ;; the debug code.
 421     (format t "cannot step, in elsewhere code~%"))
 422    (t
 423     (let* ((code-location (sb!di:frame-code-location frame))
 424            (next-code-locations (next-code-locations code-location)))
 425       (cond
 426        (next-code-locations
 427         (dolist (code-location next-code-locations)
 428           (let ((bp-info (location-in-list code-location *breakpoints*)))
 429             (when bp-info
 430               (sb!di:deactivate-breakpoint (breakpoint-info-breakpoint
 431                                             bp-info))))
 432           (let ((bp (sb!di:make-breakpoint #'main-hook-fun code-location
 433                                            :kind :code-location)))
 434             (sb!di:activate-breakpoint bp)
 435             (push (create-breakpoint-info code-location bp 0)
 436                   *step-breakpoints*))))
 437        (t
 438         (let* ((debug-fun (sb!di:frame-debug-fun *current-frame*))
 439                (bp (sb!di:make-breakpoint #'main-hook-fun debug-fun
 440                                           :kind :fun-end)))
 441           (sb!di:activate-breakpoint bp)
 442           (push (create-breakpoint-info debug-fun bp 0)
 443                 *step-breakpoints*))))))))
 444 \f
 445 ;;;; STEP
 446
 447 ;;; ANSI specifies that this macro shall exist, even if only as a
 448 ;;; trivial placeholder like this.
 449 (defmacro step (form)
 450   "This is a trivial placeholder implementation of the CL:STEP macro required
 451    by the ANSI spec, simply expanding to `(LET () ,FORM). A more featureful
 452    version would be welcome, we just haven't written it."
 453   `(let ()
 454      ,form))
 455 \f
 456 ;;;; BACKTRACE
 457
 458 (defun backtrace (&optional (count most-positive-fixnum)
 459                             (*standard-output* *debug-io*))
 460   #!+sb-doc
 461   "Show a listing of the call stack going down from the current frame. In the
 462    debugger, the current frame is indicated by the prompt. COUNT is how many
 463    frames to show."
 464   (fresh-line *standard-output*)
 465   (do ((frame (if *in-the-debugger* *current-frame* (sb!di:top-frame))
 466               (sb!di:frame-down frame))
 467        (count count (1- count)))
 468       ((or (null frame) (zerop count)))
 469     (print-frame-call frame :number t))
 470   (fresh-line *standard-output*)
 471   (values))
 472
 473 (defun backtrace-as-list (&optional (count most-positive-fixnum))
 474   #!+sb-doc "Return a list representing the current BACKTRACE."
 475   (do ((reversed-result nil)
 476        (frame (if *in-the-debugger* *current-frame* (sb!di:top-frame))
 477               (sb!di:frame-down frame))
 478        (count count (1- count)))
 479       ((or (null frame) (zerop count))
 480        (nreverse reversed-result))
 481     (push (frame-call-as-list frame) reversed-result)))
 482
 483 (defun frame-call-as-list (frame)
 484   (cons (sb!di:debug-fun-name (sb!di:frame-debug-fun frame))
 485         (frame-args-as-list frame)))
 486 \f
 487 ;;;; frame printing
 488
 489 (eval-when (:compile-toplevel :execute)
 490
 491 ;;; This is a convenient way to express what to do for each type of
 492 ;;; lambda-list element.
 493 (sb!xc:defmacro lambda-list-element-dispatch (element
 494                                               &key
 495                                               required
 496                                               optional
 497                                               rest
 498                                               keyword
 499                                               deleted)
 500   `(etypecase ,element
 501      (sb!di:debug-var
 502       ,@required)
 503      (cons
 504       (ecase (car ,element)
 505         (:optional ,@optional)
 506         (:rest ,@rest)
 507         (:keyword ,@keyword)))
 508      (symbol
 509       (aver (eq ,element :deleted))
 510       ,@deleted)))
 511
 512 (sb!xc:defmacro lambda-var-dispatch (variable location deleted valid other)
 513   (let ((var (gensym)))
 514     `(let ((,var ,variable))
 515        (cond ((eq ,var :deleted) ,deleted)
 516              ((eq (sb!di:debug-var-validity ,var ,location) :valid)
 517               ,valid)
 518              (t ,other)))))
 519
 520 ) ; EVAL-WHEN
 521
 522 ;;; This is used in constructing arg lists for debugger printing when
 523 ;;; the arg list is unavailable, some arg is unavailable or unused, etc.
 524 (defstruct (unprintable-object
 525             (:constructor make-unprintable-object (string))
 526             (:print-object (lambda (x s)
 527                              (print-unreadable-object (x s)
 528                                (write-string (unprintable-object-string x)
 529                                              s))))
 530             (:copier nil))
 531   string)
 532
 533 ;;; Extract the function argument values for a debug frame.
 534 (defun frame-args-as-list (frame)
 535   (let ((debug-fun (sb!di:frame-debug-fun frame))
 536         (loc (sb!di:frame-code-location frame))
 537         (reversed-result nil))
 538     (handler-case
 539         (progn
 540           (dolist (ele (sb!di:debug-fun-lambda-list debug-fun))
 541             (lambda-list-element-dispatch ele
 542              :required ((push (frame-call-arg ele loc frame) reversed-result))
 543              :optional ((push (frame-call-arg (second ele) loc frame)
 544                               reversed-result))
 545              :keyword ((push (second ele) reversed-result)
 546                        (push (frame-call-arg (third ele) loc frame)
 547                              reversed-result))
 548              :deleted ((push (frame-call-arg ele loc frame) reversed-result))
 549              :rest ((lambda-var-dispatch (second ele) loc
 550                      nil
 551                      (progn
 552                        (setf reversed-result
 553                              (append (reverse (sb!di:debug-var-value
 554                                                (second ele) frame))
 555                                      reversed-result))
 556                        (return))
 557                      (push (make-unprintable-object
 558                             "unavailable &REST argument")
 559                      reversed-result)))))
 560           ;; As long as we do an ordinary return (as opposed to SIGNALing
 561           ;; a CONDITION) from the DOLIST above:
 562           (nreverse reversed-result))
 563       (sb!di:lambda-list-unavailable
 564        ()
 565        (make-unprintable-object "unavailable lambda list")))))
 566
 567 ;;; Print FRAME with verbosity level 1. If we hit a &REST arg, then
 568 ;;; print as many of the values as possible, punting the loop over
 569 ;;; lambda-list variables since any other arguments will be in the
 570 ;;; &REST arg's list of values.
 571 (defun print-frame-call-1 (frame)
 572   (let ((debug-fun (sb!di:frame-debug-fun frame)))
 573
 574     (pprint-logical-block (*standard-output* nil :prefix "(" :suffix ")")
 575       (let ((args (ensure-printable-object (frame-args-as-list frame))))
 576         ;; Since we go to some trouble to make nice informative function
 577         ;; names like (PRINT-OBJECT :AROUND (CLOWN T)), let's make sure
 578         ;; that they aren't truncated by *PRINT-LENGTH* and *PRINT-LEVEL*.
 579         (let ((*print-length* nil)
 580               (*print-level* nil))
 581           (prin1 (ensure-printable-object (sb!di:debug-fun-name debug-fun))))
 582         ;; For the function arguments, we can just print normally.
 583         (if (listp args)
 584             (format t "~{ ~_~S~}" args)
 585             (format t " ~S" args))))
 586
 587     (when (sb!di:debug-fun-kind debug-fun)
 588       (write-char #\[)
 589       (prin1 (sb!di:debug-fun-kind debug-fun))
 590       (write-char #\]))))
 591
 592 (defun ensure-printable-object (object)
 593   (handler-case
 594       (with-open-stream (out (make-broadcast-stream))
 595         (prin1 object out)
 596         object)
 597     (error (cond)
 598       (declare (ignore cond))
 599       (make-unprintable-object "error printing object"))))
 600
 601 (defun frame-call-arg (var location frame)
 602   (lambda-var-dispatch var location
 603     (make-unprintable-object "unused argument")
 604     (sb!di:debug-var-value var frame)
 605     (make-unprintable-object "unavailable argument")))
 606
 607 ;;; Prints a representation of the function call causing FRAME to
 608 ;;; exist. VERBOSITY indicates the level of information to output;
 609 ;;; zero indicates just printing the DEBUG-FUN's name, and one
 610 ;;; indicates displaying call-like, one-liner format with argument
 611 ;;; values.
 612 (defun print-frame-call (frame &key (verbosity 1) (number nil))
 613   (cond
 614    ((zerop verbosity)
 615     (when number
 616       (format t "~&~S: " (sb!di:frame-number frame)))
 617     (format t "~S" frame))
 618    (t
 619     (when number
 620       (format t "~&~S: " (sb!di:frame-number frame)))
 621     (print-frame-call-1 frame)))
 622   (when (>= verbosity 2)
 623     (let ((loc (sb!di:frame-code-location frame)))
 624       (handler-case
 625           (progn
 626             (sb!di:code-location-debug-block loc)
 627             (format t "~%source: ")
 628             (print-code-location-source-form loc 0))
 629         (sb!di:debug-condition (ignore) ignore)
 630         (error (c) (format t "error finding source: ~A" c))))))
 631 \f
 632 ;;;; INVOKE-DEBUGGER
 633
 634 (defvar *debugger-hook* nil
 635   #!+sb-doc
 636   "This is either NIL or a function of two arguments, a condition and the value
 637    of *DEBUGGER-HOOK*. This function can either handle the condition or return
 638    which causes the standard debugger to execute. The system passes the value
 639    of this variable to the function because it binds *DEBUGGER-HOOK* to NIL
 640    around the invocation.")
 641
 642 ;;; These are bound on each invocation of INVOKE-DEBUGGER.
 643 (defvar *debug-restarts*)
 644 (defvar *debug-condition*)
 645 (defvar *nested-debug-condition*)
 646
 647 ;;; the ordinary ANSI case of INVOKE-DEBUGGER, when not suppressed by
 648 ;;; command-line --disable-debugger option
 649 (defun invoke-debugger/enabled (condition)
 650   #!+sb-doc
 651   "Enter the debugger."
 652   (let ((old-hook *debugger-hook*))
 653     (when old-hook
 654       (let ((*debugger-hook* nil))
 655         (funcall old-hook condition old-hook))))
 656
 657   ;; If we're a background thread and *background-threads-wait-for-debugger*
 658   ;; is NIL, this will invoke a restart
 659
 660   ;; Note: CMU CL had (SB-UNIX:UNIX-SIGSETMASK 0) here. I deleted it
 661   ;; around sbcl-0.7.8.5 (by which time it had mutated to have a
 662   ;; #!-SUNOS prefix and a FIXME note observing that it wasn't needed
 663   ;; on SunOS and no one knew why it was needed anywhere else either).
 664   ;; So if something mysteriously breaks that has worked since the CMU
 665   ;; CL days, that might be why. -- WHN 2002-09-28
 666
 667   ;; We definitely want *PACKAGE* to be of valid type.
 668   ;;
 669   ;; Elsewhere in the system, we use the SANE-PACKAGE function for
 670   ;; this, but here causing an exception just as we're trying to handle
 671   ;; an exception would be confusing, so instead we use a special hack.
 672   (unless (and (packagep *package*)
 673                (package-name *package*))
 674     (setf *package* (find-package :cl-user))
 675     (format *error-output*
 676             "The value of ~S was not an undeleted PACKAGE. It has been
 677 reset to ~S."
 678             '*package* *package*))
 679
 680   ;; Try to force the other special variables into a useful state.
 681   (let (;; Protect from WITH-STANDARD-IO-SYNTAX some variables where
 682         ;; any default we might use is less useful than just reusing
 683         ;; the global values.
 684         (original-package *package*)
 685         (original-print-pretty *print-pretty*))
 686     (with-standard-io-syntax
 687      (let ((*debug-condition* condition)
 688            (*debug-restarts* (compute-restarts condition))
 689            (*nested-debug-condition* nil)
 690            ;; We want the printer and reader to be in a useful state,
 691            ;; regardless of where the debugger was invoked in the
 692            ;; program. WITH-STANDARD-IO-SYNTAX did much of what we
 693            ;; want, but
 694            ;;   * It doesn't affect our internal special variables
 695            ;;     like *CURRENT-LEVEL-IN-PRINT*.
 696            ;;   * It isn't customizable.
 697            ;;   * It doesn't set *PRINT-READABLY* to the same value
 698            ;;     as the toplevel default.
 699            ;;   * It sets *PACKAGE* to COMMON-LISP-USER, which is not
 700            ;;     helpful behavior for a debugger.
 701            ;;   * There's no particularly good debugger default for
 702            ;;     *PRINT-PRETTY*, since T is usually what you want
 703            ;;     -- except absolutely not what you want when you're
 704            ;;     debugging failures in PRINT-OBJECT logic.
 705            ;; We try to address all these issues with explicit
 706            ;; rebindings here.
 707            (sb!kernel:*current-level-in-print* 0)
 708            (*print-length* *debug-print-length*)
 709            (*print-level* *debug-print-level*)
 710            (*readtable* *debug-readtable*)
 711            (*print-readably* nil)
 712            (*package* original-package)
 713            (background-p nil)
 714            (*print-pretty* original-print-pretty))
 715
 716        ;; Before we start our own output, finish any pending output.
 717        ;; Otherwise, if the user tried to track the progress of his
 718        ;; program using PRINT statements, he'd tend to lose the last
 719        ;; line of output or so, which'd be confusing.
 720        (flush-standard-output-streams)
 721
 722        ;; (The initial output here goes to *ERROR-OUTPUT*, because the
 723        ;; initial output is not interactive, just an error message,
 724        ;; and when people redirect *ERROR-OUTPUT*, they could
 725        ;; reasonably expect to see error messages logged there,
 726        ;; regardless of what the debugger does afterwards.)
 727        (handler-case
 728            (format *error-output*
 729                    "~2&~@<debugger invoked on condition of type ~S in thread ~A: ~
 730                     ~2I~_~A~:>~%"
 731                    (type-of *debug-condition*)
 732                    (sb!thread:current-thread-id)
 733                    *debug-condition*)
 734          (error (condition)
 735            (setf *nested-debug-condition* condition)
 736            (let ((ndc-type (type-of *nested-debug-condition*)))
 737              (format *error-output*
 738                      "~&~@<(A ~S was caught when trying to print ~S when ~
 739                       entering the debugger. Printing was aborted and the ~
 740                       ~S was stored in ~S.)~@:>~%"
 741                      ndc-type
 742                      '*debug-condition*
 743                      ndc-type
 744                      '*nested-debug-condition*))
 745            (when (typep condition 'cell-error)
 746              ;; what we really want to know when it's e.g. an UNBOUND-VARIABLE:
 747              (format *error-output*
 748                      "~&(CELL-ERROR-NAME ~S) = ~S~%"
 749                      '*debug-condition*
 750                      (cell-error-name *debug-condition*)))))
 751
 752        ;; After the initial error/condition/whatever announcement to
 753        ;; *ERROR-OUTPUT*, we become interactive, and should talk on
 754        ;; *DEBUG-IO* from now on. (KLUDGE: This is a normative
 755        ;; statement, not a description of reality.:-| There's a lot of
 756        ;; older debugger code which was written to do i/o on whatever
 757        ;; stream was in fashion at the time, and not all of it has
 758        ;; been converted to behave this way. -- WHN 2000-11-16)
 759
 760        (setf background-p
 761              (sb!thread::debugger-wait-until-foreground-thread *debug-io*))
 762        (unwind-protect
 763        (let (;; FIXME: Rebinding *STANDARD-OUTPUT* here seems wrong,
 764              ;; violating the principle of least surprise, and making
 765              ;; it impossible for the user to do reasonable things
 766              ;; like using PRINT at the debugger prompt to send output
 767              ;; to the program's ordinary (possibly
 768              ;; redirected-to-a-file) *STANDARD-OUTPUT*. (CMU CL
 769              ;; used to rebind *STANDARD-INPUT* here too, but that's
 770              ;; been fixed already.)
 771              (*standard-output* *debug-io*)
 772              ;; This seems reasonable: e.g. if the user has redirected
 773              ;; *ERROR-OUTPUT* to some log file, it's probably wrong
 774              ;; to send errors which occur in interactive debugging to
 775              ;; that file, and right to send them to *DEBUG-IO*.
 776              (*error-output* *debug-io*))
 777          (unless (typep condition 'step-condition)
 778            (when *debug-beginner-help-p*
 779              (format *debug-io*
 780                      "~%~@<Within the debugger, you can type HELP for help. ~
 781                       At any command prompt (within the debugger or not) you ~
 782                       can type (SB-EXT:QUIT) to terminate the SBCL ~
 783                       executable. The condition which caused the debugger to ~
 784                       be entered is bound to ~S. You can suppress this ~
 785                       message by clearing ~S.~:@>~2%"
 786                      '*debug-condition*
 787                      '*debug-beginner-help-p*))
 788            (show-restarts *debug-restarts* *debug-io*))
 789               (internal-debug))
 790          (when background-p (sb!thread::release-foreground)))))))
 791
 792 ;;; the degenerate case of INVOKE-DEBUGGER, when ordinary ANSI behavior
 793 ;;; has been suppressed by command-line --disable-debugger option
 794 (defun invoke-debugger/disabled (condition)
 795   ;; There is no one there to interact with, so report the
 796   ;; condition and terminate the program.
 797   (flet ((failure-quit (&key recklessly-p)
 798            (/show0 "in FAILURE-QUIT (in --disable-debugger debugger hook)")
 799            (quit :unix-status 1 :recklessly-p recklessly-p)))
 800     ;; This HANDLER-CASE is here mostly to stop output immediately
 801     ;; (and fall through to QUIT) when there's an I/O error. Thus,
 802     ;; when we're run under a shell script or something, we can die
 803     ;; cleanly when the script dies (and our pipes are cut), instead
 804     ;; of falling into ldb or something messy like that. Similarly, we
 805     ;; can terminate cleanly even if BACKTRACE dies because of bugs in
 806     ;; user PRINT-OBJECT methods.
 807     (handler-case
 808         (progn
 809           (format *error-output*
 810                   "~&~@<unhandled condition (of type ~S): ~2I~_~A~:>~2%"
 811                   (type-of condition)
 812                   condition)
 813           ;; Flush *ERROR-OUTPUT* even before the BACKTRACE, so that
 814           ;; even if we hit an error within BACKTRACE (e.g. a bug in
 815           ;; the debugger's own frame-walking code, or a bug in a user
 816           ;; PRINT-OBJECT method) we'll at least have the CONDITION
 817           ;; printed out before we die.
 818           (finish-output *error-output*)
 819           ;; (Where to truncate the BACKTRACE is of course arbitrary, but
 820           ;; it seems as though we should at least truncate it somewhere.)
 821           (sb!debug:backtrace 128 *error-output*)
 822           (format
 823            *error-output*
 824            "~%unhandled condition in --disable-debugger mode, quitting~%")
 825           (finish-output *error-output*)
 826           (failure-quit))
 827       (condition ()
 828         ;; We IGNORE-ERRORS here because even %PRIMITIVE PRINT can
 829         ;; fail when our output streams are blown away, as e.g. when
 830         ;; we're running under a Unix shell script and it dies somehow
 831         ;; (e.g. because of a SIGINT). In that case, we might as well
 832         ;; just give it up for a bad job, and stop trying to notify
 833         ;; the user of anything.
 834         ;;
 835         ;; Actually, the only way I've run across to exercise the
 836         ;; problem is to have more than one layer of shell script.
 837         ;; I have a shell script which does
 838         ;;   time nice -10 sh make.sh "$1" 2>&1 | tee make.tmp
 839         ;; and the problem occurs when I interrupt this with Ctrl-C
 840         ;; under Linux 2.2.14-5.0 and GNU bash, version 1.14.7(1).
 841         ;; I haven't figured out whether it's bash, time, tee, Linux, or
 842         ;; what that is responsible, but that it's possible at all
 843         ;; means that we should IGNORE-ERRORS here. -- WHN 2001-04-24
 844         (ignore-errors
 845          (%primitive print
 846                      "Argh! error within --disable-debugger error handling"))
 847         (failure-quit :recklessly-p t)))))
 848
 849 ;;; halt-on-failures and prompt-on-failures modes, suitable for
 850 ;;; noninteractive and interactive use respectively
 851 (defun disable-debugger ()
 852   (setf (fdefinition 'invoke-debugger) #'invoke-debugger/disabled
 853         *debug-io* *error-output*))
 854 (defun enable-debugger ()
 855   (setf (fdefinition 'invoke-debugger) #'invoke-debugger/enabled
 856         *debug-io* *query-io*))
 857 ;;; The enabled mode is the ANSI default.
 858 (enable-debugger)
 859
 860 (defun show-restarts (restarts s)
 861   (cond ((null restarts)
 862          (format s
 863                  "~&(no restarts: If you didn't do this on purpose, ~
 864                   please report it as a bug.)~%"))
 865         (t
 866          (format s "~&restarts (invokable by number or by ~
 867                     possibly-abbreviated name):~%")
 868          (let ((count 0)
 869                (names-used '(nil))
 870                (max-name-len 0))
 871            (dolist (restart restarts)
 872              (let ((name (restart-name restart)))
 873                (when name
 874                  (let ((len (length (princ-to-string name))))
 875                    (when (> len max-name-len)
 876                      (setf max-name-len len))))))
 877            (unless (zerop max-name-len)
 878              (incf max-name-len 3))
 879            (dolist (restart restarts)
 880              (let ((name (restart-name restart)))
 881                (cond ((member name names-used)
 882                       (format s "~& ~2D: ~V@T~A~%" count max-name-len restart))
 883                      (t
 884                       (format s "~& ~2D: [~VA] ~A~%"
 885                               count (- max-name-len 3) name restart)
 886                       (push name names-used))))
 887              (incf count))))))
 888
 889 ;;; This calls DEBUG-LOOP, performing some simple initializations
 890 ;;; before doing so. INVOKE-DEBUGGER calls this to actually get into
 891 ;;; the debugger. SB!KERNEL::ERROR-ERROR calls this in emergencies
 892 ;;; to get into a debug prompt as quickly as possible with as little
 893 ;;; risk as possible for stepping on whatever is causing recursive
 894 ;;; errors.
 895 (defun internal-debug ()
 896   (let ((*in-the-debugger* t)
 897         (*read-suppress* nil))
 898     (unless (typep *debug-condition* 'step-condition)
 899       (clear-input *debug-io*))
 900     (funcall *debug-loop-fun*)))
 901 \f
 902 ;;;; DEBUG-LOOP
 903
 904 ;;; Note: This defaulted to T in CMU CL. The changed default in SBCL
 905 ;;; was motivated by desire to play nicely with ILISP.
 906 (defvar *flush-debug-errors* nil
 907   #!+sb-doc
 908   "When set, avoid calling INVOKE-DEBUGGER recursively when errors occur while
 909    executing in the debugger.")
 910
 911 (defun debug-loop-fun ()
 912   (let* ((*debug-command-level* (1+ *debug-command-level*))
 913          (*real-stack-top* (sb!di:top-frame))
 914          (*stack-top* (or *stack-top-hint* *real-stack-top*))
 915          (*stack-top-hint* nil)
 916          (*current-frame* *stack-top*))
 917     (handler-bind ((sb!di:debug-condition
 918                     (lambda (condition)
 919                       (princ condition *debug-io*)
 920                       (/show0 "handling d-c by THROWing DEBUG-LOOP-CATCHER")
 921                       (throw 'debug-loop-catcher nil))))
 922       (fresh-line)
 923       (print-frame-call *current-frame* :verbosity 2)
 924       (loop
 925         (catch 'debug-loop-catcher
 926           (handler-bind ((error (lambda (condition)
 927                                   (when *flush-debug-errors*
 928                                     (clear-input *debug-io*)
 929                                     (princ condition)
 930                                     ;; FIXME: Doing input on *DEBUG-IO*
 931                                     ;; and output on T seems broken.
 932                                     (format t
 933                                             "~&error flushed (because ~
 934                                              ~S is set)"
 935                                             '*flush-debug-errors*)
 936                                     (/show0 "throwing DEBUG-LOOP-CATCHER")
 937                                     (throw 'debug-loop-catcher nil)))))
 938             ;; We have to bind LEVEL for the restart function created by
 939             ;; WITH-SIMPLE-RESTART.
 940             (let ((level *debug-command-level*)
 941                   (restart-commands (make-restart-commands)))
 942               (with-simple-restart (abort
 943                                    "~@<Reduce debugger level (to debug level ~W).~@:>"
 944                                     level)
 945                 (debug-prompt *debug-io*)
 946                 (force-output *debug-io*)
 947                 (let* ((exp (read *debug-io*))
 948                        (cmd-fun (debug-command-p exp restart-commands)))
 949                   (cond ((not cmd-fun)
 950                          (debug-eval-print exp))
 951                         ((consp cmd-fun)
 952                          (format t "~&Your command, ~S, is ambiguous:~%"
 953                                  exp)
 954                          (dolist (ele cmd-fun)
 955                            (format t "   ~A~%" ele)))
 956                         (t
 957                          (funcall cmd-fun))))))))))))
 958
 959 (defvar *debug-loop-fun* #'debug-loop-fun
 960   "a function taking no parameters that starts the low-level debug loop")
 961
 962 ;;; FIXME: We could probably use INTERACTIVE-EVAL for much of this logic.
 963 (defun debug-eval-print (expr)
 964   (/noshow "entering DEBUG-EVAL-PRINT" expr)
 965   (/noshow (fboundp 'compile))
 966   (setq +++ ++ ++ + + - - expr)
 967   (let* ((values (multiple-value-list (eval -)))
 968          (*standard-output* *debug-io*))
 969     (/noshow "done with EVAL in DEBUG-EVAL-PRINT")
 970     (fresh-line)
 971     (if values (prin1 (car values)))
 972     (dolist (x (cdr values))
 973       (fresh-line)
 974       (prin1 x))
 975     (setq /// // // / / values)
 976     (setq *** ** ** * * (car values))
 977     ;; Make sure that nobody passes back an unbound marker.
 978     (unless (boundp '*)
 979       (setq * nil)
 980       (fresh-line)
 981       ;; FIXME: The way INTERACTIVE-EVAL does this seems better.
 982       (princ "Setting * to NIL (was unbound marker)."))))
 983 \f
 984 ;;;; debug loop functions
 985
 986 ;;; These commands are functions, not really commands, so that users
 987 ;;; can get their hands on the values returned.
 988
 989 (eval-when (:execute :compile-toplevel)
 990
 991 (sb!xc:defmacro define-var-operation (ref-or-set &optional value-var)
 992   `(let* ((temp (etypecase name
 993                   (symbol (sb!di:debug-fun-symbol-vars
 994                            (sb!di:frame-debug-fun *current-frame*)
 995                            name))
 996                   (simple-string (sb!di:ambiguous-debug-vars
 997                                   (sb!di:frame-debug-fun *current-frame*)
 998                                   name))))
 999           (location (sb!di:frame-code-location *current-frame*))
1000           ;; Let's only deal with valid variables.
1001           (vars (remove-if-not (lambda (v)
1002                                  (eq (sb!di:debug-var-validity v location)
1003                                      :valid))
1004                                temp)))
1005      (declare (list vars))
1006      (cond ((null vars)
1007             (error "No known valid variables match ~S." name))
1008            ((= (length vars) 1)
1009             ,(ecase ref-or-set
1010                (:ref
1011                 '(sb!di:debug-var-value (car vars) *current-frame*))
1012                (:set
1013                 `(setf (sb!di:debug-var-value (car vars) *current-frame*)
1014                        ,value-var))))
1015            (t
1016             ;; Since we have more than one, first see whether we have
1017             ;; any variables that exactly match the specification.
1018             (let* ((name (etypecase name
1019                            (symbol (symbol-name name))
1020                            (simple-string name)))
1021                    ;; FIXME: REMOVE-IF-NOT is deprecated, use STRING/=
1022                    ;; instead.
1023                    (exact (remove-if-not (lambda (v)
1024                                            (string= (sb!di:debug-var-symbol-name v)
1025                                                     name))
1026                                          vars))
1027                    (vars (or exact vars)))
1028               (declare (simple-string name)
1029                        (list exact vars))
1030               (cond
1031                ;; Check now for only having one variable.
1032                ((= (length vars) 1)
1033                 ,(ecase ref-or-set
1034                    (:ref
1035                     '(sb!di:debug-var-value (car vars) *current-frame*))
1036                    (:set
1037                     `(setf (sb!di:debug-var-value (car vars) *current-frame*)
1038                            ,value-var))))
1039                ;; If there weren't any exact matches, flame about
1040                ;; ambiguity unless all the variables have the same
1041                ;; name.
1042                ((and (not exact)
1043                      (find-if-not
1044                       (lambda (v)
1045                         (string= (sb!di:debug-var-symbol-name v)
1046                                  (sb!di:debug-var-symbol-name (car vars))))
1047                       (cdr vars)))
1048                 (error "specification ambiguous:~%~{   ~A~%~}"
1049                        (mapcar #'sb!di:debug-var-symbol-name
1050                                (delete-duplicates
1051                                 vars :test #'string=
1052                                 :key #'sb!di:debug-var-symbol-name))))
1053                ;; All names are the same, so see whether the user
1054                ;; ID'ed one of them.
1055                (id-supplied
1056                 (let ((v (find id vars :key #'sb!di:debug-var-id)))
1057                   (unless v
1058                     (error
1059                      "invalid variable ID, ~W: should have been one of ~S"
1060                      id
1061                      (mapcar #'sb!di:debug-var-id vars)))
1062                   ,(ecase ref-or-set
1063                      (:ref
1064                       '(sb!di:debug-var-value v *current-frame*))
1065                      (:set
1066                       `(setf (sb!di:debug-var-value v *current-frame*)
1067                              ,value-var)))))
1068                (t
1069                 (error "Specify variable ID to disambiguate ~S. Use one of ~S."
1070                        name
1071                        (mapcar #'sb!di:debug-var-id vars)))))))))
1072
1073 ) ; EVAL-WHEN
1074
1075 ;;; FIXME: This doesn't work. It would be real nice we could make it
1076 ;;; work! Alas, it doesn't seem to work in CMU CL X86 either..
1077 (defun var (name &optional (id 0 id-supplied))
1078   #!+sb-doc
1079   "Return a variable's value if possible. NAME is a simple-string or symbol.
1080    If it is a simple-string, it is an initial substring of the variable's name.
1081    If name is a symbol, it has the same name and package as the variable whose
1082    value this function returns. If the symbol is uninterned, then the variable
1083    has the same name as the symbol, but it has no package.
1084
1085    If name is the initial substring of variables with different names, then
1086    this return no values after displaying the ambiguous names. If name
1087    determines multiple variables with the same name, then you must use the
1088    optional id argument to specify which one you want. If you left id
1089    unspecified, then this returns no values after displaying the distinguishing
1090    id values.
1091
1092    The result of this function is limited to the availability of variable
1093    information. This is SETF'able."
1094   (define-var-operation :ref))
1095 (defun (setf var) (value name &optional (id 0 id-supplied))
1096   (define-var-operation :set value))
1097
1098 ;;; This returns the COUNT'th arg as the user sees it from args, the
1099 ;;; result of SB!DI:DEBUG-FUN-LAMBDA-LIST. If this returns a
1100 ;;; potential DEBUG-VAR from the lambda-list, then the second value is
1101 ;;; T. If this returns a keyword symbol or a value from a rest arg,
1102 ;;; then the second value is NIL.
1103 ;;;
1104 ;;; FIXME: There's probably some way to merge the code here with
1105 ;;; FRAME-ARGS-AS-LIST. (A fair amount of logic is already shared
1106 ;;; through LAMBDA-LIST-ELEMENT-DISPATCH, but I suspect more could be.)
1107 (declaim (ftype (function (index list)) nth-arg))
1108 (defun nth-arg (count args)
1109   (let ((n count))
1110     (dolist (ele args (error "The argument specification ~S is out of range."
1111                              n))
1112       (lambda-list-element-dispatch ele
1113         :required ((if (zerop n) (return (values ele t))))
1114         :optional ((if (zerop n) (return (values (second ele) t))))
1115         :keyword ((cond ((zerop n)
1116                          (return (values (second ele) nil)))
1117                         ((zerop (decf n))
1118                          (return (values (third ele) t)))))
1119         :deleted ((if (zerop n) (return (values ele t))))
1120         :rest ((let ((var (second ele)))
1121                  (lambda-var-dispatch var (sb!di:frame-code-location
1122                                            *current-frame*)
1123                    (error "unused &REST argument before n'th argument")
1124                    (dolist (value
1125                             (sb!di:debug-var-value var *current-frame*)
1126                             (error
1127                              "The argument specification ~S is out of range."
1128                              n))
1129                      (if (zerop n)
1130                          (return-from nth-arg (values value nil))
1131                          (decf n)))
1132                    (error "invalid &REST argument before n'th argument")))))
1133       (decf n))))
1134
1135 (defun arg (n)
1136   #!+sb-doc
1137   "Return the N'th argument's value if possible. Argument zero is the first
1138    argument in a frame's default printed representation. Count keyword/value
1139    pairs as separate arguments."
1140   (multiple-value-bind (var lambda-var-p)
1141       (nth-arg n (handler-case (sb!di:debug-fun-lambda-list
1142                                 (sb!di:frame-debug-fun *current-frame*))
1143                    (sb!di:lambda-list-unavailable ()
1144                      (error "No argument values are available."))))
1145     (if lambda-var-p
1146         (lambda-var-dispatch var (sb!di:frame-code-location *current-frame*)
1147           (error "Unused arguments have no values.")
1148           (sb!di:debug-var-value var *current-frame*)
1149           (error "invalid argument value"))
1150         var)))
1151 \f
1152 ;;;; machinery for definition of debug loop commands
1153
1154 (defvar *debug-commands* nil)
1155
1156 ;;; Interface to *DEBUG-COMMANDS*. No required arguments in args are
1157 ;;; permitted.
1158 (defmacro !def-debug-command (name args &rest body)
1159   (let ((fun-name (symbolicate name "-DEBUG-COMMAND")))
1160     `(progn
1161        (setf *debug-commands*
1162              (remove ,name *debug-commands* :key #'car :test #'string=))
1163        (defun ,fun-name ,args
1164          (unless *in-the-debugger*
1165            (error "invoking debugger command while outside the debugger"))
1166          ,@body)
1167        (push (cons ,name #',fun-name) *debug-commands*)
1168        ',fun-name)))
1169
1170 (defun !def-debug-command-alias (new-name existing-name)
1171   (let ((pair (assoc existing-name *debug-commands* :test #'string=)))
1172     (unless pair (error "unknown debug command name: ~S" existing-name))
1173     (push (cons new-name (cdr pair)) *debug-commands*))
1174   new-name)
1175
1176 ;;; This takes a symbol and uses its name to find a debugger command,
1177 ;;; using initial substring matching. It returns the command function
1178 ;;; if form identifies only one command, but if form is ambiguous,
1179 ;;; this returns a list of the command names. If there are no matches,
1180 ;;; this returns nil. Whenever the loop that looks for a set of
1181 ;;; possibilities encounters an exact name match, we return that
1182 ;;; command function immediately.
1183 (defun debug-command-p (form &optional other-commands)
1184   (if (or (symbolp form) (integerp form))
1185       (let* ((name
1186               (if (symbolp form)
1187                   (symbol-name form)
1188                   (format nil "~W" form)))
1189              (len (length name))
1190              (res nil))
1191         (declare (simple-string name)
1192                  (fixnum len)
1193                  (list res))
1194
1195         ;; Find matching commands, punting if exact match.
1196         (flet ((match-command (ele)
1197                  (let* ((str (car ele))
1198                         (str-len (length str)))
1199                    (declare (simple-string str)
1200                             (fixnum str-len))
1201                    (cond ((< str-len len))
1202                          ((= str-len len)
1203                           (when (string= name str :end1 len :end2 len)
1204                             (return-from debug-command-p (cdr ele))))
1205                          ((string= name str :end1 len :end2 len)
1206                           (push ele res))))))
1207           (mapc #'match-command *debug-commands*)
1208           (mapc #'match-command other-commands))
1209
1210         ;; Return the right value.
1211         (cond ((not res) nil)
1212               ((= (length res) 1)
1213                (cdar res))
1214               (t ; Just return the names.
1215                (do ((cmds res (cdr cmds)))
1216                    ((not cmds) res)
1217                  (setf (car cmds) (caar cmds))))))))
1218
1219 ;;; Return a list of debug commands (in the same format as
1220 ;;; *DEBUG-COMMANDS*) that invoke each active restart.
1221 ;;;
1222 ;;; Two commands are made for each restart: one for the number, and
1223 ;;; one for the restart name (unless it's been shadowed by an earlier
1224 ;;; restart of the same name, or it is NIL).
1225 (defun make-restart-commands (&optional (restarts *debug-restarts*))
1226   (let ((commands)
1227         (num 0))                        ; better be the same as show-restarts!
1228     (dolist (restart restarts)
1229       (let ((name (string (restart-name restart))))
1230         (let ((restart-fun
1231                 (lambda ()
1232                   (/show0 "in restart-command closure, about to i-r-i")
1233                   (invoke-restart-interactively restart))))
1234           (push (cons (prin1-to-string num) restart-fun) commands)
1235           (unless (or (null (restart-name restart))
1236                       (find name commands :key #'car :test #'string=))
1237             (push (cons name restart-fun) commands))))
1238     (incf num))
1239   commands))
1240 \f
1241 ;;;; frame-changing commands
1242
1243 (!def-debug-command "UP" ()
1244   (let ((next (sb!di:frame-up *current-frame*)))
1245     (cond (next
1246            (setf *current-frame* next)
1247            (print-frame-call next))
1248           (t
1249            (format t "~&Top of stack.")))))
1250
1251 (!def-debug-command "DOWN" ()
1252   (let ((next (sb!di:frame-down *current-frame*)))
1253     (cond (next
1254            (setf *current-frame* next)
1255            (print-frame-call next))
1256           (t
1257            (format t "~&Bottom of stack.")))))
1258
1259 (!def-debug-command-alias "D" "DOWN")
1260
1261 ;;; CMU CL had this command, but SBCL doesn't, since it's redundant
1262 ;;; with "FRAME 0", and it interferes with abbreviations for the
1263 ;;; TOPLEVEL restart.
1264 ;;;(!def-debug-command "TOP" ()
1265 ;;;  (do ((prev *current-frame* lead)
1266 ;;;       (lead (sb!di:frame-up *current-frame*) (sb!di:frame-up lead)))
1267 ;;;      ((null lead)
1268 ;;;       (setf *current-frame* prev)
1269 ;;;       (print-frame-call prev))))
1270
1271 (!def-debug-command "BOTTOM" ()
1272   (do ((prev *current-frame* lead)
1273        (lead (sb!di:frame-down *current-frame*) (sb!di:frame-down lead)))
1274       ((null lead)
1275        (setf *current-frame* prev)
1276        (print-frame-call prev))))
1277
1278 (!def-debug-command-alias "B" "BOTTOM")
1279
1280 (!def-debug-command "FRAME" (&optional
1281                              (n (read-prompting-maybe "frame number: ")))
1282   (setf *current-frame*
1283         (multiple-value-bind (next-frame-fun limit-string)
1284             (if (< n (sb!di:frame-number *current-frame*))
1285                 (values #'sb!di:frame-up "top")
1286               (values #'sb!di:frame-down "bottom"))
1287           (do ((frame *current-frame*))
1288               ((= n (sb!di:frame-number frame))
1289                frame)
1290             (let ((next-frame (funcall next-frame-fun frame)))
1291               (cond (next-frame
1292                      (setf frame next-frame))
1293                     (t
1294                      (format t
1295                              "The ~A of the stack was encountered.~%"
1296                              limit-string)
1297                      (return frame)))))))
1298   (print-frame-call *current-frame*))
1299
1300 (!def-debug-command-alias "F" "FRAME")
1301 \f
1302 ;;;; commands for entering and leaving the debugger
1303
1304 ;;; CMU CL supported this QUIT debug command, but SBCL provides this
1305 ;;; functionality with a restart instead. (The QUIT debug command was
1306 ;;; removed because it's confusing to have "quit" mean two different
1307 ;;; things in the system, "restart the top level REPL" in the debugger
1308 ;;; and "terminate the Lisp system" as the SB-EXT:QUIT function.)
1309 ;;;
1310 ;;;(!def-debug-command "QUIT" ()
1311 ;;;  (throw 'sb!impl::toplevel-catcher nil))
1312
1313 ;;; CMU CL supported this GO debug command, but SBCL doesn't -- in
1314 ;;; SBCL you just type the CONTINUE restart name instead (or "C" or
1315 ;;; "RESTART CONTINUE", that's OK too).
1316 ;;;(!def-debug-command "GO" ()
1317 ;;;  (continue *debug-condition*)
1318 ;;;  (error "There is no restart named CONTINUE."))
1319
1320 (!def-debug-command "RESTART" ()
1321   (/show0 "doing RESTART debug-command")
1322   (let ((num (read-if-available :prompt)))
1323     (when (eq num :prompt)
1324       (show-restarts *debug-restarts* *debug-io*)
1325       (write-string "restart: ")
1326       (force-output)
1327       (setf num (read *debug-io*)))
1328     (let ((restart (typecase num
1329                      (unsigned-byte
1330                       (nth num *debug-restarts*))
1331                      (symbol
1332                       (find num *debug-restarts* :key #'restart-name
1333                             :test (lambda (sym1 sym2)
1334                                     (string= (symbol-name sym1)
1335                                              (symbol-name sym2)))))
1336                      (t
1337                       (format t "~S is invalid as a restart name.~%" num)
1338                       (return-from restart-debug-command nil)))))
1339       (/show0 "got RESTART")
1340       (if restart
1341           (invoke-restart-interactively restart)
1342           ;; FIXME: Even if this isn't handled by WARN, it probably
1343           ;; shouldn't go to *STANDARD-OUTPUT*, but *ERROR-OUTPUT* or
1344           ;; *QUERY-IO* or something. Look through this file to
1345           ;; straighten out stream usage.
1346           (princ "There is no such restart.")))))
1347 \f
1348 ;;;; information commands
1349
1350 (!def-debug-command "HELP" ()
1351   ;; CMU CL had a little toy pager here, but "if you aren't running
1352   ;; ILISP (or a smart windowing system, or something) you deserve to
1353   ;; lose", so we've dropped it in SBCL. However, in case some
1354   ;; desperate holdout is running this on a dumb terminal somewhere,
1355   ;; we tell him where to find the message stored as a string.
1356   (format *debug-io*
1357           "~&~A~2%(The HELP string is stored in ~S.)~%"
1358           *debug-help-string*
1359           '*debug-help-string*))
1360
1361 (!def-debug-command-alias "?" "HELP")
1362
1363 (!def-debug-command "ERROR" ()
1364   (format *debug-io* "~A~%" *debug-condition*)
1365   (show-restarts *debug-restarts* *debug-io*))
1366
1367 (!def-debug-command "BACKTRACE" ()
1368   (backtrace (read-if-available most-positive-fixnum)))
1369
1370 (!def-debug-command "PRINT" ()
1371   (print-frame-call *current-frame*))
1372
1373 (!def-debug-command-alias "P" "PRINT")
1374
1375 (!def-debug-command "LIST-LOCALS" ()
1376   (let ((d-fun (sb!di:frame-debug-fun *current-frame*)))
1377     (if (sb!di:debug-var-info-available d-fun)
1378         (let ((*standard-output* *debug-io*)
1379               (location (sb!di:frame-code-location *current-frame*))
1380               (prefix (read-if-available nil))
1381               (any-p nil)
1382               (any-valid-p nil))
1383           (dolist (v (sb!di:ambiguous-debug-vars
1384                         d-fun
1385                         (if prefix (string prefix) "")))
1386             (setf any-p t)
1387             (when (eq (sb!di:debug-var-validity v location) :valid)
1388               (setf any-valid-p t)
1389               (format t "~S~:[#~W~;~*~]  =  ~S~%"
1390                       (sb!di:debug-var-symbol v)
1391                       (zerop (sb!di:debug-var-id v))
1392                       (sb!di:debug-var-id v)
1393                       (sb!di:debug-var-value v *current-frame*))))
1394
1395           (cond
1396            ((not any-p)
1397             (format t "There are no local variables ~@[starting with ~A ~]~
1398                        in the function."
1399                     prefix))
1400            ((not any-valid-p)
1401             (format t "All variables ~@[starting with ~A ~]currently ~
1402                        have invalid values."
1403                     prefix))))
1404         (write-line "There is no variable information available."))))
1405
1406 (!def-debug-command-alias "L" "LIST-LOCALS")
1407
1408 (!def-debug-command "SOURCE" ()
1409   (fresh-line)
1410   (print-code-location-source-form (sb!di:frame-code-location *current-frame*)
1411                                    (read-if-available 0)))
1412 \f
1413 ;;;; source location printing
1414
1415 ;;; We cache a stream to the last valid file debug source so that we
1416 ;;; won't have to repeatedly open the file.
1417 ;;;
1418 ;;; KLUDGE: This sounds like a bug, not a feature. Opening files is fast
1419 ;;; in the 1990s, so the benefit is negligible, less important than the
1420 ;;; potential of extra confusion if someone changes the source during
1421 ;;; a debug session and the change doesn't show up. And removing this
1422 ;;; would simplify the system, which I like. -- WHN 19990903
1423 (defvar *cached-debug-source* nil)
1424 (declaim (type (or sb!di:debug-source null) *cached-debug-source*))
1425 (defvar *cached-source-stream* nil)
1426 (declaim (type (or stream null) *cached-source-stream*))
1427
1428 ;;; To suppress the read-time evaluation #. macro during source read,
1429 ;;; *READTABLE* is modified. *READTABLE* is cached to avoid
1430 ;;; copying it each time, and invalidated when the
1431 ;;; *CACHED-DEBUG-SOURCE* has changed.
1432 (defvar *cached-readtable* nil)
1433 (declaim (type (or readtable null) *cached-readtable*))
1434
1435 (pushnew (lambda ()
1436            (setq *cached-debug-source* nil *cached-source-stream* nil
1437                  *cached-readtable* nil))
1438          *before-save-initializations*)
1439
1440 ;;; We also cache the last toplevel form that we printed a source for
1441 ;;; so that we don't have to do repeated reads and calls to
1442 ;;; FORM-NUMBER-TRANSLATIONS.
1443 (defvar *cached-toplevel-form-offset* nil)
1444 (declaim (type (or index null) *cached-toplevel-form-offset*))
1445 (defvar *cached-toplevel-form*)
1446 (defvar *cached-form-number-translations*)
1447
1448 ;;; Given a code location, return the associated form-number
1449 ;;; translations and the actual top level form. We check our cache ---
1450 ;;; if there is a miss, we dispatch on the kind of the debug source.
1451 (defun get-toplevel-form (location)
1452   (let ((d-source (sb!di:code-location-debug-source location)))
1453     (if (and (eq d-source *cached-debug-source*)
1454              (eql (sb!di:code-location-toplevel-form-offset location)
1455                   *cached-toplevel-form-offset*))
1456         (values *cached-form-number-translations* *cached-toplevel-form*)
1457         (let* ((offset (sb!di:code-location-toplevel-form-offset location))
1458                (res
1459                 (ecase (sb!di:debug-source-from d-source)
1460                   (:file (get-file-toplevel-form location))
1461                   (:lisp (svref (sb!di:debug-source-name d-source) offset)))))
1462           (setq *cached-toplevel-form-offset* offset)
1463           (values (setq *cached-form-number-translations*
1464                         (sb!di:form-number-translations res offset))
1465                   (setq *cached-toplevel-form* res))))))
1466
1467 ;;; Locate the source file (if it still exists) and grab the top level
1468 ;;; form. If the file is modified, we use the top level form offset
1469 ;;; instead of the recorded character offset.
1470 (defun get-file-toplevel-form (location)
1471   (let* ((d-source (sb!di:code-location-debug-source location))
1472          (tlf-offset (sb!di:code-location-toplevel-form-offset location))
1473          (local-tlf-offset (- tlf-offset
1474                               (sb!di:debug-source-root-number d-source)))
1475          (char-offset
1476           (aref (or (sb!di:debug-source-start-positions d-source)
1477                     (error "no start positions map"))
1478                 local-tlf-offset))
1479          (name (sb!di:debug-source-name d-source)))
1480     (unless (eq d-source *cached-debug-source*)
1481       (unless (and *cached-source-stream*
1482                    (equal (pathname *cached-source-stream*)
1483                           (pathname name)))
1484         (setq *cached-readtable* nil)
1485         (when *cached-source-stream* (close *cached-source-stream*))
1486         (setq *cached-source-stream* (open name :if-does-not-exist nil))
1487         (unless *cached-source-stream*
1488           (error "The source file no longer exists:~%  ~A" (namestring name)))
1489         (format t "~%; file: ~A~%" (namestring name)))
1490
1491         (setq *cached-debug-source*
1492               (if (= (sb!di:debug-source-created d-source)
1493                      (file-write-date name))
1494                   d-source nil)))
1495
1496     (cond
1497      ((eq *cached-debug-source* d-source)
1498       (file-position *cached-source-stream* char-offset))
1499      (t
1500       (format t "~%; File has been modified since compilation:~%;   ~A~@
1501                  ; Using form offset instead of character position.~%"
1502               (namestring name))
1503       (file-position *cached-source-stream* 0)
1504       (let ((*read-suppress* t))
1505         (dotimes (i local-tlf-offset)
1506           (read *cached-source-stream*)))))
1507     (unless *cached-readtable*
1508       (setq *cached-readtable* (copy-readtable))
1509       (set-dispatch-macro-character
1510        #\# #\.
1511        (lambda (stream sub-char &rest rest)
1512          (declare (ignore rest sub-char))
1513          (let ((token (read stream t nil t)))
1514            (format nil "#.~S" token)))
1515        *cached-readtable*))
1516     (let ((*readtable* *cached-readtable*))
1517       (read *cached-source-stream*))))
1518
1519 (defun print-code-location-source-form (location context)
1520   (let* ((location (maybe-block-start-location location))
1521          (form-num (sb!di:code-location-form-number location)))
1522     (multiple-value-bind (translations form) (get-toplevel-form location)
1523       (unless (< form-num (length translations))
1524         (error "The source path no longer exists."))
1525       (prin1 (sb!di:source-path-context form
1526                                         (svref translations form-num)
1527                                         context)))))
1528 \f
1529 ;;; breakpoint and step commands
1530
1531 ;;; Step to the next code-location.
1532 (!def-debug-command "STEP" ()
1533   (setf *number-of-steps* (read-if-available 1))
1534   (set-step-breakpoint *current-frame*)
1535   (continue *debug-condition*)
1536   (error "couldn't continue"))
1537
1538 ;;; List possible breakpoint locations, which ones are active, and
1539 ;;; where the CONTINUE restart will transfer control. Set
1540 ;;; *POSSIBLE-BREAKPOINTS* to the code-locations which can then be
1541 ;;; used by sbreakpoint.
1542 (!def-debug-command "LIST-LOCATIONS" ()
1543   (let ((df (read-if-available *default-breakpoint-debug-fun*)))
1544     (cond ((consp df)
1545            (setf df (sb!di:fun-debug-fun (eval df)))
1546            (setf *default-breakpoint-debug-fun* df))
1547           ((or (eq ':c df)
1548                (not *default-breakpoint-debug-fun*))
1549            (setf df (sb!di:frame-debug-fun *current-frame*))
1550            (setf *default-breakpoint-debug-fun* df)))
1551     (setf *possible-breakpoints* (possible-breakpoints df)))
1552   (let ((continue-at (sb!di:frame-code-location *current-frame*)))
1553     (let ((active (location-in-list *default-breakpoint-debug-fun*
1554                                     *breakpoints* :fun-start))
1555           (here (sb!di:code-location=
1556                  (sb!di:debug-fun-start-location
1557                   *default-breakpoint-debug-fun*) continue-at)))
1558       (when (or active here)
1559         (format t "::FUN-START ")
1560         (when active (format t " *Active*"))
1561         (when here (format t " *Continue here*"))))
1562
1563     (let ((prev-location nil)
1564           (prev-num 0)
1565           (this-num 0))
1566       (flet ((flush ()
1567                (when prev-location
1568                  (let ((this-num (1- this-num)))
1569                    (if (= prev-num this-num)
1570                        (format t "~&~W: " prev-num)
1571                        (format t "~&~W-~W: " prev-num this-num)))
1572                  (print-code-location-source-form prev-location 0)
1573                  (when *print-location-kind*
1574                    (format t "~S " (sb!di:code-location-kind prev-location)))
1575                  (when (location-in-list prev-location *breakpoints*)
1576                    (format t " *Active*"))
1577                  (when (sb!di:code-location= prev-location continue-at)
1578                    (format t " *Continue here*")))))
1579
1580         (dolist (code-location *possible-breakpoints*)
1581           (when (or *print-location-kind*
1582                     (location-in-list code-location *breakpoints*)
1583                     (sb!di:code-location= code-location continue-at)
1584                     (not prev-location)
1585                     (not (eq (sb!di:code-location-debug-source code-location)
1586                              (sb!di:code-location-debug-source prev-location)))
1587                     (not (eq (sb!di:code-location-toplevel-form-offset
1588                               code-location)
1589                              (sb!di:code-location-toplevel-form-offset
1590                               prev-location)))
1591                     (not (eq (sb!di:code-location-form-number code-location)
1592                              (sb!di:code-location-form-number prev-location))))
1593             (flush)
1594             (setq prev-location code-location  prev-num this-num))
1595
1596           (incf this-num))))
1597
1598     (when (location-in-list *default-breakpoint-debug-fun*
1599                             *breakpoints*
1600                             :fun-end)
1601       (format t "~&::FUN-END *Active* "))))
1602
1603 (!def-debug-command-alias "LL" "LIST-LOCATIONS")
1604
1605 ;;; Set breakpoint at the given number.
1606 (!def-debug-command "BREAKPOINT" ()
1607   (let ((index (read-prompting-maybe "location number, :START, or :END: "))
1608         (break t)
1609         (condition t)
1610         (print nil)
1611         (print-functions nil)
1612         (function nil)
1613         (bp)
1614         (place *default-breakpoint-debug-fun*))
1615     (flet ((get-command-line ()
1616              (let ((command-line nil)
1617                    (unique '(nil)))
1618                (loop
1619                  (let ((next-input (read-if-available unique)))
1620                    (when (eq next-input unique) (return))
1621                    (push next-input command-line)))
1622                (nreverse command-line)))
1623            (set-vars-from-command-line (command-line)
1624              (do ((arg (pop command-line) (pop command-line)))
1625                  ((not arg))
1626                (ecase arg
1627                  (:condition (setf condition (pop command-line)))
1628                  (:print (push (pop command-line) print))
1629                  (:break (setf break (pop command-line)))
1630                  (:function
1631                   (setf function (eval (pop command-line)))
1632                   (setf *default-breakpoint-debug-fun*
1633                         (sb!di:fun-debug-fun function))
1634                   (setf place *default-breakpoint-debug-fun*)
1635                   (setf *possible-breakpoints*
1636                         (possible-breakpoints
1637                          *default-breakpoint-debug-fun*))))))
1638            (setup-fun-start ()
1639              (let ((code-loc (sb!di:debug-fun-start-location place)))
1640                (setf bp (sb!di:make-breakpoint #'main-hook-fun
1641                                                place
1642                                                :kind :fun-start))
1643                (setf break (sb!di:preprocess-for-eval break code-loc))
1644                (setf condition (sb!di:preprocess-for-eval condition code-loc))
1645                (dolist (form print)
1646                  (push (cons (sb!di:preprocess-for-eval form code-loc) form)
1647                        print-functions))))
1648            (setup-fun-end ()
1649              (setf bp
1650                    (sb!di:make-breakpoint #'main-hook-fun
1651                                           place
1652                                           :kind :fun-end))
1653              (setf break
1654                    ;; FIXME: These and any other old (COERCE `(LAMBDA ..) ..)
1655                    ;; forms should be converted to shiny new (LAMBDA ..) forms.
1656                    ;; (Search the sources for "coerce.*\(lambda".)
1657                    (coerce `(lambda (dummy)
1658                               (declare (ignore dummy)) ,break)
1659                            'function))
1660              (setf condition (coerce `(lambda (dummy)
1661                                         (declare (ignore dummy)) ,condition)
1662                                      'function))
1663              (dolist (form print)
1664                (push (cons
1665                       (coerce `(lambda (dummy)
1666                                  (declare (ignore dummy)) ,form) 'function)
1667                       form)
1668                      print-functions)))
1669            (setup-code-location ()
1670              (setf place (nth index *possible-breakpoints*))
1671              (setf bp (sb!di:make-breakpoint #'main-hook-fun place
1672                                              :kind :code-location))
1673              (dolist (form print)
1674                (push (cons
1675                       (sb!di:preprocess-for-eval form place)
1676                       form)
1677                      print-functions))
1678              (setf break (sb!di:preprocess-for-eval break place))
1679              (setf condition (sb!di:preprocess-for-eval condition place))))
1680       (set-vars-from-command-line (get-command-line))
1681       (cond
1682        ((or (eq index :start) (eq index :s))
1683         (setup-fun-start))
1684        ((or (eq index :end) (eq index :e))
1685         (setup-fun-end))
1686        (t
1687         (setup-code-location)))
1688       (sb!di:activate-breakpoint bp)
1689       (let* ((new-bp-info (create-breakpoint-info place bp index
1690                                                   :break break
1691                                                   :print print-functions
1692                                                   :condition condition))
1693              (old-bp-info (location-in-list new-bp-info *breakpoints*)))
1694         (when old-bp-info
1695           (sb!di:deactivate-breakpoint (breakpoint-info-breakpoint
1696                                         old-bp-info))
1697           (setf *breakpoints* (remove old-bp-info *breakpoints*))
1698           (format t "previous breakpoint removed~%"))
1699         (push new-bp-info *breakpoints*))
1700       (print-breakpoint-info (first *breakpoints*))
1701       (format t "~&added"))))
1702
1703 (!def-debug-command-alias "BP" "BREAKPOINT")
1704
1705 ;;; List all breakpoints which are set.
1706 (!def-debug-command "LIST-BREAKPOINTS" ()
1707   (setf *breakpoints*
1708         (sort *breakpoints* #'< :key #'breakpoint-info-breakpoint-number))
1709   (dolist (info *breakpoints*)
1710     (print-breakpoint-info info)))
1711
1712 (!def-debug-command-alias "LB" "LIST-BREAKPOINTS")
1713 (!def-debug-command-alias "LBP" "LIST-BREAKPOINTS")
1714
1715 ;;; Remove breakpoint N, or remove all breakpoints if no N given.
1716 (!def-debug-command "DELETE-BREAKPOINT" ()
1717   (let* ((index (read-if-available nil))
1718          (bp-info
1719           (find index *breakpoints* :key #'breakpoint-info-breakpoint-number)))
1720     (cond (bp-info
1721            (sb!di:delete-breakpoint (breakpoint-info-breakpoint bp-info))
1722            (setf *breakpoints* (remove bp-info *breakpoints*))
1723            (format t "breakpoint ~S removed~%" index))
1724           (index (format t "The breakpoint doesn't exist."))
1725           (t
1726            (dolist (ele *breakpoints*)
1727              (sb!di:delete-breakpoint (breakpoint-info-breakpoint ele)))
1728            (setf *breakpoints* nil)
1729            (format t "all breakpoints deleted~%")))))
1730
1731 (!def-debug-command-alias "DBP" "DELETE-BREAKPOINT")
1732 \f
1733 ;;; miscellaneous commands
1734
1735 (!def-debug-command "DESCRIBE" ()
1736   (let* ((curloc (sb!di:frame-code-location *current-frame*))
1737          (debug-fun (sb!di:code-location-debug-fun curloc))
1738          (function (sb!di:debug-fun-fun debug-fun)))
1739     (if function
1740         (describe function)
1741         (format t "can't figure out the function for this frame"))))
1742
1743 (!def-debug-command "SLURP" ()
1744   (loop while (read-char-no-hang *standard-input*)))
1745
1746 (!def-debug-command "RETURN" (&optional
1747                               (return (read-prompting-maybe
1748                                        "return: ")))
1749   (let ((tag (find-if (lambda (x)
1750                         (and (typep (car x) 'symbol)
1751                              (not (symbol-package (car x)))
1752                              (string= (car x) "SB-DEBUG-CATCH-TAG")))
1753                       (sb!di::frame-catches *current-frame*))))
1754     (if tag
1755         (throw (car tag)
1756           (funcall (sb!di:preprocess-for-eval
1757                     return
1758                     (sb!di:frame-code-location *current-frame*))
1759                    *current-frame*))
1760         (format t "~@<can't find a tag for this frame ~
1761                    ~2I~_(hint: try increasing the DEBUG optimization quality ~
1762                    and recompiling)~:@>"))))
1763 \f
1764 ;;;; debug loop command utilities
1765
1766 (defun read-prompting-maybe (prompt)
1767   (unless (sb!int:listen-skip-whitespace *debug-io*)
1768     (princ prompt)
1769     (force-output))
1770   (read *debug-io*))
1771
1772 (defun read-if-available (default)
1773   (if (sb!int:listen-skip-whitespace *debug-io*)
1774       (read *debug-io*)
1775       default))