src/code/defboot.lisp

   1 ;;;; bootstrapping fundamental machinery (e.g. DEFUN, DEFCONSTANT,
   2 ;;;; DEFVAR) from special forms and primitive functions
   3 ;;;;
   4 ;;;; KLUDGE: The bootstrapping aspect of this is now obsolete. It was
   5 ;;;; originally intended that this file file would be loaded into a
   6 ;;;; Lisp image which had Common Lisp primitives defined, and DEFMACRO
   7 ;;;; defined, and little else. Since then that approach has been
   8 ;;;; dropped and this file has been modified somewhat to make it work
   9 ;;;; more cleanly when used to predefine macros at
  10 ;;;; build-the-cross-compiler time.
  11
  12 ;;;; This software is part of the SBCL system. See the README file for
  13 ;;;; more information.
  14 ;;;;
  15 ;;;; This software is derived from the CMU CL system, which was
  16 ;;;; written at Carnegie Mellon University and released into the
  17 ;;;; public domain. The software is in the public domain and is
  18 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  19 ;;;; files for more information.
  20
  21 (in-package "SB!IMPL")
  22
  23 \f
  24 ;;;; IN-PACKAGE
  25
  26 (defmacro-mundanely in-package (string-designator)
  27   (let ((string (string string-designator)))
  28     `(eval-when (:compile-toplevel :load-toplevel :execute)
  29        (setq *package* (find-undeleted-package-or-lose ,string)))))
  30 \f
  31 ;;;; MULTIPLE-VALUE-FOO
  32
  33 (defun list-of-symbols-p (x)
  34   (and (listp x)
  35        (every #'symbolp x)))
  36
  37 (defmacro-mundanely multiple-value-bind (vars value-form &body body)
  38   (if (list-of-symbols-p vars)
  39     ;; It's unclear why it would be important to special-case the LENGTH=1 case
  40     ;; at this level, but the CMU CL code did it, so.. -- WHN 19990411
  41     (if (= (length vars) 1)
  42       `(let ((,(car vars) ,value-form))
  43          ,@body)
  44       (let ((ignore (sb!xc:gensym)))
  45         `(multiple-value-call #'(lambda (&optional ,@(mapcar #'list vars)
  46                                          &rest ,ignore)
  47                                   (declare (ignore ,ignore))
  48                                   ,@body)
  49                               ,value-form)))
  50     (error "Vars is not a list of symbols: ~S" vars)))
  51
  52 (defmacro-mundanely multiple-value-setq (vars value-form)
  53   (unless (list-of-symbols-p vars)
  54     (error "Vars is not a list of symbols: ~S" vars))
  55   ;; MULTIPLE-VALUE-SETQ is required to always return just the primary
  56   ;; value of the value-from, even if there are no vars. (SETF VALUES)
  57   ;; in turn is required to return as many values as there are
  58   ;; value-places, hence this:
  59   (if vars
  60       `(values (setf (values ,@vars) ,value-form))
  61       `(values ,value-form)))
  62
  63 (defmacro-mundanely multiple-value-list (value-form)
  64   `(multiple-value-call #'list ,value-form))
  65 \f
  66 ;;;; various conditional constructs
  67
  68 ;;; COND defined in terms of IF
  69 (defmacro-mundanely cond (&rest clauses)
  70   (if (endp clauses)
  71       nil
  72       (let ((clause (first clauses))
  73             (more (rest clauses)))
  74         (if (atom clause)
  75             (error "COND clause is not a list: ~S" clause)
  76             (let ((test (first clause))
  77                   (forms (rest clause)))
  78               (if (endp forms)
  79                   (let ((n-result (gensym)))
  80                     `(let ((,n-result ,test))
  81                        (if ,n-result
  82                            ,n-result
  83                            (cond ,@more))))
  84                   (if (eq t test)
  85                       ;; THE to perserve non-toplevelness for FOO in
  86                       ;;   (COND (T (FOO)))
  87                       `(the t (progn ,@forms))
  88                       `(if ,test
  89                            (progn ,@forms)
  90                            ,(when more `(cond ,@more))))))))))
  91
  92 (defmacro-mundanely when (test &body forms)
  93   #!+sb-doc
  94   "If the first argument is true, the rest of the forms are
  95 evaluated as a PROGN."
  96   `(if ,test (progn ,@forms) nil))
  97
  98 (defmacro-mundanely unless (test &body forms)
  99   #!+sb-doc
 100   "If the first argument is not true, the rest of the forms are
 101 evaluated as a PROGN."
 102   `(if ,test nil (progn ,@forms)))
 103
 104 (defmacro-mundanely and (&rest forms)
 105   (cond ((endp forms) t)
 106         ((endp (rest forms))
 107          ;; Preserve non-toplevelness of the form!
 108          `(the t ,(first forms)))
 109         (t
 110          `(if ,(first forms)
 111               (and ,@(rest forms))
 112               nil))))
 113
 114 (defmacro-mundanely or (&rest forms)
 115   (cond ((endp forms) nil)
 116         ((endp (rest forms))
 117          ;; Preserve non-toplevelness of the form!
 118          `(the t ,(first forms)))
 119         (t
 120          (let ((n-result (gensym)))
 121            `(let ((,n-result ,(first forms)))
 122               (if ,n-result
 123                   ,n-result
 124                   (or ,@(rest forms))))))))
 125 \f
 126 ;;;; various sequencing constructs
 127
 128 (flet ((prog-expansion-from-let (varlist body-decls let)
 129          (multiple-value-bind (body decls)
 130              (parse-body body-decls :doc-string-allowed nil)
 131            `(block nil
 132               (,let ,varlist
 133                 ,@decls
 134                 (tagbody ,@body))))))
 135   (defmacro-mundanely prog (varlist &body body-decls)
 136     (prog-expansion-from-let varlist body-decls 'let))
 137   (defmacro-mundanely prog* (varlist &body body-decls)
 138     (prog-expansion-from-let varlist body-decls 'let*)))
 139
 140 (defmacro-mundanely prog1 (result &body body)
 141   (let ((n-result (gensym)))
 142     `(let ((,n-result ,result))
 143        ,@body
 144        ,n-result)))
 145
 146 (defmacro-mundanely prog2 (form1 result &body body)
 147   `(prog1 (progn ,form1 ,result) ,@body))
 148 \f
 149 ;;;; DEFUN
 150
 151 ;;; Should we save the inline expansion of the function named NAME?
 152 (defun inline-fun-name-p (name)
 153   (or
 154    ;; the normal reason for saving the inline expansion
 155    (info :function :inlinep name)
 156    ;; another reason for saving the inline expansion: If the
 157    ;; ANSI-recommended idiom
 158    ;;   (DECLAIM (INLINE FOO))
 159    ;;   (DEFUN FOO ..)
 160    ;;   (DECLAIM (NOTINLINE FOO))
 161    ;; has been used, and then we later do another
 162    ;;   (DEFUN FOO ..)
 163    ;; without a preceding
 164    ;;   (DECLAIM (INLINE FOO))
 165    ;; what should we do with the old inline expansion when we see the
 166    ;; new DEFUN? Overwriting it with the new definition seems like
 167    ;; the only unsurprising choice.
 168    (info :function :inline-expansion-designator name)))
 169
 170 (defmacro-mundanely defun (&environment env name args &body body)
 171   "Define a function at top level."
 172   #+sb-xc-host
 173   (unless (symbol-package (fun-name-block-name name))
 174     (warn "DEFUN of uninterned function name ~S (tricky for GENESIS)" name))
 175   (multiple-value-bind (forms decls doc) (parse-body body)
 176     (let* (;; stuff shared between LAMBDA and INLINE-LAMBDA and NAMED-LAMBDA
 177            (lambda-guts `(,args
 178                           ,@decls
 179                           (block ,(fun-name-block-name name)
 180                             ,@forms)))
 181            (lambda `(lambda ,@lambda-guts))
 182            #-sb-xc-host
 183            (named-lambda `(named-lambda ,name ,@lambda-guts))
 184            (inline-lambda
 185             (when (inline-fun-name-p name)
 186               ;; we want to attempt to inline, so complain if we can't
 187               (or (sb!c:maybe-inline-syntactic-closure lambda env)
 188                   (progn
 189                     (#+sb-xc-host warn
 190                      #-sb-xc-host sb!c:maybe-compiler-notify
 191                      "lexical environment too hairy, can't inline DEFUN ~S"
 192                      name)
 193                     nil)))))
 194       `(progn
 195          ;; In cross-compilation of toplevel DEFUNs, we arrange for
 196          ;; the LAMBDA to be statically linked by GENESIS.
 197          ;;
 198          ;; It may seem strangely inconsistent not to use NAMED-LAMBDA
 199          ;; here instead of LAMBDA. The reason is historical:
 200          ;; COLD-FSET was written before NAMED-LAMBDA, and has special
 201          ;; logic of its own to notify the compiler about NAME.
 202          #+sb-xc-host
 203          (cold-fset ,name ,lambda)
 204
 205          (eval-when (:compile-toplevel)
 206            (sb!c:%compiler-defun ',name ',inline-lambda t))
 207          (eval-when (:load-toplevel :execute)
 208            (%defun ',name
 209                    ;; In normal compilation (not for cold load) this is
 210                    ;; where the compiled LAMBDA first appears. In
 211                    ;; cross-compilation, we manipulate the
 212                    ;; previously-statically-linked LAMBDA here.
 213                    #-sb-xc-host ,named-lambda
 214                    #+sb-xc-host (fdefinition ',name)
 215                    ,doc
 216                    ',inline-lambda
 217                    (sb!c:source-location)))))))
 218
 219 #-sb-xc-host
 220 (defun %defun (name def doc inline-lambda source-location)
 221   (declare (type function def))
 222   (declare (type (or null simple-string) doc))
 223   (aver (legal-fun-name-p name)) ; should've been checked by DEFMACRO DEFUN
 224   (sb!c:%compiler-defun name inline-lambda nil)
 225   (when (fboundp name)
 226     (/show0 "redefining NAME in %DEFUN")
 227     (warn 'sb!kernel::redefinition-with-defun
 228           :name name
 229           :new-function def
 230           :new-location source-location))
 231   (setf (sb!xc:fdefinition name) def)
 232
 233   (sb!c::note-name-defined name :function)
 234
 235   (when doc
 236     (setf (%fun-doc def) doc))
 237
 238   name)
 239 \f
 240 ;;;; DEFVAR and DEFPARAMETER
 241
 242 (defmacro-mundanely defvar (var &optional (val nil valp) (doc nil docp))
 243   #!+sb-doc
 244   "Define a special variable at top level. Declare the variable
 245   SPECIAL and, optionally, initialize it. If the variable already has a
 246   value, the old value is not clobbered. The third argument is an optional
 247   documentation string for the variable."
 248   `(progn
 249      (eval-when (:compile-toplevel)
 250        (%compiler-defvar ',var))
 251      (eval-when (:load-toplevel :execute)
 252        (%defvar ',var (unless (boundp ',var) ,val)
 253                 ',valp ,doc ',docp
 254                 (sb!c:source-location)))))
 255
 256 (defmacro-mundanely defparameter (var val &optional (doc nil docp))
 257   #!+sb-doc
 258   "Define a parameter that is not normally changed by the program,
 259   but that may be changed without causing an error. Declare the
 260   variable special and sets its value to VAL, overwriting any
 261   previous value. The third argument is an optional documentation
 262   string for the parameter."
 263   `(progn
 264      (eval-when (:compile-toplevel)
 265        (%compiler-defvar ',var))
 266      (eval-when (:load-toplevel :execute)
 267        (%defparameter ',var ,val ,doc ',docp (sb!c:source-location)))))
 268
 269 (defun %compiler-defvar (var)
 270   (sb!xc:proclaim `(special ,var)))
 271
 272 #-sb-xc-host
 273 (defun %defvar (var val valp doc docp source-location)
 274   (%compiler-defvar var)
 275   (when valp
 276     (unless (boundp var)
 277       (set var val)))
 278   (when docp
 279     (setf (fdocumentation var 'variable) doc))
 280   (sb!c:with-source-location (source-location)
 281     (setf (info :source-location :variable var) source-location))
 282   var)
 283
 284 #-sb-xc-host
 285 (defun %defparameter (var val doc docp source-location)
 286   (%compiler-defvar var)
 287   (set var val)
 288   (when docp
 289     (setf (fdocumentation var 'variable) doc))
 290   (sb!c:with-source-location (source-location)
 291     (setf (info :source-location :variable var) source-location))
 292   var)
 293 \f
 294 ;;;; iteration constructs
 295
 296 ;;; (These macros are defined in terms of a function FROB-DO-BODY which
 297 ;;; is also used by SB!INT:DO-ANONYMOUS. Since these macros should not
 298 ;;; be loaded on the cross-compilation host, but SB!INT:DO-ANONYMOUS
 299 ;;; and FROB-DO-BODY should be, these macros can't conveniently be in
 300 ;;; the same file as FROB-DO-BODY.)
 301 (defmacro-mundanely do (varlist endlist &body body)
 302   #!+sb-doc
 303   "DO ({(Var [Init] [Step])}*) (Test Exit-Form*) Declaration* Form*
 304   Iteration construct. Each Var is initialized in parallel to the value of the
 305   specified Init form. On subsequent iterations, the Vars are assigned the
 306   value of the Step form (if any) in parallel. The Test is evaluated before
 307   each evaluation of the body Forms. When the Test is true, the Exit-Forms
 308   are evaluated as a PROGN, with the result being the value of the DO. A block
 309   named NIL is established around the entire expansion, allowing RETURN to be
 310   used as an alternate exit mechanism."
 311   (frob-do-body varlist endlist body 'let 'psetq 'do nil))
 312 (defmacro-mundanely do* (varlist endlist &body body)
 313   #!+sb-doc
 314   "DO* ({(Var [Init] [Step])}*) (Test Exit-Form*) Declaration* Form*
 315   Iteration construct. Each Var is initialized sequentially (like LET*) to the
 316   value of the specified Init form. On subsequent iterations, the Vars are
 317   sequentially assigned the value of the Step form (if any). The Test is
 318   evaluated before each evaluation of the body Forms. When the Test is true,
 319   the Exit-Forms are evaluated as a PROGN, with the result being the value
 320   of the DO. A block named NIL is established around the entire expansion,
 321   allowing RETURN to be used as an laternate exit mechanism."
 322   (frob-do-body varlist endlist body 'let* 'setq 'do* nil))
 323
 324 ;;; DOTIMES and DOLIST could be defined more concisely using
 325 ;;; destructuring macro lambda lists or DESTRUCTURING-BIND, but then
 326 ;;; it'd be tricky to use them before those things were defined.
 327 ;;; They're used enough times before destructuring mechanisms are
 328 ;;; defined that it looks as though it's worth just implementing them
 329 ;;; ASAP, at the cost of being unable to use the standard
 330 ;;; destructuring mechanisms.
 331 (defmacro-mundanely dotimes ((var count &optional (result nil)) &body body)
 332   (cond ((integerp count)
 333         `(do ((,var 0 (1+ ,var)))
 334              ((>= ,var ,count) ,result)
 335            (declare (type unsigned-byte ,var))
 336            ,@body))
 337         (t
 338          (let ((c (gensym "COUNT")))
 339            `(do ((,var 0 (1+ ,var))
 340                  (,c ,count))
 341                 ((>= ,var ,c) ,result)
 342               (declare (type unsigned-byte ,var)
 343                        (type integer ,c))
 344               ,@body)))))
 345
 346 (defmacro-mundanely dolist ((var list &optional (result nil)) &body body &environment env)
 347   ;; We repeatedly bind the var instead of setting it so that we never
 348   ;; have to give the var an arbitrary value such as NIL (which might
 349   ;; conflict with a declaration). If there is a result form, we
 350   ;; introduce a gratuitous binding of the variable to NIL without the
 351   ;; declarations, then evaluate the result form in that
 352   ;; environment. We spuriously reference the gratuitous variable,
 353   ;; since we don't want to use IGNORABLE on what might be a special
 354   ;; var.
 355   (multiple-value-bind (forms decls) (parse-body body :doc-string-allowed nil)
 356     (let* ((n-list (gensym "N-LIST"))
 357            (start (gensym "START"))
 358            (tmp (gensym "TMP")))
 359       (multiple-value-bind (clist members clist-ok)
 360           (cond ((sb!xc:constantp list env)
 361                  (let ((value (constant-form-value list env)))
 362                    (multiple-value-bind (all dot) (list-members value)
 363                      (when dot
 364                        ;; Full warning is too much: the user may terminate the loop
 365                        ;; early enough. Contents are still right, though.
 366                        (style-warn "Dotted list ~S in DOLIST." value))
 367                      (values value all t))))
 368                 ((and (consp list) (eq 'list (car list))
 369                       (every (lambda (arg) (sb!xc:constantp arg env)) (cdr list)))
 370                  (let ((values (mapcar (lambda (arg) (constant-form-value arg env)) (cdr list))))
 371                    (values values values t)))
 372                 (t
 373                  (values nil nil nil)))
 374         `(block nil
 375            (let ((,n-list ,(if clist-ok (list 'quote clist) list)))
 376              (tagbody
 377                 ,start
 378                 (unless (endp ,n-list)
 379                   (let* (,@(if clist-ok
 380                                `((,tmp (truly-the (member ,@members) (car ,n-list)))
 381                                  (,var ,tmp))
 382                                `((,var (car ,n-list)))))
 383                     ,@decls
 384                     (setq ,n-list (cdr ,n-list))
 385                     (tagbody ,@forms))
 386                   (go ,start))))
 387            ,(if result
 388                 `(let ((,var nil))
 389                    ;; Filter out TYPE declarations (VAR gets bound to NIL,
 390                    ;; and might have a conflicting type declaration) and
 391                    ;; IGNORE (VAR might be ignored in the loop body, but
 392                    ;; it's used in the result form).
 393                    ,@(filter-dolist-declarations decls)
 394                    ,var
 395                    ,result)
 396                 nil))))))
 397 \f
 398 ;;;; conditions, handlers, restarts
 399
 400 ;;; KLUDGE: we PROCLAIM these special here so that we can use restart
 401 ;;; macros in the compiler before the DEFVARs are compiled.
 402 (sb!xc:proclaim
 403  '(special *handler-clusters* *restart-clusters* *condition-restarts*))
 404
 405 (defmacro-mundanely with-condition-restarts
 406     (condition-form restarts-form &body body)
 407   #!+sb-doc
 408   "Evaluates the BODY in a dynamic environment where the restarts in the list
 409    RESTARTS-FORM are associated with the condition returned by CONDITION-FORM.
 410    This allows FIND-RESTART, etc., to recognize restarts that are not related
 411    to the error currently being debugged. See also RESTART-CASE."
 412   (let ((n-cond (gensym)))
 413     `(let ((*condition-restarts*
 414             (cons (let ((,n-cond ,condition-form))
 415                     (cons ,n-cond
 416                           (append ,restarts-form
 417                                   (cdr (assoc ,n-cond *condition-restarts*)))))
 418                   *condition-restarts*)))
 419        ,@body)))
 420
 421 (defmacro-mundanely restart-bind (bindings &body forms)
 422   #!+sb-doc
 423   "Executes forms in a dynamic context where the given restart bindings are
 424    in effect. Users probably want to use RESTART-CASE. When clauses contain
 425    the same restart name, FIND-RESTART will find the first such clause."
 426   `(let ((*restart-clusters*
 427           (cons (list
 428                  ,@(mapcar (lambda (binding)
 429                              (unless (or (car binding)
 430                                          (member :report-function
 431                                                  binding
 432                                                  :test #'eq))
 433                                (warn "Unnamed restart does not have a ~
 434                                       report function: ~S"
 435                                      binding))
 436                              `(make-restart :name ',(car binding)
 437                                             :function ,(cadr binding)
 438                                             ,@(cddr binding)))
 439                            bindings))
 440                 *restart-clusters*)))
 441      ,@forms))
 442
 443 ;;; Wrap the RESTART-CASE expression in a WITH-CONDITION-RESTARTS if
 444 ;;; appropriate. Gross, but it's what the book seems to say...
 445 (defun munge-restart-case-expression (expression env)
 446   (let ((exp (sb!xc:macroexpand expression env)))
 447     (if (consp exp)
 448         (let* ((name (car exp))
 449                (args (if (eq name 'cerror) (cddr exp) (cdr exp))))
 450           (if (member name '(signal error cerror warn))
 451               (once-only ((n-cond `(coerce-to-condition
 452                                     ,(first args)
 453                                     (list ,@(rest args))
 454                                     ',(case name
 455                                         (warn 'simple-warning)
 456                                         (signal 'simple-condition)
 457                                         (t 'simple-error))
 458                                     ',name)))
 459                 `(with-condition-restarts
 460                      ,n-cond
 461                      (car *restart-clusters*)
 462                    ,(if (eq name 'cerror)
 463                         `(cerror ,(second exp) ,n-cond)
 464                         `(,name ,n-cond))))
 465               expression))
 466         expression)))
 467
 468 ;;; FIXME: I did a fair amount of rearrangement of this code in order to
 469 ;;; get WITH-KEYWORD-PAIRS to work cleanly. This code should be tested..
 470 (defmacro-mundanely restart-case (expression &body clauses &environment env)
 471   #!+sb-doc
 472   "(RESTART-CASE form
 473    {(case-name arg-list {keyword value}* body)}*)
 474    The form is evaluated in a dynamic context where the clauses have special
 475    meanings as points to which control may be transferred (see INVOKE-RESTART).
 476    When clauses contain the same case-name, FIND-RESTART will find the first
 477    such clause. If Expression is a call to SIGNAL, ERROR, CERROR or WARN (or
 478    macroexpands into such) then the signalled condition will be associated with
 479    the new restarts."
 480   (flet ((transform-keywords (&key report interactive test)
 481            (let ((result '()))
 482              (when report
 483                (setq result (list* (if (stringp report)
 484                                        `#'(lambda (stream)
 485                                             (write-string ,report stream))
 486                                        `#',report)
 487                                    :report-function
 488                                    result)))
 489              (when interactive
 490                (setq result (list* `#',interactive
 491                                    :interactive-function
 492                                    result)))
 493              (when test
 494                (setq result (list* `#',test :test-function result)))
 495              (nreverse result)))
 496          (parse-keyword-pairs (list keys)
 497            (do ((l list (cddr l))
 498                 (k '() (list* (cadr l) (car l) k)))
 499                ((or (null l) (not (member (car l) keys)))
 500                 (values (nreverse k) l)))))
 501     (let ((block-tag (sb!xc:gensym "BLOCK"))
 502           (temp-var (gensym))
 503           (data
 504            (macrolet (;; KLUDGE: This started as an old DEFMACRO
 505                       ;; WITH-KEYWORD-PAIRS general utility, which was used
 506                       ;; only in this one place in the code. It was translated
 507                       ;; literally into this MACROLET in order to avoid some
 508                       ;; cross-compilation bootstrap problems. It would almost
 509                       ;; certainly be clearer, and it would certainly be more
 510                       ;; concise, to do a more idiomatic translation, merging
 511                       ;; this with the TRANSFORM-KEYWORDS logic above.
 512                       ;;   -- WHN 19990925
 513                       (with-keyword-pairs ((names expression) &body forms)
 514                         (let ((temp (member '&rest names)))
 515                           (unless (= (length temp) 2)
 516                             (error "&REST keyword is ~:[missing~;misplaced~]."
 517                                    temp))
 518                           (let* ((key-vars (ldiff names temp))
 519                                  (keywords (mapcar #'keywordicate key-vars))
 520                                  (key-var (gensym))
 521                                  (rest-var (cadr temp)))
 522                             `(multiple-value-bind (,key-var ,rest-var)
 523                                  (parse-keyword-pairs ,expression ',keywords)
 524                                (let ,(mapcar (lambda (var keyword)
 525                                                `(,var (getf ,key-var
 526                                                             ,keyword)))
 527                                              key-vars keywords)
 528                                  ,@forms))))))
 529              (mapcar (lambda (clause)
 530                        (unless (listp (second clause))
 531                          (error "Malformed ~S clause, no lambda-list:~%  ~S"
 532                                 'restart-case clause))
 533                        (with-keyword-pairs ((report interactive test
 534                                                     &rest forms)
 535                                             (cddr clause))
 536                          (list (car clause) ;name=0
 537                                (sb!xc:gensym "TAG") ;tag=1
 538                                (transform-keywords :report report ;keywords=2
 539                                                    :interactive interactive
 540                                                    :test test)
 541                                (cadr clause) ;bvl=3
 542                                forms))) ;body=4
 543                    clauses))))
 544       `(block ,block-tag
 545          (let ((,temp-var nil))
 546            (tagbody
 547             (restart-bind
 548                 ,(mapcar (lambda (datum)
 549                            (let ((name (nth 0 datum))
 550                                  (tag  (nth 1 datum))
 551                                  (keys (nth 2 datum)))
 552                              `(,name #'(lambda (&rest temp)
 553                                          (setq ,temp-var temp)
 554                                          (go ,tag))
 555                                      ,@keys)))
 556                          data)
 557               (return-from ,block-tag
 558                            ,(munge-restart-case-expression expression env)))
 559             ,@(mapcan (lambda (datum)
 560                         (let ((tag  (nth 1 datum))
 561                               (bvl  (nth 3 datum))
 562                               (body (nth 4 datum)))
 563                           (list tag
 564                                 `(return-from ,block-tag
 565                                    (apply (lambda ,bvl ,@body)
 566                                           ,temp-var)))))
 567                       data)))))))
 568
 569 (defmacro-mundanely with-simple-restart ((restart-name format-string
 570                                                        &rest format-arguments)
 571                                          &body forms)
 572   #!+sb-doc
 573   "(WITH-SIMPLE-RESTART (restart-name format-string format-arguments)
 574    body)
 575    If restart-name is not invoked, then all values returned by forms are
 576    returned. If control is transferred to this restart, it immediately
 577    returns the values NIL and T."
 578   `(restart-case
 579        ;; If there's just one body form, then don't use PROGN. This allows
 580        ;; RESTART-CASE to "see" calls to ERROR, etc.
 581        ,(if (= (length forms) 1) (car forms) `(progn ,@forms))
 582      (,restart-name ()
 583         :report (lambda (stream)
 584                   (format stream ,format-string ,@format-arguments))
 585       (values nil t))))
 586
 587 (defmacro-mundanely %handler-bind (bindings form)
 588   (let ((member-if (member-if (lambda (x)
 589                                 (not (proper-list-of-length-p x 2)))
 590                               bindings)))
 591     (when member-if
 592       (error "ill-formed handler binding: ~S" (first member-if))))
 593   (let* ((local-funs nil)
 594          (mapped-bindings (mapcar (lambda (binding)
 595                                     (destructuring-bind (type handler) binding
 596                                       (let ((lambda-form handler))
 597                                         (if (and (consp handler)
 598                                                  (or (eq 'lambda (car handler))
 599                                                      (and (eq 'function (car handler))
 600                                                           (consp (cdr handler))
 601                                                           (let ((x (second handler)))
 602                                                             (and (consp x)
 603                                                                  (eq 'lambda (car x))
 604                                                                  (setf lambda-form x))))))
 605                                             (let ((name (sb!xc:gensym "LAMBDA")))
 606                                               (push `(,name ,@(cdr lambda-form)) local-funs)
 607                                               (list type `(function ,name)))
 608                                             binding))))
 609                                   bindings)))
 610     `(dx-flet (,@(reverse local-funs))
 611        (let ((*handler-clusters*
 612               (cons (list ,@(mapcar (lambda (x) `(cons ',(car x) ,(cadr x)))
 613                                     mapped-bindings))
 614                     *handler-clusters*)))
 615          #!+stack-allocatable-fixed-objects
 616          (declare (truly-dynamic-extent *handler-clusters*))
 617          (progn ,form)))))
 618
 619 (defmacro-mundanely handler-bind (bindings &body forms)
 620   #!+sb-doc
 621   "(HANDLER-BIND ( {(type handler)}* )  body)
 622
 623 Executes body in a dynamic context where the given handler bindings are in
 624 effect. Each handler must take the condition being signalled as an argument.
 625 The bindings are searched first to last in the event of a signalled
 626 condition."
 627   `(%handler-bind ,bindings
 628                   #!-x86 (progn ,@forms)
 629                   ;; Need to catch FP errors here!
 630                   #!+x86 (multiple-value-prog1 (progn ,@forms) (float-wait))))
 631
 632 (defmacro-mundanely handler-case (form &rest cases)
 633   "(HANDLER-CASE form { (type ([var]) body) }* )
 634
 635 Execute FORM in a context with handlers established for the condition types. A
 636 peculiar property allows type to be :NO-ERROR. If such a clause occurs, and
 637 form returns normally, all its values are passed to this clause as if by
 638 MULTIPLE-VALUE-CALL. The :NO-ERROR clause accepts more than one var
 639 specification."
 640   (let ((no-error-clause (assoc ':no-error cases)))
 641     (if no-error-clause
 642         (let ((normal-return (make-symbol "normal-return"))
 643               (error-return  (make-symbol "error-return")))
 644           `(block ,error-return
 645              (multiple-value-call (lambda ,@(cdr no-error-clause))
 646                (block ,normal-return
 647                  (return-from ,error-return
 648                    (handler-case (return-from ,normal-return ,form)
 649                      ,@(remove no-error-clause cases)))))))
 650         (let* ((local-funs nil)
 651                (annotated-cases
 652                 (mapcar (lambda (case)
 653                           (with-unique-names (tag fun)
 654                             (destructuring-bind (type ll &body body) case
 655                               (push `(,fun ,ll ,@body) local-funs)
 656                               (list tag type ll fun))))
 657                         cases)))
 658           (with-unique-names (block cell form-fun)
 659             `(dx-flet ((,form-fun ()
 660                          #!-x86 ,form
 661                          ;; Need to catch FP errors here!
 662                          #!+x86 (multiple-value-prog1 ,form (float-wait)))
 663                        ,@(reverse local-funs))
 664                (declare (optimize (sb!c::check-tag-existence 0)))
 665                (block ,block
 666                  ;; KLUDGE: We use a dx CONS cell instead of just assigning to
 667                  ;; the variable directly, so that we can stack allocate
 668                  ;; robustly: dx value cells don't work quite right, and it is
 669                  ;; possible to construct user code that should loop
 670                  ;; indefinitely, but instead eats up some stack each time
 671                  ;; around.
 672                  (dx-let ((,cell (cons :condition nil)))
 673                    (declare (ignorable ,cell))
 674                    (tagbody
 675                       (%handler-bind
 676                        ,(mapcar (lambda (annotated-case)
 677                                   (destructuring-bind (tag type ll fun-name) annotated-case
 678                                     (declare (ignore fun-name))
 679                                     (list type
 680                                           `(lambda (temp)
 681                                              ,(if ll
 682                                                   `(setf (cdr ,cell) temp)
 683                                                   '(declare (ignore temp)))
 684                                              (go ,tag)))))
 685                                 annotated-cases)
 686                        (return-from ,block (,form-fun)))
 687                       ,@(mapcan
 688                          (lambda (annotated-case)
 689                            (destructuring-bind (tag type ll fun-name) annotated-case
 690                              (declare (ignore type))
 691                              (list tag
 692                                    `(return-from ,block
 693                                       ,(if ll
 694                                            `(,fun-name (cdr ,cell))
 695                                            `(,fun-name))))))
 696                          annotated-cases))))))))))
 697 \f
 698 ;;;; miscellaneous
 699
 700 (defmacro-mundanely return (&optional (value nil))
 701   `(return-from nil ,value))
 702
 703 (defmacro-mundanely psetq (&rest pairs)
 704   #!+sb-doc
 705   "PSETQ {var value}*
 706    Set the variables to the values, like SETQ, except that assignments
 707    happen in parallel, i.e. no assignments take place until all the
 708    forms have been evaluated."
 709   ;; Given the possibility of symbol-macros, we delegate to PSETF
 710   ;; which knows how to deal with them, after checking that syntax is
 711   ;; compatible with PSETQ.
 712   (do ((pair pairs (cddr pair)))
 713       ((endp pair) `(psetf ,@pairs))
 714     (unless (symbolp (car pair))
 715       (error 'simple-program-error
 716              :format-control "variable ~S in PSETQ is not a SYMBOL"
 717              :format-arguments (list (car pair))))))
 718
 719 (defmacro-mundanely lambda (&whole whole args &body body)
 720   (declare (ignore args body))
 721   `#',whole)
 722
 723 (defmacro-mundanely named-lambda (&whole whole name args &body body)
 724   (declare (ignore name args body))
 725   `#',whole)
 726
 727 (defmacro-mundanely lambda-with-lexenv (&whole whole
 728                                         declarations macros symbol-macros
 729                                         &body body)
 730   (declare (ignore declarations macros symbol-macros body))
 731   `#',whole)
 732
 733 ;;; this eliminates a whole bundle of unknown function STYLE-WARNINGs
 734 ;;; when cross-compiling.  It's not critical for behaviour, but is
 735 ;;; aesthetically pleasing, except inasmuch as there's this list of
 736 ;;; magic functions here.  -- CSR, 2003-04-01
 737 #+sb-xc-host
 738 (sb!xc:proclaim '(ftype (function * *)
 739                         ;; functions appearing in fundamental defining
 740                         ;; macro expansions:
 741                         %compiler-deftype
 742                         %compiler-defvar
 743                         %defun
 744                         %defsetf
 745                         %defparameter
 746                         %defvar
 747                         sb!c:%compiler-defun
 748                         sb!c::%define-symbol-macro
 749                         sb!c::%defconstant
 750                         sb!c::%define-compiler-macro
 751                         sb!c::%defmacro
 752                         sb!kernel::%compiler-defstruct
 753                         sb!kernel::%compiler-define-condition
 754                         sb!kernel::%defstruct
 755                         sb!kernel::%define-condition
 756                         ;; miscellaneous functions commonly appearing
 757                         ;; as a result of macro expansions or compiler
 758                         ;; transformations:
 759                         sb!int:find-undeleted-package-or-lose ; IN-PACKAGE
 760                         sb!kernel::arg-count-error ; PARSE-DEFMACRO
 761                         ))