src/code/early-type.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3 ;;;;
   4 ;;;; This software is derived from the CMU CL system, which was
   5 ;;;; written at Carnegie Mellon University and released into the
   6 ;;;; public domain. The software is in the public domain and is
   7 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
   8 ;;;; files for more information.
   9
  10 (in-package "SB!KERNEL")
  11
  12 (!begin-collecting-cold-init-forms)
  13
  14 ;;;; representations of types
  15
  16 ;;; A HAIRY-TYPE represents anything too weird to be described
  17 ;;; reasonably or to be useful, such as NOT, SATISFIES, unknown types,
  18 ;;; and unreasonably complicated types involving AND. We just remember
  19 ;;; the original type spec.
  20 (defstruct (hairy-type (:include ctype
  21                                  (class-info (type-class-or-lose 'hairy))
  22                                  (enumerable t)
  23                                  (might-contain-other-types-p t))
  24                        (:copier nil)
  25                        #!+cmu (:pure nil))
  26   ;; the Common Lisp type-specifier of the type we represent
  27   (specifier nil :type t))
  28
  29 (!define-type-class hairy)
  30
  31 ;;; An UNKNOWN-TYPE is a type not known to the type system (not yet
  32 ;;; defined). We make this distinction since we don't want to complain
  33 ;;; about types that are hairy but defined.
  34 (defstruct (unknown-type (:include hairy-type)
  35                          (:copier nil)))
  36
  37 (defstruct (negation-type (:include ctype
  38                                     (class-info (type-class-or-lose 'negation))
  39                                     ;; FIXME: is this right?  It's
  40                                     ;; what they had before, anyway
  41                                     (enumerable t)
  42                                     (might-contain-other-types-p t))
  43                           (:copier nil)
  44                           #!+cmu (:pure nil))
  45   (type (missing-arg) :type ctype))
  46
  47 (!define-type-class negation)
  48
  49 ;;; ARGS-TYPE objects are used both to represent VALUES types and
  50 ;;; to represent FUNCTION types.
  51 (defstruct (args-type (:include ctype)
  52                       (:constructor nil)
  53                       (:copier nil))
  54   ;; Lists of the type for each required and optional argument.
  55   (required nil :type list)
  56   (optional nil :type list)
  57   ;; The type for the rest arg. NIL if there is no &REST arg.
  58   (rest nil :type (or ctype null))
  59   ;; true if &KEY arguments are specified
  60   (keyp nil :type boolean)
  61   ;; list of KEY-INFO structures describing the &KEY arguments
  62   (keywords nil :type list)
  63   ;; true if other &KEY arguments are allowed
  64   (allowp nil :type boolean))
  65
  66 (defun canonicalize-args-type-args (required optional rest)
  67   (when (eq rest *empty-type*)
  68     ;; or vice-versa?
  69     (setq rest nil))
  70   (loop with last-not-rest = nil
  71         for i from 0
  72         for opt in optional
  73         do (cond ((eq opt *empty-type*)
  74                   (return (values required (subseq optional i) rest)))
  75                  ((neq opt rest)
  76                   (setq last-not-rest i)))
  77         finally (return (values required
  78                                 (if last-not-rest
  79                                     (subseq optional 0 (1+ last-not-rest))
  80                                     nil)
  81                                 rest))))
  82
  83 (defun args-types (lambda-list-like-thing)
  84   (multiple-value-bind
  85         (required optional restp rest keyp keys allowp auxp aux
  86                   morep more-context more-count llk-p)
  87       (parse-lambda-list-like-thing lambda-list-like-thing)
  88     (declare (ignore aux morep more-context more-count))
  89     (when auxp
  90       (error "&AUX in a FUNCTION or VALUES type: ~S." lambda-list-like-thing))
  91     (let ((required (mapcar #'single-value-specifier-type required))
  92           (optional (mapcar #'single-value-specifier-type optional))
  93           (rest (when restp (single-value-specifier-type rest)))
  94           (keywords
  95            (collect ((key-info))
  96              (dolist (key keys)
  97                (unless (proper-list-of-length-p key 2)
  98                  (error "Keyword type description is not a two-list: ~S." key))
  99                (let ((kwd (first key)))
 100                  (when (find kwd (key-info) :key #'key-info-name)
 101                    (error "~@<repeated keyword ~S in lambda list: ~2I~_~S~:>"
 102                           kwd lambda-list-like-thing))
 103                  (key-info
 104                   (make-key-info
 105                    :name kwd
 106                    :type (single-value-specifier-type (second key))))))
 107              (key-info))))
 108       (multiple-value-bind (required optional rest)
 109           (canonicalize-args-type-args required optional rest)
 110         (values required optional rest keyp keywords allowp llk-p)))))
 111
 112 (defstruct (values-type
 113             (:include args-type
 114                       (class-info (type-class-or-lose 'values)))
 115             (:constructor %make-values-type)
 116             (:copier nil)))
 117
 118 (defun-cached (make-values-type-cached
 119                :hash-bits 8
 120                :hash-function (lambda (req opt rest allowp)
 121                                 (logand (logxor
 122                                          (type-list-cache-hash req)
 123                                          (type-list-cache-hash opt)
 124                                          (if rest
 125                                              (type-hash-value rest)
 126                                              42)
 127                                          (sxhash allowp))
 128                                         #xFF)))
 129     ((required equal-but-no-car-recursion)
 130      (optional equal-but-no-car-recursion)
 131      (rest eq)
 132      (allowp eq))
 133   (%make-values-type :required required
 134                      :optional optional
 135                      :rest rest
 136                      :allowp allowp))
 137
 138 (defun make-values-type (&key (args nil argsp)
 139                          required optional rest allowp)
 140   (if argsp
 141       (if (eq args '*)
 142           *wild-type*
 143           (multiple-value-bind (required optional rest keyp keywords allowp
 144                                 llk-p)
 145               (args-types args)
 146             (declare (ignore keywords))
 147             (when keyp
 148               (error "&KEY appeared in a VALUES type specifier ~S."
 149                      `(values ,@args)))
 150             (if llk-p
 151                 (make-values-type :required required
 152                                   :optional optional
 153                                   :rest rest
 154                                   :allowp allowp)
 155                 (make-short-values-type required))))
 156       (multiple-value-bind (required optional rest)
 157           (canonicalize-args-type-args required optional rest)
 158         (cond ((and (null required)
 159                     (null optional)
 160                     (eq rest *universal-type*))
 161                *wild-type*)
 162               ((memq *empty-type* required)
 163                *empty-type*)
 164               (t (make-values-type-cached required optional
 165                                           rest allowp))))))
 166
 167 (!define-type-class values)
 168
 169 ;;; (SPECIFIER-TYPE 'FUNCTION) and its subtypes
 170 (defstruct (fun-type (:include args-type
 171                                (class-info (type-class-or-lose 'function)))
 172                      (:constructor
 173                       %make-fun-type (&key required optional rest
 174                                            keyp keywords allowp
 175                                            wild-args
 176                                            returns
 177                                       &aux (rest (if (eq rest *empty-type*)
 178                                                      nil
 179                                                      rest)))))
 180   ;; true if the arguments are unrestrictive, i.e. *
 181   (wild-args nil :type boolean)
 182   ;; type describing the return values. This is a values type
 183   ;; when multiple values were specified for the return.
 184   (returns (missing-arg) :type ctype))
 185 (defun make-fun-type (&rest initargs
 186                       &key (args nil argsp) returns &allow-other-keys)
 187   (if argsp
 188       (if (eq args '*)
 189           (if (eq returns *wild-type*)
 190               (specifier-type 'function)
 191               (%make-fun-type :wild-args t :returns returns))
 192           (multiple-value-bind (required optional rest keyp keywords allowp)
 193               (args-types args)
 194             (if (and (null required)
 195                      (null optional)
 196                      (eq rest *universal-type*)
 197                      (not keyp))
 198                 (if (eq returns *wild-type*)
 199                     (specifier-type 'function)
 200                     (%make-fun-type :wild-args t :returns returns))
 201                 (%make-fun-type :required required
 202                                 :optional optional
 203                                 :rest rest
 204                                 :keyp keyp
 205                                 :keywords keywords
 206                                 :allowp allowp
 207                                 :returns returns))))
 208       ;; FIXME: are we really sure that we won't make something that
 209       ;; looks like a completely wild function here?
 210       (apply #'%make-fun-type initargs)))
 211
 212 ;;; The CONSTANT-TYPE structure represents a use of the CONSTANT-ARG
 213 ;;; "type specifier", which is only meaningful in function argument
 214 ;;; type specifiers used within the compiler. (It represents something
 215 ;;; that the compiler knows to be a constant.)
 216 (defstruct (constant-type
 217             (:include ctype
 218                       (class-info (type-class-or-lose 'constant)))
 219             (:copier nil))
 220   ;; The type which the argument must be a constant instance of for this type
 221   ;; specifier to win.
 222   (type (missing-arg) :type ctype))
 223
 224 ;;; The NAMED-TYPE is used to represent *, T and NIL. These types must
 225 ;;; be super- or sub-types of all types, not just classes and * and
 226 ;;; NIL aren't classes anyway, so it wouldn't make much sense to make
 227 ;;; them built-in classes.
 228 (defstruct (named-type (:include ctype
 229                                  (class-info (type-class-or-lose 'named)))
 230                        (:copier nil))
 231   (name nil :type symbol))
 232
 233 ;;; a list of all the float "formats" (i.e. internal representations;
 234 ;;; nothing to do with #'FORMAT), in order of decreasing precision
 235 (eval-when (:compile-toplevel :load-toplevel :execute)
 236   (defparameter *float-formats*
 237     '(long-float double-float single-float short-float)))
 238
 239 ;;; The type of a float format.
 240 (deftype float-format () `(member ,@*float-formats*))
 241
 242 ;;; A NUMERIC-TYPE represents any numeric type, including things
 243 ;;; such as FIXNUM.
 244 (defstruct (numeric-type (:include ctype
 245                                    (class-info (type-class-or-lose 'number)))
 246                          (:constructor %make-numeric-type)
 247                          (:copier nil))
 248   ;; the kind of numeric type we have, or NIL if not specified (just
 249   ;; NUMBER or COMPLEX)
 250   ;;
 251   ;; KLUDGE: A slot named CLASS for a non-CLASS value is bad.
 252   ;; Especially when a CLASS value *is* stored in another slot (called
 253   ;; CLASS-INFO:-). Perhaps this should be called CLASS-NAME? Also
 254   ;; weird that comment above says "Numeric-Type is used to represent
 255   ;; all numeric types" but this slot doesn't allow COMPLEX as an
 256   ;; option.. how does this fall into "not specified" NIL case above?
 257   ;; Perhaps someday we can switch to CLOS and make NUMERIC-TYPE
 258   ;; be an abstract base class and INTEGER-TYPE, RATIONAL-TYPE, and
 259   ;; whatnot be concrete subclasses..
 260   (class nil :type (member integer rational float nil) :read-only t)
 261   ;; "format" for a float type (i.e. type specifier for a CPU
 262   ;; representation of floating point, e.g. 'SINGLE-FLOAT -- nothing
 263   ;; to do with #'FORMAT), or NIL if not specified or not a float.
 264   ;; Formats which don't exist in a given implementation don't appear
 265   ;; here.
 266   (format nil :type (or float-format null) :read-only t)
 267   ;; Is this a complex numeric type?  Null if unknown (only in NUMBER).
 268   ;;
 269   ;; FIXME: I'm bewildered by FOO-P names for things not intended to
 270   ;; interpreted as truth values. Perhaps rename this COMPLEXNESS?
 271   (complexp :real :type (member :real :complex nil) :read-only t)
 272   ;; The upper and lower bounds on the value, or NIL if there is no
 273   ;; bound. If a list of a number, the bound is exclusive. Integer
 274   ;; types never have exclusive bounds, i.e. they may have them on
 275   ;; input, but they're canonicalized to inclusive bounds before we
 276   ;; store them here.
 277   (low nil :type (or number cons null) :read-only t)
 278   (high nil :type (or number cons null) :read-only t))
 279
 280 ;;; Impose canonicalization rules for NUMERIC-TYPE. Note that in some
 281 ;;; cases, despite the name, we return *EMPTY-TYPE* instead of a
 282 ;;; NUMERIC-TYPE.
 283 (defun make-numeric-type (&key class format (complexp :real) low high
 284                                enumerable)
 285   ;; if interval is empty
 286   (if (and low
 287            high
 288            (if (or (consp low) (consp high)) ; if either bound is exclusive
 289                (>= (type-bound-number low) (type-bound-number high))
 290                (> low high)))
 291       *empty-type*
 292       (multiple-value-bind (canonical-low canonical-high)
 293           (case class
 294             (integer
 295              ;; INTEGER types always have their LOW and HIGH bounds
 296              ;; represented as inclusive, not exclusive values.
 297              (values (if (consp low)
 298                          (1+ (type-bound-number low))
 299                          low)
 300                      (if (consp high)
 301                          (1- (type-bound-number high))
 302                          high)))
 303             (t
 304              ;; no canonicalization necessary
 305              (values low high)))
 306         (when (and (eq class 'rational)
 307                    (integerp canonical-low)
 308                    (integerp canonical-high)
 309                    (= canonical-low canonical-high))
 310           (setf class 'integer))
 311         (%make-numeric-type :class class
 312                             :format format
 313                             :complexp complexp
 314                             :low canonical-low
 315                             :high canonical-high
 316                             :enumerable enumerable))))
 317
 318 (defun modified-numeric-type (base
 319                               &key
 320                               (class      (numeric-type-class      base))
 321                               (format     (numeric-type-format     base))
 322                               (complexp   (numeric-type-complexp   base))
 323                               (low        (numeric-type-low        base))
 324                               (high       (numeric-type-high       base))
 325                               (enumerable (numeric-type-enumerable base)))
 326   (make-numeric-type :class class
 327                      :format format
 328                      :complexp complexp
 329                      :low low
 330                      :high high
 331                      :enumerable enumerable))
 332
 333 (defstruct (character-set-type
 334             (:include ctype
 335                       (class-info (type-class-or-lose 'character-set)))
 336             (:constructor %make-character-set-type)
 337             (:copier nil))
 338   (pairs (missing-arg) :type list :read-only t))
 339 (defun make-character-set-type (&key pairs)
 340   ; (aver (equal (mapcar #'car pairs)
 341   ;              (sort (mapcar #'car pairs) #'<)))
 342   ;; aver that the cars of the list elements are sorted into increasing order
 343   (aver (or (null pairs)
 344             (do ((p pairs (cdr p)))
 345                 ((null (cdr p)) t)
 346               (when (> (caar p) (caadr p)) (return nil)))))
 347   (let ((pairs (let (result)
 348                 (do ((pairs pairs (cdr pairs)))
 349                     ((null pairs) (nreverse result))
 350                   (destructuring-bind (low . high) (car pairs)
 351                     (loop for (low1 . high1) in (cdr pairs)
 352                           if (<= low1 (1+ high))
 353                           do (progn (setf high (max high high1))
 354                                     (setf pairs (cdr pairs)))
 355                           else do (return nil))
 356                     (cond
 357                       ((>= low sb!xc:char-code-limit))
 358                       ((< high 0))
 359                       (t (push (cons (max 0 low)
 360                                      (min high (1- sb!xc:char-code-limit)))
 361                                result))))))))
 362     (if (null pairs)
 363        *empty-type*
 364        (%make-character-set-type :pairs pairs))))
 365
 366 ;;; An ARRAY-TYPE is used to represent any array type, including
 367 ;;; things such as SIMPLE-BASE-STRING.
 368 (defstruct (array-type (:include ctype
 369                                  (class-info (type-class-or-lose 'array)))
 370                        (:constructor %make-array-type)
 371                        (:copier nil))
 372   ;; the dimensions of the array, or * if unspecified. If a dimension
 373   ;; is unspecified, it is *.
 374   (dimensions '* :type (or list (member *)))
 375   ;; Is this not a simple array type? (:MAYBE means that we don't know.)
 376   (complexp :maybe :type (member t nil :maybe))
 377   ;; the element type as originally specified
 378   (element-type (missing-arg) :type ctype)
 379   ;; the element type as it is specialized in this implementation
 380   (specialized-element-type *wild-type* :type ctype))
 381 (define-cached-synonym make-array-type)
 382
 383 ;;; A MEMBER-TYPE represent a use of the MEMBER type specifier. We
 384 ;;; bother with this at this level because MEMBER types are fairly
 385 ;;; important and union and intersection are well defined.
 386 (defstruct (member-type (:include ctype
 387                                   (class-info (type-class-or-lose 'member))
 388                                   (enumerable t))
 389                         (:copier nil)
 390                         (:constructor %make-member-type (members))
 391                         #-sb-xc-host (:pure nil))
 392   ;; the things in the set, with no duplications
 393   (members nil :type list))
 394 (defun make-member-type (&key members)
 395   (declare (type list members))
 396   ;; make sure that we've removed duplicates
 397   (aver (= (length members) (length (remove-duplicates members))))
 398   ;; if we have a pair of zeros (e.g. 0.0d0 and -0.0d0), then we can
 399   ;; canonicalize to (DOUBLE-FLOAT 0.0d0 0.0d0), because numeric
 400   ;; ranges are compared by arithmetic operators (while MEMBERship is
 401   ;; compared by EQL).  -- CSR, 2003-04-23
 402   (let ((singlep (subsetp `(,(load-time-value (make-unportable-float :single-float-negative-zero)) 0.0f0) members))
 403         (doublep (subsetp `(,(load-time-value (make-unportable-float :double-float-negative-zero)) 0.0d0) members))
 404         #!+long-float
 405         (longp (subsetp `(,(load-time-value (make-unportable-float :long-float-negative-zero)) 0.0l0) members)))
 406     (if (or singlep doublep #!+long-float longp)
 407         (let (union-types)
 408           (when singlep
 409             (push (ctype-of 0.0f0) union-types)
 410             (setf members (set-difference members `(,(load-time-value (make-unportable-float :single-float-negative-zero)) 0.0f0))))
 411           (when doublep
 412             (push (ctype-of 0.0d0) union-types)
 413             (setf members (set-difference members `(,(load-time-value (make-unportable-float :double-float-negative-zero)) 0.0d0))))
 414           #!+long-float
 415           (when longp
 416             (push (ctype-of 0.0l0) union-types)
 417             (setf members (set-difference members `(,(load-time-value (make-unportable-float :long-float-negative-zero)) 0.0l0))))
 418           (aver (not (null union-types)))
 419           (make-union-type t
 420                            (if (null members)
 421                                union-types
 422                                (cons (%make-member-type members)
 423                                      union-types))))
 424         (%make-member-type members))))
 425
 426 ;;; A COMPOUND-TYPE is a type defined out of a set of types, the
 427 ;;; common parent of UNION-TYPE and INTERSECTION-TYPE.
 428 (defstruct (compound-type (:include ctype
 429                                     (might-contain-other-types-p t))
 430                           (:constructor nil)
 431                           (:copier nil))
 432   (types nil :type list :read-only t))
 433
 434 ;;; A UNION-TYPE represents a use of the OR type specifier which we
 435 ;;; couldn't canonicalize to something simpler. Canonical form:
 436 ;;;   1. All possible pairwise simplifications (using the UNION2 type
 437 ;;;      methods) have been performed. Thus e.g. there is never more
 438 ;;;      than one MEMBER-TYPE component. FIXME: As of sbcl-0.6.11.13,
 439 ;;;      this hadn't been fully implemented yet.
 440 ;;;   2. There are never any UNION-TYPE components.
 441 (defstruct (union-type (:include compound-type
 442                                  (class-info (type-class-or-lose 'union)))
 443                        (:constructor %make-union-type (enumerable types))
 444                        (:copier nil)))
 445 (define-cached-synonym make-union-type)
 446
 447 ;;; An INTERSECTION-TYPE represents a use of the AND type specifier
 448 ;;; which we couldn't canonicalize to something simpler. Canonical form:
 449 ;;;   1. All possible pairwise simplifications (using the INTERSECTION2
 450 ;;;      type methods) have been performed. Thus e.g. there is never more
 451 ;;;      than one MEMBER-TYPE component.
 452 ;;;   2. There are never any INTERSECTION-TYPE components: we've
 453 ;;;      flattened everything into a single INTERSECTION-TYPE object.
 454 ;;;   3. There are never any UNION-TYPE components. Either we should
 455 ;;;      use the distributive rule to rearrange things so that
 456 ;;;      unions contain intersections and not vice versa, or we
 457 ;;;      should just punt to using a HAIRY-TYPE.
 458 (defstruct (intersection-type (:include compound-type
 459                                         (class-info (type-class-or-lose
 460                                                      'intersection)))
 461                               (:constructor %make-intersection-type
 462                                             (enumerable types))
 463                               (:copier nil)))
 464
 465 ;;; Return TYPE converted to canonical form for a situation where the
 466 ;;; "type" '* (which SBCL still represents as a type even though ANSI
 467 ;;; CL defines it as a related but different kind of placeholder) is
 468 ;;; equivalent to type T.
 469 (defun type-*-to-t (type)
 470   (if (type= type *wild-type*)
 471       *universal-type*
 472       type))
 473
 474 ;;; A CONS-TYPE is used to represent a CONS type.
 475 (defstruct (cons-type (:include ctype (class-info (type-class-or-lose 'cons)))
 476                       (:constructor
 477                        %make-cons-type (car-type
 478                                         cdr-type))
 479                       (:copier nil))
 480   ;; the CAR and CDR element types (to support ANSI (CONS FOO BAR) types)
 481   ;;
 482   ;; FIXME: Most or all other type structure slots could also be :READ-ONLY.
 483   (car-type (missing-arg) :type ctype :read-only t)
 484   (cdr-type (missing-arg) :type ctype :read-only t))
 485 (defun make-cons-type (car-type cdr-type)
 486   (aver (not (or (eq car-type *wild-type*)
 487                  (eq cdr-type *wild-type*))))
 488   (if (or (eq car-type *empty-type*)
 489           (eq cdr-type *empty-type*))
 490       *empty-type*
 491       (%make-cons-type car-type cdr-type)))
 492
 493 (defun cons-type-length-info (type)
 494   (declare (type cons-type type))
 495   (do ((min 1 (1+ min))
 496        (cdr (cons-type-cdr-type type) (cons-type-cdr-type cdr)))
 497       ((not (cons-type-p cdr))
 498        (cond
 499          ((csubtypep cdr (specifier-type 'null))
 500           (values min t))
 501          ((csubtypep *universal-type* cdr)
 502           (values min nil))
 503          ((type/= (type-intersection (specifier-type 'cons) cdr) *empty-type*)
 504           (values min nil))
 505          ((type/= (type-intersection (specifier-type 'null) cdr) *empty-type*)
 506           (values min t))
 507          (t (values min :maybe))))
 508     ()))
 509
 510 \f
 511 ;;;; type utilities
 512
 513 ;;; Return the type structure corresponding to a type specifier. We
 514 ;;; pick off structure types as a special case.
 515 ;;;
 516 ;;; Note: VALUES-SPECIFIER-TYPE-CACHE-CLEAR must be called whenever a
 517 ;;; type is defined (or redefined).
 518 (defun-cached (values-specifier-type
 519                :hash-function (lambda (x)
 520                                 (logand (sxhash x) #x3FF))
 521                :hash-bits 10
 522                :init-wrapper !cold-init-forms)
 523               ((orig equal-but-no-car-recursion))
 524   (let ((u (uncross orig)))
 525     (or (info :type :builtin u)
 526         (let ((spec (type-expand u)))
 527           (cond
 528            ((and (not (eq spec u))
 529                  (info :type :builtin spec)))
 530            ((eq (info :type :kind spec) :instance)
 531             (find-classoid spec))
 532            ((typep spec 'classoid)
 533             ;; There doesn't seem to be any way to translate
 534             ;; (TYPEP SPEC 'BUILT-IN-CLASS) into something which can be
 535             ;; executed on the host Common Lisp at cross-compilation time.
 536             #+sb-xc-host (error
 537                           "stub: (TYPEP SPEC 'BUILT-IN-CLASS) on xc host")
 538             (if (typep spec 'built-in-classoid)
 539                 (or (built-in-classoid-translation spec) spec)
 540                 spec))
 541            (t
 542             (when (and (atom spec)
 543                        (member spec '(and or not member eql satisfies values)))
 544               (error "The symbol ~S is not valid as a type specifier." spec))
 545             (let* ((lspec (if (atom spec) (list spec) spec))
 546                    (fun (info :type :translator (car lspec))))
 547               (cond (fun
 548                      (funcall fun lspec))
 549                     ((or (and (consp spec) (symbolp (car spec))
 550                               (not (info :type :builtin (car spec))))
 551                          (and (symbolp spec) (not (info :type :builtin spec))))
 552                      (when (and *type-system-initialized*
 553                                 (not (eq (info :type :kind spec)
 554                                          :forthcoming-defclass-type)))
 555                        (signal 'parse-unknown-type :specifier spec))
 556                      ;; (The RETURN-FROM here inhibits caching.)
 557                      (return-from values-specifier-type
 558                        (make-unknown-type :specifier spec)))
 559                     (t
 560                      (error "bad thing to be a type specifier: ~S"
 561                             spec))))))))))
 562
 563 ;;; This is like VALUES-SPECIFIER-TYPE, except that we guarantee to
 564 ;;; never return a VALUES type.
 565 (defun specifier-type (x)
 566   (let ((res (values-specifier-type x)))
 567     (when (or (values-type-p res)
 568               ;; bootstrap magic :-(
 569               (and (named-type-p res)
 570                    (eq (named-type-name res) '*)))
 571       (error "VALUES type illegal in this context:~%  ~S" x))
 572     res))
 573
 574 (defun single-value-specifier-type (x)
 575   (if (eq x '*)
 576       *universal-type*
 577       (specifier-type x)))
 578
 579 ;;; Similar to MACROEXPAND, but expands DEFTYPEs. We don't bother
 580 ;;; returning a second value.
 581 (defun type-expand (form)
 582   (let ((def (cond ((symbolp form)
 583                     (info :type :expander form))
 584                    ((and (consp form) (symbolp (car form)))
 585                     (info :type :expander (car form)))
 586                    (t nil))))
 587     (if def
 588         (type-expand (funcall def (if (consp form) form (list form))))
 589         form)))
 590
 591 ;;; Note that the type NAME has been (re)defined, updating the
 592 ;;; undefined warnings and VALUES-SPECIFIER-TYPE cache.
 593 (defun %note-type-defined (name)
 594   (declare (symbol name))
 595   (note-name-defined name :type)
 596   (when (boundp 'sb!kernel::*values-specifier-type-cache-vector*)
 597     (values-specifier-type-cache-clear))
 598   (values))
 599
 600 \f
 601 (!defun-from-collected-cold-init-forms !early-type-cold-init)