src/code/deftypes-for-target.lisp

   1 ;;;; definitions of types for the target (output of the compiler)
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!KERNEL")
  13
  14 (/show0 "deftypes-for-target.lisp 14")
  15 \f
  16 ;;;; Now that DEFTYPE is set up, any pending requests for it can
  17 ;;;; be honored.
  18
  19 #+sb-xc-host
  20 (progn
  21   (/show "about to force delayed DEF!TYPEs")
  22   (force-delayed-def!types)
  23   (/show "done forcing delayed DEF!TYPEs"))
  24 \f
  25 ;;;; standard types
  26
  27 (sb!xc:deftype boolean () '(member t nil))
  28
  29 (sb!xc:deftype mod (n)
  30   (unless (and (integerp n) (> n 0))
  31     (error "bad modulus specified for MOD type specifier: ~S" n))
  32   `(integer 0 ,(1- n)))
  33
  34 (sb!xc:deftype signed-byte (&optional s)
  35   (cond ((eq s '*) 'integer)
  36         ((and (integerp s) (> s 1))
  37          (let ((bound (ash 1 (1- s))))
  38            `(integer ,(- bound) ,(1- bound))))
  39         (t
  40          (error "bad size specified for SIGNED-BYTE type specifier: ~S" s))))
  41
  42 (sb!xc:deftype unsigned-byte (&optional s)
  43   (cond ((eq s '*) '(integer 0))
  44         ((and (integerp s) (> s 0))
  45          `(integer 0 ,(1- (ash 1 s))))
  46         (t
  47          (error "bad size specified for UNSIGNED-BYTE type specifier: ~S" s))))
  48
  49 (sb!xc:deftype bit () '(integer 0 1))
  50
  51 (sb!xc:deftype compiled-function () 'function)
  52
  53 (sb!xc:deftype atom () '(not cons))
  54
  55 (sb!xc:deftype extended-char ()
  56   #!+sb-doc
  57   "Type of CHARACTERs that aren't BASE-CHARs."
  58   '(and character (not base-char)))
  59
  60 (sb!xc:deftype standard-char ()
  61   #!+sb-doc
  62   "Type corresponding to the characters required by the standard."
  63   '(member
  64     #\NEWLINE #\SPACE #\! #\" #\# #\$ #\% #\& #\' #\( #\) #\* #\+ #\,
  65     #\- #\. #\/ #\0 #\1 #\2 #\3 #\4 #\5 #\6 #\7 #\8 #\9 #\: #\; #\< #\=
  66     #\> #\?  #\@ #\A #\B #\C #\D #\E #\F #\G #\H #\I #\J #\K #\L #\M
  67     #\N #\O #\P #\Q #\R #\S #\T #\U #\V #\W #\X #\Y #\Z #\[ #\\ #\]
  68     #\^ #\_ #\` #\a #\b #\c #\d #\e #\f #\g #\h #\i #\j #\k #\l #\m
  69     #\n #\o #\p #\q #\r #\s #\t #\u #\v #\w #\x #\y #\z #\{
  70     #\| #\} #\~))
  71
  72 (sb!xc:deftype keyword ()
  73   ;; Defining this as (AND SYMBOL ..) lets (SUBTYPEP 'KEYWORD 'SYMBOL)=>T,T.
  74   '(and symbol (satisfies keywordp)))
  75
  76 (sb!xc:deftype eql (n) `(member ,n))
  77
  78 (sb!xc:deftype vector (&optional element-type size)
  79   `(array ,element-type (,size)))
  80
  81 (sb!xc:deftype simple-vector (&optional size)
  82   `(simple-array t (,size)))
  83
  84 (sb!xc:deftype base-string (&optional size)
  85   `(array base-char (,size)))
  86 (sb!xc:deftype simple-base-string (&optional size)
  87   `(simple-array base-char (,size)))
  88 (sb!xc:deftype string (&optional size)
  89   `(or (array character (,size))
  90        (array nil (,size))
  91        (base-string ,size)))
  92 (sb!xc:deftype simple-string (&optional size)
  93   `(or (simple-array character (,size))
  94        (simple-array nil (,size))
  95        (simple-base-string ,size)))
  96
  97 (sb!xc:deftype bit-vector (&optional size)
  98   `(array bit (,size)))
  99
 100 (sb!xc:deftype simple-bit-vector (&optional size)
 101   `(simple-array bit (,size)))
 102 \f
 103 ;;;; some private types that we use in defining the standard functions,
 104 ;;;; or implementing declarations in standard compiler transforms
 105
 106 ;;; semistandard types
 107 (sb!xc:deftype generalized-boolean () t)
 108
 109 (sb!xc:deftype format-control ()
 110   '(or string function))
 111
 112 (sb!xc:deftype restart-designator ()
 113   '(or (and symbol (not null)) restart))
 114
 115 ;;; array rank, total size...
 116 (sb!xc:deftype array-rank () `(integer 0 (,sb!xc:array-rank-limit)))
 117 (sb!xc:deftype array-total-size ()
 118   `(integer 0 (,sb!xc:array-total-size-limit)))
 119
 120 ;;; something legal in an evaluated context
 121 ;;; FIXME: could probably go away
 122 (sb!xc:deftype form () t)
 123
 124 ;;; Maclisp compatibility...
 125 ;;; FIXME: should be STRING-DESIGNATOR (the term used in the ANSI spec)
 126 (sb!xc:deftype stringable () '(or string symbol character))
 127
 128 ;;; a thing legal in places where we want the name of a file
 129 (sb!xc:deftype filename () '(or string pathname))
 130
 131 ;;; legal args to pathname functions
 132 (sb!xc:deftype pathname-designator ()
 133   '(or string pathname #+sb-xc-host stream #-sb-xc-host file-stream))
 134 (sb!xc:deftype logical-host-designator ()
 135   '(or host string))
 136
 137 ;;; a thing returned by the irrational functions. We assume that they
 138 ;;; never compute a rational result.
 139 (sb!xc:deftype irrational ()
 140   '(or float (complex float)))
 141
 142 ;;; character components
 143 (sb!xc:deftype char-code () `(integer 0 (,sb!xc:char-code-limit)))
 144
 145 ;;; a consed sequence result. If a vector, is a simple array.
 146 (sb!xc:deftype consed-sequence () '(or list (simple-array * (*))))
 147
 148 ;;; the :END arg to a sequence
 149 (sb!xc:deftype sequence-end () '(or null index))
 150
 151 ;;; the :COUNT arg to a sequence
 152 (sb!xc:deftype sequence-count ()
 153   `(or null integer))
 154
 155 ;;; a valid argument to a stream function
 156 ;;;
 157 ;;; FIXME: should probably be STREAM-DESIGNATOR, after the term
 158 ;;; used in the ANSI spec (if this is in fact exactly the same thing)
 159 (sb!xc:deftype streamlike () '(or stream (member nil t)))
 160
 161 ;;; an object suitable for input to standard functions that accept
 162 ;;; "environment objects" (of the ANSI glossary)
 163 (sb!xc:deftype lexenv-designator () '(or lexenv null))
 164
 165 ;;; a thing that can be passed to FUNCALL & friends
 166 ;;;
 167 ;;; FIXME: should be FUNCTION-DESIGNATOR?
 168 (sb!xc:deftype callable () '(or function symbol))
 169
 170 ;;; decomposing floats into integers
 171 (sb!xc:deftype single-float-exponent ()
 172   `(integer ,(- sb!vm:single-float-normal-exponent-min
 173                 sb!vm:single-float-bias
 174                 sb!vm:single-float-digits)
 175             ,(- sb!vm:single-float-normal-exponent-max
 176                 sb!vm:single-float-bias)))
 177 (sb!xc:deftype double-float-exponent ()
 178   `(integer ,(- sb!vm:double-float-normal-exponent-min
 179                 sb!vm:double-float-bias
 180                 sb!vm:double-float-digits)
 181             ,(- sb!vm:double-float-normal-exponent-max
 182                 sb!vm:double-float-bias)))
 183 (sb!xc:deftype single-float-int-exponent ()
 184   `(integer ,(- sb!vm:single-float-normal-exponent-min
 185                 sb!vm:single-float-bias
 186                 (* sb!vm:single-float-digits 2))
 187             ,(- sb!vm:single-float-normal-exponent-max
 188                 sb!vm:single-float-bias
 189                 sb!vm:single-float-digits)))
 190 (sb!xc:deftype double-float-int-exponent ()
 191   `(integer ,(- sb!vm:double-float-normal-exponent-min sb!vm:double-float-bias
 192                 (* sb!vm:double-float-digits 2))
 193             ,(- sb!vm:double-float-normal-exponent-max sb!vm:double-float-bias
 194                 sb!vm:double-float-digits)))
 195 (sb!xc:deftype single-float-significand ()
 196   `(integer 0 (,(ash 1 sb!vm:single-float-digits))))
 197 (sb!xc:deftype double-float-significand ()
 198   `(integer 0 (,(ash 1 sb!vm:double-float-digits))))
 199
 200 (/show0 "deftypes-for-target.lisp end of file")