src/code/error.lisp

   1 ;;;; SBCL-specific parts of the condition system, i.e. parts which
   2 ;;;; don't duplicate/clobber functionality already provided by the
   3 ;;;; cross-compilation host Common Lisp
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!KERNEL")
  15
  16 ;;; not sure this is the right place, but where else?
  17 (defun style-warn (datum &rest arguments)
  18   (/show0 "entering STYLE-WARN")
  19   (/show datum arguments)
  20   (if (stringp datum)
  21       (with-sane-io-syntax
  22         (warn 'simple-style-warning
  23               :format-control datum
  24               :format-arguments arguments))
  25       ;; Maybe FIXME: check that the DATUM is a STYLE-WARNING or a
  26       ;; specifier for a subtype of STYLE-WARNING?  (I had trouble
  27       ;; getting through cold-init with that check enabled, though.)
  28       ;; -- RMK, 20080701.
  29       (apply #'warn datum arguments)))
  30
  31 ;;; a utility for SIGNAL, ERROR, CERROR, WARN, COMPILER-NOTIFY and
  32 ;;; INVOKE-DEBUGGER: Parse the hairy argument conventions into a
  33 ;;; single argument that's directly usable by all the other routines.
  34 (defun coerce-to-condition (datum arguments default-type fun-name)
  35   (cond ((typep datum 'condition)
  36          (when (and arguments (not (eq fun-name 'cerror)))
  37            (cerror "Ignore the additional arguments."
  38                    'simple-type-error
  39                    :datum arguments
  40                    :expected-type 'null
  41                    :format-control "You may not supply additional arguments ~
  42                                     when giving ~S to ~S."
  43                    :format-arguments (list datum fun-name)))
  44          datum)
  45         ((symbolp datum) ; roughly, (SUBTYPEP DATUM 'CONDITION)
  46          (apply #'make-condition datum arguments))
  47         ((or (stringp datum) (functionp datum))
  48          (make-condition default-type
  49                          :format-control datum
  50                          :format-arguments arguments))
  51         (t
  52          (error 'simple-type-error
  53                 :datum datum
  54                 :expected-type '(or symbol string function)
  55                 :format-control "Condition designator ~s is not of type ~s."
  56                 :format-arguments (list datum
  57                                         '(or symbol string function))))))
  58
  59 (define-condition layout-invalid (type-error)
  60   ()
  61   (:report
  62    (lambda (condition stream)
  63      (format stream
  64              "~@<invalid structure layout: ~
  65               ~2I~_A test for class ~4I~_~S ~
  66               ~2I~_was passed the obsolete instance ~4I~_~S~:>"
  67              (classoid-proper-name (type-error-expected-type condition))
  68              (type-error-datum condition)))))
  69
  70 (define-condition case-failure (type-error)
  71   ((name :reader case-failure-name :initarg :name)
  72    (possibilities :reader case-failure-possibilities :initarg :possibilities))
  73   (:report
  74     (lambda (condition stream)
  75       (format stream "~@<~S fell through ~S expression. ~
  76                       ~:_Wanted one of ~:S.~:>"
  77               (type-error-datum condition)
  78               (case-failure-name condition)
  79               (case-failure-possibilities condition)))))
  80
  81 (define-condition compiled-program-error (program-error)
  82   ((message :initarg :message :reader program-error-message)
  83    (source :initarg :source :reader program-error-source))
  84   (:report (lambda (condition stream)
  85              (format stream "Execution of a form compiled with errors.~%~
  86                              Form:~%  ~A~%~
  87                              Compile-time error:~%  ~A"
  88                        (program-error-source condition)
  89                        (program-error-message condition)))))
  90
  91 (define-condition interpreted-program-error
  92     (program-error encapsulated-condition)
  93   ;; Unlike COMPILED-PROGRAM-ERROR, we don't need to dump these, so
  94   ;; storing the original condition and form is OK.
  95   ((form :initarg :form :reader program-error-form))
  96   (:report (lambda (condition stream)
  97              (format stream "~&Evaluation of~%  ~S~%~
  98                              caused error:~%  ~A~%"
  99                      (program-error-form condition)
 100                      (encapsulated-condition condition)))))
 101
 102 (define-condition simple-control-error (simple-condition control-error) ())
 103 (define-condition simple-file-error    (simple-condition file-error)    ())
 104 (define-condition simple-program-error (simple-condition program-error) ())
 105 (define-condition simple-stream-error  (simple-condition stream-error)  ())
 106 (define-condition simple-parse-error   (simple-condition parse-error)   ())
 107
 108 (define-condition character-coding-error (error)
 109   ((external-format :initarg :external-format :reader character-coding-error-external-format)))
 110 (define-condition character-encoding-error (character-coding-error)
 111   ((code :initarg :code :reader character-encoding-error-code)))
 112 (define-condition character-decoding-error (character-coding-error)
 113   ((octets :initarg :octets :reader character-decoding-error-octets)))
 114 (define-condition stream-encoding-error (stream-error character-encoding-error)
 115   ()
 116   (:report
 117    (lambda (c s)
 118      (let ((stream (stream-error-stream c))
 119            (code (character-encoding-error-code c)))
 120        (format s "~@<~S stream encoding error on ~S: ~2I~_~
 121                   the character with code ~D cannot be encoded.~@:>"
 122                (character-coding-error-external-format c)
 123                stream
 124                code)))))
 125 (define-condition stream-decoding-error (stream-error character-decoding-error)
 126   ()
 127   (:report
 128    (lambda (c s)
 129      (let ((stream (stream-error-stream c))
 130            (octets (character-decoding-error-octets c)))
 131        (format s "~@<~S stream decoding error on ~S: ~2I~_~
 132                   the octet sequence ~S cannot be decoded.~@:>"
 133                (character-coding-error-external-format c)
 134                stream
 135                octets)))))
 136
 137 (define-condition c-string-encoding-error (character-encoding-error)
 138   ()
 139   (:report
 140    (lambda (c s)
 141      (format s "~@<~S c-string encoding error: ~2I~_~
 142                   the character with code ~D cannot be encoded.~@:>"
 143                (character-coding-error-external-format c)
 144                (character-encoding-error-code c)))))
 145
 146 (define-condition c-string-decoding-error (character-decoding-error)
 147   ()
 148   (:report
 149    (lambda (c s)
 150      (format s "~@<~S c-string decoding error: ~2I~_~
 151                   the octet sequence ~S cannot be decoded.~@:>"
 152              (character-coding-error-external-format c)
 153              (character-decoding-error-octets c)))))
 154
 155 (define-condition control-stack-exhausted (storage-condition)
 156   ()
 157   (:report
 158     (lambda (condition stream)
 159       (declare (ignore condition))
 160       (format stream
 161               ;; no pretty-printing, because that would use a lot of stack.
 162               "Control stack exhausted (no more space for function call frames).
 163 This is probably due to heavily nested or infinitely recursive function
 164 calls, or a tail call that SBCL cannot or has not optimized away.
 165
 166 PROCEED WITH CAUTION."))))
 167
 168 (define-condition binding-stack-exhausted (storage-condition)
 169   ()
 170   (:report
 171     (lambda (condition stream)
 172       (declare (ignore condition))
 173       (format stream
 174               ;; no pretty-printing, because that would use a lot of stack.
 175               "Binding stack exhausted.
 176
 177 PROCEED WITH CAUTION."))))
 178
 179 (define-condition alien-stack-exhausted (storage-condition)
 180   ()
 181   (:report
 182     (lambda (condition stream)
 183       (declare (ignore condition))
 184       (format stream
 185               ;; no pretty-printing, because that would use a lot of stack.
 186               "Alien stack exhausted.
 187
 188 PROCEED WITH CAUTION."))))
 189
 190 (define-condition heap-exhausted-error (storage-condition)
 191   ()
 192   (:report
 193    (lambda (condition stream)
 194      (declare (ignore condition))
 195      (declare (special *heap-exhausted-error-available-bytes*
 196                        *heap-exhausted-error-requested-bytes*))
 197      ;; See comments in interr.lisp -- there is a method to this madness.
 198      (if (and (boundp '*heap-exhausted-error-available-bytes*)
 199               (boundp '*heap-exhausted-error-requested-bytes*))
 200          (format stream
 201                  ;; no pretty-printing, because that will use a lot of heap.
 202                  "Heap exhausted (no more space for allocation).
 203 There are still ~D bytes available; the request was for ~D bytes.
 204
 205 PROCEED WITH CAUTION."
 206                  *heap-exhausted-error-available-bytes*
 207                  *heap-exhausted-error-requested-bytes*)
 208          (format stream
 209                  "A ~S condition without bindings for heap statistics.  (If
 210 you did not expect to see this message, please report it."
 211                  'heap-exhausted-error)))))
 212
 213 (define-condition system-condition (condition)
 214   ((address :initarg :address :reader system-condition-address :initform nil)
 215    (context :initarg :context :reader system-condition-context :initform nil)))
 216
 217 (define-condition memory-fault-error (system-condition error) ()
 218   (:report
 219    (lambda (condition stream)
 220      (format stream "Unhandled memory fault at #x~X."
 221              (system-condition-address condition)))))
 222
 223 (define-condition breakpoint-error (system-condition error) ()
 224   (:report
 225    (lambda (condition stream)
 226      (format stream "Unhandled breakpoint/trap at #x~X."
 227              (system-condition-address condition)))))
 228
 229 (define-condition interactive-interrupt (system-condition serious-condition) ()
 230   (:report
 231    (lambda (condition stream)
 232      (format stream "Interactive interrupt at #x~X."
 233              (system-condition-address condition)))))