src/code/defboot.lisp

   1 ;;;; bootstrapping fundamental machinery (e.g. DEFUN, DEFCONSTANT,
   2 ;;;; DEFVAR) from special forms and primitive functions
   3 ;;;;
   4 ;;;; KLUDGE: The bootstrapping aspect of this is now obsolete. It was
   5 ;;;; originally intended that this file file would be loaded into a
   6 ;;;; Lisp image which had Common Lisp primitives defined, and DEFMACRO
   7 ;;;; defined, and little else. Since then that approach has been
   8 ;;;; dropped and this file has been modified somewhat to make it work
   9 ;;;; more cleanly when used to predefine macros at
  10 ;;;; build-the-cross-compiler time.
  11
  12 ;;;; This software is part of the SBCL system. See the README file for
  13 ;;;; more information.
  14 ;;;;
  15 ;;;; This software is derived from the CMU CL system, which was
  16 ;;;; written at Carnegie Mellon University and released into the
  17 ;;;; public domain. The software is in the public domain and is
  18 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  19 ;;;; files for more information.
  20
  21 (in-package "SB!IMPL")
  22 \f
  23 ;;;; IN-PACKAGE
  24
  25 (defmacro-mundanely in-package (package-designator)
  26   `(eval-when (:compile-toplevel :load-toplevel :execute)
  27      (setq *package* (find-undeleted-package-or-lose ',package-designator))))
  28 \f
  29 ;;;; MULTIPLE-VALUE-FOO
  30
  31 (defun list-of-symbols-p (x)
  32   (and (listp x)
  33        (every #'symbolp x)))
  34
  35 (defmacro-mundanely multiple-value-bind (vars value-form &body body)
  36   (if (list-of-symbols-p vars)
  37     ;; It's unclear why it would be important to special-case the LENGTH=1 case
  38     ;; at this level, but the CMU CL code did it, so.. -- WHN 19990411
  39     (if (= (length vars) 1)
  40       `(let ((,(car vars) ,value-form))
  41          ,@body)
  42       (let ((ignore (gensym)))
  43         `(multiple-value-call #'(lambda (&optional ,@vars &rest ,ignore)
  44                                   (declare (ignore ,ignore))
  45                                   ,@body)
  46                               ,value-form)))
  47     (error "Vars is not a list of symbols: ~S" vars)))
  48
  49 (defmacro-mundanely multiple-value-setq (vars value-form)
  50   (cond ((null vars)
  51          ;; The ANSI spec says that the primary value of VALUE-FORM must be
  52          ;; returned. The general-case-handling code below doesn't do this
  53          ;; correctly in the special case when there are no vars bound, so we
  54          ;; handle this special case separately here.
  55          (let ((g (gensym)))
  56            `(multiple-value-bind (,g) ,value-form
  57               ,g)))
  58         ((list-of-symbols-p vars)
  59          (let ((temps (make-gensym-list (length vars))))
  60            `(multiple-value-bind ,temps ,value-form
  61               ,@(mapcar #'(lambda (var temp)
  62                             `(setq ,var ,temp))
  63                         vars temps)
  64               ,(car temps))))
  65         (t (error "Vars is not a list of symbols: ~S" vars))))
  66
  67 (defmacro-mundanely multiple-value-list (value-form)
  68   `(multiple-value-call #'list ,value-form))
  69 \f
  70 ;;;; various conditional constructs
  71
  72 ;;; COND defined in terms of IF
  73 (defmacro-mundanely cond (&rest clauses)
  74   (if (endp clauses)
  75     nil
  76     (let ((clause (first clauses)))
  77       (if (atom clause)
  78         (error "Cond clause is not a list: ~S" clause)
  79         (let ((test (first clause))
  80               (forms (rest clause)))
  81           (if (endp forms)
  82             (let ((n-result (gensym)))
  83               `(let ((,n-result ,test))
  84                  (if ,n-result
  85                    ,n-result
  86                    (cond ,@(rest clauses)))))
  87             `(if ,test
  88                (progn ,@forms)
  89                (cond ,@(rest clauses)))))))))
  90
  91 ;;; other things defined in terms of COND
  92 (defmacro-mundanely when (test &body forms)
  93   #!+sb-doc
  94   "If the first argument is true, the rest of the forms are
  95   evaluated as a PROGN."
  96   `(cond (,test nil ,@forms)))
  97 (defmacro-mundanely unless (test &body forms)
  98   #!+sb-doc
  99   "If the first argument is not true, the rest of the forms are
 100   evaluated as a PROGN."
 101   `(cond ((not ,test) nil ,@forms)))
 102 (defmacro-mundanely and (&rest forms)
 103   (cond ((endp forms) t)
 104         ((endp (rest forms)) (first forms))
 105         (t
 106          `(if ,(first forms)
 107               (and ,@(rest forms))
 108               nil))))
 109 (defmacro-mundanely or (&rest forms)
 110   (cond ((endp forms) nil)
 111         ((endp (rest forms)) (first forms))
 112         (t
 113          (let ((n-result (gensym)))
 114            `(let ((,n-result ,(first forms)))
 115               (if ,n-result
 116                   ,n-result
 117                   (or ,@(rest forms))))))))
 118 \f
 119 ;;;; various sequencing constructs
 120
 121 (defmacro-mundanely prog (varlist &body body-decls)
 122   (multiple-value-bind (body decls) (parse-body body-decls nil)
 123     `(block nil
 124        (let ,varlist
 125          ,@decls
 126          (tagbody ,@body)))))
 127
 128 (defmacro-mundanely prog* (varlist &body body-decls)
 129   (multiple-value-bind (body decls) (parse-body body-decls nil)
 130     `(block nil
 131        (let* ,varlist
 132          ,@decls
 133          (tagbody ,@body)))))
 134
 135 (defmacro-mundanely prog1 (result &body body)
 136   (let ((n-result (gensym)))
 137     `(let ((,n-result ,result))
 138        ,@body
 139        ,n-result)))
 140
 141 (defmacro-mundanely prog2 (form1 result &body body)
 142   `(prog1 (progn ,form1 ,result) ,@body))
 143 \f
 144 ;;; Now that we have the definition of MULTIPLE-VALUE-BIND, we can make a
 145 ;;; reasonably readable definition of DEFUN.
 146 ;;;
 147 ;;; DEFUN expands into %DEFUN which is a function that is treated
 148 ;;; magically by the compiler (through an IR1 transform) in order to
 149 ;;; handle stuff like inlining. After the compiler has gotten the
 150 ;;; information it wants out of macro definition, it compiles a call
 151 ;;; to %%DEFUN which happens at load time.
 152 (defmacro-mundanely defun (&whole whole name args &body body)
 153   (multiple-value-bind (forms decls doc) (parse-body body)
 154     (let ((def `(lambda ,args
 155                   ,@decls
 156                   (block ,(function-name-block-name name)
 157                     ,@forms))))
 158       `(sb!c::%defun ',name #',def ,doc ',whole))))
 159 #+sb-xc-host (/show "before PROCLAIM" (sb!c::info :function :kind 'sb!c::%%defun))
 160 #+sb-xc-host (sb!xc:proclaim '(ftype function sb!c::%%defun)) ; to avoid
 161                                         ; undefined function warnings
 162 #+sb-xc-host (/show "after PROCLAIM" (sb!c::info :function :kind 'sb!c::%%defun))
 163 (defun sb!c::%%defun (name def doc &optional inline-expansion)
 164   (when (fboundp name)
 165     (style-warn "redefining ~S in DEFUN" name))
 166   (setf (sb!xc:fdefinition name) def)
 167   (when doc
 168     ;; FIXME: This should use shared SETF-name parsing logic.
 169     (if (and (consp name) (eq (first name) 'setf))
 170         (setf (fdocumentation (second name) 'setf) doc)
 171         (setf (fdocumentation name 'function) doc)))
 172   (become-defined-function-name name)
 173   (when (or inline-expansion
 174             (info :function :inline-expansion name))
 175     (setf (info :function :inline-expansion name)
 176           inline-expansion))
 177   name)
 178 ;;; Ordinarily this definition of SB!C:%DEFUN as an ordinary function is not
 179 ;;; used: the parallel (but different) definition as an IR1 transform takes
 180 ;;; precedence. However, it's still good to define this in order to keep the
 181 ;;; interpreter happy. We define it here (instead of alongside the parallel
 182 ;;; IR1 transform) because while the IR1 transform is needed and appropriate
 183 ;;; in the cross-compiler running in the host Common Lisp, this parallel
 184 ;;; ordinary function definition is only appropriate in the target Lisp.
 185 (defun sb!c::%defun (name def doc source)
 186   (declare (ignore source))
 187   (setf (sb!eval:interpreted-function-name def) name)
 188   (ecase (info :function :where-from name)
 189     (:assumed
 190       (setf (info :function :where-from name) :defined)
 191       (setf (info :function :type name)
 192               (extract-function-type def))
 193       (when (info :function :assumed-type name)
 194         (setf (info :function :assumed-type name) nil)))
 195     (:declared)
 196     (:defined
 197      (setf (info :function :type name)
 198            (extract-function-type def))
 199      ;; We shouldn't need to clear this here because it should be clear
 200      ;; already (cleared when the last definition was processed).
 201      (aver (null (info :function :assumed-type name)))))
 202   (sb!c::%%defun name def doc))
 203 \f
 204 ;;;; DEFVAR and DEFPARAMETER
 205
 206 (defmacro-mundanely defvar (var &optional (val nil valp) (doc nil docp))
 207   #!+sb-doc
 208   "For defining global variables at top level. Declares the variable
 209   SPECIAL and, optionally, initializes it. If the variable already has a
 210   value, the old value is not clobbered. The third argument is an optional
 211   documentation string for the variable."
 212   `(progn
 213      (declaim (special ,var))
 214      ,@(when valp
 215          `((unless (boundp ',var)
 216              (setq ,var ,val))))
 217      ,@(when docp
 218          `((funcall #'(setf fdocumentation) ',doc ',var 'variable)))
 219      ',var))
 220
 221 (defmacro-mundanely defparameter (var val &optional (doc nil docp))
 222   #!+sb-doc
 223   "Defines a parameter that is not normally changed by the program,
 224   but that may be changed without causing an error. Declares the
 225   variable special and sets its value to VAL. The third argument is
 226   an optional documentation string for the parameter."
 227   `(progn
 228      (declaim (special ,var))
 229      (setq ,var ,val)
 230      ,@(when docp
 231          ;; FIXME: The various FUNCALL #'(SETF FDOCUMENTATION) and
 232          ;; other FUNCALL #'(SETF FOO) forms in the code should
 233          ;; unbogobootstrapized back to ordinary SETF forms.
 234          `((funcall #'(setf fdocumentation) ',doc ',var 'variable)))
 235      ',var))
 236 \f
 237 ;;;; iteration constructs
 238
 239 ;;; (These macros are defined in terms of a function DO-DO-BODY which is also
 240 ;;; used by SB!INT:DO-ANONYMOUS. Since these macros should not be loaded
 241 ;;; on the cross-compilation host, but SB!INT:DO-ANONYMOUS and DO-DO-BODY
 242 ;;; should be, these macros can't conveniently be in the same file as
 243 ;;; DO-DO-BODY.)
 244 (defmacro-mundanely do (varlist endlist &body body)
 245   #!+sb-doc
 246   "DO ({(Var [Init] [Step])}*) (Test Exit-Form*) Declaration* Form*
 247   Iteration construct. Each Var is initialized in parallel to the value of the
 248   specified Init form. On subsequent iterations, the Vars are assigned the
 249   value of the Step form (if any) in parallel. The Test is evaluated before
 250   each evaluation of the body Forms. When the Test is true, the Exit-Forms
 251   are evaluated as a PROGN, with the result being the value of the DO. A block
 252   named NIL is established around the entire expansion, allowing RETURN to be
 253   used as an alternate exit mechanism."
 254   (do-do-body varlist endlist body 'let 'psetq 'do nil))
 255 (defmacro-mundanely do* (varlist endlist &body body)
 256   #!+sb-doc
 257   "DO* ({(Var [Init] [Step])}*) (Test Exit-Form*) Declaration* Form*
 258   Iteration construct. Each Var is initialized sequentially (like LET*) to the
 259   value of the specified Init form. On subsequent iterations, the Vars are
 260   sequentially assigned the value of the Step form (if any). The Test is
 261   evaluated before each evaluation of the body Forms. When the Test is true,
 262   the Exit-Forms are evaluated as a PROGN, with the result being the value
 263   of the DO. A block named NIL is established around the entire expansion,
 264   allowing RETURN to be used as an laternate exit mechanism."
 265   (do-do-body varlist endlist body 'let* 'setq 'do* nil))
 266
 267 ;;; DOTIMES and DOLIST could be defined more concisely using destructuring
 268 ;;; macro lambda lists or DESTRUCTURING-BIND, but then it'd be tricky to use
 269 ;;; them before those things were defined. They're used enough times before
 270 ;;; destructuring mechanisms are defined that it looks as though it's worth
 271 ;;; just implementing them ASAP, at the cost of being unable to use the
 272 ;;; standard destructuring mechanisms.
 273 (defmacro-mundanely dotimes (var-count-result &body body)
 274   (multiple-value-bind ; to roll our own destructuring
 275       (var count result)
 276       (apply (lambda (var count &optional (result nil))
 277                (values var count result))
 278              var-count-result)
 279     (cond ((numberp count)
 280            `(do ((,var 0 (1+ ,var)))
 281                 ((>= ,var ,count) ,result)
 282               (declare (type unsigned-byte ,var))
 283               ,@body))
 284           (t (let ((v1 (gensym)))
 285                `(do ((,var 0 (1+ ,var)) (,v1 ,count))
 286                     ((>= ,var ,v1) ,result)
 287                   (declare (type unsigned-byte ,var))
 288                   ,@body))))))
 289 (defmacro-mundanely dolist (var-list-result &body body)
 290   (multiple-value-bind ; to roll our own destructuring
 291       (var list result)
 292       (apply (lambda (var list &optional (result nil))
 293                (values var list result))
 294              var-list-result)
 295     ;; We repeatedly bind the var instead of setting it so that we never have
 296     ;; to give the var an arbitrary value such as NIL (which might conflict
 297     ;; with a declaration). If there is a result form, we introduce a
 298     ;; gratuitous binding of the variable to NIL w/o the declarations, then
 299     ;; evaluate the result form in that environment. We spuriously reference
 300     ;; the gratuitous variable, since we don't want to use IGNORABLE on what
 301     ;; might be a special var.
 302     (let ((n-list (gensym)))
 303       `(do ((,n-list ,list (cdr ,n-list)))
 304            ((endp ,n-list)
 305             ,@(if result
 306                 `((let ((,var nil))
 307                     ,var
 308                     ,result))
 309                 '(nil)))
 310          (let ((,var (car ,n-list)))
 311            ,@body)))))
 312 \f
 313 ;;;; miscellaneous
 314
 315 (defmacro-mundanely return (&optional (value nil))
 316   `(return-from nil ,value))
 317
 318 (defmacro-mundanely psetq (&rest pairs)
 319   #!+sb-doc
 320   "SETQ {var value}*
 321    Set the variables to the values, like SETQ, except that assignments
 322    happen in parallel, i.e. no assignments take place until all the
 323    forms have been evaluated."
 324   ;; (This macro is used in the definition of DO, so we can't use DO in the
 325   ;; definition of this macro without getting into confusing bootstrap issues.)
 326   (prog ((lets nil)
 327          (setqs nil)
 328          (pairs pairs))
 329     :again
 330     (when (atom (cdr pairs))
 331       (return `(let ,(nreverse lets)
 332                  (setq ,@(nreverse setqs))
 333                  nil)))
 334     (let ((gen (gensym)))
 335       (setq lets (cons `(,gen ,(cadr pairs)) lets)
 336             setqs (list* gen (car pairs) setqs)
 337             pairs (cddr pairs)))
 338     (go :again)))
 339
 340 (defmacro-mundanely lambda (&whole whole args &body body)
 341   (declare (ignore args body))
 342   `#',whole)