src/code/eval.lisp

   1 ;;;; EVAL and friends
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13
  14 ;;; general case of EVAL (except in that it can't handle toplevel
  15 ;;; EVAL-WHEN magic properly): Delegate to #'COMPILE.
  16 (defun %eval (expr lexenv)
  17   ;; FIXME: It might be nice to quieten the toplevel by muffling
  18   ;; warnings generated by this compilation (since we're about to
  19   ;; execute the results irrespective of the warnings).  We might want
  20   ;; to be careful about not muffling warnings arising from inner
  21   ;; evaluations/compilations, though [e.g. the ignored variable in
  22   ;; (DEFUN FOO (X) 1)].  -- CSR, 2003-05-13
  23   (let ((fun (sb!c:compile-in-lexenv nil
  24                                      `(lambda () ,expr)
  25                                      lexenv)))
  26     (funcall fun)))
  27
  28 ;;; Handle PROGN and implicit PROGN.
  29 (defun eval-progn-body (progn-body lexenv)
  30   (unless (list-with-length-p progn-body)
  31     (let ((*print-circle* t))
  32       (error 'simple-program-error
  33              :format-control
  34              "~@<not a proper list in PROGN or implicit PROGN: ~2I~_~S~:>"
  35              :format-arguments (list progn-body))))
  36   ;; Note:
  37   ;;   * We can't just use (MAP NIL #'EVAL PROGN-BODY) here, because we
  38   ;;     need to take care to return all the values of the final EVAL.
  39   ;;   * It's left as an exercise to the reader to verify that this
  40   ;;     gives the right result when PROGN-BODY is NIL, because
  41   ;;     (FIRST NIL) = (REST NIL) = NIL.
  42   (do* ((i progn-body rest-i)
  43         (rest-i (rest i) (rest i)))
  44       (nil)
  45     (if rest-i ; if not last element of list
  46         (eval-in-lexenv (first i) lexenv)
  47         (return (eval-in-lexenv (first i) lexenv)))))
  48
  49 (defun eval-locally (exp lexenv &key vars)
  50   (multiple-value-bind (body decls)
  51       (parse-body (rest exp) :doc-string-allowed nil)
  52     (let ((lexenv
  53            ;; KLUDGE: Uh, yeah.  I'm not anticipating
  54            ;; winning any prizes for this code, which was
  55            ;; written on a "let's get it to work" basis.
  56            ;; These seem to be the variables that need
  57            ;; bindings for PROCESS-DECLS to work
  58            ;; (*FREE-FUNS* and *FREE-VARS* so that
  59            ;; references to free functions and variables
  60            ;; in the declarations can be noted;
  61            ;; *UNDEFINED-WARNINGS* so that warnings about
  62            ;; undefined things can be accumulated [and
  63            ;; then thrown away, as it happens]). -- CSR,
  64            ;; 2002-10-24
  65            (let* ((sb!c:*lexenv* lexenv)
  66                   (sb!c::*free-funs* (make-hash-table :test 'equal))
  67                   (sb!c::*free-vars* (make-hash-table :test 'eq))
  68                   (sb!c::*undefined-warnings* nil))
  69              ;; FIXME: VALUES declaration
  70              (sb!c::process-decls decls
  71                                   vars
  72                                   nil
  73                                   :lexenv lexenv))))
  74       (eval-progn-body body lexenv))))
  75
  76 (defun eval (original-exp)
  77   #!+sb-doc
  78   "Evaluate the argument in a null lexical environment, returning the
  79   result or results."
  80   (eval-in-lexenv original-exp (make-null-lexenv)))
  81
  82 ;;; Pick off a few easy cases, and the various top level EVAL-WHEN
  83 ;;; magical cases, and call %EVAL for the rest.
  84 (defun eval-in-lexenv (original-exp lexenv)
  85   (declare (optimize (safety 1)))
  86   ;; (aver (lexenv-simple-p lexenv))
  87   (handler-bind
  88       ((sb!c:compiler-error
  89         (lambda (c)
  90           (if (boundp 'sb!c::*compiler-error-bailout*)
  91               ;; if we're in the compiler, delegate either to a higher
  92               ;; authority or, if that's us, back down to the
  93               ;; outermost compiler handler...
  94               (progn
  95                 (signal c)
  96                 nil)
  97               ;; ... if we're not in the compiler, better signal the
  98               ;; error straight away.
  99               (invoke-restart 'sb!c::signal-error)))))
 100     (let ((exp (macroexpand original-exp lexenv)))
 101       (typecase exp
 102         (symbol
 103          (ecase (info :variable :kind exp)
 104            (:constant
 105             (values (info :variable :constant-value exp)))
 106            ((:special :global)
 107             (symbol-value exp))
 108            ;; FIXME: This special case here is a symptom of non-ANSI
 109            ;; weirdness in SBCL's ALIEN implementation, which could
 110            ;; cause problems for e.g. code walkers. It'd probably be
 111            ;; good to ANSIfy it by making alien variable accessors
 112            ;; into ordinary forms, e.g. (SB-UNIX:ENV) and (SETF
 113            ;; SB-UNIX:ENV), instead of magical symbols, e.g. plain
 114            ;; SB-UNIX:ENV. Then if the old magical-symbol syntax is to
 115            ;; be retained for compatibility, it can be implemented
 116            ;; with DEFINE-SYMBOL-MACRO, keeping the code walkers
 117            ;; happy.
 118            (:alien
 119             (%eval original-exp lexenv))))
 120         (list
 121          (let ((name (first exp))
 122                (n-args (1- (length exp))))
 123            (case name
 124              ((function)
 125               (unless (= n-args 1)
 126                 (error "wrong number of args to FUNCTION:~% ~S" exp))
 127               (let ((name (second exp)))
 128                 (if (and (legal-fun-name-p name)
 129                          (not (consp (let ((sb!c:*lexenv* lexenv))
 130                                        (sb!c:lexenv-find name funs)))))
 131                     (%coerce-name-to-fun name)
 132                     (%eval original-exp lexenv))))
 133              ((quote)
 134               (unless (= n-args 1)
 135                 (error "wrong number of args to QUOTE:~% ~S" exp))
 136               (second exp))
 137              (setq
 138               (unless (evenp n-args)
 139                 (error "odd number of args to SETQ:~% ~S" exp))
 140               (unless (zerop n-args)
 141                 (do ((name (cdr exp) (cddr name)))
 142                     ((null name)
 143                      (do ((args (cdr exp) (cddr args)))
 144                          ((null (cddr args))
 145                           ;; We duplicate the call to SET so that the
 146                           ;; correct value gets returned.
 147                           (set (first args) (eval-in-lexenv (second args) lexenv)))
 148                        (set (first args) (eval-in-lexenv (second args) lexenv))))
 149                   (let ((symbol (first name)))
 150                     (case (info :variable :kind symbol)
 151                       (:special)
 152                       (t (return (%eval original-exp lexenv))))
 153                     (unless (type= (info :variable :type symbol)
 154                                    *universal-type*)
 155                       ;; let the compiler deal with type checking
 156                       (return (%eval original-exp lexenv)))))))
 157              ((progn)
 158               (eval-progn-body (rest exp) lexenv))
 159              ((eval-when)
 160               ;; FIXME: DESTRUCTURING-BIND returns ARG-COUNT-ERROR
 161               ;; instead of PROGRAM-ERROR when there's something wrong
 162               ;; with the syntax here (e.g. missing SITUATIONS). This
 163               ;; could be fixed by hand-crafting clauses to catch and
 164               ;; report each possibility, but it would probably be
 165               ;; cleaner to write a new macro
 166               ;; DESTRUCTURING-BIND-PROGRAM-SYNTAX which does
 167               ;; DESTRUCTURING-BIND and promotes any mismatch to
 168               ;; PROGRAM-ERROR, then to use it here and in (probably
 169               ;; dozens of) other places where the same problem
 170               ;; arises.
 171               (destructuring-bind (eval-when situations &rest body) exp
 172                 (declare (ignore eval-when))
 173                 (multiple-value-bind (ct lt e)
 174                     (sb!c:parse-eval-when-situations situations)
 175                   ;; CLHS 3.8 - Special Operator EVAL-WHEN: The use of
 176                   ;; the situation :EXECUTE (or EVAL) controls whether
 177                   ;; evaluation occurs for other EVAL-WHEN forms; that
 178                   ;; is, those that are not top level forms, or those
 179                   ;; in code processed by EVAL or COMPILE. If the
 180                   ;; :EXECUTE situation is specified in such a form,
 181                   ;; then the body forms are processed as an implicit
 182                   ;; PROGN; otherwise, the EVAL-WHEN form returns NIL.
 183                   (declare (ignore ct lt))
 184                   (when e
 185                     (eval-progn-body body lexenv)))))
 186              ((locally)
 187               (eval-locally exp lexenv))
 188              ((macrolet)
 189               (destructuring-bind (definitions &rest body)
 190                   (rest exp)
 191                 (let ((lexenv
 192                        (let ((sb!c:*lexenv* lexenv))
 193                          (sb!c::funcall-in-macrolet-lexenv
 194                           definitions
 195                           (lambda (&key funs)
 196                             (declare (ignore funs))
 197                             sb!c:*lexenv*)
 198                           :eval))))
 199                   (eval-locally `(locally ,@body) lexenv))))
 200              ((symbol-macrolet)
 201               (destructuring-bind (definitions &rest body) (rest exp)
 202                 (multiple-value-bind (lexenv vars)
 203                     (let ((sb!c:*lexenv* lexenv))
 204                       (sb!c::funcall-in-symbol-macrolet-lexenv
 205                        definitions
 206                        (lambda (&key vars)
 207                          (values sb!c:*lexenv* vars))
 208                        :eval))
 209                   (eval-locally `(locally ,@body) lexenv :vars vars))))
 210              (t
 211               (if (and (symbolp name)
 212                        (eq (info :function :kind name) :function))
 213                   (collect ((args))
 214                     (dolist (arg (rest exp))
 215                       (args (eval-in-lexenv arg lexenv)))
 216                     (apply (symbol-function name) (args)))
 217                   (%eval exp lexenv))))))
 218         (t
 219          exp)))))
 220 \f
 221 ;;; miscellaneous full function definitions of things which are
 222 ;;; ordinarily handled magically by the compiler
 223
 224 (defun apply (function arg &rest arguments)
 225   #!+sb-doc
 226   "Apply FUNCTION to a list of arguments produced by evaluating ARGUMENTS in
 227   the manner of LIST*. That is, a list is made of the values of all but the
 228   last argument, appended to the value of the last argument, which must be a
 229   list."
 230   (cond ((atom arguments)
 231          (apply function arg))
 232         ((atom (cdr arguments))
 233          (apply function (cons arg (car arguments))))
 234         (t (do* ((a1 arguments a2)
 235                  (a2 (cdr arguments) (cdr a2)))
 236                 ((atom (cdr a2))
 237                  (rplacd a1 (car a2))
 238                  (apply function (cons arg arguments)))))))
 239
 240 (defun funcall (function &rest arguments)
 241   #!+sb-doc
 242   "Call FUNCTION with the given ARGUMENTS."
 243   (apply function arguments))
 244
 245 (defun values (&rest values)
 246   #!+sb-doc
 247   "Return all arguments, in order, as values."
 248   (declare (dynamic-extent values))
 249   (values-list values))
 250
 251 (defun values-list (list)
 252   #!+sb-doc
 253   "Return all of the elements of LIST, in order, as values."
 254   (values-list list))