src/code/defstruct.lisp

   1 ;;;; that part of DEFSTRUCT implementation which is needed not just
   2 ;;;; in the target Lisp but also in the cross-compilation host
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!KERNEL")
  14
  15 (/show0 "code/defstruct.lisp 15")
  16 \f
  17 ;;;; getting LAYOUTs
  18
  19 ;;; Return the compiler layout for NAME. (The class referred to by
  20 ;;; NAME must be a structure-like class.)
  21 (defun compiler-layout-or-lose (name)
  22   (let ((res (info :type :compiler-layout name)))
  23     (cond ((not res)
  24            (error "Class is not yet defined or was undefined: ~S" name))
  25           ((not (typep (layout-info res) 'defstruct-description))
  26            (error "Class is not a structure class: ~S" name))
  27           (t res))))
  28
  29 ;;; Delay looking for compiler-layout until the constructor is being
  30 ;;; compiled, since it doesn't exist until after the EVAL-WHEN
  31 ;;; (COMPILE) stuff is compiled. (Or, in the oddball case when
  32 ;;; DEFSTRUCT is executing in a non-toplevel context, the
  33 ;;; compiler-layout still doesn't exist at compilation time, and we
  34 ;;; delay still further.)
  35 (sb!xc:defmacro %delayed-get-compiler-layout (name)
  36   (let ((layout (info :type :compiler-layout name)))
  37     (cond (layout
  38            ;; ordinary case: When the DEFSTRUCT is at top level,
  39            ;; then EVAL-WHEN (COMPILE) stuff will have set up the
  40            ;; layout for us to use.
  41            (unless (typep (layout-info layout) 'defstruct-description)
  42              (error "Class is not a structure class: ~S" name))
  43            `,layout)
  44           (t
  45            ;; KLUDGE: In the case that DEFSTRUCT is not at top-level
  46            ;; the layout doesn't exist at compile time. In that case
  47            ;; we laboriously look it up at run time. This code will
  48            ;; run on every constructor call and will likely be quite
  49            ;; slow, so if anyone cares about performance of
  50            ;; non-toplevel DEFSTRUCTs, it should be rewritten to be
  51            ;; cleverer. -- WHN 2002-10-23
  52            (sb!c:compiler-notify
  53             "implementation limitation: ~
  54              Non-toplevel DEFSTRUCT constructors are slow.")
  55            (with-unique-names (layout)
  56              `(let ((,layout (info :type :compiler-layout ',name)))
  57                 (unless (typep (layout-info ,layout) 'defstruct-description)
  58                   (error "Class is not a structure class: ~S" ',name))
  59                 ,layout))))))
  60
  61 ;;; Get layout right away.
  62 (sb!xc:defmacro compile-time-find-layout (name)
  63   (find-layout name))
  64
  65 ;;; re. %DELAYED-GET-COMPILER-LAYOUT and COMPILE-TIME-FIND-LAYOUT, above..
  66 ;;;
  67 ;;; FIXME: Perhaps both should be defined with DEFMACRO-MUNDANELY?
  68 ;;; FIXME: Do we really need both? If so, their names and implementations
  69 ;;; should probably be tweaked to be more parallel.
  70 \f
  71 ;;;; DEFSTRUCT-DESCRIPTION
  72
  73 ;;; The DEFSTRUCT-DESCRIPTION structure holds compile-time information
  74 ;;; about a structure type.
  75 (def!struct (defstruct-description
  76              (:conc-name dd-)
  77              (:make-load-form-fun just-dump-it-normally)
  78              #-sb-xc-host (:pure t)
  79              (:constructor make-defstruct-description
  80                            (name &aux
  81                                  (conc-name (symbolicate name "-"))
  82                                  (copier-name (symbolicate "COPY-" name))
  83                                  (predicate-name (symbolicate name "-P")))))
  84   ;; name of the structure
  85   (name (missing-arg) :type symbol :read-only t)
  86   ;; documentation on the structure
  87   (doc nil :type (or string null))
  88   ;; prefix for slot names. If NIL, none.
  89   (conc-name nil :type (or symbol null))
  90   ;; the name of the primary standard keyword constructor, or NIL if none
  91   (default-constructor nil :type (or symbol null))
  92   ;; all the explicit :CONSTRUCTOR specs, with name defaulted
  93   (constructors () :type list)
  94   ;; name of copying function
  95   (copier-name nil :type (or symbol null))
  96   ;; name of type predicate
  97   (predicate-name nil :type (or symbol null))
  98   ;; the arguments to the :INCLUDE option, or NIL if no included
  99   ;; structure
 100   (include nil :type list)
 101   ;; properties used to define structure-like classes with an
 102   ;; arbitrary superclass and that may not have STRUCTURE-CLASS as the
 103   ;; metaclass. Syntax is:
 104   ;;    (superclass-name metaclass-name metaclass-constructor)
 105   (alternate-metaclass nil :type list)
 106   ;; a list of DEFSTRUCT-SLOT-DESCRIPTION objects for all slots
 107   ;; (including included ones)
 108   (slots () :type list)
 109   ;; a list of (NAME . INDEX) pairs for accessors of included structures
 110   (inherited-accessor-alist () :type list)
 111   ;; number of elements we've allocated (See also RAW-LENGTH, which is not
 112   ;; included in LENGTH.)
 113   (length 0 :type index)
 114   ;; General kind of implementation.
 115   (type 'structure :type (member structure vector list
 116                                  funcallable-structure))
 117
 118   ;; The next three slots are for :TYPE'd structures (which aren't
 119   ;; classes, DD-CLASS-P = NIL)
 120   ;;
 121   ;; vector element type
 122   (element-type t)
 123   ;; T if :NAMED was explicitly specified, NIL otherwise
 124   (named nil :type boolean)
 125   ;; any INITIAL-OFFSET option on this direct type
 126   (offset nil :type (or index null))
 127
 128   ;; the argument to the PRINT-FUNCTION option, or NIL if a
 129   ;; PRINT-FUNCTION option was given with no argument, or 0 if no
 130   ;; PRINT-FUNCTION option was given
 131   (print-function 0 :type (or cons symbol (member 0)))
 132   ;; the argument to the PRINT-OBJECT option, or NIL if a PRINT-OBJECT
 133   ;; option was given with no argument, or 0 if no PRINT-OBJECT option
 134   ;; was given
 135   (print-object 0 :type (or cons symbol (member 0)))
 136   ;; The number of untagged slots at the end.
 137   (raw-length 0 :type index)
 138   ;; the value of the :PURE option, or :UNSPECIFIED. This is only
 139   ;; meaningful if DD-CLASS-P = T.
 140   (pure :unspecified :type (member t nil :substructure :unspecified)))
 141 (def!method print-object ((x defstruct-description) stream)
 142   (print-unreadable-object (x stream :type t)
 143     (prin1 (dd-name x) stream)))
 144
 145 ;;; Does DD describe a structure with a class?
 146 (defun dd-class-p (dd)
 147   (member (dd-type dd)
 148           '(structure funcallable-structure)))
 149
 150 ;;; a type name which can be used when declaring things which operate
 151 ;;; on structure instances
 152 (defun dd-declarable-type (dd)
 153   (if (dd-class-p dd)
 154       ;; Native classes are known to the type system, and we can
 155       ;; declare them as types.
 156       (dd-name dd)
 157       ;; Structures layered on :TYPE LIST or :TYPE VECTOR aren't part
 158       ;; of the type system, so all we can declare is the underlying
 159       ;; LIST or VECTOR type.
 160       (dd-type dd)))
 161
 162 (defun dd-layout-or-lose (dd)
 163   (compiler-layout-or-lose (dd-name dd)))
 164 \f
 165 ;;;; DEFSTRUCT-SLOT-DESCRIPTION
 166
 167 ;;; A DEFSTRUCT-SLOT-DESCRIPTION holds compile-time information about
 168 ;;; a structure slot.
 169 (def!struct (defstruct-slot-description
 170              (:make-load-form-fun just-dump-it-normally)
 171              (:conc-name dsd-)
 172              (:copier nil)
 173              #-sb-xc-host (:pure t))
 174   ;; name of slot
 175   name
 176   ;; its position in the implementation sequence
 177   (index (missing-arg) :type fixnum)
 178   ;; the name of the accessor function
 179   ;;
 180   ;; (CMU CL had extra complexity here ("..or NIL if this accessor has
 181   ;; the same name as an inherited accessor (which we don't want to
 182   ;; shadow)") but that behavior doesn't seem to be specified by (or
 183   ;; even particularly consistent with) ANSI, so it's gone in SBCL.)
 184   (accessor-name nil)
 185   default                       ; default value expression
 186   (type t)                      ; declared type specifier
 187   (safe-p t :type boolean)      ; whether the slot is known to be
 188                                 ; always of the specified type
 189   ;; If this object does not describe a raw slot, this value is T.
 190   ;;
 191   ;; If this object describes a raw slot, this value is the type of the
 192   ;; value that the raw slot holds.
 193   (raw-type t :type (member t single-float double-float
 194                             #!+long-float long-float
 195                             complex-single-float complex-double-float
 196                             #!+long-float complex-long-float
 197                             sb!vm:word))
 198   (read-only nil :type (member t nil)))
 199 (def!method print-object ((x defstruct-slot-description) stream)
 200   (print-unreadable-object (x stream :type t)
 201     (prin1 (dsd-name x) stream)))
 202 \f
 203 ;;;; typed (non-class) structures
 204
 205 ;;; Return a type specifier we can use for testing :TYPE'd structures.
 206 (defun dd-lisp-type (defstruct)
 207   (ecase (dd-type defstruct)
 208     (list 'list)
 209     (vector `(simple-array ,(dd-element-type defstruct) (*)))))
 210 \f
 211 ;;;; shared machinery for inline and out-of-line slot accessor functions
 212
 213 ;;; Classic comment preserved for entertainment value:
 214 ;;;
 215 ;;; "A lie can travel halfway round the world while the truth is
 216 ;;; putting on its shoes." -- Mark Twain
 217
 218 (eval-when (#-sb-xc :compile-toplevel :load-toplevel :execute)
 219
 220   ;; information about how a slot of a given DSD-RAW-TYPE is to be accessed
 221   (defstruct raw-slot-data
 222     ;; the raw slot type, or T for a non-raw slot
 223     ;;
 224     ;; (Non-raw slots are in the ordinary place you'd expect, directly
 225     ;; indexed off the instance pointer.  Raw slots are indexed from the end
 226     ;; of the instance and skipped by GC.)
 227     (raw-type (missing-arg) :type (or symbol cons) :read-only t)
 228     ;; What operator is used to access a slot of this type?
 229     (accessor-name (missing-arg) :type symbol :read-only t)
 230     ;; How many words are each value of this type?
 231     (n-words (missing-arg) :type (and index (integer 1)) :read-only t)
 232     ;; Necessary alignment in units of words.  Note that instances
 233     ;; themselves are aligned by exactly two words, so specifying more
 234     ;; than two words here would not work.
 235     (alignment 1 :type (integer 1 2) :read-only t))
 236
 237   (defvar *raw-slot-data-list*
 238     #!+hppa
 239     nil
 240     #!-hppa
 241     (let ((double-float-alignment
 242            ;; white list of architectures that can load unaligned doubles:
 243            #!+(or x86 x86-64 ppc) 1
 244            ;; at least sparc, mips and alpha can't:
 245            #!-(or x86 x86-64 ppc) 2))
 246       (list
 247        (make-raw-slot-data :raw-type 'sb!vm:word
 248                            :accessor-name '%raw-instance-ref/word
 249                            :n-words 1)
 250        (make-raw-slot-data :raw-type 'single-float
 251                            :accessor-name '%raw-instance-ref/single
 252                            ;; KLUDGE: On 64 bit architectures, we
 253                            ;; could pack two SINGLE-FLOATs into the
 254                            ;; same word if raw slots were indexed
 255                            ;; using bytes instead of words.  However,
 256                            ;; I don't personally find optimizing
 257                            ;; SINGLE-FLOAT memory usage worthwile
 258                            ;; enough.  And the other datatype that
 259                            ;; would really benefit is (UNSIGNED-BYTE
 260                            ;; 32), but that is a subtype of FIXNUM, so
 261                            ;; we store it unraw anyway.  :-( -- DFL
 262                            :n-words 1)
 263        (make-raw-slot-data :raw-type 'double-float
 264                            :accessor-name '%raw-instance-ref/double
 265                            :alignment double-float-alignment
 266                            :n-words (/ 8 sb!vm:n-word-bytes))
 267        (make-raw-slot-data :raw-type 'complex-single-float
 268                            :accessor-name '%raw-instance-ref/complex-single
 269                            :n-words (/ 8 sb!vm:n-word-bytes))
 270        (make-raw-slot-data :raw-type 'complex-double-float
 271                            :accessor-name '%raw-instance-ref/complex-double
 272                            :alignment double-float-alignment
 273                            :n-words (/ 16 sb!vm:n-word-bytes))
 274        #!+long-float
 275        (make-raw-slot-data :raw-type long-float
 276                            :accessor-name '%raw-instance-ref/long
 277                            :n-words #!+x86 3 #!+sparc 4)
 278        #!+long-float
 279        (make-raw-slot-data :raw-type complex-long-float
 280                            :accessor-name '%raw-instance-ref/complex-long
 281                            :n-words #!+x86 6 #!+sparc 8)))))
 282 \f
 283 ;;;; the legendary DEFSTRUCT macro itself (both CL:DEFSTRUCT and its
 284 ;;;; close personal friend SB!XC:DEFSTRUCT)
 285
 286 ;;; Return a list of forms to install PRINT and MAKE-LOAD-FORM funs,
 287 ;;; mentioning them in the expansion so that they can be compiled.
 288 (defun class-method-definitions (defstruct)
 289   (let ((name (dd-name defstruct)))
 290     `((locally
 291         ;; KLUDGE: There's a FIND-CLASS DEFTRANSFORM for constant
 292         ;; class names which creates fast but non-cold-loadable,
 293         ;; non-compact code. In this context, we'd rather have
 294         ;; compact, cold-loadable code. -- WHN 19990928
 295         (declare (notinline find-classoid))
 296         ,@(let ((pf (dd-print-function defstruct))
 297                 (po (dd-print-object defstruct))
 298                 (x (gensym))
 299                 (s (gensym)))
 300             ;; Giving empty :PRINT-OBJECT or :PRINT-FUNCTION options
 301             ;; leaves PO or PF equal to NIL. The user-level effect is
 302             ;; to generate a PRINT-OBJECT method specialized for the type,
 303             ;; implementing the default #S structure-printing behavior.
 304             (when (or (eq pf nil) (eq po nil))
 305               (setf pf '(default-structure-print)
 306                     po 0))
 307             (flet (;; Given an arg from a :PRINT-OBJECT or :PRINT-FUNCTION
 308                    ;; option, return the value to pass as an arg to FUNCTION.
 309                    (farg (oarg)
 310                      (destructuring-bind (fun-name) oarg
 311                        fun-name)))
 312               (cond ((not (eql pf 0))
 313                      `((def!method print-object ((,x ,name) ,s)
 314                          (funcall #',(farg pf)
 315                                   ,x
 316                                   ,s
 317                                   *current-level-in-print*))))
 318                     ((not (eql po 0))
 319                      `((def!method print-object ((,x ,name) ,s)
 320                          (funcall #',(farg po) ,x ,s))))
 321                     (t nil))))
 322         ,@(let ((pure (dd-pure defstruct)))
 323             (cond ((eq pure t)
 324                    `((setf (layout-pure (classoid-layout
 325                                          (find-classoid ',name)))
 326                            t)))
 327                   ((eq pure :substructure)
 328                    `((setf (layout-pure (classoid-layout
 329                                          (find-classoid ',name)))
 330                            0)))))
 331         ,@(let ((def-con (dd-default-constructor defstruct)))
 332             (when (and def-con (not (dd-alternate-metaclass defstruct)))
 333               `((setf (structure-classoid-constructor (find-classoid ',name))
 334                       #',def-con))))))))
 335
 336 ;;; shared logic for CL:DEFSTRUCT and SB!XC:DEFSTRUCT
 337 (defmacro !expander-for-defstruct (name-and-options
 338                                    slot-descriptions
 339                                    expanding-into-code-for-xc-host-p)
 340   `(let ((name-and-options ,name-and-options)
 341          (slot-descriptions ,slot-descriptions)
 342          (expanding-into-code-for-xc-host-p
 343           ,expanding-into-code-for-xc-host-p))
 344      (let* ((dd (parse-defstruct-name-and-options-and-slot-descriptions
 345                  name-and-options
 346                  slot-descriptions))
 347             (name (dd-name dd)))
 348        (if (dd-class-p dd)
 349            (let ((inherits (inherits-for-structure dd)))
 350              `(progn
 351                 ;; Note we intentionally enforce package locks and
 352                 ;; call %DEFSTRUCT first, and especially before
 353                 ;; %COMPILER-DEFSTRUCT. %DEFSTRUCT has the tests (and
 354                 ;; resulting CERROR) for collisions with LAYOUTs which
 355                 ;; already exist in the runtime. If there are any
 356                 ;; collisions, we want the user's response to CERROR
 357                 ;; to control what happens. Especially, if the user
 358                 ;; responds to the collision with ABORT, we don't want
 359                 ;; %COMPILER-DEFSTRUCT to modify the definition of the
 360                 ;; class.
 361                 (with-single-package-locked-error
 362                     (:symbol ',name "defining ~A as a structure"))
 363                 (%defstruct ',dd ',inherits (sb!c:source-location))
 364                 (eval-when (:compile-toplevel :load-toplevel :execute)
 365                   (%compiler-defstruct ',dd ',inherits))
 366                 ,@(unless expanding-into-code-for-xc-host-p
 367                     (append ;; FIXME: We've inherited from CMU CL nonparallel
 368                             ;; code for creating copiers for typed and untyped
 369                             ;; structures. This should be fixed.
 370                             ;(copier-definition dd)
 371                             (constructor-definitions dd)
 372                             (class-method-definitions dd)))
 373                 ',name))
 374            `(progn
 375               (with-single-package-locked-error
 376                   (:symbol ',name "defining ~A as a structure"))
 377               (eval-when (:compile-toplevel :load-toplevel :execute)
 378                 (setf (info :typed-structure :info ',name) ',dd))
 379               (eval-when (:load-toplevel :execute)
 380                 (setf (info :source-location :typed-structure ',name)
 381                       (sb!c:source-location)))
 382               ,@(unless expanding-into-code-for-xc-host-p
 383                   (append (typed-accessor-definitions dd)
 384                           (typed-predicate-definitions dd)
 385                           (typed-copier-definitions dd)
 386                           (constructor-definitions dd)))
 387               ',name)))))
 388
 389 (sb!xc:defmacro defstruct (name-and-options &rest slot-descriptions)
 390   #!+sb-doc
 391   "DEFSTRUCT {Name | (Name Option*)} {Slot | (Slot [Default] {Key Value}*)}
 392    Define the structure type Name. Instances are created by MAKE-<name>,
 393    which takes &KEY arguments allowing initial slot values to the specified.
 394    A SETF'able function <name>-<slot> is defined for each slot to read and
 395    write slot values. <name>-p is a type predicate.
 396
 397    Popular DEFSTRUCT options (see manual for others):
 398
 399    (:CONSTRUCTOR Name)
 400    (:PREDICATE Name)
 401        Specify the name for the constructor or predicate.
 402
 403    (:CONSTRUCTOR Name Lambda-List)
 404        Specify the name and arguments for a BOA constructor
 405        (which is more efficient when keyword syntax isn't necessary.)
 406
 407    (:INCLUDE Supertype Slot-Spec*)
 408        Make this type a subtype of the structure type Supertype. The optional
 409        Slot-Specs override inherited slot options.
 410
 411    Slot options:
 412
 413    :TYPE Type-Spec
 414        Asserts that the value of this slot is always of the specified type.
 415
 416    :READ-ONLY {T | NIL}
 417        If true, no setter function is defined for this slot."
 418     (!expander-for-defstruct name-and-options slot-descriptions nil))
 419 #+sb-xc-host
 420 (defmacro sb!xc:defstruct (name-and-options &rest slot-descriptions)
 421   #!+sb-doc
 422   "Cause information about a target structure to be built into the
 423   cross-compiler."
 424   (!expander-for-defstruct name-and-options slot-descriptions t))
 425 \f
 426 ;;;; functions to generate code for various parts of DEFSTRUCT definitions
 427
 428 ;;; First, a helper to determine whether a name names an inherited
 429 ;;; accessor.
 430 (defun accessor-inherited-data (name defstruct)
 431   (assoc name (dd-inherited-accessor-alist defstruct) :test #'eq))
 432
 433 ;;; Return a list of forms which create a predicate function for a
 434 ;;; typed DEFSTRUCT.
 435 (defun typed-predicate-definitions (defstruct)
 436   (let ((name (dd-name defstruct))
 437         (predicate-name (dd-predicate-name defstruct))
 438         (argname (gensym)))
 439     (when (and predicate-name (dd-named defstruct))
 440       (let ((ltype (dd-lisp-type defstruct))
 441             (name-index (cdr (car (last (find-name-indices defstruct))))))
 442         `((defun ,predicate-name (,argname)
 443             (and (typep ,argname ',ltype)
 444                  ,(cond
 445                    ((subtypep ltype 'list)
 446                      `(do ((head (the ,ltype ,argname) (cdr head))
 447                            (i 0 (1+ i)))
 448                           ((or (not (consp head)) (= i ,name-index))
 449                            (and (consp head) (eq ',name (car head))))))
 450                    ((subtypep ltype 'vector)
 451                     `(and (= (length (the ,ltype ,argname))
 452                            ,(dd-length defstruct))
 453                           (eq ',name (aref (the ,ltype ,argname) ,name-index))))
 454                    (t (bug "Uncatered-for lisp type in typed DEFSTRUCT: ~S."
 455                            ltype))))))))))
 456
 457 ;;; Return a list of forms to create a copier function of a typed DEFSTRUCT.
 458 (defun typed-copier-definitions (defstruct)
 459   (when (dd-copier-name defstruct)
 460     `((setf (fdefinition ',(dd-copier-name defstruct)) #'copy-seq)
 461       (declaim (ftype function ,(dd-copier-name defstruct))))))
 462
 463 ;;; Return a list of function definitions for accessing and setting
 464 ;;; the slots of a typed DEFSTRUCT. The functions are proclaimed to be
 465 ;;; inline, and the types of their arguments and results are declared
 466 ;;; as well. We count on the compiler to do clever things with ELT.
 467 (defun typed-accessor-definitions (defstruct)
 468   (collect ((stuff))
 469     (let ((ltype (dd-lisp-type defstruct)))
 470       (dolist (slot (dd-slots defstruct))
 471         (let ((name (dsd-accessor-name slot))
 472               (index (dsd-index slot))
 473               (slot-type `(and ,(dsd-type slot)
 474                                ,(dd-element-type defstruct))))
 475           (let ((inherited (accessor-inherited-data name defstruct)))
 476             (cond
 477               ((not inherited)
 478                (stuff `(declaim (inline ,name (setf ,name))))
 479                ;; FIXME: The arguments in the next two DEFUNs should
 480                ;; be gensyms. (Otherwise e.g. if NEW-VALUE happened to
 481                ;; be the name of a special variable, things could get
 482                ;; weird.)
 483                (stuff `(defun ,name (structure)
 484                         (declare (type ,ltype structure))
 485                         (the ,slot-type (elt structure ,index))))
 486                (unless (dsd-read-only slot)
 487                  (stuff
 488                   `(defun (setf ,name) (new-value structure)
 489                     (declare (type ,ltype structure) (type ,slot-type new-value))
 490                     (setf (elt structure ,index) new-value)))))
 491               ((not (= (cdr inherited) index))
 492                (style-warn "~@<Non-overwritten accessor ~S does not access ~
 493                             slot with name ~S (accessing an inherited slot ~
 494                             instead).~:@>" name (dsd-name slot))))))))
 495     (stuff)))
 496 \f
 497 ;;;; parsing
 498
 499 (defun require-no-print-options-so-far (defstruct)
 500   (unless (and (eql (dd-print-function defstruct) 0)
 501                (eql (dd-print-object defstruct) 0))
 502     (error "No more than one of the following options may be specified:
 503   :PRINT-FUNCTION, :PRINT-OBJECT, :TYPE")))
 504
 505 ;;; Parse a single DEFSTRUCT option and store the results in DD.
 506 (defun parse-1-dd-option (option dd)
 507   (let ((args (rest option))
 508         (name (dd-name dd)))
 509     (case (first option)
 510       (:conc-name
 511        (destructuring-bind (&optional conc-name) args
 512          (setf (dd-conc-name dd)
 513                (if (symbolp conc-name)
 514                    conc-name
 515                    (make-symbol (string conc-name))))))
 516       (:constructor
 517        (destructuring-bind (&optional (cname (symbolicate "MAKE-" name))
 518                                       &rest stuff)
 519            args
 520          (push (cons cname stuff) (dd-constructors dd))))
 521       (:copier
 522        (destructuring-bind (&optional (copier (symbolicate "COPY-" name)))
 523            args
 524          (setf (dd-copier-name dd) copier)))
 525       (:predicate
 526        (destructuring-bind (&optional (predicate-name (symbolicate name "-P")))
 527            args
 528          (setf (dd-predicate-name dd) predicate-name)))
 529       (:include
 530        (when (dd-include dd)
 531          (error "more than one :INCLUDE option"))
 532        (setf (dd-include dd) args))
 533       (:print-function
 534        (require-no-print-options-so-far dd)
 535        (setf (dd-print-function dd)
 536              (the (or symbol cons) args)))
 537       (:print-object
 538        (require-no-print-options-so-far dd)
 539        (setf (dd-print-object dd)
 540              (the (or symbol cons) args)))
 541       (:type
 542        (destructuring-bind (type) args
 543          (cond ((member type '(list vector))
 544                 (setf (dd-element-type dd) t)
 545                 (setf (dd-type dd) type))
 546                ((and (consp type) (eq (first type) 'vector))
 547                 (destructuring-bind (vector vtype) type
 548                   (declare (ignore vector))
 549                   (setf (dd-element-type dd) vtype)
 550                   (setf (dd-type dd) 'vector)))
 551                (t
 552                 (error "~S is a bad :TYPE for DEFSTRUCT." type)))))
 553       (:named
 554        (error "The DEFSTRUCT option :NAMED takes no arguments."))
 555       (:initial-offset
 556        (destructuring-bind (offset) args
 557          (setf (dd-offset dd) offset)))
 558       (:pure
 559        (destructuring-bind (fun) args
 560          (setf (dd-pure dd) fun)))
 561       (t (error "unknown DEFSTRUCT option:~%  ~S" option)))))
 562
 563 ;;; Given name and options, return a DD holding that info.
 564 (defun parse-defstruct-name-and-options (name-and-options)
 565   (destructuring-bind (name &rest options) name-and-options
 566     (aver name) ; A null name doesn't seem to make sense here.
 567     (let ((dd (make-defstruct-description name)))
 568       (dolist (option options)
 569         (cond ((eq option :named)
 570                (setf (dd-named dd) t))
 571               ((consp option)
 572                (parse-1-dd-option option dd))
 573               ((member option '(:conc-name :constructor :copier :predicate))
 574                (parse-1-dd-option (list option) dd))
 575               (t
 576                (error "unrecognized DEFSTRUCT option: ~S" option))))
 577
 578       (case (dd-type dd)
 579         (structure
 580          (when (dd-offset dd)
 581            (error ":OFFSET can't be specified unless :TYPE is specified."))
 582          (unless (dd-include dd)
 583            ;; FIXME: It'd be cleaner to treat no-:INCLUDE as defaulting
 584            ;; to :INCLUDE STRUCTURE-OBJECT, and then let the general-case
 585            ;; (INCF (DD-LENGTH DD) (DD-LENGTH included-DD)) logic take
 586            ;; care of this. (Except that the :TYPE VECTOR and :TYPE
 587            ;; LIST cases, with their :NAMED and un-:NAMED flavors,
 588            ;; make that messy, alas.)
 589            (incf (dd-length dd))))
 590         (t
 591          (require-no-print-options-so-far dd)
 592          (when (dd-named dd)
 593            (incf (dd-length dd)))
 594          (let ((offset (dd-offset dd)))
 595            (when offset (incf (dd-length dd) offset)))))
 596
 597       (when (dd-include dd)
 598         (frob-dd-inclusion-stuff dd))
 599
 600       dd)))
 601
 602 ;;; Given name and options and slot descriptions (and possibly doc
 603 ;;; string at the head of slot descriptions) return a DD holding that
 604 ;;; info.
 605 (defun parse-defstruct-name-and-options-and-slot-descriptions
 606     (name-and-options slot-descriptions)
 607   (let ((result (parse-defstruct-name-and-options (if (atom name-and-options)
 608                                                       (list name-and-options)
 609                                                       name-and-options))))
 610     (when (stringp (car slot-descriptions))
 611       (setf (dd-doc result) (pop slot-descriptions)))
 612     (dolist (slot-description slot-descriptions)
 613       (allocate-1-slot result (parse-1-dsd result slot-description)))
 614     result))
 615 \f
 616 ;;;; stuff to parse slot descriptions
 617
 618 ;;; Parse a slot description for DEFSTRUCT, add it to the description
 619 ;;; and return it. If supplied, SLOT is a pre-initialized DSD
 620 ;;; that we modify to get the new slot. This is supplied when handling
 621 ;;; included slots.
 622 (defun parse-1-dsd (defstruct spec &optional
 623                     (slot (make-defstruct-slot-description :name ""
 624                                                            :index 0
 625                                                            :type t)))
 626   (multiple-value-bind (name default default-p type type-p read-only ro-p)
 627       (typecase spec
 628         (symbol
 629          (when (keywordp spec)
 630            (style-warn "Keyword slot name indicates probable syntax ~
 631                         error in DEFSTRUCT: ~S."
 632                        spec))
 633          spec)
 634         (cons
 635          (destructuring-bind
 636                (name
 637                 &optional (default nil default-p)
 638                 &key (type nil type-p) (read-only nil ro-p))
 639              spec
 640            (values name
 641                    default default-p
 642                    (uncross type) type-p
 643                    read-only ro-p)))
 644         (t (error 'simple-program-error
 645                   :format-control "in DEFSTRUCT, ~S is not a legal slot ~
 646                                    description."
 647                   :format-arguments (list spec))))
 648
 649     (when (find name (dd-slots defstruct)
 650                 :test #'string=
 651                 :key (lambda (x) (symbol-name (dsd-name x))))
 652       (error 'simple-program-error
 653              :format-control "duplicate slot name ~S"
 654              :format-arguments (list name)))
 655     (setf (dsd-name slot) name)
 656     (setf (dd-slots defstruct) (nconc (dd-slots defstruct) (list slot)))
 657
 658     (let ((accessor-name (if (dd-conc-name defstruct)
 659                              (symbolicate (dd-conc-name defstruct) name)
 660                              name))
 661           (predicate-name (dd-predicate-name defstruct)))
 662       (setf (dsd-accessor-name slot) accessor-name)
 663       (when (eql accessor-name predicate-name)
 664         ;; Some adventurous soul has named a slot so that its accessor
 665         ;; collides with the structure type predicate. ANSI doesn't
 666         ;; specify what to do in this case. As of 2001-09-04, Martin
 667         ;; Atzmueller reports that CLISP and Lispworks both give
 668         ;; priority to the slot accessor, so that the predicate is
 669         ;; overwritten. We might as well do the same (as well as
 670         ;; signalling a warning).
 671         (style-warn
 672          "~@<The structure accessor name ~S is the same as the name of the ~
 673           structure type predicate. ANSI doesn't specify what to do in ~
 674           this case. We'll overwrite the type predicate with the slot ~
 675           accessor, but you can't rely on this behavior, so it'd be wise to ~
 676           remove the ambiguity in your code.~@:>"
 677          accessor-name)
 678         (setf (dd-predicate-name defstruct) nil))
 679       ;; FIXME: It would be good to check for name collisions here, but
 680       ;; the easy check,
 681       ;;x#-sb-xc-host
 682       ;;x(when (and (fboundp accessor-name)
 683       ;;x           (not (accessor-inherited-data accessor-name defstruct)))
 684       ;;x  (style-warn "redefining ~S in DEFSTRUCT" accessor-name)))
 685       ;; which was done until sbcl-0.8.11.18 or so, is wrong: it causes
 686       ;; a warning at MACROEXPAND time, when instead the warning should
 687       ;; occur not just because the code was constructed, but because it
 688       ;; is actually compiled or loaded.
 689       )
 690
 691     (when default-p
 692       (setf (dsd-default slot) default))
 693     (when type-p
 694       (setf (dsd-type slot)
 695             (if (eq (dsd-type slot) t)
 696                 type
 697                 `(and ,(dsd-type slot) ,type))))
 698     (when ro-p
 699       (if read-only
 700           (setf (dsd-read-only slot) t)
 701           (when (dsd-read-only slot)
 702             (error "~@<The slot ~S is :READ-ONLY in superclass, and so must ~
 703                        be :READ-ONLY in subclass.~:@>"
 704                    (dsd-name slot)))))
 705     slot))
 706
 707 ;;; When a value of type TYPE is stored in a structure, should it be
 708 ;;; stored in a raw slot?  Return the matching RAW-SLOT-DATA structure
 709 ;; if TYPE should be stored in a raw slot, or NIL if not.
 710 (defun structure-raw-slot-data (type)
 711   (multiple-value-bind (fixnum? fixnum-certain?)
 712       (sb!xc:subtypep type 'fixnum)
 713     ;; (The extra test for FIXNUM-CERTAIN? here is intended for
 714     ;; bootstrapping the system. In particular, in sbcl-0.6.2, we set up
 715     ;; LAYOUT before FIXNUM is defined, and so could bogusly end up
 716     ;; putting INDEX-typed values into raw slots if we didn't test
 717     ;; FIXNUM-CERTAIN?.)
 718     (if (or fixnum? (not fixnum-certain?))
 719         nil
 720         (dolist (data *raw-slot-data-list*)
 721           (when (sb!xc:subtypep type (raw-slot-data-raw-type data))
 722             (return data))))))
 723
 724 ;;; Allocate storage for a DSD in DD. This is where we decide whether
 725 ;;; a slot is raw or not. Raw objects are aligned on the unit of their size.
 726 (defun allocate-1-slot (dd dsd)
 727   (let ((rsd
 728          (if (eq (dd-type dd) 'structure)
 729              (structure-raw-slot-data (dsd-type dsd))
 730              nil)))
 731     (cond
 732       ((null rsd)
 733         (setf (dsd-index dsd) (dd-length dd))
 734         (incf (dd-length dd)))
 735       (t
 736         (let* ((words (raw-slot-data-n-words rsd))
 737                (alignment (raw-slot-data-alignment rsd))
 738                (off (rem (dd-raw-length dd) alignment)))
 739           (unless (zerop off)
 740             (incf (dd-raw-length dd) (- alignment off)))
 741           (setf (dsd-raw-type dsd) (raw-slot-data-raw-type rsd))
 742           (setf (dsd-index dsd) (dd-raw-length dd))
 743           (incf (dd-raw-length dd) words)))))
 744   (values))
 745
 746 (defun typed-structure-info-or-lose (name)
 747   (or (info :typed-structure :info name)
 748       (error ":TYPE'd DEFSTRUCT ~S not found for inclusion." name)))
 749
 750 ;;; Process any included slots pretty much like they were specified.
 751 ;;; Also inherit various other attributes.
 752 (defun frob-dd-inclusion-stuff (dd)
 753   (destructuring-bind (included-name &rest modified-slots) (dd-include dd)
 754     (let* ((type (dd-type dd))
 755            (included-structure
 756             (if (dd-class-p dd)
 757                 (layout-info (compiler-layout-or-lose included-name))
 758                 (typed-structure-info-or-lose included-name))))
 759
 760       ;; checks on legality
 761       (unless (and (eq type (dd-type included-structure))
 762                    (type= (specifier-type (dd-element-type included-structure))
 763                           (specifier-type (dd-element-type dd))))
 764         (error ":TYPE option mismatch between structures ~S and ~S"
 765                (dd-name dd) included-name))
 766       (let ((included-classoid (find-classoid included-name nil)))
 767         (when included-classoid
 768           ;; It's not particularly well-defined to :INCLUDE any of the
 769           ;; CMU CL INSTANCE weirdosities like CONDITION or
 770           ;; GENERIC-FUNCTION, and it's certainly not ANSI-compliant.
 771           (let* ((included-layout (classoid-layout included-classoid))
 772                  (included-dd (layout-info included-layout)))
 773             (when (and (dd-alternate-metaclass included-dd)
 774                        ;; As of sbcl-0.pre7.73, anyway, STRUCTURE-OBJECT
 775                        ;; is represented with an ALTERNATE-METACLASS. But
 776                        ;; it's specifically OK to :INCLUDE (and PCL does)
 777                        ;; so in this one case, it's OK to include
 778                        ;; something with :ALTERNATE-METACLASS after all.
 779                        (not (eql included-name 'structure-object)))
 780               (error "can't :INCLUDE class ~S (has alternate metaclass)"
 781                      included-name)))))
 782
 783       (incf (dd-length dd) (dd-length included-structure))
 784       (when (dd-class-p dd)
 785         (let ((mc (rest (dd-alternate-metaclass included-structure))))
 786           (when (and mc (not (dd-alternate-metaclass dd)))
 787             (setf (dd-alternate-metaclass dd)
 788                   (cons included-name mc))))
 789         (when (eq (dd-pure dd) :unspecified)
 790           (setf (dd-pure dd) (dd-pure included-structure)))
 791         (setf (dd-raw-length dd) (dd-raw-length included-structure)))
 792
 793       (setf (dd-inherited-accessor-alist dd)
 794             (dd-inherited-accessor-alist included-structure))
 795       (dolist (included-slot (dd-slots included-structure))
 796         (let* ((included-name (dsd-name included-slot))
 797                (modified (or (find included-name modified-slots
 798                                    :key (lambda (x) (if (atom x) x (car x)))
 799                                    :test #'string=)
 800                              `(,included-name))))
 801           ;; We stash away an alist of accessors to parents' slots
 802           ;; that have already been created to avoid conflicts later
 803           ;; so that structures with :INCLUDE and :CONC-NAME (and
 804           ;; other edge cases) can work as specified.
 805           (when (dsd-accessor-name included-slot)
 806             ;; the "oldest" (i.e. highest up the tree of inheritance)
 807             ;; will prevail, so don't push new ones on if they
 808             ;; conflict.
 809             (pushnew (cons (dsd-accessor-name included-slot)
 810                            (dsd-index included-slot))
 811                      (dd-inherited-accessor-alist dd)
 812                      :test #'eq :key #'car))
 813           (let ((new-slot (parse-1-dsd dd
 814                                        modified
 815                                        (copy-structure included-slot))))
 816             (when (and (neq (dsd-type new-slot) (dsd-type included-slot))
 817                        (not (sb!xc:subtypep (dsd-type included-slot)
 818                                             (dsd-type new-slot)))
 819                        (dsd-safe-p included-slot))
 820               (setf (dsd-safe-p new-slot) nil)
 821               ;; XXX: notify?
 822               )))))))
 823 \f
 824 ;;;; various helper functions for setting up DEFSTRUCTs
 825
 826 ;;; This function is called at macroexpand time to compute the INHERITS
 827 ;;; vector for a structure type definition.
 828 (defun inherits-for-structure (info)
 829   (declare (type defstruct-description info))
 830   (let* ((include (dd-include info))
 831          (superclass-opt (dd-alternate-metaclass info))
 832          (super
 833           (if include
 834               (compiler-layout-or-lose (first include))
 835               (classoid-layout (find-classoid
 836                                 (or (first superclass-opt)
 837                                     'structure-object))))))
 838     (case (dd-name info)
 839       ((ansi-stream)
 840        (concatenate 'simple-vector
 841                     (layout-inherits super)
 842                     (vector super (classoid-layout (find-classoid 'stream)))))
 843       ((fd-stream)
 844        (concatenate 'simple-vector
 845                     (layout-inherits super)
 846                     (vector super
 847                             (classoid-layout (find-classoid 'file-stream)))))
 848       ((sb!impl::string-input-stream
 849         sb!impl::string-output-stream
 850         sb!impl::fill-pointer-output-stream)
 851        (concatenate 'simple-vector
 852                     (layout-inherits super)
 853                     (vector super
 854                             (classoid-layout (find-classoid 'string-stream)))))
 855       (t (concatenate 'simple-vector
 856                       (layout-inherits super)
 857                       (vector super))))))
 858
 859 ;;; Do miscellaneous (LOAD EVAL) time actions for the structure
 860 ;;; described by DD. Create the class and LAYOUT, checking for
 861 ;;; incompatible redefinition. Define those functions which are
 862 ;;; sufficiently stereotyped that we can implement them as standard
 863 ;;; closures.
 864 (defun %defstruct (dd inherits source-location)
 865   (declare (type defstruct-description dd))
 866
 867   ;; We set up LAYOUTs even in the cross-compilation host.
 868   (multiple-value-bind (classoid layout old-layout)
 869       (ensure-structure-class dd inherits "current" "new")
 870     (cond ((not old-layout)
 871            (unless (eq (classoid-layout classoid) layout)
 872              (register-layout layout)))
 873           (t
 874            (let ((old-dd (layout-info old-layout)))
 875              (when (defstruct-description-p old-dd)
 876                (dolist (slot (dd-slots old-dd))
 877                  (fmakunbound (dsd-accessor-name slot))
 878                  (unless (dsd-read-only slot)
 879                    (fmakunbound `(setf ,(dsd-accessor-name slot)))))))
 880            (%redefine-defstruct classoid old-layout layout)
 881            (setq layout (classoid-layout classoid))))
 882     (setf (find-classoid (dd-name dd)) classoid)
 883
 884     (sb!c:with-source-location (source-location)
 885       (setf (layout-source-location layout) source-location))
 886
 887     ;; Various other operations only make sense on the target SBCL.
 888     #-sb-xc-host
 889     (%target-defstruct dd layout))
 890
 891   (values))
 892 \f
 893 ;;; Return a form describing the writable place used for this slot
 894 ;;; in the instance named INSTANCE-NAME.
 895 (defun %accessor-place-form (dd dsd instance-name)
 896   (let (;; the operator that we'll use to access a typed slot
 897         (ref (ecase (dd-type dd)
 898                (structure '%instance-ref)
 899                (list 'nth-but-with-sane-arg-order)
 900                (vector 'aref)))
 901         (raw-type (dsd-raw-type dsd)))
 902     (if (eq raw-type t) ; if not raw slot
 903         `(,ref ,instance-name ,(dsd-index dsd))
 904         (let* ((raw-slot-data (find raw-type *raw-slot-data-list*
 905                                     :key #'raw-slot-data-raw-type
 906                                     :test #'equal))
 907                (raw-slot-accessor (raw-slot-data-accessor-name raw-slot-data)))
 908           `(,raw-slot-accessor ,instance-name ,(dsd-index dsd))))))
 909
 910 ;;; Return source transforms for the reader and writer functions of
 911 ;;; the slot described by DSD. They should be inline expanded, but
 912 ;;; source transforms work faster.
 913 (defun slot-accessor-transforms (dd dsd)
 914   (let ((accessor-place-form (%accessor-place-form dd dsd
 915                                                    `(the ,(dd-name dd) instance)))
 916         (dsd-type (dsd-type dsd))
 917         (value-the (if (dsd-safe-p dsd) 'truly-the 'the)))
 918     (values (sb!c:source-transform-lambda (instance)
 919               `(,value-the ,dsd-type ,(subst instance 'instance
 920                                              accessor-place-form)))
 921             (sb!c:source-transform-lambda (new-value instance)
 922               (destructuring-bind (accessor-name &rest accessor-args)
 923                   accessor-place-form
 924                 (once-only ((new-value new-value)
 925                             (instance instance))
 926                   `(,(info :setf :inverse accessor-name)
 927                      ,@(subst instance 'instance accessor-args)
 928                      (the ,dsd-type ,new-value))))))))
 929
 930 ;;; Return a LAMBDA form which can be used to set a slot.
 931 (defun slot-setter-lambda-form (dd dsd)
 932   `(lambda (new-value instance)
 933      ,(funcall (nth-value 1 (slot-accessor-transforms dd dsd))
 934                '(dummy new-value instance))))
 935
 936 ;;; core compile-time setup of any class with a LAYOUT, used even by
 937 ;;; !DEFSTRUCT-WITH-ALTERNATE-METACLASS weirdosities
 938 (defun %compiler-set-up-layout (dd
 939                                 &optional
 940                                 ;; Several special cases
 941                                 ;; (STRUCTURE-OBJECT itself, and
 942                                 ;; structures with alternate
 943                                 ;; metaclasses) call this function
 944                                 ;; directly, and they're all at the
 945                                 ;; base of the instance class
 946                                 ;; structure, so this is a handy
 947                                 ;; default.  (But note
 948                                 ;; FUNCALLABLE-STRUCTUREs need
 949                                 ;; assistance here)
 950                                 (inherits (vector (find-layout t))))
 951
 952   (multiple-value-bind (classoid layout old-layout)
 953       (multiple-value-bind (clayout clayout-p)
 954           (info :type :compiler-layout (dd-name dd))
 955         (ensure-structure-class dd
 956                                 inherits
 957                                 (if clayout-p "previously compiled" "current")
 958                                 "compiled"
 959                                 :compiler-layout clayout))
 960     (cond (old-layout
 961            (undefine-structure (layout-classoid old-layout))
 962            (when (and (classoid-subclasses classoid)
 963                       (not (eq layout old-layout)))
 964              (collect ((subs))
 965                       (dohash (classoid layout (classoid-subclasses classoid))
 966                         (declare (ignore layout))
 967                         (undefine-structure classoid)
 968                         (subs (classoid-proper-name classoid)))
 969                       (when (subs)
 970                         (warn "removing old subclasses of ~S:~%  ~S"
 971                               (classoid-name classoid)
 972                               (subs))))))
 973           (t
 974            (unless (eq (classoid-layout classoid) layout)
 975              (register-layout layout :invalidate nil))
 976            (setf (find-classoid (dd-name dd)) classoid)))
 977
 978     ;; At this point the class should be set up in the INFO database.
 979     ;; But the logic that enforces this is a little tangled and
 980     ;; scattered, so it's not obvious, so let's check.
 981     (aver (find-classoid (dd-name dd) nil))
 982
 983     (setf (info :type :compiler-layout (dd-name dd)) layout))
 984
 985   (values))
 986
 987 ;;; Do (COMPILE LOAD EVAL)-time actions for the normal (not
 988 ;;; ALTERNATE-LAYOUT) DEFSTRUCT described by DD.
 989 (defun %compiler-defstruct (dd inherits)
 990   (declare (type defstruct-description dd))
 991
 992   (%compiler-set-up-layout dd inherits)
 993
 994   (let* ((dtype (dd-declarable-type dd)))
 995
 996     (let ((copier-name (dd-copier-name dd)))
 997       (when copier-name
 998         (sb!xc:proclaim `(ftype (sfunction (,dtype) ,dtype) ,copier-name))))
 999
1000     (let ((predicate-name (dd-predicate-name dd)))
1001       (when predicate-name
1002         (sb!xc:proclaim `(ftype (sfunction (t) boolean) ,predicate-name))
1003         ;; Provide inline expansion (or not).
1004         (ecase (dd-type dd)
1005           ((structure funcallable-structure)
1006            ;; Let the predicate be inlined.
1007            (setf (info :function :inline-expansion-designator predicate-name)
1008                  (lambda ()
1009                    `(lambda (x)
1010                       ;; This dead simple definition works because the
1011                       ;; type system knows how to generate inline type
1012                       ;; tests for instances.
1013                       (typep x ',(dd-name dd))))
1014                  (info :function :inlinep predicate-name)
1015                  :inline))
1016           ((list vector)
1017            ;; Just punt. We could provide inline expansions for :TYPE
1018            ;; LIST and :TYPE VECTOR predicates too, but it'd be a
1019            ;; little messier and we don't bother. (Does anyway use
1020            ;; typed DEFSTRUCTs at all, let alone for high
1021            ;; performance?)
1022            ))))
1023
1024     (dolist (dsd (dd-slots dd))
1025       (let* ((accessor-name (dsd-accessor-name dsd))
1026              (dsd-type (dsd-type dsd)))
1027         (when accessor-name
1028           (let ((inherited (accessor-inherited-data accessor-name dd)))
1029             (cond
1030               ((not inherited)
1031                (multiple-value-bind (reader-designator writer-designator)
1032                    (slot-accessor-transforms dd dsd)
1033                  (sb!xc:proclaim `(ftype (sfunction (,dtype) ,dsd-type)
1034                                    ,accessor-name))
1035                  (setf (info :function :source-transform accessor-name)
1036                        reader-designator)
1037                  (unless (dsd-read-only dsd)
1038                    (let ((setf-accessor-name `(setf ,accessor-name)))
1039                      (sb!xc:proclaim
1040                       `(ftype (sfunction (,dsd-type ,dtype) ,dsd-type)
1041                         ,setf-accessor-name))
1042                      (setf (info :function :source-transform setf-accessor-name)
1043                            writer-designator)))))
1044               ((not (= (cdr inherited) (dsd-index dsd)))
1045                (style-warn "~@<Non-overwritten accessor ~S does not access ~
1046                             slot with name ~S (accessing an inherited slot ~
1047                             instead).~:@>"
1048                            accessor-name
1049                            (dsd-name dsd)))))))))
1050   (values))
1051 \f
1052 ;;;; redefinition stuff
1053
1054 ;;; Compare the slots of OLD and NEW, returning 3 lists of slot names:
1055 ;;;   1. Slots which have moved,
1056 ;;;   2. Slots whose type has changed,
1057 ;;;   3. Deleted slots.
1058 (defun compare-slots (old new)
1059   (let* ((oslots (dd-slots old))
1060          (nslots (dd-slots new))
1061          (onames (mapcar #'dsd-name oslots))
1062          (nnames (mapcar #'dsd-name nslots)))
1063     (collect ((moved)
1064               (retyped))
1065       (dolist (name (intersection onames nnames))
1066         (let ((os (find name oslots :key #'dsd-name :test #'string=))
1067               (ns (find name nslots :key #'dsd-name :test #'string=)))
1068           (unless (sb!xc:subtypep (dsd-type ns) (dsd-type os))
1069             (retyped name))
1070           (unless (and (= (dsd-index os) (dsd-index ns))
1071                        (eq (dsd-raw-type os) (dsd-raw-type ns)))
1072             (moved name))))
1073       (values (moved)
1074               (retyped)
1075               (set-difference onames nnames :test #'string=)))))
1076
1077 ;;; If we are redefining a structure with different slots than in the
1078 ;;; currently loaded version, give a warning and return true.
1079 (defun redefine-structure-warning (classoid old new)
1080   (declare (type defstruct-description old new)
1081            (type classoid classoid)
1082            (ignore classoid))
1083   (let ((name (dd-name new)))
1084     (multiple-value-bind (moved retyped deleted) (compare-slots old new)
1085       (when (or moved retyped deleted)
1086         (warn
1087          "incompatibly redefining slots of structure class ~S~@
1088           Make sure any uses of affected accessors are recompiled:~@
1089           ~@[  These slots were moved to new positions:~%    ~S~%~]~
1090           ~@[  These slots have new incompatible types:~%    ~S~%~]~
1091           ~@[  These slots were deleted:~%    ~S~%~]"
1092          name moved retyped deleted)
1093         t))))
1094
1095 ;;; This function is called when we are incompatibly redefining a
1096 ;;; structure CLASS to have the specified NEW-LAYOUT. We signal an
1097 ;;; error with some proceed options and return the layout that should
1098 ;;; be used.
1099 (defun %redefine-defstruct (classoid old-layout new-layout)
1100   (declare (type classoid classoid)
1101            (type layout old-layout new-layout))
1102   (let ((name (classoid-proper-name classoid)))
1103     (restart-case
1104         (error "~@<attempt to redefine the ~S class ~S incompatibly with the current definition~:@>"
1105                'structure-object
1106                name)
1107       (continue ()
1108        :report (lambda (s)
1109                  (format s
1110                          "~@<Use the new definition of ~S, invalidating ~
1111                           already-loaded code and instances.~@:>"
1112                          name))
1113        (register-layout new-layout))
1114       (recklessly-continue ()
1115        :report (lambda (s)
1116                  (format s
1117                          "~@<Use the new definition of ~S as if it were ~
1118                           compatible, allowing old accessors to use new ~
1119                           instances and allowing new accessors to use old ~
1120                           instances.~@:>"
1121                          name))
1122        ;; classic CMU CL warning: "Any old ~S instances will be in a bad way.
1123        ;; I hope you know what you're doing..."
1124        (register-layout new-layout
1125                         :invalidate nil
1126                         :destruct-layout old-layout))
1127       (clobber-it ()
1128        ;; FIXME: deprecated 2002-10-16, and since it's only interactive
1129        ;; hackery instead of a supported feature, can probably be deleted
1130        ;; in early 2003
1131        :report "(deprecated synonym for RECKLESSLY-CONTINUE)"
1132        (register-layout new-layout
1133                         :invalidate nil
1134                         :destruct-layout old-layout))))
1135   (values))
1136
1137 ;;; This is called when we are about to define a structure class. It
1138 ;;; returns a (possibly new) class object and the layout which should
1139 ;;; be used for the new definition (may be the current layout, and
1140 ;;; also might be an uninstalled forward referenced layout.) The third
1141 ;;; value is true if this is an incompatible redefinition, in which
1142 ;;; case it is the old layout.
1143 (defun ensure-structure-class (info inherits old-context new-context
1144                                     &key compiler-layout)
1145   (multiple-value-bind (class old-layout)
1146       (destructuring-bind
1147           (&optional
1148            name
1149            (class 'structure-classoid)
1150            (constructor 'make-structure-classoid))
1151           (dd-alternate-metaclass info)
1152         (declare (ignore name))
1153         (insured-find-classoid (dd-name info)
1154                                (if (eq class 'structure-classoid)
1155                                    (lambda (x)
1156                                      (sb!xc:typep x 'structure-classoid))
1157                                    (lambda (x)
1158                                      (sb!xc:typep x (find-classoid class))))
1159                                (fdefinition constructor)))
1160     (setf (classoid-direct-superclasses class)
1161           (case (dd-name info)
1162             ((ansi-stream
1163               fd-stream
1164               sb!impl::string-input-stream sb!impl::string-output-stream
1165               sb!impl::fill-pointer-output-stream)
1166              (list (layout-classoid (svref inherits (1- (length inherits))))
1167                    (layout-classoid (svref inherits (- (length inherits) 2)))))
1168             (t
1169              (list (layout-classoid
1170                     (svref inherits (1- (length inherits))))))))
1171     (let ((new-layout (make-layout :classoid class
1172                                    :inherits inherits
1173                                    :depthoid (length inherits)
1174                                    :length (+ (dd-length info)
1175                                               (dd-raw-length info))
1176                                    :n-untagged-slots (dd-raw-length info)
1177                                    :info info))
1178           (old-layout (or compiler-layout old-layout)))
1179       (cond
1180        ((not old-layout)
1181         (values class new-layout nil))
1182        (;; This clause corresponds to an assertion in REDEFINE-LAYOUT-WARNING
1183         ;; of classic CMU CL. I moved it out to here because it was only
1184         ;; exercised in this code path anyway. -- WHN 19990510
1185         (not (eq (layout-classoid new-layout) (layout-classoid old-layout)))
1186         (error "shouldn't happen: weird state of OLD-LAYOUT?"))
1187        ((not *type-system-initialized*)
1188         (setf (layout-info old-layout) info)
1189         (values class old-layout nil))
1190        ((redefine-layout-warning old-context
1191                                  old-layout
1192                                  new-context
1193                                  (layout-length new-layout)
1194                                  (layout-inherits new-layout)
1195                                  (layout-depthoid new-layout)
1196                                  (layout-n-untagged-slots new-layout))
1197         (values class new-layout old-layout))
1198        (t
1199         (let ((old-info (layout-info old-layout)))
1200           (typecase old-info
1201             ((or defstruct-description)
1202              (cond ((redefine-structure-warning class old-info info)
1203                     (values class new-layout old-layout))
1204                    (t
1205                     (setf (layout-info old-layout) info)
1206                     (values class old-layout nil))))
1207             (null
1208              (setf (layout-info old-layout) info)
1209              (values class old-layout nil))
1210             (t
1211              (error "shouldn't happen! strange thing in LAYOUT-INFO:~%  ~S"
1212                     old-layout)
1213              (values class new-layout old-layout)))))))))
1214
1215 ;;; Blow away all the compiler info for the structure CLASS. Iterate
1216 ;;; over this type, clearing the compiler structure type info, and
1217 ;;; undefining all the associated functions.
1218 (defun undefine-structure (class)
1219   (let ((info (layout-info (classoid-layout class))))
1220     (when (defstruct-description-p info)
1221       (let ((type (dd-name info)))
1222         (remhash type *typecheckfuns*)
1223         (setf (info :type :compiler-layout type) nil)
1224         (undefine-fun-name (dd-copier-name info))
1225         (undefine-fun-name (dd-predicate-name info))
1226         (dolist (slot (dd-slots info))
1227           (let ((fun (dsd-accessor-name slot)))
1228             (unless (accessor-inherited-data fun info)
1229               (undefine-fun-name fun)
1230               (unless (dsd-read-only slot)
1231                 (undefine-fun-name `(setf ,fun)))))))
1232       ;; Clear out the SPECIFIER-TYPE cache so that subsequent
1233       ;; references are unknown types.
1234       (values-specifier-type-cache-clear)))
1235   (values))
1236 \f
1237 ;;; Return a list of pairs (name . index). Used for :TYPE'd
1238 ;;; constructors to find all the names that we have to splice in &
1239 ;;; where. Note that these types don't have a layout, so we can't look
1240 ;;; at LAYOUT-INHERITS.
1241 (defun find-name-indices (defstruct)
1242   (collect ((res))
1243     (let ((infos ()))
1244       (do ((info defstruct
1245                  (typed-structure-info-or-lose (first (dd-include info)))))
1246           ((not (dd-include info))
1247            (push info infos))
1248         (push info infos))
1249
1250       (let ((i 0))
1251         (dolist (info infos)
1252           (incf i (or (dd-offset info) 0))
1253           (when (dd-named info)
1254             (res (cons (dd-name info) i)))
1255           (setq i (dd-length info)))))
1256
1257     (res)))
1258 \f
1259 ;;; These functions are called to actually make a constructor after we
1260 ;;; have processed the arglist. The correct variant (according to the
1261 ;;; DD-TYPE) should be called. The function is defined with the
1262 ;;; specified name and arglist. VARS and TYPES are used for argument
1263 ;;; type declarations. VALUES are the values for the slots (in order.)
1264 ;;;
1265 ;;; This is split three ways because:
1266 ;;;   * LIST & VECTOR structures need "name" symbols stuck in at
1267 ;;;     various weird places, whereas STRUCTURE structures have
1268 ;;;     a LAYOUT slot.
1269 ;;;   * We really want to use LIST to make list structures, instead of
1270 ;;;     MAKE-LIST/(SETF ELT). (We can't in general use VECTOR in an
1271 ;;;     analogous way, since VECTOR makes a SIMPLE-VECTOR and vector-typed
1272 ;;;     structures can have arbitrary subtypes of VECTOR, not necessarily
1273 ;;;     SIMPLE-VECTOR.)
1274 ;;;   * STRUCTURE structures can have raw slots that must also be
1275 ;;;     allocated and indirectly referenced.
1276 (defun create-vector-constructor (dd cons-name arglist vars types values)
1277   (let ((temp (gensym))
1278         (etype (dd-element-type dd)))
1279     `(defun ,cons-name ,arglist
1280        (declare ,@(mapcar (lambda (var type) `(type (and ,type ,etype) ,var))
1281                           vars types))
1282        (let ((,temp (make-array ,(dd-length dd)
1283                                 :element-type ',(dd-element-type dd))))
1284          ,@(mapcar (lambda (x)
1285                      `(setf (aref ,temp ,(cdr x))  ',(car x)))
1286                    (find-name-indices dd))
1287          ,@(mapcar (lambda (dsd value)
1288                      (unless (eq value '.do-not-initialize-slot.)
1289                          `(setf (aref ,temp ,(dsd-index dsd)) ,value)))
1290                    (dd-slots dd) values)
1291          ,temp))))
1292 (defun create-list-constructor (dd cons-name arglist vars types values)
1293   (let ((vals (make-list (dd-length dd) :initial-element nil)))
1294     (dolist (x (find-name-indices dd))
1295       (setf (elt vals (cdr x)) `',(car x)))
1296     (loop for dsd in (dd-slots dd) and val in values do
1297       (setf (elt vals (dsd-index dsd))
1298             (if (eq val '.do-not-initialize-slot.) 0 val)))
1299
1300     `(defun ,cons-name ,arglist
1301        (declare ,@(mapcar (lambda (var type) `(type ,type ,var)) vars types))
1302        (list ,@vals))))
1303 (defun create-structure-constructor (dd cons-name arglist vars types values)
1304   (let* ((instance (gensym "INSTANCE")))
1305     `(defun ,cons-name ,arglist
1306        (declare ,@(mapcar (lambda (var type) `(type ,type ,var))
1307                           vars types))
1308        (let ((,instance (truly-the ,(dd-name dd)
1309                           (%make-instance-with-layout
1310                            (%delayed-get-compiler-layout ,(dd-name dd))))))
1311          ,@(mapcar (lambda (dsd value)
1312                      ;; (Note that we can't in general use the
1313                      ;; ordinary named slot setter function here
1314                      ;; because the slot might be :READ-ONLY, so we
1315                      ;; whip up new LAMBDA representations of slot
1316                      ;; setters for the occasion.)
1317                      (unless (eq value '.do-not-initialize-slot.)
1318                        `(,(slot-setter-lambda-form dd dsd) ,value ,instance)))
1319                    (dd-slots dd)
1320                    values)
1321          ,instance))))
1322
1323 ;;; Create a default (non-BOA) keyword constructor.
1324 (defun create-keyword-constructor (defstruct creator)
1325   (declare (type function creator))
1326   (collect ((arglist (list '&key))
1327             (types)
1328             (vals))
1329     (dolist (slot (dd-slots defstruct))
1330       (let ((dum (gensym))
1331             (name (dsd-name slot)))
1332         (arglist `((,(keywordicate name) ,dum) ,(dsd-default slot)))
1333         (types (dsd-type slot))
1334         (vals dum)))
1335     (funcall creator
1336              defstruct (dd-default-constructor defstruct)
1337              (arglist) (vals) (types) (vals))))
1338
1339 ;;; Given a structure and a BOA constructor spec, call CREATOR with
1340 ;;; the appropriate args to make a constructor.
1341 (defun create-boa-constructor (defstruct boa creator)
1342   (declare (type function creator))
1343   (multiple-value-bind (req opt restp rest keyp keys allowp auxp aux)
1344       (parse-lambda-list (second boa))
1345     (collect ((arglist)
1346               (vars)
1347               (types)
1348               (skipped-vars))
1349       (labels ((get-slot (name)
1350                  (let ((res (find name (dd-slots defstruct)
1351                                   :test #'string=
1352                                   :key #'dsd-name)))
1353                    (if res
1354                        (values (dsd-type res) (dsd-default res))
1355                        (values t nil))))
1356                (do-default (arg)
1357                  (multiple-value-bind (type default) (get-slot arg)
1358                    (arglist `(,arg ,default))
1359                    (vars arg)
1360                    (types type))))
1361         (dolist (arg req)
1362           (arglist arg)
1363           (vars arg)
1364           (types (get-slot arg)))
1365
1366         (when opt
1367           (arglist '&optional)
1368           (dolist (arg opt)
1369             (cond ((consp arg)
1370                    (destructuring-bind
1371                          ;; FIXME: this shares some logic (though not
1372                          ;; code) with the &key case below (and it
1373                          ;; looks confusing) -- factor out the logic
1374                          ;; if possible. - CSR, 2002-04-19
1375                          (name
1376                           &optional
1377                           (def (nth-value 1 (get-slot name)))
1378                           (supplied-test nil supplied-test-p))
1379                        arg
1380                      (arglist `(,name ,def ,@(if supplied-test-p `(,supplied-test) nil)))
1381                      (vars name)
1382                      (types (get-slot name))))
1383                   (t
1384                    (do-default arg)))))
1385
1386         (when restp
1387           (arglist '&rest rest)
1388           (vars rest)
1389           (types 'list))
1390
1391         (when keyp
1392           (arglist '&key)
1393           (dolist (key keys)
1394             (if (consp key)
1395                 (destructuring-bind (wot
1396                                      &optional
1397                                      (def nil def-p)
1398                                      (supplied-test nil supplied-test-p))
1399                     key
1400                   (let ((name (if (consp wot)
1401                                   (destructuring-bind (key var) wot
1402                                     (declare (ignore key))
1403                                     var)
1404                                   wot)))
1405                     (multiple-value-bind (type slot-def)
1406                         (get-slot name)
1407                       (arglist `(,wot ,(if def-p def slot-def)
1408                                  ,@(if supplied-test-p `(,supplied-test) nil)))
1409                       (vars name)
1410                       (types type))))
1411                 (do-default key))))
1412
1413         (when allowp (arglist '&allow-other-keys))
1414
1415         (when auxp
1416           (arglist '&aux)
1417           (dolist (arg aux)
1418             (arglist arg)
1419             (if (proper-list-of-length-p arg 2)
1420               (let ((var (first arg)))
1421                 (vars var)
1422                 (types (get-slot var)))
1423               (skipped-vars (if (consp arg) (first arg) arg))))))
1424
1425       (funcall creator defstruct (first boa)
1426                (arglist) (vars) (types)
1427                (loop for slot in (dd-slots defstruct)
1428                      for name = (dsd-name slot)
1429                      collect (cond ((find name (skipped-vars) :test #'string=)
1430                                     (setf (dsd-safe-p slot) nil)
1431                                     '.do-not-initialize-slot.)
1432                                    ((or (find (dsd-name slot) (vars) :test #'string=)
1433                                         (dsd-default slot)))))))))
1434
1435 ;;; Grovel the constructor options, and decide what constructors (if
1436 ;;; any) to create.
1437 (defun constructor-definitions (defstruct)
1438   (let ((no-constructors nil)
1439         (boas ())
1440         (defaults ())
1441         (creator (ecase (dd-type defstruct)
1442                    (structure #'create-structure-constructor)
1443                    (vector #'create-vector-constructor)
1444                    (list #'create-list-constructor))))
1445     (dolist (constructor (dd-constructors defstruct))
1446       (destructuring-bind (name &optional (boa-ll nil boa-p)) constructor
1447         (declare (ignore boa-ll))
1448         (cond ((not name) (setq no-constructors t))
1449               (boa-p (push constructor boas))
1450               (t (push name defaults)))))
1451
1452     (when no-constructors
1453       (when (or defaults boas)
1454         (error "(:CONSTRUCTOR NIL) combined with other :CONSTRUCTORs"))
1455       (return-from constructor-definitions ()))
1456
1457     (unless (or defaults boas)
1458       (push (symbolicate "MAKE-" (dd-name defstruct)) defaults))
1459
1460     (collect ((res) (names))
1461       (when defaults
1462         (let ((cname (first defaults)))
1463           (setf (dd-default-constructor defstruct) cname)
1464           (res (create-keyword-constructor defstruct creator))
1465           (names cname)
1466           (dolist (other-name (rest defaults))
1467             (res `(setf (fdefinition ',other-name) (fdefinition ',cname)))
1468             (names other-name))))
1469
1470       (dolist (boa boas)
1471         (res (create-boa-constructor defstruct boa creator))
1472         (names (first boa)))
1473
1474       (res `(declaim (ftype
1475                       (sfunction *
1476                                  ,(if (eq (dd-type defstruct) 'structure)
1477                                       (dd-name defstruct)
1478                                       '*))
1479                       ,@(names))))
1480
1481       (res))))
1482 \f
1483 ;;;; instances with ALTERNATE-METACLASS
1484 ;;;;
1485 ;;;; The CMU CL support for structures with ALTERNATE-METACLASS was a
1486 ;;;; fairly general extension embedded in the main DEFSTRUCT code, and
1487 ;;;; the result was an fairly impressive mess as ALTERNATE-METACLASS
1488 ;;;; extension mixed with ANSI CL generality (e.g. :TYPE and :INCLUDE)
1489 ;;;; and CMU CL implementation hairiness (esp. raw slots). This SBCL
1490 ;;;; version is much less ambitious, noticing that ALTERNATE-METACLASS
1491 ;;;; is only used to implement CONDITION, STANDARD-INSTANCE, and
1492 ;;;; GENERIC-FUNCTION, and defining a simple specialized
1493 ;;;; separate-from-DEFSTRUCT macro to provide only enough
1494 ;;;; functionality to support those.
1495 ;;;;
1496 ;;;; KLUDGE: The defining macro here is so specialized that it's ugly
1497 ;;;; in its own way. It also violates once-and-only-once by knowing
1498 ;;;; much about structures and layouts that is already known by the
1499 ;;;; main DEFSTRUCT macro. Hopefully it will go away presently
1500 ;;;; (perhaps when CL:CLASS and SB-PCL:CLASS meet) as per FIXME below.
1501 ;;;; -- WHN 2001-10-28
1502 ;;;;
1503 ;;;; FIXME: There seems to be no good reason to shoehorn CONDITION,
1504 ;;;; STANDARD-INSTANCE, and GENERIC-FUNCTION into mutated structures
1505 ;;;; instead of just implementing them as primitive objects. (This
1506 ;;;; reduced-functionality macro seems pretty close to the
1507 ;;;; functionality of DEFINE-PRIMITIVE-OBJECT..)
1508
1509 (defun make-dd-with-alternate-metaclass (&key (class-name (missing-arg))
1510                                               (superclass-name (missing-arg))
1511                                               (metaclass-name (missing-arg))
1512                                               (dd-type (missing-arg))
1513                                               metaclass-constructor
1514                                               slot-names)
1515   (let* ((dd (make-defstruct-description class-name))
1516          (conc-name (concatenate 'string (symbol-name class-name) "-"))
1517          (dd-slots (let ((reversed-result nil)
1518                          ;; The index starts at 1 for ordinary named
1519                          ;; slots because slot 0 is magical, used for
1520                          ;; the LAYOUT in CONDITIONs and
1521                          ;; FUNCALLABLE-INSTANCEs.  (This is the same
1522                          ;; in ordinary structures too: see (INCF
1523                          ;; DD-LENGTH) in
1524                          ;; PARSE-DEFSTRUCT-NAME-AND-OPTIONS).
1525                          (index 1))
1526                      (dolist (slot-name slot-names)
1527                        (push (make-defstruct-slot-description
1528                               :name slot-name
1529                               :index index
1530                               :accessor-name (symbolicate conc-name slot-name))
1531                              reversed-result)
1532                        (incf index))
1533                      (nreverse reversed-result))))
1534     (case dd-type
1535       ;; We don't support inheritance of alternate metaclass stuff,
1536       ;; and it's not a general-purpose facility, so sanity check our
1537       ;; own code.
1538       (structure
1539        (aver (eq superclass-name 't)))
1540       (funcallable-structure
1541        (aver (eq superclass-name 'function)))
1542       (t (bug "Unknown DD-TYPE in ALTERNATE-METACLASS: ~S" dd-type)))
1543     (setf (dd-alternate-metaclass dd) (list superclass-name
1544                                             metaclass-name
1545                                             metaclass-constructor)
1546           (dd-slots dd) dd-slots
1547           (dd-length dd) (1+ (length slot-names))
1548           (dd-type dd) dd-type)
1549     dd))
1550
1551 (sb!xc:defmacro !defstruct-with-alternate-metaclass
1552     (class-name &key
1553                 (slot-names (missing-arg))
1554                 (boa-constructor (missing-arg))
1555                 (superclass-name (missing-arg))
1556                 (metaclass-name (missing-arg))
1557                 (metaclass-constructor (missing-arg))
1558                 (dd-type (missing-arg))
1559                 predicate
1560                 (runtime-type-checks-p t))
1561
1562   (declare (type (and list (not null)) slot-names))
1563   (declare (type (and symbol (not null))
1564                  boa-constructor
1565                  superclass-name
1566                  metaclass-name
1567                  metaclass-constructor))
1568   (declare (type symbol predicate))
1569   (declare (type (member structure funcallable-structure) dd-type))
1570
1571   (let* ((dd (make-dd-with-alternate-metaclass
1572               :class-name class-name
1573               :slot-names slot-names
1574               :superclass-name superclass-name
1575               :metaclass-name metaclass-name
1576               :metaclass-constructor metaclass-constructor
1577               :dd-type dd-type))
1578          (dd-slots (dd-slots dd))
1579          (dd-length (1+ (length slot-names)))
1580          (object-gensym (gensym "OBJECT"))
1581          (new-value-gensym (gensym "NEW-VALUE-"))
1582          (delayed-layout-form `(%delayed-get-compiler-layout ,class-name)))
1583     (multiple-value-bind (raw-maker-form raw-reffer-operator)
1584         (ecase dd-type
1585           (structure
1586            (values `(let ((,object-gensym (%make-instance ,dd-length)))
1587                       (setf (%instance-layout ,object-gensym)
1588                             ,delayed-layout-form)
1589                       ,object-gensym)
1590                    '%instance-ref))
1591           (funcallable-structure
1592            (values `(let ((,object-gensym
1593                            (%make-funcallable-instance ,dd-length)))
1594                       (setf (%funcallable-instance-layout ,object-gensym)
1595                             ,delayed-layout-form)
1596                       ,object-gensym)
1597                    '%funcallable-instance-info)))
1598       `(progn
1599
1600          (eval-when (:compile-toplevel :load-toplevel :execute)
1601            (%compiler-set-up-layout ',dd ',(inherits-for-structure dd)))
1602
1603          ;; slot readers and writers
1604          (declaim (inline ,@(mapcar #'dsd-accessor-name dd-slots)))
1605          ,@(mapcar (lambda (dsd)
1606                      `(defun ,(dsd-accessor-name dsd) (,object-gensym)
1607                         ,@(when runtime-type-checks-p
1608                             `((declare (type ,class-name ,object-gensym))))
1609                         (,raw-reffer-operator ,object-gensym
1610                                               ,(dsd-index dsd))))
1611                    dd-slots)
1612          (declaim (inline ,@(mapcar (lambda (dsd)
1613                                       `(setf ,(dsd-accessor-name dsd)))
1614                                     dd-slots)))
1615          ,@(mapcar (lambda (dsd)
1616                      `(defun (setf ,(dsd-accessor-name dsd)) (,new-value-gensym
1617                                                               ,object-gensym)
1618                         ,@(when runtime-type-checks-p
1619                             `((declare (type ,class-name ,object-gensym))))
1620                         (setf (,raw-reffer-operator ,object-gensym
1621                                                     ,(dsd-index dsd))
1622                               ,new-value-gensym)))
1623                    dd-slots)
1624
1625          ;; constructor
1626          (defun ,boa-constructor ,slot-names
1627            (let ((,object-gensym ,raw-maker-form))
1628              ,@(mapcar (lambda (slot-name)
1629                          (let ((dsd (find (symbol-name slot-name) dd-slots
1630                                           :key (lambda (x)
1631                                                  (symbol-name (dsd-name x)))
1632                                           :test #'string=)))
1633                            ;; KLUDGE: bug 117 bogowarning.  Neither
1634                            ;; DECLAREing the type nor TRULY-THE cut
1635                            ;; the mustard -- it still gives warnings.
1636                            (enforce-type dsd defstruct-slot-description)
1637                            `(setf (,(dsd-accessor-name dsd) ,object-gensym)
1638                                   ,slot-name)))
1639                        slot-names)
1640              ,object-gensym))
1641
1642          ;; predicate
1643          ,@(when predicate
1644              ;; Just delegate to the compiler's type optimization
1645              ;; code, which knows how to generate inline type tests
1646              ;; for the whole CMU CL INSTANCE menagerie.
1647              `(defun ,predicate (,object-gensym)
1648                 (typep ,object-gensym ',class-name)))))))
1649 \f
1650 ;;;; finalizing bootstrapping
1651
1652 ;;; Set up DD and LAYOUT for STRUCTURE-OBJECT class itself.
1653 ;;;
1654 ;;; Ordinary structure classes effectively :INCLUDE STRUCTURE-OBJECT
1655 ;;; when they have no explicit :INCLUDEs, so (1) it needs to be set up
1656 ;;; before we can define ordinary structure classes, and (2) it's
1657 ;;; special enough (and simple enough) that we just build it by hand
1658 ;;; instead of trying to generalize the ordinary DEFSTRUCT code.
1659 (defun !set-up-structure-object-class ()
1660   (let ((dd (make-defstruct-description 'structure-object)))
1661     (setf
1662      ;; Note: This has an ALTERNATE-METACLASS only because of blind
1663      ;; clueless imitation of the CMU CL code -- dunno if or why it's
1664      ;; needed. -- WHN
1665      (dd-alternate-metaclass dd) '(t)
1666      (dd-slots dd) nil
1667      (dd-length dd) 1
1668      (dd-type dd) 'structure)
1669     (%compiler-set-up-layout dd)))
1670 (!set-up-structure-object-class)
1671
1672 ;;; early structure predeclarations: Set up DD and LAYOUT for ordinary
1673 ;;; (non-ALTERNATE-METACLASS) structures which are needed early.
1674 (dolist (args
1675          '#.(sb-cold:read-from-file
1676              "src/code/early-defstruct-args.lisp-expr"))
1677   (let* ((dd (parse-defstruct-name-and-options-and-slot-descriptions
1678               (first args)
1679               (rest args)))
1680          (inherits (inherits-for-structure dd)))
1681     (%compiler-defstruct dd inherits)))
1682
1683 (/show0 "code/defstruct.lisp end of file")