src/code/error.lisp

   1 ;;;; SBCL-specific parts of the condition system, i.e. parts which
   2 ;;;; don't duplicate/clobber functionality already provided by the
   3 ;;;; cross-compilation host Common Lisp
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!KERNEL")
  15
  16 ;;; not sure this is the right place, but where else?
  17 (defun style-warn (datum &rest arguments)
  18   (/show0 "entering STYLE-WARN")
  19   (/show format-control format-arguments)
  20   (if (stringp datum)
  21       (with-sane-io-syntax
  22         (warn 'simple-style-warning
  23               :format-control datum
  24               :format-arguments arguments))
  25       ;; Maybe FIXME: check that the DATUM is a STYLE-WARNING or a
  26       ;; specifier for a subtype of STYLE-WARNING?  (I had trouble
  27       ;; getting through cold-init with that check enabled, though.)
  28       ;; -- RMK, 20080701.
  29       (apply #'warn datum arguments)))
  30
  31 ;;; a utility for SIGNAL, ERROR, CERROR, WARN, COMPILER-NOTIFY and
  32 ;;; INVOKE-DEBUGGER: Parse the hairy argument conventions into a
  33 ;;; single argument that's directly usable by all the other routines.
  34 (defun coerce-to-condition (datum arguments default-type fun-name)
  35   (cond ((typep datum 'condition)
  36          (when (and arguments (not (eq fun-name 'cerror)))
  37            (cerror "Ignore the additional arguments."
  38                    'simple-type-error
  39                    :datum arguments
  40                    :expected-type 'null
  41                    :format-control "You may not supply additional arguments ~
  42                                     when giving ~S to ~S."
  43                    :format-arguments (list datum fun-name)))
  44          datum)
  45         ((symbolp datum) ; roughly, (SUBTYPEP DATUM 'CONDITION)
  46          (apply #'make-condition datum arguments))
  47         ((or (stringp datum) (functionp datum))
  48          (make-condition default-type
  49                          :format-control datum
  50                          :format-arguments arguments))
  51         (t
  52          (error 'simple-type-error
  53                 :datum datum
  54                 :expected-type '(or symbol string)
  55                 :format-control "bad argument to ~S: ~S"
  56                 :format-arguments (list fun-name datum)))))
  57
  58 (define-condition layout-invalid (type-error)
  59   ()
  60   (:report
  61    (lambda (condition stream)
  62      (format stream
  63              "~@<invalid structure layout: ~
  64               ~2I~_A test for class ~4I~_~S ~
  65               ~2I~_was passed the obsolete instance ~4I~_~S~:>"
  66              (classoid-proper-name (type-error-expected-type condition))
  67              (type-error-datum condition)))))
  68
  69 (define-condition case-failure (type-error)
  70   ((name :reader case-failure-name :initarg :name)
  71    (possibilities :reader case-failure-possibilities :initarg :possibilities))
  72   (:report
  73     (lambda (condition stream)
  74       (format stream "~@<~S fell through ~S expression. ~
  75                       ~:_Wanted one of ~:S.~:>"
  76               (type-error-datum condition)
  77               (case-failure-name condition)
  78               (case-failure-possibilities condition)))))
  79
  80 (define-condition compiled-program-error (program-error)
  81   ((message :initarg :message :reader program-error-message)
  82    (source :initarg :source :reader program-error-source))
  83   (:report (lambda (condition stream)
  84              (format stream "Execution of a form compiled with errors.~%~
  85                              Form:~%  ~A~%~
  86                              Compile-time error:~%  ~A"
  87                        (program-error-source condition)
  88                        (program-error-message condition)))))
  89
  90 (define-condition interpreted-program-error
  91     (program-error encapsulated-condition)
  92   ;; Unlike COMPILED-PROGRAM-ERROR, we don't need to dump these, so
  93   ;; storing the original condition and form is OK.
  94   ((form :initarg :form :reader program-error-form))
  95   (:report (lambda (condition stream)
  96              (format stream "~&Evaluation of~%  ~S~%~
  97                              caused error:~%  ~A~%"
  98                      (program-error-form condition)
  99                      (encapsulated-condition condition)))))
 100
 101 (define-condition simple-control-error (simple-condition control-error) ())
 102 (define-condition simple-file-error    (simple-condition file-error)    ())
 103 (define-condition simple-program-error (simple-condition program-error) ())
 104 (define-condition simple-stream-error  (simple-condition stream-error)  ())
 105 (define-condition simple-parse-error   (simple-condition parse-error)   ())
 106
 107 (define-condition character-coding-error (error) ())
 108 (define-condition character-encoding-error (character-coding-error)
 109   ((code :initarg :code :reader character-encoding-error-code)))
 110 (define-condition character-decoding-error (character-coding-error)
 111   ((octets :initarg :octets :reader character-decoding-error-octets)))
 112 (define-condition stream-encoding-error (stream-error character-encoding-error)
 113   ()
 114   (:report
 115    (lambda (c s)
 116      (let ((stream (stream-error-stream c))
 117            (code (character-encoding-error-code c)))
 118        (format s "~@<encoding error on stream ~S (~S ~S): ~2I~_~
 119                   the character with code ~D cannot be encoded.~@:>"
 120                stream ':external-format (stream-external-format stream)
 121                code)))))
 122 (define-condition stream-decoding-error (stream-error character-decoding-error)
 123   ()
 124   (:report
 125    (lambda (c s)
 126      (let ((stream (stream-error-stream c))
 127            (octets (character-decoding-error-octets c)))
 128        (format s "~@<decoding error on stream ~S (~S ~S): ~2I~_~
 129                   the octet sequence ~S cannot be decoded.~@:>"
 130                stream ':external-format (stream-external-format stream)
 131                octets)))))
 132
 133 (define-condition c-string-encoding-error (character-encoding-error)
 134   ((external-format :initarg :external-format :reader c-string-encoding-error-external-format))
 135   (:report
 136    (lambda (c s)
 137      (format s "~@<c-string encoding error (:external-format ~S): ~2I~_~
 138                   the character with code ~D cannot be encoded.~@:>"
 139                (c-string-encoding-error-external-format c)
 140                (character-encoding-error-code c)))))
 141
 142 (define-condition c-string-decoding-error (character-decoding-error)
 143   ((external-format :initarg :external-format :reader c-string-decoding-error-external-format))
 144   (:report
 145    (lambda (c s)
 146      (format s "~@<c-string decoding error (:external-format ~S): ~2I~_~
 147                   the octet sequence ~S cannot be decoded.~@:>"
 148              (c-string-decoding-error-external-format c)
 149              (character-decoding-error-octets c)))))
 150
 151 (define-condition control-stack-exhausted (storage-condition)
 152   ()
 153   (:report
 154     (lambda (condition stream)
 155       (declare (ignore condition))
 156       (format stream
 157               ;; no pretty-printing, because that would use a lot of stack.
 158               "Control stack exhausted (no more space for function call frames).
 159 This is probably due to heavily nested or infinitely recursive function
 160 calls, or a tail call that SBCL cannot or has not optimized away.
 161
 162 PROCEED WITH CAUTION."))))
 163
 164 (define-condition heap-exhausted-error (storage-condition)
 165   ()
 166   (:report
 167    (lambda (condition stream)
 168      (declare (ignore condition))
 169      (declare (special *heap-exhausted-error-available-bytes*
 170                        *heap-exhausted-error-requested-bytes*))
 171      ;; See comments in interr.lisp -- there is a method to this madness.
 172      (if (and (boundp '*heap-exhausted-error-available-bytes*)
 173               (boundp '*heap-exhausted-error-requested-bytes*))
 174          (format stream
 175                  ;; no pretty-printing, because that will use a lot of heap.
 176                  "Heap exhausted (no more space for allocation).
 177 There are still ~D bytes available; the request was for ~D bytes.
 178
 179 PROCEED WITH CAUTION."
 180                  *heap-exhausted-error-available-bytes*
 181                  *heap-exhausted-error-requested-bytes*)
 182          (format stream
 183                  "A ~S condition without bindings for heap statistics.  (If
 184 you did not expect to see this message, please report it."
 185                  'heap-exhausted-error)))))
 186
 187 (define-condition system-condition (condition)
 188   ((address :initarg :address :reader system-condition-address :initform nil)
 189    (context :initarg :context :reader system-condition-context :initform nil)))
 190
 191 (define-condition memory-fault-error (system-condition error) ()
 192   (:report
 193    (lambda (condition stream)
 194      (format stream "Unhandled memory fault at #x~X."
 195              (system-condition-address condition)))))
 196
 197 (define-condition breakpoint-error (system-condition error) ()
 198   (:report
 199    (lambda (condition stream)
 200      (format stream "Unhandled breakpoint/trap at #x~X."
 201              (system-condition-address condition)))))
 202
 203 (define-condition interactive-interrupt (system-condition serious-condition) ()
 204   (:report
 205    (lambda (condition stream)
 206      (format stream "Interactive interrupt at #x~X."
 207              (system-condition-address condition)))))