src/code/debug.lisp

   1 ;;;; the debugger
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!DEBUG")
  13 \f
  14 ;;;; variables and constants
  15
  16 ;;; things to consider when tweaking these values:
  17 ;;;   * We're afraid to just default them to NIL and NIL, in case the
  18 ;;;     user inadvertently causes a hairy data structure to be printed
  19 ;;;     when he inadvertently enters the debugger.
  20 ;;;   * We don't want to truncate output too much. These days anyone
  21 ;;;     can easily run their Lisp in a windowing system or under Emacs,
  22 ;;;     so it's not the end of the world even if the worst case is a
  23 ;;;     few thousand lines of output.
  24 ;;;   * As condition :REPORT methods are converted to use the pretty
  25 ;;;     printer, they acquire *PRINT-LEVEL* constraints, so e.g. under
  26 ;;;     sbcl-0.7.1.28's old value of *DEBUG-PRINT-LEVEL*=3, an
  27 ;;;     ARG-COUNT-ERROR printed as
  28 ;;;       error while parsing arguments to DESTRUCTURING-BIND:
  29 ;;;         invalid number of elements in
  30 ;;;           #
  31 ;;;         to satisfy lambda list
  32 ;;;           #:
  33 ;;;         exactly 2 expected, but 5 found
  34 (defvar *debug-print-level* 5
  35   #!+sb-doc
  36   "*PRINT-LEVEL* for the debugger")
  37 (defvar *debug-print-length* 7
  38   #!+sb-doc
  39   "*PRINT-LENGTH* for the debugger")
  40
  41 (defvar *debug-readtable*
  42   ;; KLUDGE: This can't be initialized in a cold toplevel form,
  43   ;; because the *STANDARD-READTABLE* isn't initialized until after
  44   ;; cold toplevel forms have run. So instead we initialize it
  45   ;; immediately after *STANDARD-READTABLE*. -- WHN 20000205
  46   nil
  47   #!+sb-doc
  48   "*READTABLE* for the debugger")
  49
  50 (defvar *in-the-debugger* nil
  51   #!+sb-doc
  52   "This is T while in the debugger.")
  53
  54 ;;; nestedness inside debugger command loops
  55 (defvar *debug-command-level* 0)
  56
  57 ;;; If this is bound before the debugger is invoked, it is used as the
  58 ;;; stack top by the debugger.
  59 (defvar *stack-top-hint* nil)
  60
  61 (defvar *stack-top* nil)
  62 (defvar *real-stack-top* nil)
  63
  64 (defvar *current-frame* nil)
  65
  66 ;;; Beginner-oriented help messages are important because you end up
  67 ;;; in the debugger whenever something bad happens, or if you try to
  68 ;;; get out of the system with Ctrl-C or (EXIT) or EXIT or whatever.
  69 ;;; But after memorizing them the wasted screen space gets annoying..
  70 (defvar *debug-beginner-help-p* t
  71   "Should the debugger display beginner-oriented help messages?")
  72
  73 (defun debug-prompt (stream)
  74   (sb!thread::get-foreground)
  75   (format stream
  76           "~%~W~:[~;[~W~]] "
  77           (sb!di:frame-number *current-frame*)
  78           (> *debug-command-level* 1)
  79           *debug-command-level*))
  80
  81 (defparameter *debug-help-string*
  82 "The debug prompt is square brackets, with number(s) indicating the current
  83   control stack level and, if you've entered the debugger recursively, how
  84   deeply recursed you are.
  85 Any command -- including the name of a restart -- may be uniquely abbreviated.
  86 The debugger rebinds various special variables for controlling i/o, sometimes
  87   to defaults (much like WITH-STANDARD-IO-SYNTAX does) and sometimes to
  88   its own special values, e.g. SB-DEBUG:*DEBUG-PRINT-LEVEL*.
  89 Debug commands do not affect *, //, and similar variables, but evaluation in
  90   the debug loop does affect these variables.
  91 SB-DEBUG:*FLUSH-DEBUG-ERRORS* controls whether errors at the debug prompt
  92   drop you deeper into the debugger.
  93
  94 Getting in and out of the debugger:
  95   RESTART  invokes restart numbered as shown (prompt if not given).
  96   ERROR    prints the error condition and restart cases.
  97   The number of any restart, or its name, or a unique abbreviation for its
  98     name, is a valid command, and is the same as using RESTART to invoke
  99     that restart.
 100
 101 Changing frames:
 102   U      up frame     D    down frame
 103   B  bottom frame     F n  frame n (n=0 for top frame)
 104
 105 Inspecting frames:
 106   BACKTRACE [n]  shows n frames going down the stack.
 107   LIST-LOCALS, L lists locals in current function.
 108   PRINT, P       displays current function call.
 109   SOURCE [n]     displays frame's source form with n levels of enclosing forms.
 110
 111 Breakpoints and steps:
 112   LIST-LOCATIONS [{function | :C}]   List the locations for breakpoints.
 113                                      Specify :C for the current frame.
 114     Abbreviation: LL
 115   LIST-BREAKPOINTS                   List the active breakpoints.
 116     Abbreviations: LB, LBP
 117   DELETE-BREAKPOINT [n]              Remove breakpoint n or all breakpoints.
 118     Abbreviations: DEL, DBP
 119   BREAKPOINT {n | :end | :start} [:break form] [:function function]
 120              [{:print form}*] [:condition form]
 121                                      Set a breakpoint.
 122     Abbreviations: BR, BP
 123   STEP [n]                           Step to the next location or step n times.
 124
 125 Function and macro commands:
 126  (SB-DEBUG:ARG n)
 127     Return the n'th argument in the current frame.
 128  (SB-DEBUG:VAR string-or-symbol [id])
 129     Returns the value of the specified variable in the current frame.
 130
 131 Other commands:
 132   RETURN expr
 133     [EXPERIMENTAL] Return the values resulting from evaluation of expr
 134     from the current frame, if this frame was compiled with a sufficiently
 135     high DEBUG optimization quality.
 136   SLURP
 137     Discard all pending input on *STANDARD-INPUT*. (This can be
 138     useful when the debugger was invoked to handle an error in
 139     deeply nested input syntax, and now the reader is confused.)")
 140 \f
 141 ;;; This is used to communicate to DEBUG-LOOP that we are at a step breakpoint.
 142 (define-condition step-condition (simple-condition) ())
 143 \f
 144 ;;;; breakpoint state
 145
 146 (defvar *only-block-start-locations* nil
 147   #!+sb-doc
 148   "When true, the LIST-LOCATIONS command only displays block start locations.
 149    Otherwise, all locations are displayed.")
 150
 151 (defvar *print-location-kind* nil
 152   #!+sb-doc
 153   "When true, list the code location type in the LIST-LOCATIONS command.")
 154
 155 ;;; a list of the types of code-locations that should not be stepped
 156 ;;; to and should not be listed when listing breakpoints
 157 (defvar *bad-code-location-types* '(:call-site :internal-error))
 158 (declaim (type list *bad-code-location-types*))
 159
 160 ;;; code locations of the possible breakpoints
 161 (defvar *possible-breakpoints*)
 162 (declaim (type list *possible-breakpoints*))
 163
 164 ;;; a list of the made and active breakpoints, each is a
 165 ;;; BREAKPOINT-INFO structure
 166 (defvar *breakpoints* nil)
 167 (declaim (type list *breakpoints*))
 168
 169 ;;; a list of BREAKPOINT-INFO structures of the made and active step
 170 ;;; breakpoints
 171 (defvar *step-breakpoints* nil)
 172 (declaim (type list *step-breakpoints*))
 173
 174 ;;; the number of times left to step
 175 (defvar *number-of-steps* 1)
 176 (declaim (type integer *number-of-steps*))
 177
 178 ;;; This is used when listing and setting breakpoints.
 179 (defvar *default-breakpoint-debug-fun* nil)
 180 (declaim (type (or list sb!di:debug-fun) *default-breakpoint-debug-fun*))
 181 \f
 182 ;;;; code location utilities
 183
 184 ;;; Return the first code-location in the passed debug block.
 185 (defun first-code-location (debug-block)
 186   (let ((found nil)
 187         (first-code-location nil))
 188     (sb!di:do-debug-block-locations (code-location debug-block)
 189       (unless found
 190         (setf first-code-location code-location)
 191         (setf found t)))
 192     first-code-location))
 193
 194 ;;; Return a list of the next code-locations following the one passed.
 195 ;;; One of the *BAD-CODE-LOCATION-TYPES* will not be returned.
 196 (defun next-code-locations (code-location)
 197   (let ((debug-block (sb!di:code-location-debug-block code-location))
 198         (block-code-locations nil))
 199     (sb!di:do-debug-block-locations (block-code-location debug-block)
 200       (unless (member (sb!di:code-location-kind block-code-location)
 201                       *bad-code-location-types*)
 202         (push block-code-location block-code-locations)))
 203     (setf block-code-locations (nreverse block-code-locations))
 204     (let* ((code-loc-list (rest (member code-location block-code-locations
 205                                         :test #'sb!di:code-location=)))
 206            (next-list (cond (code-loc-list
 207                              (list (first code-loc-list)))
 208                             ((map 'list #'first-code-location
 209                                   (sb!di:debug-block-successors debug-block)))
 210                             (t nil))))
 211       (when (and (= (length next-list) 1)
 212                  (sb!di:code-location= (first next-list) code-location))
 213         (setf next-list (next-code-locations (first next-list))))
 214       next-list)))
 215
 216 ;;; Return a list of code-locations of the possible breakpoints of DEBUG-FUN.
 217 (defun possible-breakpoints (debug-fun)
 218   (let ((possible-breakpoints nil))
 219     (sb!di:do-debug-fun-blocks (debug-block debug-fun)
 220       (unless (sb!di:debug-block-elsewhere-p debug-block)
 221         (if *only-block-start-locations*
 222             (push (first-code-location debug-block) possible-breakpoints)
 223             (sb!di:do-debug-block-locations (code-location debug-block)
 224               (when (not (member (sb!di:code-location-kind code-location)
 225                                  *bad-code-location-types*))
 226                 (push code-location possible-breakpoints))))))
 227     (nreverse possible-breakpoints)))
 228
 229 ;;; Search the info-list for the item passed (CODE-LOCATION,
 230 ;;; DEBUG-FUN, or BREAKPOINT-INFO). If the item passed is a debug
 231 ;;; function then kind will be compared if it was specified. The kind
 232 ;;; if also compared if a breakpoint-info is passed since it's in the
 233 ;;; breakpoint. The info structure is returned if found.
 234 (defun location-in-list (place info-list &optional (kind nil))
 235   (when (breakpoint-info-p place)
 236     (setf kind (sb!di:breakpoint-kind (breakpoint-info-breakpoint place)))
 237     (setf place (breakpoint-info-place place)))
 238   (cond ((sb!di:code-location-p place)
 239          (find place info-list
 240                :key #'breakpoint-info-place
 241                :test (lambda (x y) (and (sb!di:code-location-p y)
 242                                         (sb!di:code-location= x y)))))
 243         (t
 244          (find place info-list
 245                :test (lambda (x-debug-fun y-info)
 246                        (let ((y-place (breakpoint-info-place y-info))
 247                              (y-breakpoint (breakpoint-info-breakpoint
 248                                             y-info)))
 249                          (and (sb!di:debug-fun-p y-place)
 250                               (eq x-debug-fun y-place)
 251                               (or (not kind)
 252                                   (eq kind (sb!di:breakpoint-kind
 253                                             y-breakpoint))))))))))
 254
 255 ;;; If LOC is an unknown location, then try to find the block start
 256 ;;; location. Used by source printing to some information instead of
 257 ;;; none for the user.
 258 (defun maybe-block-start-location (loc)
 259   (if (sb!di:code-location-unknown-p loc)
 260       (let* ((block (sb!di:code-location-debug-block loc))
 261              (start (sb!di:do-debug-block-locations (loc block)
 262                       (return loc))))
 263         (cond ((and (not (sb!di:debug-block-elsewhere-p block))
 264                     start)
 265                ;; FIXME: Why output on T instead of *DEBUG-FOO* or something?
 266                (format t "~%unknown location: using block start~%")
 267                start)
 268               (t
 269                loc)))
 270       loc))
 271 \f
 272 ;;;; the BREAKPOINT-INFO structure
 273
 274 ;;; info about a made breakpoint
 275 (defstruct (breakpoint-info (:copier nil)
 276                             (:constructor %make-breakpoint-info))
 277   ;; where we are going to stop
 278   (place (missing-arg)
 279          :type (or sb!di:code-location sb!di:debug-fun)
 280          :read-only t)
 281   ;; the breakpoint returned by SB!DI:MAKE-BREAKPOINT
 282   (breakpoint (missing-arg) :type sb!di:breakpoint :read-only t)
 283   ;; the function returned from SB!DI:PREPROCESS-FOR-EVAL. If result is
 284   ;; non-NIL, drop into the debugger.
 285   (break #'identity :type function :read-only t)
 286   ;; the function returned from SB!DI:PREPROCESS-FOR-EVAL. If result is
 287   ;; non-NIL, eval (each) print and print results.
 288   (condition #'identity :type function :read-only t)
 289   ;; the list of functions from SB!DI:PREPROCESS-FOR-EVAL to evaluate.
 290   ;; Results are conditionally printed. CAR of each element is the
 291   ;; function, CDR is the form it goes with.
 292   (print nil :type list :read-only t)
 293   ;; the number used when listing the possible breakpoints within a
 294   ;; function; or could also be a symbol such as START or END
 295   (code-location-selector (missing-arg) :type (or symbol integer) :read-only t)
 296   ;; the number used when listing the active breakpoints, and when
 297   ;; deleting breakpoints
 298   (breakpoint-number (missing-arg) :type integer :read-only t))
 299
 300 (defun create-breakpoint-info (place breakpoint code-location-selector
 301                                      &key (break #'identity)
 302                                      (condition #'identity) (print nil))
 303   (setf *breakpoints*
 304         (sort *breakpoints* #'< :key #'breakpoint-info-breakpoint-number))
 305   (let ((breakpoint-number
 306          (do ((i 1 (incf i)) (breakpoints *breakpoints* (rest breakpoints)))
 307              ((or (> i (length *breakpoints*))
 308                   (not (= i (breakpoint-info-breakpoint-number
 309                              (first breakpoints)))))
 310
 311               i))))
 312     (%make-breakpoint-info :place place
 313                            :breakpoint breakpoint
 314                            :code-location-selector code-location-selector
 315                            :breakpoint-number breakpoint-number
 316                            :break break
 317                            :condition condition
 318                            :print print)))
 319
 320 (defun print-breakpoint-info (breakpoint-info)
 321   (let ((place (breakpoint-info-place breakpoint-info))
 322         (bp-number (breakpoint-info-breakpoint-number breakpoint-info)))
 323     (case (sb!di:breakpoint-kind (breakpoint-info-breakpoint breakpoint-info))
 324       (:code-location
 325        (print-code-location-source-form place 0)
 326        (format t
 327                "~&~S: ~S in ~S"
 328                bp-number
 329                (breakpoint-info-code-location-selector breakpoint-info)
 330                (sb!di:debug-fun-name (sb!di:code-location-debug-fun place))))
 331       (:fun-start
 332        (format t "~&~S: FUN-START in ~S" bp-number
 333                (sb!di:debug-fun-name place)))
 334       (:fun-end
 335        (format t "~&~S: FUN-END in ~S" bp-number
 336                (sb!di:debug-fun-name place))))))
 337 \f
 338 ;;;; MAIN-HOOK-FUN for steps and breakpoints
 339
 340 ;;; This must be passed as the hook function. It keeps track of where
 341 ;;; STEP breakpoints are.
 342 (defun main-hook-fun (current-frame breakpoint &optional return-vals
 343                                     fun-end-cookie)
 344   (setf *default-breakpoint-debug-fun*
 345         (sb!di:frame-debug-fun current-frame))
 346   (dolist (step-info *step-breakpoints*)
 347     (sb!di:delete-breakpoint (breakpoint-info-breakpoint step-info))
 348     (let ((bp-info (location-in-list step-info *breakpoints*)))
 349       (when bp-info
 350         (sb!di:activate-breakpoint (breakpoint-info-breakpoint bp-info)))))
 351   (let ((*stack-top-hint* current-frame)
 352         (step-hit-info
 353          (location-in-list (sb!di:breakpoint-what breakpoint)
 354                            *step-breakpoints*
 355                            (sb!di:breakpoint-kind breakpoint)))
 356         (bp-hit-info
 357          (location-in-list (sb!di:breakpoint-what breakpoint)
 358                            *breakpoints*
 359                            (sb!di:breakpoint-kind breakpoint)))
 360         (break)
 361         (condition)
 362         (string ""))
 363     (setf *step-breakpoints* nil)
 364     (labels ((build-string (str)
 365                (setf string (concatenate 'string string str)))
 366              (print-common-info ()
 367                (build-string
 368                 (with-output-to-string (*standard-output*)
 369                   (when fun-end-cookie
 370                     (format t "~%Return values: ~S" return-vals))
 371                   (when condition
 372                     (when (breakpoint-info-print bp-hit-info)
 373                       (format t "~%")
 374                       (print-frame-call current-frame))
 375                     (dolist (print (breakpoint-info-print bp-hit-info))
 376                       (format t "~& ~S = ~S" (rest print)
 377                               (funcall (first print) current-frame))))))))
 378       (when bp-hit-info
 379         (setf break (funcall (breakpoint-info-break bp-hit-info)
 380                              current-frame))
 381         (setf condition (funcall (breakpoint-info-condition bp-hit-info)
 382                                  current-frame)))
 383       (cond ((and bp-hit-info step-hit-info (= 1 *number-of-steps*))
 384              (build-string (format nil "~&*Step (to a breakpoint)*"))
 385              (print-common-info)
 386              (break string))
 387             ((and bp-hit-info step-hit-info break)
 388              (build-string (format nil "~&*Step (to a breakpoint)*"))
 389              (print-common-info)
 390              (break string))
 391             ((and bp-hit-info step-hit-info)
 392              (print-common-info)
 393              (format t "~A" string)
 394              (decf *number-of-steps*)
 395              (set-step-breakpoint current-frame))
 396             ((and step-hit-info (= 1 *number-of-steps*))
 397              (build-string "*Step*")
 398              (break (make-condition 'step-condition :format-control string)))
 399             (step-hit-info
 400              (decf *number-of-steps*)
 401              (set-step-breakpoint current-frame))
 402             (bp-hit-info
 403              (when break
 404                (build-string (format nil "~&*Breakpoint hit*")))
 405              (print-common-info)
 406              (if break
 407                  (break string)
 408                  (format t "~A" string)))
 409             (t
 410              (break "unknown breakpoint"))))))
 411 \f
 412 ;;; Set breakpoints at the next possible code-locations. After calling
 413 ;;; this, either (CONTINUE) if in the debugger or just let program flow
 414 ;;; return if in a hook function.
 415 (defun set-step-breakpoint (frame)
 416   (cond
 417    ((sb!di:debug-block-elsewhere-p (sb!di:code-location-debug-block
 418                                     (sb!di:frame-code-location frame)))
 419     ;; FIXME: FORMAT T is used for error output here and elsewhere in
 420     ;; the debug code.
 421     (format t "cannot step, in elsewhere code~%"))
 422    (t
 423     (let* ((code-location (sb!di:frame-code-location frame))
 424            (next-code-locations (next-code-locations code-location)))
 425       (cond
 426        (next-code-locations
 427         (dolist (code-location next-code-locations)
 428           (let ((bp-info (location-in-list code-location *breakpoints*)))
 429             (when bp-info
 430               (sb!di:deactivate-breakpoint (breakpoint-info-breakpoint
 431                                             bp-info))))
 432           (let ((bp (sb!di:make-breakpoint #'main-hook-fun code-location
 433                                            :kind :code-location)))
 434             (sb!di:activate-breakpoint bp)
 435             (push (create-breakpoint-info code-location bp 0)
 436                   *step-breakpoints*))))
 437        (t
 438         (let* ((debug-fun (sb!di:frame-debug-fun *current-frame*))
 439                (bp (sb!di:make-breakpoint #'main-hook-fun debug-fun
 440                                           :kind :fun-end)))
 441           (sb!di:activate-breakpoint bp)
 442           (push (create-breakpoint-info debug-fun bp 0)
 443                 *step-breakpoints*))))))))
 444 \f
 445 ;;;; STEP
 446
 447 ;;; ANSI specifies that this macro shall exist, even if only as a
 448 ;;; trivial placeholder like this.
 449 (defmacro step (form)
 450   "This is a trivial placeholder implementation of the CL:STEP macro required
 451    by the ANSI spec, simply expanding to `(LET () ,FORM). A more featureful
 452    version would be welcome, we just haven't written it."
 453   `(let ()
 454      ,form))
 455 \f
 456 ;;;; BACKTRACE
 457
 458 (defun backtrace (&optional (count most-positive-fixnum)
 459                             (*standard-output* *debug-io*))
 460   #!+sb-doc
 461   "Show a listing of the call stack going down from the current frame. In the
 462    debugger, the current frame is indicated by the prompt. COUNT is how many
 463    frames to show."
 464   (fresh-line *standard-output*)
 465   (do ((frame (if *in-the-debugger* *current-frame* (sb!di:top-frame))
 466               (sb!di:frame-down frame))
 467        (count count (1- count)))
 468       ((or (null frame) (zerop count)))
 469     (print-frame-call frame :number t))
 470   (fresh-line *standard-output*)
 471   (values))
 472
 473 (defun backtrace-as-list (&optional (count most-positive-fixnum))
 474   #!+sb-doc "Return a list representing the current BACKTRACE."
 475   (do ((reversed-result nil)
 476        (frame (if *in-the-debugger* *current-frame* (sb!di:top-frame))
 477               (sb!di:frame-down frame))
 478        (count count (1- count)))
 479       ((or (null frame) (zerop count))
 480        (nreverse reversed-result))
 481     (push (frame-call-as-list frame) reversed-result)))
 482
 483 (defun frame-call-as-list (frame)
 484   (cons (sb!di:debug-fun-name (sb!di:frame-debug-fun frame))
 485         (frame-args-as-list frame)))
 486 \f
 487 ;;;; frame printing
 488
 489 (eval-when (:compile-toplevel :execute)
 490
 491 ;;; This is a convenient way to express what to do for each type of
 492 ;;; lambda-list element.
 493 (sb!xc:defmacro lambda-list-element-dispatch (element
 494                                               &key
 495                                               required
 496                                               optional
 497                                               rest
 498                                               keyword
 499                                               deleted)
 500   `(etypecase ,element
 501      (sb!di:debug-var
 502       ,@required)
 503      (cons
 504       (ecase (car ,element)
 505         (:optional ,@optional)
 506         (:rest ,@rest)
 507         (:keyword ,@keyword)))
 508      (symbol
 509       (aver (eq ,element :deleted))
 510       ,@deleted)))
 511
 512 (sb!xc:defmacro lambda-var-dispatch (variable location deleted valid other)
 513   (let ((var (gensym)))
 514     `(let ((,var ,variable))
 515        (cond ((eq ,var :deleted) ,deleted)
 516              ((eq (sb!di:debug-var-validity ,var ,location) :valid)
 517               ,valid)
 518              (t ,other)))))
 519
 520 ) ; EVAL-WHEN
 521
 522 ;;; This is used in constructing arg lists for debugger printing when
 523 ;;; the arg list is unavailable, some arg is unavailable or unused, etc.
 524 (defstruct (unprintable-object
 525             (:constructor make-unprintable-object (string))
 526             (:print-object (lambda (x s)
 527                              (print-unreadable-object (x s)
 528                                (write-string (unprintable-object-string x)
 529                                              s))))
 530             (:copier nil))
 531   string)
 532
 533 ;;; Extract the function argument values for a debug frame.
 534 (defun frame-args-as-list (frame)
 535   (let ((debug-fun (sb!di:frame-debug-fun frame))
 536         (loc (sb!di:frame-code-location frame))
 537         (reversed-result nil))
 538     (handler-case
 539         (progn
 540           (dolist (ele (sb!di:debug-fun-lambda-list debug-fun))
 541             (lambda-list-element-dispatch ele
 542              :required ((push (frame-call-arg ele loc frame) reversed-result))
 543              :optional ((push (frame-call-arg (second ele) loc frame)
 544                               reversed-result))
 545              :keyword ((push (second ele) reversed-result)
 546                        (push (frame-call-arg (third ele) loc frame)
 547                              reversed-result))
 548              :deleted ((push (frame-call-arg ele loc frame) reversed-result))
 549              :rest ((lambda-var-dispatch (second ele) loc
 550                      nil
 551                      (progn
 552                        (setf reversed-result
 553                              (append (reverse (sb!di:debug-var-value
 554                                                (second ele) frame))
 555                                      reversed-result))
 556                        (return))
 557                      (push (make-unprintable-object
 558                             "unavailable &REST argument")
 559                      reversed-result)))))
 560           ;; As long as we do an ordinary return (as opposed to SIGNALing
 561           ;; a CONDITION) from the DOLIST above:
 562           (nreverse reversed-result))
 563       (sb!di:lambda-list-unavailable
 564        ()
 565        (make-unprintable-object "unavailable lambda list")))))
 566
 567 ;;; Print FRAME with verbosity level 1. If we hit a &REST arg, then
 568 ;;; print as many of the values as possible, punting the loop over
 569 ;;; lambda-list variables since any other arguments will be in the
 570 ;;; &REST arg's list of values.
 571 (defun print-frame-call-1 (frame)
 572   (let ((debug-fun (sb!di:frame-debug-fun frame)))
 573
 574     (pprint-logical-block (*standard-output* nil :prefix "(" :suffix ")")
 575       (let ((args (ensure-printable-object (frame-args-as-list frame))))
 576         ;; Since we go to some trouble to make nice informative function
 577         ;; names like (PRINT-OBJECT :AROUND (CLOWN T)), let's make sure
 578         ;; that they aren't truncated by *PRINT-LENGTH* and *PRINT-LEVEL*.
 579         (let ((*print-length* nil)
 580               (*print-level* nil))
 581           (prin1 (ensure-printable-object (sb!di:debug-fun-name debug-fun))))
 582         ;; For the function arguments, we can just print normally.
 583         (if (listp args)
 584             (format t "~{ ~_~S~}" args)
 585             (format t " ~S" args))))
 586
 587     (when (sb!di:debug-fun-kind debug-fun)
 588       (write-char #\[)
 589       (prin1 (sb!di:debug-fun-kind debug-fun))
 590       (write-char #\]))))
 591
 592 (defun ensure-printable-object (object)
 593   (handler-case
 594       (with-open-stream (out (make-broadcast-stream))
 595         (prin1 object out)
 596         object)
 597     (error (cond)
 598       (declare (ignore cond))
 599       (make-unprintable-object "error printing object"))))
 600
 601 (defun frame-call-arg (var location frame)
 602   (lambda-var-dispatch var location
 603     (make-unprintable-object "unused argument")
 604     (sb!di:debug-var-value var frame)
 605     (make-unprintable-object "unavailable argument")))
 606
 607 ;;; Prints a representation of the function call causing FRAME to
 608 ;;; exist. VERBOSITY indicates the level of information to output;
 609 ;;; zero indicates just printing the DEBUG-FUN's name, and one
 610 ;;; indicates displaying call-like, one-liner format with argument
 611 ;;; values.
 612 (defun print-frame-call (frame &key (verbosity 1) (number nil))
 613   (cond
 614    ((zerop verbosity)
 615     (when number
 616       (format t "~&~S: " (sb!di:frame-number frame)))
 617     (format t "~S" frame))
 618    (t
 619     (when number
 620       (format t "~&~S: " (sb!di:frame-number frame)))
 621     (print-frame-call-1 frame)))
 622   (when (>= verbosity 2)
 623     (let ((loc (sb!di:frame-code-location frame)))
 624       (handler-case
 625           (progn
 626             (sb!di:code-location-debug-block loc)
 627             (format t "~%source: ")
 628             (print-code-location-source-form loc 0))
 629         (sb!di:debug-condition (ignore) ignore)
 630         (error (c) (format t "error finding source: ~A" c))))))
 631 \f
 632 ;;;; INVOKE-DEBUGGER
 633
 634 (defvar *debugger-hook* nil
 635   #!+sb-doc
 636   "This is either NIL or a function of two arguments, a condition and the value
 637    of *DEBUGGER-HOOK*. This function can either handle the condition or return
 638    which causes the standard debugger to execute. The system passes the value
 639    of this variable to the function because it binds *DEBUGGER-HOOK* to NIL
 640    around the invocation.")
 641
 642 ;;; These are bound on each invocation of INVOKE-DEBUGGER.
 643 (defvar *debug-restarts*)
 644 (defvar *debug-condition*)
 645 (defvar *nested-debug-condition*)
 646
 647 (defun invoke-debugger (condition)
 648   #!+sb-doc
 649   "Enter the debugger."
 650   (let ((old-hook *debugger-hook*))
 651     (when old-hook
 652       (let ((*debugger-hook* nil))
 653         (funcall old-hook condition old-hook))))
 654
 655   ;; If we're a background thread and *background-threads-wait-for-debugger*
 656   ;; is NIL, this will invoke a restart
 657
 658   ;; Note: CMU CL had (SB-UNIX:UNIX-SIGSETMASK 0) here. I deleted it
 659   ;; around sbcl-0.7.8.5 (by which time it had mutated to have a
 660   ;; #!-SUNOS prefix and a FIXME note observing that it wasn't needed
 661   ;; on SunOS and no one knew why it was needed anywhere else either).
 662   ;; So if something mysteriously breaks that has worked since the CMU
 663   ;; CL days, that might be why. -- WHN 2002-09-28
 664
 665   ;; We definitely want *PACKAGE* to be of valid type.
 666   ;;
 667   ;; Elsewhere in the system, we use the SANE-PACKAGE function for
 668   ;; this, but here causing an exception just as we're trying to handle
 669   ;; an exception would be confusing, so instead we use a special hack.
 670   (unless (and (packagep *package*)
 671                (package-name *package*))
 672     (setf *package* (find-package :cl-user))
 673     (format *error-output*
 674             "The value of ~S was not an undeleted PACKAGE. It has been
 675 reset to ~S."
 676             '*package* *package*))
 677
 678   ;; Try to force the other special variables into a useful state.
 679   (let (;; Protect from WITH-STANDARD-IO-SYNTAX some variables where
 680         ;; any default we might use is less useful than just reusing
 681         ;; the global values.
 682         (original-package *package*)
 683         (original-print-pretty *print-pretty*))
 684     (with-standard-io-syntax
 685      (let ((*debug-condition* condition)
 686            (*debug-restarts* (compute-restarts condition))
 687            (*nested-debug-condition* nil)
 688            ;; We want the printer and reader to be in a useful state,
 689            ;; regardless of where the debugger was invoked in the
 690            ;; program. WITH-STANDARD-IO-SYNTAX did much of what we
 691            ;; want, but
 692            ;;   * It doesn't affect our internal special variables
 693            ;;     like *CURRENT-LEVEL-IN-PRINT*.
 694            ;;   * It isn't customizable.
 695            ;;   * It doesn't set *PRINT-READABLY* to the same value
 696            ;;     as the toplevel default.
 697            ;;   * It sets *PACKAGE* to COMMON-LISP-USER, which is not
 698            ;;     helpful behavior for a debugger.
 699            ;;   * There's no particularly good debugger default for
 700            ;;     *PRINT-PRETTY*, since T is usually what you want
 701            ;;     -- except absolutely not what you want when you're
 702            ;;     debugging failures in PRINT-OBJECT logic.
 703            ;; We try to address all these issues with explicit
 704            ;; rebindings here.
 705            (sb!kernel:*current-level-in-print* 0)
 706            (*print-length* *debug-print-length*)
 707            (*print-level* *debug-print-level*)
 708            (*readtable* *debug-readtable*)
 709            (*print-readably* nil)
 710            (*package* original-package)
 711            (background-p nil)
 712            (*print-pretty* original-print-pretty))
 713
 714        ;; Before we start our own output, finish any pending output.
 715        ;; Otherwise, if the user tried to track the progress of his
 716        ;; program using PRINT statements, he'd tend to lose the last
 717        ;; line of output or so, which'd be confusing.
 718        (flush-standard-output-streams)
 719
 720        ;; (The initial output here goes to *ERROR-OUTPUT*, because the
 721        ;; initial output is not interactive, just an error message,
 722        ;; and when people redirect *ERROR-OUTPUT*, they could
 723        ;; reasonably expect to see error messages logged there,
 724        ;; regardless of what the debugger does afterwards.)
 725        (handler-case
 726            (format *error-output*
 727                    "~2&~@<debugger invoked on condition of type ~S: ~
 728                     ~2I~_~A~:>~%"
 729                    (type-of *debug-condition*)
 730                    *debug-condition*)
 731          (error (condition)
 732            (setf *nested-debug-condition* condition)
 733            (let ((ndc-type (type-of *nested-debug-condition*)))
 734              (format *error-output*
 735                      "~&~@<(A ~S was caught when trying to print ~S when ~
 736                       entering the debugger. Printing was aborted and the ~
 737                       ~S was stored in ~S.)~@:>~%"
 738                      ndc-type
 739                      '*debug-condition*
 740                      ndc-type
 741                      '*nested-debug-condition*))
 742            (when (typep condition 'cell-error)
 743              ;; what we really want to know when it's e.g. an UNBOUND-VARIABLE:
 744              (format *error-output*
 745                      "~&(CELL-ERROR-NAME ~S) = ~S~%"
 746                      '*debug-condition*
 747                      (cell-error-name *debug-condition*)))))
 748
 749        ;; After the initial error/condition/whatever announcement to
 750        ;; *ERROR-OUTPUT*, we become interactive, and should talk on
 751        ;; *DEBUG-IO* from now on. (KLUDGE: This is a normative
 752        ;; statement, not a description of reality.:-| There's a lot of
 753        ;; older debugger code which was written to do i/o on whatever
 754        ;; stream was in fashion at the time, and not all of it has
 755        ;; been converted to behave this way. -- WHN 2000-11-16)
 756
 757        (setf background-p
 758              (sb!thread::debugger-wait-until-foreground-thread *debug-io*))
 759        (unwind-protect
 760        (let (;; FIXME: Rebinding *STANDARD-OUTPUT* here seems wrong,
 761              ;; violating the principle of least surprise, and making
 762              ;; it impossible for the user to do reasonable things
 763              ;; like using PRINT at the debugger prompt to send output
 764              ;; to the program's ordinary (possibly
 765              ;; redirected-to-a-file) *STANDARD-OUTPUT*. (CMU CL
 766              ;; used to rebind *STANDARD-INPUT* here too, but that's
 767              ;; been fixed already.)
 768              (*standard-output* *debug-io*)
 769              ;; This seems reasonable: e.g. if the user has redirected
 770              ;; *ERROR-OUTPUT* to some log file, it's probably wrong
 771              ;; to send errors which occur in interactive debugging to
 772              ;; that file, and right to send them to *DEBUG-IO*.
 773              (*error-output* *debug-io*))
 774          (unless (typep condition 'step-condition)
 775            (when *debug-beginner-help-p*
 776              (format *debug-io*
 777                      "~%~@<Within the debugger, you can type HELP for help. ~
 778                       At any command prompt (within the debugger or not) you ~
 779                       can type (SB-EXT:QUIT) to terminate the SBCL ~
 780                       executable. The condition which caused the debugger to ~
 781                       be entered is bound to ~S. You can suppress this ~
 782                       message by clearing ~S.~:@>~2%"
 783                      '*debug-condition*
 784                      '*debug-beginner-help-p*))
 785            (show-restarts *debug-restarts* *debug-io*))
 786               (internal-debug))
 787          (when background-p (sb!thread::release-foreground)))))))
 788
 789 (defun show-restarts (restarts s)
 790   (cond ((null restarts)
 791          (format s
 792                  "~&(no restarts: If you didn't do this on purpose, ~
 793                   please report it as a bug.)~%"))
 794         (t
 795          (format s "~&restarts:~%")
 796          (let ((count 0)
 797                (names-used '(nil))
 798                (max-name-len 0))
 799            (dolist (restart restarts)
 800              (let ((name (restart-name restart)))
 801                (when name
 802                  (let ((len (length (princ-to-string name))))
 803                    (when (> len max-name-len)
 804                      (setf max-name-len len))))))
 805            (unless (zerop max-name-len)
 806              (incf max-name-len 3))
 807            (dolist (restart restarts)
 808              (let ((name (restart-name restart)))
 809                (cond ((member name names-used)
 810                       (format s "~& ~2D: ~V@T~A~%" count max-name-len restart))
 811                      (t
 812                       (format s "~& ~2D: [~VA] ~A~%"
 813                               count (- max-name-len 3) name restart)
 814                       (push name names-used))))
 815              (incf count))))))
 816
 817 ;;; This calls DEBUG-LOOP, performing some simple initializations
 818 ;;; before doing so. INVOKE-DEBUGGER calls this to actually get into
 819 ;;; the debugger. SB!KERNEL::ERROR-ERROR calls this in emergencies
 820 ;;; to get into a debug prompt as quickly as possible with as little
 821 ;;; risk as possible for stepping on whatever is causing recursive
 822 ;;; errors.
 823 (defun internal-debug ()
 824   (let ((*in-the-debugger* t)
 825         (*read-suppress* nil))
 826     (unless (typep *debug-condition* 'step-condition)
 827       (clear-input *debug-io*))
 828     (debug-loop)))
 829 \f
 830 ;;;; DEBUG-LOOP
 831
 832 ;;; Note: This defaulted to T in CMU CL. The changed default in SBCL
 833 ;;; was motivated by desire to play nicely with ILISP.
 834 (defvar *flush-debug-errors* nil
 835   #!+sb-doc
 836   "When set, avoid calling INVOKE-DEBUGGER recursively when errors occur while
 837    executing in the debugger.")
 838
 839 (defun debug-loop ()
 840   (let* ((*debug-command-level* (1+ *debug-command-level*))
 841          (*real-stack-top* (sb!di:top-frame))
 842          (*stack-top* (or *stack-top-hint* *real-stack-top*))
 843          (*stack-top-hint* nil)
 844          (*current-frame* *stack-top*))
 845     (handler-bind ((sb!di:debug-condition
 846                     (lambda (condition)
 847                       (princ condition *debug-io*)
 848                       (/show0 "handling d-c by THROWing DEBUG-LOOP-CATCHER")
 849                       (throw 'debug-loop-catcher nil))))
 850       (fresh-line)
 851       (print-frame-call *current-frame* :verbosity 2)
 852       (loop
 853         (catch 'debug-loop-catcher
 854           (handler-bind ((error (lambda (condition)
 855                                   (when *flush-debug-errors*
 856                                     (clear-input *debug-io*)
 857                                     (princ condition)
 858                                     ;; FIXME: Doing input on *DEBUG-IO*
 859                                     ;; and output on T seems broken.
 860                                     (format t
 861                                             "~&error flushed (because ~
 862                                              ~S is set)"
 863                                             '*flush-debug-errors*)
 864                                     (/show0 "throwing DEBUG-LOOP-CATCHER")
 865                                     (throw 'debug-loop-catcher nil)))))
 866             ;; We have to bind LEVEL for the restart function created by
 867             ;; WITH-SIMPLE-RESTART.
 868             (let ((level *debug-command-level*)
 869                   (restart-commands (make-restart-commands)))
 870               (with-simple-restart (abort
 871                                    "~@<Reduce debugger level (to debug level ~W).~@:>"
 872                                     level)
 873                 (debug-prompt *debug-io*)
 874                 (force-output *debug-io*)
 875                 (let* ((exp (read *debug-io*))
 876                        (cmd-fun (debug-command-p exp restart-commands)))
 877                   (cond ((not cmd-fun)
 878                          (debug-eval-print exp))
 879                         ((consp cmd-fun)
 880                          (format t "~&Your command, ~S, is ambiguous:~%"
 881                                  exp)
 882                          (dolist (ele cmd-fun)
 883                            (format t "   ~A~%" ele)))
 884                         (t
 885                          (funcall cmd-fun))))))))))))
 886
 887 ;;; FIXME: We could probably use INTERACTIVE-EVAL for much of this logic.
 888 (defun debug-eval-print (expr)
 889   (/noshow "entering DEBUG-EVAL-PRINT" expr)
 890   (/noshow (fboundp 'compile))
 891   (setq +++ ++ ++ + + - - expr)
 892   (let* ((values (multiple-value-list (eval -)))
 893          (*standard-output* *debug-io*))
 894     (/noshow "done with EVAL in DEBUG-EVAL-PRINT")
 895     (fresh-line)
 896     (if values (prin1 (car values)))
 897     (dolist (x (cdr values))
 898       (fresh-line)
 899       (prin1 x))
 900     (setq /// // // / / values)
 901     (setq *** ** ** * * (car values))
 902     ;; Make sure that nobody passes back an unbound marker.
 903     (unless (boundp '*)
 904       (setq * nil)
 905       (fresh-line)
 906       ;; FIXME: The way INTERACTIVE-EVAL does this seems better.
 907       (princ "Setting * to NIL (was unbound marker)."))))
 908 \f
 909 ;;;; debug loop functions
 910
 911 ;;; These commands are functions, not really commands, so that users
 912 ;;; can get their hands on the values returned.
 913
 914 (eval-when (:execute :compile-toplevel)
 915
 916 (sb!xc:defmacro define-var-operation (ref-or-set &optional value-var)
 917   `(let* ((temp (etypecase name
 918                   (symbol (sb!di:debug-fun-symbol-vars
 919                            (sb!di:frame-debug-fun *current-frame*)
 920                            name))
 921                   (simple-string (sb!di:ambiguous-debug-vars
 922                                   (sb!di:frame-debug-fun *current-frame*)
 923                                   name))))
 924           (location (sb!di:frame-code-location *current-frame*))
 925           ;; Let's only deal with valid variables.
 926           (vars (remove-if-not (lambda (v)
 927                                  (eq (sb!di:debug-var-validity v location)
 928                                      :valid))
 929                                temp)))
 930      (declare (list vars))
 931      (cond ((null vars)
 932             (error "No known valid variables match ~S." name))
 933            ((= (length vars) 1)
 934             ,(ecase ref-or-set
 935                (:ref
 936                 '(sb!di:debug-var-value (car vars) *current-frame*))
 937                (:set
 938                 `(setf (sb!di:debug-var-value (car vars) *current-frame*)
 939                        ,value-var))))
 940            (t
 941             ;; Since we have more than one, first see whether we have
 942             ;; any variables that exactly match the specification.
 943             (let* ((name (etypecase name
 944                            (symbol (symbol-name name))
 945                            (simple-string name)))
 946                    ;; FIXME: REMOVE-IF-NOT is deprecated, use STRING/=
 947                    ;; instead.
 948                    (exact (remove-if-not (lambda (v)
 949                                            (string= (sb!di:debug-var-symbol-name v)
 950                                                     name))
 951                                          vars))
 952                    (vars (or exact vars)))
 953               (declare (simple-string name)
 954                        (list exact vars))
 955               (cond
 956                ;; Check now for only having one variable.
 957                ((= (length vars) 1)
 958                 ,(ecase ref-or-set
 959                    (:ref
 960                     '(sb!di:debug-var-value (car vars) *current-frame*))
 961                    (:set
 962                     `(setf (sb!di:debug-var-value (car vars) *current-frame*)
 963                            ,value-var))))
 964                ;; If there weren't any exact matches, flame about
 965                ;; ambiguity unless all the variables have the same
 966                ;; name.
 967                ((and (not exact)
 968                      (find-if-not
 969                       (lambda (v)
 970                         (string= (sb!di:debug-var-symbol-name v)
 971                                  (sb!di:debug-var-symbol-name (car vars))))
 972                       (cdr vars)))
 973                 (error "specification ambiguous:~%~{   ~A~%~}"
 974                        (mapcar #'sb!di:debug-var-symbol-name
 975                                (delete-duplicates
 976                                 vars :test #'string=
 977                                 :key #'sb!di:debug-var-symbol-name))))
 978                ;; All names are the same, so see whether the user
 979                ;; ID'ed one of them.
 980                (id-supplied
 981                 (let ((v (find id vars :key #'sb!di:debug-var-id)))
 982                   (unless v
 983                     (error
 984                      "invalid variable ID, ~W: should have been one of ~S"
 985                      id
 986                      (mapcar #'sb!di:debug-var-id vars)))
 987                   ,(ecase ref-or-set
 988                      (:ref
 989                       '(sb!di:debug-var-value v *current-frame*))
 990                      (:set
 991                       `(setf (sb!di:debug-var-value v *current-frame*)
 992                              ,value-var)))))
 993                (t
 994                 (error "Specify variable ID to disambiguate ~S. Use one of ~S."
 995                        name
 996                        (mapcar #'sb!di:debug-var-id vars)))))))))
 997
 998 ) ; EVAL-WHEN
 999
1000 ;;; FIXME: This doesn't work. It would be real nice we could make it
1001 ;;; work! Alas, it doesn't seem to work in CMU CL X86 either..
1002 (defun var (name &optional (id 0 id-supplied))
1003   #!+sb-doc
1004   "Return a variable's value if possible. NAME is a simple-string or symbol.
1005    If it is a simple-string, it is an initial substring of the variable's name.
1006    If name is a symbol, it has the same name and package as the variable whose
1007    value this function returns. If the symbol is uninterned, then the variable
1008    has the same name as the symbol, but it has no package.
1009
1010    If name is the initial substring of variables with different names, then
1011    this return no values after displaying the ambiguous names. If name
1012    determines multiple variables with the same name, then you must use the
1013    optional id argument to specify which one you want. If you left id
1014    unspecified, then this returns no values after displaying the distinguishing
1015    id values.
1016
1017    The result of this function is limited to the availability of variable
1018    information. This is SETF'able."
1019   (define-var-operation :ref))
1020 (defun (setf var) (value name &optional (id 0 id-supplied))
1021   (define-var-operation :set value))
1022
1023 ;;; This returns the COUNT'th arg as the user sees it from args, the
1024 ;;; result of SB!DI:DEBUG-FUN-LAMBDA-LIST. If this returns a
1025 ;;; potential DEBUG-VAR from the lambda-list, then the second value is
1026 ;;; T. If this returns a keyword symbol or a value from a rest arg,
1027 ;;; then the second value is NIL.
1028 ;;;
1029 ;;; FIXME: There's probably some way to merge the code here with
1030 ;;; FRAME-ARGS-AS-LIST. (A fair amount of logic is already shared
1031 ;;; through LAMBDA-LIST-ELEMENT-DISPATCH, but I suspect more could be.)
1032 (declaim (ftype (function (index list)) nth-arg))
1033 (defun nth-arg (count args)
1034   (let ((n count))
1035     (dolist (ele args (error "The argument specification ~S is out of range."
1036                              n))
1037       (lambda-list-element-dispatch ele
1038         :required ((if (zerop n) (return (values ele t))))
1039         :optional ((if (zerop n) (return (values (second ele) t))))
1040         :keyword ((cond ((zerop n)
1041                          (return (values (second ele) nil)))
1042                         ((zerop (decf n))
1043                          (return (values (third ele) t)))))
1044         :deleted ((if (zerop n) (return (values ele t))))
1045         :rest ((let ((var (second ele)))
1046                  (lambda-var-dispatch var (sb!di:frame-code-location
1047                                            *current-frame*)
1048                    (error "unused &REST argument before n'th argument")
1049                    (dolist (value
1050                             (sb!di:debug-var-value var *current-frame*)
1051                             (error
1052                              "The argument specification ~S is out of range."
1053                              n))
1054                      (if (zerop n)
1055                          (return-from nth-arg (values value nil))
1056                          (decf n)))
1057                    (error "invalid &REST argument before n'th argument")))))
1058       (decf n))))
1059
1060 (defun arg (n)
1061   #!+sb-doc
1062   "Return the N'th argument's value if possible. Argument zero is the first
1063    argument in a frame's default printed representation. Count keyword/value
1064    pairs as separate arguments."
1065   (multiple-value-bind (var lambda-var-p)
1066       (nth-arg n (handler-case (sb!di:debug-fun-lambda-list
1067                                 (sb!di:frame-debug-fun *current-frame*))
1068                    (sb!di:lambda-list-unavailable ()
1069                      (error "No argument values are available."))))
1070     (if lambda-var-p
1071         (lambda-var-dispatch var (sb!di:frame-code-location *current-frame*)
1072           (error "Unused arguments have no values.")
1073           (sb!di:debug-var-value var *current-frame*)
1074           (error "invalid argument value"))
1075         var)))
1076 \f
1077 ;;;; machinery for definition of debug loop commands
1078
1079 (defvar *debug-commands* nil)
1080
1081 ;;; Interface to *DEBUG-COMMANDS*. No required arguments in args are
1082 ;;; permitted.
1083 (defmacro !def-debug-command (name args &rest body)
1084   (let ((fun-name (symbolicate name "-DEBUG-COMMAND")))
1085     `(progn
1086        (setf *debug-commands*
1087              (remove ,name *debug-commands* :key #'car :test #'string=))
1088        (defun ,fun-name ,args
1089          (unless *in-the-debugger*
1090            (error "invoking debugger command while outside the debugger"))
1091          ,@body)
1092        (push (cons ,name #',fun-name) *debug-commands*)
1093        ',fun-name)))
1094
1095 (defun !def-debug-command-alias (new-name existing-name)
1096   (let ((pair (assoc existing-name *debug-commands* :test #'string=)))
1097     (unless pair (error "unknown debug command name: ~S" existing-name))
1098     (push (cons new-name (cdr pair)) *debug-commands*))
1099   new-name)
1100
1101 ;;; This takes a symbol and uses its name to find a debugger command,
1102 ;;; using initial substring matching. It returns the command function
1103 ;;; if form identifies only one command, but if form is ambiguous,
1104 ;;; this returns a list of the command names. If there are no matches,
1105 ;;; this returns nil. Whenever the loop that looks for a set of
1106 ;;; possibilities encounters an exact name match, we return that
1107 ;;; command function immediately.
1108 (defun debug-command-p (form &optional other-commands)
1109   (if (or (symbolp form) (integerp form))
1110       (let* ((name
1111               (if (symbolp form)
1112                   (symbol-name form)
1113                   (format nil "~W" form)))
1114              (len (length name))
1115              (res nil))
1116         (declare (simple-string name)
1117                  (fixnum len)
1118                  (list res))
1119
1120         ;; Find matching commands, punting if exact match.
1121         (flet ((match-command (ele)
1122                  (let* ((str (car ele))
1123                         (str-len (length str)))
1124                    (declare (simple-string str)
1125                             (fixnum str-len))
1126                    (cond ((< str-len len))
1127                          ((= str-len len)
1128                           (when (string= name str :end1 len :end2 len)
1129                             (return-from debug-command-p (cdr ele))))
1130                          ((string= name str :end1 len :end2 len)
1131                           (push ele res))))))
1132           (mapc #'match-command *debug-commands*)
1133           (mapc #'match-command other-commands))
1134
1135         ;; Return the right value.
1136         (cond ((not res) nil)
1137               ((= (length res) 1)
1138                (cdar res))
1139               (t ; Just return the names.
1140                (do ((cmds res (cdr cmds)))
1141                    ((not cmds) res)
1142                  (setf (car cmds) (caar cmds))))))))
1143
1144 ;;; Return a list of debug commands (in the same format as
1145 ;;; *DEBUG-COMMANDS*) that invoke each active restart.
1146 ;;;
1147 ;;; Two commands are made for each restart: one for the number, and
1148 ;;; one for the restart name (unless it's been shadowed by an earlier
1149 ;;; restart of the same name, or it is NIL).
1150 (defun make-restart-commands (&optional (restarts *debug-restarts*))
1151   (let ((commands)
1152         (num 0))                        ; better be the same as show-restarts!
1153     (dolist (restart restarts)
1154       (let ((name (string (restart-name restart))))
1155         (let ((restart-fun
1156                 (lambda ()
1157                   (/show0 "in restart-command closure, about to i-r-i")
1158                   (invoke-restart-interactively restart))))
1159           (push (cons (prin1-to-string num) restart-fun) commands)
1160           (unless (or (null (restart-name restart))
1161                       (find name commands :key #'car :test #'string=))
1162             (push (cons name restart-fun) commands))))
1163     (incf num))
1164   commands))
1165 \f
1166 ;;;; frame-changing commands
1167
1168 (!def-debug-command "UP" ()
1169   (let ((next (sb!di:frame-up *current-frame*)))
1170     (cond (next
1171            (setf *current-frame* next)
1172            (print-frame-call next))
1173           (t
1174            (format t "~&Top of stack.")))))
1175
1176 (!def-debug-command "DOWN" ()
1177   (let ((next (sb!di:frame-down *current-frame*)))
1178     (cond (next
1179            (setf *current-frame* next)
1180            (print-frame-call next))
1181           (t
1182            (format t "~&Bottom of stack.")))))
1183
1184 (!def-debug-command-alias "D" "DOWN")
1185
1186 ;;; CMU CL had this command, but SBCL doesn't, since it's redundant
1187 ;;; with "FRAME 0", and it interferes with abbreviations for the
1188 ;;; TOPLEVEL restart.
1189 ;;;(!def-debug-command "TOP" ()
1190 ;;;  (do ((prev *current-frame* lead)
1191 ;;;       (lead (sb!di:frame-up *current-frame*) (sb!di:frame-up lead)))
1192 ;;;      ((null lead)
1193 ;;;       (setf *current-frame* prev)
1194 ;;;       (print-frame-call prev))))
1195
1196 (!def-debug-command "BOTTOM" ()
1197   (do ((prev *current-frame* lead)
1198        (lead (sb!di:frame-down *current-frame*) (sb!di:frame-down lead)))
1199       ((null lead)
1200        (setf *current-frame* prev)
1201        (print-frame-call prev))))
1202
1203 (!def-debug-command-alias "B" "BOTTOM")
1204
1205 (!def-debug-command "FRAME" (&optional
1206                              (n (read-prompting-maybe "frame number: ")))
1207   (setf *current-frame*
1208         (multiple-value-bind (next-frame-fun limit-string)
1209             (if (< n (sb!di:frame-number *current-frame*))
1210                 (values #'sb!di:frame-up "top")
1211               (values #'sb!di:frame-down "bottom"))
1212           (do ((frame *current-frame*))
1213               ((= n (sb!di:frame-number frame))
1214                frame)
1215             (let ((next-frame (funcall next-frame-fun frame)))
1216               (cond (next-frame
1217                      (setf frame next-frame))
1218                     (t
1219                      (format t
1220                              "The ~A of the stack was encountered.~%"
1221                              limit-string)
1222                      (return frame)))))))
1223   (print-frame-call *current-frame*))
1224
1225 (!def-debug-command-alias "F" "FRAME")
1226 \f
1227 ;;;; commands for entering and leaving the debugger
1228
1229 ;;; CMU CL supported this QUIT debug command, but SBCL provides this
1230 ;;; functionality with a restart instead. (The QUIT debug command was
1231 ;;; removed because it's confusing to have "quit" mean two different
1232 ;;; things in the system, "restart the top level REPL" in the debugger
1233 ;;; and "terminate the Lisp system" as the SB-EXT:QUIT function.)
1234 ;;;
1235 ;;;(!def-debug-command "QUIT" ()
1236 ;;;  (throw 'sb!impl::toplevel-catcher nil))
1237
1238 ;;; CMU CL supported this GO debug command, but SBCL doesn't -- in
1239 ;;; SBCL you just type the CONTINUE restart name instead (or "C" or
1240 ;;; "RESTART CONTINUE", that's OK too).
1241 ;;;(!def-debug-command "GO" ()
1242 ;;;  (continue *debug-condition*)
1243 ;;;  (error "There is no restart named CONTINUE."))
1244
1245 (!def-debug-command "RESTART" ()
1246   (/show0 "doing RESTART debug-command")
1247   (let ((num (read-if-available :prompt)))
1248     (when (eq num :prompt)
1249       (show-restarts *debug-restarts* *debug-io*)
1250       (write-string "restart: ")
1251       (force-output)
1252       (setf num (read *debug-io*)))
1253     (let ((restart (typecase num
1254                      (unsigned-byte
1255                       (nth num *debug-restarts*))
1256                      (symbol
1257                       (find num *debug-restarts* :key #'restart-name
1258                             :test (lambda (sym1 sym2)
1259                                     (string= (symbol-name sym1)
1260                                              (symbol-name sym2)))))
1261                      (t
1262                       (format t "~S is invalid as a restart name.~%" num)
1263                       (return-from restart-debug-command nil)))))
1264       (/show0 "got RESTART")
1265       (if restart
1266           (invoke-restart-interactively restart)
1267           ;; FIXME: Even if this isn't handled by WARN, it probably
1268           ;; shouldn't go to *STANDARD-OUTPUT*, but *ERROR-OUTPUT* or
1269           ;; *QUERY-IO* or something. Look through this file to
1270           ;; straighten out stream usage.
1271           (princ "There is no such restart.")))))
1272 \f
1273 ;;;; information commands
1274
1275 (!def-debug-command "HELP" ()
1276   ;; CMU CL had a little toy pager here, but "if you aren't running
1277   ;; ILISP (or a smart windowing system, or something) you deserve to
1278   ;; lose", so we've dropped it in SBCL. However, in case some
1279   ;; desperate holdout is running this on a dumb terminal somewhere,
1280   ;; we tell him where to find the message stored as a string.
1281   (format *debug-io*
1282           "~&~A~2%(The HELP string is stored in ~S.)~%"
1283           *debug-help-string*
1284           '*debug-help-string*))
1285
1286 (!def-debug-command-alias "?" "HELP")
1287
1288 (!def-debug-command "ERROR" ()
1289   (format *debug-io* "~A~%" *debug-condition*)
1290   (show-restarts *debug-restarts* *debug-io*))
1291
1292 (!def-debug-command "BACKTRACE" ()
1293   (backtrace (read-if-available most-positive-fixnum)))
1294
1295 (!def-debug-command "PRINT" ()
1296   (print-frame-call *current-frame*))
1297
1298 (!def-debug-command-alias "P" "PRINT")
1299
1300 (!def-debug-command "LIST-LOCALS" ()
1301   (let ((d-fun (sb!di:frame-debug-fun *current-frame*)))
1302     (if (sb!di:debug-var-info-available d-fun)
1303         (let ((*standard-output* *debug-io*)
1304               (location (sb!di:frame-code-location *current-frame*))
1305               (prefix (read-if-available nil))
1306               (any-p nil)
1307               (any-valid-p nil))
1308           (dolist (v (sb!di:ambiguous-debug-vars
1309                         d-fun
1310                         (if prefix (string prefix) "")))
1311             (setf any-p t)
1312             (when (eq (sb!di:debug-var-validity v location) :valid)
1313               (setf any-valid-p t)
1314               (format t "~S~:[#~W~;~*~]  =  ~S~%"
1315                       (sb!di:debug-var-symbol v)
1316                       (zerop (sb!di:debug-var-id v))
1317                       (sb!di:debug-var-id v)
1318                       (sb!di:debug-var-value v *current-frame*))))
1319
1320           (cond
1321            ((not any-p)
1322             (format t "There are no local variables ~@[starting with ~A ~]~
1323                        in the function."
1324                     prefix))
1325            ((not any-valid-p)
1326             (format t "All variables ~@[starting with ~A ~]currently ~
1327                        have invalid values."
1328                     prefix))))
1329         (write-line "There is no variable information available."))))
1330
1331 (!def-debug-command-alias "L" "LIST-LOCALS")
1332
1333 (!def-debug-command "SOURCE" ()
1334   (fresh-line)
1335   (print-code-location-source-form (sb!di:frame-code-location *current-frame*)
1336                                    (read-if-available 0)))
1337 \f
1338 ;;;; source location printing
1339
1340 ;;; We cache a stream to the last valid file debug source so that we
1341 ;;; won't have to repeatedly open the file.
1342 ;;;
1343 ;;; KLUDGE: This sounds like a bug, not a feature. Opening files is fast
1344 ;;; in the 1990s, so the benefit is negligible, less important than the
1345 ;;; potential of extra confusion if someone changes the source during
1346 ;;; a debug session and the change doesn't show up. And removing this
1347 ;;; would simplify the system, which I like. -- WHN 19990903
1348 (defvar *cached-debug-source* nil)
1349 (declaim (type (or sb!di:debug-source null) *cached-debug-source*))
1350 (defvar *cached-source-stream* nil)
1351 (declaim (type (or stream null) *cached-source-stream*))
1352
1353 ;;; To suppress the read-time evaluation #. macro during source read,
1354 ;;; *READTABLE* is modified. *READTABLE* is cached to avoid
1355 ;;; copying it each time, and invalidated when the
1356 ;;; *CACHED-DEBUG-SOURCE* has changed.
1357 (defvar *cached-readtable* nil)
1358 (declaim (type (or readtable null) *cached-readtable*))
1359
1360 (pushnew (lambda ()
1361            (setq *cached-debug-source* nil *cached-source-stream* nil
1362                  *cached-readtable* nil))
1363          *before-save-initializations*)
1364
1365 ;;; We also cache the last toplevel form that we printed a source for
1366 ;;; so that we don't have to do repeated reads and calls to
1367 ;;; FORM-NUMBER-TRANSLATIONS.
1368 (defvar *cached-toplevel-form-offset* nil)
1369 (declaim (type (or index null) *cached-toplevel-form-offset*))
1370 (defvar *cached-toplevel-form*)
1371 (defvar *cached-form-number-translations*)
1372
1373 ;;; Given a code location, return the associated form-number
1374 ;;; translations and the actual top level form. We check our cache ---
1375 ;;; if there is a miss, we dispatch on the kind of the debug source.
1376 (defun get-toplevel-form (location)
1377   (let ((d-source (sb!di:code-location-debug-source location)))
1378     (if (and (eq d-source *cached-debug-source*)
1379              (eql (sb!di:code-location-toplevel-form-offset location)
1380                   *cached-toplevel-form-offset*))
1381         (values *cached-form-number-translations* *cached-toplevel-form*)
1382         (let* ((offset (sb!di:code-location-toplevel-form-offset location))
1383                (res
1384                 (ecase (sb!di:debug-source-from d-source)
1385                   (:file (get-file-toplevel-form location))
1386                   (:lisp (svref (sb!di:debug-source-name d-source) offset)))))
1387           (setq *cached-toplevel-form-offset* offset)
1388           (values (setq *cached-form-number-translations*
1389                         (sb!di:form-number-translations res offset))
1390                   (setq *cached-toplevel-form* res))))))
1391
1392 ;;; Locate the source file (if it still exists) and grab the top level
1393 ;;; form. If the file is modified, we use the top level form offset
1394 ;;; instead of the recorded character offset.
1395 (defun get-file-toplevel-form (location)
1396   (let* ((d-source (sb!di:code-location-debug-source location))
1397          (tlf-offset (sb!di:code-location-toplevel-form-offset location))
1398          (local-tlf-offset (- tlf-offset
1399                               (sb!di:debug-source-root-number d-source)))
1400          (char-offset
1401           (aref (or (sb!di:debug-source-start-positions d-source)
1402                     (error "no start positions map"))
1403                 local-tlf-offset))
1404          (name (sb!di:debug-source-name d-source)))
1405     (unless (eq d-source *cached-debug-source*)
1406       (unless (and *cached-source-stream*
1407                    (equal (pathname *cached-source-stream*)
1408                           (pathname name)))
1409         (setq *cached-readtable* nil)
1410         (when *cached-source-stream* (close *cached-source-stream*))
1411         (setq *cached-source-stream* (open name :if-does-not-exist nil))
1412         (unless *cached-source-stream*
1413           (error "The source file no longer exists:~%  ~A" (namestring name)))
1414         (format t "~%; file: ~A~%" (namestring name)))
1415
1416         (setq *cached-debug-source*
1417               (if (= (sb!di:debug-source-created d-source)
1418                      (file-write-date name))
1419                   d-source nil)))
1420
1421     (cond
1422      ((eq *cached-debug-source* d-source)
1423       (file-position *cached-source-stream* char-offset))
1424      (t
1425       (format t "~%; File has been modified since compilation:~%;   ~A~@
1426                  ; Using form offset instead of character position.~%"
1427               (namestring name))
1428       (file-position *cached-source-stream* 0)
1429       (let ((*read-suppress* t))
1430         (dotimes (i local-tlf-offset)
1431           (read *cached-source-stream*)))))
1432     (unless *cached-readtable*
1433       (setq *cached-readtable* (copy-readtable))
1434       (set-dispatch-macro-character
1435        #\# #\.
1436        (lambda (stream sub-char &rest rest)
1437          (declare (ignore rest sub-char))
1438          (let ((token (read stream t nil t)))
1439            (format nil "#.~S" token)))
1440        *cached-readtable*))
1441     (let ((*readtable* *cached-readtable*))
1442       (read *cached-source-stream*))))
1443
1444 (defun print-code-location-source-form (location context)
1445   (let* ((location (maybe-block-start-location location))
1446          (form-num (sb!di:code-location-form-number location)))
1447     (multiple-value-bind (translations form) (get-toplevel-form location)
1448       (unless (< form-num (length translations))
1449         (error "The source path no longer exists."))
1450       (prin1 (sb!di:source-path-context form
1451                                         (svref translations form-num)
1452                                         context)))))
1453 \f
1454 ;;; breakpoint and step commands
1455
1456 ;;; Step to the next code-location.
1457 (!def-debug-command "STEP" ()
1458   (setf *number-of-steps* (read-if-available 1))
1459   (set-step-breakpoint *current-frame*)
1460   (continue *debug-condition*)
1461   (error "couldn't continue"))
1462
1463 ;;; List possible breakpoint locations, which ones are active, and
1464 ;;; where the CONTINUE restart will transfer control. Set
1465 ;;; *POSSIBLE-BREAKPOINTS* to the code-locations which can then be
1466 ;;; used by sbreakpoint.
1467 (!def-debug-command "LIST-LOCATIONS" ()
1468   (let ((df (read-if-available *default-breakpoint-debug-fun*)))
1469     (cond ((consp df)
1470            (setf df (sb!di:fun-debug-fun (eval df)))
1471            (setf *default-breakpoint-debug-fun* df))
1472           ((or (eq ':c df)
1473                (not *default-breakpoint-debug-fun*))
1474            (setf df (sb!di:frame-debug-fun *current-frame*))
1475            (setf *default-breakpoint-debug-fun* df)))
1476     (setf *possible-breakpoints* (possible-breakpoints df)))
1477   (let ((continue-at (sb!di:frame-code-location *current-frame*)))
1478     (let ((active (location-in-list *default-breakpoint-debug-fun*
1479                                     *breakpoints* :fun-start))
1480           (here (sb!di:code-location=
1481                  (sb!di:debug-fun-start-location
1482                   *default-breakpoint-debug-fun*) continue-at)))
1483       (when (or active here)
1484         (format t "::FUN-START ")
1485         (when active (format t " *Active*"))
1486         (when here (format t " *Continue here*"))))
1487
1488     (let ((prev-location nil)
1489           (prev-num 0)
1490           (this-num 0))
1491       (flet ((flush ()
1492                (when prev-location
1493                  (let ((this-num (1- this-num)))
1494                    (if (= prev-num this-num)
1495                        (format t "~&~W: " prev-num)
1496                        (format t "~&~W-~W: " prev-num this-num)))
1497                  (print-code-location-source-form prev-location 0)
1498                  (when *print-location-kind*
1499                    (format t "~S " (sb!di:code-location-kind prev-location)))
1500                  (when (location-in-list prev-location *breakpoints*)
1501                    (format t " *Active*"))
1502                  (when (sb!di:code-location= prev-location continue-at)
1503                    (format t " *Continue here*")))))
1504
1505         (dolist (code-location *possible-breakpoints*)
1506           (when (or *print-location-kind*
1507                     (location-in-list code-location *breakpoints*)
1508                     (sb!di:code-location= code-location continue-at)
1509                     (not prev-location)
1510                     (not (eq (sb!di:code-location-debug-source code-location)
1511                              (sb!di:code-location-debug-source prev-location)))
1512                     (not (eq (sb!di:code-location-toplevel-form-offset
1513                               code-location)
1514                              (sb!di:code-location-toplevel-form-offset
1515                               prev-location)))
1516                     (not (eq (sb!di:code-location-form-number code-location)
1517                              (sb!di:code-location-form-number prev-location))))
1518             (flush)
1519             (setq prev-location code-location  prev-num this-num))
1520
1521           (incf this-num))))
1522
1523     (when (location-in-list *default-breakpoint-debug-fun*
1524                             *breakpoints*
1525                             :fun-end)
1526       (format t "~&::FUN-END *Active* "))))
1527
1528 (!def-debug-command-alias "LL" "LIST-LOCATIONS")
1529
1530 ;;; Set breakpoint at the given number.
1531 (!def-debug-command "BREAKPOINT" ()
1532   (let ((index (read-prompting-maybe "location number, :START, or :END: "))
1533         (break t)
1534         (condition t)
1535         (print nil)
1536         (print-functions nil)
1537         (function nil)
1538         (bp)
1539         (place *default-breakpoint-debug-fun*))
1540     (flet ((get-command-line ()
1541              (let ((command-line nil)
1542                    (unique '(nil)))
1543                (loop
1544                  (let ((next-input (read-if-available unique)))
1545                    (when (eq next-input unique) (return))
1546                    (push next-input command-line)))
1547                (nreverse command-line)))
1548            (set-vars-from-command-line (command-line)
1549              (do ((arg (pop command-line) (pop command-line)))
1550                  ((not arg))
1551                (ecase arg
1552                  (:condition (setf condition (pop command-line)))
1553                  (:print (push (pop command-line) print))
1554                  (:break (setf break (pop command-line)))
1555                  (:function
1556                   (setf function (eval (pop command-line)))
1557                   (setf *default-breakpoint-debug-fun*
1558                         (sb!di:fun-debug-fun function))
1559                   (setf place *default-breakpoint-debug-fun*)
1560                   (setf *possible-breakpoints*
1561                         (possible-breakpoints
1562                          *default-breakpoint-debug-fun*))))))
1563            (setup-fun-start ()
1564              (let ((code-loc (sb!di:debug-fun-start-location place)))
1565                (setf bp (sb!di:make-breakpoint #'main-hook-fun
1566                                                place
1567                                                :kind :fun-start))
1568                (setf break (sb!di:preprocess-for-eval break code-loc))
1569                (setf condition (sb!di:preprocess-for-eval condition code-loc))
1570                (dolist (form print)
1571                  (push (cons (sb!di:preprocess-for-eval form code-loc) form)
1572                        print-functions))))
1573            (setup-fun-end ()
1574              (setf bp
1575                    (sb!di:make-breakpoint #'main-hook-fun
1576                                           place
1577                                           :kind :fun-end))
1578              (setf break
1579                    ;; FIXME: These and any other old (COERCE `(LAMBDA ..) ..)
1580                    ;; forms should be converted to shiny new (LAMBDA ..) forms.
1581                    ;; (Search the sources for "coerce.*\(lambda".)
1582                    (coerce `(lambda (dummy)
1583                               (declare (ignore dummy)) ,break)
1584                            'function))
1585              (setf condition (coerce `(lambda (dummy)
1586                                         (declare (ignore dummy)) ,condition)
1587                                      'function))
1588              (dolist (form print)
1589                (push (cons
1590                       (coerce `(lambda (dummy)
1591                                  (declare (ignore dummy)) ,form) 'function)
1592                       form)
1593                      print-functions)))
1594            (setup-code-location ()
1595              (setf place (nth index *possible-breakpoints*))
1596              (setf bp (sb!di:make-breakpoint #'main-hook-fun place
1597                                              :kind :code-location))
1598              (dolist (form print)
1599                (push (cons
1600                       (sb!di:preprocess-for-eval form place)
1601                       form)
1602                      print-functions))
1603              (setf break (sb!di:preprocess-for-eval break place))
1604              (setf condition (sb!di:preprocess-for-eval condition place))))
1605       (set-vars-from-command-line (get-command-line))
1606       (cond
1607        ((or (eq index :start) (eq index :s))
1608         (setup-fun-start))
1609        ((or (eq index :end) (eq index :e))
1610         (setup-fun-end))
1611        (t
1612         (setup-code-location)))
1613       (sb!di:activate-breakpoint bp)
1614       (let* ((new-bp-info (create-breakpoint-info place bp index
1615                                                   :break break
1616                                                   :print print-functions
1617                                                   :condition condition))
1618              (old-bp-info (location-in-list new-bp-info *breakpoints*)))
1619         (when old-bp-info
1620           (sb!di:deactivate-breakpoint (breakpoint-info-breakpoint
1621                                         old-bp-info))
1622           (setf *breakpoints* (remove old-bp-info *breakpoints*))
1623           (format t "previous breakpoint removed~%"))
1624         (push new-bp-info *breakpoints*))
1625       (print-breakpoint-info (first *breakpoints*))
1626       (format t "~&added"))))
1627
1628 (!def-debug-command-alias "BP" "BREAKPOINT")
1629
1630 ;;; List all breakpoints which are set.
1631 (!def-debug-command "LIST-BREAKPOINTS" ()
1632   (setf *breakpoints*
1633         (sort *breakpoints* #'< :key #'breakpoint-info-breakpoint-number))
1634   (dolist (info *breakpoints*)
1635     (print-breakpoint-info info)))
1636
1637 (!def-debug-command-alias "LB" "LIST-BREAKPOINTS")
1638 (!def-debug-command-alias "LBP" "LIST-BREAKPOINTS")
1639
1640 ;;; Remove breakpoint N, or remove all breakpoints if no N given.
1641 (!def-debug-command "DELETE-BREAKPOINT" ()
1642   (let* ((index (read-if-available nil))
1643          (bp-info
1644           (find index *breakpoints* :key #'breakpoint-info-breakpoint-number)))
1645     (cond (bp-info
1646            (sb!di:delete-breakpoint (breakpoint-info-breakpoint bp-info))
1647            (setf *breakpoints* (remove bp-info *breakpoints*))
1648            (format t "breakpoint ~S removed~%" index))
1649           (index (format t "The breakpoint doesn't exist."))
1650           (t
1651            (dolist (ele *breakpoints*)
1652              (sb!di:delete-breakpoint (breakpoint-info-breakpoint ele)))
1653            (setf *breakpoints* nil)
1654            (format t "all breakpoints deleted~%")))))
1655
1656 (!def-debug-command-alias "DBP" "DELETE-BREAKPOINT")
1657 \f
1658 ;;; miscellaneous commands
1659
1660 (!def-debug-command "DESCRIBE" ()
1661   (let* ((curloc (sb!di:frame-code-location *current-frame*))
1662          (debug-fun (sb!di:code-location-debug-fun curloc))
1663          (function (sb!di:debug-fun-fun debug-fun)))
1664     (if function
1665         (describe function)
1666         (format t "can't figure out the function for this frame"))))
1667
1668 (!def-debug-command "SLURP" ()
1669   (loop while (read-char-no-hang *standard-input*)))
1670
1671 (!def-debug-command "RETURN" (&optional
1672                               (return (read-prompting-maybe
1673                                        "return: ")))
1674   (let ((tag (find-if (lambda (x)
1675                         (and (typep (car x) 'symbol)
1676                              (not (symbol-package (car x)))
1677                              (string= (car x) "SB-DEBUG-CATCH-TAG")))
1678                       (sb!di::frame-catches *current-frame*))))
1679     (if tag
1680         (throw (car tag)
1681           (funcall (sb!di:preprocess-for-eval
1682                     return
1683                     (sb!di:frame-code-location *current-frame*))
1684                    *current-frame*))
1685         (format t "~@<can't find a tag for this frame ~
1686                    ~2I~_(hint: try increasing the DEBUG optimization quality ~
1687                    and recompiling)~:@>"))))
1688 \f
1689 ;;;; debug loop command utilities
1690
1691 (defun read-prompting-maybe (prompt)
1692   (unless (sb!int:listen-skip-whitespace *debug-io*)
1693     (princ prompt)
1694     (force-output))
1695   (read *debug-io*))
1696
1697 (defun read-if-available (default)
1698   (if (sb!int:listen-skip-whitespace *debug-io*)
1699       (read *debug-io*)
1700       default))