src/code/defstruct.lisp

   1 ;;;; that part of DEFSTRUCT implementation which is needed not just
   2 ;;;; in the target Lisp but also in the cross-compilation host
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!KERNEL")
  14
  15 (/show0 "code/defstruct.lisp 15")
  16 \f
  17 ;;;; getting LAYOUTs
  18
  19 ;;; Return the compiler layout for NAME. (The class referred to by
  20 ;;; NAME must be a structure-like class.)
  21 (defun compiler-layout-or-lose (name)
  22   (let ((res (info :type :compiler-layout name)))
  23     (cond ((not res)
  24            (error "Class is not yet defined or was undefined: ~S" name))
  25           ((not (typep (layout-info res) 'defstruct-description))
  26            (error "Class is not a structure class: ~S" name))
  27           (t res))))
  28
  29 ;;; Delay looking for compiler-layout until the constructor is being
  30 ;;; compiled, since it doesn't exist until after the EVAL-WHEN
  31 ;;; (COMPILE) stuff is compiled. (Or, in the oddball case when
  32 ;;; DEFSTRUCT is executing in a non-toplevel context, the
  33 ;;; compiler-layout still doesn't exist at compilation time, and we
  34 ;;; delay still further.)
  35 (sb!xc:defmacro %delayed-get-compiler-layout (name)
  36   (let ((layout (info :type :compiler-layout name)))
  37     (cond (layout
  38            ;; ordinary case: When the DEFSTRUCT is at top level,
  39            ;; then EVAL-WHEN (COMPILE) stuff will have set up the
  40            ;; layout for us to use.
  41            (unless (typep (layout-info layout) 'defstruct-description)
  42              (error "Class is not a structure class: ~S" name))
  43            `,layout)
  44           (t
  45            ;; KLUDGE: In the case that DEFSTRUCT is not at top-level
  46            ;; the layout doesn't exist at compile time. In that case
  47            ;; we laboriously look it up at run time. This code will
  48            ;; run on every constructor call and will likely be quite
  49            ;; slow, so if anyone cares about performance of
  50            ;; non-toplevel DEFSTRUCTs, it should be rewritten to be
  51            ;; cleverer. -- WHN 2002-10-23
  52            (sb!c::compiler-note
  53             "implementation limitation: ~
  54              Non-toplevel DEFSTRUCT constructors are slow.")
  55            (with-unique-names (layout)
  56              `(let ((,layout (info :type :compiler-layout ',name)))
  57                 (unless (typep (layout-info ,layout) 'defstruct-description)
  58                   (error "Class is not a structure class: ~S" ',name))
  59                 ,layout))))))
  60
  61 ;;; Get layout right away.
  62 (sb!xc:defmacro compile-time-find-layout (name)
  63   (find-layout name))
  64
  65 ;;; re. %DELAYED-GET-COMPILER-LAYOUT and COMPILE-TIME-FIND-LAYOUT, above..
  66 ;;;
  67 ;;; FIXME: Perhaps both should be defined with DEFMACRO-MUNDANELY?
  68 ;;; FIXME: Do we really need both? If so, their names and implementations
  69 ;;; should probably be tweaked to be more parallel.
  70 \f
  71 ;;;; DEFSTRUCT-DESCRIPTION
  72
  73 ;;; The DEFSTRUCT-DESCRIPTION structure holds compile-time information
  74 ;;; about a structure type.
  75 (def!struct (defstruct-description
  76              (:conc-name dd-)
  77              (:make-load-form-fun just-dump-it-normally)
  78              #-sb-xc-host (:pure t)
  79              (:constructor make-defstruct-description
  80                            (name &aux
  81                                  (conc-name (symbolicate name "-"))
  82                                  (copier-name (symbolicate "COPY-" name))
  83                                  (predicate-name (symbolicate name "-P")))))
  84   ;; name of the structure
  85   (name (missing-arg) :type symbol :read-only t)
  86   ;; documentation on the structure
  87   (doc nil :type (or string null))
  88   ;; prefix for slot names. If NIL, none.
  89   (conc-name nil :type (or symbol null))
  90   ;; the name of the primary standard keyword constructor, or NIL if none
  91   (default-constructor nil :type (or symbol null))
  92   ;; all the explicit :CONSTRUCTOR specs, with name defaulted
  93   (constructors () :type list)
  94   ;; name of copying function
  95   (copier-name nil :type (or symbol null))
  96   ;; name of type predicate
  97   (predicate-name nil :type (or symbol null))
  98   ;; the arguments to the :INCLUDE option, or NIL if no included
  99   ;; structure
 100   (include nil :type list)
 101   ;; properties used to define structure-like classes with an
 102   ;; arbitrary superclass and that may not have STRUCTURE-CLASS as the
 103   ;; metaclass. Syntax is:
 104   ;;    (superclass-name metaclass-name metaclass-constructor)
 105   (alternate-metaclass nil :type list)
 106   ;; a list of DEFSTRUCT-SLOT-DESCRIPTION objects for all slots
 107   ;; (including included ones)
 108   (slots () :type list)
 109   ;; a list of (NAME . INDEX) pairs for accessors of included structures
 110   (inherited-accessor-alist () :type list)
 111   ;; number of elements we've allocated (See also RAW-LENGTH.)
 112   (length 0 :type index)
 113   ;; General kind of implementation.
 114   (type 'structure :type (member structure vector list
 115                                  funcallable-structure))
 116
 117   ;; The next three slots are for :TYPE'd structures (which aren't
 118   ;; classes, DD-CLASS-P = NIL)
 119   ;;
 120   ;; vector element type
 121   (element-type t)
 122   ;; T if :NAMED was explicitly specified, NIL otherwise
 123   (named nil :type boolean)
 124   ;; any INITIAL-OFFSET option on this direct type
 125   (offset nil :type (or index null))
 126
 127   ;; the argument to the PRINT-FUNCTION option, or NIL if a
 128   ;; PRINT-FUNCTION option was given with no argument, or 0 if no
 129   ;; PRINT-FUNCTION option was given
 130   (print-function 0 :type (or cons symbol (member 0)))
 131   ;; the argument to the PRINT-OBJECT option, or NIL if a PRINT-OBJECT
 132   ;; option was given with no argument, or 0 if no PRINT-OBJECT option
 133   ;; was given
 134   (print-object 0 :type (or cons symbol (member 0)))
 135   ;; the index of the raw data vector and the number of words in it,
 136   ;; or NIL and 0 if not allocated (either because this structure
 137   ;; has no raw slots, or because we're still parsing it and haven't
 138   ;; run across any raw slots yet)
 139   (raw-index nil :type (or index null))
 140   (raw-length 0 :type index)
 141   ;; the value of the :PURE option, or :UNSPECIFIED. This is only
 142   ;; meaningful if DD-CLASS-P = T.
 143   (pure :unspecified :type (member t nil :substructure :unspecified)))
 144 (def!method print-object ((x defstruct-description) stream)
 145   (print-unreadable-object (x stream :type t)
 146     (prin1 (dd-name x) stream)))
 147
 148 ;;; Does DD describe a structure with a class?
 149 (defun dd-class-p (dd)
 150   (member (dd-type dd)
 151           '(structure funcallable-structure)))
 152
 153 ;;; a type name which can be used when declaring things which operate
 154 ;;; on structure instances
 155 (defun dd-declarable-type (dd)
 156   (if (dd-class-p dd)
 157       ;; Native classes are known to the type system, and we can
 158       ;; declare them as types.
 159       (dd-name dd)
 160       ;; Structures layered on :TYPE LIST or :TYPE VECTOR aren't part
 161       ;; of the type system, so all we can declare is the underlying
 162       ;; LIST or VECTOR type.
 163       (dd-type dd)))
 164
 165 (defun dd-layout-or-lose (dd)
 166   (compiler-layout-or-lose (dd-name dd)))
 167 \f
 168 ;;;; DEFSTRUCT-SLOT-DESCRIPTION
 169
 170 ;;; A DEFSTRUCT-SLOT-DESCRIPTION holds compile-time information about
 171 ;;; a structure slot.
 172 (def!struct (defstruct-slot-description
 173              (:make-load-form-fun just-dump-it-normally)
 174              (:conc-name dsd-)
 175              (:copier nil)
 176              #-sb-xc-host (:pure t))
 177   ;; name of slot
 178   name
 179   ;; its position in the implementation sequence
 180   (index (missing-arg) :type fixnum)
 181   ;; the name of the accessor function
 182   ;;
 183   ;; (CMU CL had extra complexity here ("..or NIL if this accessor has
 184   ;; the same name as an inherited accessor (which we don't want to
 185   ;; shadow)") but that behavior doesn't seem to be specified by (or
 186   ;; even particularly consistent with) ANSI, so it's gone in SBCL.)
 187   (accessor-name nil)
 188   default                       ; default value expression
 189   (type t)                      ; declared type specifier
 190   (safe-p t :type boolean)      ; whether the slot is known to be
 191                                 ; always of the specified type
 192   ;; If this object does not describe a raw slot, this value is T.
 193   ;;
 194   ;; If this object describes a raw slot, this value is the type of the
 195   ;; value that the raw slot holds. Mostly. (KLUDGE: If the raw slot has
 196   ;; type (UNSIGNED-BYTE 32), the value here is UNSIGNED-BYTE, not
 197   ;; (UNSIGNED-BYTE 32).)
 198   (raw-type t :type (member t single-float double-float
 199                             #!+long-float long-float
 200                             complex-single-float complex-double-float
 201                             #!+long-float complex-long-float
 202                             unsigned-byte))
 203   (read-only nil :type (member t nil)))
 204 (def!method print-object ((x defstruct-slot-description) stream)
 205   (print-unreadable-object (x stream :type t)
 206     (prin1 (dsd-name x) stream)))
 207 \f
 208 ;;;; typed (non-class) structures
 209
 210 ;;; Return a type specifier we can use for testing :TYPE'd structures.
 211 (defun dd-lisp-type (defstruct)
 212   (ecase (dd-type defstruct)
 213     (list 'list)
 214     (vector `(simple-array ,(dd-element-type defstruct) (*)))))
 215 \f
 216 ;;;; shared machinery for inline and out-of-line slot accessor functions
 217
 218 (eval-when (#-sb-xc :compile-toplevel :load-toplevel :execute)
 219
 220   ;; information about how a slot of a given DSD-RAW-TYPE is to be accessed
 221   (defstruct raw-slot-data
 222     ;; the raw slot type, or T for a non-raw slot
 223     ;;
 224     ;; (Raw slots are allocated in the raw slots array in a vector which
 225     ;; the GC doesn't need to scavenge. Non-raw slots are in the
 226     ;; ordinary place you'd expect, directly indexed off the instance
 227     ;; pointer.)
 228     (raw-type (missing-arg) :type (or symbol cons) :read-only t)
 229     ;; What operator is used (on the raw data vector) to access a slot
 230     ;; of this type?
 231     (accessor-name (missing-arg) :type symbol :read-only t)
 232     ;; How many words are each value of this type? (This is used to
 233     ;; rescale the offset into the raw data vector.)
 234     (n-words (missing-arg) :type (and index (integer 1)) :read-only t))
 235
 236   (defvar *raw-slot-data-list*
 237     (list
 238      ;; The compiler thinks that the raw data vector is a vector of
 239      ;; word-sized unsigned bytes, so if the slot we want to access
 240      ;; actually *is* an unsigned byte, it'll access the slot for us
 241      ;; even if we don't lie to it at all, just let it use normal AREF.
 242      (make-raw-slot-data :raw-type 'unsigned-byte
 243                          :accessor-name 'aref
 244                          :n-words 1)
 245      ;; In the other cases, we lie to the compiler, making it use
 246      ;; some low-level AREFish access in order to pun the hapless
 247      ;; bits into some other-than-unsigned-byte meaning.
 248      ;;
 249      ;; "A lie can travel halfway round the world while the truth is
 250      ;; putting on its shoes." -- Mark Twain
 251      (make-raw-slot-data :raw-type 'single-float
 252                          :accessor-name '%raw-ref-single
 253                          :n-words 1)
 254      (make-raw-slot-data :raw-type 'double-float
 255                          :accessor-name '%raw-ref-double
 256                          :n-words 2)
 257      (make-raw-slot-data :raw-type 'complex-single-float
 258                          :accessor-name '%raw-ref-complex-single
 259                          :n-words 2)
 260      (make-raw-slot-data :raw-type 'complex-double-float
 261                          :accessor-name '%raw-ref-complex-double
 262                          :n-words 4)
 263      #!+long-float
 264      (make-raw-slot-data :raw-type long-float
 265                          :accessor-name '%raw-ref-long
 266                          :n-words #!+x86 3 #!+sparc 4)
 267      #!+long-float
 268      (make-raw-slot-data :raw-type complex-long-float
 269                          :accessor-name '%raw-ref-complex-long
 270                          :n-words #!+x86 6 #!+sparc 8))))
 271 \f
 272 ;;;; the legendary DEFSTRUCT macro itself (both CL:DEFSTRUCT and its
 273 ;;;; close personal friend SB!XC:DEFSTRUCT)
 274
 275 ;;; Return a list of forms to install PRINT and MAKE-LOAD-FORM funs,
 276 ;;; mentioning them in the expansion so that they can be compiled.
 277 (defun class-method-definitions (defstruct)
 278   (let ((name (dd-name defstruct)))
 279     `((locally
 280         ;; KLUDGE: There's a FIND-CLASS DEFTRANSFORM for constant
 281         ;; class names which creates fast but non-cold-loadable,
 282         ;; non-compact code. In this context, we'd rather have
 283         ;; compact, cold-loadable code. -- WHN 19990928
 284         (declare (notinline find-classoid))
 285         ,@(let ((pf (dd-print-function defstruct))
 286                 (po (dd-print-object defstruct))
 287                 (x (gensym))
 288                 (s (gensym)))
 289             ;; Giving empty :PRINT-OBJECT or :PRINT-FUNCTION options
 290             ;; leaves PO or PF equal to NIL. The user-level effect is
 291             ;; to generate a PRINT-OBJECT method specialized for the type,
 292             ;; implementing the default #S structure-printing behavior.
 293             (when (or (eq pf nil) (eq po nil))
 294               (setf pf '(default-structure-print)
 295                     po 0))
 296             (flet (;; Given an arg from a :PRINT-OBJECT or :PRINT-FUNCTION
 297                    ;; option, return the value to pass as an arg to FUNCTION.
 298                    (farg (oarg)
 299                      (destructuring-bind (fun-name) oarg
 300                        fun-name)))
 301               (cond ((not (eql pf 0))
 302                      `((def!method print-object ((,x ,name) ,s)
 303                          (funcall #',(farg pf)
 304                                   ,x
 305                                   ,s
 306                                   *current-level-in-print*))))
 307                     ((not (eql po 0))
 308                      `((def!method print-object ((,x ,name) ,s)
 309                          (funcall #',(farg po) ,x ,s))))
 310                     (t nil))))
 311         ,@(let ((pure (dd-pure defstruct)))
 312             (cond ((eq pure t)
 313                    `((setf (layout-pure (classoid-layout
 314                                          (find-classoid ',name)))
 315                            t)))
 316                   ((eq pure :substructure)
 317                    `((setf (layout-pure (classoid-layout
 318                                          (find-classoid ',name)))
 319                            0)))))
 320         ,@(let ((def-con (dd-default-constructor defstruct)))
 321             (when (and def-con (not (dd-alternate-metaclass defstruct)))
 322               `((setf (structure-classoid-constructor (find-classoid ',name))
 323                       #',def-con))))))))
 324
 325 ;;; shared logic for CL:DEFSTRUCT and SB!XC:DEFSTRUCT
 326 (defmacro !expander-for-defstruct (name-and-options
 327                                    slot-descriptions
 328                                    expanding-into-code-for-xc-host-p)
 329   `(let ((name-and-options ,name-and-options)
 330          (slot-descriptions ,slot-descriptions)
 331          (expanding-into-code-for-xc-host-p
 332           ,expanding-into-code-for-xc-host-p))
 333      (let* ((dd (parse-defstruct-name-and-options-and-slot-descriptions
 334                  name-and-options
 335                  slot-descriptions))
 336             (name (dd-name dd)))
 337        (if (dd-class-p dd)
 338            (let ((inherits (inherits-for-structure dd)))
 339              `(progn
 340                 ;; Note we intentionally call %DEFSTRUCT first, and
 341                 ;; especially before %COMPILER-DEFSTRUCT. %DEFSTRUCT
 342                 ;; has the tests (and resulting CERROR) for collisions
 343                 ;; with LAYOUTs which already exist in the runtime. If
 344                 ;; there are any collisions, we want the user's
 345                 ;; response to CERROR to control what happens.
 346                 ;; Especially, if the user responds to the collision
 347                 ;; with ABORT, we don't want %COMPILER-DEFSTRUCT to
 348                 ;; modify the definition of the class.
 349                 (%defstruct ',dd ',inherits)
 350                 (eval-when (:compile-toplevel :load-toplevel :execute)
 351                   (%compiler-defstruct ',dd ',inherits))
 352                 ,@(unless expanding-into-code-for-xc-host-p
 353                     (append ;; FIXME: We've inherited from CMU CL nonparallel
 354                             ;; code for creating copiers for typed and untyped
 355                             ;; structures. This should be fixed.
 356                             ;(copier-definition dd)
 357                             (constructor-definitions dd)
 358                             (class-method-definitions dd)))
 359                 ',name))
 360            `(progn
 361               (eval-when (:compile-toplevel :load-toplevel :execute)
 362                 (setf (info :typed-structure :info ',name) ',dd))
 363               ,@(unless expanding-into-code-for-xc-host-p
 364                   (append (typed-accessor-definitions dd)
 365                           (typed-predicate-definitions dd)
 366                           (typed-copier-definitions dd)
 367                           (constructor-definitions dd)))
 368               ',name)))))
 369
 370 (sb!xc:defmacro defstruct (name-and-options &rest slot-descriptions)
 371   #!+sb-doc
 372   "DEFSTRUCT {Name | (Name Option*)} {Slot | (Slot [Default] {Key Value}*)}
 373    Define the structure type Name. Instances are created by MAKE-<name>,
 374    which takes &KEY arguments allowing initial slot values to the specified.
 375    A SETF'able function <name>-<slot> is defined for each slot to read and
 376    write slot values. <name>-p is a type predicate.
 377
 378    Popular DEFSTRUCT options (see manual for others):
 379
 380    (:CONSTRUCTOR Name)
 381    (:PREDICATE Name)
 382        Specify the name for the constructor or predicate.
 383
 384    (:CONSTRUCTOR Name Lambda-List)
 385        Specify the name and arguments for a BOA constructor
 386        (which is more efficient when keyword syntax isn't necessary.)
 387
 388    (:INCLUDE Supertype Slot-Spec*)
 389        Make this type a subtype of the structure type Supertype. The optional
 390        Slot-Specs override inherited slot options.
 391
 392    Slot options:
 393
 394    :TYPE Type-Spec
 395        Asserts that the value of this slot is always of the specified type.
 396
 397    :READ-ONLY {T | NIL}
 398        If true, no setter function is defined for this slot."
 399     (!expander-for-defstruct name-and-options slot-descriptions nil))
 400 #+sb-xc-host
 401 (defmacro sb!xc:defstruct (name-and-options &rest slot-descriptions)
 402   #!+sb-doc
 403   "Cause information about a target structure to be built into the
 404   cross-compiler."
 405   (!expander-for-defstruct name-and-options slot-descriptions t))
 406 \f
 407 ;;;; functions to generate code for various parts of DEFSTRUCT definitions
 408
 409 ;;; First, a helper to determine whether a name names an inherited
 410 ;;; accessor.
 411 (defun accessor-inherited-data (name defstruct)
 412   (assoc name (dd-inherited-accessor-alist defstruct) :test #'eq))
 413
 414 ;;; Return a list of forms which create a predicate function for a
 415 ;;; typed DEFSTRUCT.
 416 (defun typed-predicate-definitions (defstruct)
 417   (let ((name (dd-name defstruct))
 418         (predicate-name (dd-predicate-name defstruct))
 419         (argname (gensym)))
 420     (when (and predicate-name (dd-named defstruct))
 421       (let ((ltype (dd-lisp-type defstruct))
 422             (name-index (cdr (car (last (find-name-indices defstruct))))))
 423         `((defun ,predicate-name (,argname)
 424             (and (typep ,argname ',ltype)
 425                  ,(cond
 426                    ((subtypep ltype 'list)
 427                     `(consp (nthcdr ,name-index (the ,ltype ,argname))))
 428                    ((subtypep ltype 'vector)
 429                     `(= (length (the ,ltype ,argname))
 430                         ,(dd-length defstruct)))
 431                    (t (bug "Uncatered-for lisp type in typed DEFSTRUCT: ~S."
 432                            ltype)))
 433                  (eq (elt (the ,ltype ,argname)
 434                           ,name-index)
 435                      ',name))))))))
 436
 437 ;;; Return a list of forms to create a copier function of a typed DEFSTRUCT.
 438 (defun typed-copier-definitions (defstruct)
 439   (when (dd-copier-name defstruct)
 440     `((setf (fdefinition ',(dd-copier-name defstruct)) #'copy-seq)
 441       (declaim (ftype function ,(dd-copier-name defstruct))))))
 442
 443 ;;; Return a list of function definitions for accessing and setting
 444 ;;; the slots of a typed DEFSTRUCT. The functions are proclaimed to be
 445 ;;; inline, and the types of their arguments and results are declared
 446 ;;; as well. We count on the compiler to do clever things with ELT.
 447 (defun typed-accessor-definitions (defstruct)
 448   (collect ((stuff))
 449     (let ((ltype (dd-lisp-type defstruct)))
 450       (dolist (slot (dd-slots defstruct))
 451         (let ((name (dsd-accessor-name slot))
 452               (index (dsd-index slot))
 453               (slot-type `(and ,(dsd-type slot)
 454                                ,(dd-element-type defstruct))))
 455           (let ((inherited (accessor-inherited-data name defstruct)))
 456             (cond
 457               ((not inherited)
 458                (stuff `(proclaim '(inline ,name (setf ,name))))
 459                ;; FIXME: The arguments in the next two DEFUNs should
 460                ;; be gensyms. (Otherwise e.g. if NEW-VALUE happened to
 461                ;; be the name of a special variable, things could get
 462                ;; weird.)
 463                (stuff `(defun ,name (structure)
 464                         (declare (type ,ltype structure))
 465                         (the ,slot-type (elt structure ,index))))
 466                (unless (dsd-read-only slot)
 467                  (stuff
 468                   `(defun (setf ,name) (new-value structure)
 469                     (declare (type ,ltype structure) (type ,slot-type new-value))
 470                     (setf (elt structure ,index) new-value)))))
 471               ((not (= (cdr inherited) index))
 472                (style-warn "~@<Non-overwritten accessor ~S does not access ~
 473                             slot with name ~S (accessing an inherited slot ~
 474                             instead).~:@>" name (dsd-name slot))))))))
 475     (stuff)))
 476 \f
 477 ;;;; parsing
 478
 479 (defun require-no-print-options-so-far (defstruct)
 480   (unless (and (eql (dd-print-function defstruct) 0)
 481                (eql (dd-print-object defstruct) 0))
 482     (error "No more than one of the following options may be specified:
 483   :PRINT-FUNCTION, :PRINT-OBJECT, :TYPE")))
 484
 485 ;;; Parse a single DEFSTRUCT option and store the results in DD.
 486 (defun parse-1-dd-option (option dd)
 487   (let ((args (rest option))
 488         (name (dd-name dd)))
 489     (case (first option)
 490       (:conc-name
 491        (destructuring-bind (&optional conc-name) args
 492          (setf (dd-conc-name dd)
 493                (if (symbolp conc-name)
 494                    conc-name
 495                    (make-symbol (string conc-name))))))
 496       (:constructor
 497        (destructuring-bind (&optional (cname (symbolicate "MAKE-" name))
 498                                       &rest stuff)
 499            args
 500          (push (cons cname stuff) (dd-constructors dd))))
 501       (:copier
 502        (destructuring-bind (&optional (copier (symbolicate "COPY-" name)))
 503            args
 504          (setf (dd-copier-name dd) copier)))
 505       (:predicate
 506        (destructuring-bind (&optional (predicate-name (symbolicate name "-P")))
 507            args
 508          (setf (dd-predicate-name dd) predicate-name)))
 509       (:include
 510        (when (dd-include dd)
 511          (error "more than one :INCLUDE option"))
 512        (setf (dd-include dd) args))
 513       (:print-function
 514        (require-no-print-options-so-far dd)
 515        (setf (dd-print-function dd)
 516              (the (or symbol cons) args)))
 517       (:print-object
 518        (require-no-print-options-so-far dd)
 519        (setf (dd-print-object dd)
 520              (the (or symbol cons) args)))
 521       (:type
 522        (destructuring-bind (type) args
 523          (cond ((member type '(list vector))
 524                 (setf (dd-element-type dd) t)
 525                 (setf (dd-type dd) type))
 526                ((and (consp type) (eq (first type) 'vector))
 527                 (destructuring-bind (vector vtype) type
 528                   (declare (ignore vector))
 529                   (setf (dd-element-type dd) vtype)
 530                   (setf (dd-type dd) 'vector)))
 531                (t
 532                 (error "~S is a bad :TYPE for DEFSTRUCT." type)))))
 533       (:named
 534        (error "The DEFSTRUCT option :NAMED takes no arguments."))
 535       (:initial-offset
 536        (destructuring-bind (offset) args
 537          (setf (dd-offset dd) offset)))
 538       (:pure
 539        (destructuring-bind (fun) args
 540          (setf (dd-pure dd) fun)))
 541       (t (error "unknown DEFSTRUCT option:~%  ~S" option)))))
 542
 543 ;;; Given name and options, return a DD holding that info.
 544 (defun parse-defstruct-name-and-options (name-and-options)
 545   (destructuring-bind (name &rest options) name-and-options
 546     (aver name) ; A null name doesn't seem to make sense here.
 547     (let ((dd (make-defstruct-description name)))
 548       (dolist (option options)
 549         (cond ((eq option :named)
 550                (setf (dd-named dd) t))
 551               ((consp option)
 552                (parse-1-dd-option option dd))
 553               ((member option '(:conc-name :constructor :copier :predicate))
 554                (parse-1-dd-option (list option) dd))
 555               (t
 556                (error "unrecognized DEFSTRUCT option: ~S" option))))
 557
 558       (case (dd-type dd)
 559         (structure
 560          (when (dd-offset dd)
 561            (error ":OFFSET can't be specified unless :TYPE is specified."))
 562          (unless (dd-include dd)
 563            ;; FIXME: It'd be cleaner to treat no-:INCLUDE as defaulting
 564            ;; to :INCLUDE STRUCTURE-OBJECT, and then let the general-case
 565            ;; (INCF (DD-LENGTH DD) (DD-LENGTH included-DD)) logic take
 566            ;; care of this. (Except that the :TYPE VECTOR and :TYPE
 567            ;; LIST cases, with their :NAMED and un-:NAMED flavors,
 568            ;; make that messy, alas.)
 569            (incf (dd-length dd))))
 570         (t
 571          (require-no-print-options-so-far dd)
 572          (when (dd-named dd)
 573            (incf (dd-length dd)))
 574          (let ((offset (dd-offset dd)))
 575            (when offset (incf (dd-length dd) offset)))))
 576
 577       (when (dd-include dd)
 578         (frob-dd-inclusion-stuff dd))
 579
 580       dd)))
 581
 582 ;;; Given name and options and slot descriptions (and possibly doc
 583 ;;; string at the head of slot descriptions) return a DD holding that
 584 ;;; info.
 585 (defun parse-defstruct-name-and-options-and-slot-descriptions
 586     (name-and-options slot-descriptions)
 587   (let ((result (parse-defstruct-name-and-options (if (atom name-and-options)
 588                                                       (list name-and-options)
 589                                                       name-and-options))))
 590     (when (stringp (car slot-descriptions))
 591       (setf (dd-doc result) (pop slot-descriptions)))
 592     (dolist (slot-description slot-descriptions)
 593       (allocate-1-slot result (parse-1-dsd result slot-description)))
 594     result))
 595 \f
 596 ;;;; stuff to parse slot descriptions
 597
 598 ;;; Parse a slot description for DEFSTRUCT, add it to the description
 599 ;;; and return it. If supplied, SLOT is a pre-initialized DSD
 600 ;;; that we modify to get the new slot. This is supplied when handling
 601 ;;; included slots.
 602 (defun parse-1-dsd (defstruct spec &optional
 603                     (slot (make-defstruct-slot-description :name ""
 604                                                            :index 0
 605                                                            :type t)))
 606   (multiple-value-bind (name default default-p type type-p read-only ro-p)
 607       (typecase spec
 608         (symbol
 609          (when (keywordp spec)
 610            (style-warn "Keyword slot name indicates probable syntax ~
 611                         error in DEFSTRUCT: ~S."
 612                        spec))
 613          spec)
 614         (cons
 615          (destructuring-bind
 616                (name
 617                 &optional (default nil default-p)
 618                 &key (type nil type-p) (read-only nil ro-p))
 619              spec
 620            (values name
 621                    default default-p
 622                    (uncross type) type-p
 623                    read-only ro-p)))
 624         (t (error 'simple-program-error
 625                   :format-control "in DEFSTRUCT, ~S is not a legal slot ~
 626                                    description."
 627                   :format-arguments (list spec))))
 628
 629     (when (find name (dd-slots defstruct)
 630                 :test #'string=
 631                 :key (lambda (x) (symbol-name (dsd-name x))))
 632       (error 'simple-program-error
 633              :format-control "duplicate slot name ~S"
 634              :format-arguments (list name)))
 635     (setf (dsd-name slot) name)
 636     (setf (dd-slots defstruct) (nconc (dd-slots defstruct) (list slot)))
 637
 638     (let ((accessor-name (if (dd-conc-name defstruct)
 639                              (symbolicate (dd-conc-name defstruct) name)
 640                              name))
 641           (predicate-name (dd-predicate-name defstruct)))
 642       (setf (dsd-accessor-name slot) accessor-name)
 643       (when (eql accessor-name predicate-name)
 644         ;; Some adventurous soul has named a slot so that its accessor
 645         ;; collides with the structure type predicate. ANSI doesn't
 646         ;; specify what to do in this case. As of 2001-09-04, Martin
 647         ;; Atzmueller reports that CLISP and Lispworks both give
 648         ;; priority to the slot accessor, so that the predicate is
 649         ;; overwritten. We might as well do the same (as well as
 650         ;; signalling a warning).
 651         (style-warn
 652          "~@<The structure accessor name ~S is the same as the name of the ~
 653           structure type predicate. ANSI doesn't specify what to do in ~
 654           this case. We'll overwrite the type predicate with the slot ~
 655           accessor, but you can't rely on this behavior, so it'd be wise to ~
 656           remove the ambiguity in your code.~@:>"
 657          accessor-name)
 658         (setf (dd-predicate-name defstruct) nil))
 659       #-sb-xc-host
 660       (when (and (fboundp accessor-name)
 661                  (not (accessor-inherited-data accessor-name defstruct)))
 662         (style-warn "redefining ~S in DEFSTRUCT" accessor-name)))
 663
 664     (when default-p
 665       (setf (dsd-default slot) default))
 666     (when type-p
 667       (setf (dsd-type slot)
 668             (if (eq (dsd-type slot) t)
 669                 type
 670                 `(and ,(dsd-type slot) ,type))))
 671     (when ro-p
 672       (if read-only
 673           (setf (dsd-read-only slot) t)
 674           (when (dsd-read-only slot)
 675             (error "Slot ~S is :READ-ONLY in parent and must be :READ-ONLY in subtype ~S."
 676                    name
 677                    (dsd-name slot)))))
 678     slot))
 679
 680 ;;; When a value of type TYPE is stored in a structure, should it be
 681 ;;; stored in a raw slot? Return (VALUES RAW? RAW-TYPE WORDS), where
 682 ;;;   RAW? is true if TYPE should be stored in a raw slot.
 683 ;;;   RAW-TYPE is the raw slot type, or NIL if no raw slot.
 684 ;;;   WORDS is the number of words in the raw slot, or NIL if no raw slot.
 685 ;;;
 686 ;;; FIXME: This should use the data in *RAW-SLOT-DATA-LIST*.
 687 (defun structure-raw-slot-type-and-size (type)
 688   (cond ((and (sb!xc:subtypep type '(unsigned-byte 32))
 689               (multiple-value-bind (fixnum? fixnum-certain?)
 690                   (sb!xc:subtypep type 'fixnum)
 691                 ;; (The extra test for FIXNUM-CERTAIN? here is
 692                 ;; intended for bootstrapping the system. In
 693                 ;; particular, in sbcl-0.6.2, we set up LAYOUT before
 694                 ;; FIXNUM is defined, and so could bogusly end up
 695                 ;; putting INDEX-typed values into raw slots if we
 696                 ;; didn't test FIXNUM-CERTAIN?.)
 697                 (and (not fixnum?) fixnum-certain?)))
 698          (values t 'unsigned-byte 1))
 699         ((sb!xc:subtypep type 'single-float)
 700          (values t 'single-float 1))
 701         ((sb!xc:subtypep type 'double-float)
 702          (values t 'double-float 2))
 703         #!+long-float
 704         ((sb!xc:subtypep type 'long-float)
 705          (values t 'long-float #!+x86 3 #!+sparc 4))
 706         ((sb!xc:subtypep type '(complex single-float))
 707          (values t 'complex-single-float 2))
 708         ((sb!xc:subtypep type '(complex double-float))
 709          (values t 'complex-double-float 4))
 710         #!+long-float
 711         ((sb!xc:subtypep type '(complex long-float))
 712          (values t 'complex-long-float #!+x86 6 #!+sparc 8))
 713         (t
 714          (values nil nil nil))))
 715
 716 ;;; Allocate storage for a DSD in DD. This is where we decide whether
 717 ;;; a slot is raw or not. If raw, and we haven't allocated a raw-index
 718 ;;; yet for the raw data vector, then do it. Raw objects are aligned
 719 ;;; on the unit of their size.
 720 (defun allocate-1-slot (dd dsd)
 721   (multiple-value-bind (raw? raw-type words)
 722       (if (eq (dd-type dd) 'structure)
 723           (structure-raw-slot-type-and-size (dsd-type dsd))
 724           (values nil nil nil))
 725     (cond ((not raw?)
 726            (setf (dsd-index dsd) (dd-length dd))
 727            (incf (dd-length dd)))
 728           (t
 729            (unless (dd-raw-index dd)
 730              (setf (dd-raw-index dd) (dd-length dd))
 731              (incf (dd-length dd)))
 732            (let ((off (rem (dd-raw-length dd) words)))
 733              (unless (zerop off)
 734                (incf (dd-raw-length dd) (- words off))))
 735            (setf (dsd-raw-type dsd) raw-type)
 736            (setf (dsd-index dsd) (dd-raw-length dd))
 737            (incf (dd-raw-length dd) words))))
 738   (values))
 739
 740 (defun typed-structure-info-or-lose (name)
 741   (or (info :typed-structure :info name)
 742       (error ":TYPE'd DEFSTRUCT ~S not found for inclusion." name)))
 743
 744 ;;; Process any included slots pretty much like they were specified.
 745 ;;; Also inherit various other attributes.
 746 (defun frob-dd-inclusion-stuff (dd)
 747   (destructuring-bind (included-name &rest modified-slots) (dd-include dd)
 748     (let* ((type (dd-type dd))
 749            (included-structure
 750             (if (dd-class-p dd)
 751                 (layout-info (compiler-layout-or-lose included-name))
 752                 (typed-structure-info-or-lose included-name))))
 753
 754       ;; checks on legality
 755       (unless (and (eq type (dd-type included-structure))
 756                    (type= (specifier-type (dd-element-type included-structure))
 757                           (specifier-type (dd-element-type dd))))
 758         (error ":TYPE option mismatch between structures ~S and ~S"
 759                (dd-name dd) included-name))
 760       (let ((included-classoid (find-classoid included-name nil)))
 761         (when included-classoid
 762           ;; It's not particularly well-defined to :INCLUDE any of the
 763           ;; CMU CL INSTANCE weirdosities like CONDITION or
 764           ;; GENERIC-FUNCTION, and it's certainly not ANSI-compliant.
 765           (let* ((included-layout (classoid-layout included-classoid))
 766                  (included-dd (layout-info included-layout)))
 767             (when (and (dd-alternate-metaclass included-dd)
 768                        ;; As of sbcl-0.pre7.73, anyway, STRUCTURE-OBJECT
 769                        ;; is represented with an ALTERNATE-METACLASS. But
 770                        ;; it's specifically OK to :INCLUDE (and PCL does)
 771                        ;; so in this one case, it's OK to include
 772                        ;; something with :ALTERNATE-METACLASS after all.
 773                        (not (eql included-name 'structure-object)))
 774               (error "can't :INCLUDE class ~S (has alternate metaclass)"
 775                      included-name)))))
 776
 777       (incf (dd-length dd) (dd-length included-structure))
 778       (when (dd-class-p dd)
 779         (let ((mc (rest (dd-alternate-metaclass included-structure))))
 780           (when (and mc (not (dd-alternate-metaclass dd)))
 781             (setf (dd-alternate-metaclass dd)
 782                   (cons included-name mc))))
 783         (when (eq (dd-pure dd) :unspecified)
 784           (setf (dd-pure dd) (dd-pure included-structure)))
 785         (setf (dd-raw-index dd) (dd-raw-index included-structure))
 786         (setf (dd-raw-length dd) (dd-raw-length included-structure)))
 787
 788       (setf (dd-inherited-accessor-alist dd)
 789             (dd-inherited-accessor-alist included-structure))
 790       (dolist (included-slot (dd-slots included-structure))
 791         (let* ((included-name (dsd-name included-slot))
 792                (modified (or (find included-name modified-slots
 793                                    :key (lambda (x) (if (atom x) x (car x)))
 794                                    :test #'string=)
 795                              `(,included-name))))
 796           ;; We stash away an alist of accessors to parents' slots
 797           ;; that have already been created to avoid conflicts later
 798           ;; so that structures with :INCLUDE and :CONC-NAME (and
 799           ;; other edge cases) can work as specified.
 800           (when (dsd-accessor-name included-slot)
 801             ;; the "oldest" (i.e. highest up the tree of inheritance)
 802             ;; will prevail, so don't push new ones on if they
 803             ;; conflict.
 804             (pushnew (cons (dsd-accessor-name included-slot)
 805                            (dsd-index included-slot))
 806                      (dd-inherited-accessor-alist dd)
 807                      :test #'eq :key #'car))
 808           (parse-1-dsd dd
 809                        modified
 810                        (copy-structure included-slot)))))))
 811 \f
 812 ;;;; various helper functions for setting up DEFSTRUCTs
 813
 814 ;;; This function is called at macroexpand time to compute the INHERITS
 815 ;;; vector for a structure type definition.
 816 (defun inherits-for-structure (info)
 817   (declare (type defstruct-description info))
 818   (let* ((include (dd-include info))
 819          (superclass-opt (dd-alternate-metaclass info))
 820          (super
 821           (if include
 822               (compiler-layout-or-lose (first include))
 823               (classoid-layout (find-classoid
 824                                 (or (first superclass-opt)
 825                                     'structure-object))))))
 826     (if (eq (dd-name info) 'ansi-stream)
 827         ;; a hack to add the CL:STREAM class as a mixin for ANSI-STREAMs
 828         (concatenate 'simple-vector
 829                      (layout-inherits super)
 830                      (vector super
 831                              (classoid-layout (find-classoid 'stream))))
 832         (concatenate 'simple-vector
 833                      (layout-inherits super)
 834                      (vector super)))))
 835
 836 ;;; Do miscellaneous (LOAD EVAL) time actions for the structure
 837 ;;; described by DD. Create the class and LAYOUT, checking for
 838 ;;; incompatible redefinition. Define those functions which are
 839 ;;; sufficiently stereotyped that we can implement them as standard
 840 ;;; closures.
 841 (defun %defstruct (dd inherits)
 842   (declare (type defstruct-description dd))
 843
 844   ;; We set up LAYOUTs even in the cross-compilation host.
 845   (multiple-value-bind (classoid layout old-layout)
 846       (ensure-structure-class dd inherits "current" "new")
 847     (cond ((not old-layout)
 848            (unless (eq (classoid-layout classoid) layout)
 849              (register-layout layout)))
 850           (t
 851            (let ((old-dd (layout-info old-layout)))
 852              (when (defstruct-description-p old-dd)
 853                (dolist (slot (dd-slots old-dd))
 854                  (fmakunbound (dsd-accessor-name slot))
 855                  (unless (dsd-read-only slot)
 856                    (fmakunbound `(setf ,(dsd-accessor-name slot)))))))
 857            (%redefine-defstruct classoid old-layout layout)
 858            (setq layout (classoid-layout classoid))))
 859     (setf (find-classoid (dd-name dd)) classoid)
 860
 861     ;; Various other operations only make sense on the target SBCL.
 862     #-sb-xc-host
 863     (%target-defstruct dd layout))
 864
 865   (values))
 866 \f
 867 ;;; Return a form describing the writable place used for this slot
 868 ;;; in the instance named INSTANCE-NAME.
 869 (defun %accessor-place-form (dd dsd instance-name)
 870   (let (;; the operator that we'll use to access a typed slot or, in
 871         ;; the case of a raw slot, to read the vector of raw slots
 872         (ref (ecase (dd-type dd)
 873                (structure '%instance-ref)
 874                (list 'nth-but-with-sane-arg-order)
 875                (vector 'aref)))
 876         (raw-type (dsd-raw-type dsd)))
 877     (if (eq raw-type t) ; if not raw slot
 878         `(,ref ,instance-name ,(dsd-index dsd))
 879         (let* ((raw-slot-data (find raw-type *raw-slot-data-list*
 880                                     :key #'raw-slot-data-raw-type
 881                                     :test #'equal))
 882                (raw-slot-accessor (raw-slot-data-accessor-name raw-slot-data))
 883                (raw-n-words (raw-slot-data-n-words raw-slot-data)))
 884           (multiple-value-bind (scaled-dsd-index misalignment)
 885               (floor (dsd-index dsd) raw-n-words)
 886             (aver (zerop misalignment))
 887             (let* ((raw-vector-bare-form
 888                     `(,ref ,instance-name ,(dd-raw-index dd)))
 889                    (raw-vector-form
 890                     (if (eq raw-type 'unsigned-byte)
 891                         (progn
 892                           (aver (= raw-n-words 1))
 893                           (aver (eq raw-slot-accessor 'aref))
 894                           ;; FIXME: when the 64-bit world rolls
 895                           ;; around, this will need to be reviewed,
 896                           ;; along with the whole RAW-SLOT thing.
 897                           `(truly-the (simple-array (unsigned-byte 32) (*))
 898                                       ,raw-vector-bare-form))
 899                         raw-vector-bare-form)))
 900               `(,raw-slot-accessor ,raw-vector-form ,scaled-dsd-index)))))))
 901
 902 ;;; Return source transforms for the reader and writer functions of
 903 ;;; the slot described by DSD. They should be inline expanded, but
 904 ;;; source transforms work faster.
 905 (defun slot-accessor-transforms (dd dsd)
 906   (let ((accessor-place-form (%accessor-place-form dd dsd
 907                                                    `(the ,(dd-name dd) instance)))
 908         (dsd-type (dsd-type dsd))
 909         (value-the (if (dsd-safe-p dsd) 'truly-the 'the)))
 910     (values (sb!c:source-transform-lambda (instance)
 911               `(,value-the ,dsd-type ,(subst instance 'instance
 912                                              accessor-place-form)))
 913             (sb!c:source-transform-lambda (new-value instance)
 914                (destructuring-bind (accessor-name &rest accessor-args)
 915                    accessor-place-form
 916                  `(,(info :setf :inverse accessor-name)
 917                     ,@(subst instance 'instance accessor-args)
 918                     (the ,dsd-type ,new-value)))))))
 919
 920 ;;; Return a LAMBDA form which can be used to set a slot.
 921 (defun slot-setter-lambda-form (dd dsd)
 922   `(lambda (new-value instance)
 923      ,(funcall (nth-value 1 (slot-accessor-transforms dd dsd))
 924                '(dummy new-value instance))))
 925
 926 ;;; core compile-time setup of any class with a LAYOUT, used even by
 927 ;;; !DEFSTRUCT-WITH-ALTERNATE-METACLASS weirdosities
 928 (defun %compiler-set-up-layout (dd
 929                                 &optional
 930                                 ;; Several special cases (STRUCTURE-OBJECT
 931                                 ;; itself, and structures with alternate
 932                                 ;; metaclasses) call this function directly,
 933                                 ;; and they're all at the base of the
 934                                 ;; instance class structure, so this is
 935                                 ;; a handy default.
 936                                 (inherits (vector (find-layout t)
 937                                                   (find-layout 'instance))))
 938
 939   (multiple-value-bind (classoid layout old-layout)
 940       (multiple-value-bind (clayout clayout-p)
 941           (info :type :compiler-layout (dd-name dd))
 942         (ensure-structure-class dd
 943                                 inherits
 944                                 (if clayout-p "previously compiled" "current")
 945                                 "compiled"
 946                                 :compiler-layout clayout))
 947     (cond (old-layout
 948            (undefine-structure (layout-classoid old-layout))
 949            (when (and (classoid-subclasses classoid)
 950                       (not (eq layout old-layout)))
 951              (collect ((subs))
 952                       (dohash (classoid layout (classoid-subclasses classoid))
 953                         (declare (ignore layout))
 954                         (undefine-structure classoid)
 955                         (subs (classoid-proper-name classoid)))
 956                       (when (subs)
 957                         (warn "removing old subclasses of ~S:~%  ~S"
 958                               (classoid-name classoid)
 959                               (subs))))))
 960           (t
 961            (unless (eq (classoid-layout classoid) layout)
 962              (register-layout layout :invalidate nil))
 963            (setf (find-classoid (dd-name dd)) classoid)))
 964
 965     ;; At this point the class should be set up in the INFO database.
 966     ;; But the logic that enforces this is a little tangled and
 967     ;; scattered, so it's not obvious, so let's check.
 968     (aver (find-classoid (dd-name dd) nil))
 969
 970     (setf (info :type :compiler-layout (dd-name dd)) layout))
 971
 972   (values))
 973
 974 ;;; Do (COMPILE LOAD EVAL)-time actions for the normal (not
 975 ;;; ALTERNATE-LAYOUT) DEFSTRUCT described by DD.
 976 (defun %compiler-defstruct (dd inherits)
 977   (declare (type defstruct-description dd))
 978
 979   (%compiler-set-up-layout dd inherits)
 980
 981   (let* ((dtype (dd-declarable-type dd)))
 982
 983     (let ((copier-name (dd-copier-name dd)))
 984       (when copier-name
 985         (sb!xc:proclaim `(ftype (sfunction (,dtype) ,dtype) ,copier-name))))
 986
 987     (let ((predicate-name (dd-predicate-name dd)))
 988       (when predicate-name
 989         (sb!xc:proclaim `(ftype (sfunction (t) t) ,predicate-name))
 990         ;; Provide inline expansion (or not).
 991         (ecase (dd-type dd)
 992           ((structure funcallable-structure)
 993            ;; Let the predicate be inlined.
 994            (setf (info :function :inline-expansion-designator predicate-name)
 995                  (lambda ()
 996                    `(lambda (x)
 997                       ;; This dead simple definition works because the
 998                       ;; type system knows how to generate inline type
 999                       ;; tests for instances.
1000                       (typep x ',(dd-name dd))))
1001                  (info :function :inlinep predicate-name)
1002                  :inline))
1003           ((list vector)
1004            ;; Just punt. We could provide inline expansions for :TYPE
1005            ;; LIST and :TYPE VECTOR predicates too, but it'd be a
1006            ;; little messier and we don't bother. (Does anyway use
1007            ;; typed DEFSTRUCTs at all, let alone for high
1008            ;; performance?)
1009            ))))
1010
1011     (dolist (dsd (dd-slots dd))
1012       (let* ((accessor-name (dsd-accessor-name dsd))
1013              (dsd-type (dsd-type dsd)))
1014         (when accessor-name
1015           (let ((inherited (accessor-inherited-data accessor-name dd)))
1016             (cond
1017               ((not inherited)
1018                (multiple-value-bind (reader-designator writer-designator)
1019                    (slot-accessor-transforms dd dsd)
1020                  (sb!xc:proclaim `(ftype (sfunction (,dtype) ,dsd-type)
1021                                    ,accessor-name))
1022                  (setf (info :function :source-transform accessor-name)
1023                        reader-designator)
1024                  (unless (dsd-read-only dsd)
1025                    (let ((setf-accessor-name `(setf ,accessor-name)))
1026                      (sb!xc:proclaim
1027                       `(ftype (sfunction (,dsd-type ,dtype) ,dsd-type)
1028                         ,setf-accessor-name))
1029                      (setf (info :function :source-transform setf-accessor-name)
1030                            writer-designator)))))
1031               ((not (= (cdr inherited) (dsd-index dsd)))
1032                (style-warn "~@<Non-overwritten accessor ~S does not access ~
1033                             slot with name ~S (accessing an inherited slot ~
1034                             instead).~:@>"
1035                            accessor-name
1036                            (dsd-name dsd)))))))))
1037   (values))
1038 \f
1039 ;;;; redefinition stuff
1040
1041 ;;; Compare the slots of OLD and NEW, returning 3 lists of slot names:
1042 ;;;   1. Slots which have moved,
1043 ;;;   2. Slots whose type has changed,
1044 ;;;   3. Deleted slots.
1045 (defun compare-slots (old new)
1046   (let* ((oslots (dd-slots old))
1047          (nslots (dd-slots new))
1048          (onames (mapcar #'dsd-name oslots))
1049          (nnames (mapcar #'dsd-name nslots)))
1050     (collect ((moved)
1051               (retyped))
1052       (dolist (name (intersection onames nnames))
1053         (let ((os (find name oslots :key #'dsd-name :test #'string=))
1054               (ns (find name nslots :key #'dsd-name :test #'string=)))
1055           (unless (sb!xc:subtypep (dsd-type ns) (dsd-type os))
1056             (retyped name))
1057           (unless (and (= (dsd-index os) (dsd-index ns))
1058                        (eq (dsd-raw-type os) (dsd-raw-type ns)))
1059             (moved name))))
1060       (values (moved)
1061               (retyped)
1062               (set-difference onames nnames :test #'string=)))))
1063
1064 ;;; If we are redefining a structure with different slots than in the
1065 ;;; currently loaded version, give a warning and return true.
1066 (defun redefine-structure-warning (classoid old new)
1067   (declare (type defstruct-description old new)
1068            (type classoid classoid)
1069            (ignore classoid))
1070   (let ((name (dd-name new)))
1071     (multiple-value-bind (moved retyped deleted) (compare-slots old new)
1072       (when (or moved retyped deleted)
1073         (warn
1074          "incompatibly redefining slots of structure class ~S~@
1075           Make sure any uses of affected accessors are recompiled:~@
1076           ~@[  These slots were moved to new positions:~%    ~S~%~]~
1077           ~@[  These slots have new incompatible types:~%    ~S~%~]~
1078           ~@[  These slots were deleted:~%    ~S~%~]"
1079          name moved retyped deleted)
1080         t))))
1081
1082 ;;; This function is called when we are incompatibly redefining a
1083 ;;; structure CLASS to have the specified NEW-LAYOUT. We signal an
1084 ;;; error with some proceed options and return the layout that should
1085 ;;; be used.
1086 (defun %redefine-defstruct (classoid old-layout new-layout)
1087   (declare (type classoid classoid)
1088            (type layout old-layout new-layout))
1089   (let ((name (classoid-proper-name classoid)))
1090     (restart-case
1091         (error "~@<attempt to redefine the ~S class ~S incompatibly with the current definition~:@>"
1092                'structure-object
1093                name)
1094       (continue ()
1095        :report (lambda (s)
1096                  (format s
1097                          "~@<Use the new definition of ~S, invalidating ~
1098                           already-loaded code and instances.~@:>"
1099                          name))
1100        (register-layout new-layout))
1101       (recklessly-continue ()
1102        :report (lambda (s)
1103                  (format s
1104                          "~@<Use the new definition of ~S as if it were ~
1105                           compatible, allowing old accessors to use new ~
1106                           instances and allowing new accessors to use old ~
1107                           instances.~@:>"
1108                          name))
1109        ;; classic CMU CL warning: "Any old ~S instances will be in a bad way.
1110        ;; I hope you know what you're doing..."
1111        (register-layout new-layout
1112                         :invalidate nil
1113                         :destruct-layout old-layout))
1114       (clobber-it ()
1115        ;; FIXME: deprecated 2002-10-16, and since it's only interactive
1116        ;; hackery instead of a supported feature, can probably be deleted
1117        ;; in early 2003
1118        :report "(deprecated synonym for RECKLESSLY-CONTINUE)"
1119        (register-layout new-layout
1120                         :invalidate nil
1121                         :destruct-layout old-layout))))
1122   (values))
1123
1124 ;;; This is called when we are about to define a structure class. It
1125 ;;; returns a (possibly new) class object and the layout which should
1126 ;;; be used for the new definition (may be the current layout, and
1127 ;;; also might be an uninstalled forward referenced layout.) The third
1128 ;;; value is true if this is an incompatible redefinition, in which
1129 ;;; case it is the old layout.
1130 (defun ensure-structure-class (info inherits old-context new-context
1131                                     &key compiler-layout)
1132   (multiple-value-bind (class old-layout)
1133       (destructuring-bind
1134           (&optional
1135            name
1136            (class 'structure-classoid)
1137            (constructor 'make-structure-classoid))
1138           (dd-alternate-metaclass info)
1139         (declare (ignore name))
1140         (insured-find-classoid (dd-name info)
1141                                (if (eq class 'structure-classoid)
1142                                    (lambda (x)
1143                                      (sb!xc:typep x 'structure-classoid))
1144                                    (lambda (x)
1145                                      (sb!xc:typep x (find-classoid class))))
1146                                (fdefinition constructor)))
1147     (setf (classoid-direct-superclasses class)
1148           (if (eq (dd-name info) 'ansi-stream)
1149               ;; a hack to add CL:STREAM as a superclass mixin to ANSI-STREAMs
1150               (list (layout-classoid (svref inherits (1- (length inherits))))
1151                     (layout-classoid (svref inherits (- (length inherits) 2))))
1152               (list (layout-classoid
1153                      (svref inherits (1- (length inherits)))))))
1154     (let ((new-layout (make-layout :classoid class
1155                                    :inherits inherits
1156                                    :depthoid (length inherits)
1157                                    :length (dd-length info)
1158                                    :info info))
1159           (old-layout (or compiler-layout old-layout)))
1160       (cond
1161        ((not old-layout)
1162         (values class new-layout nil))
1163        (;; This clause corresponds to an assertion in REDEFINE-LAYOUT-WARNING
1164         ;; of classic CMU CL. I moved it out to here because it was only
1165         ;; exercised in this code path anyway. -- WHN 19990510
1166         (not (eq (layout-classoid new-layout) (layout-classoid old-layout)))
1167         (error "shouldn't happen: weird state of OLD-LAYOUT?"))
1168        ((not *type-system-initialized*)
1169         (setf (layout-info old-layout) info)
1170         (values class old-layout nil))
1171        ((redefine-layout-warning old-context
1172                                  old-layout
1173                                  new-context
1174                                  (layout-length new-layout)
1175                                  (layout-inherits new-layout)
1176                                  (layout-depthoid new-layout))
1177         (values class new-layout old-layout))
1178        (t
1179         (let ((old-info (layout-info old-layout)))
1180           (typecase old-info
1181             ((or defstruct-description)
1182              (cond ((redefine-structure-warning class old-info info)
1183                     (values class new-layout old-layout))
1184                    (t
1185                     (setf (layout-info old-layout) info)
1186                     (values class old-layout nil))))
1187             (null
1188              (setf (layout-info old-layout) info)
1189              (values class old-layout nil))
1190             (t
1191              (error "shouldn't happen! strange thing in LAYOUT-INFO:~%  ~S"
1192                     old-layout)
1193              (values class new-layout old-layout)))))))))
1194
1195 ;;; Blow away all the compiler info for the structure CLASS. Iterate
1196 ;;; over this type, clearing the compiler structure type info, and
1197 ;;; undefining all the associated functions.
1198 (defun undefine-structure (class)
1199   (let ((info (layout-info (classoid-layout class))))
1200     (when (defstruct-description-p info)
1201       (let ((type (dd-name info)))
1202         (remhash type *typecheckfuns*)
1203         (setf (info :type :compiler-layout type) nil)
1204         (undefine-fun-name (dd-copier-name info))
1205         (undefine-fun-name (dd-predicate-name info))
1206         (dolist (slot (dd-slots info))
1207           (let ((fun (dsd-accessor-name slot)))
1208             (unless (accessor-inherited-data fun info)
1209               (undefine-fun-name fun)
1210               (unless (dsd-read-only slot)
1211                 (undefine-fun-name `(setf ,fun)))))))
1212       ;; Clear out the SPECIFIER-TYPE cache so that subsequent
1213       ;; references are unknown types.
1214       (values-specifier-type-cache-clear)))
1215   (values))
1216 \f
1217 ;;; Return a list of pairs (name . index). Used for :TYPE'd
1218 ;;; constructors to find all the names that we have to splice in &
1219 ;;; where. Note that these types don't have a layout, so we can't look
1220 ;;; at LAYOUT-INHERITS.
1221 (defun find-name-indices (defstruct)
1222   (collect ((res))
1223     (let ((infos ()))
1224       (do ((info defstruct
1225                  (typed-structure-info-or-lose (first (dd-include info)))))
1226           ((not (dd-include info))
1227            (push info infos))
1228         (push info infos))
1229
1230       (let ((i 0))
1231         (dolist (info infos)
1232           (incf i (or (dd-offset info) 0))
1233           (when (dd-named info)
1234             (res (cons (dd-name info) i)))
1235           (setq i (dd-length info)))))
1236
1237     (res)))
1238 \f
1239 ;;; These functions are called to actually make a constructor after we
1240 ;;; have processed the arglist. The correct variant (according to the
1241 ;;; DD-TYPE) should be called. The function is defined with the
1242 ;;; specified name and arglist. VARS and TYPES are used for argument
1243 ;;; type declarations. VALUES are the values for the slots (in order.)
1244 ;;;
1245 ;;; This is split three ways because:
1246 ;;;   * LIST & VECTOR structures need "name" symbols stuck in at
1247 ;;;     various weird places, whereas STRUCTURE structures have
1248 ;;;     a LAYOUT slot.
1249 ;;;   * We really want to use LIST to make list structures, instead of
1250 ;;;     MAKE-LIST/(SETF ELT). (We can't in general use VECTOR in an
1251 ;;;     analogous way, since VECTOR makes a SIMPLE-VECTOR and vector-typed
1252 ;;;     structures can have arbitrary subtypes of VECTOR, not necessarily
1253 ;;;     SIMPLE-VECTOR.)
1254 ;;;   * STRUCTURE structures can have raw slots that must also be
1255 ;;;     allocated and indirectly referenced.
1256 (defun create-vector-constructor (dd cons-name arglist vars types values)
1257   (let ((temp (gensym))
1258         (etype (dd-element-type dd)))
1259     `(defun ,cons-name ,arglist
1260        (declare ,@(mapcar (lambda (var type) `(type (and ,type ,etype) ,var))
1261                           vars types))
1262        (let ((,temp (make-array ,(dd-length dd)
1263                                 :element-type ',(dd-element-type dd))))
1264          ,@(mapcar (lambda (x)
1265                      `(setf (aref ,temp ,(cdr x))  ',(car x)))
1266                    (find-name-indices dd))
1267          ,@(mapcar (lambda (dsd value)
1268                      (unless (eq value '.do-not-initialize-slot.)
1269                          `(setf (aref ,temp ,(dsd-index dsd)) ,value)))
1270                    (dd-slots dd) values)
1271          ,temp))))
1272 (defun create-list-constructor (dd cons-name arglist vars types values)
1273   (let ((vals (make-list (dd-length dd) :initial-element nil)))
1274     (dolist (x (find-name-indices dd))
1275       (setf (elt vals (cdr x)) `',(car x)))
1276     (loop for dsd in (dd-slots dd) and val in values do
1277       (setf (elt vals (dsd-index dsd))
1278             (if (eq val '.do-not-initialize-slot.) 0 val)))
1279
1280     `(defun ,cons-name ,arglist
1281        (declare ,@(mapcar (lambda (var type) `(type ,type ,var)) vars types))
1282        (list ,@vals))))
1283 (defun create-structure-constructor (dd cons-name arglist vars types values)
1284   (let* ((instance (gensym "INSTANCE"))
1285          (raw-index (dd-raw-index dd)))
1286     `(defun ,cons-name ,arglist
1287        (declare ,@(mapcar (lambda (var type) `(type ,type ,var))
1288                           vars types))
1289        (let ((,instance (truly-the ,(dd-name dd)
1290                           (%make-instance-with-layout
1291                            (%delayed-get-compiler-layout ,(dd-name dd))))))
1292          ,@(when raw-index
1293              `((setf (%instance-ref ,instance ,raw-index)
1294                      (make-array ,(dd-raw-length dd)
1295                                  :element-type '(unsigned-byte 32)))))
1296          ,@(mapcar (lambda (dsd value)
1297                      ;; (Note that we can't in general use the
1298                      ;; ordinary named slot setter function here
1299                      ;; because the slot might be :READ-ONLY, so we
1300                      ;; whip up new LAMBDA representations of slot
1301                      ;; setters for the occasion.)
1302                      (unless (eq value '.do-not-initialize-slot.)
1303                        `(,(slot-setter-lambda-form dd dsd) ,value ,instance)))
1304                    (dd-slots dd)
1305                    values)
1306          ,instance))))
1307
1308 ;;; Create a default (non-BOA) keyword constructor.
1309 (defun create-keyword-constructor (defstruct creator)
1310   (declare (type function creator))
1311   (collect ((arglist (list '&key))
1312             (types)
1313             (vals))
1314     (dolist (slot (dd-slots defstruct))
1315       (let ((dum (gensym))
1316             (name (dsd-name slot)))
1317         (arglist `((,(keywordicate name) ,dum) ,(dsd-default slot)))
1318         (types (dsd-type slot))
1319         (vals dum)))
1320     (funcall creator
1321              defstruct (dd-default-constructor defstruct)
1322              (arglist) (vals) (types) (vals))))
1323
1324 ;;; Given a structure and a BOA constructor spec, call CREATOR with
1325 ;;; the appropriate args to make a constructor.
1326 (defun create-boa-constructor (defstruct boa creator)
1327   (declare (type function creator))
1328   (multiple-value-bind (req opt restp rest keyp keys allowp auxp aux)
1329       (parse-lambda-list (second boa))
1330     (collect ((arglist)
1331               (vars)
1332               (types)
1333               (skipped-vars))
1334       (labels ((get-slot (name)
1335                  (let ((res (find name (dd-slots defstruct)
1336                                   :test #'string=
1337                                   :key #'dsd-name)))
1338                    (if res
1339                        (values (dsd-type res) (dsd-default res))
1340                        (values t nil))))
1341                (do-default (arg)
1342                  (multiple-value-bind (type default) (get-slot arg)
1343                    (arglist `(,arg ,default))
1344                    (vars arg)
1345                    (types type))))
1346         (dolist (arg req)
1347           (arglist arg)
1348           (vars arg)
1349           (types (get-slot arg)))
1350
1351         (when opt
1352           (arglist '&optional)
1353           (dolist (arg opt)
1354             (cond ((consp arg)
1355                    (destructuring-bind
1356                          ;; FIXME: this shares some logic (though not
1357                          ;; code) with the &key case below (and it
1358                          ;; looks confusing) -- factor out the logic
1359                          ;; if possible. - CSR, 2002-04-19
1360                          (name
1361                           &optional
1362                           (def (nth-value 1 (get-slot name)))
1363                           (supplied-test nil supplied-test-p))
1364                        arg
1365                      (arglist `(,name ,def ,@(if supplied-test-p `(,supplied-test) nil)))
1366                      (vars name)
1367                      (types (get-slot name))))
1368                   (t
1369                    (do-default arg)))))
1370
1371         (when restp
1372           (arglist '&rest rest)
1373           (vars rest)
1374           (types 'list))
1375
1376         (when keyp
1377           (arglist '&key)
1378           (dolist (key keys)
1379             (if (consp key)
1380                 (destructuring-bind (wot
1381                                      &optional
1382                                      (def nil def-p)
1383                                      (supplied-test nil supplied-test-p))
1384                     key
1385                   (let ((name (if (consp wot)
1386                                   (destructuring-bind (key var) wot
1387                                     (declare (ignore key))
1388                                     var)
1389                                   wot)))
1390                     (multiple-value-bind (type slot-def)
1391                         (get-slot name)
1392                       (arglist `(,wot ,(if def-p def slot-def)
1393                                  ,@(if supplied-test-p `(,supplied-test) nil)))
1394                       (vars name)
1395                       (types type))))
1396                 (do-default key))))
1397
1398         (when allowp (arglist '&allow-other-keys))
1399
1400         (when auxp
1401           (arglist '&aux)
1402           (dolist (arg aux)
1403             (arglist arg)
1404             (if (proper-list-of-length-p arg 2)
1405               (let ((var (first arg)))
1406                 (vars var)
1407                 (types (get-slot var)))
1408               (skipped-vars (if (consp arg) (first arg) arg))))))
1409
1410       (funcall creator defstruct (first boa)
1411                (arglist) (vars) (types)
1412                (loop for slot in (dd-slots defstruct)
1413                      for name = (dsd-name slot)
1414                      collect (cond ((find name (skipped-vars) :test #'string=)
1415                                     (setf (dsd-safe-p slot) nil)
1416                                     '.do-not-initialize-slot.)
1417                                    ((or (find (dsd-name slot) (vars) :test #'string=)
1418                                         (dsd-default slot)))))))))
1419
1420 ;;; Grovel the constructor options, and decide what constructors (if
1421 ;;; any) to create.
1422 (defun constructor-definitions (defstruct)
1423   (let ((no-constructors nil)
1424         (boas ())
1425         (defaults ())
1426         (creator (ecase (dd-type defstruct)
1427                    (structure #'create-structure-constructor)
1428                    (vector #'create-vector-constructor)
1429                    (list #'create-list-constructor))))
1430     (dolist (constructor (dd-constructors defstruct))
1431       (destructuring-bind (name &optional (boa-ll nil boa-p)) constructor
1432         (declare (ignore boa-ll))
1433         (cond ((not name) (setq no-constructors t))
1434               (boa-p (push constructor boas))
1435               (t (push name defaults)))))
1436
1437     (when no-constructors
1438       (when (or defaults boas)
1439         (error "(:CONSTRUCTOR NIL) combined with other :CONSTRUCTORs"))
1440       (return-from constructor-definitions ()))
1441
1442     (unless (or defaults boas)
1443       (push (symbolicate "MAKE-" (dd-name defstruct)) defaults))
1444
1445     (collect ((res))
1446       (when defaults
1447         (let ((cname (first defaults)))
1448           (setf (dd-default-constructor defstruct) cname)
1449           (res (create-keyword-constructor defstruct creator))
1450           (dolist (other-name (rest defaults))
1451             (res `(setf (fdefinition ',other-name) (fdefinition ',cname)))
1452             (res `(declaim (ftype function ',other-name))))))
1453
1454       (dolist (boa boas)
1455         (res (create-boa-constructor defstruct boa creator)))
1456
1457       (res))))
1458 \f
1459 ;;;; instances with ALTERNATE-METACLASS
1460 ;;;;
1461 ;;;; The CMU CL support for structures with ALTERNATE-METACLASS was a
1462 ;;;; fairly general extension embedded in the main DEFSTRUCT code, and
1463 ;;;; the result was an fairly impressive mess as ALTERNATE-METACLASS
1464 ;;;; extension mixed with ANSI CL generality (e.g. :TYPE and :INCLUDE)
1465 ;;;; and CMU CL implementation hairiness (esp. raw slots). This SBCL
1466 ;;;; version is much less ambitious, noticing that ALTERNATE-METACLASS
1467 ;;;; is only used to implement CONDITION, STANDARD-INSTANCE, and
1468 ;;;; GENERIC-FUNCTION, and defining a simple specialized
1469 ;;;; separate-from-DEFSTRUCT macro to provide only enough
1470 ;;;; functionality to support those.
1471 ;;;;
1472 ;;;; KLUDGE: The defining macro here is so specialized that it's ugly
1473 ;;;; in its own way. It also violates once-and-only-once by knowing
1474 ;;;; much about structures and layouts that is already known by the
1475 ;;;; main DEFSTRUCT macro. Hopefully it will go away presently
1476 ;;;; (perhaps when CL:CLASS and SB-PCL:CLASS meet) as per FIXME below.
1477 ;;;; -- WHN 2001-10-28
1478 ;;;;
1479 ;;;; FIXME: There seems to be no good reason to shoehorn CONDITION,
1480 ;;;; STANDARD-INSTANCE, and GENERIC-FUNCTION into mutated structures
1481 ;;;; instead of just implementing them as primitive objects. (This
1482 ;;;; reduced-functionality macro seems pretty close to the
1483 ;;;; functionality of DEFINE-PRIMITIVE-OBJECT..)
1484
1485 (defun make-dd-with-alternate-metaclass (&key (class-name (missing-arg))
1486                                               (superclass-name (missing-arg))
1487                                               (metaclass-name (missing-arg))
1488                                               (dd-type (missing-arg))
1489                                               metaclass-constructor
1490                                               slot-names)
1491   (let* ((dd (make-defstruct-description class-name))
1492          (conc-name (concatenate 'string (symbol-name class-name) "-"))
1493          (dd-slots (let ((reversed-result nil)
1494                          ;; The index starts at 1 for ordinary
1495                          ;; named slots because slot 0 is
1496                          ;; magical, used for LAYOUT in
1497                          ;; CONDITIONs or for something (?) in
1498                          ;; funcallable instances.
1499                          (index 1))
1500                      (dolist (slot-name slot-names)
1501                        (push (make-defstruct-slot-description
1502                               :name slot-name
1503                               :index index
1504                               :accessor-name (symbolicate conc-name slot-name))
1505                              reversed-result)
1506                        (incf index))
1507                      (nreverse reversed-result))))
1508     (setf (dd-alternate-metaclass dd) (list superclass-name
1509                                             metaclass-name
1510                                             metaclass-constructor)
1511           (dd-slots dd) dd-slots
1512           (dd-length dd) (1+ (length slot-names))
1513           (dd-type dd) dd-type)
1514     dd))
1515
1516 (sb!xc:defmacro !defstruct-with-alternate-metaclass
1517     (class-name &key
1518                 (slot-names (missing-arg))
1519                 (boa-constructor (missing-arg))
1520                 (superclass-name (missing-arg))
1521                 (metaclass-name (missing-arg))
1522                 (metaclass-constructor (missing-arg))
1523                 (dd-type (missing-arg))
1524                 predicate
1525                 (runtime-type-checks-p t))
1526
1527   (declare (type (and list (not null)) slot-names))
1528   (declare (type (and symbol (not null))
1529                  boa-constructor
1530                  superclass-name
1531                  metaclass-name
1532                  metaclass-constructor))
1533   (declare (type symbol predicate))
1534   (declare (type (member structure funcallable-structure) dd-type))
1535
1536   (let* ((dd (make-dd-with-alternate-metaclass
1537               :class-name class-name
1538               :slot-names slot-names
1539               :superclass-name superclass-name
1540               :metaclass-name metaclass-name
1541               :metaclass-constructor metaclass-constructor
1542               :dd-type dd-type))
1543          (dd-slots (dd-slots dd))
1544          (dd-length (1+ (length slot-names)))
1545          (object-gensym (gensym "OBJECT"))
1546          (new-value-gensym (gensym "NEW-VALUE-"))
1547          (delayed-layout-form `(%delayed-get-compiler-layout ,class-name)))
1548     (multiple-value-bind (raw-maker-form raw-reffer-operator)
1549         (ecase dd-type
1550           (structure
1551            (values `(let ((,object-gensym (%make-instance ,dd-length)))
1552                       (setf (%instance-layout ,object-gensym)
1553                             ,delayed-layout-form)
1554                       ,object-gensym)
1555                    '%instance-ref))
1556           (funcallable-structure
1557            (values `(%make-funcallable-instance ,dd-length
1558                                                 ,delayed-layout-form)
1559                    '%funcallable-instance-info)))
1560       `(progn
1561
1562          (eval-when (:compile-toplevel :load-toplevel :execute)
1563            (%compiler-set-up-layout ',dd))
1564
1565          ;; slot readers and writers
1566          (declaim (inline ,@(mapcar #'dsd-accessor-name dd-slots)))
1567          ,@(mapcar (lambda (dsd)
1568                      `(defun ,(dsd-accessor-name dsd) (,object-gensym)
1569                         ,@(when runtime-type-checks-p
1570                             `((declare (type ,class-name ,object-gensym))))
1571                         (,raw-reffer-operator ,object-gensym
1572                                               ,(dsd-index dsd))))
1573                    dd-slots)
1574          (declaim (inline ,@(mapcar (lambda (dsd)
1575                                       `(setf ,(dsd-accessor-name dsd)))
1576                                     dd-slots)))
1577          ,@(mapcar (lambda (dsd)
1578                      `(defun (setf ,(dsd-accessor-name dsd)) (,new-value-gensym
1579                                                               ,object-gensym)
1580                         ,@(when runtime-type-checks-p
1581                             `((declare (type ,class-name ,object-gensym))))
1582                         (setf (,raw-reffer-operator ,object-gensym
1583                                                     ,(dsd-index dsd))
1584                               ,new-value-gensym)))
1585                    dd-slots)
1586
1587          ;; constructor
1588          (defun ,boa-constructor ,slot-names
1589            (let ((,object-gensym ,raw-maker-form))
1590              ,@(mapcar (lambda (slot-name)
1591                          (let ((dsd (find (symbol-name slot-name) dd-slots
1592                                           :key (lambda (x)
1593                                                  (symbol-name (dsd-name x)))
1594                                           :test #'string=)))
1595                            ;; KLUDGE: bug 117 bogowarning.  Neither
1596                            ;; DECLAREing the type nor TRULY-THE cut
1597                            ;; the mustard -- it still gives warnings.
1598                            (enforce-type dsd defstruct-slot-description)
1599                            `(setf (,(dsd-accessor-name dsd) ,object-gensym)
1600                                   ,slot-name)))
1601                        slot-names)
1602              ,object-gensym))
1603
1604          ;; predicate
1605          ,@(when predicate
1606              ;; Just delegate to the compiler's type optimization
1607              ;; code, which knows how to generate inline type tests
1608              ;; for the whole CMU CL INSTANCE menagerie.
1609              `(defun ,predicate (,object-gensym)
1610                 (typep ,object-gensym ',class-name)))))))
1611 \f
1612 ;;;; finalizing bootstrapping
1613
1614 ;;; Set up DD and LAYOUT for STRUCTURE-OBJECT class itself.
1615 ;;;
1616 ;;; Ordinary structure classes effectively :INCLUDE STRUCTURE-OBJECT
1617 ;;; when they have no explicit :INCLUDEs, so (1) it needs to be set up
1618 ;;; before we can define ordinary structure classes, and (2) it's
1619 ;;; special enough (and simple enough) that we just build it by hand
1620 ;;; instead of trying to generalize the ordinary DEFSTRUCT code.
1621 (defun !set-up-structure-object-class ()
1622   (let ((dd (make-defstruct-description 'structure-object)))
1623     (setf
1624      ;; Note: This has an ALTERNATE-METACLASS only because of blind
1625      ;; clueless imitation of the CMU CL code -- dunno if or why it's
1626      ;; needed. -- WHN
1627      (dd-alternate-metaclass dd) '(instance)
1628      (dd-slots dd) nil
1629      (dd-length dd) 1
1630      (dd-type dd) 'structure)
1631     (%compiler-set-up-layout dd)))
1632 (!set-up-structure-object-class)
1633
1634 ;;; early structure predeclarations: Set up DD and LAYOUT for ordinary
1635 ;;; (non-ALTERNATE-METACLASS) structures which are needed early.
1636 (dolist (args
1637          '#.(sb-cold:read-from-file
1638              "src/code/early-defstruct-args.lisp-expr"))
1639   (let* ((dd (parse-defstruct-name-and-options-and-slot-descriptions
1640               (first args)
1641               (rest args)))
1642          (inherits (inherits-for-structure dd)))
1643     (%compiler-defstruct dd inherits)))
1644
1645 (/show0 "code/defstruct.lisp end of file")