src/code/early-setf.lisp

   1 ;;;; SETF and friends (except for stuff defined with COLLECT, which
   2 ;;;; comes later)
   3 ;;;;
   4 ;;;; Note: The expansions for SETF and friends sometimes create
   5 ;;;; needless LET-bindings of argument values. The compiler will
   6 ;;;; remove most of these spurious bindings, so SETF doesn't worry too
   7 ;;;; much about creating them.
   8
   9 ;;;; This software is part of the SBCL system. See the README file for
  10 ;;;; more information.
  11 ;;;;
  12 ;;;; This software is derived from the CMU CL system, which was
  13 ;;;; written at Carnegie Mellon University and released into the
  14 ;;;; public domain. The software is in the public domain and is
  15 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  16 ;;;; files for more information.
  17
  18 (in-package "SB!IMPL")
  19
  20 ;;; The inverse for a generalized-variable reference function is stored in
  21 ;;; one of two ways:
  22 ;;;
  23 ;;; A SETF inverse property corresponds to the short form of DEFSETF. It is
  24 ;;; the name of a function takes the same args as the reference form, plus a
  25 ;;; new-value arg at the end.
  26 ;;;
  27 ;;; A SETF method expander is created by the long form of DEFSETF or
  28 ;;; by DEFINE-SETF-EXPANDER. It is a function that is called on the reference
  29 ;;; form and that produces five values: a list of temporary variables, a list
  30 ;;; of value forms, a list of the single store-value form, a storing function,
  31 ;;; and an accessing function.
  32 (declaim (ftype (function (t &optional (or null sb!c::lexenv))) sb!xc:get-setf-expansion))
  33 (defun sb!xc:get-setf-expansion (form &optional environment)
  34   #!+sb-doc
  35   "Return five values needed by the SETF machinery: a list of temporary
  36    variables, a list of values with which to fill them, a list of temporaries
  37    for the new values, the setting function, and the accessing function."
  38   (let (temp)
  39     (cond ((symbolp form)
  40            (multiple-value-bind (expansion expanded)
  41                (%macroexpand-1 form environment)
  42              (if expanded
  43                  (sb!xc:get-setf-expansion expansion environment)
  44                  (let ((new-var (sb!xc:gensym "NEW")))
  45                    (values nil nil (list new-var)
  46                            `(setq ,form ,new-var) form)))))
  47           ;; Local functions inhibit global SETF methods.
  48           ((and environment
  49                 (let ((name (car form)))
  50                   (dolist (x (sb!c::lexenv-funs environment))
  51                     (when (and (eq (car x) name)
  52                                (not (sb!c::defined-fun-p (cdr x))))
  53                       (return t)))))
  54            (expand-or-get-setf-inverse form environment))
  55           ((setq temp (info :setf :inverse (car form)))
  56            (get-setf-method-inverse form `(,temp) nil environment))
  57           ((setq temp (info :setf :expander (car form)))
  58            ;; KLUDGE: It may seem as though this should go through
  59            ;; *MACROEXPAND-HOOK*, but the ANSI spec seems fairly explicit
  60            ;; that *MACROEXPAND-HOOK* is a hook for MACROEXPAND-1, not
  61            ;; for macroexpansion in general. -- WHN 19991128
  62            (funcall temp
  63                     form
  64                     ;; As near as I can tell from the ANSI spec,
  65                     ;; macroexpanders have a right to expect an actual
  66                     ;; lexical environment, not just a NIL which is to
  67                     ;; be interpreted as a null lexical environment.
  68                     ;; -- WHN 19991128
  69                     (coerce-to-lexenv environment)))
  70           (t
  71            (expand-or-get-setf-inverse form environment)))))
  72
  73 ;;; GET-SETF-METHOD existed in pre-ANSI Common Lisp, and various code inherited
  74 ;;; from CMU CL uses it repeatedly, so rather than rewrite a lot of code to not
  75 ;;; use it, we just define it in terms of ANSI's GET-SETF-EXPANSION (or
  76 ;;; actually, the cross-compiler version of that, i.e.
  77 ;;; SB!XC:GET-SETF-EXPANSION).
  78 (declaim (ftype (function (t &optional (or null sb!c::lexenv))) get-setf-method))
  79 (defun get-setf-method (form &optional environment)
  80   #!+sb-doc
  81   "This is a specialized-for-one-value version of GET-SETF-EXPANSION (and
  82 a relic from pre-ANSI Common Lisp). Portable ANSI code should use
  83 GET-SETF-EXPANSION directly."
  84   (multiple-value-bind (temps value-forms store-vars store-form access-form)
  85       (sb!xc:get-setf-expansion form environment)
  86     (when (cdr store-vars)
  87       (error "GET-SETF-METHOD used for a form with multiple store ~
  88               variables:~%  ~S"
  89              form))
  90     (values temps value-forms store-vars store-form access-form)))
  91
  92 ;;; If a macro, expand one level and try again. If not, go for the
  93 ;;; SETF function.
  94 (declaim (ftype (function (t (or null sb!c::lexenv)))
  95                 expand-or-get-setf-inverse))
  96 (defun expand-or-get-setf-inverse (form environment)
  97   (multiple-value-bind (expansion expanded)
  98       (%macroexpand-1 form environment)
  99     (if expanded
 100         (sb!xc:get-setf-expansion expansion environment)
 101         (get-setf-method-inverse form
 102                                  `(funcall #'(setf ,(car form)))
 103                                  t
 104                                  environment))))
 105
 106 (defun get-setf-method-inverse (form inverse setf-fun environment)
 107   (let ((new-var (sb!xc:gensym "NEW"))
 108         (vars nil)
 109         (vals nil)
 110         (args nil))
 111     (dolist (x (reverse (cdr form)))
 112       (cond ((sb!xc:constantp x environment)
 113              (push x args))
 114             (t
 115              (let ((temp (gensym "TMP")))
 116                (push temp args)
 117                (push temp vars)
 118                (push x vals)))))
 119     (values vars
 120             vals
 121             (list new-var)
 122             (if setf-fun
 123                 `(,@inverse ,new-var ,@args)
 124                 `(,@inverse ,@args ,new-var))
 125             `(,(car form) ,@args))))
 126 \f
 127 ;;;; SETF itself
 128
 129 ;;; Except for atoms, we always call GET-SETF-EXPANSION, since it has
 130 ;;; some non-trivial semantics. But when there is a setf inverse, and
 131 ;;; G-S-E uses it, then we return a call to the inverse, rather than
 132 ;;; returning a hairy LET form. This is probably important mainly as a
 133 ;;; convenience in allowing the use of SETF inverses without the full
 134 ;;; interpreter.
 135 (defmacro-mundanely setf (&rest args &environment env)
 136   #!+sb-doc
 137   "Takes pairs of arguments like SETQ. The first is a place and the second
 138   is the value that is supposed to go into that place. Returns the last
 139   value. The place argument may be any of the access forms for which SETF
 140   knows a corresponding setting form."
 141   (let ((nargs (length args)))
 142     (cond
 143      ((= nargs 2)
 144       (let ((place (first args))
 145             (value-form (second args)))
 146         (if (atom place)
 147           `(setq ,place ,value-form)
 148           (multiple-value-bind (dummies vals newval setter getter)
 149               (sb!xc:get-setf-expansion place env)
 150             (declare (ignore getter))
 151             (let ((inverse (info :setf :inverse (car place))))
 152               (if (and inverse (eq inverse (car setter)))
 153                 `(,inverse ,@(cdr place) ,value-form)
 154                 `(let* (,@(mapcar #'list dummies vals))
 155                    (multiple-value-bind ,newval ,value-form
 156                      ,setter))))))))
 157      ((oddp nargs)
 158       (error "odd number of args to SETF"))
 159      (t
 160       (do ((a args (cddr a))
 161            (reversed-setfs nil))
 162           ((null a)
 163            `(progn ,@(nreverse reversed-setfs)))
 164         (push (list 'setf (car a) (cadr a)) reversed-setfs))))))
 165 \f
 166 ;;;; various SETF-related macros
 167
 168 (defmacro-mundanely shiftf (&whole form &rest args &environment env)
 169   #!+sb-doc
 170   "One or more SETF-style place expressions, followed by a single
 171    value expression. Evaluates all of the expressions in turn, then
 172    assigns the value of each expression to the place on its left,
 173    returning the value of the leftmost."
 174   (when (< (length args) 2)
 175     (error "~S called with too few arguments: ~S" 'shiftf form))
 176   (let (let*-bindings mv-bindings setters getters)
 177     (dolist (arg (butlast args))
 178       (multiple-value-bind (temps subforms store-vars setter getter)
 179           (sb!xc:get-setf-expansion arg env)
 180         (mapc (lambda (tmp form)
 181                 (push `(,tmp ,form) let*-bindings))
 182               temps
 183               subforms)
 184         (push store-vars mv-bindings)
 185         (push setter setters)
 186         (push getter getters)))
 187     ;; Handle the last arg specially here. The getter is just the last
 188     ;; arg itself.
 189     (push (car (last args)) getters)
 190
 191     ;; Reverse the collected lists so last bit looks nicer.
 192     (setf let*-bindings (nreverse let*-bindings)
 193           mv-bindings (nreverse mv-bindings)
 194           setters (nreverse setters)
 195           getters (nreverse getters))
 196
 197     (labels ((thunk (mv-bindings getters)
 198                (if mv-bindings
 199                    `((multiple-value-bind
 200                            ,(car mv-bindings)
 201                          ,(car getters)
 202                        ,@(thunk (cdr mv-bindings) (cdr getters))))
 203                    `(,@setters))))
 204       `(let ,let*-bindings
 205         (multiple-value-bind ,(car mv-bindings)
 206             ,(car getters)
 207           ,@(thunk mv-bindings (cdr getters))
 208           (values ,@(car mv-bindings)))))))
 209
 210 (defmacro-mundanely push (obj place &environment env)
 211   #!+sb-doc
 212   "Takes an object and a location holding a list. Conses the object onto
 213   the list, returning the modified list. OBJ is evaluated before PLACE."
 214   (multiple-value-bind (dummies vals newval setter getter)
 215       (get-setf-method place env)
 216     (let ((g (gensym)))
 217       `(let* ((,g ,obj)
 218               ,@(mapcar #'list dummies vals)
 219               (,(car newval) (cons ,g ,getter)))
 220          ,setter))))
 221
 222 (defmacro-mundanely pushnew (obj place &rest keys
 223                              &key key test test-not &environment env)
 224   #!+sb-doc
 225   "Takes an object and a location holding a list. If the object is
 226   already in the list, does nothing; otherwise, conses the object onto
 227   the list. Returns the modified list. If there is a :TEST keyword, this
 228   is used for the comparison."
 229   (declare (ignore key test test-not))
 230   (multiple-value-bind (dummies vals newval setter getter)
 231       (get-setf-method place env)
 232     (let ((g (gensym)))
 233       `(let* ((,g ,obj)
 234               ,@(mapcar #'list dummies vals)
 235               (,(car newval) (adjoin ,g ,getter ,@keys)))
 236          ,setter))))
 237
 238 (defmacro-mundanely pop (place &environment env)
 239   #!+sb-doc
 240   "The argument is a location holding a list. Pops one item off the front
 241   of the list and returns it."
 242   (multiple-value-bind (dummies vals newval setter getter)
 243       (get-setf-method place env)
 244     (let ((list-head (gensym)))
 245       `(let* (,@(mapcar #'list dummies vals)
 246               (,list-head ,getter)
 247               (,(car newval) (cdr ,list-head)))
 248          ,setter
 249          (car ,list-head)))))
 250
 251 (defmacro-mundanely remf (place indicator &environment env)
 252   #!+sb-doc
 253   "Place may be any place expression acceptable to SETF, and is expected
 254   to hold a property list or (). This list is destructively altered to
 255   remove the property specified by the indicator. Returns T if such a
 256   property was present, NIL if not."
 257   (multiple-value-bind (dummies vals newval setter getter)
 258       (get-setf-method place env)
 259     (let ((ind-temp (gensym))
 260           (local1 (gensym))
 261           (local2 (gensym)))
 262       `(let* (,@(mapcar #'list dummies vals)
 263               ;; See ANSI 5.1.3 for why we do out-of-order evaluation
 264               (,ind-temp ,indicator)
 265               (,(car newval) ,getter))
 266          (do ((,local1 ,(car newval) (cddr ,local1))
 267               (,local2 nil ,local1))
 268              ((atom ,local1) nil)
 269              (cond ((atom (cdr ,local1))
 270                     (error "Odd-length property list in REMF."))
 271                    ((eq (car ,local1) ,ind-temp)
 272                     (cond (,local2
 273                            (rplacd (cdr ,local2) (cddr ,local1))
 274                            (return t))
 275                           (t (setq ,(car newval) (cddr ,(car newval)))
 276                              ,setter
 277                              (return t))))))))))
 278
 279 ;;; we can't use DEFINE-MODIFY-MACRO because of ANSI 5.1.3
 280 (defmacro-mundanely incf (place &optional (delta 1) &environment env)
 281   #!+sb-doc
 282   "The first argument is some location holding a number. This number is
 283   incremented by the second argument, DELTA, which defaults to 1."
 284   (multiple-value-bind (dummies vals newval setter getter)
 285       (get-setf-method place env)
 286     (let ((d (gensym)))
 287       `(let* (,@(mapcar #'list dummies vals)
 288               (,d ,delta)
 289               (,(car newval) (+ ,getter ,d)))
 290          ,setter))))
 291
 292 (defmacro-mundanely decf (place &optional (delta 1) &environment env)
 293   #!+sb-doc
 294   "The first argument is some location holding a number. This number is
 295   decremented by the second argument, DELTA, which defaults to 1."
 296   (multiple-value-bind (dummies vals newval setter getter)
 297       (get-setf-method place env)
 298     (let ((d (gensym)))
 299       `(let* (,@(mapcar #'list dummies vals)
 300               (,d ,delta)
 301               (,(car newval) (- ,getter ,d)))
 302          ,setter))))
 303 \f
 304 ;;;; DEFINE-MODIFY-MACRO stuff
 305
 306 (def!macro sb!xc:define-modify-macro (name lambda-list function &optional doc-string)
 307   #!+sb-doc
 308   "Creates a new read-modify-write macro like PUSH or INCF."
 309   (let ((other-args nil)
 310         (rest-arg nil)
 311         (env (make-symbol "ENV"))          ; To beautify resulting arglist.
 312         (reference (make-symbol "PLACE"))) ; Note that these will be nonexistent
 313                                            ;  in the final expansion anyway.
 314     ;; Parse out the variable names and &REST arg from the lambda list.
 315     (do ((ll lambda-list (cdr ll))
 316          (arg nil))
 317         ((null ll))
 318       (setq arg (car ll))
 319       (cond ((eq arg '&optional))
 320             ((eq arg '&rest)
 321              (if (symbolp (cadr ll))
 322                (setq rest-arg (cadr ll))
 323                (error "Non-symbol &REST argument in definition of ~S." name))
 324              (if (null (cddr ll))
 325                (return nil)
 326                (error "Illegal stuff after &REST argument.")))
 327             ((memq arg '(&key &allow-other-keys &aux))
 328              (error "~S not allowed in DEFINE-MODIFY-MACRO lambda list." arg))
 329             ((symbolp arg)
 330              (push arg other-args))
 331             ((and (listp arg) (symbolp (car arg)))
 332              (push (car arg) other-args))
 333             (t (error "Illegal stuff in lambda list."))))
 334     (setq other-args (nreverse other-args))
 335     `(#-sb-xc-host sb!xc:defmacro
 336       #+sb-xc-host defmacro-mundanely
 337          ,name (,reference ,@lambda-list &environment ,env)
 338        ,doc-string
 339        (multiple-value-bind (dummies vals newval setter getter)
 340            (get-setf-method ,reference ,env)
 341          (let ()
 342              `(let* (,@(mapcar #'list dummies vals)
 343                      (,(car newval)
 344                       ,,(if rest-arg
 345                           `(list* ',function getter ,@other-args ,rest-arg)
 346                           `(list ',function getter ,@other-args))))
 347                 ,setter))))))
 348 \f
 349 ;;;; DEFSETF
 350
 351 (eval-when (#-sb-xc :compile-toplevel :load-toplevel :execute)
 352   ;;; Assign SETF macro information for NAME, making all appropriate checks.
 353   (defun assign-setf-macro (name expander inverse doc)
 354     (with-single-package-locked-error
 355         (:symbol name "defining a setf-expander for ~A"))
 356     (cond ((gethash name sb!c:*setf-assumed-fboundp*)
 357            (warn
 358             "defining setf macro for ~S when ~S was previously ~
 359              treated as a function"
 360             name
 361             `(setf ,name)))
 362           ((not (fboundp `(setf ,name)))
 363            ;; All is well, we don't need any warnings.
 364            (values))
 365           ((not (eq (symbol-package name) (symbol-package 'aref)))
 366            (style-warn "defining setf macro for ~S when ~S is fbound"
 367                        name `(setf ,name))))
 368     (remhash name sb!c:*setf-assumed-fboundp*)
 369     ;; FIXME: It's probably possible to join these checks into one form which
 370     ;; is appropriate both on the cross-compilation host and on the target.
 371     (when (or inverse (info :setf :inverse name))
 372       (setf (info :setf :inverse name) inverse))
 373     (when (or expander (info :setf :expander name))
 374       (setf (info :setf :expander name) expander))
 375     (when doc
 376       (setf (fdocumentation name 'setf) doc))
 377     name))
 378
 379 (def!macro sb!xc:defsetf (access-fn &rest rest)
 380   #!+sb-doc
 381   "Associates a SETF update function or macro with the specified access
 382   function or macro. The format is complex. See the manual for details."
 383   (cond ((and (not (listp (car rest))) (symbolp (car rest)))
 384          `(eval-when (:load-toplevel :compile-toplevel :execute)
 385             (assign-setf-macro ',access-fn
 386                                nil
 387                                ',(car rest)
 388                                 ,(when (and (car rest) (stringp (cadr rest)))
 389                                    `',(cadr rest)))))
 390         ((and (cdr rest) (listp (cadr rest)))
 391          (destructuring-bind
 392              (lambda-list (&rest store-variables) &body body)
 393              rest
 394            (with-unique-names (whole access-form environment)
 395              (multiple-value-bind (body local-decs doc)
 396                  (parse-defmacro `(,lambda-list ,@store-variables)
 397                                  whole body access-fn 'defsetf
 398                                  :environment environment
 399                                  :anonymousp t)
 400                `(eval-when (:compile-toplevel :load-toplevel :execute)
 401                   (assign-setf-macro
 402                    ',access-fn
 403                    (lambda (,access-form ,environment)
 404                      ,@local-decs
 405                      (%defsetf ,access-form ,(length store-variables)
 406                                (lambda (,whole)
 407                                  ,body)))
 408                    nil
 409                    ',doc))))))
 410         (t
 411          (error "ill-formed DEFSETF for ~S" access-fn))))
 412
 413 (defun %defsetf (orig-access-form num-store-vars expander)
 414   (declare (type function expander))
 415   (let (subforms
 416         subform-vars
 417         subform-exprs
 418         store-vars)
 419     (dolist (subform (cdr orig-access-form))
 420       (if (constantp subform)
 421         (push subform subforms)
 422         (let ((var (gensym)))
 423           (push var subforms)
 424           (push var subform-vars)
 425           (push subform subform-exprs))))
 426     (dotimes (i num-store-vars)
 427       (push (gensym) store-vars))
 428     (let ((r-subforms (nreverse subforms))
 429           (r-subform-vars (nreverse subform-vars))
 430           (r-subform-exprs (nreverse subform-exprs))
 431           (r-store-vars (nreverse store-vars)))
 432       (values r-subform-vars
 433               r-subform-exprs
 434               r-store-vars
 435               (funcall expander (cons r-subforms r-store-vars))
 436               `(,(car orig-access-form) ,@r-subforms)))))
 437 \f
 438 ;;;; DEFMACRO DEFINE-SETF-EXPANDER and various DEFINE-SETF-EXPANDERs
 439
 440 ;;; DEFINE-SETF-EXPANDER is a lot like DEFMACRO.
 441 (def!macro sb!xc:define-setf-expander (access-fn lambda-list &body body)
 442   #!+sb-doc
 443   "Syntax like DEFMACRO, but creates a setf expander function. The body
 444   of the definition must be a form that returns five appropriate values."
 445   (unless (symbolp access-fn)
 446     (error "~S access-function name ~S is not a symbol."
 447            'sb!xc:define-setf-expander access-fn))
 448   (with-unique-names (whole environment)
 449     (multiple-value-bind (body local-decs doc)
 450         (parse-defmacro lambda-list whole body access-fn
 451                         'sb!xc:define-setf-expander
 452                         :environment environment)
 453       `(eval-when (:compile-toplevel :load-toplevel :execute)
 454          (assign-setf-macro ',access-fn
 455                             (lambda (,whole ,environment)
 456                               ,@local-decs
 457                               ,body)
 458                             nil
 459                             ',doc)))))
 460
 461 (sb!xc:define-setf-expander getf (place prop
 462                                   &optional default
 463                                   &environment env)
 464   (declare (type sb!c::lexenv env))
 465   (multiple-value-bind (temps values stores set get)
 466       (get-setf-method place env)
 467     (let ((newval (gensym))
 468           (ptemp (gensym))
 469           (def-temp (if default (gensym))))
 470       (values `(,@temps ,ptemp ,@(if default `(,def-temp)))
 471               `(,@values ,prop ,@(if default `(,default)))
 472               `(,newval)
 473               `(let ((,(car stores) (%putf ,get ,ptemp ,newval)))
 474                  ,set
 475                  ,newval)
 476               `(getf ,get ,ptemp ,@(if default `(,def-temp)))))))
 477
 478 (sb!xc:define-setf-expander get (symbol prop &optional default)
 479   (let ((symbol-temp (gensym))
 480         (prop-temp (gensym))
 481         (def-temp (gensym))
 482         (newval (gensym)))
 483     (values `(,symbol-temp ,prop-temp ,@(if default `(,def-temp)))
 484             `(,symbol ,prop ,@(if default `(,default)))
 485             (list newval)
 486             `(%put ,symbol-temp ,prop-temp ,newval)
 487             `(get ,symbol-temp ,prop-temp ,@(if default `(,def-temp))))))
 488
 489 (sb!xc:define-setf-expander gethash (key hashtable &optional default)
 490   (let ((key-temp (gensym))
 491         (hashtable-temp (gensym))
 492         (default-temp (gensym))
 493         (new-value-temp (gensym)))
 494     (values
 495      `(,key-temp ,hashtable-temp ,@(if default `(,default-temp)))
 496      `(,key ,hashtable ,@(if default `(,default)))
 497      `(,new-value-temp)
 498      `(%puthash ,key-temp ,hashtable-temp ,new-value-temp)
 499      `(gethash ,key-temp ,hashtable-temp ,@(if default `(,default-temp))))))
 500
 501 (sb!xc:define-setf-expander logbitp (index int &environment env)
 502   (declare (type sb!c::lexenv env))
 503   (multiple-value-bind (temps vals stores store-form access-form)
 504       (get-setf-method int env)
 505     (let ((ind (gensym))
 506           (store (gensym))
 507           (stemp (first stores)))
 508       (values `(,ind ,@temps)
 509               `(,index
 510                 ,@vals)
 511               (list store)
 512               `(let ((,stemp
 513                       (dpb (if ,store 1 0) (byte 1 ,ind) ,access-form)))
 514                  ,store-form
 515                  ,store)
 516               `(logbitp ,ind ,access-form)))))
 517
 518 ;;; CMU CL had a comment here that:
 519 ;;;   Evil hack invented by the gnomes of Vassar Street (though not as evil as
 520 ;;;   it used to be.)  The function arg must be constant, and is converted to
 521 ;;;   an APPLY of the SETF function, which ought to exist.
 522 ;;;
 523 ;;; It may not be clear (wasn't to me..) that this is a standard thing, but See
 524 ;;; "5.1.2.5 APPLY Forms as Places" in the ANSI spec. I haven't actually
 525 ;;; verified that this code has any correspondence to that code, but at least
 526 ;;; ANSI has some place for SETF APPLY. -- WHN 19990604
 527 (sb!xc:define-setf-expander apply (functionoid &rest args)
 528   (unless (and (listp functionoid)
 529                (= (length functionoid) 2)
 530                (eq (first functionoid) 'function)
 531                (symbolp (second functionoid)))
 532     (error "SETF of APPLY is only defined for function args like #'SYMBOL."))
 533   (let ((function (second functionoid))
 534         (new-var (gensym))
 535         (vars (make-gensym-list (length args))))
 536     (values vars args (list new-var)
 537             `(apply #'(setf ,function) ,new-var ,@vars)
 538             `(apply #',function ,@vars))))
 539
 540 ;;; Special-case a BYTE bytespec so that the compiler can recognize it.
 541 (sb!xc:define-setf-expander ldb (bytespec place &environment env)
 542   #!+sb-doc
 543   "The first argument is a byte specifier. The second is any place form
 544   acceptable to SETF. Replace the specified byte of the number in this
 545   place with bits from the low-order end of the new value."
 546   (declare (type sb!c::lexenv env))
 547   (multiple-value-bind (dummies vals newval setter getter)
 548       (get-setf-method place env)
 549     (if (and (consp bytespec) (eq (car bytespec) 'byte))
 550         (let ((n-size (gensym))
 551               (n-pos (gensym))
 552               (n-new (gensym)))
 553           (values (list* n-size n-pos dummies)
 554                   (list* (second bytespec) (third bytespec) vals)
 555                   (list n-new)
 556                   `(let ((,(car newval) (dpb ,n-new (byte ,n-size ,n-pos)
 557                                              ,getter)))
 558                      ,setter
 559                      ,n-new)
 560                   `(ldb (byte ,n-size ,n-pos) ,getter)))
 561         (let ((btemp (gensym))
 562               (gnuval (gensym)))
 563           (values (cons btemp dummies)
 564                   (cons bytespec vals)
 565                   (list gnuval)
 566                   `(let ((,(car newval) (dpb ,gnuval ,btemp ,getter)))
 567                      ,setter
 568                      ,gnuval)
 569                   `(ldb ,btemp ,getter))))))
 570
 571 (sb!xc:define-setf-expander mask-field (bytespec place &environment env)
 572   #!+sb-doc
 573   "The first argument is a byte specifier. The second is any place form
 574   acceptable to SETF. Replaces the specified byte of the number in this place
 575   with bits from the corresponding position in the new value."
 576   (declare (type sb!c::lexenv env))
 577   (multiple-value-bind (dummies vals newval setter getter)
 578       (get-setf-method place env)
 579     (let ((btemp (gensym))
 580           (gnuval (gensym)))
 581       (values (cons btemp dummies)
 582               (cons bytespec vals)
 583               (list gnuval)
 584               `(let ((,(car newval) (deposit-field ,gnuval ,btemp ,getter)))
 585                  ,setter
 586                  ,gnuval)
 587               `(mask-field ,btemp ,getter)))))
 588
 589 (defun setf-expand-the (the type place env)
 590   (declare (type sb!c::lexenv env))
 591   (multiple-value-bind (temps subforms store-vars setter getter)
 592       (sb!xc:get-setf-expansion place env)
 593     (values temps subforms store-vars
 594             `(multiple-value-bind ,store-vars
 595                  (,the ,type (values ,@store-vars))
 596                ,setter)
 597             `(,the ,type ,getter))))
 598
 599 (sb!xc:define-setf-expander the (type place &environment env)
 600   (setf-expand-the 'the type place env))
 601
 602 (sb!xc:define-setf-expander truly-the (type place &environment env)
 603   (setf-expand-the 'truly-the type place env))