src/code/defboot.lisp

   1 ;;;; bootstrapping fundamental machinery (e.g. DEFUN, DEFCONSTANT,
   2 ;;;; DEFVAR) from special forms and primitive functions
   3 ;;;;
   4 ;;;; KLUDGE: The bootstrapping aspect of this is now obsolete. It was
   5 ;;;; originally intended that this file file would be loaded into a
   6 ;;;; Lisp image which had Common Lisp primitives defined, and DEFMACRO
   7 ;;;; defined, and little else. Since then that approach has been
   8 ;;;; dropped and this file has been modified somewhat to make it work
   9 ;;;; more cleanly when used to predefine macros at
  10 ;;;; build-the-cross-compiler time.
  11
  12 ;;;; This software is part of the SBCL system. See the README file for
  13 ;;;; more information.
  14 ;;;;
  15 ;;;; This software is derived from the CMU CL system, which was
  16 ;;;; written at Carnegie Mellon University and released into the
  17 ;;;; public domain. The software is in the public domain and is
  18 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  19 ;;;; files for more information.
  20
  21 (in-package "SB!IMPL")
  22 \f
  23 ;;;; IN-PACKAGE
  24
  25 (defmacro-mundanely in-package (package-designator)
  26   `(eval-when (:compile-toplevel :load-toplevel :execute)
  27      (setq *package* (find-undeleted-package-or-lose ',package-designator))))
  28 \f
  29 ;;;; MULTIPLE-VALUE-FOO
  30
  31 (defun list-of-symbols-p (x)
  32   (and (listp x)
  33        (every #'symbolp x)))
  34
  35 (defmacro-mundanely multiple-value-bind (vars value-form &body body)
  36   (if (list-of-symbols-p vars)
  37     ;; It's unclear why it would be important to special-case the LENGTH=1 case
  38     ;; at this level, but the CMU CL code did it, so.. -- WHN 19990411
  39     (if (= (length vars) 1)
  40       `(let ((,(car vars) ,value-form))
  41          ,@body)
  42       (let ((ignore (gensym)))
  43         `(multiple-value-call #'(lambda (&optional ,@vars &rest ,ignore)
  44                                   (declare (ignore ,ignore))
  45                                   ,@body)
  46                               ,value-form)))
  47     (error "Vars is not a list of symbols: ~S" vars)))
  48
  49 (defmacro-mundanely multiple-value-setq (vars value-form)
  50   (cond ((null vars)
  51          ;; The ANSI spec says that the primary value of VALUE-FORM must be
  52          ;; returned. The general-case-handling code below doesn't do this
  53          ;; correctly in the special case when there are no vars bound, so we
  54          ;; handle this special case separately here.
  55          (let ((g (gensym)))
  56            `(multiple-value-bind (,g) ,value-form
  57               ,g)))
  58         ((list-of-symbols-p vars)
  59          (let ((temps (make-gensym-list (length vars))))
  60            `(multiple-value-bind ,temps ,value-form
  61               ,@(mapcar #'(lambda (var temp)
  62                             `(setq ,var ,temp))
  63                         vars temps)
  64               ,(car temps))))
  65         (t (error "Vars is not a list of symbols: ~S" vars))))
  66
  67 (defmacro-mundanely multiple-value-list (value-form)
  68   `(multiple-value-call #'list ,value-form))
  69 \f
  70 ;;;; various conditional constructs
  71
  72 ;;; COND defined in terms of IF
  73 (defmacro-mundanely cond (&rest clauses)
  74   (if (endp clauses)
  75     nil
  76     (let ((clause (first clauses)))
  77       (if (atom clause)
  78         (error "Cond clause is not a list: ~S" clause)
  79         (let ((test (first clause))
  80               (forms (rest clause)))
  81           (if (endp forms)
  82             (let ((n-result (gensym)))
  83               `(let ((,n-result ,test))
  84                  (if ,n-result
  85                    ,n-result
  86                    (cond ,@(rest clauses)))))
  87             `(if ,test
  88                (progn ,@forms)
  89                (cond ,@(rest clauses)))))))))
  90
  91 ;;; other things defined in terms of COND
  92 (defmacro-mundanely when (test &body forms)
  93   #!+sb-doc
  94   "If the first argument is true, the rest of the forms are
  95   evaluated as a PROGN."
  96   `(cond (,test nil ,@forms)))
  97 (defmacro-mundanely unless (test &body forms)
  98   #!+sb-doc
  99   "If the first argument is not true, the rest of the forms are
 100   evaluated as a PROGN."
 101   `(cond ((not ,test) nil ,@forms)))
 102 (defmacro-mundanely and (&rest forms)
 103   (cond ((endp forms) t)
 104         ((endp (rest forms)) (first forms))
 105         (t
 106          `(if ,(first forms)
 107               (and ,@(rest forms))
 108               nil))))
 109 (defmacro-mundanely or (&rest forms)
 110   (cond ((endp forms) nil)
 111         ((endp (rest forms)) (first forms))
 112         (t
 113          (let ((n-result (gensym)))
 114            `(let ((,n-result ,(first forms)))
 115               (if ,n-result
 116                   ,n-result
 117                   (or ,@(rest forms))))))))
 118 \f
 119 ;;;; various sequencing constructs
 120
 121 (defmacro-mundanely prog (varlist &body body-decls)
 122   (multiple-value-bind (body decls) (parse-body body-decls nil)
 123     `(block nil
 124        (let ,varlist
 125          ,@decls
 126          (tagbody ,@body)))))
 127
 128 (defmacro-mundanely prog* (varlist &body body-decls)
 129   (multiple-value-bind (body decls) (parse-body body-decls nil)
 130     `(block nil
 131        (let* ,varlist
 132          ,@decls
 133          (tagbody ,@body)))))
 134
 135 (defmacro-mundanely prog1 (result &body body)
 136   (let ((n-result (gensym)))
 137     `(let ((,n-result ,result))
 138        ,@body
 139        ,n-result)))
 140
 141 (defmacro-mundanely prog2 (form1 result &body body)
 142   `(prog1 (progn ,form1 ,result) ,@body))
 143 \f
 144 ;;;; DEFUN
 145
 146 ;;; Should we save the inline expansion of the function named NAME?
 147 (defun inline-fun-name-p (name)
 148   (or
 149    ;; the normal reason for saving the inline expansion
 150    (info :function :inlinep name)
 151    ;; another reason for saving the inline expansion: If the
 152    ;; ANSI-recommended idiom
 153    ;;   (DECLAIM (INLINE FOO))
 154    ;;   (DEFUN FOO ..)
 155    ;;   (DECLAIM (NOTINLINE FOO))
 156    ;; has been used, and then we later do another
 157    ;;   (DEFUN FOO ..)
 158    ;; without a preceding
 159    ;;   (DECLAIM (INLINE FOO))
 160    ;; what should we do with the old inline expansion when we see the
 161    ;; new DEFUN? Overwriting it with the new definition seems like
 162    ;; the only unsurprising choice.
 163    (info :function :inline-expansion-designator name)))
 164
 165 ;;; Now that we have the definition of MULTIPLE-VALUE-BIND, we can
 166 ;;; make a reasonably readable definition of DEFUN.
 167 (defmacro-mundanely defun (&environment env name args &body body)
 168   "Define a function at top level."
 169   #+sb-xc-host
 170   (unless (symbol-package (fun-name-block-name name))
 171     (warn "DEFUN of uninterned symbol ~S (tricky for GENESIS)" name))
 172   (multiple-value-bind (forms decls doc) (parse-body body)
 173     (let* (;; stuff shared between LAMBDA and INLINE-LAMBDA
 174            (lambda-guts `(,args
 175                           ,@decls
 176                           (block ,(fun-name-block-name name)
 177                             ,@forms)))
 178            (lambda `(lambda ,@lambda-guts))
 179            (inline-lambda
 180             (cond (;; Does the user not even want to inline?
 181                    (not (inline-fun-name-p name))
 182                    nil)
 183                   (;; Does inlining look too hairy to handle?
 184                    (not (sb!c:lambda-independent-of-lexenv-p lambda env))
 185                    (sb!c:maybe-compiler-note
 186                     "lexical environment too hairy, can't inline DEFUN ~S"
 187                     name)
 188                    nil)
 189                   (t
 190                    ;; FIXME: The only reason that we return
 191                    ;; LAMBDA-WITH-LEXENV instead of returning bare
 192                    ;; LAMBDA is to avoid modifying downstream code
 193                    ;; which expects LAMBDA-WITH-LEXENV. But the code
 194                    ;; here is the only code which feeds into the
 195                    ;; downstream code, and the generality of the
 196                    ;; interface is no longer used, so it'd make sense
 197                    ;; to simplify the interface instead of using the
 198                    ;; old general LAMBDA-WITH-LEXENV interface in this
 199                    ;; simplified way.
 200                    `(sb!c:lambda-with-lexenv
 201                      nil nil nil ; i.e. no DECLS, no MACROS, no SYMMACS
 202                      ,@lambda-guts)))))
 203       `(progn
 204
 205          ;; In cross-compilation of toplevel DEFUNs, we arrange
 206          ;; for the LAMBDA to be statically linked by GENESIS.
 207          #+sb-xc-host
 208          (cold-fset ,name ,lambda)
 209
 210          (eval-when (:compile-toplevel :load-toplevel :execute)
 211            (sb!c:%compiler-defun ',name ',inline-lambda))
 212
 213          (%defun ',name
 214                  ;; In normal compilation (not for cold load) this is
 215                  ;; where the compiled LAMBDA first appears. In
 216                  ;; cross-compilation, we manipulate the
 217                  ;; previously-statically-linked LAMBDA here.
 218                  #-sb-xc-host ,lambda
 219                  #+sb-xc-host (fdefinition ',name)
 220                  ,doc)))))
 221 #-sb-xc-host
 222 (defun %defun (name def doc)
 223   (declare (type function def))
 224   (declare (type (or null simple-string doc)))
 225   (aver (legal-fun-name-p name))
 226   (when (fboundp name)
 227     (/show0 "redefining NAME in %DEFUN")
 228     (style-warn "redefining ~S in DEFUN" name))
 229   (setf (sb!xc:fdefinition name) def)
 230
 231   ;; FIXME: I want to do this here (and fix bug 137), but until the
 232   ;; breathtaking CMU CL function name architecture is converted into
 233   ;; something sane, (1) doing so doesn't really fix the bug, and
 234   ;; (2) doing probably isn't even really safe.
 235   #+nil (setf (%fun-name def) name)
 236
 237   (when doc
 238     ;; FIXME: This should use shared SETF-name-parsing logic.
 239     (if (and (consp name) (eq (first name) 'setf))
 240         (setf (fdocumentation (second name) 'setf) doc)
 241         (setf (fdocumentation (the symbol name) 'function) doc)))
 242   name)
 243 \f
 244 ;;;; DEFVAR and DEFPARAMETER
 245
 246 (defmacro-mundanely defvar (var &optional (val nil valp) (doc nil docp))
 247   #!+sb-doc
 248   "Define a global variable at top level. Declare the variable
 249   SPECIAL and, optionally, initialize it. If the variable already has a
 250   value, the old value is not clobbered. The third argument is an optional
 251   documentation string for the variable."
 252   `(progn
 253      (declaim (special ,var))
 254      ,@(when valp
 255          `((unless (boundp ',var)
 256              (setq ,var ,val))))
 257      ,@(when docp
 258          `((funcall #'(setf fdocumentation) ',doc ',var 'variable)))
 259      ',var))
 260
 261 (defmacro-mundanely defparameter (var val &optional (doc nil docp))
 262   #!+sb-doc
 263   "Define a parameter that is not normally changed by the program,
 264   but that may be changed without causing an error. Declare the
 265   variable special and sets its value to VAL, overwriting any
 266   previous value. The third argument is an optional documentation
 267   string for the parameter."
 268   `(progn
 269      (declaim (special ,var))
 270      (setq ,var ,val)
 271      ,@(when docp
 272          ;; FIXME: The various FUNCALL #'(SETF FDOCUMENTATION) and
 273          ;; other FUNCALL #'(SETF FOO) forms in the code should
 274          ;; unbogobootstrapized back to ordinary SETF forms.
 275          `((funcall #'(setf fdocumentation) ',doc ',var 'variable)))
 276      ',var))
 277 \f
 278 ;;;; iteration constructs
 279
 280 ;;; (These macros are defined in terms of a function DO-DO-BODY which
 281 ;;; is also used by SB!INT:DO-ANONYMOUS. Since these macros should not
 282 ;;; be loaded on the cross-compilation host, but SB!INT:DO-ANONYMOUS
 283 ;;; and DO-DO-BODY should be, these macros can't conveniently be in
 284 ;;; the same file as DO-DO-BODY.)
 285 (defmacro-mundanely do (varlist endlist &body body)
 286   #!+sb-doc
 287   "DO ({(Var [Init] [Step])}*) (Test Exit-Form*) Declaration* Form*
 288   Iteration construct. Each Var is initialized in parallel to the value of the
 289   specified Init form. On subsequent iterations, the Vars are assigned the
 290   value of the Step form (if any) in parallel. The Test is evaluated before
 291   each evaluation of the body Forms. When the Test is true, the Exit-Forms
 292   are evaluated as a PROGN, with the result being the value of the DO. A block
 293   named NIL is established around the entire expansion, allowing RETURN to be
 294   used as an alternate exit mechanism."
 295   (do-do-body varlist endlist body 'let 'psetq 'do nil))
 296 (defmacro-mundanely do* (varlist endlist &body body)
 297   #!+sb-doc
 298   "DO* ({(Var [Init] [Step])}*) (Test Exit-Form*) Declaration* Form*
 299   Iteration construct. Each Var is initialized sequentially (like LET*) to the
 300   value of the specified Init form. On subsequent iterations, the Vars are
 301   sequentially assigned the value of the Step form (if any). The Test is
 302   evaluated before each evaluation of the body Forms. When the Test is true,
 303   the Exit-Forms are evaluated as a PROGN, with the result being the value
 304   of the DO. A block named NIL is established around the entire expansion,
 305   allowing RETURN to be used as an laternate exit mechanism."
 306   (do-do-body varlist endlist body 'let* 'setq 'do* nil))
 307
 308 ;;; DOTIMES and DOLIST could be defined more concisely using
 309 ;;; destructuring macro lambda lists or DESTRUCTURING-BIND, but then
 310 ;;; it'd be tricky to use them before those things were defined.
 311 ;;; They're used enough times before destructuring mechanisms are
 312 ;;; defined that it looks as though it's worth just implementing them
 313 ;;; ASAP, at the cost of being unable to use the standard
 314 ;;; destructuring mechanisms.
 315 (defmacro-mundanely dotimes (var-count-result &body body)
 316   (multiple-value-bind ; to roll our own destructuring
 317       (var count result)
 318       (apply (lambda (var count &optional (result nil))
 319                (values var count result))
 320              var-count-result)
 321     (cond ((numberp count)
 322            `(do ((,var 0 (1+ ,var)))
 323                 ((>= ,var ,count) ,result)
 324               (declare (type unsigned-byte ,var))
 325               ,@body))
 326           (t (let ((v1 (gensym)))
 327                `(do ((,var 0 (1+ ,var)) (,v1 ,count))
 328                     ((>= ,var ,v1) ,result)
 329                   (declare (type unsigned-byte ,var))
 330                   ,@body))))))
 331 (defmacro-mundanely dolist (var-list-result &body body)
 332   (multiple-value-bind ; to roll our own destructuring
 333       (var list result)
 334       (apply (lambda (var list &optional (result nil))
 335                (values var list result))
 336              var-list-result)
 337     ;; We repeatedly bind the var instead of setting it so that we
 338     ;; never have to give the var an arbitrary value such as NIL
 339     ;; (which might conflict with a declaration). If there is a result
 340     ;; form, we introduce a gratuitous binding of the variable to NIL
 341     ;; without the declarations, then evaluate the result form in that
 342     ;; environment. We spuriously reference the gratuitous variable,
 343     ;; since since we don't want to use IGNORABLE on what might be a
 344     ;; special var.
 345     (let ((n-list (gensym)))
 346       `(do ((,n-list ,list (cdr ,n-list)))
 347            ((endp ,n-list)
 348             ,@(if result
 349                 `((let ((,var nil))
 350                     ,var
 351                     ,result))
 352                 '(nil)))
 353          (let ((,var (car ,n-list)))
 354            ,@body)))))
 355 \f
 356 ;;;; miscellaneous
 357
 358 (defmacro-mundanely return (&optional (value nil))
 359   `(return-from nil ,value))
 360
 361 (defmacro-mundanely psetq (&rest pairs)
 362   #!+sb-doc
 363   "SETQ {var value}*
 364    Set the variables to the values, like SETQ, except that assignments
 365    happen in parallel, i.e. no assignments take place until all the
 366    forms have been evaluated."
 367   ;; (This macro is used in the definition of DO, so we can't use DO in the
 368   ;; definition of this macro without getting into confusing bootstrap issues.)
 369   (prog ((lets nil)
 370          (setqs nil)
 371          (pairs pairs))
 372     :again
 373     (when (atom (cdr pairs))
 374       (return `(let ,(nreverse lets)
 375                  (setq ,@(nreverse setqs))
 376                  nil)))
 377     (let ((gen (gensym)))
 378       (setq lets (cons `(,gen ,(cadr pairs)) lets)
 379             setqs (list* gen (car pairs) setqs)
 380             pairs (cddr pairs)))
 381     (go :again)))
 382
 383 (defmacro-mundanely lambda (&whole whole args &body body)
 384   (declare (ignore args body))
 385   `#',whole)