src/code/defmacro.lisp

   1 ;;;; DEFMACRO machinery
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13
  14 ;;; the guts of the DEFMACRO macro, pulled out into a separate
  15 ;;; function in order to make it easier to express the common
  16 ;;; bootstrap idiom
  17 ;;;   CL:DEFMACRO SB!XC:DEFMACRO
  18 ;;;   SB!XC:DEFMACRO CL:DEFMACRO
  19 (eval-when (#-sb-xc :compile-toplevel :load-toplevel :execute)
  20   (defun %expander-for-defmacro (name lambda-list body)
  21     (unless (symbolp name)
  22       (error "The macro name ~S is not a symbol." name))
  23     ;; When we are building the cross-compiler, we could be in a host
  24     ;; lisp which implements CL macros (e.g. CL:AND) as special
  25     ;; operators (while still providing a macroexpansion for
  26     ;; compliance): therefore can't use the host's SPECIAL-OPERATOR-P
  27     ;; as a discriminator, but that's OK because the set of forms the
  28     ;; cross-compiler compiles is tightly controlled.  -- CSR,
  29     ;; 2003-04-20
  30     #-sb-xc-host
  31     (when (special-operator-p name)
  32       (error "The special operator ~S can't be redefined as a macro."
  33              name))
  34     (with-unique-names (whole environment)
  35       (multiple-value-bind (new-body local-decs doc)
  36           (parse-defmacro lambda-list whole body name 'defmacro
  37                           :environment environment)
  38         (let ((def `(#+sb-xc-host lambda
  39                      ;; Use a named-lambda rather than a lambda so that
  40                      ;; proper xref information can be stored. Use a
  41                      ;; list-based name, since otherwise the compiler
  42                      ;; will momentarily assume that it names a normal
  43                      ;; function, and report spurious warnings about
  44                      ;; redefinition a macro as a function, and then
  45                      ;; vice versa.
  46                      #-sb-xc-host named-lambda #-sb-xc-host (defmacro ,name)
  47                      (,whole ,environment)
  48                       ,@local-decs
  49                       ,new-body))
  50               (debug-name (sb!c::debug-name 'macro-function name)))
  51           `(eval-when (:compile-toplevel :load-toplevel :execute)
  52              (sb!c::%defmacro ',name #',def ',lambda-list
  53                               ,doc ',debug-name)))))))
  54
  55 (macrolet
  56     ((def (times set-p)
  57        `(eval-when (,@times)
  58           (defun sb!c::%defmacro (name definition lambda-list doc debug-name)
  59             ;; old note (ca. 1985, maybe:-): "Eventually %%DEFMACRO
  60             ;; should deal with clearing old compiler information for
  61             ;; the functional value."
  62             ,@(unless set-p
  63                 '((declare (ignore lambda-list debug-name))))
  64             (with-single-package-locked-error ()
  65               (case (info :function :kind name)
  66                 (:function
  67                  (let ((where-from (info :function :where-from name)))
  68                    (when (eq :defined where-from)
  69                      (assert-symbol-home-package-unlocked name "defining ~S as a macro"))
  70                    (style-warn
  71                     "~S is being redefined as a macro when it was ~
  72                      previously ~(~A~) to be a function."
  73                     name where-from))
  74                  (undefine-fun-name name))
  75                 (:special-form
  76                  (error "The special form ~S can't be redefined as a macro."
  77                         name)))
  78               (clear-info :function :where-from name)
  79
  80               ;; FIXME: It would be nice to warn about DEFMACRO of an
  81               ;; already-defined macro, but that's slightly hard to do
  82               ;; because in common usage DEFMACRO is defined at compile
  83               ;; time and then redefined at load time. We'd need to make a
  84               ;; distinction between the defined-at-compile-time state and
  85               ;; the defined-at-load-time state to make this work. (Trying
  86               ;; to warn about duplicate DEFTYPEs runs into the same
  87               ;; problem.)
  88               #+nil
  89               (when (sb!xc:macro-function name)
  90                 ;; Someday we could check for macro arguments
  91                 ;; being incompatibly redefined. Doing this right
  92                 ;; will involve finding the old macro lambda-list
  93                 ;; and comparing it with the new one.
  94                 (style-warn "redefining ~/sb-impl::print-symbol-with-prefix/ ~
  95                                  in DEFMACRO" name))
  96               (setf (sb!xc:macro-function name) definition)
  97               ,(when set-p
  98                      `(setf (%fun-doc definition) doc
  99                             (%fun-lambda-list definition) lambda-list
 100                             (%fun-name definition) debug-name)))
 101             name))))
 102   (progn
 103     (def (:load-toplevel :execute) #-sb-xc-host t #+sb-xc-host nil)
 104     (def (#-sb-xc :compile-toplevel) nil)))
 105
 106 ;;; Parse the definition and make an expander function. The actual
 107 ;;; definition is done by %DEFMACRO which we expand into. After the
 108 ;;; compiler has gotten the information it wants out of macro
 109 ;;; definition, it compiles a call to %DEFMACRO which happens at load
 110 ;;; time.
 111 (defmacro sb!xc:defmacro (name lambda-list &rest body)
 112   (%expander-for-defmacro name lambda-list body))
 113
 114 ;;; In the cross-compiler, we not only need to support the definition
 115 ;;; of target macros at cross-compiler-build-time (with SB!XC:DEFMACRO
 116 ;;; running in the cross-compilation host), we also need to support
 117 ;;; the definition of target macros at target compilation time (with
 118 ;;; CL:DEFMACRO processed by the cross-compiler)..
 119 #+sb-xc-host
 120 (sb!xc:defmacro defmacro (name lambda-list &rest body)
 121   (%expander-for-defmacro name lambda-list body))
 122
 123 ;;; DEFMACRO-MUNDANELY is like SB!XC:DEFMACRO, except that it doesn't
 124 ;;; have any EVAL-WHEN or IR1 magic associated with it, so it only
 125 ;;; takes effect in :LOAD-TOPLEVEL or :EXECUTE situations.
 126 (def!macro defmacro-mundanely (name lambda-list &body body)
 127
 128   ;; old way:
 129   ;;(let ((whole (gensym "WHOLE-"))
 130   ;;      (environment (gensym "ENVIRONMENT-")))
 131   ;;  (multiple-value-bind (new-body local-decs doc)
 132   ;;      (parse-defmacro lambda-list whole body name 'defmacro
 133   ;;                      :environment environment)
 134   ;;    `(progn
 135   ;;       (setf (sb!xc:macro-function ',name)
 136   ;;             (lambda (,whole ,environment)
 137   ;;                 ,@local-decs
 138   ;;                 (block ,name
 139   ;;                 ,new-body)))
 140   ;;       (setf (fdocumentation ',name 'macro)
 141   ;;             ,doc)
 142   ;;       ',name)))
 143
 144   `(let ()
 145      (sb!xc:defmacro ,name ,lambda-list ,@body)))