src/code/debug.lisp

   1 ;;;; the debugger
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!DEBUG")
  13 \f
  14 ;;;; variables and constants
  15
  16 ;;; things to consider when tweaking these values:
  17 ;;;   * We're afraid to just default them to NIL and NIL, in case the
  18 ;;;     user inadvertently causes a hairy data structure to be printed
  19 ;;;     when he inadvertently enters the debugger.
  20 ;;;   * We don't want to truncate output too much. These days anyone
  21 ;;;     can easily run their Lisp in a windowing system or under Emacs,
  22 ;;;     so it's not the end of the world even if the worst case is a
  23 ;;;     few thousand lines of output.
  24 ;;;   * As condition :REPORT methods are converted to use the pretty
  25 ;;;     printer, they acquire *PRINT-LEVEL* constraints, so e.g. under
  26 ;;;     sbcl-0.7.1.28's old value of *DEBUG-PRINT-LEVEL*=3, an
  27 ;;;     ARG-COUNT-ERROR printed as
  28 ;;;       error while parsing arguments to DESTRUCTURING-BIND:
  29 ;;;         invalid number of elements in
  30 ;;;           #
  31 ;;;         to satisfy lambda list
  32 ;;;           #:
  33 ;;;         exactly 2 expected, but 5 found
  34 (defvar *debug-print-level* 5
  35   #!+sb-doc
  36   "*PRINT-LEVEL* for the debugger")
  37 (defvar *debug-print-length* 7
  38   #!+sb-doc
  39   "*PRINT-LENGTH* for the debugger")
  40
  41 (defvar *debug-readtable*
  42   ;; KLUDGE: This can't be initialized in a cold toplevel form,
  43   ;; because the *STANDARD-READTABLE* isn't initialized until after
  44   ;; cold toplevel forms have run. So instead we initialize it
  45   ;; immediately after *STANDARD-READTABLE*. -- WHN 20000205
  46   nil
  47   #!+sb-doc
  48   "*READTABLE* for the debugger")
  49
  50 (defvar *in-the-debugger* nil
  51   #!+sb-doc
  52   "This is T while in the debugger.")
  53
  54 ;;; nestedness inside debugger command loops
  55 (defvar *debug-command-level* 0)
  56
  57 ;;; If this is bound before the debugger is invoked, it is used as the
  58 ;;; stack top by the debugger.
  59 (defvar *stack-top-hint* nil)
  60
  61 (defvar *stack-top* nil)
  62 (defvar *real-stack-top* nil)
  63
  64 (defvar *current-frame* nil)
  65
  66 ;;; Beginner-oriented help messages are important because you end up
  67 ;;; in the debugger whenever something bad happens, or if you try to
  68 ;;; get out of the system with Ctrl-C or (EXIT) or EXIT or whatever.
  69 ;;; But after memorizing them the wasted screen space gets annoying..
  70 (defvar *debug-beginner-help-p* t
  71   "Should the debugger display beginner-oriented help messages?")
  72
  73 (defun debug-prompt (stream)
  74   (sb!thread::get-foreground)
  75   (format stream
  76           "~%~W~:[~;[~W~]] "
  77           (sb!di:frame-number *current-frame*)
  78           (> *debug-command-level* 1)
  79           *debug-command-level*))
  80
  81 (defparameter *debug-help-string*
  82 "The debug prompt is square brackets, with number(s) indicating the current
  83   control stack level and, if you've entered the debugger recursively, how
  84   deeply recursed you are.
  85 Any command -- including the name of a restart -- may be uniquely abbreviated.
  86 The debugger rebinds various special variables for controlling i/o, sometimes
  87   to defaults (much like WITH-STANDARD-IO-SYNTAX does) and sometimes to
  88   its own special values, e.g. SB-DEBUG:*DEBUG-PRINT-LEVEL*.
  89 Debug commands do not affect *, //, and similar variables, but evaluation in
  90   the debug loop does affect these variables.
  91 SB-DEBUG:*FLUSH-DEBUG-ERRORS* controls whether errors at the debug prompt
  92   drop you deeper into the debugger.
  93
  94 Getting in and out of the debugger:
  95   RESTART  invokes restart numbered as shown (prompt if not given).
  96   ERROR    prints the error condition and restart cases.
  97   The number of any restart, or its name, or a unique abbreviation for its
  98     name, is a valid command, and is the same as using RESTART to invoke
  99     that restart.
 100
 101 Changing frames:
 102   U      up frame     D    down frame
 103   B  bottom frame     F n  frame n (n=0 for top frame)
 104
 105 Inspecting frames:
 106   BACKTRACE [n]  shows n frames going down the stack.
 107   LIST-LOCALS, L lists locals in current function.
 108   PRINT, P       displays current function call.
 109   SOURCE [n]     displays frame's source form with n levels of enclosing forms.
 110
 111 Breakpoints and steps:
 112   LIST-LOCATIONS [{function | :C}]   List the locations for breakpoints.
 113                                      Specify :C for the current frame.
 114     Abbreviation: LL
 115   LIST-BREAKPOINTS                   List the active breakpoints.
 116     Abbreviations: LB, LBP
 117   DELETE-BREAKPOINT [n]              Remove breakpoint n or all breakpoints.
 118     Abbreviations: DEL, DBP
 119   BREAKPOINT {n | :end | :start} [:break form] [:function function]
 120              [{:print form}*] [:condition form]
 121                                      Set a breakpoint.
 122     Abbreviations: BR, BP
 123   STEP [n]                           Step to the next location or step n times.
 124
 125 Function and macro commands:
 126  (SB-DEBUG:ARG n)
 127     Return the n'th argument in the current frame.
 128  (SB-DEBUG:VAR string-or-symbol [id])
 129     Returns the value of the specified variable in the current frame.
 130
 131 Other commands:
 132   RETURN expr
 133     [EXPERIMENTAL] Return the values resulting from evaluation of expr
 134     from the current frame, if this frame was compiled with a sufficiently
 135     high DEBUG optimization quality.
 136   SLURP
 137     Discard all pending input on *STANDARD-INPUT*. (This can be
 138     useful when the debugger was invoked to handle an error in
 139     deeply nested input syntax, and now the reader is confused.)")
 140 \f
 141 ;;; This is used to communicate to DEBUG-LOOP that we are at a step breakpoint.
 142 (define-condition step-condition (simple-condition) ())
 143 \f
 144 ;;;; breakpoint state
 145
 146 (defvar *only-block-start-locations* nil
 147   #!+sb-doc
 148   "When true, the LIST-LOCATIONS command only displays block start locations.
 149    Otherwise, all locations are displayed.")
 150
 151 (defvar *print-location-kind* nil
 152   #!+sb-doc
 153   "When true, list the code location type in the LIST-LOCATIONS command.")
 154
 155 ;;; a list of the types of code-locations that should not be stepped
 156 ;;; to and should not be listed when listing breakpoints
 157 (defvar *bad-code-location-types* '(:call-site :internal-error))
 158 (declaim (type list *bad-code-location-types*))
 159
 160 ;;; code locations of the possible breakpoints
 161 (defvar *possible-breakpoints*)
 162 (declaim (type list *possible-breakpoints*))
 163
 164 ;;; a list of the made and active breakpoints, each is a
 165 ;;; BREAKPOINT-INFO structure
 166 (defvar *breakpoints* nil)
 167 (declaim (type list *breakpoints*))
 168
 169 ;;; a list of BREAKPOINT-INFO structures of the made and active step
 170 ;;; breakpoints
 171 (defvar *step-breakpoints* nil)
 172 (declaim (type list *step-breakpoints*))
 173
 174 ;;; the number of times left to step
 175 (defvar *number-of-steps* 1)
 176 (declaim (type integer *number-of-steps*))
 177
 178 ;;; This is used when listing and setting breakpoints.
 179 (defvar *default-breakpoint-debug-fun* nil)
 180 (declaim (type (or list sb!di:debug-fun) *default-breakpoint-debug-fun*))
 181 \f
 182 ;;;; code location utilities
 183
 184 ;;; Return the first code-location in the passed debug block.
 185 (defun first-code-location (debug-block)
 186   (let ((found nil)
 187         (first-code-location nil))
 188     (sb!di:do-debug-block-locations (code-location debug-block)
 189       (unless found
 190         (setf first-code-location code-location)
 191         (setf found t)))
 192     first-code-location))
 193
 194 ;;; Return a list of the next code-locations following the one passed.
 195 ;;; One of the *BAD-CODE-LOCATION-TYPES* will not be returned.
 196 (defun next-code-locations (code-location)
 197   (let ((debug-block (sb!di:code-location-debug-block code-location))
 198         (block-code-locations nil))
 199     (sb!di:do-debug-block-locations (block-code-location debug-block)
 200       (unless (member (sb!di:code-location-kind block-code-location)
 201                       *bad-code-location-types*)
 202         (push block-code-location block-code-locations)))
 203     (setf block-code-locations (nreverse block-code-locations))
 204     (let* ((code-loc-list (rest (member code-location block-code-locations
 205                                         :test #'sb!di:code-location=)))
 206            (next-list (cond (code-loc-list
 207                              (list (first code-loc-list)))
 208                             ((map 'list #'first-code-location
 209                                   (sb!di:debug-block-successors debug-block)))
 210                             (t nil))))
 211       (when (and (= (length next-list) 1)
 212                  (sb!di:code-location= (first next-list) code-location))
 213         (setf next-list (next-code-locations (first next-list))))
 214       next-list)))
 215
 216 ;;; Return a list of code-locations of the possible breakpoints of DEBUG-FUN.
 217 (defun possible-breakpoints (debug-fun)
 218   (let ((possible-breakpoints nil))
 219     (sb!di:do-debug-fun-blocks (debug-block debug-fun)
 220       (unless (sb!di:debug-block-elsewhere-p debug-block)
 221         (if *only-block-start-locations*
 222             (push (first-code-location debug-block) possible-breakpoints)
 223             (sb!di:do-debug-block-locations (code-location debug-block)
 224               (when (not (member (sb!di:code-location-kind code-location)
 225                                  *bad-code-location-types*))
 226                 (push code-location possible-breakpoints))))))
 227     (nreverse possible-breakpoints)))
 228
 229 ;;; Search the info-list for the item passed (CODE-LOCATION,
 230 ;;; DEBUG-FUN, or BREAKPOINT-INFO). If the item passed is a debug
 231 ;;; function then kind will be compared if it was specified. The kind
 232 ;;; if also compared if a breakpoint-info is passed since it's in the
 233 ;;; breakpoint. The info structure is returned if found.
 234 (defun location-in-list (place info-list &optional (kind nil))
 235   (when (breakpoint-info-p place)
 236     (setf kind (sb!di:breakpoint-kind (breakpoint-info-breakpoint place)))
 237     (setf place (breakpoint-info-place place)))
 238   (cond ((sb!di:code-location-p place)
 239          (find place info-list
 240                :key #'breakpoint-info-place
 241                :test (lambda (x y) (and (sb!di:code-location-p y)
 242                                         (sb!di:code-location= x y)))))
 243         (t
 244          (find place info-list
 245                :test (lambda (x-debug-fun y-info)
 246                        (let ((y-place (breakpoint-info-place y-info))
 247                              (y-breakpoint (breakpoint-info-breakpoint
 248                                             y-info)))
 249                          (and (sb!di:debug-fun-p y-place)
 250                               (eq x-debug-fun y-place)
 251                               (or (not kind)
 252                                   (eq kind (sb!di:breakpoint-kind
 253                                             y-breakpoint))))))))))
 254
 255 ;;; If LOC is an unknown location, then try to find the block start
 256 ;;; location. Used by source printing to some information instead of
 257 ;;; none for the user.
 258 (defun maybe-block-start-location (loc)
 259   (if (sb!di:code-location-unknown-p loc)
 260       (let* ((block (sb!di:code-location-debug-block loc))
 261              (start (sb!di:do-debug-block-locations (loc block)
 262                       (return loc))))
 263         (cond ((and (not (sb!di:debug-block-elsewhere-p block))
 264                     start)
 265                ;; FIXME: Why output on T instead of *DEBUG-FOO* or something?
 266                (format t "~%unknown location: using block start~%")
 267                start)
 268               (t
 269                loc)))
 270       loc))
 271 \f
 272 ;;;; the BREAKPOINT-INFO structure
 273
 274 ;;; info about a made breakpoint
 275 (defstruct (breakpoint-info (:copier nil)
 276                             (:constructor %make-breakpoint-info))
 277   ;; where we are going to stop
 278   (place (missing-arg)
 279          :type (or sb!di:code-location sb!di:debug-fun)
 280          :read-only t)
 281   ;; the breakpoint returned by SB!DI:MAKE-BREAKPOINT
 282   (breakpoint (missing-arg) :type sb!di:breakpoint :read-only t)
 283   ;; the function returned from SB!DI:PREPROCESS-FOR-EVAL. If result is
 284   ;; non-NIL, drop into the debugger.
 285   (break #'identity :type function :read-only t)
 286   ;; the function returned from SB!DI:PREPROCESS-FOR-EVAL. If result is
 287   ;; non-NIL, eval (each) print and print results.
 288   (condition #'identity :type function :read-only t)
 289   ;; the list of functions from SB!DI:PREPROCESS-FOR-EVAL to evaluate.
 290   ;; Results are conditionally printed. CAR of each element is the
 291   ;; function, CDR is the form it goes with.
 292   (print nil :type list :read-only t)
 293   ;; the number used when listing the possible breakpoints within a
 294   ;; function; or could also be a symbol such as START or END
 295   (code-location-selector (missing-arg) :type (or symbol integer) :read-only t)
 296   ;; the number used when listing the active breakpoints, and when
 297   ;; deleting breakpoints
 298   (breakpoint-number (missing-arg) :type integer :read-only t))
 299
 300 (defun create-breakpoint-info (place breakpoint code-location-selector
 301                                      &key (break #'identity)
 302                                      (condition #'identity) (print nil))
 303   (setf *breakpoints*
 304         (sort *breakpoints* #'< :key #'breakpoint-info-breakpoint-number))
 305   (let ((breakpoint-number
 306          (do ((i 1 (incf i)) (breakpoints *breakpoints* (rest breakpoints)))
 307              ((or (> i (length *breakpoints*))
 308                   (not (= i (breakpoint-info-breakpoint-number
 309                              (first breakpoints)))))
 310
 311               i))))
 312     (%make-breakpoint-info :place place
 313                            :breakpoint breakpoint
 314                            :code-location-selector code-location-selector
 315                            :breakpoint-number breakpoint-number
 316                            :break break
 317                            :condition condition
 318                            :print print)))
 319
 320 (defun print-breakpoint-info (breakpoint-info)
 321   (let ((place (breakpoint-info-place breakpoint-info))
 322         (bp-number (breakpoint-info-breakpoint-number breakpoint-info)))
 323     (case (sb!di:breakpoint-kind (breakpoint-info-breakpoint breakpoint-info))
 324       (:code-location
 325        (print-code-location-source-form place 0)
 326        (format t
 327                "~&~S: ~S in ~S"
 328                bp-number
 329                (breakpoint-info-code-location-selector breakpoint-info)
 330                (sb!di:debug-fun-name (sb!di:code-location-debug-fun place))))
 331       (:fun-start
 332        (format t "~&~S: FUN-START in ~S" bp-number
 333                (sb!di:debug-fun-name place)))
 334       (:fun-end
 335        (format t "~&~S: FUN-END in ~S" bp-number
 336                (sb!di:debug-fun-name place))))))
 337 \f
 338 ;;;; MAIN-HOOK-FUN for steps and breakpoints
 339
 340 ;;; This must be passed as the hook function. It keeps track of where
 341 ;;; STEP breakpoints are.
 342 (defun main-hook-fun (current-frame breakpoint &optional return-vals
 343                                     fun-end-cookie)
 344   (setf *default-breakpoint-debug-fun*
 345         (sb!di:frame-debug-fun current-frame))
 346   (dolist (step-info *step-breakpoints*)
 347     (sb!di:delete-breakpoint (breakpoint-info-breakpoint step-info))
 348     (let ((bp-info (location-in-list step-info *breakpoints*)))
 349       (when bp-info
 350         (sb!di:activate-breakpoint (breakpoint-info-breakpoint bp-info)))))
 351   (let ((*stack-top-hint* current-frame)
 352         (step-hit-info
 353          (location-in-list (sb!di:breakpoint-what breakpoint)
 354                            *step-breakpoints*
 355                            (sb!di:breakpoint-kind breakpoint)))
 356         (bp-hit-info
 357          (location-in-list (sb!di:breakpoint-what breakpoint)
 358                            *breakpoints*
 359                            (sb!di:breakpoint-kind breakpoint)))
 360         (break)
 361         (condition)
 362         (string ""))
 363     (setf *step-breakpoints* nil)
 364     (labels ((build-string (str)
 365                (setf string (concatenate 'string string str)))
 366              (print-common-info ()
 367                (build-string
 368                 (with-output-to-string (*standard-output*)
 369                   (when fun-end-cookie
 370                     (format t "~%Return values: ~S" return-vals))
 371                   (when condition
 372                     (when (breakpoint-info-print bp-hit-info)
 373                       (format t "~%")
 374                       (print-frame-call current-frame))
 375                     (dolist (print (breakpoint-info-print bp-hit-info))
 376                       (format t "~& ~S = ~S" (rest print)
 377                               (funcall (first print) current-frame))))))))
 378       (when bp-hit-info
 379         (setf break (funcall (breakpoint-info-break bp-hit-info)
 380                              current-frame))
 381         (setf condition (funcall (breakpoint-info-condition bp-hit-info)
 382                                  current-frame)))
 383       (cond ((and bp-hit-info step-hit-info (= 1 *number-of-steps*))
 384              (build-string (format nil "~&*Step (to a breakpoint)*"))
 385              (print-common-info)
 386              (break string))
 387             ((and bp-hit-info step-hit-info break)
 388              (build-string (format nil "~&*Step (to a breakpoint)*"))
 389              (print-common-info)
 390              (break string))
 391             ((and bp-hit-info step-hit-info)
 392              (print-common-info)
 393              (format t "~A" string)
 394              (decf *number-of-steps*)
 395              (set-step-breakpoint current-frame))
 396             ((and step-hit-info (= 1 *number-of-steps*))
 397              (build-string "*Step*")
 398              (break (make-condition 'step-condition :format-control string)))
 399             (step-hit-info
 400              (decf *number-of-steps*)
 401              (set-step-breakpoint current-frame))
 402             (bp-hit-info
 403              (when break
 404                (build-string (format nil "~&*Breakpoint hit*")))
 405              (print-common-info)
 406              (if break
 407                  (break string)
 408                  (format t "~A" string)))
 409             (t
 410              (break "unknown breakpoint"))))))
 411 \f
 412 ;;; Set breakpoints at the next possible code-locations. After calling
 413 ;;; this, either (CONTINUE) if in the debugger or just let program flow
 414 ;;; return if in a hook function.
 415 (defun set-step-breakpoint (frame)
 416   (cond
 417    ((sb!di:debug-block-elsewhere-p (sb!di:code-location-debug-block
 418                                     (sb!di:frame-code-location frame)))
 419     ;; FIXME: FORMAT T is used for error output here and elsewhere in
 420     ;; the debug code.
 421     (format t "cannot step, in elsewhere code~%"))
 422    (t
 423     (let* ((code-location (sb!di:frame-code-location frame))
 424            (next-code-locations (next-code-locations code-location)))
 425       (cond
 426        (next-code-locations
 427         (dolist (code-location next-code-locations)
 428           (let ((bp-info (location-in-list code-location *breakpoints*)))
 429             (when bp-info
 430               (sb!di:deactivate-breakpoint (breakpoint-info-breakpoint
 431                                             bp-info))))
 432           (let ((bp (sb!di:make-breakpoint #'main-hook-fun code-location
 433                                            :kind :code-location)))
 434             (sb!di:activate-breakpoint bp)
 435             (push (create-breakpoint-info code-location bp 0)
 436                   *step-breakpoints*))))
 437        (t
 438         (let* ((debug-fun (sb!di:frame-debug-fun *current-frame*))
 439                (bp (sb!di:make-breakpoint #'main-hook-fun debug-fun
 440                                           :kind :fun-end)))
 441           (sb!di:activate-breakpoint bp)
 442           (push (create-breakpoint-info debug-fun bp 0)
 443                 *step-breakpoints*))))))))
 444 \f
 445 ;;;; STEP
 446
 447 ;;; ANSI specifies that this macro shall exist, even if only as a
 448 ;;; trivial placeholder like this.
 449 (defmacro step (form)
 450   "This is a trivial placeholder implementation of the CL:STEP macro required
 451    by the ANSI spec, simply expanding to `(LET () ,FORM). A more featureful
 452    version would be welcome, we just haven't written it."
 453   `(let ()
 454      ,form))
 455 \f
 456 ;;;; BACKTRACE
 457
 458 (defun backtrace (&optional (count most-positive-fixnum)
 459                             (*standard-output* *debug-io*))
 460   #!+sb-doc
 461   "Show a listing of the call stack going down from the current frame. In the
 462    debugger, the current frame is indicated by the prompt. COUNT is how many
 463    frames to show."
 464   (fresh-line *standard-output*)
 465   (do ((frame (if *in-the-debugger* *current-frame* (sb!di:top-frame))
 466               (sb!di:frame-down frame))
 467        (count count (1- count)))
 468       ((or (null frame) (zerop count)))
 469     (print-frame-call frame :number t))
 470   (fresh-line *standard-output*)
 471   (values))
 472
 473 (defun backtrace-as-list (&optional (count most-positive-fixnum))
 474   #!+sb-doc "Return a list representing the current BACKTRACE."
 475   (do ((reversed-result nil)
 476        (frame (if *in-the-debugger* *current-frame* (sb!di:top-frame))
 477               (sb!di:frame-down frame))
 478        (count count (1- count)))
 479       ((or (null frame) (zerop count))
 480        (nreverse reversed-result))
 481     (push (frame-call-as-list frame) reversed-result)))
 482
 483 (defun frame-call-as-list (frame)
 484   (cons (sb!di:debug-fun-name (sb!di:frame-debug-fun frame))
 485         (frame-args-as-list frame)))
 486 \f
 487 ;;;; frame printing
 488
 489 (eval-when (:compile-toplevel :execute)
 490
 491 ;;; This is a convenient way to express what to do for each type of
 492 ;;; lambda-list element.
 493 (sb!xc:defmacro lambda-list-element-dispatch (element
 494                                               &key
 495                                               required
 496                                               optional
 497                                               rest
 498                                               keyword
 499                                               deleted)
 500   `(etypecase ,element
 501      (sb!di:debug-var
 502       ,@required)
 503      (cons
 504       (ecase (car ,element)
 505         (:optional ,@optional)
 506         (:rest ,@rest)
 507         (:keyword ,@keyword)))
 508      (symbol
 509       (aver (eq ,element :deleted))
 510       ,@deleted)))
 511
 512 (sb!xc:defmacro lambda-var-dispatch (variable location deleted valid other)
 513   (let ((var (gensym)))
 514     `(let ((,var ,variable))
 515        (cond ((eq ,var :deleted) ,deleted)
 516              ((eq (sb!di:debug-var-validity ,var ,location) :valid)
 517               ,valid)
 518              (t ,other)))))
 519
 520 ) ; EVAL-WHEN
 521
 522 ;;; This is used in constructing arg lists for debugger printing when
 523 ;;; the arg list is unavailable, some arg is unavailable or unused, etc.
 524 (defstruct (unprintable-object
 525             (:constructor make-unprintable-object (string))
 526             (:print-object (lambda (x s)
 527                              (print-unreadable-object (x s)
 528                                (write-string (unprintable-object-string x)
 529                                              s))))
 530             (:copier nil))
 531   string)
 532
 533 ;;; Extract the function argument values for a debug frame.
 534 (defun frame-args-as-list (frame)
 535   (let ((debug-fun (sb!di:frame-debug-fun frame))
 536         (loc (sb!di:frame-code-location frame))
 537         (reversed-result nil))
 538     (handler-case
 539         (progn
 540           (dolist (ele (sb!di:debug-fun-lambda-list debug-fun))
 541             (lambda-list-element-dispatch ele
 542              :required ((push (frame-call-arg ele loc frame) reversed-result))
 543              :optional ((push (frame-call-arg (second ele) loc frame)
 544                               reversed-result))
 545              :keyword ((push (second ele) reversed-result)
 546                        (push (frame-call-arg (third ele) loc frame)
 547                              reversed-result))
 548              :deleted ((push (frame-call-arg ele loc frame) reversed-result))
 549              :rest ((lambda-var-dispatch (second ele) loc
 550                      nil
 551                      (progn
 552                        (setf reversed-result
 553                              (append (reverse (sb!di:debug-var-value
 554                                                (second ele) frame))
 555                                      reversed-result))
 556                        (return))
 557                      (push (make-unprintable-object
 558                             "unavailable &REST argument")
 559                      reversed-result)))))
 560           ;; As long as we do an ordinary return (as opposed to SIGNALing
 561           ;; a CONDITION) from the DOLIST above:
 562           (nreverse reversed-result))
 563       (sb!di:lambda-list-unavailable
 564        ()
 565        (make-unprintable-object "unavailable lambda list")))))
 566
 567 ;;; Print FRAME with verbosity level 1. If we hit a &REST arg, then
 568 ;;; print as many of the values as possible, punting the loop over
 569 ;;; lambda-list variables since any other arguments will be in the
 570 ;;; &REST arg's list of values.
 571 (defun print-frame-call-1 (frame)
 572   (let ((debug-fun (sb!di:frame-debug-fun frame)))
 573
 574     (pprint-logical-block (*standard-output* nil :prefix "(" :suffix ")")
 575       (let ((args (ensure-printable-object (frame-args-as-list frame))))
 576         ;; Since we go to some trouble to make nice informative function
 577         ;; names like (PRINT-OBJECT :AROUND (CLOWN T)), let's make sure
 578         ;; that they aren't truncated by *PRINT-LENGTH* and *PRINT-LEVEL*.
 579         (let ((*print-length* nil)
 580               (*print-level* nil))
 581           (prin1 (ensure-printable-object (sb!di:debug-fun-name debug-fun))))
 582         ;; For the function arguments, we can just print normally.
 583         (if (listp args)
 584             (format t "~{ ~_~S~}" args)
 585             (format t " ~S" args))))
 586
 587     (when (sb!di:debug-fun-kind debug-fun)
 588       (write-char #\[)
 589       (prin1 (sb!di:debug-fun-kind debug-fun))
 590       (write-char #\]))))
 591
 592 (defun ensure-printable-object (object)
 593   (handler-case
 594       (with-open-stream (out (make-broadcast-stream))
 595         (prin1 object out)
 596         object)
 597     (error (cond)
 598       (declare (ignore cond))
 599       (make-unprintable-object "error printing object"))))
 600
 601 (defun frame-call-arg (var location frame)
 602   (lambda-var-dispatch var location
 603     (make-unprintable-object "unused argument")
 604     (sb!di:debug-var-value var frame)
 605     (make-unprintable-object "unavailable argument")))
 606
 607 ;;; Prints a representation of the function call causing FRAME to
 608 ;;; exist. VERBOSITY indicates the level of information to output;
 609 ;;; zero indicates just printing the DEBUG-FUN's name, and one
 610 ;;; indicates displaying call-like, one-liner format with argument
 611 ;;; values.
 612 (defun print-frame-call (frame &key (verbosity 1) (number nil))
 613   (cond
 614    ((zerop verbosity)
 615     (when number
 616       (format t "~&~S: " (sb!di:frame-number frame)))
 617     (format t "~S" frame))
 618    (t
 619     (when number
 620       (format t "~&~S: " (sb!di:frame-number frame)))
 621     (print-frame-call-1 frame)))
 622   (when (>= verbosity 2)
 623     (let ((loc (sb!di:frame-code-location frame)))
 624       (handler-case
 625           (progn
 626             (sb!di:code-location-debug-block loc)
 627             (format t "~%source: ")
 628             (print-code-location-source-form loc 0))
 629         (sb!di:debug-condition (ignore) ignore)
 630         (error (c) (format t "error finding source: ~A" c))))))
 631 \f
 632 ;;;; INVOKE-DEBUGGER
 633
 634 (defvar *debugger-hook* nil
 635   #!+sb-doc
 636   "This is either NIL or a function of two arguments, a condition and the value
 637    of *DEBUGGER-HOOK*. This function can either handle the condition or return
 638    which causes the standard debugger to execute. The system passes the value
 639    of this variable to the function because it binds *DEBUGGER-HOOK* to NIL
 640    around the invocation.")
 641
 642 ;;; These are bound on each invocation of INVOKE-DEBUGGER.
 643 (defvar *debug-restarts*)
 644 (defvar *debug-condition*)
 645 (defvar *nested-debug-condition*)
 646
 647 ;;; the ordinary ANSI case of INVOKE-DEBUGGER, when not suppressed by
 648 ;;; command-line --disable-debugger option
 649 (defun invoke-debugger/enabled (condition)
 650   #!+sb-doc
 651   "Enter the debugger."
 652   (let ((old-hook *debugger-hook*))
 653     (when old-hook
 654       (let ((*debugger-hook* nil))
 655         (funcall old-hook condition old-hook))))
 656
 657   ;; If we're a background thread and *background-threads-wait-for-debugger*
 658   ;; is NIL, this will invoke a restart
 659
 660   ;; Note: CMU CL had (SB-UNIX:UNIX-SIGSETMASK 0) here. I deleted it
 661   ;; around sbcl-0.7.8.5 (by which time it had mutated to have a
 662   ;; #!-SUNOS prefix and a FIXME note observing that it wasn't needed
 663   ;; on SunOS and no one knew why it was needed anywhere else either).
 664   ;; So if something mysteriously breaks that has worked since the CMU
 665   ;; CL days, that might be why. -- WHN 2002-09-28
 666
 667   ;; We definitely want *PACKAGE* to be of valid type.
 668   ;;
 669   ;; Elsewhere in the system, we use the SANE-PACKAGE function for
 670   ;; this, but here causing an exception just as we're trying to handle
 671   ;; an exception would be confusing, so instead we use a special hack.
 672   (unless (and (packagep *package*)
 673                (package-name *package*))
 674     (setf *package* (find-package :cl-user))
 675     (format *error-output*
 676             "The value of ~S was not an undeleted PACKAGE. It has been
 677 reset to ~S."
 678             '*package* *package*))
 679
 680   ;; Try to force the other special variables into a useful state.
 681   (let (;; Protect from WITH-STANDARD-IO-SYNTAX some variables where
 682         ;; any default we might use is less useful than just reusing
 683         ;; the global values.
 684         (original-package *package*)
 685         (original-print-pretty *print-pretty*))
 686     (with-standard-io-syntax
 687      (let ((*debug-condition* condition)
 688            (*debug-restarts* (compute-restarts condition))
 689            (*nested-debug-condition* nil)
 690            ;; We want the printer and reader to be in a useful state,
 691            ;; regardless of where the debugger was invoked in the
 692            ;; program. WITH-STANDARD-IO-SYNTAX did much of what we
 693            ;; want, but
 694            ;;   * It doesn't affect our internal special variables
 695            ;;     like *CURRENT-LEVEL-IN-PRINT*.
 696            ;;   * It isn't customizable.
 697            ;;   * It doesn't set *PRINT-READABLY* to the same value
 698            ;;     as the toplevel default.
 699            ;;   * It sets *PACKAGE* to COMMON-LISP-USER, which is not
 700            ;;     helpful behavior for a debugger.
 701            ;;   * There's no particularly good debugger default for
 702            ;;     *PRINT-PRETTY*, since T is usually what you want
 703            ;;     -- except absolutely not what you want when you're
 704            ;;     debugging failures in PRINT-OBJECT logic.
 705            ;; We try to address all these issues with explicit
 706            ;; rebindings here.
 707            (sb!kernel:*current-level-in-print* 0)
 708            (*print-length* *debug-print-length*)
 709            (*print-level* *debug-print-level*)
 710            (*readtable* *debug-readtable*)
 711            (*print-readably* nil)
 712            (*package* original-package)
 713            (background-p nil)
 714            (*print-pretty* original-print-pretty))
 715
 716        ;; Before we start our own output, finish any pending output.
 717        ;; Otherwise, if the user tried to track the progress of his
 718        ;; program using PRINT statements, he'd tend to lose the last
 719        ;; line of output or so, which'd be confusing.
 720        (flush-standard-output-streams)
 721
 722        ;; (The initial output here goes to *ERROR-OUTPUT*, because the
 723        ;; initial output is not interactive, just an error message,
 724        ;; and when people redirect *ERROR-OUTPUT*, they could
 725        ;; reasonably expect to see error messages logged there,
 726        ;; regardless of what the debugger does afterwards.)
 727        (handler-case
 728            (format *error-output*
 729                    "~2&~@<debugger invoked on condition of type ~S: ~
 730                     ~2I~_~A~:>~%"
 731                    (type-of *debug-condition*)
 732                    *debug-condition*)
 733          (error (condition)
 734            (setf *nested-debug-condition* condition)
 735            (let ((ndc-type (type-of *nested-debug-condition*)))
 736              (format *error-output*
 737                      "~&~@<(A ~S was caught when trying to print ~S when ~
 738                       entering the debugger. Printing was aborted and the ~
 739                       ~S was stored in ~S.)~@:>~%"
 740                      ndc-type
 741                      '*debug-condition*
 742                      ndc-type
 743                      '*nested-debug-condition*))
 744            (when (typep condition 'cell-error)
 745              ;; what we really want to know when it's e.g. an UNBOUND-VARIABLE:
 746              (format *error-output*
 747                      "~&(CELL-ERROR-NAME ~S) = ~S~%"
 748                      '*debug-condition*
 749                      (cell-error-name *debug-condition*)))))
 750
 751        ;; After the initial error/condition/whatever announcement to
 752        ;; *ERROR-OUTPUT*, we become interactive, and should talk on
 753        ;; *DEBUG-IO* from now on. (KLUDGE: This is a normative
 754        ;; statement, not a description of reality.:-| There's a lot of
 755        ;; older debugger code which was written to do i/o on whatever
 756        ;; stream was in fashion at the time, and not all of it has
 757        ;; been converted to behave this way. -- WHN 2000-11-16)
 758
 759        (setf background-p
 760              (sb!thread::debugger-wait-until-foreground-thread *debug-io*))
 761        (unwind-protect
 762        (let (;; FIXME: Rebinding *STANDARD-OUTPUT* here seems wrong,
 763              ;; violating the principle of least surprise, and making
 764              ;; it impossible for the user to do reasonable things
 765              ;; like using PRINT at the debugger prompt to send output
 766              ;; to the program's ordinary (possibly
 767              ;; redirected-to-a-file) *STANDARD-OUTPUT*. (CMU CL
 768              ;; used to rebind *STANDARD-INPUT* here too, but that's
 769              ;; been fixed already.)
 770              (*standard-output* *debug-io*)
 771              ;; This seems reasonable: e.g. if the user has redirected
 772              ;; *ERROR-OUTPUT* to some log file, it's probably wrong
 773              ;; to send errors which occur in interactive debugging to
 774              ;; that file, and right to send them to *DEBUG-IO*.
 775              (*error-output* *debug-io*))
 776          (unless (typep condition 'step-condition)
 777            (when *debug-beginner-help-p*
 778              (format *debug-io*
 779                      "~%~@<Within the debugger, you can type HELP for help. ~
 780                       At any command prompt (within the debugger or not) you ~
 781                       can type (SB-EXT:QUIT) to terminate the SBCL ~
 782                       executable. The condition which caused the debugger to ~
 783                       be entered is bound to ~S. You can suppress this ~
 784                       message by clearing ~S.~:@>~2%"
 785                      '*debug-condition*
 786                      '*debug-beginner-help-p*))
 787            (show-restarts *debug-restarts* *debug-io*))
 788               (internal-debug))
 789          (when background-p (sb!thread::release-foreground)))))))
 790
 791 ;;; the degenerate case of INVOKE-DEBUGGER, when ordinary ANSI behavior
 792 ;;; has been suppressed by command-line --disable-debugger option
 793 (defun invoke-debugger/disabled (condition)
 794   ;; There is no one there to interact with, so report the
 795   ;; condition and terminate the program.
 796   (flet ((failure-quit (&key recklessly-p)
 797            (/show0 "in FAILURE-QUIT (in --disable-debugger debugger hook)")
 798            (quit :unix-status 1 :recklessly-p recklessly-p)))
 799     ;; This HANDLER-CASE is here mostly to stop output immediately
 800     ;; (and fall through to QUIT) when there's an I/O error. Thus,
 801     ;; when we're run under a shell script or something, we can die
 802     ;; cleanly when the script dies (and our pipes are cut), instead
 803     ;; of falling into ldb or something messy like that. Similarly, we
 804     ;; can terminate cleanly even if BACKTRACE dies because of bugs in
 805     ;; user PRINT-OBJECT methods.
 806     (handler-case
 807         (progn
 808           (format *error-output*
 809                   "~&~@<unhandled condition (of type ~S): ~2I~_~A~:>~2%"
 810                   (type-of condition)
 811                   condition)
 812           ;; Flush *ERROR-OUTPUT* even before the BACKTRACE, so that
 813           ;; even if we hit an error within BACKTRACE (e.g. a bug in
 814           ;; the debugger's own frame-walking code, or a bug in a user
 815           ;; PRINT-OBJECT method) we'll at least have the CONDITION
 816           ;; printed out before we die.
 817           (finish-output *error-output*)
 818           ;; (Where to truncate the BACKTRACE is of course arbitrary, but
 819           ;; it seems as though we should at least truncate it somewhere.)
 820           (sb!debug:backtrace 128 *error-output*)
 821           (format
 822            *error-output*
 823            "~%unhandled condition in --disable-debugger mode, quitting~%")
 824           (finish-output *error-output*)
 825           (failure-quit))
 826       (condition ()
 827         ;; We IGNORE-ERRORS here because even %PRIMITIVE PRINT can
 828         ;; fail when our output streams are blown away, as e.g. when
 829         ;; we're running under a Unix shell script and it dies somehow
 830         ;; (e.g. because of a SIGINT). In that case, we might as well
 831         ;; just give it up for a bad job, and stop trying to notify
 832         ;; the user of anything.
 833         ;;
 834         ;; Actually, the only way I've run across to exercise the
 835         ;; problem is to have more than one layer of shell script.
 836         ;; I have a shell script which does
 837         ;;   time nice -10 sh make.sh "$1" 2>&1 | tee make.tmp
 838         ;; and the problem occurs when I interrupt this with Ctrl-C
 839         ;; under Linux 2.2.14-5.0 and GNU bash, version 1.14.7(1).
 840         ;; I haven't figured out whether it's bash, time, tee, Linux, or
 841         ;; what that is responsible, but that it's possible at all
 842         ;; means that we should IGNORE-ERRORS here. -- WHN 2001-04-24
 843         (ignore-errors
 844          (%primitive print
 845                      "Argh! error within --disable-debugger error handling"))
 846         (failure-quit :recklessly-p t)))))
 847
 848 ;;; halt-on-failures and prompt-on-failures modes, suitable for
 849 ;;; noninteractive and interactive use respectively
 850 (defun disable-debugger ()
 851   (setf (fdefinition 'invoke-debugger) #'invoke-debugger/disabled
 852         *debug-io* *error-output*))
 853 (defun enable-debugger ()
 854   (setf (fdefinition 'invoke-debugger) #'invoke-debugger/enabled
 855         *debug-io* *query-io*))
 856 ;;; The enabled mode is the ANSI default.
 857 (enable-debugger)
 858
 859 (defun show-restarts (restarts s)
 860   (cond ((null restarts)
 861          (format s
 862                  "~&(no restarts: If you didn't do this on purpose, ~
 863                   please report it as a bug.)~%"))
 864         (t
 865          (format s "~&restarts (invokable by number or by ~
 866                     possibly-abbreviated name):~%")
 867          (let ((count 0)
 868                (names-used '(nil))
 869                (max-name-len 0))
 870            (dolist (restart restarts)
 871              (let ((name (restart-name restart)))
 872                (when name
 873                  (let ((len (length (princ-to-string name))))
 874                    (when (> len max-name-len)
 875                      (setf max-name-len len))))))
 876            (unless (zerop max-name-len)
 877              (incf max-name-len 3))
 878            (dolist (restart restarts)
 879              (let ((name (restart-name restart)))
 880                (cond ((member name names-used)
 881                       (format s "~& ~2D: ~V@T~A~%" count max-name-len restart))
 882                      (t
 883                       (format s "~& ~2D: [~VA] ~A~%"
 884                               count (- max-name-len 3) name restart)
 885                       (push name names-used))))
 886              (incf count))))))
 887
 888 ;;; This calls DEBUG-LOOP, performing some simple initializations
 889 ;;; before doing so. INVOKE-DEBUGGER calls this to actually get into
 890 ;;; the debugger. SB!KERNEL::ERROR-ERROR calls this in emergencies
 891 ;;; to get into a debug prompt as quickly as possible with as little
 892 ;;; risk as possible for stepping on whatever is causing recursive
 893 ;;; errors.
 894 (defun internal-debug ()
 895   (let ((*in-the-debugger* t)
 896         (*read-suppress* nil))
 897     (unless (typep *debug-condition* 'step-condition)
 898       (clear-input *debug-io*))
 899     (funcall *debug-loop-fun*)))
 900 \f
 901 ;;;; DEBUG-LOOP
 902
 903 ;;; Note: This defaulted to T in CMU CL. The changed default in SBCL
 904 ;;; was motivated by desire to play nicely with ILISP.
 905 (defvar *flush-debug-errors* nil
 906   #!+sb-doc
 907   "When set, avoid calling INVOKE-DEBUGGER recursively when errors occur while
 908    executing in the debugger.")
 909
 910 (defun debug-loop-fun ()
 911   (let* ((*debug-command-level* (1+ *debug-command-level*))
 912          (*real-stack-top* (sb!di:top-frame))
 913          (*stack-top* (or *stack-top-hint* *real-stack-top*))
 914          (*stack-top-hint* nil)
 915          (*current-frame* *stack-top*))
 916     (handler-bind ((sb!di:debug-condition
 917                     (lambda (condition)
 918                       (princ condition *debug-io*)
 919                       (/show0 "handling d-c by THROWing DEBUG-LOOP-CATCHER")
 920                       (throw 'debug-loop-catcher nil))))
 921       (fresh-line)
 922       (print-frame-call *current-frame* :verbosity 2)
 923       (loop
 924         (catch 'debug-loop-catcher
 925           (handler-bind ((error (lambda (condition)
 926                                   (when *flush-debug-errors*
 927                                     (clear-input *debug-io*)
 928                                     (princ condition)
 929                                     ;; FIXME: Doing input on *DEBUG-IO*
 930                                     ;; and output on T seems broken.
 931                                     (format t
 932                                             "~&error flushed (because ~
 933                                              ~S is set)"
 934                                             '*flush-debug-errors*)
 935                                     (/show0 "throwing DEBUG-LOOP-CATCHER")
 936                                     (throw 'debug-loop-catcher nil)))))
 937             ;; We have to bind LEVEL for the restart function created by
 938             ;; WITH-SIMPLE-RESTART.
 939             (let ((level *debug-command-level*)
 940                   (restart-commands (make-restart-commands)))
 941               (with-simple-restart (abort
 942                                    "~@<Reduce debugger level (to debug level ~W).~@:>"
 943                                     level)
 944                 (debug-prompt *debug-io*)
 945                 (force-output *debug-io*)
 946                 (let* ((exp (read *debug-io*))
 947                        (cmd-fun (debug-command-p exp restart-commands)))
 948                   (cond ((not cmd-fun)
 949                          (debug-eval-print exp))
 950                         ((consp cmd-fun)
 951                          (format t "~&Your command, ~S, is ambiguous:~%"
 952                                  exp)
 953                          (dolist (ele cmd-fun)
 954                            (format t "   ~A~%" ele)))
 955                         (t
 956                          (funcall cmd-fun))))))))))))
 957
 958 (defvar *debug-loop-fun* #'debug-loop-fun
 959   "a function taking no parameters that starts the low-level debug loop")
 960
 961 ;;; FIXME: We could probably use INTERACTIVE-EVAL for much of this logic.
 962 (defun debug-eval-print (expr)
 963   (/noshow "entering DEBUG-EVAL-PRINT" expr)
 964   (/noshow (fboundp 'compile))
 965   (setq +++ ++ ++ + + - - expr)
 966   (let* ((values (multiple-value-list (eval -)))
 967          (*standard-output* *debug-io*))
 968     (/noshow "done with EVAL in DEBUG-EVAL-PRINT")
 969     (fresh-line)
 970     (if values (prin1 (car values)))
 971     (dolist (x (cdr values))
 972       (fresh-line)
 973       (prin1 x))
 974     (setq /// // // / / values)
 975     (setq *** ** ** * * (car values))
 976     ;; Make sure that nobody passes back an unbound marker.
 977     (unless (boundp '*)
 978       (setq * nil)
 979       (fresh-line)
 980       ;; FIXME: The way INTERACTIVE-EVAL does this seems better.
 981       (princ "Setting * to NIL (was unbound marker)."))))
 982 \f
 983 ;;;; debug loop functions
 984
 985 ;;; These commands are functions, not really commands, so that users
 986 ;;; can get their hands on the values returned.
 987
 988 (eval-when (:execute :compile-toplevel)
 989
 990 (sb!xc:defmacro define-var-operation (ref-or-set &optional value-var)
 991   `(let* ((temp (etypecase name
 992                   (symbol (sb!di:debug-fun-symbol-vars
 993                            (sb!di:frame-debug-fun *current-frame*)
 994                            name))
 995                   (simple-string (sb!di:ambiguous-debug-vars
 996                                   (sb!di:frame-debug-fun *current-frame*)
 997                                   name))))
 998           (location (sb!di:frame-code-location *current-frame*))
 999           ;; Let's only deal with valid variables.
1000           (vars (remove-if-not (lambda (v)
1001                                  (eq (sb!di:debug-var-validity v location)
1002                                      :valid))
1003                                temp)))
1004      (declare (list vars))
1005      (cond ((null vars)
1006             (error "No known valid variables match ~S." name))
1007            ((= (length vars) 1)
1008             ,(ecase ref-or-set
1009                (:ref
1010                 '(sb!di:debug-var-value (car vars) *current-frame*))
1011                (:set
1012                 `(setf (sb!di:debug-var-value (car vars) *current-frame*)
1013                        ,value-var))))
1014            (t
1015             ;; Since we have more than one, first see whether we have
1016             ;; any variables that exactly match the specification.
1017             (let* ((name (etypecase name
1018                            (symbol (symbol-name name))
1019                            (simple-string name)))
1020                    ;; FIXME: REMOVE-IF-NOT is deprecated, use STRING/=
1021                    ;; instead.
1022                    (exact (remove-if-not (lambda (v)
1023                                            (string= (sb!di:debug-var-symbol-name v)
1024                                                     name))
1025                                          vars))
1026                    (vars (or exact vars)))
1027               (declare (simple-string name)
1028                        (list exact vars))
1029               (cond
1030                ;; Check now for only having one variable.
1031                ((= (length vars) 1)
1032                 ,(ecase ref-or-set
1033                    (:ref
1034                     '(sb!di:debug-var-value (car vars) *current-frame*))
1035                    (:set
1036                     `(setf (sb!di:debug-var-value (car vars) *current-frame*)
1037                            ,value-var))))
1038                ;; If there weren't any exact matches, flame about
1039                ;; ambiguity unless all the variables have the same
1040                ;; name.
1041                ((and (not exact)
1042                      (find-if-not
1043                       (lambda (v)
1044                         (string= (sb!di:debug-var-symbol-name v)
1045                                  (sb!di:debug-var-symbol-name (car vars))))
1046                       (cdr vars)))
1047                 (error "specification ambiguous:~%~{   ~A~%~}"
1048                        (mapcar #'sb!di:debug-var-symbol-name
1049                                (delete-duplicates
1050                                 vars :test #'string=
1051                                 :key #'sb!di:debug-var-symbol-name))))
1052                ;; All names are the same, so see whether the user
1053                ;; ID'ed one of them.
1054                (id-supplied
1055                 (let ((v (find id vars :key #'sb!di:debug-var-id)))
1056                   (unless v
1057                     (error
1058                      "invalid variable ID, ~W: should have been one of ~S"
1059                      id
1060                      (mapcar #'sb!di:debug-var-id vars)))
1061                   ,(ecase ref-or-set
1062                      (:ref
1063                       '(sb!di:debug-var-value v *current-frame*))
1064                      (:set
1065                       `(setf (sb!di:debug-var-value v *current-frame*)
1066                              ,value-var)))))
1067                (t
1068                 (error "Specify variable ID to disambiguate ~S. Use one of ~S."
1069                        name
1070                        (mapcar #'sb!di:debug-var-id vars)))))))))
1071
1072 ) ; EVAL-WHEN
1073
1074 ;;; FIXME: This doesn't work. It would be real nice we could make it
1075 ;;; work! Alas, it doesn't seem to work in CMU CL X86 either..
1076 (defun var (name &optional (id 0 id-supplied))
1077   #!+sb-doc
1078   "Return a variable's value if possible. NAME is a simple-string or symbol.
1079    If it is a simple-string, it is an initial substring of the variable's name.
1080    If name is a symbol, it has the same name and package as the variable whose
1081    value this function returns. If the symbol is uninterned, then the variable
1082    has the same name as the symbol, but it has no package.
1083
1084    If name is the initial substring of variables with different names, then
1085    this return no values after displaying the ambiguous names. If name
1086    determines multiple variables with the same name, then you must use the
1087    optional id argument to specify which one you want. If you left id
1088    unspecified, then this returns no values after displaying the distinguishing
1089    id values.
1090
1091    The result of this function is limited to the availability of variable
1092    information. This is SETF'able."
1093   (define-var-operation :ref))
1094 (defun (setf var) (value name &optional (id 0 id-supplied))
1095   (define-var-operation :set value))
1096
1097 ;;; This returns the COUNT'th arg as the user sees it from args, the
1098 ;;; result of SB!DI:DEBUG-FUN-LAMBDA-LIST. If this returns a
1099 ;;; potential DEBUG-VAR from the lambda-list, then the second value is
1100 ;;; T. If this returns a keyword symbol or a value from a rest arg,
1101 ;;; then the second value is NIL.
1102 ;;;
1103 ;;; FIXME: There's probably some way to merge the code here with
1104 ;;; FRAME-ARGS-AS-LIST. (A fair amount of logic is already shared
1105 ;;; through LAMBDA-LIST-ELEMENT-DISPATCH, but I suspect more could be.)
1106 (declaim (ftype (function (index list)) nth-arg))
1107 (defun nth-arg (count args)
1108   (let ((n count))
1109     (dolist (ele args (error "The argument specification ~S is out of range."
1110                              n))
1111       (lambda-list-element-dispatch ele
1112         :required ((if (zerop n) (return (values ele t))))
1113         :optional ((if (zerop n) (return (values (second ele) t))))
1114         :keyword ((cond ((zerop n)
1115                          (return (values (second ele) nil)))
1116                         ((zerop (decf n))
1117                          (return (values (third ele) t)))))
1118         :deleted ((if (zerop n) (return (values ele t))))
1119         :rest ((let ((var (second ele)))
1120                  (lambda-var-dispatch var (sb!di:frame-code-location
1121                                            *current-frame*)
1122                    (error "unused &REST argument before n'th argument")
1123                    (dolist (value
1124                             (sb!di:debug-var-value var *current-frame*)
1125                             (error
1126                              "The argument specification ~S is out of range."
1127                              n))
1128                      (if (zerop n)
1129                          (return-from nth-arg (values value nil))
1130                          (decf n)))
1131                    (error "invalid &REST argument before n'th argument")))))
1132       (decf n))))
1133
1134 (defun arg (n)
1135   #!+sb-doc
1136   "Return the N'th argument's value if possible. Argument zero is the first
1137    argument in a frame's default printed representation. Count keyword/value
1138    pairs as separate arguments."
1139   (multiple-value-bind (var lambda-var-p)
1140       (nth-arg n (handler-case (sb!di:debug-fun-lambda-list
1141                                 (sb!di:frame-debug-fun *current-frame*))
1142                    (sb!di:lambda-list-unavailable ()
1143                      (error "No argument values are available."))))
1144     (if lambda-var-p
1145         (lambda-var-dispatch var (sb!di:frame-code-location *current-frame*)
1146           (error "Unused arguments have no values.")
1147           (sb!di:debug-var-value var *current-frame*)
1148           (error "invalid argument value"))
1149         var)))
1150 \f
1151 ;;;; machinery for definition of debug loop commands
1152
1153 (defvar *debug-commands* nil)
1154
1155 ;;; Interface to *DEBUG-COMMANDS*. No required arguments in args are
1156 ;;; permitted.
1157 (defmacro !def-debug-command (name args &rest body)
1158   (let ((fun-name (symbolicate name "-DEBUG-COMMAND")))
1159     `(progn
1160        (setf *debug-commands*
1161              (remove ,name *debug-commands* :key #'car :test #'string=))
1162        (defun ,fun-name ,args
1163          (unless *in-the-debugger*
1164            (error "invoking debugger command while outside the debugger"))
1165          ,@body)
1166        (push (cons ,name #',fun-name) *debug-commands*)
1167        ',fun-name)))
1168
1169 (defun !def-debug-command-alias (new-name existing-name)
1170   (let ((pair (assoc existing-name *debug-commands* :test #'string=)))
1171     (unless pair (error "unknown debug command name: ~S" existing-name))
1172     (push (cons new-name (cdr pair)) *debug-commands*))
1173   new-name)
1174
1175 ;;; This takes a symbol and uses its name to find a debugger command,
1176 ;;; using initial substring matching. It returns the command function
1177 ;;; if form identifies only one command, but if form is ambiguous,
1178 ;;; this returns a list of the command names. If there are no matches,
1179 ;;; this returns nil. Whenever the loop that looks for a set of
1180 ;;; possibilities encounters an exact name match, we return that
1181 ;;; command function immediately.
1182 (defun debug-command-p (form &optional other-commands)
1183   (if (or (symbolp form) (integerp form))
1184       (let* ((name
1185               (if (symbolp form)
1186                   (symbol-name form)
1187                   (format nil "~W" form)))
1188              (len (length name))
1189              (res nil))
1190         (declare (simple-string name)
1191                  (fixnum len)
1192                  (list res))
1193
1194         ;; Find matching commands, punting if exact match.
1195         (flet ((match-command (ele)
1196                  (let* ((str (car ele))
1197                         (str-len (length str)))
1198                    (declare (simple-string str)
1199                             (fixnum str-len))
1200                    (cond ((< str-len len))
1201                          ((= str-len len)
1202                           (when (string= name str :end1 len :end2 len)
1203                             (return-from debug-command-p (cdr ele))))
1204                          ((string= name str :end1 len :end2 len)
1205                           (push ele res))))))
1206           (mapc #'match-command *debug-commands*)
1207           (mapc #'match-command other-commands))
1208
1209         ;; Return the right value.
1210         (cond ((not res) nil)
1211               ((= (length res) 1)
1212                (cdar res))
1213               (t ; Just return the names.
1214                (do ((cmds res (cdr cmds)))
1215                    ((not cmds) res)
1216                  (setf (car cmds) (caar cmds))))))))
1217
1218 ;;; Return a list of debug commands (in the same format as
1219 ;;; *DEBUG-COMMANDS*) that invoke each active restart.
1220 ;;;
1221 ;;; Two commands are made for each restart: one for the number, and
1222 ;;; one for the restart name (unless it's been shadowed by an earlier
1223 ;;; restart of the same name, or it is NIL).
1224 (defun make-restart-commands (&optional (restarts *debug-restarts*))
1225   (let ((commands)
1226         (num 0))                        ; better be the same as show-restarts!
1227     (dolist (restart restarts)
1228       (let ((name (string (restart-name restart))))
1229         (let ((restart-fun
1230                 (lambda ()
1231                   (/show0 "in restart-command closure, about to i-r-i")
1232                   (invoke-restart-interactively restart))))
1233           (push (cons (prin1-to-string num) restart-fun) commands)
1234           (unless (or (null (restart-name restart))
1235                       (find name commands :key #'car :test #'string=))
1236             (push (cons name restart-fun) commands))))
1237     (incf num))
1238   commands))
1239 \f
1240 ;;;; frame-changing commands
1241
1242 (!def-debug-command "UP" ()
1243   (let ((next (sb!di:frame-up *current-frame*)))
1244     (cond (next
1245            (setf *current-frame* next)
1246            (print-frame-call next))
1247           (t
1248            (format t "~&Top of stack.")))))
1249
1250 (!def-debug-command "DOWN" ()
1251   (let ((next (sb!di:frame-down *current-frame*)))
1252     (cond (next
1253            (setf *current-frame* next)
1254            (print-frame-call next))
1255           (t
1256            (format t "~&Bottom of stack.")))))
1257
1258 (!def-debug-command-alias "D" "DOWN")
1259
1260 ;;; CMU CL had this command, but SBCL doesn't, since it's redundant
1261 ;;; with "FRAME 0", and it interferes with abbreviations for the
1262 ;;; TOPLEVEL restart.
1263 ;;;(!def-debug-command "TOP" ()
1264 ;;;  (do ((prev *current-frame* lead)
1265 ;;;       (lead (sb!di:frame-up *current-frame*) (sb!di:frame-up lead)))
1266 ;;;      ((null lead)
1267 ;;;       (setf *current-frame* prev)
1268 ;;;       (print-frame-call prev))))
1269
1270 (!def-debug-command "BOTTOM" ()
1271   (do ((prev *current-frame* lead)
1272        (lead (sb!di:frame-down *current-frame*) (sb!di:frame-down lead)))
1273       ((null lead)
1274        (setf *current-frame* prev)
1275        (print-frame-call prev))))
1276
1277 (!def-debug-command-alias "B" "BOTTOM")
1278
1279 (!def-debug-command "FRAME" (&optional
1280                              (n (read-prompting-maybe "frame number: ")))
1281   (setf *current-frame*
1282         (multiple-value-bind (next-frame-fun limit-string)
1283             (if (< n (sb!di:frame-number *current-frame*))
1284                 (values #'sb!di:frame-up "top")
1285               (values #'sb!di:frame-down "bottom"))
1286           (do ((frame *current-frame*))
1287               ((= n (sb!di:frame-number frame))
1288                frame)
1289             (let ((next-frame (funcall next-frame-fun frame)))
1290               (cond (next-frame
1291                      (setf frame next-frame))
1292                     (t
1293                      (format t
1294                              "The ~A of the stack was encountered.~%"
1295                              limit-string)
1296                      (return frame)))))))
1297   (print-frame-call *current-frame*))
1298
1299 (!def-debug-command-alias "F" "FRAME")
1300 \f
1301 ;;;; commands for entering and leaving the debugger
1302
1303 ;;; CMU CL supported this QUIT debug command, but SBCL provides this
1304 ;;; functionality with a restart instead. (The QUIT debug command was
1305 ;;; removed because it's confusing to have "quit" mean two different
1306 ;;; things in the system, "restart the top level REPL" in the debugger
1307 ;;; and "terminate the Lisp system" as the SB-EXT:QUIT function.)
1308 ;;;
1309 ;;;(!def-debug-command "QUIT" ()
1310 ;;;  (throw 'sb!impl::toplevel-catcher nil))
1311
1312 ;;; CMU CL supported this GO debug command, but SBCL doesn't -- in
1313 ;;; SBCL you just type the CONTINUE restart name instead (or "C" or
1314 ;;; "RESTART CONTINUE", that's OK too).
1315 ;;;(!def-debug-command "GO" ()
1316 ;;;  (continue *debug-condition*)
1317 ;;;  (error "There is no restart named CONTINUE."))
1318
1319 (!def-debug-command "RESTART" ()
1320   (/show0 "doing RESTART debug-command")
1321   (let ((num (read-if-available :prompt)))
1322     (when (eq num :prompt)
1323       (show-restarts *debug-restarts* *debug-io*)
1324       (write-string "restart: ")
1325       (force-output)
1326       (setf num (read *debug-io*)))
1327     (let ((restart (typecase num
1328                      (unsigned-byte
1329                       (nth num *debug-restarts*))
1330                      (symbol
1331                       (find num *debug-restarts* :key #'restart-name
1332                             :test (lambda (sym1 sym2)
1333                                     (string= (symbol-name sym1)
1334                                              (symbol-name sym2)))))
1335                      (t
1336                       (format t "~S is invalid as a restart name.~%" num)
1337                       (return-from restart-debug-command nil)))))
1338       (/show0 "got RESTART")
1339       (if restart
1340           (invoke-restart-interactively restart)
1341           ;; FIXME: Even if this isn't handled by WARN, it probably
1342           ;; shouldn't go to *STANDARD-OUTPUT*, but *ERROR-OUTPUT* or
1343           ;; *QUERY-IO* or something. Look through this file to
1344           ;; straighten out stream usage.
1345           (princ "There is no such restart.")))))
1346 \f
1347 ;;;; information commands
1348
1349 (!def-debug-command "HELP" ()
1350   ;; CMU CL had a little toy pager here, but "if you aren't running
1351   ;; ILISP (or a smart windowing system, or something) you deserve to
1352   ;; lose", so we've dropped it in SBCL. However, in case some
1353   ;; desperate holdout is running this on a dumb terminal somewhere,
1354   ;; we tell him where to find the message stored as a string.
1355   (format *debug-io*
1356           "~&~A~2%(The HELP string is stored in ~S.)~%"
1357           *debug-help-string*
1358           '*debug-help-string*))
1359
1360 (!def-debug-command-alias "?" "HELP")
1361
1362 (!def-debug-command "ERROR" ()
1363   (format *debug-io* "~A~%" *debug-condition*)
1364   (show-restarts *debug-restarts* *debug-io*))
1365
1366 (!def-debug-command "BACKTRACE" ()
1367   (backtrace (read-if-available most-positive-fixnum)))
1368
1369 (!def-debug-command "PRINT" ()
1370   (print-frame-call *current-frame*))
1371
1372 (!def-debug-command-alias "P" "PRINT")
1373
1374 (!def-debug-command "LIST-LOCALS" ()
1375   (let ((d-fun (sb!di:frame-debug-fun *current-frame*)))
1376     (if (sb!di:debug-var-info-available d-fun)
1377         (let ((*standard-output* *debug-io*)
1378               (location (sb!di:frame-code-location *current-frame*))
1379               (prefix (read-if-available nil))
1380               (any-p nil)
1381               (any-valid-p nil))
1382           (dolist (v (sb!di:ambiguous-debug-vars
1383                         d-fun
1384                         (if prefix (string prefix) "")))
1385             (setf any-p t)
1386             (when (eq (sb!di:debug-var-validity v location) :valid)
1387               (setf any-valid-p t)
1388               (format t "~S~:[#~W~;~*~]  =  ~S~%"
1389                       (sb!di:debug-var-symbol v)
1390                       (zerop (sb!di:debug-var-id v))
1391                       (sb!di:debug-var-id v)
1392                       (sb!di:debug-var-value v *current-frame*))))
1393
1394           (cond
1395            ((not any-p)
1396             (format t "There are no local variables ~@[starting with ~A ~]~
1397                        in the function."
1398                     prefix))
1399            ((not any-valid-p)
1400             (format t "All variables ~@[starting with ~A ~]currently ~
1401                        have invalid values."
1402                     prefix))))
1403         (write-line "There is no variable information available."))))
1404
1405 (!def-debug-command-alias "L" "LIST-LOCALS")
1406
1407 (!def-debug-command "SOURCE" ()
1408   (fresh-line)
1409   (print-code-location-source-form (sb!di:frame-code-location *current-frame*)
1410                                    (read-if-available 0)))
1411 \f
1412 ;;;; source location printing
1413
1414 ;;; We cache a stream to the last valid file debug source so that we
1415 ;;; won't have to repeatedly open the file.
1416 ;;;
1417 ;;; KLUDGE: This sounds like a bug, not a feature. Opening files is fast
1418 ;;; in the 1990s, so the benefit is negligible, less important than the
1419 ;;; potential of extra confusion if someone changes the source during
1420 ;;; a debug session and the change doesn't show up. And removing this
1421 ;;; would simplify the system, which I like. -- WHN 19990903
1422 (defvar *cached-debug-source* nil)
1423 (declaim (type (or sb!di:debug-source null) *cached-debug-source*))
1424 (defvar *cached-source-stream* nil)
1425 (declaim (type (or stream null) *cached-source-stream*))
1426
1427 ;;; To suppress the read-time evaluation #. macro during source read,
1428 ;;; *READTABLE* is modified. *READTABLE* is cached to avoid
1429 ;;; copying it each time, and invalidated when the
1430 ;;; *CACHED-DEBUG-SOURCE* has changed.
1431 (defvar *cached-readtable* nil)
1432 (declaim (type (or readtable null) *cached-readtable*))
1433
1434 (pushnew (lambda ()
1435            (setq *cached-debug-source* nil *cached-source-stream* nil
1436                  *cached-readtable* nil))
1437          *before-save-initializations*)
1438
1439 ;;; We also cache the last toplevel form that we printed a source for
1440 ;;; so that we don't have to do repeated reads and calls to
1441 ;;; FORM-NUMBER-TRANSLATIONS.
1442 (defvar *cached-toplevel-form-offset* nil)
1443 (declaim (type (or index null) *cached-toplevel-form-offset*))
1444 (defvar *cached-toplevel-form*)
1445 (defvar *cached-form-number-translations*)
1446
1447 ;;; Given a code location, return the associated form-number
1448 ;;; translations and the actual top level form. We check our cache ---
1449 ;;; if there is a miss, we dispatch on the kind of the debug source.
1450 (defun get-toplevel-form (location)
1451   (let ((d-source (sb!di:code-location-debug-source location)))
1452     (if (and (eq d-source *cached-debug-source*)
1453              (eql (sb!di:code-location-toplevel-form-offset location)
1454                   *cached-toplevel-form-offset*))
1455         (values *cached-form-number-translations* *cached-toplevel-form*)
1456         (let* ((offset (sb!di:code-location-toplevel-form-offset location))
1457                (res
1458                 (ecase (sb!di:debug-source-from d-source)
1459                   (:file (get-file-toplevel-form location))
1460                   (:lisp (svref (sb!di:debug-source-name d-source) offset)))))
1461           (setq *cached-toplevel-form-offset* offset)
1462           (values (setq *cached-form-number-translations*
1463                         (sb!di:form-number-translations res offset))
1464                   (setq *cached-toplevel-form* res))))))
1465
1466 ;;; Locate the source file (if it still exists) and grab the top level
1467 ;;; form. If the file is modified, we use the top level form offset
1468 ;;; instead of the recorded character offset.
1469 (defun get-file-toplevel-form (location)
1470   (let* ((d-source (sb!di:code-location-debug-source location))
1471          (tlf-offset (sb!di:code-location-toplevel-form-offset location))
1472          (local-tlf-offset (- tlf-offset
1473                               (sb!di:debug-source-root-number d-source)))
1474          (char-offset
1475           (aref (or (sb!di:debug-source-start-positions d-source)
1476                     (error "no start positions map"))
1477                 local-tlf-offset))
1478          (name (sb!di:debug-source-name d-source)))
1479     (unless (eq d-source *cached-debug-source*)
1480       (unless (and *cached-source-stream*
1481                    (equal (pathname *cached-source-stream*)
1482                           (pathname name)))
1483         (setq *cached-readtable* nil)
1484         (when *cached-source-stream* (close *cached-source-stream*))
1485         (setq *cached-source-stream* (open name :if-does-not-exist nil))
1486         (unless *cached-source-stream*
1487           (error "The source file no longer exists:~%  ~A" (namestring name)))
1488         (format t "~%; file: ~A~%" (namestring name)))
1489
1490         (setq *cached-debug-source*
1491               (if (= (sb!di:debug-source-created d-source)
1492                      (file-write-date name))
1493                   d-source nil)))
1494
1495     (cond
1496      ((eq *cached-debug-source* d-source)
1497       (file-position *cached-source-stream* char-offset))
1498      (t
1499       (format t "~%; File has been modified since compilation:~%;   ~A~@
1500                  ; Using form offset instead of character position.~%"
1501               (namestring name))
1502       (file-position *cached-source-stream* 0)
1503       (let ((*read-suppress* t))
1504         (dotimes (i local-tlf-offset)
1505           (read *cached-source-stream*)))))
1506     (unless *cached-readtable*
1507       (setq *cached-readtable* (copy-readtable))
1508       (set-dispatch-macro-character
1509        #\# #\.
1510        (lambda (stream sub-char &rest rest)
1511          (declare (ignore rest sub-char))
1512          (let ((token (read stream t nil t)))
1513            (format nil "#.~S" token)))
1514        *cached-readtable*))
1515     (let ((*readtable* *cached-readtable*))
1516       (read *cached-source-stream*))))
1517
1518 (defun print-code-location-source-form (location context)
1519   (let* ((location (maybe-block-start-location location))
1520          (form-num (sb!di:code-location-form-number location)))
1521     (multiple-value-bind (translations form) (get-toplevel-form location)
1522       (unless (< form-num (length translations))
1523         (error "The source path no longer exists."))
1524       (prin1 (sb!di:source-path-context form
1525                                         (svref translations form-num)
1526                                         context)))))
1527 \f
1528 ;;; breakpoint and step commands
1529
1530 ;;; Step to the next code-location.
1531 (!def-debug-command "STEP" ()
1532   (setf *number-of-steps* (read-if-available 1))
1533   (set-step-breakpoint *current-frame*)
1534   (continue *debug-condition*)
1535   (error "couldn't continue"))
1536
1537 ;;; List possible breakpoint locations, which ones are active, and
1538 ;;; where the CONTINUE restart will transfer control. Set
1539 ;;; *POSSIBLE-BREAKPOINTS* to the code-locations which can then be
1540 ;;; used by sbreakpoint.
1541 (!def-debug-command "LIST-LOCATIONS" ()
1542   (let ((df (read-if-available *default-breakpoint-debug-fun*)))
1543     (cond ((consp df)
1544            (setf df (sb!di:fun-debug-fun (eval df)))
1545            (setf *default-breakpoint-debug-fun* df))
1546           ((or (eq ':c df)
1547                (not *default-breakpoint-debug-fun*))
1548            (setf df (sb!di:frame-debug-fun *current-frame*))
1549            (setf *default-breakpoint-debug-fun* df)))
1550     (setf *possible-breakpoints* (possible-breakpoints df)))
1551   (let ((continue-at (sb!di:frame-code-location *current-frame*)))
1552     (let ((active (location-in-list *default-breakpoint-debug-fun*
1553                                     *breakpoints* :fun-start))
1554           (here (sb!di:code-location=
1555                  (sb!di:debug-fun-start-location
1556                   *default-breakpoint-debug-fun*) continue-at)))
1557       (when (or active here)
1558         (format t "::FUN-START ")
1559         (when active (format t " *Active*"))
1560         (when here (format t " *Continue here*"))))
1561
1562     (let ((prev-location nil)
1563           (prev-num 0)
1564           (this-num 0))
1565       (flet ((flush ()
1566                (when prev-location
1567                  (let ((this-num (1- this-num)))
1568                    (if (= prev-num this-num)
1569                        (format t "~&~W: " prev-num)
1570                        (format t "~&~W-~W: " prev-num this-num)))
1571                  (print-code-location-source-form prev-location 0)
1572                  (when *print-location-kind*
1573                    (format t "~S " (sb!di:code-location-kind prev-location)))
1574                  (when (location-in-list prev-location *breakpoints*)
1575                    (format t " *Active*"))
1576                  (when (sb!di:code-location= prev-location continue-at)
1577                    (format t " *Continue here*")))))
1578
1579         (dolist (code-location *possible-breakpoints*)
1580           (when (or *print-location-kind*
1581                     (location-in-list code-location *breakpoints*)
1582                     (sb!di:code-location= code-location continue-at)
1583                     (not prev-location)
1584                     (not (eq (sb!di:code-location-debug-source code-location)
1585                              (sb!di:code-location-debug-source prev-location)))
1586                     (not (eq (sb!di:code-location-toplevel-form-offset
1587                               code-location)
1588                              (sb!di:code-location-toplevel-form-offset
1589                               prev-location)))
1590                     (not (eq (sb!di:code-location-form-number code-location)
1591                              (sb!di:code-location-form-number prev-location))))
1592             (flush)
1593             (setq prev-location code-location  prev-num this-num))
1594
1595           (incf this-num))))
1596
1597     (when (location-in-list *default-breakpoint-debug-fun*
1598                             *breakpoints*
1599                             :fun-end)
1600       (format t "~&::FUN-END *Active* "))))
1601
1602 (!def-debug-command-alias "LL" "LIST-LOCATIONS")
1603
1604 ;;; Set breakpoint at the given number.
1605 (!def-debug-command "BREAKPOINT" ()
1606   (let ((index (read-prompting-maybe "location number, :START, or :END: "))
1607         (break t)
1608         (condition t)
1609         (print nil)
1610         (print-functions nil)
1611         (function nil)
1612         (bp)
1613         (place *default-breakpoint-debug-fun*))
1614     (flet ((get-command-line ()
1615              (let ((command-line nil)
1616                    (unique '(nil)))
1617                (loop
1618                  (let ((next-input (read-if-available unique)))
1619                    (when (eq next-input unique) (return))
1620                    (push next-input command-line)))
1621                (nreverse command-line)))
1622            (set-vars-from-command-line (command-line)
1623              (do ((arg (pop command-line) (pop command-line)))
1624                  ((not arg))
1625                (ecase arg
1626                  (:condition (setf condition (pop command-line)))
1627                  (:print (push (pop command-line) print))
1628                  (:break (setf break (pop command-line)))
1629                  (:function
1630                   (setf function (eval (pop command-line)))
1631                   (setf *default-breakpoint-debug-fun*
1632                         (sb!di:fun-debug-fun function))
1633                   (setf place *default-breakpoint-debug-fun*)
1634                   (setf *possible-breakpoints*
1635                         (possible-breakpoints
1636                          *default-breakpoint-debug-fun*))))))
1637            (setup-fun-start ()
1638              (let ((code-loc (sb!di:debug-fun-start-location place)))
1639                (setf bp (sb!di:make-breakpoint #'main-hook-fun
1640                                                place
1641                                                :kind :fun-start))
1642                (setf break (sb!di:preprocess-for-eval break code-loc))
1643                (setf condition (sb!di:preprocess-for-eval condition code-loc))
1644                (dolist (form print)
1645                  (push (cons (sb!di:preprocess-for-eval form code-loc) form)
1646                        print-functions))))
1647            (setup-fun-end ()
1648              (setf bp
1649                    (sb!di:make-breakpoint #'main-hook-fun
1650                                           place
1651                                           :kind :fun-end))
1652              (setf break
1653                    ;; FIXME: These and any other old (COERCE `(LAMBDA ..) ..)
1654                    ;; forms should be converted to shiny new (LAMBDA ..) forms.
1655                    ;; (Search the sources for "coerce.*\(lambda".)
1656                    (coerce `(lambda (dummy)
1657                               (declare (ignore dummy)) ,break)
1658                            'function))
1659              (setf condition (coerce `(lambda (dummy)
1660                                         (declare (ignore dummy)) ,condition)
1661                                      'function))
1662              (dolist (form print)
1663                (push (cons
1664                       (coerce `(lambda (dummy)
1665                                  (declare (ignore dummy)) ,form) 'function)
1666                       form)
1667                      print-functions)))
1668            (setup-code-location ()
1669              (setf place (nth index *possible-breakpoints*))
1670              (setf bp (sb!di:make-breakpoint #'main-hook-fun place
1671                                              :kind :code-location))
1672              (dolist (form print)
1673                (push (cons
1674                       (sb!di:preprocess-for-eval form place)
1675                       form)
1676                      print-functions))
1677              (setf break (sb!di:preprocess-for-eval break place))
1678              (setf condition (sb!di:preprocess-for-eval condition place))))
1679       (set-vars-from-command-line (get-command-line))
1680       (cond
1681        ((or (eq index :start) (eq index :s))
1682         (setup-fun-start))
1683        ((or (eq index :end) (eq index :e))
1684         (setup-fun-end))
1685        (t
1686         (setup-code-location)))
1687       (sb!di:activate-breakpoint bp)
1688       (let* ((new-bp-info (create-breakpoint-info place bp index
1689                                                   :break break
1690                                                   :print print-functions
1691                                                   :condition condition))
1692              (old-bp-info (location-in-list new-bp-info *breakpoints*)))
1693         (when old-bp-info
1694           (sb!di:deactivate-breakpoint (breakpoint-info-breakpoint
1695                                         old-bp-info))
1696           (setf *breakpoints* (remove old-bp-info *breakpoints*))
1697           (format t "previous breakpoint removed~%"))
1698         (push new-bp-info *breakpoints*))
1699       (print-breakpoint-info (first *breakpoints*))
1700       (format t "~&added"))))
1701
1702 (!def-debug-command-alias "BP" "BREAKPOINT")
1703
1704 ;;; List all breakpoints which are set.
1705 (!def-debug-command "LIST-BREAKPOINTS" ()
1706   (setf *breakpoints*
1707         (sort *breakpoints* #'< :key #'breakpoint-info-breakpoint-number))
1708   (dolist (info *breakpoints*)
1709     (print-breakpoint-info info)))
1710
1711 (!def-debug-command-alias "LB" "LIST-BREAKPOINTS")
1712 (!def-debug-command-alias "LBP" "LIST-BREAKPOINTS")
1713
1714 ;;; Remove breakpoint N, or remove all breakpoints if no N given.
1715 (!def-debug-command "DELETE-BREAKPOINT" ()
1716   (let* ((index (read-if-available nil))
1717          (bp-info
1718           (find index *breakpoints* :key #'breakpoint-info-breakpoint-number)))
1719     (cond (bp-info
1720            (sb!di:delete-breakpoint (breakpoint-info-breakpoint bp-info))
1721            (setf *breakpoints* (remove bp-info *breakpoints*))
1722            (format t "breakpoint ~S removed~%" index))
1723           (index (format t "The breakpoint doesn't exist."))
1724           (t
1725            (dolist (ele *breakpoints*)
1726              (sb!di:delete-breakpoint (breakpoint-info-breakpoint ele)))
1727            (setf *breakpoints* nil)
1728            (format t "all breakpoints deleted~%")))))
1729
1730 (!def-debug-command-alias "DBP" "DELETE-BREAKPOINT")
1731 \f
1732 ;;; miscellaneous commands
1733
1734 (!def-debug-command "DESCRIBE" ()
1735   (let* ((curloc (sb!di:frame-code-location *current-frame*))
1736          (debug-fun (sb!di:code-location-debug-fun curloc))
1737          (function (sb!di:debug-fun-fun debug-fun)))
1738     (if function
1739         (describe function)
1740         (format t "can't figure out the function for this frame"))))
1741
1742 (!def-debug-command "SLURP" ()
1743   (loop while (read-char-no-hang *standard-input*)))
1744
1745 (!def-debug-command "RETURN" (&optional
1746                               (return (read-prompting-maybe
1747                                        "return: ")))
1748   (let ((tag (find-if (lambda (x)
1749                         (and (typep (car x) 'symbol)
1750                              (not (symbol-package (car x)))
1751                              (string= (car x) "SB-DEBUG-CATCH-TAG")))
1752                       (sb!di::frame-catches *current-frame*))))
1753     (if tag
1754         (throw (car tag)
1755           (funcall (sb!di:preprocess-for-eval
1756                     return
1757                     (sb!di:frame-code-location *current-frame*))
1758                    *current-frame*))
1759         (format t "~@<can't find a tag for this frame ~
1760                    ~2I~_(hint: try increasing the DEBUG optimization quality ~
1761                    and recompiling)~:@>"))))
1762 \f
1763 ;;;; debug loop command utilities
1764
1765 (defun read-prompting-maybe (prompt)
1766   (unless (sb!int:listen-skip-whitespace *debug-io*)
1767     (princ prompt)
1768     (force-output))
1769   (read *debug-io*))
1770
1771 (defun read-if-available (default)
1772   (if (sb!int:listen-skip-whitespace *debug-io*)
1773       (read *debug-io*)
1774       default))