src/code/early-setf.lisp

   1 ;;;; SETF and friends (except for stuff defined with COLLECT, which
   2 ;;;; comes later)
   3 ;;;;
   4 ;;;; Note: The expansions for SETF and friends sometimes create
   5 ;;;; needless LET-bindings of argument values. The compiler will
   6 ;;;; remove most of these spurious bindings, so SETF doesn't worry too
   7 ;;;; much about creating them.
   8
   9 ;;;; This software is part of the SBCL system. See the README file for
  10 ;;;; more information.
  11 ;;;;
  12 ;;;; This software is derived from the CMU CL system, which was
  13 ;;;; written at Carnegie Mellon University and released into the
  14 ;;;; public domain. The software is in the public domain and is
  15 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  16 ;;;; files for more information.
  17
  18 (in-package "SB!IMPL")
  19
  20 ;;; The inverse for a generalized-variable reference function is stored in
  21 ;;; one of two ways:
  22 ;;;
  23 ;;; A SETF inverse property corresponds to the short form of DEFSETF. It is
  24 ;;; the name of a function takes the same args as the reference form, plus a
  25 ;;; new-value arg at the end.
  26 ;;;
  27 ;;; A SETF method expander is created by the long form of DEFSETF or
  28 ;;; by DEFINE-SETF-EXPANDER. It is a function that is called on the reference
  29 ;;; form and that produces five values: a list of temporary variables, a list
  30 ;;; of value forms, a list of the single store-value form, a storing function,
  31 ;;; and an accessing function.
  32 (declaim (ftype (function (t &optional (or null sb!c::lexenv))) sb!xc:get-setf-expansion))
  33 (defun sb!xc:get-setf-expansion (form &optional environment)
  34   #!+sb-doc
  35   "Return five values needed by the SETF machinery: a list of temporary
  36    variables, a list of values with which to fill them, a list of temporaries
  37    for the new values, the setting function, and the accessing function."
  38   (let (temp)
  39     (cond ((symbolp form)
  40            (multiple-value-bind (expansion expanded)
  41                (sb!xc:macroexpand-1 form environment)
  42              (if expanded
  43                  (sb!xc:get-setf-expansion expansion environment)
  44                  (let ((new-var (gensym)))
  45                    (values nil nil (list new-var)
  46                            `(setq ,form ,new-var) form)))))
  47           ;; Local functions inhibit global SETF methods.
  48           ((and environment
  49                 (let ((name (car form)))
  50                   (dolist (x (sb!c::lexenv-funs environment))
  51                     (when (and (eq (car x) name)
  52                                (not (sb!c::defined-fun-p (cdr x))))
  53                       (return t)))))
  54            (expand-or-get-setf-inverse form environment))
  55           ((setq temp (info :setf :inverse (car form)))
  56            (get-setf-method-inverse form `(,temp) nil))
  57           ((setq temp (info :setf :expander (car form)))
  58            ;; KLUDGE: It may seem as though this should go through
  59            ;; *MACROEXPAND-HOOK*, but the ANSI spec seems fairly explicit
  60            ;; that *MACROEXPAND-HOOK* is a hook for MACROEXPAND-1, not
  61            ;; for macroexpansion in general. -- WHN 19991128
  62            (funcall temp
  63                     form
  64                     ;; As near as I can tell from the ANSI spec,
  65                     ;; macroexpanders have a right to expect an actual
  66                     ;; lexical environment, not just a NIL which is to
  67                     ;; be interpreted as a null lexical environment.
  68                     ;; -- WHN 19991128
  69                     (coerce-to-lexenv environment)))
  70           (t
  71            (expand-or-get-setf-inverse form environment)))))
  72
  73 ;;; GET-SETF-METHOD existed in pre-ANSI Common Lisp, and various code inherited
  74 ;;; from CMU CL uses it repeatedly, so rather than rewrite a lot of code to not
  75 ;;; use it, we just define it in terms of ANSI's GET-SETF-EXPANSION (or
  76 ;;; actually, the cross-compiler version of that, i.e.
  77 ;;; SB!XC:GET-SETF-EXPANSION).
  78 (declaim (ftype (function (t &optional (or null sb!c::lexenv))) get-setf-method))
  79 (defun get-setf-method (form &optional environment)
  80   #!+sb-doc
  81   "This is a specialized-for-one-value version of GET-SETF-EXPANSION (and
  82 a relic from pre-ANSI Common Lisp). Portable ANSI code should use
  83 GET-SETF-EXPANSION directly."
  84   (multiple-value-bind (temps value-forms store-vars store-form access-form)
  85       (sb!xc:get-setf-expansion form environment)
  86     (when (cdr store-vars)
  87       (error "GET-SETF-METHOD used for a form with multiple store ~
  88               variables:~%  ~S"
  89              form))
  90     (values temps value-forms store-vars store-form access-form)))
  91
  92 ;;; If a macro, expand one level and try again. If not, go for the
  93 ;;; SETF function.
  94 (declaim (ftype (function (t (or null sb!c::lexenv)))
  95                 expand-or-get-setf-inverse))
  96 (defun expand-or-get-setf-inverse (form environment)
  97   (multiple-value-bind (expansion expanded)
  98       (sb!xc:macroexpand-1 form environment)
  99     (if expanded
 100         (sb!xc:get-setf-expansion expansion environment)
 101         (get-setf-method-inverse form
 102                                  `(funcall #'(setf ,(car form)))
 103                                  t))))
 104
 105 (defun get-setf-method-inverse (form inverse setf-fun)
 106   (let ((new-var (gensym))
 107         (vars nil)
 108         (vals nil))
 109     (dolist (x (cdr form))
 110       (push (gensym) vars)
 111       (push x vals))
 112     (setq vals (nreverse vals))
 113     (values vars vals (list new-var)
 114             (if setf-fun
 115                 `(,@inverse ,new-var ,@vars)
 116                 `(,@inverse ,@vars ,new-var))
 117             `(,(car form) ,@vars))))
 118 \f
 119 ;;;; SETF itself
 120
 121 ;;; Except for atoms, we always call GET-SETF-EXPANSION, since it has
 122 ;;; some non-trivial semantics. But when there is a setf inverse, and
 123 ;;; G-S-E uses it, then we return a call to the inverse, rather than
 124 ;;; returning a hairy LET form. This is probably important mainly as a
 125 ;;; convenience in allowing the use of SETF inverses without the full
 126 ;;; interpreter.
 127 (defmacro-mundanely setf (&rest args &environment env)
 128   #!+sb-doc
 129   "Takes pairs of arguments like SETQ. The first is a place and the second
 130   is the value that is supposed to go into that place. Returns the last
 131   value. The place argument may be any of the access forms for which SETF
 132   knows a corresponding setting form."
 133   (let ((nargs (length args)))
 134     (cond
 135      ((= nargs 2)
 136       (let ((place (first args))
 137             (value-form (second args)))
 138         (if (atom place)
 139           `(setq ,place ,value-form)
 140           (multiple-value-bind (dummies vals newval setter getter)
 141               (sb!xc:get-setf-expansion place env)
 142             (declare (ignore getter))
 143             (let ((inverse (info :setf :inverse (car place))))
 144               (if (and inverse (eq inverse (car setter)))
 145                 `(,inverse ,@(cdr place) ,value-form)
 146                 `(let* (,@(mapcar #'list dummies vals))
 147                    (multiple-value-bind ,newval ,value-form
 148                      ,setter))))))))
 149      ((oddp nargs)
 150       (error "odd number of args to SETF"))
 151      (t
 152       (do ((a args (cddr a))
 153            (reversed-setfs nil))
 154           ((null a)
 155            `(progn ,@(nreverse reversed-setfs)))
 156         (push (list 'setf (car a) (cadr a)) reversed-setfs))))))
 157 \f
 158 ;;;; various SETF-related macros
 159
 160 (defmacro-mundanely shiftf (&whole form &rest args &environment env)
 161   #!+sb-doc
 162   "One or more SETF-style place expressions, followed by a single
 163    value expression. Evaluates all of the expressions in turn, then
 164    assigns the value of each expression to the place on its left,
 165    returning the value of the leftmost."
 166   (when (< (length args) 2)
 167     (error "~S called with too few arguments: ~S" 'shiftf form))
 168   (let ((resultvar (gensym)))
 169     (do ((arglist args (cdr arglist))
 170          (bindlist nil)
 171          (storelist nil)
 172          (lastvar resultvar))
 173         ((atom (cdr arglist))
 174          (push `(,lastvar ,(first arglist)) bindlist)
 175          `(let* ,(nreverse bindlist) ,@(nreverse storelist) ,resultvar))
 176       (multiple-value-bind (sm1 sm2 sm3 sm4 sm5)
 177           (get-setf-method (first arglist) env)
 178         (mapc (lambda (var val)
 179                 (push `(,var ,val) bindlist))
 180               sm1
 181               sm2)
 182         (push `(,lastvar ,sm5) bindlist)
 183         (push sm4 storelist)
 184         (setq lastvar (first sm3))))))
 185
 186 (defmacro-mundanely push (obj place &environment env)
 187   #!+sb-doc
 188   "Takes an object and a location holding a list. Conses the object onto
 189   the list, returning the modified list. OBJ is evaluated before PLACE."
 190   (multiple-value-bind (dummies vals newval setter getter)
 191       (get-setf-method place env)
 192     (let ((g (gensym)))
 193       `(let* ((,g ,obj)
 194               ,@(mapcar #'list dummies vals)
 195               (,(car newval) (cons ,g ,getter)))
 196          ,setter))))
 197
 198 (defmacro-mundanely pushnew (obj place &rest keys &environment env)
 199   #!+sb-doc
 200   "Takes an object and a location holding a list. If the object is already
 201   in the list, does nothing. Else, conses the object onto the list. Returns
 202   NIL. If there is a :TEST keyword, this is used for the comparison."
 203   (multiple-value-bind (dummies vals newval setter getter)
 204       (get-setf-method place env)
 205     (let ((g (gensym)))
 206       `(let* ((,g ,obj)
 207               ,@(mapcar #'list dummies vals)
 208               (,(car newval) (adjoin ,g ,getter ,@keys)))
 209          ,setter))))
 210
 211 (defmacro-mundanely pop (place &environment env)
 212   #!+sb-doc
 213   "The argument is a location holding a list. Pops one item off the front
 214   of the list and returns it."
 215   (multiple-value-bind (dummies vals newval setter getter)
 216       (get-setf-method place env)
 217     (do* ((d dummies (cdr d))
 218           (v vals (cdr v))
 219           (let-list nil))
 220          ((null d)
 221           (push (list (car newval) getter) let-list)
 222           `(let* ,(nreverse let-list)
 223              (prog1 (car ,(car newval))
 224                (setq ,(car newval) (cdr ,(car newval)))
 225                ,setter)))
 226       (push (list (car d) (car v)) let-list))))
 227
 228 (defmacro-mundanely remf (place indicator &environment env)
 229   #!+sb-doc
 230   "Place may be any place expression acceptable to SETF, and is expected
 231   to hold a property list or (). This list is destructively altered to
 232   remove the property specified by the indicator. Returns T if such a
 233   property was present, NIL if not."
 234   (multiple-value-bind (dummies vals newval setter getter)
 235       (get-setf-method place env)
 236     (do* ((d dummies (cdr d))
 237           (v vals (cdr v))
 238           (let-list nil)
 239           (ind-temp (gensym))
 240           (local1 (gensym))
 241           (local2 (gensym)))
 242          ((null d)
 243           (push (list (car newval) getter) let-list)
 244           (push (list ind-temp indicator) let-list)
 245           `(let* ,(nreverse let-list)
 246              (do ((,local1 ,(car newval) (cddr ,local1))
 247                   (,local2 nil ,local1))
 248                  ((atom ,local1) nil)
 249                (cond ((atom (cdr ,local1))
 250                       (error "Odd-length property list in REMF."))
 251                      ((eq (car ,local1) ,ind-temp)
 252                       (cond (,local2
 253                              (rplacd (cdr ,local2) (cddr ,local1))
 254                              (return t))
 255                             (t (setq ,(car newval) (cddr ,(car newval)))
 256                                ,setter
 257                                (return t))))))))
 258       (push (list (car d) (car v)) let-list))))
 259 \f
 260 ;;;; DEFINE-MODIFY-MACRO stuff
 261
 262 (def!macro sb!xc:define-modify-macro (name lambda-list function &optional doc-string)
 263   #!+sb-doc
 264   "Creates a new read-modify-write macro like PUSH or INCF."
 265   (let ((other-args nil)
 266         (rest-arg nil)
 267         (env (gensym))
 268         (reference (gensym)))
 269     ;; Parse out the variable names and &REST arg from the lambda list.
 270     (do ((ll lambda-list (cdr ll))
 271          (arg nil))
 272         ((null ll))
 273       (setq arg (car ll))
 274       (cond ((eq arg '&optional))
 275             ((eq arg '&rest)
 276              (if (symbolp (cadr ll))
 277                (setq rest-arg (cadr ll))
 278                (error "Non-symbol &REST argument in definition of ~S." name))
 279              (if (null (cddr ll))
 280                (return nil)
 281                (error "Illegal stuff after &REST argument.")))
 282             ((memq arg '(&key &allow-other-keys &aux))
 283              (error "~S not allowed in DEFINE-MODIFY-MACRO lambda list." arg))
 284             ((symbolp arg)
 285              (push arg other-args))
 286             ((and (listp arg) (symbolp (car arg)))
 287              (push (car arg) other-args))
 288             (t (error "Illegal stuff in lambda list."))))
 289     (setq other-args (nreverse other-args))
 290     `(#-sb-xc-host sb!xc:defmacro
 291       #+sb-xc-host defmacro-mundanely
 292          ,name (,reference ,@lambda-list &environment ,env)
 293        ,doc-string
 294        (multiple-value-bind (dummies vals newval setter getter)
 295            (get-setf-method ,reference ,env)
 296          (do ((d dummies (cdr d))
 297               (v vals (cdr v))
 298               (let-list nil (cons (list (car d) (car v)) let-list)))
 299              ((null d)
 300               (push (list (car newval)
 301                           ,(if rest-arg
 302                              `(list* ',function getter ,@other-args ,rest-arg)
 303                              `(list ',function getter ,@other-args)))
 304                     let-list)
 305               `(let* ,(nreverse let-list)
 306                  ,setter)))))))
 307
 308 (sb!xc:define-modify-macro incf (&optional (delta 1)) +
 309   #!+sb-doc
 310   "The first argument is some location holding a number. This number is
 311   incremented by the second argument, DELTA, which defaults to 1.")
 312
 313 (sb!xc:define-modify-macro decf (&optional (delta 1)) -
 314   #!+sb-doc
 315   "The first argument is some location holding a number. This number is
 316   decremented by the second argument, DELTA, which defaults to 1.")
 317 \f
 318 ;;;; DEFSETF
 319
 320 (eval-when (#-sb-xc :compile-toplevel :load-toplevel :execute)
 321   ;;; Assign SETF macro information for NAME, making all appropriate checks.
 322   (defun assign-setf-macro (name expander inverse doc)
 323     (cond ((gethash name sb!c:*setf-assumed-fboundp*)
 324            (warn
 325             "defining setf macro for ~S when ~S was previously ~
 326              treated as a function"
 327             name
 328             `(setf ,name)))
 329           ((not (fboundp `(setf ,name)))
 330            ;; All is well, we don't need any warnings.
 331            (values))
 332           ((not (eq (symbol-package name) (symbol-package 'aref)))
 333            (style-warn "defining setf macro for ~S when ~S is fbound"
 334                        name `(setf ,name))))
 335     (remhash name sb!c:*setf-assumed-fboundp*)
 336     ;; FIXME: It's probably possible to join these checks into one form which
 337     ;; is appropriate both on the cross-compilation host and on the target.
 338     (when (or inverse (info :setf :inverse name))
 339       (setf (info :setf :inverse name) inverse))
 340     (when (or expander (info :setf :expander name))
 341       (setf (info :setf :expander name) expander))
 342     (when doc
 343       (setf (fdocumentation name 'setf) doc))
 344     name))
 345
 346 (def!macro sb!xc:defsetf (access-fn &rest rest)
 347   #!+sb-doc
 348   "Associates a SETF update function or macro with the specified access
 349   function or macro. The format is complex. See the manual for details."
 350   (cond ((not (listp (car rest)))
 351          `(eval-when (:load-toplevel :compile-toplevel :execute)
 352             (assign-setf-macro ',access-fn
 353                                nil
 354                                ',(car rest)
 355                                 ,(when (and (car rest) (stringp (cadr rest)))
 356                                    `',(cadr rest)))))
 357         ((and (cdr rest) (listp (cadr rest)))
 358          (destructuring-bind
 359              (lambda-list (&rest store-variables) &body body)
 360              rest
 361            (let ((arglist-var (gensym "ARGS-"))
 362                  (access-form-var (gensym "ACCESS-FORM-"))
 363                  (env-var (gensym "ENVIRONMENT-")))
 364              (multiple-value-bind (body local-decs doc)
 365                  (parse-defmacro `(,lambda-list ,@store-variables)
 366                                  arglist-var body access-fn 'defsetf
 367                                  :anonymousp t)
 368                `(eval-when (:compile-toplevel :load-toplevel :execute)
 369                   (assign-setf-macro
 370                    ',access-fn
 371                    (lambda (,access-form-var ,env-var)
 372                      (declare (ignore ,env-var))
 373                      (%defsetf ,access-form-var ,(length store-variables)
 374                                (lambda (,arglist-var)
 375                                  ,@local-decs
 376                                  ,body)))
 377                    nil
 378                    ',doc))))))
 379         (t
 380          (error "ill-formed DEFSETF for ~S" access-fn))))
 381
 382 (defun %defsetf (orig-access-form num-store-vars expander)
 383   (declare (type function expander))
 384   (let (subforms
 385         subform-vars
 386         subform-exprs
 387         store-vars)
 388     (dolist (subform (cdr orig-access-form))
 389       (if (constantp subform)
 390         (push subform subforms)
 391         (let ((var (gensym)))
 392           (push var subforms)
 393           (push var subform-vars)
 394           (push subform subform-exprs))))
 395     (dotimes (i num-store-vars)
 396       (push (gensym) store-vars))
 397     (let ((r-subforms (nreverse subforms))
 398           (r-subform-vars (nreverse subform-vars))
 399           (r-subform-exprs (nreverse subform-exprs))
 400           (r-store-vars (nreverse store-vars)))
 401       (values r-subform-vars
 402               r-subform-exprs
 403               r-store-vars
 404               (funcall expander (cons r-subforms r-store-vars))
 405               `(,(car orig-access-form) ,@r-subforms)))))
 406 \f
 407 ;;;; DEFMACRO DEFINE-SETF-EXPANDER and various DEFINE-SETF-EXPANDERs
 408
 409 ;;; DEFINE-SETF-EXPANDER is a lot like DEFMACRO.
 410 (def!macro sb!xc:define-setf-expander (access-fn lambda-list &body body)
 411   #!+sb-doc
 412   "Syntax like DEFMACRO, but creates a Setf-Method generator. The body
 413   must be a form that returns the five magical values."
 414   (unless (symbolp access-fn)
 415     (error "DEFINE-SETF-EXPANDER access-function name ~S is not a symbol."
 416            access-fn))
 417   (with-unique-names (whole environment)
 418     (multiple-value-bind (body local-decs doc)
 419         (parse-defmacro lambda-list whole body access-fn
 420                         'sb!xc:define-setf-expander
 421                         :environment environment)
 422       `(eval-when (:compile-toplevel :load-toplevel :execute)
 423          (assign-setf-macro ',access-fn
 424                             (lambda (,whole ,environment)
 425                               ,@local-decs
 426                               ,body)
 427                             nil
 428                             ',doc)))))
 429
 430 (sb!xc:define-setf-expander getf (place prop
 431                                   &optional default
 432                                   &environment env)
 433   (declare (type sb!c::lexenv env))
 434   (multiple-value-bind (temps values stores set get)
 435       (get-setf-method place env)
 436     (let ((newval (gensym))
 437           (ptemp (gensym))
 438           (def-temp (if default (gensym))))
 439       (values `(,@temps ,ptemp ,@(if default `(,def-temp)))
 440               `(,@values ,prop ,@(if default `(,default)))
 441               `(,newval)
 442               `(let ((,(car stores) (%putf ,get ,ptemp ,newval)))
 443                  ,set
 444                  ,newval)
 445               `(getf ,get ,ptemp ,@(if default `(,def-temp)))))))
 446
 447 (sb!xc:define-setf-expander get (symbol prop &optional default)
 448   (let ((symbol-temp (gensym))
 449         (prop-temp (gensym))
 450         (def-temp (gensym))
 451         (newval (gensym)))
 452     (values `(,symbol-temp ,prop-temp ,@(if default `(,def-temp)))
 453             `(,symbol ,prop ,@(if default `(,default)))
 454             (list newval)
 455             `(%put ,symbol-temp ,prop-temp ,newval)
 456             `(get ,symbol-temp ,prop-temp ,@(if default `(,def-temp))))))
 457
 458 (sb!xc:define-setf-expander gethash (key hashtable &optional default)
 459   (let ((key-temp (gensym))
 460         (hashtable-temp (gensym))
 461         (default-temp (gensym))
 462         (new-value-temp (gensym)))
 463     (values
 464      `(,key-temp ,hashtable-temp ,@(if default `(,default-temp)))
 465      `(,key ,hashtable ,@(if default `(,default)))
 466      `(,new-value-temp)
 467      `(%puthash ,key-temp ,hashtable-temp ,new-value-temp)
 468      `(gethash ,key-temp ,hashtable-temp ,@(if default `(,default-temp))))))
 469
 470 (sb!xc:define-setf-expander logbitp (index int &environment env)
 471   (declare (type sb!c::lexenv env))
 472   (multiple-value-bind (temps vals stores store-form access-form)
 473       (get-setf-method int env)
 474     (let ((ind (gensym))
 475           (store (gensym))
 476           (stemp (first stores)))
 477       (values `(,ind ,@temps)
 478               `(,index
 479                 ,@vals)
 480               (list store)
 481               `(let ((,stemp
 482                       (dpb (if ,store 1 0) (byte 1 ,ind) ,access-form)))
 483                  ,store-form
 484                  ,store)
 485               `(logbitp ,ind ,access-form)))))
 486
 487 ;;; CMU CL had a comment here that:
 488 ;;;   Evil hack invented by the gnomes of Vassar Street (though not as evil as
 489 ;;;   it used to be.)  The function arg must be constant, and is converted to
 490 ;;;   an APPLY of the SETF function, which ought to exist.
 491 ;;;
 492 ;;; It may not be clear (wasn't to me..) that this is a standard thing, but See
 493 ;;; "5.1.2.5 APPLY Forms as Places" in the ANSI spec. I haven't actually
 494 ;;; verified that this code has any correspondence to that code, but at least
 495 ;;; ANSI has some place for SETF APPLY. -- WHN 19990604
 496 (sb!xc:define-setf-expander apply (functionoid &rest args)
 497   (unless (and (listp functionoid)
 498                (= (length functionoid) 2)
 499                (eq (first functionoid) 'function)
 500                (symbolp (second functionoid)))
 501     (error "SETF of APPLY is only defined for function args like #'SYMBOL."))
 502   (let ((function (second functionoid))
 503         (new-var (gensym))
 504         (vars (make-gensym-list (length args))))
 505     (values vars args (list new-var)
 506             `(apply #'(setf ,function) ,new-var ,@vars)
 507             `(apply #',function ,@vars))))
 508
 509 ;;; Special-case a BYTE bytespec so that the compiler can recognize it.
 510 (sb!xc:define-setf-expander ldb (bytespec place &environment env)
 511   #!+sb-doc
 512   "The first argument is a byte specifier. The second is any place form
 513   acceptable to SETF. Replace the specified byte of the number in this
 514   place with bits from the low-order end of the new value."
 515   (declare (type sb!c::lexenv env))
 516   (multiple-value-bind (dummies vals newval setter getter)
 517       (get-setf-method place env)
 518     (if (and (consp bytespec) (eq (car bytespec) 'byte))
 519         (let ((n-size (gensym))
 520               (n-pos (gensym))
 521               (n-new (gensym)))
 522           (values (list* n-size n-pos dummies)
 523                   (list* (second bytespec) (third bytespec) vals)
 524                   (list n-new)
 525                   `(let ((,(car newval) (dpb ,n-new (byte ,n-size ,n-pos)
 526                                              ,getter)))
 527                      ,setter
 528                      ,n-new)
 529                   `(ldb (byte ,n-size ,n-pos) ,getter)))
 530         (let ((btemp (gensym))
 531               (gnuval (gensym)))
 532           (values (cons btemp dummies)
 533                   (cons bytespec vals)
 534                   (list gnuval)
 535                   `(let ((,(car newval) (dpb ,gnuval ,btemp ,getter)))
 536                      ,setter
 537                      ,gnuval)
 538                   `(ldb ,btemp ,getter))))))
 539
 540 (sb!xc:define-setf-expander mask-field (bytespec place &environment env)
 541   #!+sb-doc
 542   "The first argument is a byte specifier. The second is any place form
 543   acceptable to SETF. Replaces the specified byte of the number in this place
 544   with bits from the corresponding position in the new value."
 545   (declare (type sb!c::lexenv env))
 546   (multiple-value-bind (dummies vals newval setter getter)
 547       (get-setf-method place env)
 548     (let ((btemp (gensym))
 549           (gnuval (gensym)))
 550       (values (cons btemp dummies)
 551               (cons bytespec vals)
 552               (list gnuval)
 553               `(let ((,(car newval) (deposit-field ,gnuval ,btemp ,getter)))
 554                  ,setter
 555                  ,gnuval)
 556               `(mask-field ,btemp ,getter)))))
 557
 558 (sb!xc:define-setf-expander the (type place &environment env)
 559   (declare (type sb!c::lexenv env))
 560   (multiple-value-bind (dummies vals newval setter getter)
 561       (get-setf-method place env)
 562     (values dummies
 563               vals
 564               newval
 565               (subst `(the ,type ,(car newval)) (car newval) setter)
 566               `(the ,type ,getter))))