src/code/early-setf.lisp

   1 ;;;; SETF and friends (except for stuff defined with COLLECT, which
   2 ;;;; comes later)
   3 ;;;;
   4 ;;;; Note: The expansions for SETF and friends sometimes create
   5 ;;;; needless LET-bindings of argument values. The compiler will
   6 ;;;; remove most of these spurious bindings, so SETF doesn't worry too
   7 ;;;; much about creating them.
   8
   9 ;;;; This software is part of the SBCL system. See the README file for
  10 ;;;; more information.
  11 ;;;;
  12 ;;;; This software is derived from the CMU CL system, which was
  13 ;;;; written at Carnegie Mellon University and released into the
  14 ;;;; public domain. The software is in the public domain and is
  15 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  16 ;;;; files for more information.
  17
  18 (in-package "SB!IMPL")
  19
  20 ;;; The inverse for a generalized-variable reference function is stored in
  21 ;;; one of two ways:
  22 ;;;
  23 ;;; A SETF inverse property corresponds to the short form of DEFSETF. It is
  24 ;;; the name of a function takes the same args as the reference form, plus a
  25 ;;; new-value arg at the end.
  26 ;;;
  27 ;;; A SETF method expander is created by the long form of DEFSETF or
  28 ;;; by DEFINE-SETF-EXPANDER. It is a function that is called on the reference
  29 ;;; form and that produces five values: a list of temporary variables, a list
  30 ;;; of value forms, a list of the single store-value form, a storing function,
  31 ;;; and an accessing function.
  32 (declaim (ftype (function (t &optional (or null sb!c::lexenv))) sb!xc:get-setf-expansion))
  33 (defun sb!xc:get-setf-expansion (form &optional environment)
  34   #!+sb-doc
  35   "Return five values needed by the SETF machinery: a list of temporary
  36    variables, a list of values with which to fill them, a list of temporaries
  37    for the new values, the setting function, and the accessing function."
  38   (let (temp)
  39     (cond ((symbolp form)
  40            (multiple-value-bind (expansion expanded)
  41                (sb!xc:macroexpand-1 form environment)
  42              (if expanded
  43                  (sb!xc:get-setf-expansion expansion environment)
  44                  (let ((new-var (gensym)))
  45                    (values nil nil (list new-var)
  46                            `(setq ,form ,new-var) form)))))
  47           ;; Local functions inhibit global SETF methods.
  48           ((and environment
  49                 (let ((name (car form)))
  50                   (dolist (x (sb!c::lexenv-funs environment))
  51                     (when (and (eq (car x) name)
  52                                (not (sb!c::defined-fun-p (cdr x))))
  53                       (return t)))))
  54            (expand-or-get-setf-inverse form environment))
  55           ((setq temp (info :setf :inverse (car form)))
  56            (get-setf-method-inverse form `(,temp) nil))
  57           ((setq temp (info :setf :expander (car form)))
  58            ;; KLUDGE: It may seem as though this should go through
  59            ;; *MACROEXPAND-HOOK*, but the ANSI spec seems fairly explicit
  60            ;; that *MACROEXPAND-HOOK* is a hook for MACROEXPAND-1, not
  61            ;; for macroexpansion in general. -- WHN 19991128
  62            (funcall temp
  63                     form
  64                     ;; As near as I can tell from the ANSI spec,
  65                     ;; macroexpanders have a right to expect an actual
  66                     ;; lexical environment, not just a NIL which is to
  67                     ;; be interpreted as a null lexical environment.
  68                     ;; -- WHN 19991128
  69                     (coerce-to-lexenv environment)))
  70           (t
  71            (expand-or-get-setf-inverse form environment)))))
  72
  73 ;;; GET-SETF-METHOD existed in pre-ANSI Common Lisp, and various code inherited
  74 ;;; from CMU CL uses it repeatedly, so rather than rewrite a lot of code to not
  75 ;;; use it, we just define it in terms of ANSI's GET-SETF-EXPANSION (or
  76 ;;; actually, the cross-compiler version of that, i.e.
  77 ;;; SB!XC:GET-SETF-EXPANSION).
  78 (declaim (ftype (function (t &optional (or null sb!c::lexenv))) get-setf-method))
  79 (defun get-setf-method (form &optional environment)
  80   #!+sb-doc
  81   "This is a specialized-for-one-value version of GET-SETF-EXPANSION (and
  82 a relic from pre-ANSI Common Lisp). Portable ANSI code should use
  83 GET-SETF-EXPANSION directly."
  84   (multiple-value-bind (temps value-forms store-vars store-form access-form)
  85       (sb!xc:get-setf-expansion form environment)
  86     (when (cdr store-vars)
  87       (error "GET-SETF-METHOD used for a form with multiple store ~
  88               variables:~%  ~S"
  89              form))
  90     (values temps value-forms store-vars store-form access-form)))
  91
  92 ;;; If a macro, expand one level and try again. If not, go for the
  93 ;;; SETF function.
  94 (declaim (ftype (function (t (or null sb!c::lexenv)))
  95                 expand-or-get-setf-inverse))
  96 (defun expand-or-get-setf-inverse (form environment)
  97   (multiple-value-bind (expansion expanded)
  98       (sb!xc:macroexpand-1 form environment)
  99     (if expanded
 100         (sb!xc:get-setf-expansion expansion environment)
 101         (get-setf-method-inverse form
 102                                  `(funcall #'(setf ,(car form)))
 103                                  t))))
 104
 105 (defun get-setf-method-inverse (form inverse setf-fun)
 106   (let ((new-var (gensym))
 107         (vars nil)
 108         (vals nil))
 109     (dolist (x (cdr form))
 110       (push (gensym) vars)
 111       (push x vals))
 112     (setq vals (nreverse vals))
 113     (values vars vals (list new-var)
 114             (if setf-fun
 115                 `(,@inverse ,new-var ,@vars)
 116                 `(,@inverse ,@vars ,new-var))
 117             `(,(car form) ,@vars))))
 118 \f
 119 ;;;; SETF itself
 120
 121 ;;; Except for atoms, we always call GET-SETF-EXPANSION, since it has
 122 ;;; some non-trivial semantics. But when there is a setf inverse, and
 123 ;;; G-S-E uses it, then we return a call to the inverse, rather than
 124 ;;; returning a hairy LET form. This is probably important mainly as a
 125 ;;; convenience in allowing the use of SETF inverses without the full
 126 ;;; interpreter.
 127 (defmacro-mundanely setf (&rest args &environment env)
 128   #!+sb-doc
 129   "Takes pairs of arguments like SETQ. The first is a place and the second
 130   is the value that is supposed to go into that place. Returns the last
 131   value. The place argument may be any of the access forms for which SETF
 132   knows a corresponding setting form."
 133   (let ((nargs (length args)))
 134     (cond
 135      ((= nargs 2)
 136       (let ((place (first args))
 137             (value-form (second args)))
 138         (if (atom place)
 139           `(setq ,place ,value-form)
 140           (multiple-value-bind (dummies vals newval setter getter)
 141               (sb!xc:get-setf-expansion place env)
 142             (declare (ignore getter))
 143             (let ((inverse (info :setf :inverse (car place))))
 144               (if (and inverse (eq inverse (car setter)))
 145                 `(,inverse ,@(cdr place) ,value-form)
 146                 `(let* (,@(mapcar #'list dummies vals))
 147                    (multiple-value-bind ,newval ,value-form
 148                      ,setter))))))))
 149      ((oddp nargs)
 150       (error "odd number of args to SETF"))
 151      (t
 152       (do ((a args (cddr a))
 153            (reversed-setfs nil))
 154           ((null a)
 155            `(progn ,@(nreverse reversed-setfs)))
 156         (push (list 'setf (car a) (cadr a)) reversed-setfs))))))
 157 \f
 158 ;;;; various SETF-related macros
 159
 160 (defmacro-mundanely shiftf (&whole form &rest args &environment env)
 161   #!+sb-doc
 162   "One or more SETF-style place expressions, followed by a single
 163    value expression. Evaluates all of the expressions in turn, then
 164    assigns the value of each expression to the place on its left,
 165    returning the value of the leftmost."
 166   (when (< (length args) 2)
 167     (error "~S called with too few arguments: ~S" 'shiftf form))
 168   (let (let*-bindings mv-bindings setters getters)
 169     (dolist (arg (butlast args))
 170       (multiple-value-bind (temps subforms store-vars setter getter)
 171           (sb!xc:get-setf-expansion arg env)
 172         (mapc (lambda (tmp form)
 173                 (push `(,tmp ,form) let*-bindings))
 174               temps
 175               subforms)
 176         (push store-vars mv-bindings)
 177         (push setter setters)
 178         (push getter getters)))
 179     ;; Handle the last arg specially here. The getter is just the last
 180     ;; arg itself.
 181     (push (car (last args)) getters)
 182
 183     ;; Reverse the collected lists so last bit looks nicer.
 184     (setf let*-bindings (nreverse let*-bindings)
 185           mv-bindings (nreverse mv-bindings)
 186           setters (nreverse setters)
 187           getters (nreverse getters))
 188
 189     (labels ((thunk (mv-bindings getters)
 190                (if mv-bindings
 191                    `((multiple-value-bind
 192                            ,(car mv-bindings)
 193                          ,(car getters)
 194                        ,@(thunk (cdr mv-bindings) (cdr getters))))
 195                    `(,@setters))))
 196       `(let ,let*-bindings
 197         (multiple-value-bind ,(car mv-bindings)
 198             ,(car getters)
 199           ,@(thunk mv-bindings (cdr getters))
 200           (values ,@(car mv-bindings)))))))
 201
 202 (defmacro-mundanely push (obj place &environment env)
 203   #!+sb-doc
 204   "Takes an object and a location holding a list. Conses the object onto
 205   the list, returning the modified list. OBJ is evaluated before PLACE."
 206   (multiple-value-bind (dummies vals newval setter getter)
 207       (get-setf-method place env)
 208     (let ((g (gensym)))
 209       `(let* ((,g ,obj)
 210               ,@(mapcar #'list dummies vals)
 211               (,(car newval) (cons ,g ,getter)))
 212          ,setter))))
 213
 214 (defmacro-mundanely pushnew (obj place &rest keys
 215                              &key key test test-not &environment env)
 216   #!+sb-doc
 217   "Takes an object and a location holding a list. If the object is
 218   already in the list, does nothing; otherwise, conses the object onto
 219   the list. Returns the modified list. If there is a :TEST keyword, this
 220   is used for the comparison."
 221   (declare (ignore key test test-not))
 222   (multiple-value-bind (dummies vals newval setter getter)
 223       (get-setf-method place env)
 224     (let ((g (gensym)))
 225       `(let* ((,g ,obj)
 226               ,@(mapcar #'list dummies vals)
 227               (,(car newval) (adjoin ,g ,getter ,@keys)))
 228          ,setter))))
 229
 230 (defmacro-mundanely pop (place &environment env)
 231   #!+sb-doc
 232   "The argument is a location holding a list. Pops one item off the front
 233   of the list and returns it."
 234   (multiple-value-bind (dummies vals newval setter getter)
 235       (get-setf-method place env)
 236     (do* ((d dummies (cdr d))
 237           (v vals (cdr v))
 238           (let-list nil))
 239          ((null d)
 240           (push (list (car newval) getter) let-list)
 241           `(let* ,(nreverse let-list)
 242              (prog1 (car ,(car newval))
 243                (setq ,(car newval) (cdr ,(car newval)))
 244                ,setter)))
 245       (push (list (car d) (car v)) let-list))))
 246
 247 (defmacro-mundanely remf (place indicator &environment env)
 248   #!+sb-doc
 249   "Place may be any place expression acceptable to SETF, and is expected
 250   to hold a property list or (). This list is destructively altered to
 251   remove the property specified by the indicator. Returns T if such a
 252   property was present, NIL if not."
 253   (multiple-value-bind (dummies vals newval setter getter)
 254       (get-setf-method place env)
 255     (do* ((d dummies (cdr d))
 256           (v vals (cdr v))
 257           (let-list nil)
 258           (ind-temp (gensym))
 259           (local1 (gensym))
 260           (local2 (gensym)))
 261          ((null d)
 262           ;; See ANSI 5.1.3 for why we do out-of-order evaluation
 263           (push (list ind-temp indicator) let-list)
 264           (push (list (car newval) getter) let-list)
 265           `(let* ,(nreverse let-list)
 266              (do ((,local1 ,(car newval) (cddr ,local1))
 267                   (,local2 nil ,local1))
 268                  ((atom ,local1) nil)
 269                (cond ((atom (cdr ,local1))
 270                       (error "Odd-length property list in REMF."))
 271                      ((eq (car ,local1) ,ind-temp)
 272                       (cond (,local2
 273                              (rplacd (cdr ,local2) (cddr ,local1))
 274                              (return t))
 275                             (t (setq ,(car newval) (cddr ,(car newval)))
 276                                ,setter
 277                                (return t))))))))
 278       (push (list (car d) (car v)) let-list))))
 279
 280 ;;; we can't use DEFINE-MODIFY-MACRO because of ANSI 5.1.3
 281 (defmacro-mundanely incf (place &optional (delta 1) &environment env)
 282   #!+sb-doc
 283   "The first argument is some location holding a number. This number is
 284   incremented by the second argument, DELTA, which defaults to 1."
 285   (multiple-value-bind (dummies vals newval setter getter)
 286       (get-setf-method place env)
 287     (let ((d (gensym)))
 288       `(let* (,@(mapcar #'list dummies vals)
 289               (,d ,delta)
 290               (,(car newval) (+ ,getter ,d)))
 291          ,setter))))
 292
 293 (defmacro-mundanely decf (place &optional (delta 1) &environment env)
 294   #!+sb-doc
 295   "The first argument is some location holding a number. This number is
 296   decremented by the second argument, DELTA, which defaults to 1."
 297   (multiple-value-bind (dummies vals newval setter getter)
 298       (get-setf-method place env)
 299     (let ((d (gensym)))
 300       `(let* (,@(mapcar #'list dummies vals)
 301               (,d ,delta)
 302               (,(car newval) (- ,getter ,d)))
 303          ,setter))))
 304 \f
 305 ;;;; DEFINE-MODIFY-MACRO stuff
 306
 307 (def!macro sb!xc:define-modify-macro (name lambda-list function &optional doc-string)
 308   #!+sb-doc
 309   "Creates a new read-modify-write macro like PUSH or INCF."
 310   (let ((other-args nil)
 311         (rest-arg nil)
 312         (env (make-symbol "ENV"))          ; To beautify resulting arglist.
 313         (reference (make-symbol "PLACE"))) ; Note that these will be nonexistent
 314                                            ;  in the final expansion anyway.
 315     ;; Parse out the variable names and &REST arg from the lambda list.
 316     (do ((ll lambda-list (cdr ll))
 317          (arg nil))
 318         ((null ll))
 319       (setq arg (car ll))
 320       (cond ((eq arg '&optional))
 321             ((eq arg '&rest)
 322              (if (symbolp (cadr ll))
 323                (setq rest-arg (cadr ll))
 324                (error "Non-symbol &REST argument in definition of ~S." name))
 325              (if (null (cddr ll))
 326                (return nil)
 327                (error "Illegal stuff after &REST argument.")))
 328             ((memq arg '(&key &allow-other-keys &aux))
 329              (error "~S not allowed in DEFINE-MODIFY-MACRO lambda list." arg))
 330             ((symbolp arg)
 331              (push arg other-args))
 332             ((and (listp arg) (symbolp (car arg)))
 333              (push (car arg) other-args))
 334             (t (error "Illegal stuff in lambda list."))))
 335     (setq other-args (nreverse other-args))
 336     `(#-sb-xc-host sb!xc:defmacro
 337       #+sb-xc-host defmacro-mundanely
 338          ,name (,reference ,@lambda-list &environment ,env)
 339        ,doc-string
 340        (multiple-value-bind (dummies vals newval setter getter)
 341            (get-setf-method ,reference ,env)
 342          (do ((d dummies (cdr d))
 343               (v vals (cdr v))
 344               (let-list nil (cons (list (car d) (car v)) let-list)))
 345              ((null d)
 346               (push (list (car newval)
 347                           ,(if rest-arg
 348                              `(list* ',function getter ,@other-args ,rest-arg)
 349                              `(list ',function getter ,@other-args)))
 350                     let-list)
 351               `(let* ,(nreverse let-list)
 352                  ,setter)))))))
 353 \f
 354 ;;;; DEFSETF
 355
 356 (eval-when (#-sb-xc :compile-toplevel :load-toplevel :execute)
 357   ;;; Assign SETF macro information for NAME, making all appropriate checks.
 358   (defun assign-setf-macro (name expander inverse doc)
 359     (with-single-package-locked-error
 360         (:symbol name "defining a setf-expander for ~A"))
 361     (cond ((gethash name sb!c:*setf-assumed-fboundp*)
 362            (warn
 363             "defining setf macro for ~S when ~S was previously ~
 364              treated as a function"
 365             name
 366             `(setf ,name)))
 367           ((not (fboundp `(setf ,name)))
 368            ;; All is well, we don't need any warnings.
 369            (values))
 370           ((not (eq (symbol-package name) (symbol-package 'aref)))
 371            (style-warn "defining setf macro for ~S when ~S is fbound"
 372                        name `(setf ,name))))
 373     (remhash name sb!c:*setf-assumed-fboundp*)
 374     ;; FIXME: It's probably possible to join these checks into one form which
 375     ;; is appropriate both on the cross-compilation host and on the target.
 376     (when (or inverse (info :setf :inverse name))
 377       (setf (info :setf :inverse name) inverse))
 378     (when (or expander (info :setf :expander name))
 379       (setf (info :setf :expander name) expander))
 380     (when doc
 381       (setf (fdocumentation name 'setf) doc))
 382     name))
 383
 384 (def!macro sb!xc:defsetf (access-fn &rest rest)
 385   #!+sb-doc
 386   "Associates a SETF update function or macro with the specified access
 387   function or macro. The format is complex. See the manual for details."
 388   (cond ((not (listp (car rest)))
 389          `(eval-when (:load-toplevel :compile-toplevel :execute)
 390             (assign-setf-macro ',access-fn
 391                                nil
 392                                ',(car rest)
 393                                 ,(when (and (car rest) (stringp (cadr rest)))
 394                                    `',(cadr rest)))))
 395         ((and (cdr rest) (listp (cadr rest)))
 396          (destructuring-bind
 397              (lambda-list (&rest store-variables) &body body)
 398              rest
 399            (let ((whole-var (gensym "WHOLE-"))
 400                  (access-form-var (gensym "ACCESS-FORM-"))
 401                  (env-var (gensym "ENVIRONMENT-")))
 402              (multiple-value-bind (body local-decs doc)
 403                  (parse-defmacro `(,lambda-list ,@store-variables)
 404                                  whole-var body access-fn 'defsetf
 405                                  :environment env-var
 406                                  :anonymousp t)
 407                `(eval-when (:compile-toplevel :load-toplevel :execute)
 408                   (assign-setf-macro
 409                    ',access-fn
 410                    (lambda (,access-form-var ,env-var)
 411                      ,@local-decs
 412                      (%defsetf ,access-form-var ,(length store-variables)
 413                                (lambda (,whole-var)
 414                                  ,body)))
 415                    nil
 416                    ',doc))))))
 417         (t
 418          (error "ill-formed DEFSETF for ~S" access-fn))))
 419
 420 (defun %defsetf (orig-access-form num-store-vars expander)
 421   (declare (type function expander))
 422   (let (subforms
 423         subform-vars
 424         subform-exprs
 425         store-vars)
 426     (dolist (subform (cdr orig-access-form))
 427       (if (constantp subform)
 428         (push subform subforms)
 429         (let ((var (gensym)))
 430           (push var subforms)
 431           (push var subform-vars)
 432           (push subform subform-exprs))))
 433     (dotimes (i num-store-vars)
 434       (push (gensym) store-vars))
 435     (let ((r-subforms (nreverse subforms))
 436           (r-subform-vars (nreverse subform-vars))
 437           (r-subform-exprs (nreverse subform-exprs))
 438           (r-store-vars (nreverse store-vars)))
 439       (values r-subform-vars
 440               r-subform-exprs
 441               r-store-vars
 442               (funcall expander (cons r-subforms r-store-vars))
 443               `(,(car orig-access-form) ,@r-subforms)))))
 444 \f
 445 ;;;; DEFMACRO DEFINE-SETF-EXPANDER and various DEFINE-SETF-EXPANDERs
 446
 447 ;;; DEFINE-SETF-EXPANDER is a lot like DEFMACRO.
 448 (def!macro sb!xc:define-setf-expander (access-fn lambda-list &body body)
 449   #!+sb-doc
 450   "Syntax like DEFMACRO, but creates a setf expander function. The body
 451   of the definition must be a form that returns five appropriate values."
 452   (unless (symbolp access-fn)
 453     (error "~S access-function name ~S is not a symbol."
 454            'sb!xc:define-setf-expander access-fn))
 455   (with-unique-names (whole environment)
 456     (multiple-value-bind (body local-decs doc)
 457         (parse-defmacro lambda-list whole body access-fn
 458                         'sb!xc:define-setf-expander
 459                         :environment environment)
 460       `(eval-when (:compile-toplevel :load-toplevel :execute)
 461          (assign-setf-macro ',access-fn
 462                             (lambda (,whole ,environment)
 463                               ,@local-decs
 464                               ,body)
 465                             nil
 466                             ',doc)))))
 467
 468 (sb!xc:define-setf-expander getf (place prop
 469                                   &optional default
 470                                   &environment env)
 471   (declare (type sb!c::lexenv env))
 472   (multiple-value-bind (temps values stores set get)
 473       (get-setf-method place env)
 474     (let ((newval (gensym))
 475           (ptemp (gensym))
 476           (def-temp (if default (gensym))))
 477       (values `(,@temps ,ptemp ,@(if default `(,def-temp)))
 478               `(,@values ,prop ,@(if default `(,default)))
 479               `(,newval)
 480               `(let ((,(car stores) (%putf ,get ,ptemp ,newval)))
 481                  ,set
 482                  ,newval)
 483               `(getf ,get ,ptemp ,@(if default `(,def-temp)))))))
 484
 485 (sb!xc:define-setf-expander get (symbol prop &optional default)
 486   (let ((symbol-temp (gensym))
 487         (prop-temp (gensym))
 488         (def-temp (gensym))
 489         (newval (gensym)))
 490     (values `(,symbol-temp ,prop-temp ,@(if default `(,def-temp)))
 491             `(,symbol ,prop ,@(if default `(,default)))
 492             (list newval)
 493             `(%put ,symbol-temp ,prop-temp ,newval)
 494             `(get ,symbol-temp ,prop-temp ,@(if default `(,def-temp))))))
 495
 496 (sb!xc:define-setf-expander gethash (key hashtable &optional default)
 497   (let ((key-temp (gensym))
 498         (hashtable-temp (gensym))
 499         (default-temp (gensym))
 500         (new-value-temp (gensym)))
 501     (values
 502      `(,key-temp ,hashtable-temp ,@(if default `(,default-temp)))
 503      `(,key ,hashtable ,@(if default `(,default)))
 504      `(,new-value-temp)
 505      `(%puthash ,key-temp ,hashtable-temp ,new-value-temp)
 506      `(gethash ,key-temp ,hashtable-temp ,@(if default `(,default-temp))))))
 507
 508 (sb!xc:define-setf-expander logbitp (index int &environment env)
 509   (declare (type sb!c::lexenv env))
 510   (multiple-value-bind (temps vals stores store-form access-form)
 511       (get-setf-method int env)
 512     (let ((ind (gensym))
 513           (store (gensym))
 514           (stemp (first stores)))
 515       (values `(,ind ,@temps)
 516               `(,index
 517                 ,@vals)
 518               (list store)
 519               `(let ((,stemp
 520                       (dpb (if ,store 1 0) (byte 1 ,ind) ,access-form)))
 521                  ,store-form
 522                  ,store)
 523               `(logbitp ,ind ,access-form)))))
 524
 525 ;;; CMU CL had a comment here that:
 526 ;;;   Evil hack invented by the gnomes of Vassar Street (though not as evil as
 527 ;;;   it used to be.)  The function arg must be constant, and is converted to
 528 ;;;   an APPLY of the SETF function, which ought to exist.
 529 ;;;
 530 ;;; It may not be clear (wasn't to me..) that this is a standard thing, but See
 531 ;;; "5.1.2.5 APPLY Forms as Places" in the ANSI spec. I haven't actually
 532 ;;; verified that this code has any correspondence to that code, but at least
 533 ;;; ANSI has some place for SETF APPLY. -- WHN 19990604
 534 (sb!xc:define-setf-expander apply (functionoid &rest args)
 535   (unless (and (listp functionoid)
 536                (= (length functionoid) 2)
 537                (eq (first functionoid) 'function)
 538                (symbolp (second functionoid)))
 539     (error "SETF of APPLY is only defined for function args like #'SYMBOL."))
 540   (let ((function (second functionoid))
 541         (new-var (gensym))
 542         (vars (make-gensym-list (length args))))
 543     (values vars args (list new-var)
 544             `(apply #'(setf ,function) ,new-var ,@vars)
 545             `(apply #',function ,@vars))))
 546
 547 ;;; Special-case a BYTE bytespec so that the compiler can recognize it.
 548 (sb!xc:define-setf-expander ldb (bytespec place &environment env)
 549   #!+sb-doc
 550   "The first argument is a byte specifier. The second is any place form
 551   acceptable to SETF. Replace the specified byte of the number in this
 552   place with bits from the low-order end of the new value."
 553   (declare (type sb!c::lexenv env))
 554   (multiple-value-bind (dummies vals newval setter getter)
 555       (get-setf-method place env)
 556     (if (and (consp bytespec) (eq (car bytespec) 'byte))
 557         (let ((n-size (gensym))
 558               (n-pos (gensym))
 559               (n-new (gensym)))
 560           (values (list* n-size n-pos dummies)
 561                   (list* (second bytespec) (third bytespec) vals)
 562                   (list n-new)
 563                   `(let ((,(car newval) (dpb ,n-new (byte ,n-size ,n-pos)
 564                                              ,getter)))
 565                      ,setter
 566                      ,n-new)
 567                   `(ldb (byte ,n-size ,n-pos) ,getter)))
 568         (let ((btemp (gensym))
 569               (gnuval (gensym)))
 570           (values (cons btemp dummies)
 571                   (cons bytespec vals)
 572                   (list gnuval)
 573                   `(let ((,(car newval) (dpb ,gnuval ,btemp ,getter)))
 574                      ,setter
 575                      ,gnuval)
 576                   `(ldb ,btemp ,getter))))))
 577
 578 (sb!xc:define-setf-expander mask-field (bytespec place &environment env)
 579   #!+sb-doc
 580   "The first argument is a byte specifier. The second is any place form
 581   acceptable to SETF. Replaces the specified byte of the number in this place
 582   with bits from the corresponding position in the new value."
 583   (declare (type sb!c::lexenv env))
 584   (multiple-value-bind (dummies vals newval setter getter)
 585       (get-setf-method place env)
 586     (let ((btemp (gensym))
 587           (gnuval (gensym)))
 588       (values (cons btemp dummies)
 589               (cons bytespec vals)
 590               (list gnuval)
 591               `(let ((,(car newval) (deposit-field ,gnuval ,btemp ,getter)))
 592                  ,setter
 593                  ,gnuval)
 594               `(mask-field ,btemp ,getter)))))
 595
 596 (sb!xc:define-setf-expander the (type place &environment env)
 597   (declare (type sb!c::lexenv env))
 598   (multiple-value-bind (temps subforms store-vars setter getter)
 599       (sb!xc:get-setf-expansion place env)
 600     (values temps subforms store-vars
 601             `(multiple-value-bind ,store-vars
 602                  (the ,type (values ,@store-vars))
 603                ,setter)
 604             `(the ,type ,getter))))