src/code/defboot.lisp

   1 ;;;; bootstrapping fundamental machinery (e.g. DEFUN, DEFCONSTANT,
   2 ;;;; DEFVAR) from special forms and primitive functions
   3 ;;;;
   4 ;;;; KLUDGE: The bootstrapping aspect of this is now obsolete. It was
   5 ;;;; originally intended that this file file would be loaded into a
   6 ;;;; Lisp image which had Common Lisp primitives defined, and DEFMACRO
   7 ;;;; defined, and little else. Since then that approach has been
   8 ;;;; dropped and this file has been modified somewhat to make it work
   9 ;;;; more cleanly when used to predefine macros at
  10 ;;;; build-the-cross-compiler time.
  11
  12 ;;;; This software is part of the SBCL system. See the README file for
  13 ;;;; more information.
  14 ;;;;
  15 ;;;; This software is derived from the CMU CL system, which was
  16 ;;;; written at Carnegie Mellon University and released into the
  17 ;;;; public domain. The software is in the public domain and is
  18 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  19 ;;;; files for more information.
  20
  21 (in-package "SB!IMPL")
  22 \f
  23 ;;;; IN-PACKAGE
  24
  25 (defmacro-mundanely in-package (package-designator)
  26   `(eval-when (:compile-toplevel :load-toplevel :execute)
  27      (setq *package* (find-undeleted-package-or-lose ',package-designator))))
  28 \f
  29 ;;;; MULTIPLE-VALUE-FOO
  30
  31 (defun list-of-symbols-p (x)
  32   (and (listp x)
  33        (every #'symbolp x)))
  34
  35 (defmacro-mundanely multiple-value-bind (vars value-form &body body)
  36   (if (list-of-symbols-p vars)
  37     ;; It's unclear why it would be important to special-case the LENGTH=1 case
  38     ;; at this level, but the CMU CL code did it, so.. -- WHN 19990411
  39     (if (= (length vars) 1)
  40       `(let ((,(car vars) ,value-form))
  41          ,@body)
  42       (let ((ignore (gensym)))
  43         `(multiple-value-call #'(lambda (&optional ,@vars &rest ,ignore)
  44                                   (declare (ignore ,ignore))
  45                                   ,@body)
  46                               ,value-form)))
  47     (error "Vars is not a list of symbols: ~S" vars)))
  48
  49 (defmacro-mundanely multiple-value-setq (vars value-form)
  50   (cond ((null vars)
  51          ;; The ANSI spec says that the primary value of VALUE-FORM must be
  52          ;; returned. The general-case-handling code below doesn't do this
  53          ;; correctly in the special case when there are no vars bound, so we
  54          ;; handle this special case separately here.
  55          (let ((g (gensym)))
  56            `(multiple-value-bind (,g) ,value-form
  57               ,g)))
  58         ((list-of-symbols-p vars)
  59          (let ((temps (make-gensym-list (length vars))))
  60            `(multiple-value-bind ,temps ,value-form
  61               ,@(mapcar #'(lambda (var temp)
  62                             `(setq ,var ,temp))
  63                         vars temps)
  64               ,(car temps))))
  65         (t (error "Vars is not a list of symbols: ~S" vars))))
  66
  67 (defmacro-mundanely multiple-value-list (value-form)
  68   `(multiple-value-call #'list ,value-form))
  69 \f
  70 ;;;; various conditional constructs
  71
  72 ;;; COND defined in terms of IF
  73 (defmacro-mundanely cond (&rest clauses)
  74   (if (endp clauses)
  75     nil
  76     (let ((clause (first clauses)))
  77       (if (atom clause)
  78         (error "Cond clause is not a list: ~S" clause)
  79         (let ((test (first clause))
  80               (forms (rest clause)))
  81           (if (endp forms)
  82             (let ((n-result (gensym)))
  83               `(let ((,n-result ,test))
  84                  (if ,n-result
  85                    ,n-result
  86                    (cond ,@(rest clauses)))))
  87             `(if ,test
  88                (progn ,@forms)
  89                (cond ,@(rest clauses)))))))))
  90
  91 ;;; other things defined in terms of COND
  92 (defmacro-mundanely when (test &body forms)
  93   #!+sb-doc
  94   "If the first argument is true, the rest of the forms are
  95   evaluated as a PROGN."
  96   `(cond (,test nil ,@forms)))
  97 (defmacro-mundanely unless (test &body forms)
  98   #!+sb-doc
  99   "If the first argument is not true, the rest of the forms are
 100   evaluated as a PROGN."
 101   `(cond ((not ,test) nil ,@forms)))
 102 (defmacro-mundanely and (&rest forms)
 103   (cond ((endp forms) t)
 104         ((endp (rest forms)) (first forms))
 105         (t
 106          `(if ,(first forms)
 107               (and ,@(rest forms))
 108               nil))))
 109 (defmacro-mundanely or (&rest forms)
 110   (cond ((endp forms) nil)
 111         ((endp (rest forms)) (first forms))
 112         (t
 113          (let ((n-result (gensym)))
 114            `(let ((,n-result ,(first forms)))
 115               (if ,n-result
 116                   ,n-result
 117                   (or ,@(rest forms))))))))
 118 \f
 119 ;;;; various sequencing constructs
 120
 121 (defmacro-mundanely prog (varlist &body body-decls)
 122   (multiple-value-bind (body decls) (parse-body body-decls nil)
 123     `(block nil
 124        (let ,varlist
 125          ,@decls
 126          (tagbody ,@body)))))
 127
 128 (defmacro-mundanely prog* (varlist &body body-decls)
 129   (multiple-value-bind (body decls) (parse-body body-decls nil)
 130     `(block nil
 131        (let* ,varlist
 132          ,@decls
 133          (tagbody ,@body)))))
 134
 135 (defmacro-mundanely prog1 (result &body body)
 136   (let ((n-result (gensym)))
 137     `(let ((,n-result ,result))
 138        ,@body
 139        ,n-result)))
 140
 141 (defmacro-mundanely prog2 (form1 result &body body)
 142   `(prog1 (progn ,form1 ,result) ,@body))
 143 \f
 144 ;;;; DEFUN
 145
 146 ;;; Should we save the inline expansion of the function named NAME?
 147 (defun inline-fun-name-p (name)
 148   (or
 149    ;; the normal reason for saving the inline expansion
 150    (info :function :inlinep name)
 151    ;; another reason for saving the inline expansion: If the
 152    ;; ANSI-recommended idiom
 153    ;;   (DECLAIM (INLINE FOO))
 154    ;;   (DEFUN FOO ..)
 155    ;;   (DECLAIM (NOTINLINE FOO))
 156    ;; has been used, and then we later do another
 157    ;;   (DEFUN FOO ..)
 158    ;; without a preceding
 159    ;;   (DECLAIM (INLINE FOO))
 160    ;; what should we do with the old inline expansion when we see the
 161    ;; new DEFUN? Overwriting it with the new definition seems like
 162    ;; the only unsurprising choice.
 163    (info :function :inline-expansion-designator name)))
 164
 165 ;;; Now that we have the definition of MULTIPLE-VALUE-BIND, we can
 166 ;;; make a reasonably readable definition of DEFUN.
 167 (defmacro-mundanely defun (&environment env name args &body body)
 168   "Define a function at top level."
 169   #+sb-xc-host
 170   (unless (symbol-package (fun-name-block-name name))
 171     (warn "DEFUN of uninterned symbol ~S (tricky for GENESIS)" name))
 172   (multiple-value-bind (forms decls doc) (parse-body body)
 173     (let* (;; stuff shared between LAMBDA and INLINE-LAMBDA and NAMED-LAMBDA
 174            (lambda-guts `(,args
 175                           ,@decls
 176                           (block ,(fun-name-block-name name)
 177                             ,@forms)))
 178            (lambda `(lambda ,@lambda-guts))
 179            (named-lambda `(named-lambda ,name ,@lambda-guts))
 180            (inline-lambda
 181             (cond (;; Does the user not even want to inline?
 182                    (not (inline-fun-name-p name))
 183                    nil)
 184                   (;; Does inlining look too hairy to handle?
 185                    (not (sb!c:lambda-independent-of-lexenv-p lambda env))
 186                    (sb!c:maybe-compiler-note
 187                     "lexical environment too hairy, can't inline DEFUN ~S"
 188                     name)
 189                    nil)
 190                   (t
 191                    ;; FIXME: The only reason that we return
 192                    ;; LAMBDA-WITH-LEXENV instead of returning bare
 193                    ;; LAMBDA is to avoid modifying downstream code
 194                    ;; which expects LAMBDA-WITH-LEXENV. But the code
 195                    ;; here is the only code which feeds into the
 196                    ;; downstream code, and the generality of the
 197                    ;; interface is no longer used, so it'd make sense
 198                    ;; to simplify the interface instead of using the
 199                    ;; old general LAMBDA-WITH-LEXENV interface in this
 200                    ;; simplified way.
 201                    `(sb!c:lambda-with-lexenv
 202                      nil nil nil ; i.e. no DECLS, no MACROS, no SYMMACS
 203                      ,@lambda-guts)))))
 204       `(progn
 205
 206          ;; In cross-compilation of toplevel DEFUNs, we arrange
 207          ;; for the LAMBDA to be statically linked by GENESIS.
 208          ;;
 209          ;; It may seem strangely inconsistent not to use NAMED-LAMBDA
 210          ;; here instead of LAMBDA. The reason is historical:
 211          ;; COLD-FSET was written before NAMED-LAMBDA, and has special
 212          ;; logic of its own to notify the compiler about NAME.
 213          #+sb-xc-host
 214          (cold-fset ,name ,lambda)
 215
 216          (eval-when (:compile-toplevel :load-toplevel :execute)
 217            (sb!c:%compiler-defun ',name ',inline-lambda))
 218
 219          (%defun ',name
 220                  ;; In normal compilation (not for cold load) this is
 221                  ;; where the compiled LAMBDA first appears. In
 222                  ;; cross-compilation, we manipulate the
 223                  ;; previously-statically-linked LAMBDA here.
 224                  #-sb-xc-host ,named-lambda
 225                  #+sb-xc-host (fdefinition ',name)
 226                  ,doc)))))
 227 #-sb-xc-host
 228 (defun %defun (name def doc)
 229   (declare (type function def))
 230   (declare (type (or null simple-string doc)))
 231   (aver (legal-fun-name-p name))
 232   (when (fboundp name)
 233     (/show0 "redefining NAME in %DEFUN")
 234     (style-warn "redefining ~S in DEFUN" name))
 235   (setf (sb!xc:fdefinition name) def)
 236
 237   ;; FIXME: I want to do this here (and fix bug 137), but until the
 238   ;; breathtaking CMU CL function name architecture is converted into
 239   ;; something sane, (1) doing so doesn't really fix the bug, and
 240   ;; (2) doing probably isn't even really safe.
 241   #+nil (setf (%fun-name def) name)
 242
 243   (when doc
 244     ;; FIXME: This should use shared SETF-name-parsing logic.
 245     (if (and (consp name) (eq (first name) 'setf))
 246         (setf (fdocumentation (second name) 'setf) doc)
 247         (setf (fdocumentation (the symbol name) 'function) doc)))
 248   name)
 249 \f
 250 ;;;; DEFVAR and DEFPARAMETER
 251
 252 (defmacro-mundanely defvar (var &optional (val nil valp) (doc nil docp))
 253   #!+sb-doc
 254   "Define a global variable at top level. Declare the variable
 255   SPECIAL and, optionally, initialize it. If the variable already has a
 256   value, the old value is not clobbered. The third argument is an optional
 257   documentation string for the variable."
 258   `(progn
 259      (declaim (special ,var))
 260      ,@(when valp
 261          `((unless (boundp ',var)
 262              (setq ,var ,val))))
 263      ,@(when docp
 264          `((funcall #'(setf fdocumentation) ',doc ',var 'variable)))
 265      ',var))
 266
 267 (defmacro-mundanely defparameter (var val &optional (doc nil docp))
 268   #!+sb-doc
 269   "Define a parameter that is not normally changed by the program,
 270   but that may be changed without causing an error. Declare the
 271   variable special and sets its value to VAL, overwriting any
 272   previous value. The third argument is an optional documentation
 273   string for the parameter."
 274   `(progn
 275      (declaim (special ,var))
 276      (setq ,var ,val)
 277      ,@(when docp
 278          ;; FIXME: The various FUNCALL #'(SETF FDOCUMENTATION) and
 279          ;; other FUNCALL #'(SETF FOO) forms in the code should
 280          ;; unbogobootstrapized back to ordinary SETF forms.
 281          `((funcall #'(setf fdocumentation) ',doc ',var 'variable)))
 282      ',var))
 283 \f
 284 ;;;; iteration constructs
 285
 286 ;;; (These macros are defined in terms of a function DO-DO-BODY which
 287 ;;; is also used by SB!INT:DO-ANONYMOUS. Since these macros should not
 288 ;;; be loaded on the cross-compilation host, but SB!INT:DO-ANONYMOUS
 289 ;;; and DO-DO-BODY should be, these macros can't conveniently be in
 290 ;;; the same file as DO-DO-BODY.)
 291 (defmacro-mundanely do (varlist endlist &body body)
 292   #!+sb-doc
 293   "DO ({(Var [Init] [Step])}*) (Test Exit-Form*) Declaration* Form*
 294   Iteration construct. Each Var is initialized in parallel to the value of the
 295   specified Init form. On subsequent iterations, the Vars are assigned the
 296   value of the Step form (if any) in parallel. The Test is evaluated before
 297   each evaluation of the body Forms. When the Test is true, the Exit-Forms
 298   are evaluated as a PROGN, with the result being the value of the DO. A block
 299   named NIL is established around the entire expansion, allowing RETURN to be
 300   used as an alternate exit mechanism."
 301   (do-do-body varlist endlist body 'let 'psetq 'do nil))
 302 (defmacro-mundanely do* (varlist endlist &body body)
 303   #!+sb-doc
 304   "DO* ({(Var [Init] [Step])}*) (Test Exit-Form*) Declaration* Form*
 305   Iteration construct. Each Var is initialized sequentially (like LET*) to the
 306   value of the specified Init form. On subsequent iterations, the Vars are
 307   sequentially assigned the value of the Step form (if any). The Test is
 308   evaluated before each evaluation of the body Forms. When the Test is true,
 309   the Exit-Forms are evaluated as a PROGN, with the result being the value
 310   of the DO. A block named NIL is established around the entire expansion,
 311   allowing RETURN to be used as an laternate exit mechanism."
 312   (do-do-body varlist endlist body 'let* 'setq 'do* nil))
 313
 314 ;;; DOTIMES and DOLIST could be defined more concisely using
 315 ;;; destructuring macro lambda lists or DESTRUCTURING-BIND, but then
 316 ;;; it'd be tricky to use them before those things were defined.
 317 ;;; They're used enough times before destructuring mechanisms are
 318 ;;; defined that it looks as though it's worth just implementing them
 319 ;;; ASAP, at the cost of being unable to use the standard
 320 ;;; destructuring mechanisms.
 321 (defmacro-mundanely dotimes (var-count-result &body body)
 322   (multiple-value-bind ; to roll our own destructuring
 323       (var count result)
 324       (apply (lambda (var count &optional (result nil))
 325                (values var count result))
 326              var-count-result)
 327     (cond ((numberp count)
 328            `(do ((,var 0 (1+ ,var)))
 329                 ((>= ,var ,count) ,result)
 330               (declare (type unsigned-byte ,var))
 331               ,@body))
 332           (t (let ((v1 (gensym)))
 333                `(do ((,var 0 (1+ ,var)) (,v1 ,count))
 334                     ((>= ,var ,v1) ,result)
 335                   (declare (type unsigned-byte ,var))
 336                   ,@body))))))
 337 (defmacro-mundanely dolist (var-list-result &body body)
 338   (multiple-value-bind ; to roll our own destructuring
 339       (var list result)
 340       (apply (lambda (var list &optional (result nil))
 341                (values var list result))
 342              var-list-result)
 343     ;; We repeatedly bind the var instead of setting it so that we
 344     ;; never have to give the var an arbitrary value such as NIL
 345     ;; (which might conflict with a declaration). If there is a result
 346     ;; form, we introduce a gratuitous binding of the variable to NIL
 347     ;; without the declarations, then evaluate the result form in that
 348     ;; environment. We spuriously reference the gratuitous variable,
 349     ;; since since we don't want to use IGNORABLE on what might be a
 350     ;; special var.
 351     (let ((n-list (gensym)))
 352       `(do ((,n-list ,list (cdr ,n-list)))
 353            ((endp ,n-list)
 354             ,@(if result
 355                 `((let ((,var nil))
 356                     ,var
 357                     ,result))
 358                 '(nil)))
 359          (let ((,var (car ,n-list)))
 360            ,@body)))))
 361 \f
 362 ;;;; miscellaneous
 363
 364 (defmacro-mundanely return (&optional (value nil))
 365   `(return-from nil ,value))
 366
 367 (defmacro-mundanely psetq (&rest pairs)
 368   #!+sb-doc
 369   "SETQ {var value}*
 370    Set the variables to the values, like SETQ, except that assignments
 371    happen in parallel, i.e. no assignments take place until all the
 372    forms have been evaluated."
 373   ;; (This macro is used in the definition of DO, so we can't use DO in the
 374   ;; definition of this macro without getting into confusing bootstrap issues.)
 375   (prog ((lets nil)
 376          (setqs nil)
 377          (pairs pairs))
 378     :again
 379     (when (atom (cdr pairs))
 380       (return `(let ,(nreverse lets)
 381                  (setq ,@(nreverse setqs))
 382                  nil)))
 383     (let ((gen (gensym)))
 384       (setq lets (cons `(,gen ,(cadr pairs)) lets)
 385             setqs (list* gen (car pairs) setqs)
 386             pairs (cddr pairs)))
 387     (go :again)))
 388
 389 (defmacro-mundanely lambda (&whole whole args &body body)
 390   (declare (ignore args body))
 391   `#',whole)