src/code/defboot.lisp

   1 ;;;; bootstrapping fundamental machinery (e.g. DEFUN, DEFCONSTANT,
   2 ;;;; DEFVAR) from special forms and primitive functions
   3 ;;;;
   4 ;;;; KLUDGE: The bootstrapping aspect of this is now obsolete. It was
   5 ;;;; originally intended that this file file would be loaded into a
   6 ;;;; Lisp image which had Common Lisp primitives defined, and DEFMACRO
   7 ;;;; defined, and little else. Since then that approach has been
   8 ;;;; dropped and this file has been modified somewhat to make it work
   9 ;;;; more cleanly when used to predefine macros at
  10 ;;;; build-the-cross-compiler time.
  11
  12 ;;;; This software is part of the SBCL system. See the README file for
  13 ;;;; more information.
  14 ;;;;
  15 ;;;; This software is derived from the CMU CL system, which was
  16 ;;;; written at Carnegie Mellon University and released into the
  17 ;;;; public domain. The software is in the public domain and is
  18 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  19 ;;;; files for more information.
  20
  21 (in-package "SB!IMPL")
  22 \f
  23 ;;;; IN-PACKAGE
  24
  25 (defmacro-mundanely in-package (package-designator)
  26   `(eval-when (:compile-toplevel :load-toplevel :execute)
  27      (setq *package* (find-undeleted-package-or-lose ',package-designator))))
  28 \f
  29 ;;;; MULTIPLE-VALUE-FOO
  30
  31 (defun list-of-symbols-p (x)
  32   (and (listp x)
  33        (every #'symbolp x)))
  34
  35 (defmacro-mundanely multiple-value-bind (vars value-form &body body)
  36   (if (list-of-symbols-p vars)
  37     ;; It's unclear why it would be important to special-case the LENGTH=1 case
  38     ;; at this level, but the CMU CL code did it, so.. -- WHN 19990411
  39     (if (= (length vars) 1)
  40       `(let ((,(car vars) ,value-form))
  41          ,@body)
  42       (let ((ignore (gensym)))
  43         `(multiple-value-call #'(lambda (&optional ,@vars &rest ,ignore)
  44                                   (declare (ignore ,ignore))
  45                                   ,@body)
  46                               ,value-form)))
  47     (error "Vars is not a list of symbols: ~S" vars)))
  48
  49 (defmacro-mundanely multiple-value-setq (vars value-form)
  50   (unless (list-of-symbols-p vars)
  51     (error "Vars is not a list of symbols: ~S" vars))
  52   `(values (setf (values ,@vars) ,value-form)))
  53
  54 (defmacro-mundanely multiple-value-list (value-form)
  55   `(multiple-value-call #'list ,value-form))
  56 \f
  57 ;;;; various conditional constructs
  58
  59 ;;; COND defined in terms of IF
  60 (defmacro-mundanely cond (&rest clauses)
  61   (if (endp clauses)
  62       nil
  63       (let ((clause (first clauses)))
  64         (if (atom clause)
  65             (error "COND clause is not a list: ~S" clause)
  66             (let ((test (first clause))
  67                   (forms (rest clause)))
  68               (if (endp forms)
  69                   (let ((n-result (gensym)))
  70                     `(let ((,n-result ,test))
  71                        (if ,n-result
  72                            ,n-result
  73                            (cond ,@(rest clauses)))))
  74                   `(if ,test
  75                        (progn ,@forms)
  76                        (cond ,@(rest clauses)))))))))
  77
  78 ;;; other things defined in terms of COND
  79 (defmacro-mundanely when (test &body forms)
  80   #!+sb-doc
  81   "If the first argument is true, the rest of the forms are
  82   evaluated as a PROGN."
  83   `(cond (,test nil ,@forms)))
  84 (defmacro-mundanely unless (test &body forms)
  85   #!+sb-doc
  86   "If the first argument is not true, the rest of the forms are
  87   evaluated as a PROGN."
  88   `(cond ((not ,test) nil ,@forms)))
  89 (defmacro-mundanely and (&rest forms)
  90   (cond ((endp forms) t)
  91         ((endp (rest forms)) (first forms))
  92         (t
  93          `(if ,(first forms)
  94               (and ,@(rest forms))
  95               nil))))
  96 (defmacro-mundanely or (&rest forms)
  97   (cond ((endp forms) nil)
  98         ((endp (rest forms)) (first forms))
  99         (t
 100          (let ((n-result (gensym)))
 101            `(let ((,n-result ,(first forms)))
 102               (if ,n-result
 103                   ,n-result
 104                   (or ,@(rest forms))))))))
 105 \f
 106 ;;;; various sequencing constructs
 107
 108 (defmacro-mundanely prog (varlist &body body-decls)
 109   (multiple-value-bind (body decls) (parse-body body-decls nil)
 110     `(block nil
 111        (let ,varlist
 112          ,@decls
 113          (tagbody ,@body)))))
 114
 115 (defmacro-mundanely prog* (varlist &body body-decls)
 116   (multiple-value-bind (body decls) (parse-body body-decls nil)
 117     `(block nil
 118        (let* ,varlist
 119          ,@decls
 120          (tagbody ,@body)))))
 121
 122 (defmacro-mundanely prog1 (result &body body)
 123   (let ((n-result (gensym)))
 124     `(let ((,n-result ,result))
 125        ,@body
 126        ,n-result)))
 127
 128 (defmacro-mundanely prog2 (form1 result &body body)
 129   `(prog1 (progn ,form1 ,result) ,@body))
 130 \f
 131 ;;;; DEFUN
 132
 133 ;;; Should we save the inline expansion of the function named NAME?
 134 (defun inline-fun-name-p (name)
 135   (or
 136    ;; the normal reason for saving the inline expansion
 137    (info :function :inlinep name)
 138    ;; another reason for saving the inline expansion: If the
 139    ;; ANSI-recommended idiom
 140    ;;   (DECLAIM (INLINE FOO))
 141    ;;   (DEFUN FOO ..)
 142    ;;   (DECLAIM (NOTINLINE FOO))
 143    ;; has been used, and then we later do another
 144    ;;   (DEFUN FOO ..)
 145    ;; without a preceding
 146    ;;   (DECLAIM (INLINE FOO))
 147    ;; what should we do with the old inline expansion when we see the
 148    ;; new DEFUN? Overwriting it with the new definition seems like
 149    ;; the only unsurprising choice.
 150    (info :function :inline-expansion-designator name)))
 151
 152 (defmacro-mundanely defun (&environment env name args &body body)
 153   "Define a function at top level."
 154   #+sb-xc-host
 155   (unless (symbol-package (fun-name-block-name name))
 156     (warn "DEFUN of uninterned symbol ~S (tricky for GENESIS)" name))
 157   (multiple-value-bind (forms decls doc) (parse-body body)
 158     (let* (;; stuff shared between LAMBDA and INLINE-LAMBDA and NAMED-LAMBDA
 159            (lambda-guts `(,args
 160                           ,@decls
 161                           (block ,(fun-name-block-name name)
 162                             ,@forms)))
 163            (lambda `(lambda ,@lambda-guts))
 164            #-sb-xc-host
 165            (named-lambda `(named-lambda ,name ,@lambda-guts))
 166            (inline-lambda
 167             (when (inline-fun-name-p name)
 168               ;; we want to attempt to inline, so complain if we can't
 169               (or (sb!c:maybe-inline-syntactic-closure lambda env)
 170                   (progn
 171                     (#+sb-xc-host warn
 172                      #-sb-xc-host sb!c:maybe-compiler-note
 173                      "lexical environment too hairy, can't inline DEFUN ~S"
 174                      name)
 175                     nil)))))
 176       `(progn
 177
 178          ;; In cross-compilation of toplevel DEFUNs, we arrange
 179          ;; for the LAMBDA to be statically linked by GENESIS.
 180          ;;
 181          ;; It may seem strangely inconsistent not to use NAMED-LAMBDA
 182          ;; here instead of LAMBDA. The reason is historical:
 183          ;; COLD-FSET was written before NAMED-LAMBDA, and has special
 184          ;; logic of its own to notify the compiler about NAME.
 185          #+sb-xc-host
 186          (cold-fset ,name ,lambda)
 187
 188          (eval-when (:compile-toplevel :load-toplevel :execute)
 189            (sb!c:%compiler-defun ',name ',inline-lambda))
 190
 191          (%defun ',name
 192                  ;; In normal compilation (not for cold load) this is
 193                  ;; where the compiled LAMBDA first appears. In
 194                  ;; cross-compilation, we manipulate the
 195                  ;; previously-statically-linked LAMBDA here.
 196                  #-sb-xc-host ,named-lambda
 197                  #+sb-xc-host (fdefinition ',name)
 198                  ,doc)))))
 199 #-sb-xc-host
 200 (defun %defun (name def doc)
 201   (declare (type function def))
 202   (declare (type (or null simple-string doc)))
 203   (aver (legal-fun-name-p name)) ; should've been checked by DEFMACRO DEFUN
 204   (when (fboundp name)
 205     (/show0 "redefining NAME in %DEFUN")
 206     (style-warn "redefining ~S in DEFUN" name))
 207   (setf (sb!xc:fdefinition name) def)
 208
 209   ;; FIXME: I want to do this here (and fix bug 137), but until the
 210   ;; breathtaking CMU CL function name architecture is converted into
 211   ;; something sane, (1) doing so doesn't really fix the bug, and
 212   ;; (2) doing probably isn't even really safe.
 213   #+nil (setf (%fun-name def) name)
 214
 215   (when doc
 216     ;; FIXME: This should use shared SETF-name-parsing logic.
 217     (if (and (consp name) (eq (first name) 'setf))
 218         (setf (fdocumentation (second name) 'setf) doc)
 219         (setf (fdocumentation (the symbol name) 'function) doc)))
 220   name)
 221 \f
 222 ;;;; DEFVAR and DEFPARAMETER
 223
 224 (defmacro-mundanely defvar (var &optional (val nil valp) (doc nil docp))
 225   #!+sb-doc
 226   "Define a global variable at top level. Declare the variable
 227   SPECIAL and, optionally, initialize it. If the variable already has a
 228   value, the old value is not clobbered. The third argument is an optional
 229   documentation string for the variable."
 230   `(progn
 231      (declaim (special ,var))
 232      ,@(when valp
 233          `((unless (boundp ',var)
 234              (setq ,var ,val))))
 235      ,@(when docp
 236          `((setf (fdocumentation ',var 'variable) ',doc )))
 237      ',var))
 238
 239 (defmacro-mundanely defparameter (var val &optional (doc nil docp))
 240   #!+sb-doc
 241   "Define a parameter that is not normally changed by the program,
 242   but that may be changed without causing an error. Declare the
 243   variable special and sets its value to VAL, overwriting any
 244   previous value. The third argument is an optional documentation
 245   string for the parameter."
 246   `(progn
 247      (declaim (special ,var))
 248      (setq ,var ,val)
 249      ,@(when docp
 250          `((setf (fdocumentation ',var 'variable) ',doc)))
 251      ',var))
 252 \f
 253 ;;;; iteration constructs
 254
 255 ;;; (These macros are defined in terms of a function FROB-DO-BODY which
 256 ;;; is also used by SB!INT:DO-ANONYMOUS. Since these macros should not
 257 ;;; be loaded on the cross-compilation host, but SB!INT:DO-ANONYMOUS
 258 ;;; and FROB-DO-BODY should be, these macros can't conveniently be in
 259 ;;; the same file as FROB-DO-BODY.)
 260 (defmacro-mundanely do (varlist endlist &body body)
 261   #!+sb-doc
 262   "DO ({(Var [Init] [Step])}*) (Test Exit-Form*) Declaration* Form*
 263   Iteration construct. Each Var is initialized in parallel to the value of the
 264   specified Init form. On subsequent iterations, the Vars are assigned the
 265   value of the Step form (if any) in parallel. The Test is evaluated before
 266   each evaluation of the body Forms. When the Test is true, the Exit-Forms
 267   are evaluated as a PROGN, with the result being the value of the DO. A block
 268   named NIL is established around the entire expansion, allowing RETURN to be
 269   used as an alternate exit mechanism."
 270   (frob-do-body varlist endlist body 'let 'psetq 'do nil))
 271 (defmacro-mundanely do* (varlist endlist &body body)
 272   #!+sb-doc
 273   "DO* ({(Var [Init] [Step])}*) (Test Exit-Form*) Declaration* Form*
 274   Iteration construct. Each Var is initialized sequentially (like LET*) to the
 275   value of the specified Init form. On subsequent iterations, the Vars are
 276   sequentially assigned the value of the Step form (if any). The Test is
 277   evaluated before each evaluation of the body Forms. When the Test is true,
 278   the Exit-Forms are evaluated as a PROGN, with the result being the value
 279   of the DO. A block named NIL is established around the entire expansion,
 280   allowing RETURN to be used as an laternate exit mechanism."
 281   (frob-do-body varlist endlist body 'let* 'setq 'do* nil))
 282
 283 ;;; DOTIMES and DOLIST could be defined more concisely using
 284 ;;; destructuring macro lambda lists or DESTRUCTURING-BIND, but then
 285 ;;; it'd be tricky to use them before those things were defined.
 286 ;;; They're used enough times before destructuring mechanisms are
 287 ;;; defined that it looks as though it's worth just implementing them
 288 ;;; ASAP, at the cost of being unable to use the standard
 289 ;;; destructuring mechanisms.
 290 (defmacro-mundanely dotimes ((var count &optional (result nil)) &body body)
 291   (cond ((numberp count)
 292          `(do ((,var 0 (1+ ,var)))
 293            ((>= ,var ,count) ,result)
 294            (declare (type unsigned-byte ,var))
 295            ,@body))
 296         (t (let ((v1 (gensym)))
 297              `(do ((,var 0 (1+ ,var)) (,v1 ,count))
 298                ((>= ,var ,v1) ,result)
 299                (declare (type unsigned-byte ,var))
 300                ,@body)))))
 301
 302 (defmacro-mundanely dolist ((var list &optional (result nil)) &body body)
 303   ;; We repeatedly bind the var instead of setting it so that we never
 304   ;; have to give the var an arbitrary value such as NIL (which might
 305   ;; conflict with a declaration). If there is a result form, we
 306   ;; introduce a gratuitous binding of the variable to NIL without the
 307   ;; declarations, then evaluate the result form in that
 308   ;; environment. We spuriously reference the gratuitous variable,
 309   ;; since we don't want to use IGNORABLE on what might be a special
 310   ;; var.
 311   (multiple-value-bind (forms decls) (parse-body body nil)
 312     (let ((n-list (gensym)))
 313       `(do* ((,n-list ,list (cdr ,n-list)))
 314         ((endp ,n-list)
 315          ,@(if result
 316                `((let ((,var nil))
 317                    ,var
 318                    ,result))
 319                '(nil)))
 320         (let ((,var (car ,n-list)))
 321           ,@decls
 322           (tagbody
 323              ,@forms))))))
 324 \f
 325 ;;;; miscellaneous
 326
 327 (defmacro-mundanely return (&optional (value nil))
 328   `(return-from nil ,value))
 329
 330 (defmacro-mundanely psetq (&rest pairs)
 331   #!+sb-doc
 332   "PSETQ {var value}*
 333    Set the variables to the values, like SETQ, except that assignments
 334    happen in parallel, i.e. no assignments take place until all the
 335    forms have been evaluated."
 336   ;; Given the possibility of symbol-macros, we delegate to PSETF
 337   ;; which knows how to deal with them, after checking that syntax is
 338   ;; compatible with PSETQ.
 339   (do ((pair pairs (cddr pair)))
 340       ((endp pair) `(psetf ,@pairs))
 341     (unless (symbolp (car pair))
 342       (error 'simple-program-error
 343              :format-control "variable ~S in PSETQ is not a SYMBOL"
 344              :format-arguments (list (car pair))))))
 345
 346 (defmacro-mundanely lambda (&whole whole args &body body)
 347   (declare (ignore args body))
 348   `#',whole)