src/code/defstruct.lisp

   1 ;;;; that part of DEFSTRUCT implementation which is needed not just
   2 ;;;; in the target Lisp but also in the cross-compilation host
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!KERNEL")
  14
  15 (/show0 "code/defstruct.lisp 15")
  16 \f
  17 ;;;; getting LAYOUTs
  18
  19 ;;; Return the compiler layout for NAME. (The class referred to by
  20 ;;; NAME must be a structure-like class.)
  21 (defun compiler-layout-or-lose (name)
  22   (let ((res (info :type :compiler-layout name)))
  23     (cond ((not res)
  24            (error "Class is not yet defined or was undefined: ~S" name))
  25           ((not (typep (layout-info res) 'defstruct-description))
  26            (error "Class is not a structure class: ~S" name))
  27           (t res))))
  28
  29 ;;; Delay looking for compiler-layout until the constructor is being
  30 ;;; compiled, since it doesn't exist until after the EVAL-WHEN
  31 ;;; (COMPILE) stuff is compiled. (Or, in the oddball case when
  32 ;;; DEFSTRUCT is executing in a non-toplevel context, the
  33 ;;; compiler-layout still doesn't exist at compilation time, and we
  34 ;;; delay still further.)
  35 (sb!xc:defmacro %delayed-get-compiler-layout (name)
  36   (let ((layout (info :type :compiler-layout name)))
  37     (cond (layout
  38            ;; ordinary case: When the DEFSTRUCT is at top level,
  39            ;; then EVAL-WHEN (COMPILE) stuff will have set up the
  40            ;; layout for us to use.
  41            (unless (typep (layout-info layout) 'defstruct-description)
  42              (error "Class is not a structure class: ~S" name))
  43            `,layout)
  44           (t
  45            ;; KLUDGE: In the case that DEFSTRUCT is not at top-level
  46            ;; the layout doesn't exist at compile time. In that case
  47            ;; we laboriously look it up at run time. This code will
  48            ;; run on every constructor call and will likely be quite
  49            ;; slow, so if anyone cares about performance of
  50            ;; non-toplevel DEFSTRUCTs, it should be rewritten to be
  51            ;; cleverer. -- WHN 2002-10-23
  52            (sb!c:compiler-notify
  53             "implementation limitation: ~
  54              Non-toplevel DEFSTRUCT constructors are slow.")
  55            (with-unique-names (layout)
  56              `(let ((,layout (info :type :compiler-layout ',name)))
  57                 (unless (typep (layout-info ,layout) 'defstruct-description)
  58                   (error "Class is not a structure class: ~S" ',name))
  59                 ,layout))))))
  60
  61 ;;; Get layout right away.
  62 (sb!xc:defmacro compile-time-find-layout (name)
  63   (find-layout name))
  64
  65 ;;; re. %DELAYED-GET-COMPILER-LAYOUT and COMPILE-TIME-FIND-LAYOUT, above..
  66 ;;;
  67 ;;; FIXME: Perhaps both should be defined with DEFMACRO-MUNDANELY?
  68 ;;; FIXME: Do we really need both? If so, their names and implementations
  69 ;;; should probably be tweaked to be more parallel.
  70 \f
  71 ;;;; DEFSTRUCT-DESCRIPTION
  72
  73 ;;; The DEFSTRUCT-DESCRIPTION structure holds compile-time information
  74 ;;; about a structure type.
  75 (def!struct (defstruct-description
  76              (:conc-name dd-)
  77              (:make-load-form-fun just-dump-it-normally)
  78              #-sb-xc-host (:pure t)
  79              (:constructor make-defstruct-description
  80                            (name &aux
  81                                  (conc-name (symbolicate name "-"))
  82                                  (copier-name (symbolicate "COPY-" name))
  83                                  (predicate-name (symbolicate name "-P")))))
  84   ;; name of the structure
  85   (name (missing-arg) :type symbol :read-only t)
  86   ;; documentation on the structure
  87   (doc nil :type (or string null))
  88   ;; prefix for slot names. If NIL, none.
  89   (conc-name nil :type (or symbol null))
  90   ;; the name of the primary standard keyword constructor, or NIL if none
  91   (default-constructor nil :type (or symbol null))
  92   ;; all the explicit :CONSTRUCTOR specs, with name defaulted
  93   (constructors () :type list)
  94   ;; name of copying function
  95   (copier-name nil :type (or symbol null))
  96   ;; name of type predicate
  97   (predicate-name nil :type (or symbol null))
  98   ;; the arguments to the :INCLUDE option, or NIL if no included
  99   ;; structure
 100   (include nil :type list)
 101   ;; properties used to define structure-like classes with an
 102   ;; arbitrary superclass and that may not have STRUCTURE-CLASS as the
 103   ;; metaclass. Syntax is:
 104   ;;    (superclass-name metaclass-name metaclass-constructor)
 105   (alternate-metaclass nil :type list)
 106   ;; a list of DEFSTRUCT-SLOT-DESCRIPTION objects for all slots
 107   ;; (including included ones)
 108   (slots () :type list)
 109   ;; a list of (NAME . INDEX) pairs for accessors of included structures
 110   (inherited-accessor-alist () :type list)
 111   ;; number of elements we've allocated (See also RAW-LENGTH, which is not
 112   ;; included in LENGTH.)
 113   (length 0 :type index)
 114   ;; General kind of implementation.
 115   (type 'structure :type (member structure vector list
 116                                  funcallable-structure))
 117
 118   ;; The next three slots are for :TYPE'd structures (which aren't
 119   ;; classes, DD-CLASS-P = NIL)
 120   ;;
 121   ;; vector element type
 122   (element-type t)
 123   ;; T if :NAMED was explicitly specified, NIL otherwise
 124   (named nil :type boolean)
 125   ;; any INITIAL-OFFSET option on this direct type
 126   (offset nil :type (or index null))
 127
 128   ;; the argument to the PRINT-FUNCTION option, or NIL if a
 129   ;; PRINT-FUNCTION option was given with no argument, or 0 if no
 130   ;; PRINT-FUNCTION option was given
 131   (print-function 0 :type (or cons symbol (member 0)))
 132   ;; the argument to the PRINT-OBJECT option, or NIL if a PRINT-OBJECT
 133   ;; option was given with no argument, or 0 if no PRINT-OBJECT option
 134   ;; was given
 135   (print-object 0 :type (or cons symbol (member 0)))
 136   ;; The number of untagged slots at the end.
 137   (raw-length 0 :type index)
 138   ;; the value of the :PURE option, or :UNSPECIFIED. This is only
 139   ;; meaningful if DD-CLASS-P = T.
 140   (pure :unspecified :type (member t nil :substructure :unspecified)))
 141 (def!method print-object ((x defstruct-description) stream)
 142   (print-unreadable-object (x stream :type t)
 143     (prin1 (dd-name x) stream)))
 144
 145 ;;; Does DD describe a structure with a class?
 146 (defun dd-class-p (dd)
 147   (member (dd-type dd)
 148           '(structure funcallable-structure)))
 149
 150 ;;; a type name which can be used when declaring things which operate
 151 ;;; on structure instances
 152 (defun dd-declarable-type (dd)
 153   (if (dd-class-p dd)
 154       ;; Native classes are known to the type system, and we can
 155       ;; declare them as types.
 156       (dd-name dd)
 157       ;; Structures layered on :TYPE LIST or :TYPE VECTOR aren't part
 158       ;; of the type system, so all we can declare is the underlying
 159       ;; LIST or VECTOR type.
 160       (dd-type dd)))
 161
 162 (defun dd-layout-or-lose (dd)
 163   (compiler-layout-or-lose (dd-name dd)))
 164 \f
 165 ;;;; DEFSTRUCT-SLOT-DESCRIPTION
 166
 167 ;;; A DEFSTRUCT-SLOT-DESCRIPTION holds compile-time information about
 168 ;;; a structure slot.
 169 (def!struct (defstruct-slot-description
 170              (:make-load-form-fun just-dump-it-normally)
 171              (:conc-name dsd-)
 172              (:copier nil)
 173              #-sb-xc-host (:pure t))
 174   ;; name of slot
 175   name
 176   ;; its position in the implementation sequence
 177   (index (missing-arg) :type fixnum)
 178   ;; the name of the accessor function
 179   ;;
 180   ;; (CMU CL had extra complexity here ("..or NIL if this accessor has
 181   ;; the same name as an inherited accessor (which we don't want to
 182   ;; shadow)") but that behavior doesn't seem to be specified by (or
 183   ;; even particularly consistent with) ANSI, so it's gone in SBCL.)
 184   (accessor-name nil)
 185   default                       ; default value expression
 186   (type t)                      ; declared type specifier
 187   (safe-p t :type boolean)      ; whether the slot is known to be
 188                                 ; always of the specified type
 189   ;; If this object does not describe a raw slot, this value is T.
 190   ;;
 191   ;; If this object describes a raw slot, this value is the type of the
 192   ;; value that the raw slot holds.
 193   (raw-type t :type (member t single-float double-float
 194                             #!+long-float long-float
 195                             complex-single-float complex-double-float
 196                             #!+long-float complex-long-float
 197                             sb!vm:word))
 198   (read-only nil :type (member t nil)))
 199 (def!method print-object ((x defstruct-slot-description) stream)
 200   (print-unreadable-object (x stream :type t)
 201     (prin1 (dsd-name x) stream)))
 202 \f
 203 ;;;; typed (non-class) structures
 204
 205 ;;; Return a type specifier we can use for testing :TYPE'd structures.
 206 (defun dd-lisp-type (defstruct)
 207   (ecase (dd-type defstruct)
 208     (list 'list)
 209     (vector `(simple-array ,(dd-element-type defstruct) (*)))))
 210 \f
 211 ;;;; shared machinery for inline and out-of-line slot accessor functions
 212
 213 ;;; Classic comment preserved for entertainment value:
 214 ;;;
 215 ;;; "A lie can travel halfway round the world while the truth is
 216 ;;; putting on its shoes." -- Mark Twain
 217
 218 (eval-when (#-sb-xc :compile-toplevel :load-toplevel :execute)
 219
 220   ;; information about how a slot of a given DSD-RAW-TYPE is to be accessed
 221   (defstruct raw-slot-data
 222     ;; the raw slot type, or T for a non-raw slot
 223     ;;
 224     ;; (Non-raw slots are in the ordinary place you'd expect, directly
 225     ;; indexed off the instance pointer.  Raw slots are indexed from the end
 226     ;; of the instance and skipped by GC.)
 227     (raw-type (missing-arg) :type (or symbol cons) :read-only t)
 228     ;; What operator is used to access a slot of this type?
 229     (accessor-name (missing-arg) :type symbol :read-only t)
 230     ;; How many words are each value of this type?
 231     (n-words (missing-arg) :type (and index (integer 1)) :read-only t)
 232     ;; Necessary alignment in units of words.  Note that instances
 233     ;; themselves are aligned by exactly two words, so specifying more
 234     ;; than two words here would not work.
 235     (alignment 1 :type (integer 1 2) :read-only t))
 236
 237   (defvar *raw-slot-data-list*
 238     #!+hppa
 239     nil
 240     #!-hppa
 241     (let ((double-float-alignment
 242            ;; white list of architectures that can load unaligned doubles:
 243            #!+(or x86 x86-64 ppc) 1
 244            ;; at least sparc, mips and alpha can't:
 245            #!-(or x86 x86-64 ppc) 2))
 246       (list
 247        (make-raw-slot-data :raw-type 'sb!vm:word
 248                            :accessor-name '%raw-instance-ref/word
 249                            :n-words 1)
 250        (make-raw-slot-data :raw-type 'single-float
 251                            :accessor-name '%raw-instance-ref/single
 252                            ;; KLUDGE: On 64 bit architectures, we
 253                            ;; could pack two SINGLE-FLOATs into the
 254                            ;; same word if raw slots were indexed
 255                            ;; using bytes instead of words.  However,
 256                            ;; I don't personally find optimizing
 257                            ;; SINGLE-FLOAT memory usage worthwile
 258                            ;; enough.  And the other datatype that
 259                            ;; would really benefit is (UNSIGNED-BYTE
 260                            ;; 32), but that is a subtype of FIXNUM, so
 261                            ;; we store it unraw anyway.  :-( -- DFL
 262                            :n-words 1)
 263        (make-raw-slot-data :raw-type 'double-float
 264                            :accessor-name '%raw-instance-ref/double
 265                            :alignment double-float-alignment
 266                            :n-words (/ 8 sb!vm:n-word-bytes))
 267        (make-raw-slot-data :raw-type 'complex-single-float
 268                            :accessor-name '%raw-instance-ref/complex-single
 269                            :n-words (/ 8 sb!vm:n-word-bytes))
 270        (make-raw-slot-data :raw-type 'complex-double-float
 271                            :accessor-name '%raw-instance-ref/complex-double
 272                            :alignment double-float-alignment
 273                            :n-words (/ 16 sb!vm:n-word-bytes))
 274        #!+long-float
 275        (make-raw-slot-data :raw-type long-float
 276                            :accessor-name '%raw-instance-ref/long
 277                            :n-words #!+x86 3 #!+sparc 4)
 278        #!+long-float
 279        (make-raw-slot-data :raw-type complex-long-float
 280                            :accessor-name '%raw-instance-ref/complex-long
 281                            :n-words #!+x86 6 #!+sparc 8)))))
 282 \f
 283 ;;;; the legendary DEFSTRUCT macro itself (both CL:DEFSTRUCT and its
 284 ;;;; close personal friend SB!XC:DEFSTRUCT)
 285
 286 ;;; Return a list of forms to install PRINT and MAKE-LOAD-FORM funs,
 287 ;;; mentioning them in the expansion so that they can be compiled.
 288 (defun class-method-definitions (defstruct)
 289   (let ((name (dd-name defstruct)))
 290     `((locally
 291         ;; KLUDGE: There's a FIND-CLASS DEFTRANSFORM for constant
 292         ;; class names which creates fast but non-cold-loadable,
 293         ;; non-compact code. In this context, we'd rather have
 294         ;; compact, cold-loadable code. -- WHN 19990928
 295         (declare (notinline find-classoid))
 296         ,@(let ((pf (dd-print-function defstruct))
 297                 (po (dd-print-object defstruct))
 298                 (x (gensym))
 299                 (s (gensym)))
 300             ;; Giving empty :PRINT-OBJECT or :PRINT-FUNCTION options
 301             ;; leaves PO or PF equal to NIL. The user-level effect is
 302             ;; to generate a PRINT-OBJECT method specialized for the type,
 303             ;; implementing the default #S structure-printing behavior.
 304             (when (or (eq pf nil) (eq po nil))
 305               (setf pf '(default-structure-print)
 306                     po 0))
 307             (flet (;; Given an arg from a :PRINT-OBJECT or :PRINT-FUNCTION
 308                    ;; option, return the value to pass as an arg to FUNCTION.
 309                    (farg (oarg)
 310                      (destructuring-bind (fun-name) oarg
 311                        fun-name)))
 312               (cond ((not (eql pf 0))
 313                      `((def!method print-object ((,x ,name) ,s)
 314                          (funcall #',(farg pf)
 315                                   ,x
 316                                   ,s
 317                                   *current-level-in-print*))))
 318                     ((not (eql po 0))
 319                      `((def!method print-object ((,x ,name) ,s)
 320                          (funcall #',(farg po) ,x ,s))))
 321                     (t nil))))
 322         ,@(let ((pure (dd-pure defstruct)))
 323             (cond ((eq pure t)
 324                    `((setf (layout-pure (classoid-layout
 325                                          (find-classoid ',name)))
 326                            t)))
 327                   ((eq pure :substructure)
 328                    `((setf (layout-pure (classoid-layout
 329                                          (find-classoid ',name)))
 330                            0)))))
 331         ,@(let ((def-con (dd-default-constructor defstruct)))
 332             (when (and def-con (not (dd-alternate-metaclass defstruct)))
 333               `((setf (structure-classoid-constructor (find-classoid ',name))
 334                       #',def-con))))))))
 335
 336 ;;; shared logic for CL:DEFSTRUCT and SB!XC:DEFSTRUCT
 337 (defmacro !expander-for-defstruct (name-and-options
 338                                    slot-descriptions
 339                                    expanding-into-code-for-xc-host-p)
 340   `(let ((name-and-options ,name-and-options)
 341          (slot-descriptions ,slot-descriptions)
 342          (expanding-into-code-for-xc-host-p
 343           ,expanding-into-code-for-xc-host-p))
 344      (let* ((dd (parse-defstruct-name-and-options-and-slot-descriptions
 345                  name-and-options
 346                  slot-descriptions))
 347             (name (dd-name dd)))
 348        (if (dd-class-p dd)
 349            (let ((inherits (inherits-for-structure dd)))
 350              `(progn
 351                 ;; Note we intentionally enforce package locks and
 352                 ;; call %DEFSTRUCT first, and especially before
 353                 ;; %COMPILER-DEFSTRUCT. %DEFSTRUCT has the tests (and
 354                 ;; resulting CERROR) for collisions with LAYOUTs which
 355                 ;; already exist in the runtime. If there are any
 356                 ;; collisions, we want the user's response to CERROR
 357                 ;; to control what happens. Especially, if the user
 358                 ;; responds to the collision with ABORT, we don't want
 359                 ;; %COMPILER-DEFSTRUCT to modify the definition of the
 360                 ;; class.
 361                 (with-single-package-locked-error
 362                     (:symbol ',name "defining ~A as a structure"))
 363                 (%defstruct ',dd ',inherits (sb!c:source-location))
 364                 (eval-when (:compile-toplevel :load-toplevel :execute)
 365                   (%compiler-defstruct ',dd ',inherits))
 366                 ,@(unless expanding-into-code-for-xc-host-p
 367                     (append ;; FIXME: We've inherited from CMU CL nonparallel
 368                             ;; code for creating copiers for typed and untyped
 369                             ;; structures. This should be fixed.
 370                             ;(copier-definition dd)
 371                             (constructor-definitions dd)
 372                             (class-method-definitions dd)))
 373                 ',name))
 374            `(progn
 375               (with-single-package-locked-error
 376                   (:symbol ',name "defining ~A as a structure"))
 377               (eval-when (:compile-toplevel :load-toplevel :execute)
 378                 (setf (info :typed-structure :info ',name) ',dd))
 379               (eval-when (:load-toplevel :execute)
 380                 (setf (info :source-location :typed-structure ',name)
 381                       (sb!c:source-location)))
 382               ,@(unless expanding-into-code-for-xc-host-p
 383                   (append (typed-accessor-definitions dd)
 384                           (typed-predicate-definitions dd)
 385                           (typed-copier-definitions dd)
 386                           (constructor-definitions dd)
 387                           (when (dd-doc dd)
 388                             `((setf (fdocumentation ',(dd-name dd) 'structure)
 389                                ',(dd-doc dd))))))
 390               ',name)))))
 391
 392 (sb!xc:defmacro defstruct (name-and-options &rest slot-descriptions)
 393   #!+sb-doc
 394   "DEFSTRUCT {Name | (Name Option*)} {Slot | (Slot [Default] {Key Value}*)}
 395    Define the structure type Name. Instances are created by MAKE-<name>,
 396    which takes &KEY arguments allowing initial slot values to the specified.
 397    A SETF'able function <name>-<slot> is defined for each slot to read and
 398    write slot values. <name>-p is a type predicate.
 399
 400    Popular DEFSTRUCT options (see manual for others):
 401
 402    (:CONSTRUCTOR Name)
 403    (:PREDICATE Name)
 404        Specify the name for the constructor or predicate.
 405
 406    (:CONSTRUCTOR Name Lambda-List)
 407        Specify the name and arguments for a BOA constructor
 408        (which is more efficient when keyword syntax isn't necessary.)
 409
 410    (:INCLUDE Supertype Slot-Spec*)
 411        Make this type a subtype of the structure type Supertype. The optional
 412        Slot-Specs override inherited slot options.
 413
 414    Slot options:
 415
 416    :TYPE Type-Spec
 417        Asserts that the value of this slot is always of the specified type.
 418
 419    :READ-ONLY {T | NIL}
 420        If true, no setter function is defined for this slot."
 421     (!expander-for-defstruct name-and-options slot-descriptions nil))
 422 #+sb-xc-host
 423 (defmacro sb!xc:defstruct (name-and-options &rest slot-descriptions)
 424   #!+sb-doc
 425   "Cause information about a target structure to be built into the
 426   cross-compiler."
 427   (!expander-for-defstruct name-and-options slot-descriptions t))
 428 \f
 429 ;;;; functions to generate code for various parts of DEFSTRUCT definitions
 430
 431 ;;; First, a helper to determine whether a name names an inherited
 432 ;;; accessor.
 433 (defun accessor-inherited-data (name defstruct)
 434   (assoc name (dd-inherited-accessor-alist defstruct) :test #'eq))
 435
 436 ;;; Return a list of forms which create a predicate function for a
 437 ;;; typed DEFSTRUCT.
 438 (defun typed-predicate-definitions (defstruct)
 439   (let ((name (dd-name defstruct))
 440         (predicate-name (dd-predicate-name defstruct))
 441         (argname (gensym)))
 442     (when (and predicate-name (dd-named defstruct))
 443       (let ((ltype (dd-lisp-type defstruct))
 444             (name-index (cdr (car (last (find-name-indices defstruct))))))
 445         `((defun ,predicate-name (,argname)
 446             (and (typep ,argname ',ltype)
 447                  ,(cond
 448                    ((subtypep ltype 'list)
 449                      `(do ((head (the ,ltype ,argname) (cdr head))
 450                            (i 0 (1+ i)))
 451                           ((or (not (consp head)) (= i ,name-index))
 452                            (and (consp head) (eq ',name (car head))))))
 453                    ((subtypep ltype 'vector)
 454                     `(and (= (length (the ,ltype ,argname))
 455                            ,(dd-length defstruct))
 456                           (eq ',name (aref (the ,ltype ,argname) ,name-index))))
 457                    (t (bug "Uncatered-for lisp type in typed DEFSTRUCT: ~S."
 458                            ltype))))))))))
 459
 460 ;;; Return a list of forms to create a copier function of a typed DEFSTRUCT.
 461 (defun typed-copier-definitions (defstruct)
 462   (when (dd-copier-name defstruct)
 463     `((setf (fdefinition ',(dd-copier-name defstruct)) #'copy-seq)
 464       (declaim (ftype function ,(dd-copier-name defstruct))))))
 465
 466 ;;; Return a list of function definitions for accessing and setting
 467 ;;; the slots of a typed DEFSTRUCT. The functions are proclaimed to be
 468 ;;; inline, and the types of their arguments and results are declared
 469 ;;; as well. We count on the compiler to do clever things with ELT.
 470 (defun typed-accessor-definitions (defstruct)
 471   (collect ((stuff))
 472     (let ((ltype (dd-lisp-type defstruct)))
 473       (dolist (slot (dd-slots defstruct))
 474         (let ((name (dsd-accessor-name slot))
 475               (index (dsd-index slot))
 476               (slot-type `(and ,(dsd-type slot)
 477                                ,(dd-element-type defstruct))))
 478           (let ((inherited (accessor-inherited-data name defstruct)))
 479             (cond
 480               ((not inherited)
 481                (stuff `(declaim (inline ,name (setf ,name))))
 482                ;; FIXME: The arguments in the next two DEFUNs should
 483                ;; be gensyms. (Otherwise e.g. if NEW-VALUE happened to
 484                ;; be the name of a special variable, things could get
 485                ;; weird.)
 486                (stuff `(defun ,name (structure)
 487                         (declare (type ,ltype structure))
 488                         (the ,slot-type (elt structure ,index))))
 489                (unless (dsd-read-only slot)
 490                  (stuff
 491                   `(defun (setf ,name) (new-value structure)
 492                     (declare (type ,ltype structure) (type ,slot-type new-value))
 493                     (setf (elt structure ,index) new-value)))))
 494               ((not (= (cdr inherited) index))
 495                (style-warn "~@<Non-overwritten accessor ~S does not access ~
 496                             slot with name ~S (accessing an inherited slot ~
 497                             instead).~:@>" name (dsd-name slot))))))))
 498     (stuff)))
 499 \f
 500 ;;;; parsing
 501
 502 (defun require-no-print-options-so-far (defstruct)
 503   (unless (and (eql (dd-print-function defstruct) 0)
 504                (eql (dd-print-object defstruct) 0))
 505     (error "No more than one of the following options may be specified:
 506   :PRINT-FUNCTION, :PRINT-OBJECT, :TYPE")))
 507
 508 ;;; Parse a single DEFSTRUCT option and store the results in DD.
 509 (defun parse-1-dd-option (option dd)
 510   (let ((args (rest option))
 511         (name (dd-name dd)))
 512     (case (first option)
 513       (:conc-name
 514        (destructuring-bind (&optional conc-name) args
 515          (setf (dd-conc-name dd)
 516                (if (symbolp conc-name)
 517                    conc-name
 518                    (make-symbol (string conc-name))))))
 519       (:constructor
 520        (destructuring-bind (&optional (cname (symbolicate "MAKE-" name))
 521                                       &rest stuff)
 522            args
 523          (push (cons cname stuff) (dd-constructors dd))))
 524       (:copier
 525        (destructuring-bind (&optional (copier (symbolicate "COPY-" name)))
 526            args
 527          (setf (dd-copier-name dd) copier)))
 528       (:predicate
 529        (destructuring-bind (&optional (predicate-name (symbolicate name "-P")))
 530            args
 531          (setf (dd-predicate-name dd) predicate-name)))
 532       (:include
 533        (when (dd-include dd)
 534          (error "more than one :INCLUDE option"))
 535        (setf (dd-include dd) args))
 536       (:print-function
 537        (require-no-print-options-so-far dd)
 538        (setf (dd-print-function dd)
 539              (the (or symbol cons) args)))
 540       (:print-object
 541        (require-no-print-options-so-far dd)
 542        (setf (dd-print-object dd)
 543              (the (or symbol cons) args)))
 544       (:type
 545        (destructuring-bind (type) args
 546          (cond ((member type '(list vector))
 547                 (setf (dd-element-type dd) t)
 548                 (setf (dd-type dd) type))
 549                ((and (consp type) (eq (first type) 'vector))
 550                 (destructuring-bind (vector vtype) type
 551                   (declare (ignore vector))
 552                   (setf (dd-element-type dd) vtype)
 553                   (setf (dd-type dd) 'vector)))
 554                (t
 555                 (error "~S is a bad :TYPE for DEFSTRUCT." type)))))
 556       (:named
 557        (error "The DEFSTRUCT option :NAMED takes no arguments."))
 558       (:initial-offset
 559        (destructuring-bind (offset) args
 560          (setf (dd-offset dd) offset)))
 561       (:pure
 562        (destructuring-bind (fun) args
 563          (setf (dd-pure dd) fun)))
 564       (t (error "unknown DEFSTRUCT option:~%  ~S" option)))))
 565
 566 ;;; Given name and options, return a DD holding that info.
 567 (defun parse-defstruct-name-and-options (name-and-options)
 568   (destructuring-bind (name &rest options) name-and-options
 569     (aver name) ; A null name doesn't seem to make sense here.
 570     (let ((dd (make-defstruct-description name)))
 571       (dolist (option options)
 572         (cond ((eq option :named)
 573                (setf (dd-named dd) t))
 574               ((consp option)
 575                (parse-1-dd-option option dd))
 576               ((member option '(:conc-name :constructor :copier :predicate))
 577                (parse-1-dd-option (list option) dd))
 578               (t
 579                (error "unrecognized DEFSTRUCT option: ~S" option))))
 580
 581       (case (dd-type dd)
 582         (structure
 583          (when (dd-offset dd)
 584            (error ":OFFSET can't be specified unless :TYPE is specified."))
 585          (unless (dd-include dd)
 586            ;; FIXME: It'd be cleaner to treat no-:INCLUDE as defaulting
 587            ;; to :INCLUDE STRUCTURE-OBJECT, and then let the general-case
 588            ;; (INCF (DD-LENGTH DD) (DD-LENGTH included-DD)) logic take
 589            ;; care of this. (Except that the :TYPE VECTOR and :TYPE
 590            ;; LIST cases, with their :NAMED and un-:NAMED flavors,
 591            ;; make that messy, alas.)
 592            (incf (dd-length dd))))
 593         (t
 594          (require-no-print-options-so-far dd)
 595          (when (dd-named dd)
 596            (incf (dd-length dd)))
 597          (let ((offset (dd-offset dd)))
 598            (when offset (incf (dd-length dd) offset)))))
 599
 600       (when (dd-include dd)
 601         (frob-dd-inclusion-stuff dd))
 602
 603       dd)))
 604
 605 ;;; Given name and options and slot descriptions (and possibly doc
 606 ;;; string at the head of slot descriptions) return a DD holding that
 607 ;;; info.
 608 (defun parse-defstruct-name-and-options-and-slot-descriptions
 609     (name-and-options slot-descriptions)
 610   (let ((result (parse-defstruct-name-and-options (if (atom name-and-options)
 611                                                       (list name-and-options)
 612                                                       name-and-options))))
 613     (when (stringp (car slot-descriptions))
 614       (setf (dd-doc result) (pop slot-descriptions)))
 615     (dolist (slot-description slot-descriptions)
 616       (allocate-1-slot result (parse-1-dsd result slot-description)))
 617     result))
 618 \f
 619 ;;;; stuff to parse slot descriptions
 620
 621 ;;; Parse a slot description for DEFSTRUCT, add it to the description
 622 ;;; and return it. If supplied, SLOT is a pre-initialized DSD
 623 ;;; that we modify to get the new slot. This is supplied when handling
 624 ;;; included slots.
 625 (defun parse-1-dsd (defstruct spec &optional
 626                     (slot (make-defstruct-slot-description :name ""
 627                                                            :index 0
 628                                                            :type t)))
 629   (multiple-value-bind (name default default-p type type-p read-only ro-p)
 630       (typecase spec
 631         (symbol
 632          (when (keywordp spec)
 633            (style-warn "Keyword slot name indicates probable syntax ~
 634                         error in DEFSTRUCT: ~S."
 635                        spec))
 636          spec)
 637         (cons
 638          (destructuring-bind
 639                (name
 640                 &optional (default nil default-p)
 641                 &key (type nil type-p) (read-only nil ro-p))
 642              spec
 643            (values name
 644                    default default-p
 645                    (uncross type) type-p
 646                    read-only ro-p)))
 647         (t (error 'simple-program-error
 648                   :format-control "in DEFSTRUCT, ~S is not a legal slot ~
 649                                    description."
 650                   :format-arguments (list spec))))
 651
 652     (when (find name (dd-slots defstruct)
 653                 :test #'string=
 654                 :key (lambda (x) (symbol-name (dsd-name x))))
 655       (error 'simple-program-error
 656              :format-control "duplicate slot name ~S"
 657              :format-arguments (list name)))
 658     (setf (dsd-name slot) name)
 659     (setf (dd-slots defstruct) (nconc (dd-slots defstruct) (list slot)))
 660
 661     (let ((accessor-name (if (dd-conc-name defstruct)
 662                              (symbolicate (dd-conc-name defstruct) name)
 663                              name))
 664           (predicate-name (dd-predicate-name defstruct)))
 665       (setf (dsd-accessor-name slot) accessor-name)
 666       (when (eql accessor-name predicate-name)
 667         ;; Some adventurous soul has named a slot so that its accessor
 668         ;; collides with the structure type predicate. ANSI doesn't
 669         ;; specify what to do in this case. As of 2001-09-04, Martin
 670         ;; Atzmueller reports that CLISP and Lispworks both give
 671         ;; priority to the slot accessor, so that the predicate is
 672         ;; overwritten. We might as well do the same (as well as
 673         ;; signalling a warning).
 674         (style-warn
 675          "~@<The structure accessor name ~S is the same as the name of the ~
 676           structure type predicate. ANSI doesn't specify what to do in ~
 677           this case. We'll overwrite the type predicate with the slot ~
 678           accessor, but you can't rely on this behavior, so it'd be wise to ~
 679           remove the ambiguity in your code.~@:>"
 680          accessor-name)
 681         (setf (dd-predicate-name defstruct) nil))
 682       ;; FIXME: It would be good to check for name collisions here, but
 683       ;; the easy check,
 684       ;;x#-sb-xc-host
 685       ;;x(when (and (fboundp accessor-name)
 686       ;;x           (not (accessor-inherited-data accessor-name defstruct)))
 687       ;;x  (style-warn "redefining ~S in DEFSTRUCT" accessor-name)))
 688       ;; which was done until sbcl-0.8.11.18 or so, is wrong: it causes
 689       ;; a warning at MACROEXPAND time, when instead the warning should
 690       ;; occur not just because the code was constructed, but because it
 691       ;; is actually compiled or loaded.
 692       )
 693
 694     (when default-p
 695       (setf (dsd-default slot) default))
 696     (when type-p
 697       (setf (dsd-type slot)
 698             (if (eq (dsd-type slot) t)
 699                 type
 700                 `(and ,(dsd-type slot) ,type))))
 701     (when ro-p
 702       (if read-only
 703           (setf (dsd-read-only slot) t)
 704           (when (dsd-read-only slot)
 705             (error "~@<The slot ~S is :READ-ONLY in superclass, and so must ~
 706                        be :READ-ONLY in subclass.~:@>"
 707                    (dsd-name slot)))))
 708     slot))
 709
 710 ;;; When a value of type TYPE is stored in a structure, should it be
 711 ;;; stored in a raw slot?  Return the matching RAW-SLOT-DATA structure
 712 ;; if TYPE should be stored in a raw slot, or NIL if not.
 713 (defun structure-raw-slot-data (type)
 714   (multiple-value-bind (fixnum? fixnum-certain?)
 715       (sb!xc:subtypep type 'fixnum)
 716     ;; (The extra test for FIXNUM-CERTAIN? here is intended for
 717     ;; bootstrapping the system. In particular, in sbcl-0.6.2, we set up
 718     ;; LAYOUT before FIXNUM is defined, and so could bogusly end up
 719     ;; putting INDEX-typed values into raw slots if we didn't test
 720     ;; FIXNUM-CERTAIN?.)
 721     (if (or fixnum? (not fixnum-certain?))
 722         nil
 723         (dolist (data *raw-slot-data-list*)
 724           (when (sb!xc:subtypep type (raw-slot-data-raw-type data))
 725             (return data))))))
 726
 727 ;;; Allocate storage for a DSD in DD. This is where we decide whether
 728 ;;; a slot is raw or not. Raw objects are aligned on the unit of their size.
 729 (defun allocate-1-slot (dd dsd)
 730   (let ((rsd
 731          (if (eq (dd-type dd) 'structure)
 732              (structure-raw-slot-data (dsd-type dsd))
 733              nil)))
 734     (cond
 735       ((null rsd)
 736         (setf (dsd-index dsd) (dd-length dd))
 737         (incf (dd-length dd)))
 738       (t
 739         (let* ((words (raw-slot-data-n-words rsd))
 740                (alignment (raw-slot-data-alignment rsd))
 741                (off (rem (dd-raw-length dd) alignment)))
 742           (unless (zerop off)
 743             (incf (dd-raw-length dd) (- alignment off)))
 744           (setf (dsd-raw-type dsd) (raw-slot-data-raw-type rsd))
 745           (setf (dsd-index dsd) (dd-raw-length dd))
 746           (incf (dd-raw-length dd) words)))))
 747   (values))
 748
 749 (defun typed-structure-info-or-lose (name)
 750   (or (info :typed-structure :info name)
 751       (error ":TYPE'd DEFSTRUCT ~S not found for inclusion." name)))
 752
 753 ;;; Process any included slots pretty much like they were specified.
 754 ;;; Also inherit various other attributes.
 755 (defun frob-dd-inclusion-stuff (dd)
 756   (destructuring-bind (included-name &rest modified-slots) (dd-include dd)
 757     (let* ((type (dd-type dd))
 758            (included-structure
 759             (if (dd-class-p dd)
 760                 (layout-info (compiler-layout-or-lose included-name))
 761                 (typed-structure-info-or-lose included-name))))
 762
 763       ;; checks on legality
 764       (unless (and (eq type (dd-type included-structure))
 765                    (type= (specifier-type (dd-element-type included-structure))
 766                           (specifier-type (dd-element-type dd))))
 767         (error ":TYPE option mismatch between structures ~S and ~S"
 768                (dd-name dd) included-name))
 769       (let ((included-classoid (find-classoid included-name nil)))
 770         (when included-classoid
 771           ;; It's not particularly well-defined to :INCLUDE any of the
 772           ;; CMU CL INSTANCE weirdosities like CONDITION or
 773           ;; GENERIC-FUNCTION, and it's certainly not ANSI-compliant.
 774           (let* ((included-layout (classoid-layout included-classoid))
 775                  (included-dd (layout-info included-layout)))
 776             (when (and (dd-alternate-metaclass included-dd)
 777                        ;; As of sbcl-0.pre7.73, anyway, STRUCTURE-OBJECT
 778                        ;; is represented with an ALTERNATE-METACLASS. But
 779                        ;; it's specifically OK to :INCLUDE (and PCL does)
 780                        ;; so in this one case, it's OK to include
 781                        ;; something with :ALTERNATE-METACLASS after all.
 782                        (not (eql included-name 'structure-object)))
 783               (error "can't :INCLUDE class ~S (has alternate metaclass)"
 784                      included-name)))))
 785
 786       (incf (dd-length dd) (dd-length included-structure))
 787       (when (dd-class-p dd)
 788         (let ((mc (rest (dd-alternate-metaclass included-structure))))
 789           (when (and mc (not (dd-alternate-metaclass dd)))
 790             (setf (dd-alternate-metaclass dd)
 791                   (cons included-name mc))))
 792         (when (eq (dd-pure dd) :unspecified)
 793           (setf (dd-pure dd) (dd-pure included-structure)))
 794         (setf (dd-raw-length dd) (dd-raw-length included-structure)))
 795
 796       (setf (dd-inherited-accessor-alist dd)
 797             (dd-inherited-accessor-alist included-structure))
 798       (dolist (included-slot (dd-slots included-structure))
 799         (let* ((included-name (dsd-name included-slot))
 800                (modified (or (find included-name modified-slots
 801                                    :key (lambda (x) (if (atom x) x (car x)))
 802                                    :test #'string=)
 803                              `(,included-name))))
 804           ;; We stash away an alist of accessors to parents' slots
 805           ;; that have already been created to avoid conflicts later
 806           ;; so that structures with :INCLUDE and :CONC-NAME (and
 807           ;; other edge cases) can work as specified.
 808           (when (dsd-accessor-name included-slot)
 809             ;; the "oldest" (i.e. highest up the tree of inheritance)
 810             ;; will prevail, so don't push new ones on if they
 811             ;; conflict.
 812             (pushnew (cons (dsd-accessor-name included-slot)
 813                            (dsd-index included-slot))
 814                      (dd-inherited-accessor-alist dd)
 815                      :test #'eq :key #'car))
 816           (let ((new-slot (parse-1-dsd dd
 817                                        modified
 818                                        (copy-structure included-slot))))
 819             (when (and (neq (dsd-type new-slot) (dsd-type included-slot))
 820                        (not (sb!xc:subtypep (dsd-type included-slot)
 821                                             (dsd-type new-slot)))
 822                        (dsd-safe-p included-slot))
 823               (setf (dsd-safe-p new-slot) nil)
 824               ;; XXX: notify?
 825               )))))))
 826 \f
 827 ;;;; various helper functions for setting up DEFSTRUCTs
 828
 829 ;;; This function is called at macroexpand time to compute the INHERITS
 830 ;;; vector for a structure type definition.
 831 (defun inherits-for-structure (info)
 832   (declare (type defstruct-description info))
 833   (let* ((include (dd-include info))
 834          (superclass-opt (dd-alternate-metaclass info))
 835          (super
 836           (if include
 837               (compiler-layout-or-lose (first include))
 838               (classoid-layout (find-classoid
 839                                 (or (first superclass-opt)
 840                                     'structure-object))))))
 841     (case (dd-name info)
 842       ((ansi-stream)
 843        (concatenate 'simple-vector
 844                     (layout-inherits super)
 845                     (vector super (classoid-layout (find-classoid 'stream)))))
 846       ((fd-stream)
 847        (concatenate 'simple-vector
 848                     (layout-inherits super)
 849                     (vector super
 850                             (classoid-layout (find-classoid 'file-stream)))))
 851       ((sb!impl::string-input-stream
 852         sb!impl::string-output-stream
 853         sb!impl::fill-pointer-output-stream)
 854        (concatenate 'simple-vector
 855                     (layout-inherits super)
 856                     (vector super
 857                             (classoid-layout (find-classoid 'string-stream)))))
 858       (t (concatenate 'simple-vector
 859                       (layout-inherits super)
 860                       (vector super))))))
 861
 862 ;;; Do miscellaneous (LOAD EVAL) time actions for the structure
 863 ;;; described by DD. Create the class and LAYOUT, checking for
 864 ;;; incompatible redefinition. Define those functions which are
 865 ;;; sufficiently stereotyped that we can implement them as standard
 866 ;;; closures.
 867 (defun %defstruct (dd inherits source-location)
 868   (declare (type defstruct-description dd))
 869
 870   ;; We set up LAYOUTs even in the cross-compilation host.
 871   (multiple-value-bind (classoid layout old-layout)
 872       (ensure-structure-class dd inherits "current" "new")
 873     (cond ((not old-layout)
 874            (unless (eq (classoid-layout classoid) layout)
 875              (register-layout layout)))
 876           (t
 877            (let ((old-dd (layout-info old-layout)))
 878              (when (defstruct-description-p old-dd)
 879                (dolist (slot (dd-slots old-dd))
 880                  (fmakunbound (dsd-accessor-name slot))
 881                  (unless (dsd-read-only slot)
 882                    (fmakunbound `(setf ,(dsd-accessor-name slot)))))))
 883            (%redefine-defstruct classoid old-layout layout)
 884            (setq layout (classoid-layout classoid))))
 885     (setf (find-classoid (dd-name dd)) classoid)
 886
 887     (sb!c:with-source-location (source-location)
 888       (setf (layout-source-location layout) source-location))
 889
 890     ;; Various other operations only make sense on the target SBCL.
 891     #-sb-xc-host
 892     (%target-defstruct dd layout))
 893
 894   (values))
 895 \f
 896 ;;; Return a form describing the writable place used for this slot
 897 ;;; in the instance named INSTANCE-NAME.
 898 (defun %accessor-place-form (dd dsd instance-name)
 899   (let (;; the operator that we'll use to access a typed slot
 900         (ref (ecase (dd-type dd)
 901                (structure '%instance-ref)
 902                (list 'nth-but-with-sane-arg-order)
 903                (vector 'aref)))
 904         (raw-type (dsd-raw-type dsd)))
 905     (if (eq raw-type t) ; if not raw slot
 906         `(,ref ,instance-name ,(dsd-index dsd))
 907         (let* ((raw-slot-data (find raw-type *raw-slot-data-list*
 908                                     :key #'raw-slot-data-raw-type
 909                                     :test #'equal))
 910                (raw-slot-accessor (raw-slot-data-accessor-name raw-slot-data)))
 911           `(,raw-slot-accessor ,instance-name ,(dsd-index dsd))))))
 912
 913 ;;; Return source transforms for the reader and writer functions of
 914 ;;; the slot described by DSD. They should be inline expanded, but
 915 ;;; source transforms work faster.
 916 (defun slot-accessor-transforms (dd dsd)
 917   (let ((accessor-place-form (%accessor-place-form dd dsd
 918                                                    `(the ,(dd-name dd) instance)))
 919         (dsd-type (dsd-type dsd))
 920         (value-the (if (dsd-safe-p dsd) 'truly-the 'the)))
 921     (values (sb!c:source-transform-lambda (instance)
 922               `(,value-the ,dsd-type ,(subst instance 'instance
 923                                              accessor-place-form)))
 924             (sb!c:source-transform-lambda (new-value instance)
 925               (destructuring-bind (accessor-name &rest accessor-args)
 926                   accessor-place-form
 927                 (once-only ((new-value new-value)
 928                             (instance instance))
 929                   `(,(info :setf :inverse accessor-name)
 930                      ,@(subst instance 'instance accessor-args)
 931                      (the ,dsd-type ,new-value))))))))
 932
 933 ;;; Return a LAMBDA form which can be used to set a slot.
 934 (defun slot-setter-lambda-form (dd dsd)
 935   `(lambda (new-value instance)
 936      ,(funcall (nth-value 1 (slot-accessor-transforms dd dsd))
 937                '(dummy new-value instance))))
 938
 939 ;;; core compile-time setup of any class with a LAYOUT, used even by
 940 ;;; !DEFSTRUCT-WITH-ALTERNATE-METACLASS weirdosities
 941 (defun %compiler-set-up-layout (dd
 942                                 &optional
 943                                 ;; Several special cases
 944                                 ;; (STRUCTURE-OBJECT itself, and
 945                                 ;; structures with alternate
 946                                 ;; metaclasses) call this function
 947                                 ;; directly, and they're all at the
 948                                 ;; base of the instance class
 949                                 ;; structure, so this is a handy
 950                                 ;; default.  (But note
 951                                 ;; FUNCALLABLE-STRUCTUREs need
 952                                 ;; assistance here)
 953                                 (inherits (vector (find-layout t))))
 954
 955   (multiple-value-bind (classoid layout old-layout)
 956       (multiple-value-bind (clayout clayout-p)
 957           (info :type :compiler-layout (dd-name dd))
 958         (ensure-structure-class dd
 959                                 inherits
 960                                 (if clayout-p "previously compiled" "current")
 961                                 "compiled"
 962                                 :compiler-layout clayout))
 963     (cond (old-layout
 964            (undefine-structure (layout-classoid old-layout))
 965            (when (and (classoid-subclasses classoid)
 966                       (not (eq layout old-layout)))
 967              (collect ((subs))
 968                       (dohash (classoid layout (classoid-subclasses classoid))
 969                         (declare (ignore layout))
 970                         (undefine-structure classoid)
 971                         (subs (classoid-proper-name classoid)))
 972                       (when (subs)
 973                         (warn "removing old subclasses of ~S:~%  ~S"
 974                               (classoid-name classoid)
 975                               (subs))))))
 976           (t
 977            (unless (eq (classoid-layout classoid) layout)
 978              (register-layout layout :invalidate nil))
 979            (setf (find-classoid (dd-name dd)) classoid)))
 980
 981     ;; At this point the class should be set up in the INFO database.
 982     ;; But the logic that enforces this is a little tangled and
 983     ;; scattered, so it's not obvious, so let's check.
 984     (aver (find-classoid (dd-name dd) nil))
 985
 986     (setf (info :type :compiler-layout (dd-name dd)) layout))
 987
 988   (values))
 989
 990 ;;; Do (COMPILE LOAD EVAL)-time actions for the normal (not
 991 ;;; ALTERNATE-LAYOUT) DEFSTRUCT described by DD.
 992 (defun %compiler-defstruct (dd inherits)
 993   (declare (type defstruct-description dd))
 994
 995   (%compiler-set-up-layout dd inherits)
 996
 997   (let* ((dtype (dd-declarable-type dd)))
 998
 999     (let ((copier-name (dd-copier-name dd)))
1000       (when copier-name
1001         (sb!xc:proclaim `(ftype (sfunction (,dtype) ,dtype) ,copier-name))))
1002
1003     (let ((predicate-name (dd-predicate-name dd)))
1004       (when predicate-name
1005         (sb!xc:proclaim `(ftype (sfunction (t) boolean) ,predicate-name))
1006         ;; Provide inline expansion (or not).
1007         (ecase (dd-type dd)
1008           ((structure funcallable-structure)
1009            ;; Let the predicate be inlined.
1010            (setf (info :function :inline-expansion-designator predicate-name)
1011                  (lambda ()
1012                    `(lambda (x)
1013                       ;; This dead simple definition works because the
1014                       ;; type system knows how to generate inline type
1015                       ;; tests for instances.
1016                       (typep x ',(dd-name dd))))
1017                  (info :function :inlinep predicate-name)
1018                  :inline))
1019           ((list vector)
1020            ;; Just punt. We could provide inline expansions for :TYPE
1021            ;; LIST and :TYPE VECTOR predicates too, but it'd be a
1022            ;; little messier and we don't bother. (Does anyway use
1023            ;; typed DEFSTRUCTs at all, let alone for high
1024            ;; performance?)
1025            ))))
1026
1027     (dolist (dsd (dd-slots dd))
1028       (let* ((accessor-name (dsd-accessor-name dsd))
1029              (dsd-type (dsd-type dsd)))
1030         (when accessor-name
1031           (let ((inherited (accessor-inherited-data accessor-name dd)))
1032             (cond
1033               ((not inherited)
1034                (multiple-value-bind (reader-designator writer-designator)
1035                    (slot-accessor-transforms dd dsd)
1036                  (sb!xc:proclaim `(ftype (sfunction (,dtype) ,dsd-type)
1037                                    ,accessor-name))
1038                  (setf (info :function :source-transform accessor-name)
1039                        reader-designator)
1040                  (unless (dsd-read-only dsd)
1041                    (let ((setf-accessor-name `(setf ,accessor-name)))
1042                      (sb!xc:proclaim
1043                       `(ftype (sfunction (,dsd-type ,dtype) ,dsd-type)
1044                         ,setf-accessor-name))
1045                      (setf (info :function :source-transform setf-accessor-name)
1046                            writer-designator)))))
1047               ((not (= (cdr inherited) (dsd-index dsd)))
1048                (style-warn "~@<Non-overwritten accessor ~S does not access ~
1049                             slot with name ~S (accessing an inherited slot ~
1050                             instead).~:@>"
1051                            accessor-name
1052                            (dsd-name dsd)))))))))
1053   (values))
1054 \f
1055 ;;;; redefinition stuff
1056
1057 ;;; Compare the slots of OLD and NEW, returning 3 lists of slot names:
1058 ;;;   1. Slots which have moved,
1059 ;;;   2. Slots whose type has changed,
1060 ;;;   3. Deleted slots.
1061 (defun compare-slots (old new)
1062   (let* ((oslots (dd-slots old))
1063          (nslots (dd-slots new))
1064          (onames (mapcar #'dsd-name oslots))
1065          (nnames (mapcar #'dsd-name nslots)))
1066     (collect ((moved)
1067               (retyped))
1068       (dolist (name (intersection onames nnames))
1069         (let ((os (find name oslots :key #'dsd-name :test #'string=))
1070               (ns (find name nslots :key #'dsd-name :test #'string=)))
1071           (unless (sb!xc:subtypep (dsd-type ns) (dsd-type os))
1072             (retyped name))
1073           (unless (and (= (dsd-index os) (dsd-index ns))
1074                        (eq (dsd-raw-type os) (dsd-raw-type ns)))
1075             (moved name))))
1076       (values (moved)
1077               (retyped)
1078               (set-difference onames nnames :test #'string=)))))
1079
1080 ;;; If we are redefining a structure with different slots than in the
1081 ;;; currently loaded version, give a warning and return true.
1082 (defun redefine-structure-warning (classoid old new)
1083   (declare (type defstruct-description old new)
1084            (type classoid classoid)
1085            (ignore classoid))
1086   (let ((name (dd-name new)))
1087     (multiple-value-bind (moved retyped deleted) (compare-slots old new)
1088       (when (or moved retyped deleted)
1089         (warn
1090          "incompatibly redefining slots of structure class ~S~@
1091           Make sure any uses of affected accessors are recompiled:~@
1092           ~@[  These slots were moved to new positions:~%    ~S~%~]~
1093           ~@[  These slots have new incompatible types:~%    ~S~%~]~
1094           ~@[  These slots were deleted:~%    ~S~%~]"
1095          name moved retyped deleted)
1096         t))))
1097
1098 ;;; This function is called when we are incompatibly redefining a
1099 ;;; structure CLASS to have the specified NEW-LAYOUT. We signal an
1100 ;;; error with some proceed options and return the layout that should
1101 ;;; be used.
1102 (defun %redefine-defstruct (classoid old-layout new-layout)
1103   (declare (type classoid classoid)
1104            (type layout old-layout new-layout))
1105   (let ((name (classoid-proper-name classoid)))
1106     (restart-case
1107         (error "~@<attempt to redefine the ~S class ~S incompatibly with the current definition~:@>"
1108                'structure-object
1109                name)
1110       (continue ()
1111        :report (lambda (s)
1112                  (format s
1113                          "~@<Use the new definition of ~S, invalidating ~
1114                           already-loaded code and instances.~@:>"
1115                          name))
1116        (register-layout new-layout))
1117       (recklessly-continue ()
1118        :report (lambda (s)
1119                  (format s
1120                          "~@<Use the new definition of ~S as if it were ~
1121                           compatible, allowing old accessors to use new ~
1122                           instances and allowing new accessors to use old ~
1123                           instances.~@:>"
1124                          name))
1125        ;; classic CMU CL warning: "Any old ~S instances will be in a bad way.
1126        ;; I hope you know what you're doing..."
1127        (register-layout new-layout
1128                         :invalidate nil
1129                         :destruct-layout old-layout))
1130       (clobber-it ()
1131        ;; FIXME: deprecated 2002-10-16, and since it's only interactive
1132        ;; hackery instead of a supported feature, can probably be deleted
1133        ;; in early 2003
1134        :report "(deprecated synonym for RECKLESSLY-CONTINUE)"
1135        (register-layout new-layout
1136                         :invalidate nil
1137                         :destruct-layout old-layout))))
1138   (values))
1139
1140 ;;; This is called when we are about to define a structure class. It
1141 ;;; returns a (possibly new) class object and the layout which should
1142 ;;; be used for the new definition (may be the current layout, and
1143 ;;; also might be an uninstalled forward referenced layout.) The third
1144 ;;; value is true if this is an incompatible redefinition, in which
1145 ;;; case it is the old layout.
1146 (defun ensure-structure-class (info inherits old-context new-context
1147                                     &key compiler-layout)
1148   (multiple-value-bind (class old-layout)
1149       (destructuring-bind
1150           (&optional
1151            name
1152            (class 'structure-classoid)
1153            (constructor 'make-structure-classoid))
1154           (dd-alternate-metaclass info)
1155         (declare (ignore name))
1156         (insured-find-classoid (dd-name info)
1157                                (if (eq class 'structure-classoid)
1158                                    (lambda (x)
1159                                      (sb!xc:typep x 'structure-classoid))
1160                                    (lambda (x)
1161                                      (sb!xc:typep x (find-classoid class))))
1162                                (fdefinition constructor)))
1163     (setf (classoid-direct-superclasses class)
1164           (case (dd-name info)
1165             ((ansi-stream
1166               fd-stream
1167               sb!impl::string-input-stream sb!impl::string-output-stream
1168               sb!impl::fill-pointer-output-stream)
1169              (list (layout-classoid (svref inherits (1- (length inherits))))
1170                    (layout-classoid (svref inherits (- (length inherits) 2)))))
1171             (t
1172              (list (layout-classoid
1173                     (svref inherits (1- (length inherits))))))))
1174     (let ((new-layout (make-layout :classoid class
1175                                    :inherits inherits
1176                                    :depthoid (length inherits)
1177                                    :length (+ (dd-length info)
1178                                               (dd-raw-length info))
1179                                    :n-untagged-slots (dd-raw-length info)
1180                                    :info info))
1181           (old-layout (or compiler-layout old-layout)))
1182       (cond
1183        ((not old-layout)
1184         (values class new-layout nil))
1185        (;; This clause corresponds to an assertion in REDEFINE-LAYOUT-WARNING
1186         ;; of classic CMU CL. I moved it out to here because it was only
1187         ;; exercised in this code path anyway. -- WHN 19990510
1188         (not (eq (layout-classoid new-layout) (layout-classoid old-layout)))
1189         (error "shouldn't happen: weird state of OLD-LAYOUT?"))
1190        ((not *type-system-initialized*)
1191         (setf (layout-info old-layout) info)
1192         (values class old-layout nil))
1193        ((redefine-layout-warning old-context
1194                                  old-layout
1195                                  new-context
1196                                  (layout-length new-layout)
1197                                  (layout-inherits new-layout)
1198                                  (layout-depthoid new-layout)
1199                                  (layout-n-untagged-slots new-layout))
1200         (values class new-layout old-layout))
1201        (t
1202         (let ((old-info (layout-info old-layout)))
1203           (typecase old-info
1204             ((or defstruct-description)
1205              (cond ((redefine-structure-warning class old-info info)
1206                     (values class new-layout old-layout))
1207                    (t
1208                     (setf (layout-info old-layout) info)
1209                     (values class old-layout nil))))
1210             (null
1211              (setf (layout-info old-layout) info)
1212              (values class old-layout nil))
1213             (t
1214              (error "shouldn't happen! strange thing in LAYOUT-INFO:~%  ~S"
1215                     old-layout)
1216              (values class new-layout old-layout)))))))))
1217
1218 ;;; Blow away all the compiler info for the structure CLASS. Iterate
1219 ;;; over this type, clearing the compiler structure type info, and
1220 ;;; undefining all the associated functions.
1221 (defun undefine-structure (class)
1222   (let ((info (layout-info (classoid-layout class))))
1223     (when (defstruct-description-p info)
1224       (let ((type (dd-name info)))
1225         (remhash type *typecheckfuns*)
1226         (setf (info :type :compiler-layout type) nil)
1227         (undefine-fun-name (dd-copier-name info))
1228         (undefine-fun-name (dd-predicate-name info))
1229         (dolist (slot (dd-slots info))
1230           (let ((fun (dsd-accessor-name slot)))
1231             (unless (accessor-inherited-data fun info)
1232               (undefine-fun-name fun)
1233               (unless (dsd-read-only slot)
1234                 (undefine-fun-name `(setf ,fun)))))))
1235       ;; Clear out the SPECIFIER-TYPE cache so that subsequent
1236       ;; references are unknown types.
1237       (values-specifier-type-cache-clear)))
1238   (values))
1239 \f
1240 ;;; Return a list of pairs (name . index). Used for :TYPE'd
1241 ;;; constructors to find all the names that we have to splice in &
1242 ;;; where. Note that these types don't have a layout, so we can't look
1243 ;;; at LAYOUT-INHERITS.
1244 (defun find-name-indices (defstruct)
1245   (collect ((res))
1246     (let ((infos ()))
1247       (do ((info defstruct
1248                  (typed-structure-info-or-lose (first (dd-include info)))))
1249           ((not (dd-include info))
1250            (push info infos))
1251         (push info infos))
1252
1253       (let ((i 0))
1254         (dolist (info infos)
1255           (incf i (or (dd-offset info) 0))
1256           (when (dd-named info)
1257             (res (cons (dd-name info) i)))
1258           (setq i (dd-length info)))))
1259
1260     (res)))
1261 \f
1262 ;;; These functions are called to actually make a constructor after we
1263 ;;; have processed the arglist. The correct variant (according to the
1264 ;;; DD-TYPE) should be called. The function is defined with the
1265 ;;; specified name and arglist. VARS and TYPES are used for argument
1266 ;;; type declarations. VALUES are the values for the slots (in order.)
1267 ;;;
1268 ;;; This is split three ways because:
1269 ;;;   * LIST & VECTOR structures need "name" symbols stuck in at
1270 ;;;     various weird places, whereas STRUCTURE structures have
1271 ;;;     a LAYOUT slot.
1272 ;;;   * We really want to use LIST to make list structures, instead of
1273 ;;;     MAKE-LIST/(SETF ELT). (We can't in general use VECTOR in an
1274 ;;;     analogous way, since VECTOR makes a SIMPLE-VECTOR and vector-typed
1275 ;;;     structures can have arbitrary subtypes of VECTOR, not necessarily
1276 ;;;     SIMPLE-VECTOR.)
1277 ;;;   * STRUCTURE structures can have raw slots that must also be
1278 ;;;     allocated and indirectly referenced.
1279 (defun create-vector-constructor (dd cons-name arglist vars types values)
1280   (let ((temp (gensym))
1281         (etype (dd-element-type dd)))
1282     `(defun ,cons-name ,arglist
1283        (declare ,@(mapcar (lambda (var type) `(type (and ,type ,etype) ,var))
1284                           vars types))
1285        (let ((,temp (make-array ,(dd-length dd)
1286                                 :element-type ',(dd-element-type dd))))
1287          ,@(mapcar (lambda (x)
1288                      `(setf (aref ,temp ,(cdr x))  ',(car x)))
1289                    (find-name-indices dd))
1290          ,@(mapcar (lambda (dsd value)
1291                      (unless (eq value '.do-not-initialize-slot.)
1292                          `(setf (aref ,temp ,(dsd-index dsd)) ,value)))
1293                    (dd-slots dd) values)
1294          ,temp))))
1295 (defun create-list-constructor (dd cons-name arglist vars types values)
1296   (let ((vals (make-list (dd-length dd) :initial-element nil)))
1297     (dolist (x (find-name-indices dd))
1298       (setf (elt vals (cdr x)) `',(car x)))
1299     (loop for dsd in (dd-slots dd) and val in values do
1300       (setf (elt vals (dsd-index dsd))
1301             (if (eq val '.do-not-initialize-slot.) 0 val)))
1302
1303     `(defun ,cons-name ,arglist
1304        (declare ,@(mapcar (lambda (var type) `(type ,type ,var)) vars types))
1305        (list ,@vals))))
1306 (defun create-structure-constructor (dd cons-name arglist vars types values)
1307   (let* ((instance (gensym "INSTANCE")))
1308     `(defun ,cons-name ,arglist
1309        (declare ,@(mapcar (lambda (var type) `(type ,type ,var))
1310                           vars types))
1311        (let ((,instance (truly-the ,(dd-name dd)
1312                           (%make-instance-with-layout
1313                            (%delayed-get-compiler-layout ,(dd-name dd))))))
1314          ,@(mapcar (lambda (dsd value)
1315                      ;; (Note that we can't in general use the
1316                      ;; ordinary named slot setter function here
1317                      ;; because the slot might be :READ-ONLY, so we
1318                      ;; whip up new LAMBDA representations of slot
1319                      ;; setters for the occasion.)
1320                      (unless (eq value '.do-not-initialize-slot.)
1321                        `(,(slot-setter-lambda-form dd dsd) ,value ,instance)))
1322                    (dd-slots dd)
1323                    values)
1324          ,instance))))
1325
1326 ;;; Create a default (non-BOA) keyword constructor.
1327 (defun create-keyword-constructor (defstruct creator)
1328   (declare (type function creator))
1329   (collect ((arglist (list '&key))
1330             (types)
1331             (vals))
1332     (dolist (slot (dd-slots defstruct))
1333       (let ((dum (gensym))
1334             (name (dsd-name slot)))
1335         (arglist `((,(keywordicate name) ,dum) ,(dsd-default slot)))
1336         (types (dsd-type slot))
1337         (vals dum)))
1338     (funcall creator
1339              defstruct (dd-default-constructor defstruct)
1340              (arglist) (vals) (types) (vals))))
1341
1342 ;;; Given a structure and a BOA constructor spec, call CREATOR with
1343 ;;; the appropriate args to make a constructor.
1344 (defun create-boa-constructor (defstruct boa creator)
1345   (declare (type function creator))
1346   (multiple-value-bind (req opt restp rest keyp keys allowp auxp aux)
1347       (parse-lambda-list (second boa))
1348     (collect ((arglist)
1349               (vars)
1350               (types)
1351               (skipped-vars))
1352       (labels ((get-slot (name)
1353                  (let ((res (find name (dd-slots defstruct)
1354                                   :test #'string=
1355                                   :key #'dsd-name)))
1356                    (if res
1357                        (values (dsd-type res) (dsd-default res))
1358                        (values t nil))))
1359                (do-default (arg)
1360                  (multiple-value-bind (type default) (get-slot arg)
1361                    (arglist `(,arg ,default))
1362                    (vars arg)
1363                    (types type))))
1364         (dolist (arg req)
1365           (arglist arg)
1366           (vars arg)
1367           (types (get-slot arg)))
1368
1369         (when opt
1370           (arglist '&optional)
1371           (dolist (arg opt)
1372             (cond ((consp arg)
1373                    (destructuring-bind
1374                          ;; FIXME: this shares some logic (though not
1375                          ;; code) with the &key case below (and it
1376                          ;; looks confusing) -- factor out the logic
1377                          ;; if possible. - CSR, 2002-04-19
1378                          (name
1379                           &optional
1380                           (def (nth-value 1 (get-slot name)))
1381                           (supplied-test nil supplied-test-p))
1382                        arg
1383                      (arglist `(,name ,def ,@(if supplied-test-p `(,supplied-test) nil)))
1384                      (vars name)
1385                      (types (get-slot name))))
1386                   (t
1387                    (do-default arg)))))
1388
1389         (when restp
1390           (arglist '&rest rest)
1391           (vars rest)
1392           (types 'list))
1393
1394         (when keyp
1395           (arglist '&key)
1396           (dolist (key keys)
1397             (if (consp key)
1398                 (destructuring-bind (wot
1399                                      &optional
1400                                      (def nil def-p)
1401                                      (supplied-test nil supplied-test-p))
1402                     key
1403                   (let ((name (if (consp wot)
1404                                   (destructuring-bind (key var) wot
1405                                     (declare (ignore key))
1406                                     var)
1407                                   wot)))
1408                     (multiple-value-bind (type slot-def)
1409                         (get-slot name)
1410                       (arglist `(,wot ,(if def-p def slot-def)
1411                                  ,@(if supplied-test-p `(,supplied-test) nil)))
1412                       (vars name)
1413                       (types type))))
1414                 (do-default key))))
1415
1416         (when allowp (arglist '&allow-other-keys))
1417
1418         (when auxp
1419           (arglist '&aux)
1420           (dolist (arg aux)
1421             (arglist arg)
1422             (if (proper-list-of-length-p arg 2)
1423               (let ((var (first arg)))
1424                 (vars var)
1425                 (types (get-slot var)))
1426               (skipped-vars (if (consp arg) (first arg) arg))))))
1427
1428       (funcall creator defstruct (first boa)
1429                (arglist) (vars) (types)
1430                (loop for slot in (dd-slots defstruct)
1431                      for name = (dsd-name slot)
1432                      collect (cond ((find name (skipped-vars) :test #'string=)
1433                                     (setf (dsd-safe-p slot) nil)
1434                                     '.do-not-initialize-slot.)
1435                                    ((or (find (dsd-name slot) (vars) :test #'string=)
1436                                         (dsd-default slot)))))))))
1437
1438 ;;; Grovel the constructor options, and decide what constructors (if
1439 ;;; any) to create.
1440 (defun constructor-definitions (defstruct)
1441   (let ((no-constructors nil)
1442         (boas ())
1443         (defaults ())
1444         (creator (ecase (dd-type defstruct)
1445                    (structure #'create-structure-constructor)
1446                    (vector #'create-vector-constructor)
1447                    (list #'create-list-constructor))))
1448     (dolist (constructor (dd-constructors defstruct))
1449       (destructuring-bind (name &optional (boa-ll nil boa-p)) constructor
1450         (declare (ignore boa-ll))
1451         (cond ((not name) (setq no-constructors t))
1452               (boa-p (push constructor boas))
1453               (t (push name defaults)))))
1454
1455     (when no-constructors
1456       (when (or defaults boas)
1457         (error "(:CONSTRUCTOR NIL) combined with other :CONSTRUCTORs"))
1458       (return-from constructor-definitions ()))
1459
1460     (unless (or defaults boas)
1461       (push (symbolicate "MAKE-" (dd-name defstruct)) defaults))
1462
1463     (collect ((res) (names))
1464       (when defaults
1465         (let ((cname (first defaults)))
1466           (setf (dd-default-constructor defstruct) cname)
1467           (res (create-keyword-constructor defstruct creator))
1468           (names cname)
1469           (dolist (other-name (rest defaults))
1470             (res `(setf (fdefinition ',other-name) (fdefinition ',cname)))
1471             (names other-name))))
1472
1473       (dolist (boa boas)
1474         (res (create-boa-constructor defstruct boa creator))
1475         (names (first boa)))
1476
1477       (res `(declaim (ftype
1478                       (sfunction *
1479                                  ,(if (eq (dd-type defstruct) 'structure)
1480                                       (dd-name defstruct)
1481                                       '*))
1482                       ,@(names))))
1483
1484       (res))))
1485 \f
1486 ;;;; instances with ALTERNATE-METACLASS
1487 ;;;;
1488 ;;;; The CMU CL support for structures with ALTERNATE-METACLASS was a
1489 ;;;; fairly general extension embedded in the main DEFSTRUCT code, and
1490 ;;;; the result was an fairly impressive mess as ALTERNATE-METACLASS
1491 ;;;; extension mixed with ANSI CL generality (e.g. :TYPE and :INCLUDE)
1492 ;;;; and CMU CL implementation hairiness (esp. raw slots). This SBCL
1493 ;;;; version is much less ambitious, noticing that ALTERNATE-METACLASS
1494 ;;;; is only used to implement CONDITION, STANDARD-INSTANCE, and
1495 ;;;; GENERIC-FUNCTION, and defining a simple specialized
1496 ;;;; separate-from-DEFSTRUCT macro to provide only enough
1497 ;;;; functionality to support those.
1498 ;;;;
1499 ;;;; KLUDGE: The defining macro here is so specialized that it's ugly
1500 ;;;; in its own way. It also violates once-and-only-once by knowing
1501 ;;;; much about structures and layouts that is already known by the
1502 ;;;; main DEFSTRUCT macro. Hopefully it will go away presently
1503 ;;;; (perhaps when CL:CLASS and SB-PCL:CLASS meet) as per FIXME below.
1504 ;;;; -- WHN 2001-10-28
1505 ;;;;
1506 ;;;; FIXME: There seems to be no good reason to shoehorn CONDITION,
1507 ;;;; STANDARD-INSTANCE, and GENERIC-FUNCTION into mutated structures
1508 ;;;; instead of just implementing them as primitive objects. (This
1509 ;;;; reduced-functionality macro seems pretty close to the
1510 ;;;; functionality of DEFINE-PRIMITIVE-OBJECT..)
1511
1512 (defun make-dd-with-alternate-metaclass (&key (class-name (missing-arg))
1513                                               (superclass-name (missing-arg))
1514                                               (metaclass-name (missing-arg))
1515                                               (dd-type (missing-arg))
1516                                               metaclass-constructor
1517                                               slot-names)
1518   (let* ((dd (make-defstruct-description class-name))
1519          (conc-name (concatenate 'string (symbol-name class-name) "-"))
1520          (dd-slots (let ((reversed-result nil)
1521                          ;; The index starts at 1 for ordinary named
1522                          ;; slots because slot 0 is magical, used for
1523                          ;; the LAYOUT in CONDITIONs and
1524                          ;; FUNCALLABLE-INSTANCEs.  (This is the same
1525                          ;; in ordinary structures too: see (INCF
1526                          ;; DD-LENGTH) in
1527                          ;; PARSE-DEFSTRUCT-NAME-AND-OPTIONS).
1528                          (index 1))
1529                      (dolist (slot-name slot-names)
1530                        (push (make-defstruct-slot-description
1531                               :name slot-name
1532                               :index index
1533                               :accessor-name (symbolicate conc-name slot-name))
1534                              reversed-result)
1535                        (incf index))
1536                      (nreverse reversed-result))))
1537     (case dd-type
1538       ;; We don't support inheritance of alternate metaclass stuff,
1539       ;; and it's not a general-purpose facility, so sanity check our
1540       ;; own code.
1541       (structure
1542        (aver (eq superclass-name 't)))
1543       (funcallable-structure
1544        (aver (eq superclass-name 'function)))
1545       (t (bug "Unknown DD-TYPE in ALTERNATE-METACLASS: ~S" dd-type)))
1546     (setf (dd-alternate-metaclass dd) (list superclass-name
1547                                             metaclass-name
1548                                             metaclass-constructor)
1549           (dd-slots dd) dd-slots
1550           (dd-length dd) (1+ (length slot-names))
1551           (dd-type dd) dd-type)
1552     dd))
1553
1554 (sb!xc:defmacro !defstruct-with-alternate-metaclass
1555     (class-name &key
1556                 (slot-names (missing-arg))
1557                 (boa-constructor (missing-arg))
1558                 (superclass-name (missing-arg))
1559                 (metaclass-name (missing-arg))
1560                 (metaclass-constructor (missing-arg))
1561                 (dd-type (missing-arg))
1562                 predicate
1563                 (runtime-type-checks-p t))
1564
1565   (declare (type (and list (not null)) slot-names))
1566   (declare (type (and symbol (not null))
1567                  boa-constructor
1568                  superclass-name
1569                  metaclass-name
1570                  metaclass-constructor))
1571   (declare (type symbol predicate))
1572   (declare (type (member structure funcallable-structure) dd-type))
1573
1574   (let* ((dd (make-dd-with-alternate-metaclass
1575               :class-name class-name
1576               :slot-names slot-names
1577               :superclass-name superclass-name
1578               :metaclass-name metaclass-name
1579               :metaclass-constructor metaclass-constructor
1580               :dd-type dd-type))
1581          (dd-slots (dd-slots dd))
1582          (dd-length (1+ (length slot-names)))
1583          (object-gensym (gensym "OBJECT"))
1584          (new-value-gensym (gensym "NEW-VALUE-"))
1585          (delayed-layout-form `(%delayed-get-compiler-layout ,class-name)))
1586     (multiple-value-bind (raw-maker-form raw-reffer-operator)
1587         (ecase dd-type
1588           (structure
1589            (values `(let ((,object-gensym (%make-instance ,dd-length)))
1590                       (setf (%instance-layout ,object-gensym)
1591                             ,delayed-layout-form)
1592                       ,object-gensym)
1593                    '%instance-ref))
1594           (funcallable-structure
1595            (values `(let ((,object-gensym
1596                            (%make-funcallable-instance ,dd-length)))
1597                       (setf (%funcallable-instance-layout ,object-gensym)
1598                             ,delayed-layout-form)
1599                       ,object-gensym)
1600                    '%funcallable-instance-info)))
1601       `(progn
1602
1603          (eval-when (:compile-toplevel :load-toplevel :execute)
1604            (%compiler-set-up-layout ',dd ',(inherits-for-structure dd)))
1605
1606          ;; slot readers and writers
1607          (declaim (inline ,@(mapcar #'dsd-accessor-name dd-slots)))
1608          ,@(mapcar (lambda (dsd)
1609                      `(defun ,(dsd-accessor-name dsd) (,object-gensym)
1610                         ,@(when runtime-type-checks-p
1611                             `((declare (type ,class-name ,object-gensym))))
1612                         (,raw-reffer-operator ,object-gensym
1613                                               ,(dsd-index dsd))))
1614                    dd-slots)
1615          (declaim (inline ,@(mapcar (lambda (dsd)
1616                                       `(setf ,(dsd-accessor-name dsd)))
1617                                     dd-slots)))
1618          ,@(mapcar (lambda (dsd)
1619                      `(defun (setf ,(dsd-accessor-name dsd)) (,new-value-gensym
1620                                                               ,object-gensym)
1621                         ,@(when runtime-type-checks-p
1622                             `((declare (type ,class-name ,object-gensym))))
1623                         (setf (,raw-reffer-operator ,object-gensym
1624                                                     ,(dsd-index dsd))
1625                               ,new-value-gensym)))
1626                    dd-slots)
1627
1628          ;; constructor
1629          (defun ,boa-constructor ,slot-names
1630            (let ((,object-gensym ,raw-maker-form))
1631              ,@(mapcar (lambda (slot-name)
1632                          (let ((dsd (find (symbol-name slot-name) dd-slots
1633                                           :key (lambda (x)
1634                                                  (symbol-name (dsd-name x)))
1635                                           :test #'string=)))
1636                            ;; KLUDGE: bug 117 bogowarning.  Neither
1637                            ;; DECLAREing the type nor TRULY-THE cut
1638                            ;; the mustard -- it still gives warnings.
1639                            (enforce-type dsd defstruct-slot-description)
1640                            `(setf (,(dsd-accessor-name dsd) ,object-gensym)
1641                                   ,slot-name)))
1642                        slot-names)
1643              ,object-gensym))
1644
1645          ;; predicate
1646          ,@(when predicate
1647              ;; Just delegate to the compiler's type optimization
1648              ;; code, which knows how to generate inline type tests
1649              ;; for the whole CMU CL INSTANCE menagerie.
1650              `(defun ,predicate (,object-gensym)
1651                 (typep ,object-gensym ',class-name)))))))
1652 \f
1653 ;;;; finalizing bootstrapping
1654
1655 ;;; Set up DD and LAYOUT for STRUCTURE-OBJECT class itself.
1656 ;;;
1657 ;;; Ordinary structure classes effectively :INCLUDE STRUCTURE-OBJECT
1658 ;;; when they have no explicit :INCLUDEs, so (1) it needs to be set up
1659 ;;; before we can define ordinary structure classes, and (2) it's
1660 ;;; special enough (and simple enough) that we just build it by hand
1661 ;;; instead of trying to generalize the ordinary DEFSTRUCT code.
1662 (defun !set-up-structure-object-class ()
1663   (let ((dd (make-defstruct-description 'structure-object)))
1664     (setf
1665      ;; Note: This has an ALTERNATE-METACLASS only because of blind
1666      ;; clueless imitation of the CMU CL code -- dunno if or why it's
1667      ;; needed. -- WHN
1668      (dd-alternate-metaclass dd) '(t)
1669      (dd-slots dd) nil
1670      (dd-length dd) 1
1671      (dd-type dd) 'structure)
1672     (%compiler-set-up-layout dd)))
1673 (!set-up-structure-object-class)
1674
1675 ;;; early structure predeclarations: Set up DD and LAYOUT for ordinary
1676 ;;; (non-ALTERNATE-METACLASS) structures which are needed early.
1677 (dolist (args
1678          '#.(sb-cold:read-from-file
1679              "src/code/early-defstruct-args.lisp-expr"))
1680   (let* ((dd (parse-defstruct-name-and-options-and-slot-descriptions
1681               (first args)
1682               (rest args)))
1683          (inherits (inherits-for-structure dd)))
1684     (%compiler-defstruct dd inherits)))
1685
1686 (/show0 "code/defstruct.lisp end of file")