src/code/early-setf.lisp

   1 ;;;; SETF and friends (except for stuff defined with COLLECT, which
   2 ;;;; comes later)
   3 ;;;;
   4 ;;;; Note: The expansions for SETF and friends sometimes create
   5 ;;;; needless LET-bindings of argument values. The compiler will
   6 ;;;; remove most of these spurious bindings, so SETF doesn't worry too
   7 ;;;; much about creating them.
   8
   9 ;;;; This software is part of the SBCL system. See the README file for
  10 ;;;; more information.
  11 ;;;;
  12 ;;;; This software is derived from the CMU CL system, which was
  13 ;;;; written at Carnegie Mellon University and released into the
  14 ;;;; public domain. The software is in the public domain and is
  15 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  16 ;;;; files for more information.
  17
  18 (in-package "SB!IMPL")
  19
  20 ;;; The inverse for a generalized-variable reference function is stored in
  21 ;;; one of two ways:
  22 ;;;
  23 ;;; A SETF inverse property corresponds to the short form of DEFSETF. It is
  24 ;;; the name of a function takes the same args as the reference form, plus a
  25 ;;; new-value arg at the end.
  26 ;;;
  27 ;;; A SETF method expander is created by the long form of DEFSETF or
  28 ;;; by DEFINE-SETF-EXPANDER. It is a function that is called on the reference
  29 ;;; form and that produces five values: a list of temporary variables, a list
  30 ;;; of value forms, a list of the single store-value form, a storing function,
  31 ;;; and an accessing function.
  32 (declaim (ftype (function (t &optional (or null sb!c::lexenv))) sb!xc:get-setf-expansion))
  33 (defun sb!xc:get-setf-expansion (form &optional environment)
  34   #!+sb-doc
  35   "Return five values needed by the SETF machinery: a list of temporary
  36    variables, a list of values with which to fill them, a list of temporaries
  37    for the new values, the setting function, and the accessing function."
  38   (let (temp)
  39     (cond ((symbolp form)
  40            (multiple-value-bind (expansion expanded)
  41                (sb!xc:macroexpand-1 form environment)
  42              (if expanded
  43                  (sb!xc:get-setf-expansion expansion environment)
  44                  (let ((new-var (gensym)))
  45                    (values nil nil (list new-var)
  46                            `(setq ,form ,new-var) form)))))
  47           ;; Local functions inhibit global SETF methods.
  48           ((and environment
  49                 (let ((name (car form)))
  50                   (dolist (x (sb!c::lexenv-funs environment))
  51                     (when (and (eq (car x) name)
  52                                (not (sb!c::defined-fun-p (cdr x))))
  53                       (return t)))))
  54            (expand-or-get-setf-inverse form environment))
  55           ((setq temp (info :setf :inverse (car form)))
  56            (get-setf-method-inverse form `(,temp) nil))
  57           ((setq temp (info :setf :expander (car form)))
  58            ;; KLUDGE: It may seem as though this should go through
  59            ;; *MACROEXPAND-HOOK*, but the ANSI spec seems fairly explicit
  60            ;; that *MACROEXPAND-HOOK* is a hook for MACROEXPAND-1, not
  61            ;; for macroexpansion in general. -- WHN 19991128
  62            (funcall temp
  63                     form
  64                     ;; As near as I can tell from the ANSI spec,
  65                     ;; macroexpanders have a right to expect an actual
  66                     ;; lexical environment, not just a NIL which is to
  67                     ;; be interpreted as a null lexical environment.
  68                     ;; -- WHN 19991128
  69                     (coerce-to-lexenv environment)))
  70           (t
  71            (expand-or-get-setf-inverse form environment)))))
  72
  73 ;;; GET-SETF-METHOD existed in pre-ANSI Common Lisp, and various code inherited
  74 ;;; from CMU CL uses it repeatedly, so rather than rewrite a lot of code to not
  75 ;;; use it, we just define it in terms of ANSI's GET-SETF-EXPANSION (or
  76 ;;; actually, the cross-compiler version of that, i.e.
  77 ;;; SB!XC:GET-SETF-EXPANSION).
  78 (declaim (ftype (function (t &optional (or null sb!c::lexenv))) get-setf-method))
  79 (defun get-setf-method (form &optional environment)
  80   #!+sb-doc
  81   "This is a specialized-for-one-value version of GET-SETF-EXPANSION (and
  82 a relic from pre-ANSI Common Lisp). Portable ANSI code should use
  83 GET-SETF-EXPANSION directly."
  84   (multiple-value-bind (temps value-forms store-vars store-form access-form)
  85       (sb!xc:get-setf-expansion form environment)
  86     (when (cdr store-vars)
  87       (error "GET-SETF-METHOD used for a form with multiple store ~
  88               variables:~%  ~S"
  89              form))
  90     (values temps value-forms store-vars store-form access-form)))
  91
  92 ;;; If a macro, expand one level and try again. If not, go for the
  93 ;;; SETF function.
  94 (declaim (ftype (function (t sb!c::lexenv)) expand-or-get-setf-inverse))
  95 (defun expand-or-get-setf-inverse (form environment)
  96   (multiple-value-bind (expansion expanded)
  97       (sb!xc:macroexpand-1 form environment)
  98     (if expanded
  99         (sb!xc:get-setf-expansion expansion environment)
 100         (get-setf-method-inverse form
 101                                  `(funcall #'(setf ,(car form)))
 102                                  t))))
 103
 104 (defun get-setf-method-inverse (form inverse setf-fun)
 105   (let ((new-var (gensym))
 106         (vars nil)
 107         (vals nil))
 108     (dolist (x (cdr form))
 109       (push (gensym) vars)
 110       (push x vals))
 111     (setq vals (nreverse vals))
 112     (values vars vals (list new-var)
 113             (if setf-fun
 114                 `(,@inverse ,new-var ,@vars)
 115                 `(,@inverse ,@vars ,new-var))
 116             `(,(car form) ,@vars))))
 117 \f
 118 ;;;; SETF itself
 119
 120 ;;; Except for atoms, we always call GET-SETF-EXPANSION, since it has
 121 ;;; some non-trivial semantics. But when there is a setf inverse, and
 122 ;;; G-S-E uses it, then we return a call to the inverse, rather than
 123 ;;; returning a hairy LET form. This is probably important mainly as a
 124 ;;; convenience in allowing the use of SETF inverses without the full
 125 ;;; interpreter.
 126 (defmacro-mundanely setf (&rest args &environment env)
 127   #!+sb-doc
 128   "Takes pairs of arguments like SETQ. The first is a place and the second
 129   is the value that is supposed to go into that place. Returns the last
 130   value. The place argument may be any of the access forms for which SETF
 131   knows a corresponding setting form."
 132   (let ((nargs (length args)))
 133     (cond
 134      ((= nargs 2)
 135       (let ((place (first args))
 136             (value-form (second args)))
 137         (if (atom place)
 138           `(setq ,place ,value-form)
 139           (multiple-value-bind (dummies vals newval setter getter)
 140               (sb!xc:get-setf-expansion place env)
 141             (declare (ignore getter))
 142             (let ((inverse (info :setf :inverse (car place))))
 143               (if (and inverse (eq inverse (car setter)))
 144                 `(,inverse ,@(cdr place) ,value-form)
 145                 `(let* (,@(mapcar #'list dummies vals))
 146                    (multiple-value-bind ,newval ,value-form
 147                      ,setter))))))))
 148      ((oddp nargs)
 149       (error "odd number of args to SETF"))
 150      (t
 151       (do ((a args (cddr a))
 152            (reversed-setfs nil))
 153           ((null a)
 154            `(progn ,@(nreverse reversed-setfs)))
 155         (push (list 'setf (car a) (cadr a)) reversed-setfs))))))
 156 \f
 157 ;;;; various SETF-related macros
 158
 159 (defmacro-mundanely shiftf (&whole form &rest args &environment env)
 160   #!+sb-doc
 161   "One or more SETF-style place expressions, followed by a single
 162    value expression. Evaluates all of the expressions in turn, then
 163    assigns the value of each expression to the place on its left,
 164    returning the value of the leftmost."
 165   (when (< (length args) 2)
 166     (error "~S called with too few arguments: ~S" 'shiftf form))
 167   (let ((resultvar (gensym)))
 168     (do ((arglist args (cdr arglist))
 169          (bindlist nil)
 170          (storelist nil)
 171          (lastvar resultvar))
 172         ((atom (cdr arglist))
 173          (push `(,lastvar ,(first arglist)) bindlist)
 174          `(let* ,(nreverse bindlist) ,@(nreverse storelist) ,resultvar))
 175       (multiple-value-bind (sm1 sm2 sm3 sm4 sm5)
 176           (get-setf-method (first arglist) env)
 177         (mapc (lambda (var val)
 178                 (push `(,var ,val) bindlist))
 179               sm1
 180               sm2)
 181         (push `(,lastvar ,sm5) bindlist)
 182         (push sm4 storelist)
 183         (setq lastvar (first sm3))))))
 184
 185 (defmacro-mundanely push (obj place &environment env)
 186   #!+sb-doc
 187   "Takes an object and a location holding a list. Conses the object onto
 188   the list, returning the modified list. OBJ is evaluated before PLACE."
 189   (multiple-value-bind (dummies vals newval setter getter)
 190       (get-setf-method place env)
 191     (let ((g (gensym)))
 192       `(let* ((,g ,obj)
 193               ,@(mapcar #'list dummies vals)
 194               (,(car newval) (cons ,g ,getter)))
 195          ,setter))))
 196
 197 (defmacro-mundanely pushnew (obj place &rest keys &environment env)
 198   #!+sb-doc
 199   "Takes an object and a location holding a list. If the object is already
 200   in the list, does nothing. Else, conses the object onto the list. Returns
 201   NIL. If there is a :TEST keyword, this is used for the comparison."
 202   (multiple-value-bind (dummies vals newval setter getter)
 203       (get-setf-method place env)
 204     (let ((g (gensym)))
 205       `(let* ((,g ,obj)
 206               ,@(mapcar #'list dummies vals)
 207               (,(car newval) (adjoin ,g ,getter ,@keys)))
 208          ,setter))))
 209
 210 (defmacro-mundanely pop (place &environment env)
 211   #!+sb-doc
 212   "The argument is a location holding a list. Pops one item off the front
 213   of the list and returns it."
 214   (multiple-value-bind (dummies vals newval setter getter)
 215       (get-setf-method place env)
 216     (do* ((d dummies (cdr d))
 217           (v vals (cdr v))
 218           (let-list nil))
 219          ((null d)
 220           (push (list (car newval) getter) let-list)
 221           `(let* ,(nreverse let-list)
 222              (prog1 (car ,(car newval))
 223                (setq ,(car newval) (cdr ,(car newval)))
 224                ,setter)))
 225       (push (list (car d) (car v)) let-list))))
 226
 227 (defmacro-mundanely remf (place indicator &environment env)
 228   #!+sb-doc
 229   "Place may be any place expression acceptable to SETF, and is expected
 230   to hold a property list or (). This list is destructively altered to
 231   remove the property specified by the indicator. Returns T if such a
 232   property was present, NIL if not."
 233   (multiple-value-bind (dummies vals newval setter getter)
 234       (get-setf-method place env)
 235     (do* ((d dummies (cdr d))
 236           (v vals (cdr v))
 237           (let-list nil)
 238           (ind-temp (gensym))
 239           (local1 (gensym))
 240           (local2 (gensym)))
 241          ((null d)
 242           (push (list (car newval) getter) let-list)
 243           (push (list ind-temp indicator) let-list)
 244           `(let* ,(nreverse let-list)
 245              (do ((,local1 ,(car newval) (cddr ,local1))
 246                   (,local2 nil ,local1))
 247                  ((atom ,local1) nil)
 248                (cond ((atom (cdr ,local1))
 249                       (error "Odd-length property list in REMF."))
 250                      ((eq (car ,local1) ,ind-temp)
 251                       (cond (,local2
 252                              (rplacd (cdr ,local2) (cddr ,local1))
 253                              (return t))
 254                             (t (setq ,(car newval) (cddr ,(car newval)))
 255                                ,setter
 256                                (return t))))))))
 257       (push (list (car d) (car v)) let-list))))
 258 \f
 259 ;;;; DEFINE-MODIFY-MACRO stuff
 260
 261 (def!macro sb!xc:define-modify-macro (name lambda-list function &optional doc-string)
 262   #!+sb-doc
 263   "Creates a new read-modify-write macro like PUSH or INCF."
 264   (let ((other-args nil)
 265         (rest-arg nil)
 266         (env (gensym))
 267         (reference (gensym)))
 268     ;; Parse out the variable names and &REST arg from the lambda list.
 269     (do ((ll lambda-list (cdr ll))
 270          (arg nil))
 271         ((null ll))
 272       (setq arg (car ll))
 273       (cond ((eq arg '&optional))
 274             ((eq arg '&rest)
 275              (if (symbolp (cadr ll))
 276                (setq rest-arg (cadr ll))
 277                (error "Non-symbol &REST argument in definition of ~S." name))
 278              (if (null (cddr ll))
 279                (return nil)
 280                (error "Illegal stuff after &REST argument.")))
 281             ((memq arg '(&key &allow-other-keys &aux))
 282              (error "~S not allowed in DEFINE-MODIFY-MACRO lambda list." arg))
 283             ((symbolp arg)
 284              (push arg other-args))
 285             ((and (listp arg) (symbolp (car arg)))
 286              (push (car arg) other-args))
 287             (t (error "Illegal stuff in lambda list."))))
 288     (setq other-args (nreverse other-args))
 289     `(#-sb-xc-host sb!xc:defmacro
 290       #+sb-xc-host defmacro-mundanely
 291          ,name (,reference ,@lambda-list &environment ,env)
 292        ,doc-string
 293        (multiple-value-bind (dummies vals newval setter getter)
 294            (get-setf-method ,reference ,env)
 295          (do ((d dummies (cdr d))
 296               (v vals (cdr v))
 297               (let-list nil (cons (list (car d) (car v)) let-list)))
 298              ((null d)
 299               (push (list (car newval)
 300                           ,(if rest-arg
 301                              `(list* ',function getter ,@other-args ,rest-arg)
 302                              `(list ',function getter ,@other-args)))
 303                     let-list)
 304               `(let* ,(nreverse let-list)
 305                  ,setter)))))))
 306
 307 (sb!xc:define-modify-macro incf (&optional (delta 1)) +
 308   #!+sb-doc
 309   "The first argument is some location holding a number. This number is
 310   incremented by the second argument, DELTA, which defaults to 1.")
 311
 312 (sb!xc:define-modify-macro decf (&optional (delta 1)) -
 313   #!+sb-doc
 314   "The first argument is some location holding a number. This number is
 315   decremented by the second argument, DELTA, which defaults to 1.")
 316 \f
 317 ;;;; DEFSETF
 318
 319 (eval-when (#-sb-xc :compile-toplevel :load-toplevel :execute)
 320   ;;; Assign SETF macro information for NAME, making all appropriate checks.
 321   (defun assign-setf-macro (name expander inverse doc)
 322     (cond ((gethash name sb!c:*setf-assumed-fboundp*)
 323            (warn
 324             "defining setf macro for ~S when ~S was previously ~
 325              treated as a function"
 326             name
 327             `(setf ,name)))
 328           ((not (fboundp `(setf ,name)))
 329            ;; All is well, we don't need any warnings.
 330            (values))
 331           ((not (eq (symbol-package name) (symbol-package 'aref)))
 332            (style-warn "defining setf macro for ~S when ~S is fbound"
 333                        name `(setf ,name))))
 334     (remhash name sb!c:*setf-assumed-fboundp*)
 335     ;; FIXME: It's probably possible to join these checks into one form which
 336     ;; is appropriate both on the cross-compilation host and on the target.
 337     (when (or inverse (info :setf :inverse name))
 338       (setf (info :setf :inverse name) inverse))
 339     (when (or expander (info :setf :expander name))
 340       (setf (info :setf :expander name) expander))
 341     (when doc
 342       (setf (fdocumentation name 'setf) doc))
 343     name))
 344
 345 (def!macro sb!xc:defsetf (access-fn &rest rest)
 346   #!+sb-doc
 347   "Associates a SETF update function or macro with the specified access
 348   function or macro. The format is complex. See the manual for details."
 349   (cond ((not (listp (car rest)))
 350          `(eval-when (:load-toplevel :compile-toplevel :execute)
 351             (assign-setf-macro ',access-fn
 352                                nil
 353                                ',(car rest)
 354                                 ,(when (and (car rest) (stringp (cadr rest)))
 355                                    `',(cadr rest)))))
 356         ((and (cdr rest) (listp (cadr rest)))
 357          (destructuring-bind
 358              (lambda-list (&rest store-variables) &body body)
 359              rest
 360            (let ((arglist-var (gensym "ARGS-"))
 361                  (access-form-var (gensym "ACCESS-FORM-"))
 362                  (env-var (gensym "ENVIRONMENT-")))
 363              (multiple-value-bind (body local-decs doc)
 364                  (parse-defmacro `(,lambda-list ,@store-variables)
 365                                  arglist-var body access-fn 'defsetf
 366                                  :anonymousp t)
 367                `(eval-when (:compile-toplevel :load-toplevel :execute)
 368                   (assign-setf-macro
 369                    ',access-fn
 370                    (lambda (,access-form-var ,env-var)
 371                      (declare (ignore ,env-var))
 372                      (%defsetf ,access-form-var ,(length store-variables)
 373                                (lambda (,arglist-var)
 374                                  ,@local-decs
 375                                  (block ,access-fn
 376                                    ,body))))
 377                    nil
 378                    ',doc))))))
 379         (t
 380          (error "ill-formed DEFSETF for ~S" access-fn))))
 381
 382 (defun %defsetf (orig-access-form num-store-vars expander)
 383   (declare (type function expander))
 384   (let (subforms
 385         subform-vars
 386         subform-exprs
 387         store-vars)
 388     (dolist (subform (cdr orig-access-form))
 389       (if (constantp subform)
 390         (push subform subforms)
 391         (let ((var (gensym)))
 392           (push var subforms)
 393           (push var subform-vars)
 394           (push subform subform-exprs))))
 395     (dotimes (i num-store-vars)
 396       (push (gensym) store-vars))
 397     (let ((r-subforms (nreverse subforms))
 398           (r-subform-vars (nreverse subform-vars))
 399           (r-subform-exprs (nreverse subform-exprs))
 400           (r-store-vars (nreverse store-vars)))
 401       (values r-subform-vars
 402               r-subform-exprs
 403               r-store-vars
 404               (funcall expander (cons r-subforms r-store-vars))
 405               `(,(car orig-access-form) ,@r-subforms)))))
 406 \f
 407 ;;;; DEFMACRO DEFINE-SETF-EXPANDER and various DEFINE-SETF-EXPANDERs
 408
 409 ;;; DEFINE-SETF-EXPANDER is a lot like DEFMACRO.
 410 (def!macro sb!xc:define-setf-expander (access-fn lambda-list &body body)
 411   #!+sb-doc
 412   "Syntax like DEFMACRO, but creates a Setf-Method generator. The body
 413   must be a form that returns the five magical values."
 414   (unless (symbolp access-fn)
 415     (error "DEFINE-SETF-EXPANDER access-function name ~S is not a symbol."
 416            access-fn))
 417   (let ((whole (gensym "WHOLE-"))
 418         (environment (gensym "ENV-")))
 419     (multiple-value-bind (body local-decs doc)
 420         (parse-defmacro lambda-list whole body access-fn
 421                         'sb!xc:define-setf-expander
 422                         :environment environment)
 423       `(eval-when (:compile-toplevel :load-toplevel :execute)
 424          (assign-setf-macro ',access-fn
 425                             (lambda (,whole ,environment)
 426                               ,@local-decs
 427                               (block ,access-fn ,body))
 428                             nil
 429                             ',doc)))))
 430
 431 (sb!xc:define-setf-expander getf (place prop
 432                                   &optional default
 433                                   &environment env)
 434   (declare (type sb!c::lexenv env))
 435   (multiple-value-bind (temps values stores set get)
 436       (get-setf-method place env)
 437     (let ((newval (gensym))
 438           (ptemp (gensym))
 439           (def-temp (if default (gensym))))
 440       (values `(,@temps ,ptemp ,@(if default `(,def-temp)))
 441               `(,@values ,prop ,@(if default `(,default)))
 442               `(,newval)
 443               `(let ((,(car stores) (%putf ,get ,ptemp ,newval)))
 444                  ,set
 445                  ,newval)
 446               `(getf ,get ,ptemp ,@(if default `(,def-temp)))))))
 447
 448 (sb!xc:define-setf-expander get (symbol prop &optional default)
 449   (let ((symbol-temp (gensym))
 450         (prop-temp (gensym))
 451         (def-temp (gensym))
 452         (newval (gensym)))
 453     (values `(,symbol-temp ,prop-temp ,@(if default `(,def-temp)))
 454             `(,symbol ,prop ,@(if default `(,default)))
 455             (list newval)
 456             `(%put ,symbol-temp ,prop-temp ,newval)
 457             `(get ,symbol-temp ,prop-temp ,@(if default `(,def-temp))))))
 458
 459 (sb!xc:define-setf-expander gethash (key hashtable &optional default)
 460   (let ((key-temp (gensym))
 461         (hashtable-temp (gensym))
 462         (default-temp (gensym))
 463         (new-value-temp (gensym)))
 464     (values
 465      `(,key-temp ,hashtable-temp ,@(if default `(,default-temp)))
 466      `(,key ,hashtable ,@(if default `(,default)))
 467      `(,new-value-temp)
 468      `(%puthash ,key-temp ,hashtable-temp ,new-value-temp)
 469      `(gethash ,key-temp ,hashtable-temp ,@(if default `(,default-temp))))))
 470
 471 (sb!xc:define-setf-expander logbitp (index int &environment env)
 472   (declare (type sb!c::lexenv env))
 473   (multiple-value-bind (temps vals stores store-form access-form)
 474       (get-setf-method int env)
 475     (let ((ind (gensym))
 476           (store (gensym))
 477           (stemp (first stores)))
 478       (values `(,ind ,@temps)
 479               `(,index
 480                 ,@vals)
 481               (list store)
 482               `(let ((,stemp
 483                       (dpb (if ,store 1 0) (byte 1 ,ind) ,access-form)))
 484                  ,store-form
 485                  ,store)
 486               `(logbitp ,ind ,access-form)))))
 487
 488 ;;; CMU CL had a comment here that:
 489 ;;;   Evil hack invented by the gnomes of Vassar Street (though not as evil as
 490 ;;;   it used to be.)  The function arg must be constant, and is converted to
 491 ;;;   an APPLY of the SETF function, which ought to exist.
 492 ;;;
 493 ;;; It may not be clear (wasn't to me..) that this is a standard thing, but See
 494 ;;; "5.1.2.5 APPLY Forms as Places" in the ANSI spec. I haven't actually
 495 ;;; verified that this code has any correspondence to that code, but at least
 496 ;;; ANSI has some place for SETF APPLY. -- WHN 19990604
 497 (sb!xc:define-setf-expander apply (functionoid &rest args)
 498   (unless (and (listp functionoid)
 499                (= (length functionoid) 2)
 500                (eq (first functionoid) 'function)
 501                (symbolp (second functionoid)))
 502     (error "SETF of APPLY is only defined for function args like #'SYMBOL."))
 503   (let ((function (second functionoid))
 504         (new-var (gensym))
 505         (vars (make-gensym-list (length args))))
 506     (values vars args (list new-var)
 507             `(apply #'(setf ,function) ,new-var ,@vars)
 508             `(apply #',function ,@vars))))
 509
 510 ;;; Special-case a BYTE bytespec so that the compiler can recognize it.
 511 (sb!xc:define-setf-expander ldb (bytespec place &environment env)
 512   #!+sb-doc
 513   "The first argument is a byte specifier. The second is any place form
 514   acceptable to SETF. Replace the specified byte of the number in this
 515   place with bits from the low-order end of the new value."
 516   (declare (type sb!c::lexenv env))
 517   (multiple-value-bind (dummies vals newval setter getter)
 518       (get-setf-method place env)
 519     (if (and (consp bytespec) (eq (car bytespec) 'byte))
 520         (let ((n-size (gensym))
 521               (n-pos (gensym))
 522               (n-new (gensym)))
 523           (values (list* n-size n-pos dummies)
 524                   (list* (second bytespec) (third bytespec) vals)
 525                   (list n-new)
 526                   `(let ((,(car newval) (dpb ,n-new (byte ,n-size ,n-pos)
 527                                              ,getter)))
 528                      ,setter
 529                      ,n-new)
 530                   `(ldb (byte ,n-size ,n-pos) ,getter)))
 531         (let ((btemp (gensym))
 532               (gnuval (gensym)))
 533           (values (cons btemp dummies)
 534                   (cons bytespec vals)
 535                   (list gnuval)
 536                   `(let ((,(car newval) (dpb ,gnuval ,btemp ,getter)))
 537                      ,setter
 538                      ,gnuval)
 539                   `(ldb ,btemp ,getter))))))
 540
 541 (sb!xc:define-setf-expander mask-field (bytespec place &environment env)
 542   #!+sb-doc
 543   "The first argument is a byte specifier. The second is any place form
 544   acceptable to SETF. Replaces the specified byte of the number in this place
 545   with bits from the corresponding position in the new value."
 546   (declare (type sb!c::lexenv env))
 547   (multiple-value-bind (dummies vals newval setter getter)
 548       (get-setf-method place env)
 549     (let ((btemp (gensym))
 550           (gnuval (gensym)))
 551       (values (cons btemp dummies)
 552               (cons bytespec vals)
 553               (list gnuval)
 554               `(let ((,(car newval) (deposit-field ,gnuval ,btemp ,getter)))
 555                  ,setter
 556                  ,gnuval)
 557               `(mask-field ,btemp ,getter)))))
 558
 559 (sb!xc:define-setf-expander the (type place &environment env)
 560   (declare (type sb!c::lexenv env))
 561   (multiple-value-bind (dummies vals newval setter getter)
 562       (get-setf-method place env)
 563     (values dummies
 564               vals
 565               newval
 566               (subst `(the ,type ,(car newval)) (car newval) setter)
 567               `(the ,type ,getter))))