src/code/defboot.lisp

   1 ;;;; bootstrapping fundamental machinery (e.g. DEFUN, DEFCONSTANT,
   2 ;;;; DEFVAR) from special forms and primitive functions
   3 ;;;;
   4 ;;;; KLUDGE: The bootstrapping aspect of this is now obsolete. It was
   5 ;;;; originally intended that this file file would be loaded into a
   6 ;;;; Lisp image which had Common Lisp primitives defined, and DEFMACRO
   7 ;;;; defined, and little else. Since then that approach has been
   8 ;;;; dropped and this file has been modified somewhat to make it work
   9 ;;;; more cleanly when used to predefine macros at
  10 ;;;; build-the-cross-compiler time.
  11
  12 ;;;; This software is part of the SBCL system. See the README file for
  13 ;;;; more information.
  14 ;;;;
  15 ;;;; This software is derived from the CMU CL system, which was
  16 ;;;; written at Carnegie Mellon University and released into the
  17 ;;;; public domain. The software is in the public domain and is
  18 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  19 ;;;; files for more information.
  20
  21 (in-package "SB!IMPL")
  22 \f
  23 ;;;; IN-PACKAGE
  24
  25 (defmacro-mundanely in-package (package-designator)
  26   `(eval-when (:compile-toplevel :load-toplevel :execute)
  27      (setq *package* (find-undeleted-package-or-lose ',package-designator))))
  28 \f
  29 ;;;; MULTIPLE-VALUE-FOO
  30
  31 (defun list-of-symbols-p (x)
  32   (and (listp x)
  33        (every #'symbolp x)))
  34
  35 (defmacro-mundanely multiple-value-bind (vars value-form &body body)
  36   (if (list-of-symbols-p vars)
  37     ;; It's unclear why it would be important to special-case the LENGTH=1 case
  38     ;; at this level, but the CMU CL code did it, so.. -- WHN 19990411
  39     (if (= (length vars) 1)
  40       `(let ((,(car vars) ,value-form))
  41          ,@body)
  42       (let ((ignore (gensym)))
  43         `(multiple-value-call #'(lambda (&optional ,@vars &rest ,ignore)
  44                                   (declare (ignore ,ignore))
  45                                   ,@body)
  46                               ,value-form)))
  47     (error "Vars is not a list of symbols: ~S" vars)))
  48
  49 (defmacro-mundanely multiple-value-setq (vars value-form)
  50   (cond ((null vars)
  51          ;; The ANSI spec says that the primary value of VALUE-FORM must be
  52          ;; returned. The general-case-handling code below doesn't do this
  53          ;; correctly in the special case when there are no vars bound, so we
  54          ;; handle this special case separately here.
  55          (let ((g (gensym)))
  56            `(multiple-value-bind (,g) ,value-form
  57               ,g)))
  58         ((list-of-symbols-p vars)
  59          (let ((temps (make-gensym-list (length vars))))
  60            `(multiple-value-bind ,temps ,value-form
  61               ,@(mapcar #'(lambda (var temp)
  62                             `(setq ,var ,temp))
  63                         vars temps)
  64               ,(car temps))))
  65         (t (error "Vars is not a list of symbols: ~S" vars))))
  66
  67 (defmacro-mundanely multiple-value-list (value-form)
  68   `(multiple-value-call #'list ,value-form))
  69 \f
  70 ;;;; various conditional constructs
  71
  72 ;;; COND defined in terms of IF
  73 (defmacro-mundanely cond (&rest clauses)
  74   (if (endp clauses)
  75     nil
  76     (let ((clause (first clauses)))
  77       (if (atom clause)
  78         (error "Cond clause is not a list: ~S" clause)
  79         (let ((test (first clause))
  80               (forms (rest clause)))
  81           (if (endp forms)
  82             (let ((n-result (gensym)))
  83               `(let ((,n-result ,test))
  84                  (if ,n-result
  85                    ,n-result
  86                    (cond ,@(rest clauses)))))
  87             `(if ,test
  88                (progn ,@forms)
  89                (cond ,@(rest clauses)))))))))
  90
  91 ;;; other things defined in terms of COND
  92 (defmacro-mundanely when (test &body forms)
  93   #!+sb-doc
  94   "If the first argument is true, the rest of the forms are
  95   evaluated as a PROGN."
  96   `(cond (,test nil ,@forms)))
  97 (defmacro-mundanely unless (test &body forms)
  98   #!+sb-doc
  99   "If the first argument is not true, the rest of the forms are
 100   evaluated as a PROGN."
 101   `(cond ((not ,test) nil ,@forms)))
 102 (defmacro-mundanely and (&rest forms)
 103   (cond ((endp forms) t)
 104         ((endp (rest forms)) (first forms))
 105         (t
 106          `(if ,(first forms)
 107               (and ,@(rest forms))
 108               nil))))
 109 (defmacro-mundanely or (&rest forms)
 110   (cond ((endp forms) nil)
 111         ((endp (rest forms)) (first forms))
 112         (t
 113          (let ((n-result (gensym)))
 114            `(let ((,n-result ,(first forms)))
 115               (if ,n-result
 116                   ,n-result
 117                   (or ,@(rest forms))))))))
 118 \f
 119 ;;;; various sequencing constructs
 120
 121 (defmacro-mundanely prog (varlist &body body-decls)
 122   (multiple-value-bind (body decls) (parse-body body-decls nil)
 123     `(block nil
 124        (let ,varlist
 125          ,@decls
 126          (tagbody ,@body)))))
 127
 128 (defmacro-mundanely prog* (varlist &body body-decls)
 129   (multiple-value-bind (body decls) (parse-body body-decls nil)
 130     `(block nil
 131        (let* ,varlist
 132          ,@decls
 133          (tagbody ,@body)))))
 134
 135 (defmacro-mundanely prog1 (result &body body)
 136   (let ((n-result (gensym)))
 137     `(let ((,n-result ,result))
 138        ,@body
 139        ,n-result)))
 140
 141 (defmacro-mundanely prog2 (form1 result &body body)
 142   `(prog1 (progn ,form1 ,result) ,@body))
 143 \f
 144 ;;; Now that we have the definition of MULTIPLE-VALUE-BIND, we can make a
 145 ;;; reasonably readable definition of DEFUN.
 146 ;;;
 147 ;;; DEFUN expands into %DEFUN which is a function that is treated
 148 ;;; magically by the compiler (through an IR1 transform) in order to
 149 ;;; handle stuff like inlining. After the compiler has gotten the
 150 ;;; information it wants out of macro definition, it compiles a call
 151 ;;; to %%DEFUN which happens at load time.
 152 (defmacro-mundanely defun (&whole whole name args &body body)
 153   (multiple-value-bind (forms decls doc) (parse-body body)
 154     (let ((def `(lambda ,args
 155                   ,@decls
 156                   (block ,(function-name-block-name name)
 157                     ,@forms))))
 158       `(sb!c::%defun ',name #',def ,doc ',whole))))
 159 #+sb-xc-host (/show "before PROCLAIM" (sb!c::info :function :kind 'sb!c::%%defun))
 160 #+sb-xc-host (sb!xc:proclaim '(ftype function sb!c::%%defun)) ; to avoid
 161                                         ; undefined function warnings
 162 #+sb-xc-host (/show "after PROCLAIM" (sb!c::info :function :kind 'sb!c::%%defun))
 163 (defun sb!c::%%defun (name def doc &optional inline-expansion)
 164   ;; When we're built as a cross-compiler, the DEF is a function
 165   ;; implemented by the cross-compilation host, which is opaque to us.
 166   ;; Similarly, other things like FDEFINITION or DOCUMENTATION either
 167   ;; aren't ours to mess with or are meaningless to mess with. Thus,
 168   ;; we punt.
 169   #+sb-xc-host (declare (ignore def))
 170   #-sb-xc-host
 171   (progn
 172     (when (fboundp name)
 173       (style-warn "redefining ~S in DEFUN" name))
 174     (setf (sb!xc:fdefinition name) def)
 175     (when doc
 176       ;; FIXME: This should use shared SETF-name-parsing logic.
 177       (if (and (consp name) (eq (first name) 'setf))
 178           (setf (fdocumentation (second name) 'setf) doc)
 179           (setf (fdocumentation name 'function) doc))))
 180   ;; Other stuff remains meaningful whether we're cross-compiling or
 181   ;; native compiling.
 182   (become-defined-function-name name)
 183   (when (or inline-expansion
 184             (info :function :inline-expansion name))
 185     (setf (info :function :inline-expansion name)
 186           inline-expansion))
 187   ;; Voila.
 188   name)
 189 ;;; FIXME: Now that the IR1 interpreter is going away and EVAL-WHEN is
 190 ;;; becoming ANSI-compliant, it should be possible to merge this and
 191 ;;; DEF-IR1-TRANSLATOR %DEFUN into a single DEFUN. (And does %%DEFUN
 192 ;;; merge into that too? dunno..)
 193 (defun sb!c::%defun (name def doc source)
 194   (declare (ignore source))
 195   (flet ((set-type-info-from-def ()
 196            (setf (info :function :type name)
 197                  #-sb-xc-host (extract-function-type def)
 198                  ;; When we're built as a cross-compiler, the DEF is
 199                  ;; a function implemented by the cross-compilation
 200                  ;; host, which is opaque to us, so we have to punt here.
 201                  #+sb-xc-host *universal-function-type*)))
 202     (ecase (info :function :where-from name)
 203       (:assumed
 204        (setf (info :function :where-from name) :defined)
 205        (set-type-info-from-def)
 206        (when (info :function :assumed-type name)
 207          (setf (info :function :assumed-type name) nil)))
 208       (:declared)
 209       (:defined
 210        (set-type-info-from-def)
 211        ;; We shouldn't need to clear this here because it should be
 212        ;; clear already (having been cleared when the last definition
 213        ;; was processed).
 214        (aver (null (info :function :assumed-type name))))))
 215   (sb!c::%%defun name def doc))
 216 \f
 217 ;;;; DEFVAR and DEFPARAMETER
 218
 219 (defmacro-mundanely defvar (var &optional (val nil valp) (doc nil docp))
 220   #!+sb-doc
 221   "Define a global variable at top level. Declare the variable
 222   SPECIAL and, optionally, initialize it. If the variable already has a
 223   value, the old value is not clobbered. The third argument is an optional
 224   documentation string for the variable."
 225   `(progn
 226      (declaim (special ,var))
 227      ,@(when valp
 228          `((unless (boundp ',var)
 229              (setq ,var ,val))))
 230      ,@(when docp
 231          `((funcall #'(setf fdocumentation) ',doc ',var 'variable)))
 232      ',var))
 233
 234 (defmacro-mundanely defparameter (var val &optional (doc nil docp))
 235   #!+sb-doc
 236   "Define a parameter that is not normally changed by the program,
 237   but that may be changed without causing an error. Declare the
 238   variable special and sets its value to VAL, overwriting any
 239   previous value. The third argument is an optional documentation
 240   string for the parameter."
 241   `(progn
 242      (declaim (special ,var))
 243      (setq ,var ,val)
 244      ,@(when docp
 245          ;; FIXME: The various FUNCALL #'(SETF FDOCUMENTATION) and
 246          ;; other FUNCALL #'(SETF FOO) forms in the code should
 247          ;; unbogobootstrapized back to ordinary SETF forms.
 248          `((funcall #'(setf fdocumentation) ',doc ',var 'variable)))
 249      ',var))
 250 \f
 251 ;;;; iteration constructs
 252
 253 ;;; (These macros are defined in terms of a function DO-DO-BODY which
 254 ;;; is also used by SB!INT:DO-ANONYMOUS. Since these macros should not
 255 ;;; be loaded on the cross-compilation host, but SB!INT:DO-ANONYMOUS
 256 ;;; and DO-DO-BODY should be, these macros can't conveniently be in
 257 ;;; the same file as DO-DO-BODY.)
 258 (defmacro-mundanely do (varlist endlist &body body)
 259   #!+sb-doc
 260   "DO ({(Var [Init] [Step])}*) (Test Exit-Form*) Declaration* Form*
 261   Iteration construct. Each Var is initialized in parallel to the value of the
 262   specified Init form. On subsequent iterations, the Vars are assigned the
 263   value of the Step form (if any) in parallel. The Test is evaluated before
 264   each evaluation of the body Forms. When the Test is true, the Exit-Forms
 265   are evaluated as a PROGN, with the result being the value of the DO. A block
 266   named NIL is established around the entire expansion, allowing RETURN to be
 267   used as an alternate exit mechanism."
 268   (do-do-body varlist endlist body 'let 'psetq 'do nil))
 269 (defmacro-mundanely do* (varlist endlist &body body)
 270   #!+sb-doc
 271   "DO* ({(Var [Init] [Step])}*) (Test Exit-Form*) Declaration* Form*
 272   Iteration construct. Each Var is initialized sequentially (like LET*) to the
 273   value of the specified Init form. On subsequent iterations, the Vars are
 274   sequentially assigned the value of the Step form (if any). The Test is
 275   evaluated before each evaluation of the body Forms. When the Test is true,
 276   the Exit-Forms are evaluated as a PROGN, with the result being the value
 277   of the DO. A block named NIL is established around the entire expansion,
 278   allowing RETURN to be used as an laternate exit mechanism."
 279   (do-do-body varlist endlist body 'let* 'setq 'do* nil))
 280
 281 ;;; DOTIMES and DOLIST could be defined more concisely using
 282 ;;; destructuring macro lambda lists or DESTRUCTURING-BIND, but then
 283 ;;; it'd be tricky to use them before those things were defined.
 284 ;;; They're used enough times before destructuring mechanisms are
 285 ;;; defined that it looks as though it's worth just implementing them
 286 ;;; ASAP, at the cost of being unable to use the standard
 287 ;;; destructuring mechanisms.
 288 (defmacro-mundanely dotimes (var-count-result &body body)
 289   (multiple-value-bind ; to roll our own destructuring
 290       (var count result)
 291       (apply (lambda (var count &optional (result nil))
 292                (values var count result))
 293              var-count-result)
 294     (cond ((numberp count)
 295            `(do ((,var 0 (1+ ,var)))
 296                 ((>= ,var ,count) ,result)
 297               (declare (type unsigned-byte ,var))
 298               ,@body))
 299           (t (let ((v1 (gensym)))
 300                `(do ((,var 0 (1+ ,var)) (,v1 ,count))
 301                     ((>= ,var ,v1) ,result)
 302                   (declare (type unsigned-byte ,var))
 303                   ,@body))))))
 304 (defmacro-mundanely dolist (var-list-result &body body)
 305   (multiple-value-bind ; to roll our own destructuring
 306       (var list result)
 307       (apply (lambda (var list &optional (result nil))
 308                (values var list result))
 309              var-list-result)
 310     ;; We repeatedly bind the var instead of setting it so that we
 311     ;; never have to give the var an arbitrary value such as NIL
 312     ;; (which might conflict with a declaration). If there is a result
 313     ;; form, we introduce a gratuitous binding of the variable to NIL
 314     ;; without the declarations, then evaluate the result form in that
 315     ;; environment. We spuriously reference the gratuitous variable,
 316     ;; since we don't want to use IGNORABLE on what might be a special
 317     ;; var.
 318     (let ((n-list (gensym)))
 319       `(do ((,n-list ,list (cdr ,n-list)))
 320            ((endp ,n-list)
 321             ,@(if result
 322                 `((let ((,var nil))
 323                     ,var
 324                     ,result))
 325                 '(nil)))
 326          (let ((,var (car ,n-list)))
 327            ,@body)))))
 328 \f
 329 ;;;; miscellaneous
 330
 331 (defmacro-mundanely return (&optional (value nil))
 332   `(return-from nil ,value))
 333
 334 (defmacro-mundanely psetq (&rest pairs)
 335   #!+sb-doc
 336   "SETQ {var value}*
 337    Set the variables to the values, like SETQ, except that assignments
 338    happen in parallel, i.e. no assignments take place until all the
 339    forms have been evaluated."
 340   ;; (This macro is used in the definition of DO, so we can't use DO in the
 341   ;; definition of this macro without getting into confusing bootstrap issues.)
 342   (prog ((lets nil)
 343          (setqs nil)
 344          (pairs pairs))
 345     :again
 346     (when (atom (cdr pairs))
 347       (return `(let ,(nreverse lets)
 348                  (setq ,@(nreverse setqs))
 349                  nil)))
 350     (let ((gen (gensym)))
 351       (setq lets (cons `(,gen ,(cadr pairs)) lets)
 352             setqs (list* gen (car pairs) setqs)
 353             pairs (cddr pairs)))
 354     (go :again)))
 355
 356 (defmacro-mundanely lambda (&whole whole args &body body)
 357   (declare (ignore args body))
 358   `#',whole)