src/code/debug.lisp

   1 ;;;; the debugger
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!DEBUG")
  13 \f
  14 ;;;; variables and constants
  15
  16 (defvar *debug-print-level* 3
  17   #!+sb-doc
  18   "*PRINT-LEVEL* for the debugger")
  19
  20 (defvar *debug-print-length* 5
  21   #!+sb-doc
  22   "*PRINT-LENGTH* for the debugger")
  23
  24 (defvar *debug-readtable*
  25   ;; KLUDGE: This can't be initialized in a cold toplevel form,
  26   ;; because the *STANDARD-READTABLE* isn't initialized until after
  27   ;; cold toplevel forms have run. So instead we initialize it
  28   ;; immediately after *STANDARD-READTABLE*. -- WHN 20000205
  29   nil
  30   #!+sb-doc
  31   "*READTABLE* for the debugger")
  32
  33 (defvar *in-the-debugger* nil
  34   #!+sb-doc
  35   "This is T while in the debugger.")
  36
  37 ;;; nestedness inside debugger command loops
  38 (defvar *debug-command-level* 0)
  39
  40 (defvar *stack-top-hint* nil
  41   #!+sb-doc
  42   "If this is bound before the debugger is invoked, it is used as the stack
  43    top by the debugger.")
  44 (defvar *stack-top* nil)
  45 (defvar *real-stack-top* nil)
  46
  47 (defvar *current-frame* nil)
  48
  49 (defun debug-prompt (stream)
  50
  51   ;; old behavior, will probably go away in sbcl-0.7.x
  52   (format stream "~%~D" (sb!di:frame-number *current-frame*))
  53   (dotimes (i *debug-command-level*)
  54     (write-char #\] stream))
  55   (write-char #\space stream)
  56
  57   ;; planned new behavior, delayed since it will break ILISP
  58   #+nil
  59   (format stream
  60           "~%~D~:[~;[~D~]] "
  61           (sb!di:frame-number *current-frame*)
  62           (> *debug-command-level* 1)
  63           *debug-command-level*))
  64
  65 (defparameter *debug-help-string*
  66 "The prompt is right square brackets, the number indicating how many
  67   recursive command loops you are in.
  68 Any command may be uniquely abbreviated.
  69 The debugger rebinds various special variables for controlling i/o, sometimes
  70   to defaults (much like WITH-STANDARD-IO-SYNTAX does) and sometimes to
  71   its own special values, e.g. SB-DEBUG:*DEBUG-PRINT-LEVEL*.
  72 Debug commands do not affect * and friends, but evaluation in the debug loop
  73   does affect these variables.
  74 SB-DEBUG:*FLUSH-DEBUG-ERRORS* controls whether errors at the debug prompt
  75   drop you into deeper into the debugger.
  76
  77 Getting in and out of the debugger:
  78   RESTART  invokes restart numbered as shown (prompt if not given).
  79   ERROR    prints the error condition and restart cases.
  80   The name of any restart, or its number, is a valid command, and is the same
  81     as using RESTART to invoke that restart.
  82
  83 Changing frames:
  84   U      up frame     D    down frame
  85   B  bottom frame     F n  frame n (n=0 for top frame)
  86
  87 Inspecting frames:
  88   BACKTRACE [n]  shows n frames going down the stack.
  89   LIST-LOCALS, L lists locals in current function.
  90   PRINT, P       displays current function call.
  91   SOURCE [n]     displays frame's source form with n levels of enclosing forms.
  92
  93 Breakpoints and steps:
  94   LIST-LOCATIONS [{function | :C}]   List the locations for breakpoints.
  95                                      Specify :C for the current frame.
  96     Abbreviation: LL
  97   LIST-BREAKPOINTS                   List the active breakpoints.
  98     Abbreviations: LB, LBP
  99   DELETE-BREAKPOINT [n]              Remove breakpoint n or all breakpoints.
 100     Abbreviations: DEL, DBP
 101   BREAKPOINT {n | :end | :start} [:break form] [:function function]
 102              [{:print form}*] [:condition form]
 103                                      Set a breakpoint.
 104     Abbreviations: BR, BP
 105   STEP [n]                           Step to the next location or step n times.
 106
 107 Function and macro commands:
 108  (SB-DEBUG:DEBUG-RETURN expression)
 109     Exit the debugger, returning expression's values from the current frame.
 110  (SB-DEBUG:ARG n)
 111     Return the n'th argument in the current frame.
 112  (SB-DEBUG:VAR string-or-symbol [id])
 113     Returns the value of the specified variable in the current frame.")
 114 \f
 115 ;;; This is used to communicate to DEBUG-LOOP that we are at a step breakpoint.
 116 (define-condition step-condition (simple-condition) ())
 117 \f
 118 ;;;; breakpoint state
 119
 120 (defvar *only-block-start-locations* nil
 121   #!+sb-doc
 122   "When true, the LIST-LOCATIONS command only displays block start locations.
 123    Otherwise, all locations are displayed.")
 124
 125 (defvar *print-location-kind* nil
 126   #!+sb-doc
 127   "When true, list the code location type in the LIST-LOCATIONS command.")
 128
 129 ;;; a list of the types of code-locations that should not be stepped
 130 ;;; to and should not be listed when listing breakpoints
 131 (defvar *bad-code-location-types* '(:call-site :internal-error))
 132 (declaim (type list *bad-code-location-types*))
 133
 134 ;;; code locations of the possible breakpoints
 135 (defvar *possible-breakpoints*)
 136 (declaim (type list *possible-breakpoints*))
 137
 138 ;;; a list of the made and active breakpoints, each is a
 139 ;;; BREAKPOINT-INFO structure
 140 (defvar *breakpoints* nil)
 141 (declaim (type list *breakpoints*))
 142
 143 ;;; a list of BREAKPOINT-INFO structures of the made and active step
 144 ;;; breakpoints
 145 (defvar *step-breakpoints* nil)
 146 (declaim (type list *step-breakpoints*))
 147
 148 ;;; the number of times left to step
 149 (defvar *number-of-steps* 1)
 150 (declaim (type integer *number-of-steps*))
 151
 152 ;;; This is used when listing and setting breakpoints.
 153 (defvar *default-breakpoint-debug-function* nil)
 154 (declaim (type (or list sb!di:debug-function) *default-breakpoint-debug-function*))
 155 \f
 156 ;;;; code location utilities
 157
 158 ;;; Return the first code-location in the passed debug block.
 159 (defun first-code-location (debug-block)
 160   (let ((found nil)
 161         (first-code-location nil))
 162     (sb!di:do-debug-block-locations (code-location debug-block)
 163       (unless found
 164         (setf first-code-location code-location)
 165         (setf found t)))
 166     first-code-location))
 167
 168 ;;; Return a list of the next code-locations following the one passed.
 169 ;;; One of the *BAD-CODE-LOCATION-TYPES* will not be returned.
 170 (defun next-code-locations (code-location)
 171   (let ((debug-block (sb!di:code-location-debug-block code-location))
 172         (block-code-locations nil))
 173     (sb!di:do-debug-block-locations (block-code-location debug-block)
 174       (unless (member (sb!di:code-location-kind block-code-location)
 175                       *bad-code-location-types*)
 176         (push block-code-location block-code-locations)))
 177     (setf block-code-locations (nreverse block-code-locations))
 178     (let* ((code-loc-list (rest (member code-location block-code-locations
 179                                         :test #'sb!di:code-location=)))
 180            (next-list (cond (code-loc-list
 181                              (list (first code-loc-list)))
 182                             ((map 'list #'first-code-location
 183                                   (sb!di:debug-block-successors debug-block)))
 184                             (t nil))))
 185       (when (and (= (length next-list) 1)
 186                  (sb!di:code-location= (first next-list) code-location))
 187         (setf next-list (next-code-locations (first next-list))))
 188       next-list)))
 189
 190 ;;; Returns a list of code-locations of the possible breakpoints of the
 191 ;;; debug-function passed.
 192 (defun possible-breakpoints (debug-function)
 193   (let ((possible-breakpoints nil))
 194     (sb!di:do-debug-function-blocks (debug-block debug-function)
 195       (unless (sb!di:debug-block-elsewhere-p debug-block)
 196         (if *only-block-start-locations*
 197             (push (first-code-location debug-block) possible-breakpoints)
 198             (sb!di:do-debug-block-locations (code-location debug-block)
 199               (when (not (member (sb!di:code-location-kind code-location)
 200                                  *bad-code-location-types*))
 201                 (push code-location possible-breakpoints))))))
 202     (nreverse possible-breakpoints)))
 203
 204 ;;; Searches the info-list for the item passed (code-location,
 205 ;;; debug-function, or breakpoint-info). If the item passed is a debug
 206 ;;; function then kind will be compared if it was specified. The kind
 207 ;;; if also compared if a breakpoint-info is passed since it's in the
 208 ;;; breakpoint. The info structure is returned if found.
 209 (defun location-in-list (place info-list &optional (kind nil))
 210   (when (breakpoint-info-p place)
 211     (setf kind (sb!di:breakpoint-kind (breakpoint-info-breakpoint place)))
 212     (setf place (breakpoint-info-place place)))
 213   (cond ((sb!di:code-location-p place)
 214          (find place info-list
 215                :key #'breakpoint-info-place
 216                :test #'(lambda (x y) (and (sb!di:code-location-p y)
 217                                           (sb!di:code-location= x y)))))
 218         (t
 219          (find place info-list
 220                :test #'(lambda (x-debug-function y-info)
 221                          (let ((y-place (breakpoint-info-place y-info))
 222                                (y-breakpoint (breakpoint-info-breakpoint
 223                                               y-info)))
 224                            (and (sb!di:debug-function-p y-place)
 225                                 (eq x-debug-function y-place)
 226                                 (or (not kind)
 227                                     (eq kind (sb!di:breakpoint-kind
 228                                               y-breakpoint))))))))))
 229
 230 ;;; If LOC is an unknown location, then try to find the block start
 231 ;;; location. Used by source printing to some information instead of
 232 ;;; none for the user.
 233 (defun maybe-block-start-location (loc)
 234   (if (sb!di:code-location-unknown-p loc)
 235       (let* ((block (sb!di:code-location-debug-block loc))
 236              (start (sb!di:do-debug-block-locations (loc block)
 237                       (return loc))))
 238         (cond ((and (not (sb!di:debug-block-elsewhere-p block))
 239                     start)
 240                ;; FIXME: Why output on T instead of *DEBUG-FOO* or something?
 241                (format t "~%unknown location: using block start~%")
 242                start)
 243               (t
 244                loc)))
 245       loc))
 246 \f
 247 ;;;; the BREAKPOINT-INFO structure
 248
 249 ;;; info about a made breakpoint
 250 (defstruct (breakpoint-info (:copier nil))
 251   ;; where we are going to stop
 252   (place (required-argument)
 253          :type (or sb!di:code-location sb!di:debug-function))
 254   ;; the breakpoint returned by sb!di:make-breakpoint
 255   (breakpoint (required-argument) :type sb!di:breakpoint)
 256   ;; the function returned from sb!di:preprocess-for-eval. If result is
 257   ;; non-NIL, drop into the debugger.
 258   (break #'identity :type function)
 259   ;; the function returned from sb!di:preprocess-for-eval. If result is
 260   ;; non-NIL, eval (each) print and print results.
 261   (condition #'identity :type function)
 262   ;; the list of functions from sb!di:preprocess-for-eval to evaluate.
 263   ;; Results are conditionally printed. Car of each element is the
 264   ;; function, cdr is the form it goes with.
 265   (print nil :type list)
 266   ;; the number used when listing the possible breakpoints within a
 267   ;; function. Could also be a symbol such as start or end.
 268   (code-location-number (required-argument) :type (or symbol integer))
 269   ;; the number used when listing the breakpoints active and to delete
 270   ;; breakpoints
 271   (breakpoint-number (required-argument) :type integer))
 272
 273 ;;; Return a new BREAKPOINT-INFO structure with the info passed.
 274 (defun create-breakpoint-info (place breakpoint code-location-number
 275                                      &key (break #'identity)
 276                                      (condition #'identity) (print nil))
 277   (setf *breakpoints*
 278         (sort *breakpoints* #'< :key #'breakpoint-info-breakpoint-number))
 279   (let ((breakpoint-number
 280          (do ((i 1 (incf i)) (breakpoints *breakpoints* (rest breakpoints)))
 281              ((or (> i (length *breakpoints*))
 282                   (not (= i (breakpoint-info-breakpoint-number
 283                              (first breakpoints)))))
 284
 285               i))))
 286     (make-breakpoint-info :place place :breakpoint breakpoint
 287                           :code-location-number code-location-number
 288                           :breakpoint-number breakpoint-number
 289                           :break break :condition condition :print print)))
 290
 291 ;;; Print the breakpoint info for the breakpoint-info structure passed.
 292 (defun print-breakpoint-info (breakpoint-info)
 293   (let ((place (breakpoint-info-place breakpoint-info))
 294         (bp-number (breakpoint-info-breakpoint-number breakpoint-info))
 295         (loc-number (breakpoint-info-code-location-number breakpoint-info)))
 296     (case (sb!di:breakpoint-kind (breakpoint-info-breakpoint breakpoint-info))
 297       (:code-location
 298        (print-code-location-source-form place 0)
 299        (format t
 300                "~&~S: ~S in ~S"
 301                bp-number
 302                loc-number
 303                (sb!di:debug-function-name (sb!di:code-location-debug-function
 304                                            place))))
 305       (:function-start
 306        (format t "~&~S: FUNCTION-START in ~S" bp-number
 307                (sb!di:debug-function-name place)))
 308       (:function-end
 309        (format t "~&~S: FUNCTION-END in ~S" bp-number
 310                (sb!di:debug-function-name place))))))
 311 \f
 312 ;;;; MAIN-HOOK-FUNCTION for steps and breakpoints
 313
 314 ;;; This must be passed as the hook function. It keeps track of where
 315 ;;; STEP breakpoints are.
 316 (defun main-hook-function (current-frame breakpoint &optional return-vals
 317                                          function-end-cookie)
 318   (setf *default-breakpoint-debug-function*
 319         (sb!di:frame-debug-function current-frame))
 320   (dolist (step-info *step-breakpoints*)
 321     (sb!di:delete-breakpoint (breakpoint-info-breakpoint step-info))
 322     (let ((bp-info (location-in-list step-info *breakpoints*)))
 323       (when bp-info
 324         (sb!di:activate-breakpoint (breakpoint-info-breakpoint bp-info)))))
 325   (let ((*stack-top-hint* current-frame)
 326         (step-hit-info
 327          (location-in-list (sb!di:breakpoint-what breakpoint)
 328                            *step-breakpoints*
 329                            (sb!di:breakpoint-kind breakpoint)))
 330         (bp-hit-info
 331          (location-in-list (sb!di:breakpoint-what breakpoint)
 332                            *breakpoints*
 333                            (sb!di:breakpoint-kind breakpoint)))
 334         (break)
 335         (condition)
 336         (string ""))
 337     (setf *step-breakpoints* nil)
 338     (labels ((build-string (str)
 339                (setf string (concatenate 'string string str)))
 340              (print-common-info ()
 341                (build-string
 342                 (with-output-to-string (*standard-output*)
 343                   (when function-end-cookie
 344                     (format t "~%Return values: ~S" return-vals))
 345                   (when condition
 346                     (when (breakpoint-info-print bp-hit-info)
 347                       (format t "~%")
 348                       (print-frame-call current-frame))
 349                     (dolist (print (breakpoint-info-print bp-hit-info))
 350                       (format t "~& ~S = ~S" (rest print)
 351                               (funcall (first print) current-frame))))))))
 352       (when bp-hit-info
 353         (setf break (funcall (breakpoint-info-break bp-hit-info)
 354                              current-frame))
 355         (setf condition (funcall (breakpoint-info-condition bp-hit-info)
 356                                  current-frame)))
 357       (cond ((and bp-hit-info step-hit-info (= 1 *number-of-steps*))
 358              (build-string (format nil "~&*Step (to a breakpoint)*"))
 359              (print-common-info)
 360              (break string))
 361             ((and bp-hit-info step-hit-info break)
 362              (build-string (format nil "~&*Step (to a breakpoint)*"))
 363              (print-common-info)
 364              (break string))
 365             ((and bp-hit-info step-hit-info)
 366              (print-common-info)
 367              (format t "~A" string)
 368              (decf *number-of-steps*)
 369              (set-step-breakpoint current-frame))
 370             ((and step-hit-info (= 1 *number-of-steps*))
 371              (build-string "*Step*")
 372              (break (make-condition 'step-condition :format-control string)))
 373             (step-hit-info
 374              (decf *number-of-steps*)
 375              (set-step-breakpoint current-frame))
 376             (bp-hit-info
 377              (when break
 378                (build-string (format nil "~&*Breakpoint hit*")))
 379              (print-common-info)
 380              (if break
 381                  (break string)
 382                  (format t "~A" string)))
 383             (t
 384              (break "error in main-hook-function: unknown breakpoint"))))))
 385 \f
 386 ;;; Set breakpoints at the next possible code-locations. After calling
 387 ;;; this, either (CONTINUE) if in the debugger or just let program flow
 388 ;;; return if in a hook function.
 389 (defun set-step-breakpoint (frame)
 390   (cond
 391    ((sb!di:debug-block-elsewhere-p (sb!di:code-location-debug-block
 392                                     (sb!di:frame-code-location frame)))
 393     ;; FIXME: FORMAT T is used for error output here and elsewhere in
 394     ;; the debug code.
 395     (format t "cannot step, in elsewhere code~%"))
 396    (t
 397     (let* ((code-location (sb!di:frame-code-location frame))
 398            (next-code-locations (next-code-locations code-location)))
 399       (cond
 400        (next-code-locations
 401         (dolist (code-location next-code-locations)
 402           (let ((bp-info (location-in-list code-location *breakpoints*)))
 403             (when bp-info
 404               (sb!di:deactivate-breakpoint (breakpoint-info-breakpoint
 405                                             bp-info))))
 406           (let ((bp (sb!di:make-breakpoint #'main-hook-function code-location
 407                                            :kind :code-location)))
 408             (sb!di:activate-breakpoint bp)
 409             (push (create-breakpoint-info code-location bp 0)
 410                   *step-breakpoints*))))
 411        (t
 412         (let* ((debug-function (sb!di:frame-debug-function *current-frame*))
 413                (bp (sb!di:make-breakpoint #'main-hook-function debug-function
 414                                           :kind :function-end)))
 415           (sb!di:activate-breakpoint bp)
 416           (push (create-breakpoint-info debug-function bp 0)
 417                 *step-breakpoints*))))))))
 418 \f
 419 ;;;; STEP
 420
 421 ;;; ANSI specifies that this macro shall exist, even if only as a
 422 ;;; trivial placeholder like this.
 423 (defmacro step (form)
 424   "a trivial placeholder implementation of the CL:STEP macro required by
 425    the ANSI spec"
 426   `(progn
 427      ,form))
 428 \f
 429 ;;;; BACKTRACE
 430
 431 (defun backtrace (&optional (count most-positive-fixnum)
 432                             (*standard-output* *debug-io*))
 433   #!+sb-doc
 434   "Show a listing of the call stack going down from the current frame. In the
 435    debugger, the current frame is indicated by the prompt. Count is how many
 436    frames to show."
 437   (fresh-line *standard-output*)
 438   (do ((frame (if *in-the-debugger* *current-frame* (sb!di:top-frame))
 439               (sb!di:frame-down frame))
 440        (count count (1- count)))
 441       ((or (null frame) (zerop count)))
 442     (print-frame-call frame :number t))
 443   (fresh-line *standard-output*)
 444   (values))
 445 \f
 446 ;;;; frame printing
 447
 448 (eval-when (:compile-toplevel :execute)
 449
 450 ;;; This is a convenient way to express what to do for each type of
 451 ;;; lambda-list element.
 452 (sb!xc:defmacro lambda-list-element-dispatch (element
 453                                               &key
 454                                               required
 455                                               optional
 456                                               rest
 457                                               keyword
 458                                               deleted)
 459   `(etypecase ,element
 460      (sb!di:debug-var
 461       ,@required)
 462      (cons
 463       (ecase (car ,element)
 464         (:optional ,@optional)
 465         (:rest ,@rest)
 466         (:keyword ,@keyword)))
 467      (symbol
 468       (aver (eq ,element :deleted))
 469       ,@deleted)))
 470
 471 (sb!xc:defmacro lambda-var-dispatch (variable location deleted valid other)
 472   (let ((var (gensym)))
 473     `(let ((,var ,variable))
 474        (cond ((eq ,var :deleted) ,deleted)
 475              ((eq (sb!di:debug-var-validity ,var ,location) :valid)
 476               ,valid)
 477              (t ,other)))))
 478
 479 ) ; EVAL-WHEN
 480
 481 ;;; This is used in constructing arg lists for debugger printing when
 482 ;;; the arg list is unavailable, some arg is unavailable or unused,
 483 ;;; etc.
 484 (defstruct (unprintable-object
 485             (:constructor make-unprintable-object (string))
 486             (:print-object (lambda (x s)
 487                              (print-unreadable-object (x s :type t)
 488                                (write-string (unprintable-object-string x)
 489                                              s))))
 490             (:copier nil))
 491   string)
 492
 493 ;;; Print FRAME with verbosity level 1. If we hit a &REST arg, then
 494 ;;; print as many of the values as possible, punting the loop over
 495 ;;; lambda-list variables since any other arguments will be in the
 496 ;;; &REST arg's list of values.
 497 (defun print-frame-call-1 (frame)
 498   (let* ((d-fun (sb!di:frame-debug-function frame))
 499          (loc (sb!di:frame-code-location frame))
 500          (results (list (sb!di:debug-function-name d-fun))))
 501     (handler-case
 502         (dolist (ele (sb!di:debug-function-lambda-list d-fun))
 503           (lambda-list-element-dispatch ele
 504             :required ((push (frame-call-arg ele loc frame) results))
 505             :optional ((push (frame-call-arg (second ele) loc frame) results))
 506             :keyword ((push (second ele) results)
 507                       (push (frame-call-arg (third ele) loc frame) results))
 508             :deleted ((push (frame-call-arg ele loc frame) results))
 509             :rest ((lambda-var-dispatch (second ele) loc
 510                      nil
 511                      (progn
 512                        (setf results
 513                              (append (reverse (sb!di:debug-var-value
 514                                                (second ele) frame))
 515                                      results))
 516                        (return))
 517                      (push (make-unprintable-object
 518                             "unavailable &REST argument")
 519                            results)))))
 520       (sb!di:lambda-list-unavailable
 521        ()
 522        (push (make-unprintable-object "lambda list unavailable") results)))
 523     (pprint-logical-block (*standard-output* nil)
 524       (let ((x (nreverse (mapcar #'ensure-printable-object results))))
 525         (format t "(~@<~S~{ ~_~S~}~:>)" (first x) (rest x))))
 526     (when (sb!di:debug-function-kind d-fun)
 527       (write-char #\[)
 528       (prin1 (sb!di:debug-function-kind d-fun))
 529       (write-char #\]))))
 530
 531 (defun ensure-printable-object (object)
 532   (handler-case
 533       (with-open-stream (out (make-broadcast-stream))
 534         (prin1 object out)
 535         object)
 536     (error (cond)
 537       (declare (ignore cond))
 538       (make-unprintable-object "error printing object"))))
 539
 540 (defun frame-call-arg (var location frame)
 541   (lambda-var-dispatch var location
 542     (make-unprintable-object "unused argument")
 543     (sb!di:debug-var-value var frame)
 544     (make-unprintable-object "unavailable argument")))
 545
 546 ;;; Prints a representation of the function call causing FRAME to
 547 ;;; exist. VERBOSITY indicates the level of information to output;
 548 ;;; zero indicates just printing the debug-function's name, and one
 549 ;;; indicates displaying call-like, one-liner format with argument
 550 ;;; values.
 551 (defun print-frame-call (frame &key (verbosity 1) (number nil))
 552   (cond
 553    ((zerop verbosity)
 554     (when number
 555       (format t "~&~S: " (sb!di:frame-number frame)))
 556     (format t "~S" frame))
 557    (t
 558     (when number
 559       (format t "~&~S: " (sb!di:frame-number frame)))
 560     (print-frame-call-1 frame)))
 561   (when (>= verbosity 2)
 562     (let ((loc (sb!di:frame-code-location frame)))
 563       (handler-case
 564           (progn
 565             (sb!di:code-location-debug-block loc)
 566             (format t "~%source: ")
 567             (print-code-location-source-form loc 0))
 568         (sb!di:debug-condition (ignore) ignore)
 569         (error (c) (format t "error finding source: ~A" c))))))
 570 \f
 571 ;;;; INVOKE-DEBUGGER
 572
 573 (defvar *debugger-hook* nil
 574   #!+sb-doc
 575   "This is either NIL or a function of two arguments, a condition and the value
 576    of *DEBUGGER-HOOK*. This function can either handle the condition or return
 577    which causes the standard debugger to execute. The system passes the value
 578    of this variable to the function because it binds *DEBUGGER-HOOK* to NIL
 579    around the invocation.")
 580
 581 ;;; These are bound on each invocation of INVOKE-DEBUGGER.
 582 (defvar *debug-restarts*)
 583 (defvar *debug-condition*)
 584
 585 ;;; Print *DEBUG-CONDITION*, taking care to avoid recursive invocation
 586 ;;; of the debugger in case of a problem (e.g. a bug in the PRINT-OBJECT
 587 ;;; method for *DEBUG-CONDITION*).
 588 (defun princ-debug-condition-carefully (stream)
 589   (handler-case (princ *debug-condition* stream)
 590     (error (condition)
 591            (format stream
 592                    "  (caught ~S when trying to print ~S)"
 593                    (type-of condition)
 594                    '*debug-condition*)))
 595   *debug-condition*)
 596
 597 (defun invoke-debugger (condition)
 598   #!+sb-doc
 599   "Enter the debugger."
 600   (let ((old-hook *debugger-hook*))
 601     (when old-hook
 602       (let ((*debugger-hook* nil))
 603         (funcall old-hook condition old-hook))))
 604   (sb!unix:unix-sigsetmask 0)
 605
 606   ;; Elsewhere in the system, we use the SANE-PACKAGE function for
 607   ;; this, but here causing an exception just as we're trying to handle
 608   ;; an exception would be confusing, so instead we use a special hack.
 609   (unless (and (packagep *package*)
 610                (package-name *package*))
 611     (setf *package* (find-package :cl-user))
 612     (format *error-output*
 613             "The value of ~S was not an undeleted PACKAGE. It has been
 614 reset to ~S."
 615             '*package* *package*))
 616   (let (;; Save *PACKAGE* to protect it from WITH-STANDARD-IO-SYNTAX.
 617         (original-package *package*))
 618     (with-standard-io-syntax
 619      (let* ((*debug-condition* condition)
 620             (*debug-restarts* (compute-restarts condition))
 621             ;; We want the i/o subsystem to be in a known, useful
 622             ;; state, regardless of where the debugger was invoked in
 623             ;; the program. WITH-STANDARD-IO-SYNTAX does some of that,
 624             ;; but
 625             ;;   1. It doesn't affect our internal special variables
 626             ;;      like *CURRENT-LEVEL*.
 627             ;;   2. It isn't customizable.
 628             ;;   3. It doesn't set *PRINT-READABLY* or *PRINT-PRETTY*
 629             ;;      to the same value as the toplevel default.
 630             ;;   4. It sets *PACKAGE* to COMMON-LISP-USER, which is not
 631             ;;      helpful behavior for a debugger.
 632             ;; We try to remedy all these problems with explicit
 633             ;; rebindings here.
 634             (sb!kernel:*current-level* 0)
 635             (*print-length* *debug-print-length*)
 636             (*print-level* *debug-print-level*)
 637             (*readtable* *debug-readtable*)
 638             (*print-readably* nil)
 639             (*print-pretty* t)
 640             (*package* original-package))
 641
 642        ;; Before we start our own output, finish any pending output.
 643        ;; Otherwise, if the user tried to track the progress of
 644        ;; his program using PRINT statements, he'd tend to lose
 645        ;; the last line of output or so, and get confused.
 646        (flush-standard-output-streams)
 647
 648        ;; The initial output here goes to *ERROR-OUTPUT*, because the
 649        ;; initial output is not interactive, just an error message,
 650        ;; and when people redirect *ERROR-OUTPUT*, they could
 651        ;; reasonably expect to see error messages logged there,
 652        ;; regardless of what the debugger does afterwards.
 653        (format *error-output*
 654                "~2&debugger invoked on condition of type ~S:~%  "
 655                (type-of *debug-condition*))
 656        (princ-debug-condition-carefully *error-output*)
 657        (terpri *error-output*)
 658
 659        ;; After the initial error/condition/whatever announcement to
 660        ;; *ERROR-OUTPUT*, we become interactive, and should talk on
 661        ;; *DEBUG-IO* from now on. (KLUDGE: This is a normative
 662        ;; statement, not a description of reality.:-| There's a lot of
 663        ;; older debugger code which was written to do i/o on whatever
 664        ;; stream was in fashion at the time, and not all of it has
 665        ;; been converted to behave this way. -- WHN 2000-11-16)
 666        (let (;; FIXME: The first two bindings here seem wrong,
 667              ;; violating the principle of least surprise, and making
 668              ;; it impossible for the user to do reasonable things
 669              ;; like using PRINT at the debugger prompt to send output
 670              ;; to the program's ordinary (possibly
 671              ;; redirected-to-a-file) *STANDARD-OUTPUT*, or using
 672              ;; PEEK-CHAR or some such thing on the program's ordinary
 673              ;; (possibly also redirected) *STANDARD-INPUT*.
 674              (*standard-input* *debug-io*)
 675              (*standard-output* *debug-io*)
 676              ;; This seems reasonable: e.g. if the user has redirected
 677              ;; *ERROR-OUTPUT* to some log file, it's probably wrong
 678              ;; to send errors which occur in interactive debugging to
 679              ;; that file, and right to send them to *DEBUG-IO*.
 680              (*error-output* *debug-io*))
 681          (unless (typep condition 'step-condition)
 682            (format *debug-io*
 683                    "~%~@<Within the debugger, you can type HELP for help. At ~
 684                    any command prompt (within the debugger or not) you can ~
 685                    type (SB-EXT:QUIT) to terminate the SBCL executable. ~
 686                    The condition which caused the debugger to be entered ~
 687                    is bound to ~S.~:@>~2%"
 688                    '*debug-condition*)
 689            (show-restarts *debug-restarts* *debug-io*)
 690            (terpri *debug-io*))
 691          (internal-debug))))))
 692
 693 (defun show-restarts (restarts s)
 694   (when restarts
 695     (format s "~&restarts:~%")
 696     (let ((count 0)
 697           (names-used '(nil))
 698           (max-name-len 0))
 699       (dolist (restart restarts)
 700         (let ((name (restart-name restart)))
 701           (when name
 702             (let ((len (length (princ-to-string name))))
 703               (when (> len max-name-len)
 704                 (setf max-name-len len))))))
 705       (unless (zerop max-name-len)
 706         (incf max-name-len 3))
 707       (dolist (restart restarts)
 708         (let ((name (restart-name restart)))
 709           (cond ((member name names-used)
 710                  (format s "~& ~2D: ~@VT~A~%" count max-name-len restart))
 711                 (t
 712                  (format s "~& ~2D: [~VA] ~A~%"
 713                          count (- max-name-len 3) name restart)
 714                  (push name names-used))))
 715         (incf count)))))
 716
 717 ;;; This calls DEBUG-LOOP, performing some simple initializations
 718 ;;; before doing so. INVOKE-DEBUGGER calls this to actually get into
 719 ;;; the debugger. SB!KERNEL::ERROR-ERROR calls this in emergencies
 720 ;;; to get into a debug prompt as quickly as possible with as little
 721 ;;; risk as possible for stepping on whatever is causing recursive
 722 ;;; errors.
 723 (defun internal-debug ()
 724   (let ((*in-the-debugger* t)
 725         (*read-suppress* nil))
 726     (unless (typep *debug-condition* 'step-condition)
 727       (clear-input *debug-io*))
 728     #!-mp (debug-loop)
 729     #!+mp (sb!mp:without-scheduling (debug-loop))))
 730 \f
 731 ;;;; DEBUG-LOOP
 732
 733 ;;; Note: This defaulted to T in CMU CL. The changed default in SBCL
 734 ;;; was motivated by desire to play nicely with ILISP.
 735 (defvar *flush-debug-errors* nil
 736   #!+sb-doc
 737   "When set, avoid calling INVOKE-DEBUGGER recursively when errors occur while
 738    executing in the debugger.")
 739
 740 (defun debug-loop ()
 741   (let* ((*debug-command-level* (1+ *debug-command-level*))
 742          (*real-stack-top* (sb!di:top-frame))
 743          (*stack-top* (or *stack-top-hint* *real-stack-top*))
 744          (*stack-top-hint* nil)
 745          (*current-frame* *stack-top*))
 746     (handler-bind ((sb!di:debug-condition (lambda (condition)
 747                                             (princ condition *debug-io*)
 748                                             (throw 'debug-loop-catcher nil))))
 749       (fresh-line)
 750       (print-frame-call *current-frame* :verbosity 2)
 751       (loop
 752         (catch 'debug-loop-catcher
 753           (handler-bind ((error #'(lambda (condition)
 754                                     (when *flush-debug-errors*
 755                                       (clear-input *debug-io*)
 756                                       (princ condition)
 757                                       ;; FIXME: Doing input on *DEBUG-IO*
 758                                       ;; and output on T seems broken.
 759                                       (format t
 760                                               "~&error flushed (because ~
 761                                                ~S is set)"
 762                                               '*flush-debug-errors*)
 763                                       (throw 'debug-loop-catcher nil)))))
 764             ;; We have to bind level for the restart function created by
 765             ;; WITH-SIMPLE-RESTART.
 766             (let ((level *debug-command-level*)
 767                   (restart-commands (make-restart-commands)))
 768               (with-simple-restart (abort
 769                                    "Reduce debugger level (to debug level ~D)."
 770                                     level)
 771                 (debug-prompt *debug-io*)
 772                 (force-output *debug-io*)
 773                 (let ((input (sb!int:get-stream-command *debug-io*)))
 774                   (cond (input
 775                          (let ((cmd-fun (debug-command-p
 776                                          (sb!int:stream-command-name input)
 777                                          restart-commands)))
 778                            (cond
 779                             ((not cmd-fun)
 780                              (error "unknown stream-command: ~S" input))
 781                             ((consp cmd-fun)
 782                              (error "ambiguous debugger command: ~S" cmd-fun))
 783                             (t
 784                              (apply cmd-fun
 785                                     (sb!int:stream-command-args input))))))
 786                         (t
 787                          (let* ((exp (read))
 788                                 (cmd-fun (debug-command-p exp
 789                                                           restart-commands)))
 790                            (cond ((not cmd-fun)
 791                                   (debug-eval-print exp))
 792                                  ((consp cmd-fun)
 793                                   (format t
 794                                           "~&Your command, ~S, is ambiguous:~%"
 795                                           exp)
 796                                   (dolist (ele cmd-fun)
 797                                     (format t "   ~A~%" ele)))
 798                                  (t
 799                                   (funcall cmd-fun)))))))))))))))
 800
 801 ;;; FIXME: As far as I know, the CMU CL X86 codebase has never
 802 ;;; supported access to the environment of the debugged function. It
 803 ;;; would be really, really nice to make that work! (Until then,
 804 ;;; non-NIL *AUTO-EVAL-IN-FRAME* seems to be useless, and as of
 805 ;;; sbcl-0.6.10 it even seemed to be actively harmful, since the
 806 ;;; debugger gets confused when trying to unwind the frames which
 807 ;;; arise in SIGINT interrupts. So it's set to NIL.)
 808 (defvar *auto-eval-in-frame* nil
 809   #!+sb-doc
 810   "When set, evaluations in the debugger's command loop occur relative
 811    to the current frame's environment without the need of debugger
 812    forms that explicitly control this kind of evaluation. In an ideal
 813    world, the default would be T, but since unfortunately the X86
 814    debugger support isn't good enough to make this useful, the
 815    default is NIL instead.")
 816
 817 ;;; FIXME: We could probably use INTERACTIVE-EVAL for much of this logic.
 818 (defun debug-eval-print (expr)
 819   (/noshow "entering DEBUG-EVAL-PRINT" expr)
 820   (/noshow (fboundp 'compile))
 821   (/noshow (and (fboundp 'compile) *auto-eval-in-frame*))
 822   (setq +++ ++ ++ + + - - expr)
 823   (let* ((values (multiple-value-list
 824                   (if (and (fboundp 'compile) *auto-eval-in-frame*)
 825                       (sb!di:eval-in-frame *current-frame* -)
 826                       (eval -))))
 827          (*standard-output* *debug-io*))
 828     (/noshow "done with EVAL in DEBUG-EVAL-PRINT")
 829     (fresh-line)
 830     (if values (prin1 (car values)))
 831     (dolist (x (cdr values))
 832       (fresh-line)
 833       (prin1 x))
 834     (setq /// // // / / values)
 835     (setq *** ** ** * * (car values))
 836     ;; Make sure that nobody passes back an unbound marker.
 837     (unless (boundp '*)
 838       (setq * nil)
 839       (fresh-line)
 840       ;; FIXME: The way INTERACTIVE-EVAL does this seems better.
 841       (princ "Setting * to NIL (was unbound marker)."))))
 842 \f
 843 ;;;; debug loop functions
 844
 845 ;;; These commands are functions, not really commands, so that users
 846 ;;; can get their hands on the values returned.
 847
 848 (eval-when (:execute :compile-toplevel)
 849
 850 (sb!xc:defmacro define-var-operation (ref-or-set &optional value-var)
 851   `(let* ((temp (etypecase name
 852                   (symbol (sb!di:debug-function-symbol-variables
 853                            (sb!di:frame-debug-function *current-frame*)
 854                            name))
 855                   (simple-string (sb!di:ambiguous-debug-vars
 856                                   (sb!di:frame-debug-function *current-frame*)
 857                                   name))))
 858           (location (sb!di:frame-code-location *current-frame*))
 859           ;; Let's only deal with valid variables.
 860           (vars (remove-if-not #'(lambda (v)
 861                                    (eq (sb!di:debug-var-validity v location)
 862                                        :valid))
 863                                temp)))
 864      (declare (list vars))
 865      (cond ((null vars)
 866             (error "No known valid variables match ~S." name))
 867            ((= (length vars) 1)
 868             ,(ecase ref-or-set
 869                (:ref
 870                 '(sb!di:debug-var-value (car vars) *current-frame*))
 871                (:set
 872                 `(setf (sb!di:debug-var-value (car vars) *current-frame*)
 873                        ,value-var))))
 874            (t
 875             ;; Since we have more than one, first see whether we have
 876             ;; any variables that exactly match the specification.
 877             (let* ((name (etypecase name
 878                            (symbol (symbol-name name))
 879                            (simple-string name)))
 880                    ;; FIXME: REMOVE-IF-NOT is deprecated, use STRING/=
 881                    ;; instead.
 882                    (exact (remove-if-not (lambda (v)
 883                                            (string= (sb!di:debug-var-symbol-name v)
 884                                                     name))
 885                                          vars))
 886                    (vars (or exact vars)))
 887               (declare (simple-string name)
 888                        (list exact vars))
 889               (cond
 890                ;; Check now for only having one variable.
 891                ((= (length vars) 1)
 892                 ,(ecase ref-or-set
 893                    (:ref
 894                     '(sb!di:debug-var-value (car vars) *current-frame*))
 895                    (:set
 896                     `(setf (sb!di:debug-var-value (car vars) *current-frame*)
 897                            ,value-var))))
 898                ;; If there weren't any exact matches, flame about
 899                ;; ambiguity unless all the variables have the same
 900                ;; name.
 901                ((and (not exact)
 902                      (find-if-not
 903                       #'(lambda (v)
 904                           (string= (sb!di:debug-var-symbol-name v)
 905                                    (sb!di:debug-var-symbol-name (car vars))))
 906                       (cdr vars)))
 907                 (error "specification ambiguous:~%~{   ~A~%~}"
 908                        (mapcar #'sb!di:debug-var-symbol-name
 909                                (delete-duplicates
 910                                 vars :test #'string=
 911                                 :key #'sb!di:debug-var-symbol-name))))
 912                ;; All names are the same, so see whether the user
 913                ;; ID'ed one of them.
 914                (id-supplied
 915                 (let ((v (find id vars :key #'sb!di:debug-var-id)))
 916                   (unless v
 917                     (error
 918                      "invalid variable ID, ~D: should have been one of ~S"
 919                      id
 920                      (mapcar #'sb!di:debug-var-id vars)))
 921                   ,(ecase ref-or-set
 922                      (:ref
 923                       '(sb!di:debug-var-value v *current-frame*))
 924                      (:set
 925                       `(setf (sb!di:debug-var-value v *current-frame*)
 926                              ,value-var)))))
 927                (t
 928                 (error "Specify variable ID to disambiguate ~S. Use one of ~S."
 929                        name
 930                        (mapcar #'sb!di:debug-var-id vars)))))))))
 931
 932 ) ; EVAL-WHEN
 933
 934 ;;; FIXME: This doesn't work. It would be real nice we could make it
 935 ;;; work! Alas, it doesn't seem to work in CMU CL X86 either..
 936 (defun var (name &optional (id 0 id-supplied))
 937   #!+sb-doc
 938   "Return a variable's value if possible. NAME is a simple-string or symbol.
 939    If it is a simple-string, it is an initial substring of the variable's name.
 940    If name is a symbol, it has the same name and package as the variable whose
 941    value this function returns. If the symbol is uninterned, then the variable
 942    has the same name as the symbol, but it has no package.
 943
 944    If name is the initial substring of variables with different names, then
 945    this return no values after displaying the ambiguous names. If name
 946    determines multiple variables with the same name, then you must use the
 947    optional id argument to specify which one you want. If you left id
 948    unspecified, then this returns no values after displaying the distinguishing
 949    id values.
 950
 951    The result of this function is limited to the availability of variable
 952    information. This is SETF'able."
 953   (define-var-operation :ref))
 954 (defun (setf var) (value name &optional (id 0 id-supplied))
 955   (define-var-operation :set value))
 956
 957 ;;; This returns the COUNT'th arg as the user sees it from args, the
 958 ;;; result of SB!DI:DEBUG-FUNCTION-LAMBDA-LIST. If this returns a
 959 ;;; potential DEBUG-VAR from the lambda-list, then the second value is
 960 ;;; T. If this returns a keyword symbol or a value from a rest arg,
 961 ;;; then the second value is NIL.
 962 (declaim (ftype (function (index list)) nth-arg))
 963 (defun nth-arg (count args)
 964   (let ((n count))
 965     (dolist (ele args (error "The argument specification ~S is out of range."
 966                              n))
 967       (lambda-list-element-dispatch ele
 968         :required ((if (zerop n) (return (values ele t))))
 969         :optional ((if (zerop n) (return (values (second ele) t))))
 970         :keyword ((cond ((zerop n)
 971                          (return (values (second ele) nil)))
 972                         ((zerop (decf n))
 973                          (return (values (third ele) t)))))
 974         :deleted ((if (zerop n) (return (values ele t))))
 975         :rest ((let ((var (second ele)))
 976                  (lambda-var-dispatch var (sb!di:frame-code-location
 977                                            *current-frame*)
 978                    (error "unused &REST argument before n'th
 979 argument")
 980                    (dolist (value
 981                             (sb!di:debug-var-value var *current-frame*)
 982                             (error
 983                              "The argument specification ~S is out of range."
 984                              n))
 985                      (if (zerop n)
 986                          (return-from nth-arg (values value nil))
 987                          (decf n)))
 988                    (error "invalid &REST argument before n'th argument")))))
 989       (decf n))))
 990
 991 (defun arg (n)
 992   #!+sb-doc
 993   "Returns the N'th argument's value if possible. Argument zero is the first
 994    argument in a frame's default printed representation. Count keyword/value
 995    pairs as separate arguments."
 996   (multiple-value-bind (var lambda-var-p)
 997       (nth-arg n (handler-case (sb!di:debug-function-lambda-list
 998                                 (sb!di:frame-debug-function *current-frame*))
 999                    (sb!di:lambda-list-unavailable ()
1000                      (error "No argument values are available."))))
1001     (if lambda-var-p
1002         (lambda-var-dispatch var (sb!di:frame-code-location *current-frame*)
1003           (error "Unused arguments have no values.")
1004           (sb!di:debug-var-value var *current-frame*)
1005           (error "invalid argument value"))
1006         var)))
1007 \f
1008 ;;;; machinery for definition of debug loop commands
1009
1010 (defvar *debug-commands* nil)
1011
1012 ;;; Interface to *DEBUG-COMMANDS*. No required arguments in args are
1013 ;;; permitted.
1014 (defmacro !def-debug-command (name args &rest body)
1015   (let ((fun-name (symbolicate name "-DEBUG-COMMAND")))
1016     `(progn
1017        (setf *debug-commands*
1018              (remove ,name *debug-commands* :key #'car :test #'string=))
1019        (defun ,fun-name ,args
1020          (unless *in-the-debugger*
1021            (error "invoking debugger command while outside the debugger"))
1022          ,@body)
1023        (push (cons ,name #',fun-name) *debug-commands*)
1024        ',fun-name)))
1025
1026 (defun !def-debug-command-alias (new-name existing-name)
1027   (let ((pair (assoc existing-name *debug-commands* :test #'string=)))
1028     (unless pair (error "unknown debug command name: ~S" existing-name))
1029     (push (cons new-name (cdr pair)) *debug-commands*))
1030   new-name)
1031
1032 ;;; This takes a symbol and uses its name to find a debugger command,
1033 ;;; using initial substring matching. It returns the command function
1034 ;;; if form identifies only one command, but if form is ambiguous,
1035 ;;; this returns a list of the command names. If there are no matches,
1036 ;;; this returns nil. Whenever the loop that looks for a set of
1037 ;;; possibilities encounters an exact name match, we return that
1038 ;;; command function immediately.
1039 (defun debug-command-p (form &optional other-commands)
1040   (if (or (symbolp form) (integerp form))
1041       (let* ((name
1042               (if (symbolp form)
1043                   (symbol-name form)
1044                   (format nil "~D" form)))
1045              (len (length name))
1046              (res nil))
1047         (declare (simple-string name)
1048                  (fixnum len)
1049                  (list res))
1050
1051         ;; Find matching commands, punting if exact match.
1052         (flet ((match-command (ele)
1053                  (let* ((str (car ele))
1054                         (str-len (length str)))
1055                    (declare (simple-string str)
1056                             (fixnum str-len))
1057                    (cond ((< str-len len))
1058                          ((= str-len len)
1059                           (when (string= name str :end1 len :end2 len)
1060                             (return-from debug-command-p (cdr ele))))
1061                          ((string= name str :end1 len :end2 len)
1062                           (push ele res))))))
1063           (mapc #'match-command *debug-commands*)
1064           (mapc #'match-command other-commands))
1065
1066         ;; Return the right value.
1067         (cond ((not res) nil)
1068               ((= (length res) 1)
1069                (cdar res))
1070               (t ; Just return the names.
1071                (do ((cmds res (cdr cmds)))
1072                    ((not cmds) res)
1073                  (setf (car cmds) (caar cmds))))))))
1074
1075 ;;; Return a list of debug commands (in the same format as
1076 ;;; *debug-commands*) that invoke each active restart.
1077 ;;;
1078 ;;; Two commands are made for each restart: one for the number, and
1079 ;;; one for the restart name (unless it's been shadowed by an earlier
1080 ;;; restart of the same name, or it is NIL).
1081 (defun make-restart-commands (&optional (restarts *debug-restarts*))
1082   (let ((commands)
1083         (num 0))                        ; better be the same as show-restarts!
1084     (dolist (restart restarts)
1085       (let ((name (string (restart-name restart))))
1086         (let ((restart-fun
1087                 #'(lambda () (invoke-restart-interactively restart))))
1088           (push (cons (format nil "~d" num) restart-fun) commands)
1089           (unless (or (null (restart-name restart))
1090                       (find name commands :key #'car :test #'string=))
1091             (push (cons name restart-fun) commands))))
1092     (incf num))
1093   commands))
1094 \f
1095 ;;;; frame-changing commands
1096
1097 (!def-debug-command "UP" ()
1098   (let ((next (sb!di:frame-up *current-frame*)))
1099     (cond (next
1100            (setf *current-frame* next)
1101            (print-frame-call next))
1102           (t
1103            (format t "~&Top of stack.")))))
1104
1105 (!def-debug-command "DOWN" ()
1106   (let ((next (sb!di:frame-down *current-frame*)))
1107     (cond (next
1108            (setf *current-frame* next)
1109            (print-frame-call next))
1110           (t
1111            (format t "~&Bottom of stack.")))))
1112
1113 (!def-debug-command-alias "D" "DOWN")
1114
1115 ;;; CMU CL had this command, but SBCL doesn't, since it's redundant
1116 ;;; with "FRAME 0", and it interferes with abbreviations for the
1117 ;;; TOPLEVEL restart.
1118 ;;;(!def-debug-command "TOP" ()
1119 ;;;  (do ((prev *current-frame* lead)
1120 ;;;       (lead (sb!di:frame-up *current-frame*) (sb!di:frame-up lead)))
1121 ;;;      ((null lead)
1122 ;;;       (setf *current-frame* prev)
1123 ;;;       (print-frame-call prev))))
1124
1125 (!def-debug-command "BOTTOM" ()
1126   (do ((prev *current-frame* lead)
1127        (lead (sb!di:frame-down *current-frame*) (sb!di:frame-down lead)))
1128       ((null lead)
1129        (setf *current-frame* prev)
1130        (print-frame-call prev))))
1131
1132 (!def-debug-command-alias "B" "BOTTOM")
1133
1134 (!def-debug-command "FRAME" (&optional
1135                              (n (read-prompting-maybe "frame number: ")))
1136   (setf *current-frame*
1137         (multiple-value-bind (next-frame-fun limit-string)
1138             (if (< n (sb!di:frame-number *current-frame*))
1139                 (values #'sb!di:frame-up "top")
1140               (values #'sb!di:frame-down "bottom"))
1141           (do ((frame *current-frame*))
1142               ((= n (sb!di:frame-number frame))
1143                frame)
1144             (let ((next-frame (funcall next-frame-fun frame)))
1145               (cond (next-frame
1146                      (setf frame next-frame))
1147                     (t
1148                      (format t
1149                              "The ~A of the stack was encountered.~%"
1150                              limit-string)
1151                      (return frame)))))))
1152   (print-frame-call *current-frame*))
1153
1154 (!def-debug-command-alias "F" "FRAME")
1155 \f
1156 ;;;; commands for entering and leaving the debugger
1157
1158 ;;; CMU CL supported this QUIT debug command, but SBCL provides this
1159 ;;; functionality with a restart instead. (The QUIT debug command was
1160 ;;; removed because it's confusing to have "quit" mean two different
1161 ;;; things in the system, "restart the top level REPL" in the debugger
1162 ;;; and "terminate the Lisp system" as the SB-EXT:QUIT function.)
1163 ;;;
1164 ;;;(!def-debug-command "QUIT" ()
1165 ;;;  (throw 'sb!impl::top-level-catcher nil))
1166
1167 ;;; CMU CL supported this GO debug command, but SBCL doesn't -- just
1168 ;;; type the CONTINUE restart name.
1169 ;;;(!def-debug-command "GO" ()
1170 ;;;  (continue *debug-condition*)
1171 ;;;  (error "There is no restart named CONTINUE."))
1172
1173 (!def-debug-command "RESTART" ()
1174   (let ((num (read-if-available :prompt)))
1175     (when (eq num :prompt)
1176       (show-restarts *debug-restarts* *debug-io*)
1177       (write-string "restart: ")
1178       (force-output)
1179       (setf num (read *standard-input*)))
1180     (let ((restart (typecase num
1181                      (unsigned-byte
1182                       (nth num *debug-restarts*))
1183                      (symbol
1184                       (find num *debug-restarts* :key #'restart-name
1185                             :test #'(lambda (sym1 sym2)
1186                                       (string= (symbol-name sym1)
1187                                                (symbol-name sym2)))))
1188                      (t
1189                       (format t "~S is invalid as a restart name.~%" num)
1190                       (return-from restart-debug-command nil)))))
1191       (if restart
1192           (invoke-restart-interactively restart)
1193           ;; FIXME: Even if this isn't handled by WARN, it probably
1194           ;; shouldn't go to *STANDARD-OUTPUT*, but *ERROR-OUTPUT* or
1195           ;; *QUERY-IO* or something. Look through this file to
1196           ;; straighten out stream usage.
1197           (princ "There is no such restart.")))))
1198 \f
1199 ;;;; information commands
1200
1201 (!def-debug-command "HELP" ()
1202   ;; CMU CL had a little toy pager here, but "if you aren't running
1203   ;; ILISP (or a smart windowing system, or something) you deserve to
1204   ;; lose", so we've dropped it in SBCL. However, in case some
1205   ;; desperate holdout is running this on a dumb terminal somewhere,
1206   ;; we tell him where to find the message stored as a string.
1207   (format *debug-io*
1208           "~&~a~2%(The HELP string is stored in ~S.)~%"
1209           *debug-help-string*
1210           '*debug-help-string*))
1211
1212 (!def-debug-command-alias "?" "HELP")
1213
1214 (!def-debug-command "ERROR" ()
1215   (format *debug-io* "~A~%" *debug-condition*)
1216   (show-restarts *debug-restarts* *debug-io*))
1217
1218 (!def-debug-command "BACKTRACE" ()
1219   (backtrace (read-if-available most-positive-fixnum)))
1220
1221 (!def-debug-command "PRINT" ()
1222   (print-frame-call *current-frame*))
1223
1224 (!def-debug-command-alias "P" "PRINT")
1225
1226 (!def-debug-command "LIST-LOCALS" ()
1227   (let ((d-fun (sb!di:frame-debug-function *current-frame*)))
1228     (if (sb!di:debug-var-info-available d-fun)
1229         (let ((*standard-output* *debug-io*)
1230               (location (sb!di:frame-code-location *current-frame*))
1231               (prefix (read-if-available nil))
1232               (any-p nil)
1233               (any-valid-p nil))
1234           (dolist (v (sb!di:ambiguous-debug-vars
1235                         d-fun
1236                         (if prefix (string prefix) "")))
1237             (setf any-p t)
1238             (when (eq (sb!di:debug-var-validity v location) :valid)
1239               (setf any-valid-p t)
1240               (format t "~S~:[#~D~;~*~]  =  ~S~%"
1241                       (sb!di:debug-var-symbol v)
1242                       (zerop (sb!di:debug-var-id v))
1243                       (sb!di:debug-var-id v)
1244                       (sb!di:debug-var-value v *current-frame*))))
1245
1246           (cond
1247            ((not any-p)
1248             (format t "There are no local variables ~@[starting with ~A ~]~
1249                        in the function."
1250                     prefix))
1251            ((not any-valid-p)
1252             (format t "All variables ~@[starting with ~A ~]currently ~
1253                        have invalid values."
1254                     prefix))))
1255         (write-line "There is no variable information available."))))
1256
1257 (!def-debug-command-alias "L" "LIST-LOCALS")
1258
1259 (!def-debug-command "SOURCE" ()
1260   (fresh-line)
1261   (print-code-location-source-form (sb!di:frame-code-location *current-frame*)
1262                                    (read-if-available 0)))
1263 \f
1264 ;;;; source location printing
1265
1266 ;;; We cache a stream to the last valid file debug source so that we
1267 ;;; won't have to repeatedly open the file.
1268 ;;;
1269 ;;; KLUDGE: This sounds like a bug, not a feature. Opening files is fast
1270 ;;; in the 1990s, so the benefit is negligible, less important than the
1271 ;;; potential of extra confusion if someone changes the source during
1272 ;;; a debug session and the change doesn't show up. And removing this
1273 ;;; would simplify the system, which I like. -- WHN 19990903
1274 (defvar *cached-debug-source* nil)
1275 (declaim (type (or sb!di:debug-source null) *cached-debug-source*))
1276 (defvar *cached-source-stream* nil)
1277 (declaim (type (or stream null) *cached-source-stream*))
1278
1279 ;;; To suppress the read-time evaluation #. macro during source read,
1280 ;;; *READTABLE* is modified. *READTABLE* is cached to avoid
1281 ;;; copying it each time, and invalidated when the
1282 ;;; *CACHED-DEBUG-SOURCE* has changed.
1283 (defvar *cached-readtable* nil)
1284 (declaim (type (or readtable null) *cached-readtable*))
1285
1286 (pushnew #'(lambda ()
1287              (setq *cached-debug-source* nil *cached-source-stream* nil
1288                    *cached-readtable* nil))
1289          sb!int:*before-save-initializations*)
1290
1291 ;;; We also cache the last top-level form that we printed a source for
1292 ;;; so that we don't have to do repeated reads and calls to
1293 ;;; FORM-NUMBER-TRANSLATIONS.
1294 (defvar *cached-top-level-form-offset* nil)
1295 (declaim (type (or index null) *cached-top-level-form-offset*))
1296 (defvar *cached-top-level-form*)
1297 (defvar *cached-form-number-translations*)
1298
1299 ;;; Given a code location, return the associated form-number
1300 ;;; translations and the actual top-level form. We check our cache ---
1301 ;;; if there is a miss, we dispatch on the kind of the debug source.
1302 (defun get-top-level-form (location)
1303   (let ((d-source (sb!di:code-location-debug-source location)))
1304     (if (and (eq d-source *cached-debug-source*)
1305              (eql (sb!di:code-location-top-level-form-offset location)
1306                   *cached-top-level-form-offset*))
1307         (values *cached-form-number-translations* *cached-top-level-form*)
1308         (let* ((offset (sb!di:code-location-top-level-form-offset location))
1309                (res
1310                 (ecase (sb!di:debug-source-from d-source)
1311                   (:file (get-file-top-level-form location))
1312                   (:lisp (svref (sb!di:debug-source-name d-source) offset)))))
1313           (setq *cached-top-level-form-offset* offset)
1314           (values (setq *cached-form-number-translations*
1315                         (sb!di:form-number-translations res offset))
1316                   (setq *cached-top-level-form* res))))))
1317
1318 ;;; Locate the source file (if it still exists) and grab the top-level
1319 ;;; form. If the file is modified, we use the top-level-form offset
1320 ;;; instead of the recorded character offset.
1321 (defun get-file-top-level-form (location)
1322   (let* ((d-source (sb!di:code-location-debug-source location))
1323          (tlf-offset (sb!di:code-location-top-level-form-offset location))
1324          (local-tlf-offset (- tlf-offset
1325                               (sb!di:debug-source-root-number d-source)))
1326          (char-offset
1327           (aref (or (sb!di:debug-source-start-positions d-source)
1328                     (error "no start positions map"))
1329                 local-tlf-offset))
1330          (name (sb!di:debug-source-name d-source)))
1331     (unless (eq d-source *cached-debug-source*)
1332       (unless (and *cached-source-stream*
1333                    (equal (pathname *cached-source-stream*)
1334                           (pathname name)))
1335         (setq *cached-readtable* nil)
1336         (when *cached-source-stream* (close *cached-source-stream*))
1337         (setq *cached-source-stream* (open name :if-does-not-exist nil))
1338         (unless *cached-source-stream*
1339           (error "The source file no longer exists:~%  ~A" (namestring name)))
1340         (format t "~%; file: ~A~%" (namestring name)))
1341
1342         (setq *cached-debug-source*
1343               (if (= (sb!di:debug-source-created d-source)
1344                      (file-write-date name))
1345                   d-source nil)))
1346
1347     (cond
1348      ((eq *cached-debug-source* d-source)
1349       (file-position *cached-source-stream* char-offset))
1350      (t
1351       (format t "~%; File has been modified since compilation:~%;   ~A~@
1352                  ; Using form offset instead of character position.~%"
1353               (namestring name))
1354       (file-position *cached-source-stream* 0)
1355       (let ((*read-suppress* t))
1356         (dotimes (i local-tlf-offset)
1357           (read *cached-source-stream*)))))
1358     (unless *cached-readtable*
1359       (setq *cached-readtable* (copy-readtable))
1360       (set-dispatch-macro-character
1361        #\# #\.
1362        #'(lambda (stream sub-char &rest rest)
1363            (declare (ignore rest sub-char))
1364            (let ((token (read stream t nil t)))
1365              (format nil "#.~S" token)))
1366        *cached-readtable*))
1367     (let ((*readtable* *cached-readtable*))
1368       (read *cached-source-stream*))))
1369
1370 (defun print-code-location-source-form (location context)
1371   (let* ((location (maybe-block-start-location location))
1372          (form-num (sb!di:code-location-form-number location)))
1373     (multiple-value-bind (translations form) (get-top-level-form location)
1374       (unless (< form-num (length translations))
1375         (error "The source path no longer exists."))
1376       (prin1 (sb!di:source-path-context form
1377                                         (svref translations form-num)
1378                                         context)))))
1379 \f
1380 ;;; breakpoint and step commands
1381
1382 ;;; Step to the next code-location.
1383 (!def-debug-command "STEP" ()
1384   (setf *number-of-steps* (read-if-available 1))
1385   (set-step-breakpoint *current-frame*)
1386   (continue *debug-condition*)
1387   (error "couldn't continue"))
1388
1389 ;;; List possible breakpoint locations, which ones are active, and
1390 ;;; where the CONTINUE restart will transfer control. Set
1391 ;;; *POSSIBLE-BREAKPOINTS* to the code-locations which can then be
1392 ;;; used by sbreakpoint.
1393 (!def-debug-command "LIST-LOCATIONS" ()
1394   (let ((df (read-if-available *default-breakpoint-debug-function*)))
1395     (cond ((consp df)
1396            (setf df (sb!di:function-debug-function (eval df)))
1397            (setf *default-breakpoint-debug-function* df))
1398           ((or (eq ':c df)
1399                (not *default-breakpoint-debug-function*))
1400            (setf df (sb!di:frame-debug-function *current-frame*))
1401            (setf *default-breakpoint-debug-function* df)))
1402     (setf *possible-breakpoints* (possible-breakpoints df)))
1403   (let ((continue-at (sb!di:frame-code-location *current-frame*)))
1404     (let ((active (location-in-list *default-breakpoint-debug-function*
1405                                     *breakpoints* :function-start))
1406           (here (sb!di:code-location=
1407                  (sb!di:debug-function-start-location
1408                   *default-breakpoint-debug-function*) continue-at)))
1409       (when (or active here)
1410         (format t "::FUNCTION-START ")
1411         (when active (format t " *Active*"))
1412         (when here (format t " *Continue here*"))))
1413
1414     (let ((prev-location nil)
1415           (prev-num 0)
1416           (this-num 0))
1417       (flet ((flush ()
1418                (when prev-location
1419                  (let ((this-num (1- this-num)))
1420                    (if (= prev-num this-num)
1421                        (format t "~&~D: " prev-num)
1422                        (format t "~&~D-~D: " prev-num this-num)))
1423                  (print-code-location-source-form prev-location 0)
1424                  (when *print-location-kind*
1425                    (format t "~S " (sb!di:code-location-kind prev-location)))
1426                  (when (location-in-list prev-location *breakpoints*)
1427                    (format t " *Active*"))
1428                  (when (sb!di:code-location= prev-location continue-at)
1429                    (format t " *Continue here*")))))
1430
1431         (dolist (code-location *possible-breakpoints*)
1432           (when (or *print-location-kind*
1433                     (location-in-list code-location *breakpoints*)
1434                     (sb!di:code-location= code-location continue-at)
1435                     (not prev-location)
1436                     (not (eq (sb!di:code-location-debug-source code-location)
1437                              (sb!di:code-location-debug-source prev-location)))
1438                     (not (eq (sb!di:code-location-top-level-form-offset
1439                               code-location)
1440                              (sb!di:code-location-top-level-form-offset
1441                               prev-location)))
1442                     (not (eq (sb!di:code-location-form-number code-location)
1443                              (sb!di:code-location-form-number prev-location))))
1444             (flush)
1445             (setq prev-location code-location  prev-num this-num))
1446
1447           (incf this-num))))
1448
1449     (when (location-in-list *default-breakpoint-debug-function*
1450                             *breakpoints*
1451                             :function-end)
1452       (format t "~&::FUNCTION-END *Active* "))))
1453
1454 (!def-debug-command-alias "LL" "LIST-LOCATIONS")
1455
1456 ;;; Set breakpoint at the given number.
1457 (!def-debug-command "BREAKPOINT" ()
1458   (let ((index (read-prompting-maybe "location number, :START, or :END: "))
1459         (break t)
1460         (condition t)
1461         (print nil)
1462         (print-functions nil)
1463         (function nil)
1464         (bp)
1465         (place *default-breakpoint-debug-function*))
1466     (flet ((get-command-line ()
1467              (let ((command-line nil)
1468                    (unique '(nil)))
1469                (loop
1470                  (let ((next-input (read-if-available unique)))
1471                    (when (eq next-input unique) (return))
1472                    (push next-input command-line)))
1473                (nreverse command-line)))
1474            (set-vars-from-command-line (command-line)
1475              (do ((arg (pop command-line) (pop command-line)))
1476                  ((not arg))
1477                (ecase arg
1478                  (:condition (setf condition (pop command-line)))
1479                  (:print (push (pop command-line) print))
1480                  (:break (setf break (pop command-line)))
1481                  (:function
1482                   (setf function (eval (pop command-line)))
1483                   (setf *default-breakpoint-debug-function*
1484                         (sb!di:function-debug-function function))
1485                   (setf place *default-breakpoint-debug-function*)
1486                   (setf *possible-breakpoints*
1487                         (possible-breakpoints
1488                          *default-breakpoint-debug-function*))))))
1489            (setup-function-start ()
1490              (let ((code-loc (sb!di:debug-function-start-location place)))
1491                (setf bp (sb!di:make-breakpoint #'main-hook-function
1492                                                place
1493                                                :kind :function-start))
1494                (setf break (sb!di:preprocess-for-eval break code-loc))
1495                (setf condition (sb!di:preprocess-for-eval condition code-loc))
1496                (dolist (form print)
1497                  (push (cons (sb!di:preprocess-for-eval form code-loc) form)
1498                        print-functions))))
1499            (setup-function-end ()
1500              (setf bp
1501                    (sb!di:make-breakpoint #'main-hook-function
1502                                           place
1503                                           :kind :function-end))
1504              (setf break
1505                    ;; FIXME: These and any other old (COERCE `(LAMBDA ..) ..)
1506                    ;; forms should be converted to shiny new (LAMBDA ..) forms.
1507                    ;; (Search the sources for "coerce.*\(lambda".)
1508                    (coerce `(lambda (dummy)
1509                               (declare (ignore dummy)) ,break)
1510                            'function))
1511              (setf condition (coerce `(lambda (dummy)
1512                                         (declare (ignore dummy)) ,condition)
1513                                      'function))
1514              (dolist (form print)
1515                (push (cons
1516                       (coerce `(lambda (dummy)
1517                                  (declare (ignore dummy)) ,form) 'function)
1518                       form)
1519                      print-functions)))
1520            (setup-code-location ()
1521              (setf place (nth index *possible-breakpoints*))
1522              (setf bp (sb!di:make-breakpoint #'main-hook-function
1523                                              place
1524                                              :kind :code-location))
1525              (dolist (form print)
1526                (push (cons
1527                       (sb!di:preprocess-for-eval form place)
1528                       form)
1529                      print-functions))
1530              (setf break (sb!di:preprocess-for-eval break place))
1531              (setf condition (sb!di:preprocess-for-eval condition place))))
1532       (set-vars-from-command-line (get-command-line))
1533       (cond
1534        ((or (eq index :start) (eq index :s))
1535         (setup-function-start))
1536        ((or (eq index :end) (eq index :e))
1537         (setup-function-end))
1538        (t
1539         (setup-code-location)))
1540       (sb!di:activate-breakpoint bp)
1541       (let* ((new-bp-info (create-breakpoint-info place bp index
1542                                                   :break break
1543                                                   :print print-functions
1544                                                   :condition condition))
1545              (old-bp-info (location-in-list new-bp-info *breakpoints*)))
1546         (when old-bp-info
1547           (sb!di:deactivate-breakpoint (breakpoint-info-breakpoint
1548                                         old-bp-info))
1549           (setf *breakpoints* (remove old-bp-info *breakpoints*))
1550           (format t "previous breakpoint removed~%"))
1551         (push new-bp-info *breakpoints*))
1552       (print-breakpoint-info (first *breakpoints*))
1553       (format t "~&added"))))
1554
1555 (!def-debug-command-alias "BP" "BREAKPOINT")
1556
1557 ;;; List all breakpoints which are set.
1558 (!def-debug-command "LIST-BREAKPOINTS" ()
1559   (setf *breakpoints*
1560         (sort *breakpoints* #'< :key #'breakpoint-info-breakpoint-number))
1561   (dolist (info *breakpoints*)
1562     (print-breakpoint-info info)))
1563
1564 (!def-debug-command-alias "LB" "LIST-BREAKPOINTS")
1565 (!def-debug-command-alias "LBP" "LIST-BREAKPOINTS")
1566
1567 ;;; Remove breakpoint N, or remove all breakpoints if no N given.
1568 (!def-debug-command "DELETE-BREAKPOINT" ()
1569   (let* ((index (read-if-available nil))
1570          (bp-info
1571           (find index *breakpoints* :key #'breakpoint-info-breakpoint-number)))
1572     (cond (bp-info
1573            (sb!di:delete-breakpoint (breakpoint-info-breakpoint bp-info))
1574            (setf *breakpoints* (remove bp-info *breakpoints*))
1575            (format t "breakpoint ~S removed~%" index))
1576           (index (format t "The breakpoint doesn't exist."))
1577           (t
1578            (dolist (ele *breakpoints*)
1579              (sb!di:delete-breakpoint (breakpoint-info-breakpoint ele)))
1580            (setf *breakpoints* nil)
1581            (format t "all breakpoints deleted~%")))))
1582
1583 (!def-debug-command-alias "DBP" "DELETE-BREAKPOINT")
1584 \f
1585 ;;; miscellaneous commands
1586
1587 (!def-debug-command "DESCRIBE" ()
1588   (let* ((curloc (sb!di:frame-code-location *current-frame*))
1589          (debug-fun (sb!di:code-location-debug-function curloc))
1590          (function (sb!di:debug-function-function debug-fun)))
1591     (if function
1592         (describe function)
1593         (format t "can't figure out the function for this frame"))))
1594 \f
1595 ;;;; debug loop command utilities
1596
1597 (defun read-prompting-maybe (prompt &optional (in *standard-input*)
1598                                     (out *standard-output*))
1599   (unless (sb!int:listen-skip-whitespace in)
1600     (princ prompt out)
1601     (force-output out))
1602   (read in))
1603
1604 (defun read-if-available (default &optional (stream *standard-input*))
1605   (if (sb!int:listen-skip-whitespace stream)
1606       (read stream)
1607       default))