src/code/deftypes-for-target.lisp

   1 ;;;; definitions of types for the target (output of the compiler)
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!KERNEL")
  13
  14 (/show0 "deftypes-for-target.lisp 14")
  15 \f
  16 ;;;; Now that DEFTYPE is set up, any pending requests for it can
  17 ;;;; be honored.
  18
  19 #+sb-xc-host
  20 (progn
  21   (/show "about to force delayed DEF!TYPEs")
  22   (force-delayed-def!types)
  23   (/show "done forcing delayed DEF!TYPEs"))
  24 \f
  25 ;;;; standard types
  26
  27 (sb!xc:deftype boolean () '(member t nil))
  28
  29 (sb!xc:deftype mod (n)
  30   (unless (and (integerp n) (> n 0))
  31     (error "bad modulus specified for MOD type specifier: ~S" n))
  32   `(integer 0 ,(1- n)))
  33
  34 (sb!xc:deftype signed-byte (&optional s)
  35   (cond ((eq s '*) 'integer)
  36         ((and (integerp s) (> s 0))
  37          (let ((bound (ash 1 (1- s))))
  38            `(integer ,(- bound) ,(1- bound))))
  39         (t
  40          (error "bad size specified for SIGNED-BYTE type specifier: ~S" s))))
  41
  42 (sb!xc:deftype unsigned-byte (&optional s)
  43   (cond ((eq s '*) '(integer 0))
  44         ((and (integerp s) (> s 0))
  45          `(integer 0 ,(1- (ash 1 s))))
  46         (t
  47          (error "bad size specified for UNSIGNED-BYTE type specifier: ~S" s))))
  48
  49 ;;; ANSI got UNSIGNED-BYTE wrong, prohibiting (UNSIGNED-BYTE 0).
  50 ;;; Since this is actually a substantial impediment to clarity...
  51 (sb!xc:deftype unsigned-byte* (&optional s)
  52   (cond
  53     ((eq s '*) '(integer 0))
  54     ((zerop s) '(integer 0 0))
  55     (t `(unsigned-byte ,s))))
  56
  57 (sb!xc:deftype bit () '(integer 0 1))
  58
  59 (sb!xc:deftype atom () '(not cons))
  60
  61 (sb!xc:deftype base-char ()
  62   '(character-set ((0 . #.(1- base-char-code-limit)))))
  63
  64 (sb!xc:deftype extended-char ()
  65   #!+sb-doc
  66   "Type of CHARACTERs that aren't BASE-CHARs."
  67   '(and character (not base-char)))
  68
  69 (sb!xc:deftype standard-char ()
  70   #!+sb-doc
  71   "Type corresponding to the characters required by the standard."
  72   '(member
  73     #\Newline #\Space #\! #\" #\# #\$ #\% #\& #\' #\( #\) #\* #\+ #\,
  74     #\- #\. #\/ #\0 #\1 #\2 #\3 #\4 #\5 #\6 #\7 #\8 #\9 #\: #\; #\< #\=
  75     #\> #\? #\@ #\A #\B #\C #\D #\E #\F #\G #\H #\I #\J #\K #\L #\M
  76     #\N #\O #\P #\Q #\R #\S #\T #\U #\V #\W #\X #\Y #\Z #\[ #\\ #\]
  77     #\^ #\_ #\` #\a #\b #\c #\d #\e #\f #\g #\h #\i #\j #\k #\l #\m
  78     #\n #\o #\p #\q #\r #\s #\t #\u #\v #\w #\x #\y #\z #\{
  79     #\| #\} #\~))
  80
  81 (sb!xc:deftype keyword ()
  82   ;; Defining this as (AND SYMBOL ..) lets (SUBTYPEP 'KEYWORD 'SYMBOL)=>T,T.
  83   '(and symbol (satisfies keywordp)))
  84
  85 (sb!xc:deftype eql (n) `(member ,n))
  86
  87 (sb!xc:deftype vector (&optional element-type size)
  88   `(array ,element-type (,size)))
  89
  90 (sb!xc:deftype simple-vector (&optional size)
  91   `(simple-array t (,size)))
  92
  93 (sb!xc:deftype base-string (&optional size)
  94   `(array base-char (,size)))
  95 (sb!xc:deftype simple-base-string (&optional size)
  96   `(simple-array base-char (,size)))
  97 (sb!xc:deftype string (&optional size)
  98   `(or (array character (,size))
  99        (array nil (,size))
 100        (base-string ,size)))
 101 (sb!xc:deftype simple-string (&optional size)
 102   `(or (simple-array character (,size))
 103        (simple-array nil (,size))
 104        (simple-base-string ,size)))
 105
 106 (sb!xc:deftype bit-vector (&optional size)
 107   `(array bit (,size)))
 108
 109 (sb!xc:deftype simple-bit-vector (&optional size)
 110   `(simple-array bit (,size)))
 111 \f
 112 ;;;; some private types that we use in defining the standard functions,
 113 ;;;; or implementing declarations in standard compiler transforms
 114
 115 ;;; semistandard types
 116 (sb!xc:deftype generalized-boolean () t)
 117
 118 (sb!xc:deftype format-control ()
 119   '(or string function))
 120
 121 (sb!xc:deftype restart-designator ()
 122   '(or (and symbol (not null)) restart))
 123
 124 ;;; array rank, total size...
 125 (sb!xc:deftype array-rank () `(integer 0 (,sb!xc:array-rank-limit)))
 126 (sb!xc:deftype array-total-size ()
 127   `(integer 0 (,sb!xc:array-total-size-limit)))
 128
 129 ;;; something legal in an evaluated context
 130 ;;; FIXME: could probably go away
 131 (sb!xc:deftype form () t)
 132
 133 (sb!xc:deftype string-designator () '(or string symbol character))
 134
 135 ;;; a thing legal in places where we want the name of a file
 136 (sb!xc:deftype filename () '(or string pathname))
 137
 138 ;;; legal args to pathname functions
 139 (sb!xc:deftype pathname-designator ()
 140   '(or string pathname #+sb-xc-host stream #-sb-xc-host file-stream))
 141 (sb!xc:deftype logical-host-designator ()
 142   '(or host string))
 143
 144 (sb!xc:deftype package-designator () '(or string-designator sb!xc:package))
 145 ;;; a designator for a list of symbols
 146 (sb!xc:deftype symbols-designator () '(or list symbol))
 147
 148 ;;; a thing returned by the irrational functions. We assume that they
 149 ;;; never compute a rational result.
 150 (sb!xc:deftype irrational ()
 151   '(or float (complex float)))
 152
 153 ;;; character components
 154 (sb!xc:deftype char-code () `(integer 0 (,sb!xc:char-code-limit)))
 155
 156 ;;; a consed sequence result. If a vector, is a simple array.
 157 (sb!xc:deftype consed-sequence ()
 158   '(or (simple-array * (*)) (and sequence (not vector))))
 159
 160 ;;; the :END arg to a sequence
 161 (sb!xc:deftype sequence-end () '(or null index))
 162
 163 ;;; the :COUNT arg to a sequence
 164 (sb!xc:deftype sequence-count ()
 165   `(or null integer))
 166
 167 ;;; a valid argument to a stream function
 168 (sb!xc:deftype stream-designator () '(or stream (member nil t)))
 169
 170 ;;; an object suitable for input to standard functions that accept
 171 ;;; "environment objects" (of the ANSI glossary)
 172 (sb!xc:deftype lexenv-designator () '(or lexenv null))
 173
 174 ;;; a thing that can be passed to FUNCALL & friends
 175 ;;;
 176 ;;; FIXME: should be FUNCTION-DESIGNATOR?
 177 (sb!xc:deftype callable () '(or function symbol))
 178
 179 ;;; decomposing floats into integers
 180 (sb!xc:deftype single-float-exponent ()
 181   `(integer ,(- sb!vm:single-float-normal-exponent-min
 182                 sb!vm:single-float-bias
 183                 sb!vm:single-float-digits)
 184             ,(- sb!vm:single-float-normal-exponent-max
 185                 sb!vm:single-float-bias)))
 186 (sb!xc:deftype double-float-exponent ()
 187   `(integer ,(- sb!vm:double-float-normal-exponent-min
 188                 sb!vm:double-float-bias
 189                 sb!vm:double-float-digits)
 190             ,(- sb!vm:double-float-normal-exponent-max
 191                 sb!vm:double-float-bias)))
 192 (sb!xc:deftype single-float-int-exponent ()
 193   `(integer ,(- sb!vm:single-float-normal-exponent-min
 194                 sb!vm:single-float-bias
 195                 (* sb!vm:single-float-digits 2))
 196             ,(- sb!vm:single-float-normal-exponent-max
 197                 sb!vm:single-float-bias
 198                 sb!vm:single-float-digits)))
 199 (sb!xc:deftype double-float-int-exponent ()
 200   `(integer ,(- sb!vm:double-float-normal-exponent-min sb!vm:double-float-bias
 201                 (* sb!vm:double-float-digits 2))
 202             ,(- sb!vm:double-float-normal-exponent-max sb!vm:double-float-bias
 203                 sb!vm:double-float-digits)))
 204 (sb!xc:deftype single-float-significand ()
 205   `(integer 0 (,(ash 1 sb!vm:single-float-digits))))
 206 (sb!xc:deftype double-float-significand ()
 207   `(integer 0 (,(ash 1 sb!vm:double-float-digits))))
 208
 209 (/show0 "deftypes-for-target.lisp end of file")