src/code/defstruct.lisp

   1 ;;;; that part of DEFSTRUCT implementation which is needed not just
   2 ;;;; in the target Lisp but also in the cross-compilation host
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!KERNEL")
  14
  15 (/show0 "code/defstruct.lisp 15")
  16 \f
  17 ;;;; getting LAYOUTs
  18
  19 ;;; Return the compiler layout for NAME. (The class referred to by
  20 ;;; NAME must be a structure-like class.)
  21 (defun compiler-layout-or-lose (name)
  22   (let ((res (info :type :compiler-layout name)))
  23     (cond ((not res)
  24            (error "Class is not yet defined or was undefined: ~S" name))
  25           ((not (typep (layout-info res) 'defstruct-description))
  26            (error "Class is not a structure class: ~S" name))
  27           (t res))))
  28
  29 ;;; Delay looking for compiler-layout until the constructor is being
  30 ;;; compiled, since it doesn't exist until after the EVAL-WHEN
  31 ;;; (COMPILE) stuff is compiled. (Or, in the oddball case when
  32 ;;; DEFSTRUCT is executing in a non-toplevel context, the
  33 ;;; compiler-layout still doesn't exist at compilation time, and we
  34 ;;; delay still further.)
  35 (sb!xc:defmacro %delayed-get-compiler-layout (name)
  36   (let ((layout (info :type :compiler-layout name)))
  37     (cond (layout
  38            ;; ordinary case: When the DEFSTRUCT is at top level,
  39            ;; then EVAL-WHEN (COMPILE) stuff will have set up the
  40            ;; layout for us to use.
  41            (unless (typep (layout-info layout) 'defstruct-description)
  42              (error "Class is not a structure class: ~S" name))
  43            `,layout)
  44           (t
  45            ;; KLUDGE: In the case that DEFSTRUCT is not at top-level
  46            ;; the layout doesn't exist at compile time. In that case
  47            ;; we laboriously look it up at run time. This code will
  48            ;; run on every constructor call and will likely be quite
  49            ;; slow, so if anyone cares about performance of
  50            ;; non-toplevel DEFSTRUCTs, it should be rewritten to be
  51            ;; cleverer. -- WHN 2002-10-23
  52            (sb!c:compiler-notify
  53             "implementation limitation: ~
  54              Non-toplevel DEFSTRUCT constructors are slow.")
  55            (with-unique-names (layout)
  56              `(let ((,layout (info :type :compiler-layout ',name)))
  57                 (unless (typep (layout-info ,layout) 'defstruct-description)
  58                   (error "Class is not a structure class: ~S" ',name))
  59                 ,layout))))))
  60
  61 ;;; Get layout right away.
  62 (sb!xc:defmacro compile-time-find-layout (name)
  63   (find-layout name))
  64
  65 ;;; re. %DELAYED-GET-COMPILER-LAYOUT and COMPILE-TIME-FIND-LAYOUT, above..
  66 ;;;
  67 ;;; FIXME: Perhaps both should be defined with DEFMACRO-MUNDANELY?
  68 ;;; FIXME: Do we really need both? If so, their names and implementations
  69 ;;; should probably be tweaked to be more parallel.
  70 \f
  71 ;;;; DEFSTRUCT-DESCRIPTION
  72
  73 ;;; The DEFSTRUCT-DESCRIPTION structure holds compile-time information
  74 ;;; about a structure type.
  75 (def!struct (defstruct-description
  76              (:conc-name dd-)
  77              (:make-load-form-fun just-dump-it-normally)
  78              #-sb-xc-host (:pure t)
  79              (:constructor make-defstruct-description
  80                            (name &aux
  81                                  (conc-name (symbolicate name "-"))
  82                                  (copier-name (symbolicate "COPY-" name))
  83                                  (predicate-name (symbolicate name "-P")))))
  84   ;; name of the structure
  85   (name (missing-arg) :type symbol :read-only t)
  86   ;; documentation on the structure
  87   (doc nil :type (or string null))
  88   ;; prefix for slot names. If NIL, none.
  89   (conc-name nil :type (or symbol null))
  90   ;; the name of the primary standard keyword constructor, or NIL if none
  91   (default-constructor nil :type (or symbol null))
  92   ;; all the explicit :CONSTRUCTOR specs, with name defaulted
  93   (constructors () :type list)
  94   ;; name of copying function
  95   (copier-name nil :type (or symbol null))
  96   ;; name of type predicate
  97   (predicate-name nil :type (or symbol null))
  98   ;; the arguments to the :INCLUDE option, or NIL if no included
  99   ;; structure
 100   (include nil :type list)
 101   ;; properties used to define structure-like classes with an
 102   ;; arbitrary superclass and that may not have STRUCTURE-CLASS as the
 103   ;; metaclass. Syntax is:
 104   ;;    (superclass-name metaclass-name metaclass-constructor)
 105   (alternate-metaclass nil :type list)
 106   ;; a list of DEFSTRUCT-SLOT-DESCRIPTION objects for all slots
 107   ;; (including included ones)
 108   (slots () :type list)
 109   ;; a list of (NAME . INDEX) pairs for accessors of included structures
 110   (inherited-accessor-alist () :type list)
 111   ;; number of elements we've allocated (See also RAW-LENGTH.)
 112   (length 0 :type index)
 113   ;; General kind of implementation.
 114   (type 'structure :type (member structure vector list
 115                                  funcallable-structure))
 116
 117   ;; The next three slots are for :TYPE'd structures (which aren't
 118   ;; classes, DD-CLASS-P = NIL)
 119   ;;
 120   ;; vector element type
 121   (element-type t)
 122   ;; T if :NAMED was explicitly specified, NIL otherwise
 123   (named nil :type boolean)
 124   ;; any INITIAL-OFFSET option on this direct type
 125   (offset nil :type (or index null))
 126
 127   ;; the argument to the PRINT-FUNCTION option, or NIL if a
 128   ;; PRINT-FUNCTION option was given with no argument, or 0 if no
 129   ;; PRINT-FUNCTION option was given
 130   (print-function 0 :type (or cons symbol (member 0)))
 131   ;; the argument to the PRINT-OBJECT option, or NIL if a PRINT-OBJECT
 132   ;; option was given with no argument, or 0 if no PRINT-OBJECT option
 133   ;; was given
 134   (print-object 0 :type (or cons symbol (member 0)))
 135   ;; the index of the raw data vector and the number of words in it,
 136   ;; or NIL and 0 if not allocated (either because this structure
 137   ;; has no raw slots, or because we're still parsing it and haven't
 138   ;; run across any raw slots yet)
 139   (raw-index nil :type (or index null))
 140   (raw-length 0 :type index)
 141   ;; the value of the :PURE option, or :UNSPECIFIED. This is only
 142   ;; meaningful if DD-CLASS-P = T.
 143   (pure :unspecified :type (member t nil :substructure :unspecified)))
 144 (def!method print-object ((x defstruct-description) stream)
 145   (print-unreadable-object (x stream :type t)
 146     (prin1 (dd-name x) stream)))
 147
 148 ;;; Does DD describe a structure with a class?
 149 (defun dd-class-p (dd)
 150   (member (dd-type dd)
 151           '(structure funcallable-structure)))
 152
 153 ;;; a type name which can be used when declaring things which operate
 154 ;;; on structure instances
 155 (defun dd-declarable-type (dd)
 156   (if (dd-class-p dd)
 157       ;; Native classes are known to the type system, and we can
 158       ;; declare them as types.
 159       (dd-name dd)
 160       ;; Structures layered on :TYPE LIST or :TYPE VECTOR aren't part
 161       ;; of the type system, so all we can declare is the underlying
 162       ;; LIST or VECTOR type.
 163       (dd-type dd)))
 164
 165 (defun dd-layout-or-lose (dd)
 166   (compiler-layout-or-lose (dd-name dd)))
 167 \f
 168 ;;;; DEFSTRUCT-SLOT-DESCRIPTION
 169
 170 ;;; A DEFSTRUCT-SLOT-DESCRIPTION holds compile-time information about
 171 ;;; a structure slot.
 172 (def!struct (defstruct-slot-description
 173              (:make-load-form-fun just-dump-it-normally)
 174              (:conc-name dsd-)
 175              (:copier nil)
 176              #-sb-xc-host (:pure t))
 177   ;; name of slot
 178   name
 179   ;; its position in the implementation sequence
 180   (index (missing-arg) :type fixnum)
 181   ;; the name of the accessor function
 182   ;;
 183   ;; (CMU CL had extra complexity here ("..or NIL if this accessor has
 184   ;; the same name as an inherited accessor (which we don't want to
 185   ;; shadow)") but that behavior doesn't seem to be specified by (or
 186   ;; even particularly consistent with) ANSI, so it's gone in SBCL.)
 187   (accessor-name nil)
 188   default                       ; default value expression
 189   (type t)                      ; declared type specifier
 190   (safe-p t :type boolean)      ; whether the slot is known to be
 191                                 ; always of the specified type
 192   ;; If this object does not describe a raw slot, this value is T.
 193   ;;
 194   ;; If this object describes a raw slot, this value is the type of the
 195   ;; value that the raw slot holds. Mostly. (KLUDGE: If the raw slot has
 196   ;; type (UNSIGNED-BYTE 32), the value here is UNSIGNED-BYTE, not
 197   ;; (UNSIGNED-BYTE 32).)
 198   (raw-type t :type (member t single-float double-float
 199                             #!+long-float long-float
 200                             complex-single-float complex-double-float
 201                             #!+long-float complex-long-float
 202                             unsigned-byte))
 203   (read-only nil :type (member t nil)))
 204 (def!method print-object ((x defstruct-slot-description) stream)
 205   (print-unreadable-object (x stream :type t)
 206     (prin1 (dsd-name x) stream)))
 207 \f
 208 ;;;; typed (non-class) structures
 209
 210 ;;; Return a type specifier we can use for testing :TYPE'd structures.
 211 (defun dd-lisp-type (defstruct)
 212   (ecase (dd-type defstruct)
 213     (list 'list)
 214     (vector `(simple-array ,(dd-element-type defstruct) (*)))))
 215 \f
 216 ;;;; shared machinery for inline and out-of-line slot accessor functions
 217
 218 (eval-when (#-sb-xc :compile-toplevel :load-toplevel :execute)
 219
 220   ;; information about how a slot of a given DSD-RAW-TYPE is to be accessed
 221   (defstruct raw-slot-data
 222     ;; the raw slot type, or T for a non-raw slot
 223     ;;
 224     ;; (Raw slots are allocated in the raw slots array in a vector which
 225     ;; the GC doesn't need to scavenge. Non-raw slots are in the
 226     ;; ordinary place you'd expect, directly indexed off the instance
 227     ;; pointer.)
 228     (raw-type (missing-arg) :type (or symbol cons) :read-only t)
 229     ;; What operator is used (on the raw data vector) to access a slot
 230     ;; of this type?
 231     (accessor-name (missing-arg) :type symbol :read-only t)
 232     ;; How many words are each value of this type? (This is used to
 233     ;; rescale the offset into the raw data vector.)
 234     (n-words (missing-arg) :type (and index (integer 1)) :read-only t))
 235
 236   (defvar *raw-slot-data-list*
 237     (list
 238      ;; The compiler thinks that the raw data vector is a vector of
 239      ;; word-sized unsigned bytes, so if the slot we want to access
 240      ;; actually *is* an unsigned byte, it'll access the slot for us
 241      ;; even if we don't lie to it at all, just let it use normal AREF.
 242      (make-raw-slot-data :raw-type 'unsigned-byte
 243                          :accessor-name 'aref
 244                          :n-words 1)
 245      ;; In the other cases, we lie to the compiler, making it use
 246      ;; some low-level AREFish access in order to pun the hapless
 247      ;; bits into some other-than-unsigned-byte meaning.
 248      ;;
 249      ;; "A lie can travel halfway round the world while the truth is
 250      ;; putting on its shoes." -- Mark Twain
 251      (make-raw-slot-data :raw-type 'single-float
 252                          :accessor-name '%raw-ref-single
 253                          :n-words 1)
 254      (make-raw-slot-data :raw-type 'double-float
 255                          :accessor-name '%raw-ref-double
 256                          :n-words 2)
 257      (make-raw-slot-data :raw-type 'complex-single-float
 258                          :accessor-name '%raw-ref-complex-single
 259                          :n-words 2)
 260      (make-raw-slot-data :raw-type 'complex-double-float
 261                          :accessor-name '%raw-ref-complex-double
 262                          :n-words 4)
 263      #!+long-float
 264      (make-raw-slot-data :raw-type long-float
 265                          :accessor-name '%raw-ref-long
 266                          :n-words #!+x86 3 #!+sparc 4)
 267      #!+long-float
 268      (make-raw-slot-data :raw-type complex-long-float
 269                          :accessor-name '%raw-ref-complex-long
 270                          :n-words #!+x86 6 #!+sparc 8))))
 271 \f
 272 ;;;; the legendary DEFSTRUCT macro itself (both CL:DEFSTRUCT and its
 273 ;;;; close personal friend SB!XC:DEFSTRUCT)
 274
 275 ;;; Return a list of forms to install PRINT and MAKE-LOAD-FORM funs,
 276 ;;; mentioning them in the expansion so that they can be compiled.
 277 (defun class-method-definitions (defstruct)
 278   (let ((name (dd-name defstruct)))
 279     `((locally
 280         ;; KLUDGE: There's a FIND-CLASS DEFTRANSFORM for constant
 281         ;; class names which creates fast but non-cold-loadable,
 282         ;; non-compact code. In this context, we'd rather have
 283         ;; compact, cold-loadable code. -- WHN 19990928
 284         (declare (notinline find-classoid))
 285         ,@(let ((pf (dd-print-function defstruct))
 286                 (po (dd-print-object defstruct))
 287                 (x (gensym))
 288                 (s (gensym)))
 289             ;; Giving empty :PRINT-OBJECT or :PRINT-FUNCTION options
 290             ;; leaves PO or PF equal to NIL. The user-level effect is
 291             ;; to generate a PRINT-OBJECT method specialized for the type,
 292             ;; implementing the default #S structure-printing behavior.
 293             (when (or (eq pf nil) (eq po nil))
 294               (setf pf '(default-structure-print)
 295                     po 0))
 296             (flet (;; Given an arg from a :PRINT-OBJECT or :PRINT-FUNCTION
 297                    ;; option, return the value to pass as an arg to FUNCTION.
 298                    (farg (oarg)
 299                      (destructuring-bind (fun-name) oarg
 300                        fun-name)))
 301               (cond ((not (eql pf 0))
 302                      `((def!method print-object ((,x ,name) ,s)
 303                          (funcall #',(farg pf)
 304                                   ,x
 305                                   ,s
 306                                   *current-level-in-print*))))
 307                     ((not (eql po 0))
 308                      `((def!method print-object ((,x ,name) ,s)
 309                          (funcall #',(farg po) ,x ,s))))
 310                     (t nil))))
 311         ,@(let ((pure (dd-pure defstruct)))
 312             (cond ((eq pure t)
 313                    `((setf (layout-pure (classoid-layout
 314                                          (find-classoid ',name)))
 315                            t)))
 316                   ((eq pure :substructure)
 317                    `((setf (layout-pure (classoid-layout
 318                                          (find-classoid ',name)))
 319                            0)))))
 320         ,@(let ((def-con (dd-default-constructor defstruct)))
 321             (when (and def-con (not (dd-alternate-metaclass defstruct)))
 322               `((setf (structure-classoid-constructor (find-classoid ',name))
 323                       #',def-con))))))))
 324
 325 ;;; shared logic for CL:DEFSTRUCT and SB!XC:DEFSTRUCT
 326 (defmacro !expander-for-defstruct (name-and-options
 327                                    slot-descriptions
 328                                    expanding-into-code-for-xc-host-p)
 329   `(let ((name-and-options ,name-and-options)
 330          (slot-descriptions ,slot-descriptions)
 331          (expanding-into-code-for-xc-host-p
 332           ,expanding-into-code-for-xc-host-p))
 333      (let* ((dd (parse-defstruct-name-and-options-and-slot-descriptions
 334                  name-and-options
 335                  slot-descriptions))
 336             (name (dd-name dd)))
 337        (if (dd-class-p dd)
 338            (let ((inherits (inherits-for-structure dd)))
 339              `(progn
 340                 ;; Note we intentionally call %DEFSTRUCT first, and
 341                 ;; especially before %COMPILER-DEFSTRUCT. %DEFSTRUCT
 342                 ;; has the tests (and resulting CERROR) for collisions
 343                 ;; with LAYOUTs which already exist in the runtime. If
 344                 ;; there are any collisions, we want the user's
 345                 ;; response to CERROR to control what happens.
 346                 ;; Especially, if the user responds to the collision
 347                 ;; with ABORT, we don't want %COMPILER-DEFSTRUCT to
 348                 ;; modify the definition of the class.
 349                 (%defstruct ',dd ',inherits)
 350                 (eval-when (:compile-toplevel :load-toplevel :execute)
 351                   (%compiler-defstruct ',dd ',inherits))
 352                 ,@(unless expanding-into-code-for-xc-host-p
 353                     (append ;; FIXME: We've inherited from CMU CL nonparallel
 354                             ;; code for creating copiers for typed and untyped
 355                             ;; structures. This should be fixed.
 356                             ;(copier-definition dd)
 357                             (constructor-definitions dd)
 358                             (class-method-definitions dd)))
 359                 ',name))
 360            `(progn
 361               (eval-when (:compile-toplevel :load-toplevel :execute)
 362                 (setf (info :typed-structure :info ',name) ',dd))
 363               ,@(unless expanding-into-code-for-xc-host-p
 364                   (append (typed-accessor-definitions dd)
 365                           (typed-predicate-definitions dd)
 366                           (typed-copier-definitions dd)
 367                           (constructor-definitions dd)))
 368               ',name)))))
 369
 370 (sb!xc:defmacro defstruct (name-and-options &rest slot-descriptions)
 371   #!+sb-doc
 372   "DEFSTRUCT {Name | (Name Option*)} {Slot | (Slot [Default] {Key Value}*)}
 373    Define the structure type Name. Instances are created by MAKE-<name>,
 374    which takes &KEY arguments allowing initial slot values to the specified.
 375    A SETF'able function <name>-<slot> is defined for each slot to read and
 376    write slot values. <name>-p is a type predicate.
 377
 378    Popular DEFSTRUCT options (see manual for others):
 379
 380    (:CONSTRUCTOR Name)
 381    (:PREDICATE Name)
 382        Specify the name for the constructor or predicate.
 383
 384    (:CONSTRUCTOR Name Lambda-List)
 385        Specify the name and arguments for a BOA constructor
 386        (which is more efficient when keyword syntax isn't necessary.)
 387
 388    (:INCLUDE Supertype Slot-Spec*)
 389        Make this type a subtype of the structure type Supertype. The optional
 390        Slot-Specs override inherited slot options.
 391
 392    Slot options:
 393
 394    :TYPE Type-Spec
 395        Asserts that the value of this slot is always of the specified type.
 396
 397    :READ-ONLY {T | NIL}
 398        If true, no setter function is defined for this slot."
 399     (!expander-for-defstruct name-and-options slot-descriptions nil))
 400 #+sb-xc-host
 401 (defmacro sb!xc:defstruct (name-and-options &rest slot-descriptions)
 402   #!+sb-doc
 403   "Cause information about a target structure to be built into the
 404   cross-compiler."
 405   (!expander-for-defstruct name-and-options slot-descriptions t))
 406 \f
 407 ;;;; functions to generate code for various parts of DEFSTRUCT definitions
 408
 409 ;;; First, a helper to determine whether a name names an inherited
 410 ;;; accessor.
 411 (defun accessor-inherited-data (name defstruct)
 412   (assoc name (dd-inherited-accessor-alist defstruct) :test #'eq))
 413
 414 ;;; Return a list of forms which create a predicate function for a
 415 ;;; typed DEFSTRUCT.
 416 (defun typed-predicate-definitions (defstruct)
 417   (let ((name (dd-name defstruct))
 418         (predicate-name (dd-predicate-name defstruct))
 419         (argname (gensym)))
 420     (when (and predicate-name (dd-named defstruct))
 421       (let ((ltype (dd-lisp-type defstruct))
 422             (name-index (cdr (car (last (find-name-indices defstruct))))))
 423         `((defun ,predicate-name (,argname)
 424             (and (typep ,argname ',ltype)
 425                  ,(cond
 426                    ((subtypep ltype 'list)
 427                      `(do ((head (the ,ltype ,argname) (cdr head))
 428                            (i 0 (1+ i)))
 429                           ((or (not (consp head)) (= i ,name-index))
 430                            (and (consp head) (eq ',name (car head))))))
 431                    ((subtypep ltype 'vector)
 432                     `(and (= (length (the ,ltype ,argname))
 433                            ,(dd-length defstruct))
 434                           (eq ',name (aref (the ,ltype ,argname) ,name-index))))
 435                    (t (bug "Uncatered-for lisp type in typed DEFSTRUCT: ~S."
 436                            ltype))))))))))
 437
 438 ;;; Return a list of forms to create a copier function of a typed DEFSTRUCT.
 439 (defun typed-copier-definitions (defstruct)
 440   (when (dd-copier-name defstruct)
 441     `((setf (fdefinition ',(dd-copier-name defstruct)) #'copy-seq)
 442       (declaim (ftype function ,(dd-copier-name defstruct))))))
 443
 444 ;;; Return a list of function definitions for accessing and setting
 445 ;;; the slots of a typed DEFSTRUCT. The functions are proclaimed to be
 446 ;;; inline, and the types of their arguments and results are declared
 447 ;;; as well. We count on the compiler to do clever things with ELT.
 448 (defun typed-accessor-definitions (defstruct)
 449   (collect ((stuff))
 450     (let ((ltype (dd-lisp-type defstruct)))
 451       (dolist (slot (dd-slots defstruct))
 452         (let ((name (dsd-accessor-name slot))
 453               (index (dsd-index slot))
 454               (slot-type `(and ,(dsd-type slot)
 455                                ,(dd-element-type defstruct))))
 456           (let ((inherited (accessor-inherited-data name defstruct)))
 457             (cond
 458               ((not inherited)
 459                (stuff `(declaim (inline ,name (setf ,name))))
 460                ;; FIXME: The arguments in the next two DEFUNs should
 461                ;; be gensyms. (Otherwise e.g. if NEW-VALUE happened to
 462                ;; be the name of a special variable, things could get
 463                ;; weird.)
 464                (stuff `(defun ,name (structure)
 465                         (declare (type ,ltype structure))
 466                         (the ,slot-type (elt structure ,index))))
 467                (unless (dsd-read-only slot)
 468                  (stuff
 469                   `(defun (setf ,name) (new-value structure)
 470                     (declare (type ,ltype structure) (type ,slot-type new-value))
 471                     (setf (elt structure ,index) new-value)))))
 472               ((not (= (cdr inherited) index))
 473                (style-warn "~@<Non-overwritten accessor ~S does not access ~
 474                             slot with name ~S (accessing an inherited slot ~
 475                             instead).~:@>" name (dsd-name slot))))))))
 476     (stuff)))
 477 \f
 478 ;;;; parsing
 479
 480 (defun require-no-print-options-so-far (defstruct)
 481   (unless (and (eql (dd-print-function defstruct) 0)
 482                (eql (dd-print-object defstruct) 0))
 483     (error "No more than one of the following options may be specified:
 484   :PRINT-FUNCTION, :PRINT-OBJECT, :TYPE")))
 485
 486 ;;; Parse a single DEFSTRUCT option and store the results in DD.
 487 (defun parse-1-dd-option (option dd)
 488   (let ((args (rest option))
 489         (name (dd-name dd)))
 490     (case (first option)
 491       (:conc-name
 492        (destructuring-bind (&optional conc-name) args
 493          (setf (dd-conc-name dd)
 494                (if (symbolp conc-name)
 495                    conc-name
 496                    (make-symbol (string conc-name))))))
 497       (:constructor
 498        (destructuring-bind (&optional (cname (symbolicate "MAKE-" name))
 499                                       &rest stuff)
 500            args
 501          (push (cons cname stuff) (dd-constructors dd))))
 502       (:copier
 503        (destructuring-bind (&optional (copier (symbolicate "COPY-" name)))
 504            args
 505          (setf (dd-copier-name dd) copier)))
 506       (:predicate
 507        (destructuring-bind (&optional (predicate-name (symbolicate name "-P")))
 508            args
 509          (setf (dd-predicate-name dd) predicate-name)))
 510       (:include
 511        (when (dd-include dd)
 512          (error "more than one :INCLUDE option"))
 513        (setf (dd-include dd) args))
 514       (:print-function
 515        (require-no-print-options-so-far dd)
 516        (setf (dd-print-function dd)
 517              (the (or symbol cons) args)))
 518       (:print-object
 519        (require-no-print-options-so-far dd)
 520        (setf (dd-print-object dd)
 521              (the (or symbol cons) args)))
 522       (:type
 523        (destructuring-bind (type) args
 524          (cond ((member type '(list vector))
 525                 (setf (dd-element-type dd) t)
 526                 (setf (dd-type dd) type))
 527                ((and (consp type) (eq (first type) 'vector))
 528                 (destructuring-bind (vector vtype) type
 529                   (declare (ignore vector))
 530                   (setf (dd-element-type dd) vtype)
 531                   (setf (dd-type dd) 'vector)))
 532                (t
 533                 (error "~S is a bad :TYPE for DEFSTRUCT." type)))))
 534       (:named
 535        (error "The DEFSTRUCT option :NAMED takes no arguments."))
 536       (:initial-offset
 537        (destructuring-bind (offset) args
 538          (setf (dd-offset dd) offset)))
 539       (:pure
 540        (destructuring-bind (fun) args
 541          (setf (dd-pure dd) fun)))
 542       (t (error "unknown DEFSTRUCT option:~%  ~S" option)))))
 543
 544 ;;; Given name and options, return a DD holding that info.
 545 (defun parse-defstruct-name-and-options (name-and-options)
 546   (destructuring-bind (name &rest options) name-and-options
 547     (aver name) ; A null name doesn't seem to make sense here.
 548     (let ((dd (make-defstruct-description name)))
 549       (dolist (option options)
 550         (cond ((eq option :named)
 551                (setf (dd-named dd) t))
 552               ((consp option)
 553                (parse-1-dd-option option dd))
 554               ((member option '(:conc-name :constructor :copier :predicate))
 555                (parse-1-dd-option (list option) dd))
 556               (t
 557                (error "unrecognized DEFSTRUCT option: ~S" option))))
 558
 559       (case (dd-type dd)
 560         (structure
 561          (when (dd-offset dd)
 562            (error ":OFFSET can't be specified unless :TYPE is specified."))
 563          (unless (dd-include dd)
 564            ;; FIXME: It'd be cleaner to treat no-:INCLUDE as defaulting
 565            ;; to :INCLUDE STRUCTURE-OBJECT, and then let the general-case
 566            ;; (INCF (DD-LENGTH DD) (DD-LENGTH included-DD)) logic take
 567            ;; care of this. (Except that the :TYPE VECTOR and :TYPE
 568            ;; LIST cases, with their :NAMED and un-:NAMED flavors,
 569            ;; make that messy, alas.)
 570            (incf (dd-length dd))))
 571         (t
 572          (require-no-print-options-so-far dd)
 573          (when (dd-named dd)
 574            (incf (dd-length dd)))
 575          (let ((offset (dd-offset dd)))
 576            (when offset (incf (dd-length dd) offset)))))
 577
 578       (when (dd-include dd)
 579         (frob-dd-inclusion-stuff dd))
 580
 581       dd)))
 582
 583 ;;; Given name and options and slot descriptions (and possibly doc
 584 ;;; string at the head of slot descriptions) return a DD holding that
 585 ;;; info.
 586 (defun parse-defstruct-name-and-options-and-slot-descriptions
 587     (name-and-options slot-descriptions)
 588   (let ((result (parse-defstruct-name-and-options (if (atom name-and-options)
 589                                                       (list name-and-options)
 590                                                       name-and-options))))
 591     (when (stringp (car slot-descriptions))
 592       (setf (dd-doc result) (pop slot-descriptions)))
 593     (dolist (slot-description slot-descriptions)
 594       (allocate-1-slot result (parse-1-dsd result slot-description)))
 595     result))
 596 \f
 597 ;;;; stuff to parse slot descriptions
 598
 599 ;;; Parse a slot description for DEFSTRUCT, add it to the description
 600 ;;; and return it. If supplied, SLOT is a pre-initialized DSD
 601 ;;; that we modify to get the new slot. This is supplied when handling
 602 ;;; included slots.
 603 (defun parse-1-dsd (defstruct spec &optional
 604                     (slot (make-defstruct-slot-description :name ""
 605                                                            :index 0
 606                                                            :type t)))
 607   (multiple-value-bind (name default default-p type type-p read-only ro-p)
 608       (typecase spec
 609         (symbol
 610          (when (keywordp spec)
 611            (style-warn "Keyword slot name indicates probable syntax ~
 612                         error in DEFSTRUCT: ~S."
 613                        spec))
 614          spec)
 615         (cons
 616          (destructuring-bind
 617                (name
 618                 &optional (default nil default-p)
 619                 &key (type nil type-p) (read-only nil ro-p))
 620              spec
 621            (values name
 622                    default default-p
 623                    (uncross type) type-p
 624                    read-only ro-p)))
 625         (t (error 'simple-program-error
 626                   :format-control "in DEFSTRUCT, ~S is not a legal slot ~
 627                                    description."
 628                   :format-arguments (list spec))))
 629
 630     (when (find name (dd-slots defstruct)
 631                 :test #'string=
 632                 :key (lambda (x) (symbol-name (dsd-name x))))
 633       (error 'simple-program-error
 634              :format-control "duplicate slot name ~S"
 635              :format-arguments (list name)))
 636     (setf (dsd-name slot) name)
 637     (setf (dd-slots defstruct) (nconc (dd-slots defstruct) (list slot)))
 638
 639     (let ((accessor-name (if (dd-conc-name defstruct)
 640                              (symbolicate (dd-conc-name defstruct) name)
 641                              name))
 642           (predicate-name (dd-predicate-name defstruct)))
 643       (setf (dsd-accessor-name slot) accessor-name)
 644       (when (eql accessor-name predicate-name)
 645         ;; Some adventurous soul has named a slot so that its accessor
 646         ;; collides with the structure type predicate. ANSI doesn't
 647         ;; specify what to do in this case. As of 2001-09-04, Martin
 648         ;; Atzmueller reports that CLISP and Lispworks both give
 649         ;; priority to the slot accessor, so that the predicate is
 650         ;; overwritten. We might as well do the same (as well as
 651         ;; signalling a warning).
 652         (style-warn
 653          "~@<The structure accessor name ~S is the same as the name of the ~
 654           structure type predicate. ANSI doesn't specify what to do in ~
 655           this case. We'll overwrite the type predicate with the slot ~
 656           accessor, but you can't rely on this behavior, so it'd be wise to ~
 657           remove the ambiguity in your code.~@:>"
 658          accessor-name)
 659         (setf (dd-predicate-name defstruct) nil))
 660       #-sb-xc-host
 661       (when (and (fboundp accessor-name)
 662                  (not (accessor-inherited-data accessor-name defstruct)))
 663         (style-warn "redefining ~S in DEFSTRUCT" accessor-name)))
 664
 665     (when default-p
 666       (setf (dsd-default slot) default))
 667     (when type-p
 668       (setf (dsd-type slot)
 669             (if (eq (dsd-type slot) t)
 670                 type
 671                 `(and ,(dsd-type slot) ,type))))
 672     (when ro-p
 673       (if read-only
 674           (setf (dsd-read-only slot) t)
 675           (when (dsd-read-only slot)
 676             (error "Slot ~S is :READ-ONLY in parent and must be :READ-ONLY in subtype ~S."
 677                    name
 678                    (dsd-name slot)))))
 679     slot))
 680
 681 ;;; When a value of type TYPE is stored in a structure, should it be
 682 ;;; stored in a raw slot? Return (VALUES RAW? RAW-TYPE WORDS), where
 683 ;;;   RAW? is true if TYPE should be stored in a raw slot.
 684 ;;;   RAW-TYPE is the raw slot type, or NIL if no raw slot.
 685 ;;;   WORDS is the number of words in the raw slot, or NIL if no raw slot.
 686 ;;;
 687 ;;; FIXME: This should use the data in *RAW-SLOT-DATA-LIST*.
 688 (defun structure-raw-slot-type-and-size (type)
 689   (cond ((and (sb!xc:subtypep type '(unsigned-byte 32))
 690               (multiple-value-bind (fixnum? fixnum-certain?)
 691                   (sb!xc:subtypep type 'fixnum)
 692                 ;; (The extra test for FIXNUM-CERTAIN? here is
 693                 ;; intended for bootstrapping the system. In
 694                 ;; particular, in sbcl-0.6.2, we set up LAYOUT before
 695                 ;; FIXNUM is defined, and so could bogusly end up
 696                 ;; putting INDEX-typed values into raw slots if we
 697                 ;; didn't test FIXNUM-CERTAIN?.)
 698                 (and (not fixnum?) fixnum-certain?)))
 699          (values t 'unsigned-byte 1))
 700         ((sb!xc:subtypep type 'single-float)
 701          (values t 'single-float 1))
 702         ((sb!xc:subtypep type 'double-float)
 703          (values t 'double-float 2))
 704         #!+long-float
 705         ((sb!xc:subtypep type 'long-float)
 706          (values t 'long-float #!+x86 3 #!+sparc 4))
 707         ((sb!xc:subtypep type '(complex single-float))
 708          (values t 'complex-single-float 2))
 709         ((sb!xc:subtypep type '(complex double-float))
 710          (values t 'complex-double-float 4))
 711         #!+long-float
 712         ((sb!xc:subtypep type '(complex long-float))
 713          (values t 'complex-long-float #!+x86 6 #!+sparc 8))
 714         (t
 715          (values nil nil nil))))
 716
 717 ;;; Allocate storage for a DSD in DD. This is where we decide whether
 718 ;;; a slot is raw or not. If raw, and we haven't allocated a raw-index
 719 ;;; yet for the raw data vector, then do it. Raw objects are aligned
 720 ;;; on the unit of their size.
 721 (defun allocate-1-slot (dd dsd)
 722   (multiple-value-bind (raw? raw-type words)
 723       (if (eq (dd-type dd) 'structure)
 724           (structure-raw-slot-type-and-size (dsd-type dsd))
 725           (values nil nil nil))
 726     (cond ((not raw?)
 727            (setf (dsd-index dsd) (dd-length dd))
 728            (incf (dd-length dd)))
 729           (t
 730            (unless (dd-raw-index dd)
 731              (setf (dd-raw-index dd) (dd-length dd))
 732              (incf (dd-length dd)))
 733            (let ((off (rem (dd-raw-length dd) words)))
 734              (unless (zerop off)
 735                (incf (dd-raw-length dd) (- words off))))
 736            (setf (dsd-raw-type dsd) raw-type)
 737            (setf (dsd-index dsd) (dd-raw-length dd))
 738            (incf (dd-raw-length dd) words))))
 739   (values))
 740
 741 (defun typed-structure-info-or-lose (name)
 742   (or (info :typed-structure :info name)
 743       (error ":TYPE'd DEFSTRUCT ~S not found for inclusion." name)))
 744
 745 ;;; Process any included slots pretty much like they were specified.
 746 ;;; Also inherit various other attributes.
 747 (defun frob-dd-inclusion-stuff (dd)
 748   (destructuring-bind (included-name &rest modified-slots) (dd-include dd)
 749     (let* ((type (dd-type dd))
 750            (included-structure
 751             (if (dd-class-p dd)
 752                 (layout-info (compiler-layout-or-lose included-name))
 753                 (typed-structure-info-or-lose included-name))))
 754
 755       ;; checks on legality
 756       (unless (and (eq type (dd-type included-structure))
 757                    (type= (specifier-type (dd-element-type included-structure))
 758                           (specifier-type (dd-element-type dd))))
 759         (error ":TYPE option mismatch between structures ~S and ~S"
 760                (dd-name dd) included-name))
 761       (let ((included-classoid (find-classoid included-name nil)))
 762         (when included-classoid
 763           ;; It's not particularly well-defined to :INCLUDE any of the
 764           ;; CMU CL INSTANCE weirdosities like CONDITION or
 765           ;; GENERIC-FUNCTION, and it's certainly not ANSI-compliant.
 766           (let* ((included-layout (classoid-layout included-classoid))
 767                  (included-dd (layout-info included-layout)))
 768             (when (and (dd-alternate-metaclass included-dd)
 769                        ;; As of sbcl-0.pre7.73, anyway, STRUCTURE-OBJECT
 770                        ;; is represented with an ALTERNATE-METACLASS. But
 771                        ;; it's specifically OK to :INCLUDE (and PCL does)
 772                        ;; so in this one case, it's OK to include
 773                        ;; something with :ALTERNATE-METACLASS after all.
 774                        (not (eql included-name 'structure-object)))
 775               (error "can't :INCLUDE class ~S (has alternate metaclass)"
 776                      included-name)))))
 777
 778       (incf (dd-length dd) (dd-length included-structure))
 779       (when (dd-class-p dd)
 780         (let ((mc (rest (dd-alternate-metaclass included-structure))))
 781           (when (and mc (not (dd-alternate-metaclass dd)))
 782             (setf (dd-alternate-metaclass dd)
 783                   (cons included-name mc))))
 784         (when (eq (dd-pure dd) :unspecified)
 785           (setf (dd-pure dd) (dd-pure included-structure)))
 786         (setf (dd-raw-index dd) (dd-raw-index included-structure))
 787         (setf (dd-raw-length dd) (dd-raw-length included-structure)))
 788
 789       (setf (dd-inherited-accessor-alist dd)
 790             (dd-inherited-accessor-alist included-structure))
 791       (dolist (included-slot (dd-slots included-structure))
 792         (let* ((included-name (dsd-name included-slot))
 793                (modified (or (find included-name modified-slots
 794                                    :key (lambda (x) (if (atom x) x (car x)))
 795                                    :test #'string=)
 796                              `(,included-name))))
 797           ;; We stash away an alist of accessors to parents' slots
 798           ;; that have already been created to avoid conflicts later
 799           ;; so that structures with :INCLUDE and :CONC-NAME (and
 800           ;; other edge cases) can work as specified.
 801           (when (dsd-accessor-name included-slot)
 802             ;; the "oldest" (i.e. highest up the tree of inheritance)
 803             ;; will prevail, so don't push new ones on if they
 804             ;; conflict.
 805             (pushnew (cons (dsd-accessor-name included-slot)
 806                            (dsd-index included-slot))
 807                      (dd-inherited-accessor-alist dd)
 808                      :test #'eq :key #'car))
 809           (let ((new-slot (parse-1-dsd dd
 810                                        modified
 811                                        (copy-structure included-slot))))
 812             (when (and (neq (dsd-type new-slot) (dsd-type included-slot))
 813                        (not (subtypep (dsd-type included-slot)
 814                                       (dsd-type new-slot)))
 815                        (dsd-safe-p included-slot))
 816               (setf (dsd-safe-p new-slot) nil)
 817               ;; XXX: notify?
 818               )))))))
 819 \f
 820 ;;;; various helper functions for setting up DEFSTRUCTs
 821
 822 ;;; This function is called at macroexpand time to compute the INHERITS
 823 ;;; vector for a structure type definition.
 824 (defun inherits-for-structure (info)
 825   (declare (type defstruct-description info))
 826   (let* ((include (dd-include info))
 827          (superclass-opt (dd-alternate-metaclass info))
 828          (super
 829           (if include
 830               (compiler-layout-or-lose (first include))
 831               (classoid-layout (find-classoid
 832                                 (or (first superclass-opt)
 833                                     'structure-object))))))
 834     (if (eq (dd-name info) 'ansi-stream)
 835         ;; a hack to add the CL:STREAM class as a mixin for ANSI-STREAMs
 836         (concatenate 'simple-vector
 837                      (layout-inherits super)
 838                      (vector super
 839                              (classoid-layout (find-classoid 'stream))))
 840         (concatenate 'simple-vector
 841                      (layout-inherits super)
 842                      (vector super)))))
 843
 844 ;;; Do miscellaneous (LOAD EVAL) time actions for the structure
 845 ;;; described by DD. Create the class and LAYOUT, checking for
 846 ;;; incompatible redefinition. Define those functions which are
 847 ;;; sufficiently stereotyped that we can implement them as standard
 848 ;;; closures.
 849 (defun %defstruct (dd inherits)
 850   (declare (type defstruct-description dd))
 851
 852   ;; We set up LAYOUTs even in the cross-compilation host.
 853   (multiple-value-bind (classoid layout old-layout)
 854       (ensure-structure-class dd inherits "current" "new")
 855     (cond ((not old-layout)
 856            (unless (eq (classoid-layout classoid) layout)
 857              (register-layout layout)))
 858           (t
 859            (let ((old-dd (layout-info old-layout)))
 860              (when (defstruct-description-p old-dd)
 861                (dolist (slot (dd-slots old-dd))
 862                  (fmakunbound (dsd-accessor-name slot))
 863                  (unless (dsd-read-only slot)
 864                    (fmakunbound `(setf ,(dsd-accessor-name slot)))))))
 865            (%redefine-defstruct classoid old-layout layout)
 866            (setq layout (classoid-layout classoid))))
 867     (setf (find-classoid (dd-name dd)) classoid)
 868
 869     ;; Various other operations only make sense on the target SBCL.
 870     #-sb-xc-host
 871     (%target-defstruct dd layout))
 872
 873   (values))
 874 \f
 875 ;;; Return a form describing the writable place used for this slot
 876 ;;; in the instance named INSTANCE-NAME.
 877 (defun %accessor-place-form (dd dsd instance-name)
 878   (let (;; the operator that we'll use to access a typed slot or, in
 879         ;; the case of a raw slot, to read the vector of raw slots
 880         (ref (ecase (dd-type dd)
 881                (structure '%instance-ref)
 882                (list 'nth-but-with-sane-arg-order)
 883                (vector 'aref)))
 884         (raw-type (dsd-raw-type dsd)))
 885     (if (eq raw-type t) ; if not raw slot
 886         `(,ref ,instance-name ,(dsd-index dsd))
 887         (let* ((raw-slot-data (find raw-type *raw-slot-data-list*
 888                                     :key #'raw-slot-data-raw-type
 889                                     :test #'equal))
 890                (raw-slot-accessor (raw-slot-data-accessor-name raw-slot-data))
 891                (raw-n-words (raw-slot-data-n-words raw-slot-data)))
 892           (multiple-value-bind (scaled-dsd-index misalignment)
 893               (floor (dsd-index dsd) raw-n-words)
 894             (aver (zerop misalignment))
 895             (let* ((raw-vector-bare-form
 896                     `(,ref ,instance-name ,(dd-raw-index dd)))
 897                    (raw-vector-form
 898                     (if (eq raw-type 'unsigned-byte)
 899                         (progn
 900                           (aver (= raw-n-words 1))
 901                           (aver (eq raw-slot-accessor 'aref))
 902                           ;; FIXME: when the 64-bit world rolls
 903                           ;; around, this will need to be reviewed,
 904                           ;; along with the whole RAW-SLOT thing.
 905                           `(truly-the (simple-array (unsigned-byte 32) (*))
 906                                       ,raw-vector-bare-form))
 907                         raw-vector-bare-form)))
 908               `(,raw-slot-accessor ,raw-vector-form ,scaled-dsd-index)))))))
 909
 910 ;;; Return source transforms for the reader and writer functions of
 911 ;;; the slot described by DSD. They should be inline expanded, but
 912 ;;; source transforms work faster.
 913 (defun slot-accessor-transforms (dd dsd)
 914   (let ((accessor-place-form (%accessor-place-form dd dsd
 915                                                    `(the ,(dd-name dd) instance)))
 916         (dsd-type (dsd-type dsd))
 917         (value-the (if (dsd-safe-p dsd) 'truly-the 'the)))
 918     (values (sb!c:source-transform-lambda (instance)
 919               `(,value-the ,dsd-type ,(subst instance 'instance
 920                                              accessor-place-form)))
 921             (sb!c:source-transform-lambda (new-value instance)
 922                (destructuring-bind (accessor-name &rest accessor-args)
 923                    accessor-place-form
 924                  `(,(info :setf :inverse accessor-name)
 925                     ,@(subst instance 'instance accessor-args)
 926                     (the ,dsd-type ,new-value)))))))
 927
 928 ;;; Return a LAMBDA form which can be used to set a slot.
 929 (defun slot-setter-lambda-form (dd dsd)
 930   `(lambda (new-value instance)
 931      ,(funcall (nth-value 1 (slot-accessor-transforms dd dsd))
 932                '(dummy new-value instance))))
 933
 934 ;;; core compile-time setup of any class with a LAYOUT, used even by
 935 ;;; !DEFSTRUCT-WITH-ALTERNATE-METACLASS weirdosities
 936 (defun %compiler-set-up-layout (dd
 937                                 &optional
 938                                 ;; Several special cases (STRUCTURE-OBJECT
 939                                 ;; itself, and structures with alternate
 940                                 ;; metaclasses) call this function directly,
 941                                 ;; and they're all at the base of the
 942                                 ;; instance class structure, so this is
 943                                 ;; a handy default.
 944                                 (inherits (vector (find-layout t)
 945                                                   (find-layout 'instance))))
 946
 947   (multiple-value-bind (classoid layout old-layout)
 948       (multiple-value-bind (clayout clayout-p)
 949           (info :type :compiler-layout (dd-name dd))
 950         (ensure-structure-class dd
 951                                 inherits
 952                                 (if clayout-p "previously compiled" "current")
 953                                 "compiled"
 954                                 :compiler-layout clayout))
 955     (cond (old-layout
 956            (undefine-structure (layout-classoid old-layout))
 957            (when (and (classoid-subclasses classoid)
 958                       (not (eq layout old-layout)))
 959              (collect ((subs))
 960                       (dohash (classoid layout (classoid-subclasses classoid))
 961                         (declare (ignore layout))
 962                         (undefine-structure classoid)
 963                         (subs (classoid-proper-name classoid)))
 964                       (when (subs)
 965                         (warn "removing old subclasses of ~S:~%  ~S"
 966                               (classoid-name classoid)
 967                               (subs))))))
 968           (t
 969            (unless (eq (classoid-layout classoid) layout)
 970              (register-layout layout :invalidate nil))
 971            (setf (find-classoid (dd-name dd)) classoid)))
 972
 973     ;; At this point the class should be set up in the INFO database.
 974     ;; But the logic that enforces this is a little tangled and
 975     ;; scattered, so it's not obvious, so let's check.
 976     (aver (find-classoid (dd-name dd) nil))
 977
 978     (setf (info :type :compiler-layout (dd-name dd)) layout))
 979
 980   (values))
 981
 982 ;;; Do (COMPILE LOAD EVAL)-time actions for the normal (not
 983 ;;; ALTERNATE-LAYOUT) DEFSTRUCT described by DD.
 984 (defun %compiler-defstruct (dd inherits)
 985   (declare (type defstruct-description dd))
 986
 987   (%compiler-set-up-layout dd inherits)
 988
 989   (let* ((dtype (dd-declarable-type dd)))
 990
 991     (let ((copier-name (dd-copier-name dd)))
 992       (when copier-name
 993         (sb!xc:proclaim `(ftype (sfunction (,dtype) ,dtype) ,copier-name))))
 994
 995     (let ((predicate-name (dd-predicate-name dd)))
 996       (when predicate-name
 997         (sb!xc:proclaim `(ftype (sfunction (t) boolean) ,predicate-name))
 998         ;; Provide inline expansion (or not).
 999         (ecase (dd-type dd)
1000           ((structure funcallable-structure)
1001            ;; Let the predicate be inlined.
1002            (setf (info :function :inline-expansion-designator predicate-name)
1003                  (lambda ()
1004                    `(lambda (x)
1005                       ;; This dead simple definition works because the
1006                       ;; type system knows how to generate inline type
1007                       ;; tests for instances.
1008                       (typep x ',(dd-name dd))))
1009                  (info :function :inlinep predicate-name)
1010                  :inline))
1011           ((list vector)
1012            ;; Just punt. We could provide inline expansions for :TYPE
1013            ;; LIST and :TYPE VECTOR predicates too, but it'd be a
1014            ;; little messier and we don't bother. (Does anyway use
1015            ;; typed DEFSTRUCTs at all, let alone for high
1016            ;; performance?)
1017            ))))
1018
1019     (dolist (dsd (dd-slots dd))
1020       (let* ((accessor-name (dsd-accessor-name dsd))
1021              (dsd-type (dsd-type dsd)))
1022         (when accessor-name
1023           (let ((inherited (accessor-inherited-data accessor-name dd)))
1024             (cond
1025               ((not inherited)
1026                (multiple-value-bind (reader-designator writer-designator)
1027                    (slot-accessor-transforms dd dsd)
1028                  (sb!xc:proclaim `(ftype (sfunction (,dtype) ,dsd-type)
1029                                    ,accessor-name))
1030                  (setf (info :function :source-transform accessor-name)
1031                        reader-designator)
1032                  (unless (dsd-read-only dsd)
1033                    (let ((setf-accessor-name `(setf ,accessor-name)))
1034                      (sb!xc:proclaim
1035                       `(ftype (sfunction (,dsd-type ,dtype) ,dsd-type)
1036                         ,setf-accessor-name))
1037                      (setf (info :function :source-transform setf-accessor-name)
1038                            writer-designator)))))
1039               ((not (= (cdr inherited) (dsd-index dsd)))
1040                (style-warn "~@<Non-overwritten accessor ~S does not access ~
1041                             slot with name ~S (accessing an inherited slot ~
1042                             instead).~:@>"
1043                            accessor-name
1044                            (dsd-name dsd)))))))))
1045   (values))
1046 \f
1047 ;;;; redefinition stuff
1048
1049 ;;; Compare the slots of OLD and NEW, returning 3 lists of slot names:
1050 ;;;   1. Slots which have moved,
1051 ;;;   2. Slots whose type has changed,
1052 ;;;   3. Deleted slots.
1053 (defun compare-slots (old new)
1054   (let* ((oslots (dd-slots old))
1055          (nslots (dd-slots new))
1056          (onames (mapcar #'dsd-name oslots))
1057          (nnames (mapcar #'dsd-name nslots)))
1058     (collect ((moved)
1059               (retyped))
1060       (dolist (name (intersection onames nnames))
1061         (let ((os (find name oslots :key #'dsd-name :test #'string=))
1062               (ns (find name nslots :key #'dsd-name :test #'string=)))
1063           (unless (sb!xc:subtypep (dsd-type ns) (dsd-type os))
1064             (retyped name))
1065           (unless (and (= (dsd-index os) (dsd-index ns))
1066                        (eq (dsd-raw-type os) (dsd-raw-type ns)))
1067             (moved name))))
1068       (values (moved)
1069               (retyped)
1070               (set-difference onames nnames :test #'string=)))))
1071
1072 ;;; If we are redefining a structure with different slots than in the
1073 ;;; currently loaded version, give a warning and return true.
1074 (defun redefine-structure-warning (classoid old new)
1075   (declare (type defstruct-description old new)
1076            (type classoid classoid)
1077            (ignore classoid))
1078   (let ((name (dd-name new)))
1079     (multiple-value-bind (moved retyped deleted) (compare-slots old new)
1080       (when (or moved retyped deleted)
1081         (warn
1082          "incompatibly redefining slots of structure class ~S~@
1083           Make sure any uses of affected accessors are recompiled:~@
1084           ~@[  These slots were moved to new positions:~%    ~S~%~]~
1085           ~@[  These slots have new incompatible types:~%    ~S~%~]~
1086           ~@[  These slots were deleted:~%    ~S~%~]"
1087          name moved retyped deleted)
1088         t))))
1089
1090 ;;; This function is called when we are incompatibly redefining a
1091 ;;; structure CLASS to have the specified NEW-LAYOUT. We signal an
1092 ;;; error with some proceed options and return the layout that should
1093 ;;; be used.
1094 (defun %redefine-defstruct (classoid old-layout new-layout)
1095   (declare (type classoid classoid)
1096            (type layout old-layout new-layout))
1097   (let ((name (classoid-proper-name classoid)))
1098     (restart-case
1099         (error "~@<attempt to redefine the ~S class ~S incompatibly with the current definition~:@>"
1100                'structure-object
1101                name)
1102       (continue ()
1103        :report (lambda (s)
1104                  (format s
1105                          "~@<Use the new definition of ~S, invalidating ~
1106                           already-loaded code and instances.~@:>"
1107                          name))
1108        (register-layout new-layout))
1109       (recklessly-continue ()
1110        :report (lambda (s)
1111                  (format s
1112                          "~@<Use the new definition of ~S as if it were ~
1113                           compatible, allowing old accessors to use new ~
1114                           instances and allowing new accessors to use old ~
1115                           instances.~@:>"
1116                          name))
1117        ;; classic CMU CL warning: "Any old ~S instances will be in a bad way.
1118        ;; I hope you know what you're doing..."
1119        (register-layout new-layout
1120                         :invalidate nil
1121                         :destruct-layout old-layout))
1122       (clobber-it ()
1123        ;; FIXME: deprecated 2002-10-16, and since it's only interactive
1124        ;; hackery instead of a supported feature, can probably be deleted
1125        ;; in early 2003
1126        :report "(deprecated synonym for RECKLESSLY-CONTINUE)"
1127        (register-layout new-layout
1128                         :invalidate nil
1129                         :destruct-layout old-layout))))
1130   (values))
1131
1132 ;;; This is called when we are about to define a structure class. It
1133 ;;; returns a (possibly new) class object and the layout which should
1134 ;;; be used for the new definition (may be the current layout, and
1135 ;;; also might be an uninstalled forward referenced layout.) The third
1136 ;;; value is true if this is an incompatible redefinition, in which
1137 ;;; case it is the old layout.
1138 (defun ensure-structure-class (info inherits old-context new-context
1139                                     &key compiler-layout)
1140   (multiple-value-bind (class old-layout)
1141       (destructuring-bind
1142           (&optional
1143            name
1144            (class 'structure-classoid)
1145            (constructor 'make-structure-classoid))
1146           (dd-alternate-metaclass info)
1147         (declare (ignore name))
1148         (insured-find-classoid (dd-name info)
1149                                (if (eq class 'structure-classoid)
1150                                    (lambda (x)
1151                                      (sb!xc:typep x 'structure-classoid))
1152                                    (lambda (x)
1153                                      (sb!xc:typep x (find-classoid class))))
1154                                (fdefinition constructor)))
1155     (setf (classoid-direct-superclasses class)
1156           (if (eq (dd-name info) 'ansi-stream)
1157               ;; a hack to add CL:STREAM as a superclass mixin to ANSI-STREAMs
1158               (list (layout-classoid (svref inherits (1- (length inherits))))
1159                     (layout-classoid (svref inherits (- (length inherits) 2))))
1160               (list (layout-classoid
1161                      (svref inherits (1- (length inherits)))))))
1162     (let ((new-layout (make-layout :classoid class
1163                                    :inherits inherits
1164                                    :depthoid (length inherits)
1165                                    :length (dd-length info)
1166                                    :info info))
1167           (old-layout (or compiler-layout old-layout)))
1168       (cond
1169        ((not old-layout)
1170         (values class new-layout nil))
1171        (;; This clause corresponds to an assertion in REDEFINE-LAYOUT-WARNING
1172         ;; of classic CMU CL. I moved it out to here because it was only
1173         ;; exercised in this code path anyway. -- WHN 19990510
1174         (not (eq (layout-classoid new-layout) (layout-classoid old-layout)))
1175         (error "shouldn't happen: weird state of OLD-LAYOUT?"))
1176        ((not *type-system-initialized*)
1177         (setf (layout-info old-layout) info)
1178         (values class old-layout nil))
1179        ((redefine-layout-warning old-context
1180                                  old-layout
1181                                  new-context
1182                                  (layout-length new-layout)
1183                                  (layout-inherits new-layout)
1184                                  (layout-depthoid new-layout))
1185         (values class new-layout old-layout))
1186        (t
1187         (let ((old-info (layout-info old-layout)))
1188           (typecase old-info
1189             ((or defstruct-description)
1190              (cond ((redefine-structure-warning class old-info info)
1191                     (values class new-layout old-layout))
1192                    (t
1193                     (setf (layout-info old-layout) info)
1194                     (values class old-layout nil))))
1195             (null
1196              (setf (layout-info old-layout) info)
1197              (values class old-layout nil))
1198             (t
1199              (error "shouldn't happen! strange thing in LAYOUT-INFO:~%  ~S"
1200                     old-layout)
1201              (values class new-layout old-layout)))))))))
1202
1203 ;;; Blow away all the compiler info for the structure CLASS. Iterate
1204 ;;; over this type, clearing the compiler structure type info, and
1205 ;;; undefining all the associated functions.
1206 (defun undefine-structure (class)
1207   (let ((info (layout-info (classoid-layout class))))
1208     (when (defstruct-description-p info)
1209       (let ((type (dd-name info)))
1210         (remhash type *typecheckfuns*)
1211         (setf (info :type :compiler-layout type) nil)
1212         (undefine-fun-name (dd-copier-name info))
1213         (undefine-fun-name (dd-predicate-name info))
1214         (dolist (slot (dd-slots info))
1215           (let ((fun (dsd-accessor-name slot)))
1216             (unless (accessor-inherited-data fun info)
1217               (undefine-fun-name fun)
1218               (unless (dsd-read-only slot)
1219                 (undefine-fun-name `(setf ,fun)))))))
1220       ;; Clear out the SPECIFIER-TYPE cache so that subsequent
1221       ;; references are unknown types.
1222       (values-specifier-type-cache-clear)))
1223   (values))
1224 \f
1225 ;;; Return a list of pairs (name . index). Used for :TYPE'd
1226 ;;; constructors to find all the names that we have to splice in &
1227 ;;; where. Note that these types don't have a layout, so we can't look
1228 ;;; at LAYOUT-INHERITS.
1229 (defun find-name-indices (defstruct)
1230   (collect ((res))
1231     (let ((infos ()))
1232       (do ((info defstruct
1233                  (typed-structure-info-or-lose (first (dd-include info)))))
1234           ((not (dd-include info))
1235            (push info infos))
1236         (push info infos))
1237
1238       (let ((i 0))
1239         (dolist (info infos)
1240           (incf i (or (dd-offset info) 0))
1241           (when (dd-named info)
1242             (res (cons (dd-name info) i)))
1243           (setq i (dd-length info)))))
1244
1245     (res)))
1246 \f
1247 ;;; These functions are called to actually make a constructor after we
1248 ;;; have processed the arglist. The correct variant (according to the
1249 ;;; DD-TYPE) should be called. The function is defined with the
1250 ;;; specified name and arglist. VARS and TYPES are used for argument
1251 ;;; type declarations. VALUES are the values for the slots (in order.)
1252 ;;;
1253 ;;; This is split three ways because:
1254 ;;;   * LIST & VECTOR structures need "name" symbols stuck in at
1255 ;;;     various weird places, whereas STRUCTURE structures have
1256 ;;;     a LAYOUT slot.
1257 ;;;   * We really want to use LIST to make list structures, instead of
1258 ;;;     MAKE-LIST/(SETF ELT). (We can't in general use VECTOR in an
1259 ;;;     analogous way, since VECTOR makes a SIMPLE-VECTOR and vector-typed
1260 ;;;     structures can have arbitrary subtypes of VECTOR, not necessarily
1261 ;;;     SIMPLE-VECTOR.)
1262 ;;;   * STRUCTURE structures can have raw slots that must also be
1263 ;;;     allocated and indirectly referenced.
1264 (defun create-vector-constructor (dd cons-name arglist vars types values)
1265   (let ((temp (gensym))
1266         (etype (dd-element-type dd)))
1267     `(defun ,cons-name ,arglist
1268        (declare ,@(mapcar (lambda (var type) `(type (and ,type ,etype) ,var))
1269                           vars types))
1270        (let ((,temp (make-array ,(dd-length dd)
1271                                 :element-type ',(dd-element-type dd))))
1272          ,@(mapcar (lambda (x)
1273                      `(setf (aref ,temp ,(cdr x))  ',(car x)))
1274                    (find-name-indices dd))
1275          ,@(mapcar (lambda (dsd value)
1276                      (unless (eq value '.do-not-initialize-slot.)
1277                          `(setf (aref ,temp ,(dsd-index dsd)) ,value)))
1278                    (dd-slots dd) values)
1279          ,temp))))
1280 (defun create-list-constructor (dd cons-name arglist vars types values)
1281   (let ((vals (make-list (dd-length dd) :initial-element nil)))
1282     (dolist (x (find-name-indices dd))
1283       (setf (elt vals (cdr x)) `',(car x)))
1284     (loop for dsd in (dd-slots dd) and val in values do
1285       (setf (elt vals (dsd-index dsd))
1286             (if (eq val '.do-not-initialize-slot.) 0 val)))
1287
1288     `(defun ,cons-name ,arglist
1289        (declare ,@(mapcar (lambda (var type) `(type ,type ,var)) vars types))
1290        (list ,@vals))))
1291 (defun create-structure-constructor (dd cons-name arglist vars types values)
1292   (let* ((instance (gensym "INSTANCE"))
1293          (raw-index (dd-raw-index dd)))
1294     `(defun ,cons-name ,arglist
1295        (declare ,@(mapcar (lambda (var type) `(type ,type ,var))
1296                           vars types))
1297        (let ((,instance (truly-the ,(dd-name dd)
1298                           (%make-instance-with-layout
1299                            (%delayed-get-compiler-layout ,(dd-name dd))))))
1300          ,@(when raw-index
1301              `((setf (%instance-ref ,instance ,raw-index)
1302                      (make-array ,(dd-raw-length dd)
1303                                  :element-type '(unsigned-byte 32)))))
1304          ,@(mapcar (lambda (dsd value)
1305                      ;; (Note that we can't in general use the
1306                      ;; ordinary named slot setter function here
1307                      ;; because the slot might be :READ-ONLY, so we
1308                      ;; whip up new LAMBDA representations of slot
1309                      ;; setters for the occasion.)
1310                      (unless (eq value '.do-not-initialize-slot.)
1311                        `(,(slot-setter-lambda-form dd dsd) ,value ,instance)))
1312                    (dd-slots dd)
1313                    values)
1314          ,instance))))
1315
1316 ;;; Create a default (non-BOA) keyword constructor.
1317 (defun create-keyword-constructor (defstruct creator)
1318   (declare (type function creator))
1319   (collect ((arglist (list '&key))
1320             (types)
1321             (vals))
1322     (dolist (slot (dd-slots defstruct))
1323       (let ((dum (gensym))
1324             (name (dsd-name slot)))
1325         (arglist `((,(keywordicate name) ,dum) ,(dsd-default slot)))
1326         (types (dsd-type slot))
1327         (vals dum)))
1328     (funcall creator
1329              defstruct (dd-default-constructor defstruct)
1330              (arglist) (vals) (types) (vals))))
1331
1332 ;;; Given a structure and a BOA constructor spec, call CREATOR with
1333 ;;; the appropriate args to make a constructor.
1334 (defun create-boa-constructor (defstruct boa creator)
1335   (declare (type function creator))
1336   (multiple-value-bind (req opt restp rest keyp keys allowp auxp aux)
1337       (parse-lambda-list (second boa))
1338     (collect ((arglist)
1339               (vars)
1340               (types)
1341               (skipped-vars))
1342       (labels ((get-slot (name)
1343                  (let ((res (find name (dd-slots defstruct)
1344                                   :test #'string=
1345                                   :key #'dsd-name)))
1346                    (if res
1347                        (values (dsd-type res) (dsd-default res))
1348                        (values t nil))))
1349                (do-default (arg)
1350                  (multiple-value-bind (type default) (get-slot arg)
1351                    (arglist `(,arg ,default))
1352                    (vars arg)
1353                    (types type))))
1354         (dolist (arg req)
1355           (arglist arg)
1356           (vars arg)
1357           (types (get-slot arg)))
1358
1359         (when opt
1360           (arglist '&optional)
1361           (dolist (arg opt)
1362             (cond ((consp arg)
1363                    (destructuring-bind
1364                          ;; FIXME: this shares some logic (though not
1365                          ;; code) with the &key case below (and it
1366                          ;; looks confusing) -- factor out the logic
1367                          ;; if possible. - CSR, 2002-04-19
1368                          (name
1369                           &optional
1370                           (def (nth-value 1 (get-slot name)))
1371                           (supplied-test nil supplied-test-p))
1372                        arg
1373                      (arglist `(,name ,def ,@(if supplied-test-p `(,supplied-test) nil)))
1374                      (vars name)
1375                      (types (get-slot name))))
1376                   (t
1377                    (do-default arg)))))
1378
1379         (when restp
1380           (arglist '&rest rest)
1381           (vars rest)
1382           (types 'list))
1383
1384         (when keyp
1385           (arglist '&key)
1386           (dolist (key keys)
1387             (if (consp key)
1388                 (destructuring-bind (wot
1389                                      &optional
1390                                      (def nil def-p)
1391                                      (supplied-test nil supplied-test-p))
1392                     key
1393                   (let ((name (if (consp wot)
1394                                   (destructuring-bind (key var) wot
1395                                     (declare (ignore key))
1396                                     var)
1397                                   wot)))
1398                     (multiple-value-bind (type slot-def)
1399                         (get-slot name)
1400                       (arglist `(,wot ,(if def-p def slot-def)
1401                                  ,@(if supplied-test-p `(,supplied-test) nil)))
1402                       (vars name)
1403                       (types type))))
1404                 (do-default key))))
1405
1406         (when allowp (arglist '&allow-other-keys))
1407
1408         (when auxp
1409           (arglist '&aux)
1410           (dolist (arg aux)
1411             (arglist arg)
1412             (if (proper-list-of-length-p arg 2)
1413               (let ((var (first arg)))
1414                 (vars var)
1415                 (types (get-slot var)))
1416               (skipped-vars (if (consp arg) (first arg) arg))))))
1417
1418       (funcall creator defstruct (first boa)
1419                (arglist) (vars) (types)
1420                (loop for slot in (dd-slots defstruct)
1421                      for name = (dsd-name slot)
1422                      collect (cond ((find name (skipped-vars) :test #'string=)
1423                                     (setf (dsd-safe-p slot) nil)
1424                                     '.do-not-initialize-slot.)
1425                                    ((or (find (dsd-name slot) (vars) :test #'string=)
1426                                         (dsd-default slot)))))))))
1427
1428 ;;; Grovel the constructor options, and decide what constructors (if
1429 ;;; any) to create.
1430 (defun constructor-definitions (defstruct)
1431   (let ((no-constructors nil)
1432         (boas ())
1433         (defaults ())
1434         (creator (ecase (dd-type defstruct)
1435                    (structure #'create-structure-constructor)
1436                    (vector #'create-vector-constructor)
1437                    (list #'create-list-constructor))))
1438     (dolist (constructor (dd-constructors defstruct))
1439       (destructuring-bind (name &optional (boa-ll nil boa-p)) constructor
1440         (declare (ignore boa-ll))
1441         (cond ((not name) (setq no-constructors t))
1442               (boa-p (push constructor boas))
1443               (t (push name defaults)))))
1444
1445     (when no-constructors
1446       (when (or defaults boas)
1447         (error "(:CONSTRUCTOR NIL) combined with other :CONSTRUCTORs"))
1448       (return-from constructor-definitions ()))
1449
1450     (unless (or defaults boas)
1451       (push (symbolicate "MAKE-" (dd-name defstruct)) defaults))
1452
1453     (collect ((res) (names))
1454       (when defaults
1455         (let ((cname (first defaults)))
1456           (setf (dd-default-constructor defstruct) cname)
1457           (res (create-keyword-constructor defstruct creator))
1458           (names cname)
1459           (dolist (other-name (rest defaults))
1460             (res `(setf (fdefinition ',other-name) (fdefinition ',cname)))
1461             (names other-name))))
1462
1463       (dolist (boa boas)
1464         (res (create-boa-constructor defstruct boa creator))
1465         (names (first boa)))
1466
1467       (res `(declaim (ftype
1468                       (sfunction *
1469                                  ,(if (eq (dd-type defstruct) 'structure)
1470                                       (dd-name defstruct)
1471                                       '*))
1472                       ,@(names))))
1473
1474       (res))))
1475 \f
1476 ;;;; instances with ALTERNATE-METACLASS
1477 ;;;;
1478 ;;;; The CMU CL support for structures with ALTERNATE-METACLASS was a
1479 ;;;; fairly general extension embedded in the main DEFSTRUCT code, and
1480 ;;;; the result was an fairly impressive mess as ALTERNATE-METACLASS
1481 ;;;; extension mixed with ANSI CL generality (e.g. :TYPE and :INCLUDE)
1482 ;;;; and CMU CL implementation hairiness (esp. raw slots). This SBCL
1483 ;;;; version is much less ambitious, noticing that ALTERNATE-METACLASS
1484 ;;;; is only used to implement CONDITION, STANDARD-INSTANCE, and
1485 ;;;; GENERIC-FUNCTION, and defining a simple specialized
1486 ;;;; separate-from-DEFSTRUCT macro to provide only enough
1487 ;;;; functionality to support those.
1488 ;;;;
1489 ;;;; KLUDGE: The defining macro here is so specialized that it's ugly
1490 ;;;; in its own way. It also violates once-and-only-once by knowing
1491 ;;;; much about structures and layouts that is already known by the
1492 ;;;; main DEFSTRUCT macro. Hopefully it will go away presently
1493 ;;;; (perhaps when CL:CLASS and SB-PCL:CLASS meet) as per FIXME below.
1494 ;;;; -- WHN 2001-10-28
1495 ;;;;
1496 ;;;; FIXME: There seems to be no good reason to shoehorn CONDITION,
1497 ;;;; STANDARD-INSTANCE, and GENERIC-FUNCTION into mutated structures
1498 ;;;; instead of just implementing them as primitive objects. (This
1499 ;;;; reduced-functionality macro seems pretty close to the
1500 ;;;; functionality of DEFINE-PRIMITIVE-OBJECT..)
1501
1502 (defun make-dd-with-alternate-metaclass (&key (class-name (missing-arg))
1503                                               (superclass-name (missing-arg))
1504                                               (metaclass-name (missing-arg))
1505                                               (dd-type (missing-arg))
1506                                               metaclass-constructor
1507                                               slot-names)
1508   (let* ((dd (make-defstruct-description class-name))
1509          (conc-name (concatenate 'string (symbol-name class-name) "-"))
1510          (dd-slots (let ((reversed-result nil)
1511                          ;; The index starts at 1 for ordinary
1512                          ;; named slots because slot 0 is
1513                          ;; magical, used for LAYOUT in
1514                          ;; CONDITIONs or for something (?) in
1515                          ;; funcallable instances.
1516                          (index 1))
1517                      (dolist (slot-name slot-names)
1518                        (push (make-defstruct-slot-description
1519                               :name slot-name
1520                               :index index
1521                               :accessor-name (symbolicate conc-name slot-name))
1522                              reversed-result)
1523                        (incf index))
1524                      (nreverse reversed-result))))
1525     (setf (dd-alternate-metaclass dd) (list superclass-name
1526                                             metaclass-name
1527                                             metaclass-constructor)
1528           (dd-slots dd) dd-slots
1529           (dd-length dd) (1+ (length slot-names))
1530           (dd-type dd) dd-type)
1531     dd))
1532
1533 (sb!xc:defmacro !defstruct-with-alternate-metaclass
1534     (class-name &key
1535                 (slot-names (missing-arg))
1536                 (boa-constructor (missing-arg))
1537                 (superclass-name (missing-arg))
1538                 (metaclass-name (missing-arg))
1539                 (metaclass-constructor (missing-arg))
1540                 (dd-type (missing-arg))
1541                 predicate
1542                 (runtime-type-checks-p t))
1543
1544   (declare (type (and list (not null)) slot-names))
1545   (declare (type (and symbol (not null))
1546                  boa-constructor
1547                  superclass-name
1548                  metaclass-name
1549                  metaclass-constructor))
1550   (declare (type symbol predicate))
1551   (declare (type (member structure funcallable-structure) dd-type))
1552
1553   (let* ((dd (make-dd-with-alternate-metaclass
1554               :class-name class-name
1555               :slot-names slot-names
1556               :superclass-name superclass-name
1557               :metaclass-name metaclass-name
1558               :metaclass-constructor metaclass-constructor
1559               :dd-type dd-type))
1560          (dd-slots (dd-slots dd))
1561          (dd-length (1+ (length slot-names)))
1562          (object-gensym (gensym "OBJECT"))
1563          (new-value-gensym (gensym "NEW-VALUE-"))
1564          (delayed-layout-form `(%delayed-get-compiler-layout ,class-name)))
1565     (multiple-value-bind (raw-maker-form raw-reffer-operator)
1566         (ecase dd-type
1567           (structure
1568            (values `(let ((,object-gensym (%make-instance ,dd-length)))
1569                       (setf (%instance-layout ,object-gensym)
1570                             ,delayed-layout-form)
1571                       ,object-gensym)
1572                    '%instance-ref))
1573           (funcallable-structure
1574            (values `(%make-funcallable-instance ,dd-length
1575                                                 ,delayed-layout-form)
1576                    '%funcallable-instance-info)))
1577       `(progn
1578
1579          (eval-when (:compile-toplevel :load-toplevel :execute)
1580            (%compiler-set-up-layout ',dd))
1581
1582          ;; slot readers and writers
1583          (declaim (inline ,@(mapcar #'dsd-accessor-name dd-slots)))
1584          ,@(mapcar (lambda (dsd)
1585                      `(defun ,(dsd-accessor-name dsd) (,object-gensym)
1586                         ,@(when runtime-type-checks-p
1587                             `((declare (type ,class-name ,object-gensym))))
1588                         (,raw-reffer-operator ,object-gensym
1589                                               ,(dsd-index dsd))))
1590                    dd-slots)
1591          (declaim (inline ,@(mapcar (lambda (dsd)
1592                                       `(setf ,(dsd-accessor-name dsd)))
1593                                     dd-slots)))
1594          ,@(mapcar (lambda (dsd)
1595                      `(defun (setf ,(dsd-accessor-name dsd)) (,new-value-gensym
1596                                                               ,object-gensym)
1597                         ,@(when runtime-type-checks-p
1598                             `((declare (type ,class-name ,object-gensym))))
1599                         (setf (,raw-reffer-operator ,object-gensym
1600                                                     ,(dsd-index dsd))
1601                               ,new-value-gensym)))
1602                    dd-slots)
1603
1604          ;; constructor
1605          (defun ,boa-constructor ,slot-names
1606            (let ((,object-gensym ,raw-maker-form))
1607              ,@(mapcar (lambda (slot-name)
1608                          (let ((dsd (find (symbol-name slot-name) dd-slots
1609                                           :key (lambda (x)
1610                                                  (symbol-name (dsd-name x)))
1611                                           :test #'string=)))
1612                            ;; KLUDGE: bug 117 bogowarning.  Neither
1613                            ;; DECLAREing the type nor TRULY-THE cut
1614                            ;; the mustard -- it still gives warnings.
1615                            (enforce-type dsd defstruct-slot-description)
1616                            `(setf (,(dsd-accessor-name dsd) ,object-gensym)
1617                                   ,slot-name)))
1618                        slot-names)
1619              ,object-gensym))
1620
1621          ;; predicate
1622          ,@(when predicate
1623              ;; Just delegate to the compiler's type optimization
1624              ;; code, which knows how to generate inline type tests
1625              ;; for the whole CMU CL INSTANCE menagerie.
1626              `(defun ,predicate (,object-gensym)
1627                 (typep ,object-gensym ',class-name)))))))
1628 \f
1629 ;;;; finalizing bootstrapping
1630
1631 ;;; Set up DD and LAYOUT for STRUCTURE-OBJECT class itself.
1632 ;;;
1633 ;;; Ordinary structure classes effectively :INCLUDE STRUCTURE-OBJECT
1634 ;;; when they have no explicit :INCLUDEs, so (1) it needs to be set up
1635 ;;; before we can define ordinary structure classes, and (2) it's
1636 ;;; special enough (and simple enough) that we just build it by hand
1637 ;;; instead of trying to generalize the ordinary DEFSTRUCT code.
1638 (defun !set-up-structure-object-class ()
1639   (let ((dd (make-defstruct-description 'structure-object)))
1640     (setf
1641      ;; Note: This has an ALTERNATE-METACLASS only because of blind
1642      ;; clueless imitation of the CMU CL code -- dunno if or why it's
1643      ;; needed. -- WHN
1644      (dd-alternate-metaclass dd) '(instance)
1645      (dd-slots dd) nil
1646      (dd-length dd) 1
1647      (dd-type dd) 'structure)
1648     (%compiler-set-up-layout dd)))
1649 (!set-up-structure-object-class)
1650
1651 ;;; early structure predeclarations: Set up DD and LAYOUT for ordinary
1652 ;;; (non-ALTERNATE-METACLASS) structures which are needed early.
1653 (dolist (args
1654          '#.(sb-cold:read-from-file
1655              "src/code/early-defstruct-args.lisp-expr"))
1656   (let* ((dd (parse-defstruct-name-and-options-and-slot-descriptions
1657               (first args)
1658               (rest args)))
1659          (inherits (inherits-for-structure dd)))
1660     (%compiler-defstruct dd inherits)))
1661
1662 (/show0 "code/defstruct.lisp end of file")