src/code/defboot.lisp

   1 ;;;; bootstrapping fundamental machinery (e.g. DEFUN, DEFCONSTANT,
   2 ;;;; DEFVAR) from special forms and primitive functions
   3 ;;;;
   4 ;;;; KLUDGE: The bootstrapping aspect of this is now obsolete. It was
   5 ;;;; originally intended that this file file would be loaded into a
   6 ;;;; Lisp image which had Common Lisp primitives defined, and DEFMACRO
   7 ;;;; defined, and little else. Since then that approach has been
   8 ;;;; dropped and this file has been modified somewhat to make it work
   9 ;;;; more cleanly when used to predefine macros at
  10 ;;;; build-the-cross-compiler time.
  11
  12 ;;;; This software is part of the SBCL system. See the README file for
  13 ;;;; more information.
  14 ;;;;
  15 ;;;; This software is derived from the CMU CL system, which was
  16 ;;;; written at Carnegie Mellon University and released into the
  17 ;;;; public domain. The software is in the public domain and is
  18 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  19 ;;;; files for more information.
  20
  21 (in-package "SB!IMPL")
  22
  23 \f
  24 ;;;; IN-PACKAGE
  25
  26 (defmacro-mundanely in-package (string-designator)
  27   (let ((string (string string-designator)))
  28     `(eval-when (:compile-toplevel :load-toplevel :execute)
  29        (setq *package* (find-undeleted-package-or-lose ,string)))))
  30 \f
  31 ;;;; MULTIPLE-VALUE-FOO
  32
  33 (defun list-of-symbols-p (x)
  34   (and (listp x)
  35        (every #'symbolp x)))
  36
  37 (defmacro-mundanely multiple-value-bind (vars value-form &body body)
  38   (if (list-of-symbols-p vars)
  39     ;; It's unclear why it would be important to special-case the LENGTH=1 case
  40     ;; at this level, but the CMU CL code did it, so.. -- WHN 19990411
  41     (if (= (length vars) 1)
  42       `(let ((,(car vars) ,value-form))
  43          ,@body)
  44       (let ((ignore (sb!xc:gensym)))
  45         `(multiple-value-call #'(lambda (&optional ,@(mapcar #'list vars)
  46                                          &rest ,ignore)
  47                                   (declare (ignore ,ignore))
  48                                   ,@body)
  49                               ,value-form)))
  50     (error "Vars is not a list of symbols: ~S" vars)))
  51
  52 (defmacro-mundanely multiple-value-setq (vars value-form)
  53   (unless (list-of-symbols-p vars)
  54     (error "Vars is not a list of symbols: ~S" vars))
  55   ;; MULTIPLE-VALUE-SETQ is required to always return just the primary
  56   ;; value of the value-from, even if there are no vars. (SETF VALUES)
  57   ;; in turn is required to return as many values as there are
  58   ;; value-places, hence this:
  59   (if vars
  60       `(values (setf (values ,@vars) ,value-form))
  61       `(values ,value-form)))
  62
  63 (defmacro-mundanely multiple-value-list (value-form)
  64   `(multiple-value-call #'list ,value-form))
  65 \f
  66 ;;;; various conditional constructs
  67
  68 ;;; COND defined in terms of IF
  69 (defmacro-mundanely cond (&rest clauses)
  70   (if (endp clauses)
  71       nil
  72       (let ((clause (first clauses))
  73             (more (rest clauses)))
  74         (if (atom clause)
  75             (error "COND clause is not a list: ~S" clause)
  76             (let ((test (first clause))
  77                   (forms (rest clause)))
  78               (if (endp forms)
  79                   (let ((n-result (gensym)))
  80                     `(let ((,n-result ,test))
  81                        (if ,n-result
  82                            ,n-result
  83                            (cond ,@more))))
  84                   (if (eq t test)
  85                       ;; THE to perserve non-toplevelness for FOO in
  86                       ;;   (COND (T (FOO)))
  87                       `(the t (progn ,@forms))
  88                       `(if ,test
  89                            (progn ,@forms)
  90                            ,(when more `(cond ,@more))))))))))
  91
  92 (defmacro-mundanely when (test &body forms)
  93   #!+sb-doc
  94   "If the first argument is true, the rest of the forms are
  95 evaluated as a PROGN."
  96   `(if ,test (progn ,@forms) nil))
  97
  98 (defmacro-mundanely unless (test &body forms)
  99   #!+sb-doc
 100   "If the first argument is not true, the rest of the forms are
 101 evaluated as a PROGN."
 102   `(if ,test nil (progn ,@forms)))
 103
 104 (defmacro-mundanely and (&rest forms)
 105   (cond ((endp forms) t)
 106         ((endp (rest forms))
 107          ;; Preserve non-toplevelness of the form!
 108          `(the t ,(first forms)))
 109         (t
 110          `(if ,(first forms)
 111               (and ,@(rest forms))
 112               nil))))
 113
 114 (defmacro-mundanely or (&rest forms)
 115   (cond ((endp forms) nil)
 116         ((endp (rest forms))
 117          ;; Preserve non-toplevelness of the form!
 118          `(the t ,(first forms)))
 119         (t
 120          (let ((n-result (gensym)))
 121            `(let ((,n-result ,(first forms)))
 122               (if ,n-result
 123                   ,n-result
 124                   (or ,@(rest forms))))))))
 125 \f
 126 ;;;; various sequencing constructs
 127
 128 (flet ((prog-expansion-from-let (varlist body-decls let)
 129          (multiple-value-bind (body decls)
 130              (parse-body body-decls :doc-string-allowed nil)
 131            `(block nil
 132               (,let ,varlist
 133                 ,@decls
 134                 (tagbody ,@body))))))
 135   (defmacro-mundanely prog (varlist &body body-decls)
 136     (prog-expansion-from-let varlist body-decls 'let))
 137   (defmacro-mundanely prog* (varlist &body body-decls)
 138     (prog-expansion-from-let varlist body-decls 'let*)))
 139
 140 (defmacro-mundanely prog1 (result &body body)
 141   (let ((n-result (gensym)))
 142     `(let ((,n-result ,result))
 143        ,@body
 144        ,n-result)))
 145
 146 (defmacro-mundanely prog2 (form1 result &body body)
 147   `(prog1 (progn ,form1 ,result) ,@body))
 148 \f
 149 ;;;; DEFUN
 150
 151 ;;; Should we save the inline expansion of the function named NAME?
 152 (defun inline-fun-name-p (name)
 153   (or
 154    ;; the normal reason for saving the inline expansion
 155    (let ((inlinep (info :function :inlinep name)))
 156      (member inlinep '(:inline :maybe-inline)))
 157    ;; another reason for saving the inline expansion: If the
 158    ;; ANSI-recommended idiom
 159    ;;   (DECLAIM (INLINE FOO))
 160    ;;   (DEFUN FOO ..)
 161    ;;   (DECLAIM (NOTINLINE FOO))
 162    ;; has been used, and then we later do another
 163    ;;   (DEFUN FOO ..)
 164    ;; without a preceding
 165    ;;   (DECLAIM (INLINE FOO))
 166    ;; what should we do with the old inline expansion when we see the
 167    ;; new DEFUN? Overwriting it with the new definition seems like
 168    ;; the only unsurprising choice.
 169    (info :function :inline-expansion-designator name)))
 170
 171 (defmacro-mundanely defun (&environment env name args &body body)
 172   "Define a function at top level."
 173   #+sb-xc-host
 174   (unless (symbol-package (fun-name-block-name name))
 175     (warn "DEFUN of uninterned function name ~S (tricky for GENESIS)" name))
 176   (multiple-value-bind (forms decls doc) (parse-body body)
 177     (let* (;; stuff shared between LAMBDA and INLINE-LAMBDA and NAMED-LAMBDA
 178            (lambda-guts `(,args
 179                           ,@decls
 180                           (block ,(fun-name-block-name name)
 181                             ,@forms)))
 182            (lambda `(lambda ,@lambda-guts))
 183            #-sb-xc-host
 184            (named-lambda `(named-lambda ,name ,@lambda-guts))
 185            (inline-lambda
 186             (when (inline-fun-name-p name)
 187               ;; we want to attempt to inline, so complain if we can't
 188               (or (sb!c:maybe-inline-syntactic-closure lambda env)
 189                   (progn
 190                     (#+sb-xc-host warn
 191                      #-sb-xc-host sb!c:maybe-compiler-notify
 192                      "lexical environment too hairy, can't inline DEFUN ~S"
 193                      name)
 194                     nil)))))
 195       `(progn
 196          ;; In cross-compilation of toplevel DEFUNs, we arrange for
 197          ;; the LAMBDA to be statically linked by GENESIS.
 198          ;;
 199          ;; It may seem strangely inconsistent not to use NAMED-LAMBDA
 200          ;; here instead of LAMBDA. The reason is historical:
 201          ;; COLD-FSET was written before NAMED-LAMBDA, and has special
 202          ;; logic of its own to notify the compiler about NAME.
 203          #+sb-xc-host
 204          (cold-fset ,name ,lambda)
 205
 206          (eval-when (:compile-toplevel)
 207            (sb!c:%compiler-defun ',name ',inline-lambda t))
 208          (eval-when (:load-toplevel :execute)
 209            (%defun ',name
 210                    ;; In normal compilation (not for cold load) this is
 211                    ;; where the compiled LAMBDA first appears. In
 212                    ;; cross-compilation, we manipulate the
 213                    ;; previously-statically-linked LAMBDA here.
 214                    #-sb-xc-host ,named-lambda
 215                    #+sb-xc-host (fdefinition ',name)
 216                    ,doc
 217                    ',inline-lambda
 218                    (sb!c:source-location)))))))
 219
 220 #-sb-xc-host
 221 (defun %defun (name def doc inline-lambda source-location)
 222   (declare (type function def))
 223   (declare (type (or null simple-string) doc))
 224   (aver (legal-fun-name-p name)) ; should've been checked by DEFMACRO DEFUN
 225   (sb!c:%compiler-defun name inline-lambda nil)
 226   (when (fboundp name)
 227     (/show0 "redefining NAME in %DEFUN")
 228     (warn 'sb!kernel::redefinition-with-defun
 229           :name name
 230           :new-function def
 231           :new-location source-location))
 232   (setf (sb!xc:fdefinition name) def)
 233   ;; %COMPILER-DEFUN doesn't do this except at compile-time, when it
 234   ;; also checks package locks. By doing this here we let (SETF
 235   ;; FDEFINITION) do the load-time package lock checking before
 236   ;; we frob any existing inline expansions.
 237   (sb!c::%set-inline-expansion name nil inline-lambda)
 238
 239   (sb!c::note-name-defined name :function)
 240
 241   (when doc
 242     (setf (%fun-doc def) doc))
 243
 244   name)
 245 \f
 246 ;;;; DEFVAR and DEFPARAMETER
 247
 248 (defmacro-mundanely defvar (var &optional (val nil valp) (doc nil docp))
 249   #!+sb-doc
 250   "Define a special variable at top level. Declare the variable
 251   SPECIAL and, optionally, initialize it. If the variable already has a
 252   value, the old value is not clobbered. The third argument is an optional
 253   documentation string for the variable."
 254   `(progn
 255      (eval-when (:compile-toplevel)
 256        (%compiler-defvar ',var))
 257      (eval-when (:load-toplevel :execute)
 258        (%defvar ',var (unless (boundp ',var) ,val)
 259                 ',valp ,doc ',docp
 260                 (sb!c:source-location)))))
 261
 262 (defmacro-mundanely defparameter (var val &optional (doc nil docp))
 263   #!+sb-doc
 264   "Define a parameter that is not normally changed by the program,
 265   but that may be changed without causing an error. Declare the
 266   variable special and sets its value to VAL, overwriting any
 267   previous value. The third argument is an optional documentation
 268   string for the parameter."
 269   `(progn
 270      (eval-when (:compile-toplevel)
 271        (%compiler-defvar ',var))
 272      (eval-when (:load-toplevel :execute)
 273        (%defparameter ',var ,val ,doc ',docp (sb!c:source-location)))))
 274
 275 (defun %compiler-defvar (var)
 276   (sb!xc:proclaim `(special ,var)))
 277
 278 #-sb-xc-host
 279 (defun %defvar (var val valp doc docp source-location)
 280   (%compiler-defvar var)
 281   (when valp
 282     (unless (boundp var)
 283       (set var val)))
 284   (when docp
 285     (setf (fdocumentation var 'variable) doc))
 286   (sb!c:with-source-location (source-location)
 287     (setf (info :source-location :variable var) source-location))
 288   var)
 289
 290 #-sb-xc-host
 291 (defun %defparameter (var val doc docp source-location)
 292   (%compiler-defvar var)
 293   (set var val)
 294   (when docp
 295     (setf (fdocumentation var 'variable) doc))
 296   (sb!c:with-source-location (source-location)
 297     (setf (info :source-location :variable var) source-location))
 298   var)
 299 \f
 300 ;;;; iteration constructs
 301
 302 ;;; (These macros are defined in terms of a function FROB-DO-BODY which
 303 ;;; is also used by SB!INT:DO-ANONYMOUS. Since these macros should not
 304 ;;; be loaded on the cross-compilation host, but SB!INT:DO-ANONYMOUS
 305 ;;; and FROB-DO-BODY should be, these macros can't conveniently be in
 306 ;;; the same file as FROB-DO-BODY.)
 307 (defmacro-mundanely do (varlist endlist &body body)
 308   #!+sb-doc
 309   "DO ({(Var [Init] [Step])}*) (Test Exit-Form*) Declaration* Form*
 310   Iteration construct. Each Var is initialized in parallel to the value of the
 311   specified Init form. On subsequent iterations, the Vars are assigned the
 312   value of the Step form (if any) in parallel. The Test is evaluated before
 313   each evaluation of the body Forms. When the Test is true, the Exit-Forms
 314   are evaluated as a PROGN, with the result being the value of the DO. A block
 315   named NIL is established around the entire expansion, allowing RETURN to be
 316   used as an alternate exit mechanism."
 317   (frob-do-body varlist endlist body 'let 'psetq 'do nil))
 318 (defmacro-mundanely do* (varlist endlist &body body)
 319   #!+sb-doc
 320   "DO* ({(Var [Init] [Step])}*) (Test Exit-Form*) Declaration* Form*
 321   Iteration construct. Each Var is initialized sequentially (like LET*) to the
 322   value of the specified Init form. On subsequent iterations, the Vars are
 323   sequentially assigned the value of the Step form (if any). The Test is
 324   evaluated before each evaluation of the body Forms. When the Test is true,
 325   the Exit-Forms are evaluated as a PROGN, with the result being the value
 326   of the DO. A block named NIL is established around the entire expansion,
 327   allowing RETURN to be used as an laternate exit mechanism."
 328   (frob-do-body varlist endlist body 'let* 'setq 'do* nil))
 329
 330 ;;; DOTIMES and DOLIST could be defined more concisely using
 331 ;;; destructuring macro lambda lists or DESTRUCTURING-BIND, but then
 332 ;;; it'd be tricky to use them before those things were defined.
 333 ;;; They're used enough times before destructuring mechanisms are
 334 ;;; defined that it looks as though it's worth just implementing them
 335 ;;; ASAP, at the cost of being unable to use the standard
 336 ;;; destructuring mechanisms.
 337 (defmacro-mundanely dotimes ((var count &optional (result nil)) &body body)
 338   (cond ((integerp count)
 339         `(do ((,var 0 (1+ ,var)))
 340              ((>= ,var ,count) ,result)
 341            (declare (type unsigned-byte ,var))
 342            ,@body))
 343         (t
 344          (let ((c (gensym "COUNT")))
 345            `(do ((,var 0 (1+ ,var))
 346                  (,c ,count))
 347                 ((>= ,var ,c) ,result)
 348               (declare (type unsigned-byte ,var)
 349                        (type integer ,c))
 350               ,@body)))))
 351
 352 (defmacro-mundanely dolist ((var list &optional (result nil)) &body body &environment env)
 353   ;; We repeatedly bind the var instead of setting it so that we never
 354   ;; have to give the var an arbitrary value such as NIL (which might
 355   ;; conflict with a declaration). If there is a result form, we
 356   ;; introduce a gratuitous binding of the variable to NIL without the
 357   ;; declarations, then evaluate the result form in that
 358   ;; environment. We spuriously reference the gratuitous variable,
 359   ;; since we don't want to use IGNORABLE on what might be a special
 360   ;; var.
 361   (multiple-value-bind (forms decls) (parse-body body :doc-string-allowed nil)
 362     (let* ((n-list (gensym "N-LIST"))
 363            (start (gensym "START")))
 364       (multiple-value-bind (clist members clist-ok)
 365           (cond ((sb!xc:constantp list env)
 366                  (let ((value (constant-form-value list env)))
 367                    (multiple-value-bind (all dot) (list-members value :max-length 20)
 368                      (when (eql dot t)
 369                        ;; Full warning is too much: the user may terminate the loop
 370                        ;; early enough. Contents are still right, though.
 371                        (style-warn "Dotted list ~S in DOLIST." value))
 372                      (if (eql dot :maybe)
 373                          (values value nil nil)
 374                          (values value all t)))))
 375                 ((and (consp list) (eq 'list (car list))
 376                       (every (lambda (arg) (sb!xc:constantp arg env)) (cdr list)))
 377                  (let ((values (mapcar (lambda (arg) (constant-form-value arg env)) (cdr list))))
 378                    (values values values t)))
 379                 (t
 380                  (values nil nil nil)))
 381         `(block nil
 382            (let ((,n-list ,(if clist-ok (list 'quote clist) list)))
 383              (tagbody
 384                 ,start
 385                 (unless (endp ,n-list)
 386                   (let ((,var ,(if clist-ok
 387                                    `(truly-the (member ,@members) (car ,n-list))
 388                                    `(car ,n-list))))
 389                     ,@decls
 390                     (setq ,n-list (cdr ,n-list))
 391                     (tagbody ,@forms))
 392                   (go ,start))))
 393            ,(if result
 394                 `(let ((,var nil))
 395                    ;; Filter out TYPE declarations (VAR gets bound to NIL,
 396                    ;; and might have a conflicting type declaration) and
 397                    ;; IGNORE (VAR might be ignored in the loop body, but
 398                    ;; it's used in the result form).
 399                    ,@(filter-dolist-declarations decls)
 400                    ,var
 401                    ,result)
 402                 nil))))))
 403 \f
 404 ;;;; conditions, handlers, restarts
 405
 406 ;;; KLUDGE: we PROCLAIM these special here so that we can use restart
 407 ;;; macros in the compiler before the DEFVARs are compiled.
 408 (sb!xc:proclaim
 409  '(special *handler-clusters* *restart-clusters* *condition-restarts*))
 410
 411 (defmacro-mundanely with-condition-restarts
 412     (condition-form restarts-form &body body)
 413   #!+sb-doc
 414   "Evaluates the BODY in a dynamic environment where the restarts in the list
 415    RESTARTS-FORM are associated with the condition returned by CONDITION-FORM.
 416    This allows FIND-RESTART, etc., to recognize restarts that are not related
 417    to the error currently being debugged. See also RESTART-CASE."
 418   (let ((n-cond (gensym)))
 419     `(let ((*condition-restarts*
 420             (cons (let ((,n-cond ,condition-form))
 421                     (cons ,n-cond
 422                           (append ,restarts-form
 423                                   (cdr (assoc ,n-cond *condition-restarts*)))))
 424                   *condition-restarts*)))
 425        ,@body)))
 426
 427 (defmacro-mundanely restart-bind (bindings &body forms)
 428   #!+sb-doc
 429   "Executes forms in a dynamic context where the given restart bindings are
 430    in effect. Users probably want to use RESTART-CASE. When clauses contain
 431    the same restart name, FIND-RESTART will find the first such clause."
 432   `(let ((*restart-clusters*
 433           (cons (list
 434                  ,@(mapcar (lambda (binding)
 435                              (unless (or (car binding)
 436                                          (member :report-function
 437                                                  binding
 438                                                  :test #'eq))
 439                                (warn "Unnamed restart does not have a ~
 440                                       report function: ~S"
 441                                      binding))
 442                              `(make-restart :name ',(car binding)
 443                                             :function ,(cadr binding)
 444                                             ,@(cddr binding)))
 445                            bindings))
 446                 *restart-clusters*)))
 447      ,@forms))
 448
 449 ;;; Wrap the RESTART-CASE expression in a WITH-CONDITION-RESTARTS if
 450 ;;; appropriate. Gross, but it's what the book seems to say...
 451 (defun munge-restart-case-expression (expression env)
 452   (let ((exp (%macroexpand expression env)))
 453     (if (consp exp)
 454         (let* ((name (car exp))
 455                (args (if (eq name 'cerror) (cddr exp) (cdr exp))))
 456           (if (member name '(signal error cerror warn))
 457               (once-only ((n-cond `(coerce-to-condition
 458                                     ,(first args)
 459                                     (list ,@(rest args))
 460                                     ',(case name
 461                                         (warn 'simple-warning)
 462                                         (signal 'simple-condition)
 463                                         (t 'simple-error))
 464                                     ',name)))
 465                 `(with-condition-restarts
 466                      ,n-cond
 467                      (car *restart-clusters*)
 468                    ,(if (eq name 'cerror)
 469                         `(cerror ,(second exp) ,n-cond)
 470                         `(,name ,n-cond))))
 471               expression))
 472         expression)))
 473
 474 (defmacro-mundanely restart-case (expression &body clauses &environment env)
 475   #!+sb-doc
 476   "(RESTART-CASE form {(case-name arg-list {keyword value}* body)}*)
 477    The form is evaluated in a dynamic context where the clauses have
 478    special meanings as points to which control may be transferred (see
 479    INVOKE-RESTART).  When clauses contain the same case-name,
 480    FIND-RESTART will find the first such clause. If form is a call to
 481    SIGNAL, ERROR, CERROR or WARN (or macroexpands into such) then the
 482    signalled condition will be associated with the new restarts."
 483   ;; PARSE-CLAUSE (which uses PARSE-KEYWORDS-AND-BODY) is used to
 484   ;; parse all clauses into lists of the form
 485   ;;
 486   ;;  (NAME TAG KEYWORDS LAMBDA-LIST BODY)
 487   ;;
 488   ;; where KEYWORDS are suitable keywords for use in HANDLER-BIND
 489   ;; bindings. These lists are then passed to
 490   ;; * MAKE-BINDING which generates bindings for the respective NAME
 491   ;;   for HANDLER-BIND
 492   ;; * MAKE-APPLY-AND-RETURN which generates TAGBODY entries executing
 493   ;;   the respective BODY.
 494   (let ((block-tag (sb!xc:gensym "BLOCK"))
 495         (temp-var (gensym)))
 496     (labels ((parse-keywords-and-body (keywords-and-body)
 497                (do ((form keywords-and-body (cddr form))
 498                     (result '())) (nil)
 499                  (destructuring-bind (&optional key (arg nil argp) &rest rest)
 500                      form
 501                    (declare (ignore rest))
 502                    (setq result
 503                          (append
 504                           (cond
 505                             ((and (eq key :report) argp)
 506                              (list :report-function
 507                                    (if (stringp arg)
 508                                        `#'(lambda (stream)
 509                                             (write-string ,arg stream))
 510                                        `#',arg)))
 511                             ((and (eq key :interactive) argp)
 512                              (list :interactive-function `#',arg))
 513                             ((and (eq key :test) argp)
 514                              (list :test-function `#',arg))
 515                             (t
 516                              (return (values result form))))
 517                           result)))))
 518              (parse-clause (clause)
 519                (unless (and (listp clause ) (>= (length clause) 2)
 520                             (listp (second clause)))
 521                  (error "ill-formed ~S clause, no lambda-list:~%  ~S"
 522                         'restart-case clause))
 523                (destructuring-bind (name lambda-list &body body) clause
 524                  (multiple-value-bind (keywords body)
 525                      (parse-keywords-and-body body)
 526                    (list name (sb!xc:gensym "TAG") keywords lambda-list body))))
 527              (make-binding (clause-data)
 528                (destructuring-bind (name tag keywords &rest rest) clause-data
 529                  (declare (ignore rest))
 530                  `(,name #'(lambda (&rest temp)
 531                              (setq ,temp-var temp)
 532                              (go ,tag))
 533                          ,@keywords)))
 534              (make-apply-and-return (clause-data)
 535                (destructuring-bind (name tag keywords lambda-list body) clause-data
 536                  (declare (ignore name keywords))
 537                  `(,tag (return-from ,block-tag
 538                           (apply (lambda ,lambda-list ,@body) ,temp-var))))))
 539       (let ((clauses-data (mapcar #'parse-clause clauses)))
 540         `(block ,block-tag
 541            (let ((,temp-var nil))
 542              (declare (ignorable ,temp-var))
 543              (tagbody
 544                 (restart-bind
 545                     ,(mapcar #'make-binding clauses-data)
 546                   (return-from ,block-tag
 547                     ,(munge-restart-case-expression expression env)))
 548                 ,@(mapcan #'make-apply-and-return clauses-data))))))))
 549
 550 (defmacro-mundanely with-simple-restart ((restart-name format-string
 551                                                        &rest format-arguments)
 552                                          &body forms)
 553   #!+sb-doc
 554   "(WITH-SIMPLE-RESTART (restart-name format-string format-arguments)
 555    body)
 556    If restart-name is not invoked, then all values returned by forms are
 557    returned. If control is transferred to this restart, it immediately
 558    returns the values NIL and T."
 559   `(restart-case
 560        ;; If there's just one body form, then don't use PROGN. This allows
 561        ;; RESTART-CASE to "see" calls to ERROR, etc.
 562        ,(if (= (length forms) 1) (car forms) `(progn ,@forms))
 563      (,restart-name ()
 564         :report (lambda (stream)
 565                   (format stream ,format-string ,@format-arguments))
 566       (values nil t))))
 567
 568 (defmacro-mundanely %handler-bind (bindings form)
 569   (let ((member-if (member-if (lambda (x)
 570                                 (not (proper-list-of-length-p x 2)))
 571                               bindings)))
 572     (when member-if
 573       (error "ill-formed handler binding: ~S" (first member-if))))
 574   (let* ((local-funs nil)
 575          (mapped-bindings (mapcar (lambda (binding)
 576                                     (destructuring-bind (type handler) binding
 577                                       (let ((lambda-form handler))
 578                                         (if (and (consp handler)
 579                                                  (or (eq 'lambda (car handler))
 580                                                      (and (eq 'function (car handler))
 581                                                           (consp (cdr handler))
 582                                                           (let ((x (second handler)))
 583                                                             (and (consp x)
 584                                                                  (eq 'lambda (car x))
 585                                                                  (setf lambda-form x))))))
 586                                             (let ((name (sb!xc:gensym "LAMBDA")))
 587                                               (push `(,name ,@(cdr lambda-form)) local-funs)
 588                                               (list type `(function ,name)))
 589                                             binding))))
 590                                   bindings)))
 591     `(dx-flet (,@(reverse local-funs))
 592        (let ((*handler-clusters*
 593               (cons (list ,@(mapcar (lambda (x) `(cons ',(car x) ,(cadr x)))
 594                                     mapped-bindings))
 595                     *handler-clusters*)))
 596          #!+stack-allocatable-fixed-objects
 597          (declare (truly-dynamic-extent *handler-clusters*))
 598          (progn ,form)))))
 599
 600 (defmacro-mundanely handler-bind (bindings &body forms)
 601   #!+sb-doc
 602   "(HANDLER-BIND ( {(type handler)}* )  body)
 603
 604 Executes body in a dynamic context where the given handler bindings are in
 605 effect. Each handler must take the condition being signalled as an argument.
 606 The bindings are searched first to last in the event of a signalled
 607 condition."
 608   `(%handler-bind ,bindings
 609                   #!-x86 (progn ,@forms)
 610                   ;; Need to catch FP errors here!
 611                   #!+x86 (multiple-value-prog1 (progn ,@forms) (float-wait))))
 612
 613 (defmacro-mundanely handler-case (form &rest cases)
 614   "(HANDLER-CASE form { (type ([var]) body) }* )
 615
 616 Execute FORM in a context with handlers established for the condition types. A
 617 peculiar property allows type to be :NO-ERROR. If such a clause occurs, and
 618 form returns normally, all its values are passed to this clause as if by
 619 MULTIPLE-VALUE-CALL. The :NO-ERROR clause accepts more than one var
 620 specification."
 621   (let ((no-error-clause (assoc ':no-error cases)))
 622     (if no-error-clause
 623         (let ((normal-return (make-symbol "normal-return"))
 624               (error-return  (make-symbol "error-return")))
 625           `(block ,error-return
 626              (multiple-value-call (lambda ,@(cdr no-error-clause))
 627                (block ,normal-return
 628                  (return-from ,error-return
 629                    (handler-case (return-from ,normal-return ,form)
 630                      ,@(remove no-error-clause cases)))))))
 631         (let* ((local-funs nil)
 632                (annotated-cases
 633                 (mapcar (lambda (case)
 634                           (with-unique-names (tag fun)
 635                             (destructuring-bind (type ll &body body) case
 636                               (push `(,fun ,ll ,@body) local-funs)
 637                               (list tag type ll fun))))
 638                         cases)))
 639           (with-unique-names (block cell form-fun)
 640             `(dx-flet ((,form-fun ()
 641                          #!-x86 ,form
 642                          ;; Need to catch FP errors here!
 643                          #!+x86 (multiple-value-prog1 ,form (float-wait)))
 644                        ,@(reverse local-funs))
 645                (declare (optimize (sb!c::check-tag-existence 0)))
 646                (block ,block
 647                  ;; KLUDGE: We use a dx CONS cell instead of just assigning to
 648                  ;; the variable directly, so that we can stack allocate
 649                  ;; robustly: dx value cells don't work quite right, and it is
 650                  ;; possible to construct user code that should loop
 651                  ;; indefinitely, but instead eats up some stack each time
 652                  ;; around.
 653                  (dx-let ((,cell (cons :condition nil)))
 654                    (declare (ignorable ,cell))
 655                    (tagbody
 656                       (%handler-bind
 657                        ,(mapcar (lambda (annotated-case)
 658                                   (destructuring-bind (tag type ll fun-name) annotated-case
 659                                     (declare (ignore fun-name))
 660                                     (list type
 661                                           `(lambda (temp)
 662                                              ,(if ll
 663                                                   `(setf (cdr ,cell) temp)
 664                                                   '(declare (ignore temp)))
 665                                              (go ,tag)))))
 666                                 annotated-cases)
 667                        (return-from ,block (,form-fun)))
 668                       ,@(mapcan
 669                          (lambda (annotated-case)
 670                            (destructuring-bind (tag type ll fun-name) annotated-case
 671                              (declare (ignore type))
 672                              (list tag
 673                                    `(return-from ,block
 674                                       ,(if ll
 675                                            `(,fun-name (cdr ,cell))
 676                                            `(,fun-name))))))
 677                          annotated-cases))))))))))
 678 \f
 679 ;;;; miscellaneous
 680
 681 (defmacro-mundanely return (&optional (value nil))
 682   `(return-from nil ,value))
 683
 684 (defmacro-mundanely psetq (&rest pairs)
 685   #!+sb-doc
 686   "PSETQ {var value}*
 687    Set the variables to the values, like SETQ, except that assignments
 688    happen in parallel, i.e. no assignments take place until all the
 689    forms have been evaluated."
 690   ;; Given the possibility of symbol-macros, we delegate to PSETF
 691   ;; which knows how to deal with them, after checking that syntax is
 692   ;; compatible with PSETQ.
 693   (do ((pair pairs (cddr pair)))
 694       ((endp pair) `(psetf ,@pairs))
 695     (unless (symbolp (car pair))
 696       (error 'simple-program-error
 697              :format-control "variable ~S in PSETQ is not a SYMBOL"
 698              :format-arguments (list (car pair))))))
 699
 700 (defmacro-mundanely lambda (&whole whole args &body body)
 701   (declare (ignore args body))
 702   `#',whole)
 703
 704 (defmacro-mundanely named-lambda (&whole whole name args &body body)
 705   (declare (ignore name args body))
 706   `#',whole)
 707
 708 (defmacro-mundanely lambda-with-lexenv (&whole whole
 709                                         declarations macros symbol-macros
 710                                         &body body)
 711   (declare (ignore declarations macros symbol-macros body))
 712   `#',whole)
 713
 714 ;;; this eliminates a whole bundle of unknown function STYLE-WARNINGs
 715 ;;; when cross-compiling.  It's not critical for behaviour, but is
 716 ;;; aesthetically pleasing, except inasmuch as there's this list of
 717 ;;; magic functions here.  -- CSR, 2003-04-01
 718 #+sb-xc-host
 719 (sb!xc:proclaim '(ftype (function * *)
 720                         ;; functions appearing in fundamental defining
 721                         ;; macro expansions:
 722                         %compiler-deftype
 723                         %compiler-defvar
 724                         %defun
 725                         %defsetf
 726                         %defparameter
 727                         %defvar
 728                         sb!c:%compiler-defun
 729                         sb!c::%define-symbol-macro
 730                         sb!c::%defconstant
 731                         sb!c::%define-compiler-macro
 732                         sb!c::%defmacro
 733                         sb!kernel::%compiler-defstruct
 734                         sb!kernel::%compiler-define-condition
 735                         sb!kernel::%defstruct
 736                         sb!kernel::%define-condition
 737                         ;; miscellaneous functions commonly appearing
 738                         ;; as a result of macro expansions or compiler
 739                         ;; transformations:
 740                         sb!int:find-undeleted-package-or-lose ; IN-PACKAGE
 741                         sb!kernel::arg-count-error ; PARSE-DEFMACRO
 742                         ))